qcsrc/menu/xonotic/screenshotlist.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticScreenshotList) EXTENDS(XonoticListBox)
   3         METHOD(XonoticScreenshotList, configureXonoticScreenshotList, void(entity))
   4         ATTRIB(XonoticScreenshotList, rowsPerItem, float, 1)
   5         METHOD(XonoticScreenshotList, resizeNotify, void(entity, vector, vector, vector, vector))
   6         METHOD(XonoticScreenshotList, drawListBoxItem, void(entity, float, vector, float))
   7         METHOD(XonoticScreenshotList, getScreenshots, void(entity))
   8         METHOD(XonoticScreenshotList, previewScreenshot, void(entity))
   9         METHOD(XonoticScreenshotList, startScreenshot, void(entity))
  10         METHOD(XonoticScreenshotList, screenshotName, string(entity, float))
  11         METHOD(XonoticScreenshotList, clickListBoxItem, void(entity, float, vector))
  12         METHOD(XonoticScreenshotList, keyDown, float(entity, float, float, float))
  13         METHOD(XonoticScreenshotList, destroy, void(entity))
  14         METHOD(XonoticScreenshotList, showNotify, void(entity))
  15         ATTRIB(XonoticScreenshotList, listScreenshot, float, -1)
  16         ATTRIB(XonoticScreenshotList, realFontSize, vector, '0 0 0')
  17         ATTRIB(XonoticScreenshotList, columnNameOrigin, float, 0)
  18         ATTRIB(XonoticScreenshotList, columnNameSize, float, 0)
  19         ATTRIB(XonoticScreenshotList, realUpperMargin, float, 0)
  20         ATTRIB(XonoticScreenshotList, origin, vector, '0 0 0')
  21         ATTRIB(XonoticScreenshotList, itemAbsSize, vector, '0 0 0')
  22         ATTRIB(XonoticScreenshotList, lastClickedScreenshot, float, -1)
  23         ATTRIB(XonoticScreenshotList, lastClickedTime, float, 0)
  24         ATTRIB(XonoticScreenshotList, filterString, string, string_null)
  25
  26         ATTRIB(XonoticScreenshotList, screenshotBrowserDialog, entity, NULL)
  27         ATTRIB(XonoticScreenshotList, screenshotPreview, entity, NULL)
  28         ATTRIB(XonoticScreenshotList, screenshotViewerDialog, entity, NULL)
  29         METHOD(XonoticScreenshotList, goScreenshot, void(entity, float))
  30 ENDCLASS(XonoticScreenshotList)
  31
  32 entity makeXonoticScreenshotList();
  33 void StartScreenshot_Click(entity btn, entity me);
  34 void ScreenshotList_Refresh_Click(entity btn, entity me);
  35 void ScreenshotList_Filter_Change(entity box, entity me);
  36 #endif
  37
  38 #ifdef IMPLEMENTATION
  39
  40 entity makeXonoticScreenshotList()
  41 {
  42         entity me;
  43         me = spawnXonoticScreenshotList();
  44         me.configureXonoticScreenshotList(me);
  45         return me;
  46 }
  47
  48 void XonoticScreenshotList_configureXonoticScreenshotList(entity me)
  49 {
  50         me.configureXonoticListBox(me);
  51         me.getScreenshots(me);
  52 }
  53
  54 string XonoticScreenshotList_screenshotName(entity me, float i )
  55 {
  56         string s;
  57         s = bufstr_get(me.listScreenshot, i);
  58         s = substring(s, 12, strlen(s) - 12 - 4);  // screenshots/, .<ext>
  59         return s;
  60 }
  61
  62 // if subdir is TRUE look in subdirectories too (1 level)
  63 void getScreenshots_for_ext(entity me, string ext, float subdir)
  64 {
  65         string s;
  66         if (subdir)
  67                 s="screenshots/*/";
  68         else
  69                 s="screenshots/";
  70         if(me.filterString)
  71                 s=strcat(s, me.filterString, ext);
  72         else
  73                 s=strcat(s, "*", ext);
  74
  75         float list, i, n;
  76         list = search_begin(s, FALSE, TRUE);
  77         if(list >= 0)
  78         {
  79                 n = search_getsize(list);
  80                 for(i = 0; i < n; ++i)
  81                         bufstr_add(me.listScreenshot, search_getfilename(list, i), TRUE);
  82                 search_end(list);
  83         }
  84
  85         if (subdir)
  86                 getScreenshots_for_ext(me, ext, FALSE);
  87 }
  88
  89 void XonoticScreenshotList_getScreenshots(entity me)
  90 {
  91         if (me.listScreenshot >= 0)
  92                 buf_del(me.listScreenshot);
  93         me.listScreenshot = buf_create();
  94         if (me.listScreenshot < 0)
  95         {
  96                 me.nItems = 0;
  97                 return;
  98         }
  99         getScreenshots_for_ext(me, ".jpg", TRUE);
 100         getScreenshots_for_ext(me, ".tga", TRUE);
 101         getScreenshots_for_ext(me, ".png", TRUE);
 102         me.nItems = buf_getsize(me.listScreenshot);
 103         buf_sort(me.listScreenshot, 128, FALSE);
 104 }
 105
 106 void XonoticScreenshotList_destroy(entity me)
 107 {
 108         buf_del(me.listScreenshot);
 109 }
 110
 111 void XonoticScreenshotList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 112 {
 113         me.itemAbsSize = '0 0 0';
 114         SUPER(XonoticScreenshotList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 115
 116         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
 117         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
 118         me.realUpperMargin = 0.5 * (1 - me.realFontSize_y);
 119
 120         me.columnNameOrigin = me.realFontSize_x;
 121         me.columnNameSize = 1 - 2 * me.realFontSize_x;
 122 }
 123
 124 void XonoticScreenshotList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
 125 {
 126         string s;
 127         if(isSelected)
 128         {
 129                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 130                 me.previewScreenshot(me);
 131         }
 132
 133         s = me.screenshotName(me,i);
 134         s = draw_TextShortenToWidth(s, me.columnNameSize, 0, me.realFontSize);
 135         draw_Text(me.realUpperMargin * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 136 }
 137
 138 void XonoticScreenshotList_showNotify(entity me)
 139 {
 140         me.getScreenshots(me);
 141 }
 142
 143 void ScreenshotList_Refresh_Click(entity btn, entity me)
 144 {
 145         me.getScreenshots(me);
 146         if (me.nItems <= 0)
 147                 me.screenshotBrowserDialog.loadPreviewScreenshot(me.screenshotBrowserDialog, "");
 148         else
 149                 me.setSelected(me, 0); //always select the first element after a list update
 150 }
 151
 152 void ScreenshotList_Filter_Change(entity box, entity me)
 153 {
 154         if(me.filterString)
 155                 strunzone(me.filterString);
 156
 157         if(box.text != "")
 158         {
 159                 if (strstrofs(box.text, "*", 0) >= 0 || strstrofs(box.text, "?", 0) >= 0)
 160                         me.filterString = strzone(box.text);
 161                 else
 162                         me.filterString = strzone(strcat("*", box.text, "*"));
 163         }
 164         else
 165                 me.filterString = string_null;
 166
 167         ScreenshotList_Refresh_Click(world, me);
 168 }
 169
 170 void XonoticScreenshotList_goScreenshot(entity me, float d)
 171 {
 172         if(!me.screenshotViewerDialog)
 173                 return;
 174         me.setSelected(me, me.selectedItem + d);
 175         me.screenshotViewerDialog.loadScreenshot(me.screenshotViewerDialog, strcat("/screenshots/", me.screenshotName(me,me.selectedItem)));
 176 }
 177
 178 void XonoticScreenshotList_startScreenshot(entity me)
 179 {
 180         me.screenshotViewerDialog.loadScreenshot(me.screenshotViewerDialog, strcat("/screenshots/", me.screenshotName(me,me.selectedItem)));
 181         // pop up screenshot
 182         DialogOpenButton_Click_withCoords(NULL, me.screenshotViewerDialog, me.origin + eX * (me.columnNameOrigin * me.size_x) + eY * ((me.itemHeight * me.selectedItem - me.scrollPos) * me.size_y), eY * me.itemAbsSize_y + eX * (me.itemAbsSize_x * me.columnNameSize));
 183 }
 184
 185 void XonoticScreenshotList_previewScreenshot(entity me)
 186 {
 187         if(!me.screenshotBrowserDialog)
 188                 return;
 189         me.screenshotBrowserDialog.loadPreviewScreenshot(me.screenshotBrowserDialog, strcat("/screenshots/", me.screenshotName(me,me.selectedItem)));
 190 }
 191
 192 void StartScreenshot_Click(entity btn, entity me)
 193 {
 194         me.startScreenshot(me);
 195 }
 196
 197 void XonoticScreenshotList_clickListBoxItem(entity me, float i, vector where)
 198 {
 199         if(i == me.lastClickedScreenshot)
 200                 if(time < me.lastClickedTime + 0.3)
 201                 {
 202                         // DOUBLE CLICK!
 203                         // pop up screenshot
 204                         me.setSelected(me, i);
 205                         me.startScreenshot(me);
 206                 }
 207         me.lastClickedScreenshot = i;
 208         me.lastClickedTime = time;
 209 }
 210
 211 float XonoticScreenshotList_keyDown(entity me, float scan, float ascii, float shift)
 212 {
 213         if(scan == K_ENTER || scan == K_KP_ENTER) {
 214                 me.startScreenshot(me);
 215                 return 1;
 216         }
 217         else
 218                 return SUPER(XonoticScreenshotList).keyDown(me, scan, ascii, shift);
 219 }
 220 #endif