qcsrc/menu/xonotic/screenshotlist.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticScreenshotList) EXTENDS(XonoticListBox)
   3         METHOD(XonoticScreenshotList, configureXonoticScreenshotList, void(entity))
   4         ATTRIB(XonoticScreenshotList, rowsPerItem, float, 1)
   5         METHOD(XonoticScreenshotList, resizeNotify, void(entity, vector, vector, vector, vector))
   6         METHOD(XonoticScreenshotList, setSelected, void(entity, float))
   7         METHOD(XonoticScreenshotList, draw, void(entity))
   8         METHOD(XonoticScreenshotList, drawListBoxItem, void(entity, float, vector, float))
   9         METHOD(XonoticScreenshotList, getScreenshots, void(entity))
  10         METHOD(XonoticScreenshotList, previewScreenshot, void(entity))
  11         METHOD(XonoticScreenshotList, startScreenshot, void(entity))
  12         METHOD(XonoticScreenshotList, screenshotName, string(entity, float))
  13         METHOD(XonoticScreenshotList, clickListBoxItem, void(entity, float, vector))
  14         METHOD(XonoticScreenshotList, keyDown, float(entity, float, float, float))
  15         METHOD(XonoticScreenshotList, destroy, void(entity))
  16         METHOD(XonoticScreenshotList, showNotify, void(entity))
  17         ATTRIB(XonoticScreenshotList, listScreenshot, float, -1)
  18         ATTRIB(XonoticScreenshotList, realFontSize, vector, '0 0 0')
  19         ATTRIB(XonoticScreenshotList, columnNameOrigin, float, 0)
  20         ATTRIB(XonoticScreenshotList, columnNameSize, float, 0)
  21         ATTRIB(XonoticScreenshotList, realUpperMargin, float, 0)
  22         ATTRIB(XonoticScreenshotList, origin, vector, '0 0 0')
  23         ATTRIB(XonoticScreenshotList, itemAbsSize, vector, '0 0 0')
  24         ATTRIB(XonoticScreenshotList, lastClickedScreenshot, float, -1)
  25         ATTRIB(XonoticScreenshotList, lastClickedTime, float, 0)
  26         ATTRIB(XonoticScreenshotList, filterString, string, string_null)
  27         ATTRIB(XonoticScreenshotList, filterBox, entity, NULL)
  28         ATTRIB(XonoticScreenshotList, filterTime, float, 0)
  29
  30         ATTRIB(XonoticScreenshotList, screenshotBrowserDialog, entity, NULL)
  31         ATTRIB(XonoticScreenshotList, screenshotPreview, entity, NULL)
  32         ATTRIB(XonoticScreenshotList, screenshotViewerDialog, entity, NULL)
  33         METHOD(XonoticScreenshotList, goScreenshot, void(entity, float))
  34 ENDCLASS(XonoticScreenshotList)
  35
  36 entity makeXonoticScreenshotList();
  37 void StartScreenshot_Click(entity btn, entity me);
  38 void ScreenshotList_Refresh_Click(entity btn, entity me);
  39 void ScreenshotList_Filter_Would_Change(entity box, entity me);
  40 void ScreenshotList_Filter_Change(entity box, entity me);
  41 #endif
  42
  43 #ifdef IMPLEMENTATION
  44
  45 entity makeXonoticScreenshotList()
  46 {
  47         entity me;
  48         me = spawnXonoticScreenshotList();
  49         me.configureXonoticScreenshotList(me);
  50         return me;
  51 }
  52
  53 void XonoticScreenshotList_configureXonoticScreenshotList(entity me)
  54 {
  55         me.configureXonoticListBox(me);
  56         me.getScreenshots(me);
  57 }
  58
  59 string XonoticScreenshotList_screenshotName(entity me, float i )
  60 {
  61         string s;
  62         s = bufstr_get(me.listScreenshot, i);
  63         s = substring(s, 12, strlen(s) - 12 - 4);  // screenshots/, .<ext>
  64         return s;
  65 }
  66
  67 // if subdir is TRUE look in subdirectories too (1 level)
  68 void getScreenshots_for_ext(entity me, string ext, float subdir)
  69 {
  70         string s;
  71         if (subdir)
  72                 s="screenshots/*/";
  73         else
  74                 s="screenshots/";
  75         if(me.filterString)
  76                 s=strcat(s, me.filterString, ext);
  77         else
  78                 s=strcat(s, "*", ext);
  79
  80         float list, i, n;
  81         list = search_begin(s, FALSE, TRUE);
  82         if(list >= 0)
  83         {
  84                 n = search_getsize(list);
  85                 for(i = 0; i < n; ++i)
  86                         bufstr_add(me.listScreenshot, search_getfilename(list, i), TRUE);
  87                 search_end(list);
  88         }
  89
  90         if (subdir)
  91                 getScreenshots_for_ext(me, ext, FALSE);
  92 }
  93
  94 void XonoticScreenshotList_getScreenshots(entity me)
  95 {
  96         if (me.listScreenshot >= 0)
  97                 buf_del(me.listScreenshot);
  98         me.listScreenshot = buf_create();
  99         if (me.listScreenshot < 0)
 100         {
 101                 me.nItems = 0;
 102                 return;
 103         }
 104         getScreenshots_for_ext(me, ".jpg", TRUE);
 105         getScreenshots_for_ext(me, ".tga", TRUE);
 106         getScreenshots_for_ext(me, ".png", TRUE);
 107         me.nItems = buf_getsize(me.listScreenshot);
 108         buf_sort(me.listScreenshot, 128, FALSE);
 109 }
 110
 111 void XonoticScreenshotList_destroy(entity me)
 112 {
 113         buf_del(me.listScreenshot);
 114 }
 115
 116 void XonoticScreenshotList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 117 {
 118         me.itemAbsSize = '0 0 0';
 119         SUPER(XonoticScreenshotList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 120
 121         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
 122         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
 123         me.realUpperMargin = 0.5 * (1 - me.realFontSize_y);
 124
 125         me.columnNameOrigin = me.realFontSize_x;
 126         me.columnNameSize = 1 - 2 * me.realFontSize_x;
 127 }
 128
 129 void XonoticScreenshotList_setSelected(entity me, float i)
 130 {
 131         SUPER(XonoticScreenshotList).setSelected(me, i);
 132         me.previewScreenshot(me); // load the preview on selection change
 133 }
 134
 135 void XonoticScreenshotList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
 136 {
 137         string s;
 138         if(isSelected)
 139                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 140
 141         s = me.screenshotName(me,i);
 142         s = draw_TextShortenToWidth(s, me.columnNameSize, 0, me.realFontSize);
 143         draw_Text(me.realUpperMargin * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 144 }
 145
 146 void XonoticScreenshotList_showNotify(entity me)
 147 {
 148         me.getScreenshots(me);
 149         me.previewScreenshot(me);
 150 }
 151
 152 void ScreenshotList_Refresh_Click(entity btn, entity me)
 153 {
 154         me.getScreenshots(me);
 155         me.setSelected(me, 0); //always select the first element after a list update
 156 }
 157
 158 void ScreenshotList_Filter_Change(entity box, entity me)
 159 {
 160         if(me.filterString)
 161                 strunzone(me.filterString);
 162
 163         if(box.text != "")
 164         {
 165                 if (strstrofs(box.text, "*", 0) >= 0 || strstrofs(box.text, "?", 0) >= 0)
 166                         me.filterString = strzone(box.text);
 167                 else
 168                         me.filterString = strzone(strcat("*", box.text, "*"));
 169         }
 170         else
 171                 me.filterString = string_null;
 172
 173         ScreenshotList_Refresh_Click(world, me);
 174 }
 175
 176 void ScreenshotList_Filter_Would_Change(entity box, entity me)
 177 {
 178         me.filterBox = box;
 179         me.filterTime = time + 0.5;
 180 }
 181
 182 void XonoticScreenshotList_draw(entity me)
 183 {
 184         if (me.filterTime && time > me.filterTime)
 185         {
 186                 ScreenshotList_Filter_Change(me.filterBox, me);
 187                 me.filterTime = 0;
 188         }
 189         SUPER(XonoticScreenshotList).draw(me);
 190 }
 191
 192 void XonoticScreenshotList_goScreenshot(entity me, float d)
 193 {
 194         if(!me.screenshotViewerDialog)
 195                 return;
 196         me.setSelected(me, me.selectedItem + d);
 197         me.screenshotViewerDialog.loadScreenshot(me.screenshotViewerDialog, strcat("/screenshots/", me.screenshotName(me,me.selectedItem)));
 198 }
 199
 200 void XonoticScreenshotList_startScreenshot(entity me)
 201 {
 202         me.screenshotViewerDialog.loadScreenshot(me.screenshotViewerDialog, strcat("/screenshots/", me.screenshotName(me,me.selectedItem)));
 203         // pop up screenshot
 204         DialogOpenButton_Click_withCoords(NULL, me.screenshotViewerDialog, me.origin + eX * (me.columnNameOrigin * me.size_x) + eY * ((me.itemHeight * me.selectedItem - me.scrollPos) * me.size_y), eY * me.itemAbsSize_y + eX * (me.itemAbsSize_x * me.columnNameSize));
 205 }
 206
 207 void XonoticScreenshotList_previewScreenshot(entity me)
 208 {
 209         if(!me.screenshotBrowserDialog)
 210                 return;
 211         if (me.nItems <= 0)
 212                 me.screenshotBrowserDialog.loadPreviewScreenshot(me.screenshotBrowserDialog, "");
 213         else
 214                 me.screenshotBrowserDialog.loadPreviewScreenshot(me.screenshotBrowserDialog, strcat("/screenshots/", me.screenshotName(me,me.selectedItem)));
 215 }
 216
 217 void StartScreenshot_Click(entity btn, entity me)
 218 {
 219         me.startScreenshot(me);
 220 }
 221
 222 void XonoticScreenshotList_clickListBoxItem(entity me, float i, vector where)
 223 {
 224         if(i == me.lastClickedScreenshot)
 225                 if(time < me.lastClickedTime + 0.3)
 226                 {
 227                         // DOUBLE CLICK!
 228                         // pop up screenshot
 229                         me.setSelected(me, i);
 230                         me.startScreenshot(me);
 231                 }
 232         me.lastClickedScreenshot = i;
 233         me.lastClickedTime = time;
 234 }
 235
 236 float XonoticScreenshotList_keyDown(entity me, float scan, float ascii, float shift)
 237 {
 238         if(scan == K_ENTER || scan == K_KP_ENTER) {
 239                 me.startScreenshot(me);
 240                 return 1;
 241         }
 242         else
 243                 return SUPER(XonoticScreenshotList).keyDown(me, scan, ascii, shift);
 244 }
 245 #endif