qcsrc/menu/xonotic/screenshotlist.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticScreenshotList) EXTENDS(XonoticListBox)
   3         METHOD(XonoticScreenshotList, configureXonoticScreenshotList, void(entity))
   4         ATTRIB(XonoticScreenshotList, rowsPerItem, float, 1)
   5         METHOD(XonoticScreenshotList, resizeNotify, void(entity, vector, vector, vector, vector))
   6         METHOD(XonoticScreenshotList, drawListBoxItem, void(entity, float, vector, float))
   7         METHOD(XonoticScreenshotList, getScreenshots, void(entity))
   8         METHOD(XonoticScreenshotList, previewScreenshot, void(entity))
   9         METHOD(XonoticScreenshotList, startScreenshot, void(entity))
  10         METHOD(XonoticScreenshotList, screenshotName, string(entity, float))
  11         METHOD(XonoticScreenshotList, clickListBoxItem, void(entity, float, vector))
  12         METHOD(XonoticScreenshotList, keyDown, float(entity, float, float, float))
  13         METHOD(XonoticScreenshotList, destroy, void(entity))
  14         METHOD(XonoticScreenshotList, showNotify, void(entity))
  15         ATTRIB(XonoticScreenshotList, listScreenshot, float, -1)
  16         ATTRIB(XonoticScreenshotList, realFontSize, vector, '0 0 0')
  17         ATTRIB(XonoticScreenshotList, columnNameOrigin, float, 0)
  18         ATTRIB(XonoticScreenshotList, columnNameSize, float, 0)
  19         ATTRIB(XonoticScreenshotList, realUpperMargin, float, 0)
  20         ATTRIB(XonoticScreenshotList, origin, vector, '0 0 0')
  21         ATTRIB(XonoticScreenshotList, itemAbsSize, vector, '0 0 0')
  22         ATTRIB(XonoticScreenshotList, lastClickedScreenshot, float, -1)
  23         ATTRIB(XonoticScreenshotList, lastClickedTime, float, 0)
  24         ATTRIB(XonoticScreenshotList, filterString, string, string_null)
  25
  26         ATTRIB(XonoticScreenshotList, screenshotBrowserDialog, entity, NULL)
  27         ATTRIB(XonoticScreenshotList, screenshotPreview, entity, NULL)
  28         ATTRIB(XonoticScreenshotList, screenshotViewerDialog, entity, NULL)
  29         METHOD(XonoticScreenshotList, goScreenshot, void(entity, float))
  30 ENDCLASS(XonoticScreenshotList)
  31
  32 entity makeXonoticScreenshotList();
  33 void StartScreenshot_Click(entity btn, entity me);
  34 void ScreenshotList_Filter_Change(entity box, entity me);
  35 #endif
  36
  37 #ifdef IMPLEMENTATION
  38
  39 entity makeXonoticScreenshotList()
  40 {
  41         entity me;
  42         me = spawnXonoticScreenshotList();
  43         me.configureXonoticScreenshotList(me);
  44         return me;
  45 }
  46
  47 void XonoticScreenshotList_configureXonoticScreenshotList(entity me)
  48 {
  49         me.configureXonoticListBox(me);
  50         me.getScreenshots(me);
  51 }
  52
  53 string XonoticScreenshotList_screenshotName(entity me, float i )
  54 {
  55         string s;
  56         s = bufstr_get(me.listScreenshot, i);
  57         s = substring(s, 12, strlen(s) - 12 - 4);  // screenshots/, .<ext>
  58         return s;
  59 }
  60
  61 // if subdir is TRUE look in subdirectories too (1 level)
  62 void getScreenshots_for_ext(entity me, string ext, float subdir)
  63 {
  64         string s;
  65         if (subdir)
  66                 s="screenshots/*/";
  67         else
  68                 s="screenshots/";
  69         if(me.filterString)
  70                 s=strcat(s, me.filterString, ext);
  71         else
  72                 s=strcat(s, "*", ext);
  73
  74         float list, i, n;
  75         list = search_begin(s, FALSE, TRUE);
  76         if(list >= 0)
  77         {
  78                 n = search_getsize(list);
  79                 for(i = 0; i < n; ++i)
  80                         bufstr_add(me.listScreenshot, search_getfilename(list, i), TRUE);
  81                 search_end(list);
  82         }
  83
  84         if (subdir)
  85                 getScreenshots_for_ext(me, ext, FALSE);
  86 }
  87
  88 void XonoticScreenshotList_getScreenshots(entity me)
  89 {
  90         if (me.listScreenshot >= 0)
  91                 buf_del(me.listScreenshot);
  92         me.listScreenshot = buf_create();
  93         if (me.listScreenshot < 0)
  94         {
  95                 me.nItems = 0;
  96                 return;
  97         }
  98         getScreenshots_for_ext(me, ".jpg", TRUE);
  99         getScreenshots_for_ext(me, ".tga", TRUE);
 100         getScreenshots_for_ext(me, ".png", TRUE);
 101         me.nItems = buf_getsize(me.listScreenshot);
 102         buf_sort(me.listScreenshot, 128, FALSE);
 103 }
 104
 105 void XonoticScreenshotList_destroy(entity me)
 106 {
 107         buf_del(me.listScreenshot);
 108 }
 109
 110 void XonoticScreenshotList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 111 {
 112         me.itemAbsSize = '0 0 0';
 113         SUPER(XonoticScreenshotList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 114
 115         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
 116         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
 117         me.realUpperMargin = 0.5 * (1 - me.realFontSize_y);
 118
 119         me.columnNameOrigin = me.realFontSize_x;
 120         me.columnNameSize = 1 - 2 * me.realFontSize_x;
 121 }
 122
 123 void XonoticScreenshotList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
 124 {
 125         string s;
 126         if(isSelected)
 127         {
 128                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 129                 me.previewScreenshot(me);
 130         }
 131
 132         s = me.screenshotName(me,i);
 133         s = draw_TextShortenToWidth(s, me.columnNameSize, 0, me.realFontSize);
 134         draw_Text(me.realUpperMargin * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 135 }
 136
 137 void XonoticScreenshotList_showNotify(entity me)
 138 {
 139         me.getScreenshots(me);
 140 }
 141
 142 void ScreenshotList_Filter_Change(entity box, entity me)
 143 {
 144         if(me.filterString)
 145                 strunzone(me.filterString);
 146
 147         if(box.text != "")
 148         {
 149                 if (strstrofs(box.text, "*", 0) >= 0 || strstrofs(box.text, "?", 0) >= 0)
 150                         me.filterString = strzone(box.text);
 151                 else
 152                         me.filterString = strzone(strcat("*", box.text, "*"));
 153         }
 154         else
 155                 me.filterString = string_null;
 156
 157         me.getScreenshots(me);
 158         me.setSelected(me, 0); //alway select the first element after a new search
 159 }
 160
 161 void XonoticScreenshotList_goScreenshot(entity me, float d)
 162 {
 163         if(!me.screenshotViewerDialog)
 164                 return;
 165         me.setSelected(me, me.selectedItem + d);
 166         me.screenshotViewerDialog.loadScreenshot(me.screenshotViewerDialog, strcat("/screenshots/", me.screenshotName(me,me.selectedItem)));
 167 }
 168
 169 void XonoticScreenshotList_startScreenshot(entity me)
 170 {
 171         me.screenshotViewerDialog.loadScreenshot(me.screenshotViewerDialog, strcat("/screenshots/", me.screenshotName(me,me.selectedItem)));
 172         // pop up screenshot
 173         DialogOpenButton_Click_withCoords(NULL, me.screenshotViewerDialog, me.origin + eX * (me.columnNameOrigin * me.size_x) + eY * ((me.itemHeight * me.selectedItem - me.scrollPos) * me.size_y), eY * me.itemAbsSize_y + eX * (me.itemAbsSize_x * me.columnNameSize));
 174 }
 175
 176 void XonoticScreenshotList_previewScreenshot(entity me)
 177 {
 178         if(!me.screenshotBrowserDialog)
 179                 return;
 180         me.screenshotBrowserDialog.loadPreviewScreenshot(me.screenshotBrowserDialog, strcat("/screenshots/", me.screenshotName(me,me.selectedItem)));
 181 }
 182
 183 void StartScreenshot_Click(entity btn, entity me)
 184 {
 185         me.startScreenshot(me);
 186 }
 187
 188 void XonoticScreenshotList_clickListBoxItem(entity me, float i, vector where)
 189 {
 190         if(i == me.lastClickedScreenshot)
 191                 if(time < me.lastClickedTime + 0.3)
 192                 {
 193                         // DOUBLE CLICK!
 194                         // pop up screenshot
 195                         me.setSelected(me, i);
 196                         me.startScreenshot(me);
 197                 }
 198         me.lastClickedScreenshot = i;
 199         me.lastClickedTime = time;
 200 }
 201
 202 float XonoticScreenshotList_keyDown(entity me, float scan, float ascii, float shift)
 203 {
 204         if(scan == K_ENTER || scan == K_KP_ENTER) {
 205                 me.startScreenshot(me);
 206                 return 1;
 207         }
 208         else
 209                 return SUPER(XonoticScreenshotList).keyDown(me, scan, ascii, shift);
 210 }
 211 #endif