qcsrc/menu/xonotic/playermodel.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticPlayerModelSelector) EXTENDS(XonoticImage)
   3         METHOD(XonoticPlayerModelSelector, configureXonoticPlayerModelSelector, void(entity))
   4         METHOD(XonoticPlayerModelSelector, loadCvars, void(entity))
   5         METHOD(XonoticPlayerModelSelector, saveCvars, void(entity))
   6         METHOD(XonoticPlayerModelSelector, draw, void(entity))
   7         METHOD(XonoticPlayerModelSelector, resizeNotify, void(entity, vector, vector, vector, vector))
   8         METHOD(XonoticPlayerModelSelector, showNotify, void(entity))
   9         ATTRIB(XonoticPlayerModelSelector, currentModel, string, string_null)
  10         ATTRIB(XonoticPlayerModelSelector, currentSkin, float, 0)
  11         ATTRIB(XonoticPlayerModelSelector, currentModelImage, string, string_null)
  12         ATTRIB(XonoticPlayerModelSelector, currentModelTitle, string, string_null)
  13         ATTRIB(XonoticPlayerModelSelector, currentModelDescription, string, string_null)
  14         METHOD(XonoticPlayerModelSelector, go, void(entity, float))
  15         METHOD(XonoticPlayerModelSelector, destroy, void(entity))
  16         ATTRIB(XonoticPlayerModelSelector, origin, vector, '0 0 0')
  17         ATTRIB(XonoticPlayerModelSelector, size, vector, '0 0 0')
  18         ATTRIB(XonoticPlayerModelSelector, realFontSize, vector, '0 0 0')
  19         ATTRIB(XonoticPlayerModelSelector, fontSize, float, SKINFONTSIZE_NORMAL)
  20         ATTRIB(XonoticPlayerModelSelector, titleFontSize, float, SKINFONTSIZE_TITLE)
  21         ATTRIB(XonoticPlayerModelSelector, bufModels, float, -1)
  22         ATTRIB(XonoticPlayerModelSelector, numModels, float, -1)
  23         ATTRIB(XonoticPlayerModelSelector, idxModels, float, -1)
  24 ENDCLASS(XonoticPlayerModelSelector)
  25 entity makeXonoticPlayerModelSelector();
  26 void PlayerModelSelector_Next_Click(entity btn, entity me);
  27 void PlayerModelSelector_Prev_Click(entity btn, entity me);
  28 #endif
  29
  30 #ifdef IMPLEMENTATION
  31 entity makeXonoticPlayerModelSelector()
  32 {
  33         entity me;
  34         me = spawnXonoticPlayerModelSelector();
  35         me.configureXonoticPlayerModelSelector(me);
  36         return me;
  37 }
  38
  39 #define BUFMODELS_TITLE 0
  40 #define BUFMODELS_IMAGE 1
  41 #define BUFMODELS_MODEL 2
  42 #define BUFMODELS_SKIN 3
  43 #define BUFMODELS_DESC 4
  44 #define BUFMODELS_COUNT 5
  45
  46 void XonoticPlayerModelSelector_configureXonoticPlayerModelSelector(entity me)
  47 {
  48         float sortbuf, glob, i;
  49         string fn;
  50
  51         glob = search_begin(language_filename(get_model_datafilename(string_null, -1, "txt")), TRUE, TRUE);
  52         if (glob < 0)
  53                 return;
  54
  55         me.configureXonoticImage(me, string_null, -1);
  56
  57         sortbuf = buf_create();
  58         for(i = 0; i < search_getsize(glob); ++i)
  59         {
  60                 // select model #i!
  61                 fn = search_getfilename(glob, i);
  62                 if(!get_model_parameters(fn, -1))
  63                         continue;
  64                 bufstr_add(sortbuf, sprintf("%-128s%s", get_model_parameters_name, fn), 1);
  65         }
  66         search_end(glob);
  67         buf_sort(sortbuf, 128, 0);
  68         me.numModels = buf_getsize(sortbuf);
  69         me.bufModels = buf_create();
  70         for(i = 0; i < me.numModels; ++i)
  71         {
  72                 fn = substring(bufstr_get(sortbuf, i), 128, -1);
  73                 if(!get_model_parameters(fn, -1))
  74                         error("But it JUST worked!");
  75                 bufstr_set(me.bufModels, BUFMODELS_COUNT*i+BUFMODELS_TITLE, get_model_parameters_name);
  76                 bufstr_set(me.bufModels, BUFMODELS_COUNT*i+BUFMODELS_IMAGE, strcat("/", substring(get_model_datafilename(get_model_parameters_modelname, get_model_parameters_modelskin, "tga"), 0, -5)));
  77                 bufstr_set(me.bufModels, BUFMODELS_COUNT*i+BUFMODELS_MODEL, get_model_parameters_modelname);
  78                 bufstr_set(me.bufModels, BUFMODELS_COUNT*i+BUFMODELS_SKIN, ftos(get_model_parameters_modelskin));
  79                 get_model_parameters_desc = strcat(get_model_parameters_desc, "\n");
  80                 if(get_model_parameters_sex)
  81                         get_model_parameters_desc = strcat(get_model_parameters_desc, sprintf("\nSex: %s", get_model_parameters_sex));
  82                 if(get_model_parameters_weight)
  83                         get_model_parameters_desc = strcat(get_model_parameters_desc, sprintf("\nWeight: %g kg", get_model_parameters_weight));
  84                 if(get_model_parameters_age)
  85                         get_model_parameters_desc = strcat(get_model_parameters_desc, sprintf("\nAge: %g", get_model_parameters_age));
  86                 while(substring(get_model_parameters_desc, -1, 1) == "\n")
  87                         get_model_parameters_desc = substring(get_model_parameters_desc, 0, -2);
  88                 bufstr_set(me.bufModels, BUFMODELS_COUNT*i+BUFMODELS_DESC, get_model_parameters_desc);
  89         }
  90         buf_del(sortbuf);
  91         get_model_parameters(string_null, 0);
  92         me.loadCvars(me); // this will select the initial model, depending on the current cvars
  93         me.go(me, 0); // this will set the vars for the selected model
  94 }
  95 void XonoticPlayerModelSelector_destroy(entity me)
  96 {
  97         buf_del(me.bufModels);
  98         me.bufModels = -1;
  99 }
 100
 101 void XonoticPlayerModelSelector_loadCvars(entity me)
 102 {
 103         string skin, modelname;
 104         float i;
 105
 106         skin = cvar_string("_cl_playerskin");
 107         modelname = cvar_string("_cl_playermodel");
 108
 109         for(i = 0; i < me.numModels; ++i)
 110         {
 111                 if(bufstr_get(me.bufModels, BUFMODELS_COUNT*i+BUFMODELS_MODEL) == modelname)
 112                 if(bufstr_get(me.bufModels, BUFMODELS_COUNT*i+BUFMODELS_SKIN) == skin)
 113                         break;
 114         }
 115         if(i >= me.numModels) // fail
 116                 i = 0;
 117         me.idxModels = i;
 118 }
 119
 120 void XonoticPlayerModelSelector_go(entity me, float d)
 121 {
 122         me.idxModels = mod(me.idxModels + d + me.numModels, me.numModels);
 123
 124         if(me.currentModel)
 125                 strunzone(me.currentModel);
 126         if(me.currentModelTitle)
 127                 strunzone(me.currentModelTitle);
 128         if(me.currentModelImage)
 129                 strunzone(me.currentModelImage);
 130         if(me.currentModelDescription)
 131                 strunzone(me.currentModelDescription);
 132
 133         // select model #i!
 134         me.currentModelTitle = strzone(bufstr_get(me.bufModels, BUFMODELS_COUNT*me.idxModels+BUFMODELS_TITLE));
 135         me.currentModelImage = strzone(bufstr_get(me.bufModels, BUFMODELS_COUNT*me.idxModels+BUFMODELS_IMAGE));
 136         me.currentSkin = stof(bufstr_get(me.bufModels, BUFMODELS_COUNT*me.idxModels+BUFMODELS_SKIN));
 137         me.currentModel = strzone(bufstr_get(me.bufModels, BUFMODELS_COUNT*me.idxModels+BUFMODELS_MODEL));
 138         me.currentModelDescription = strzone(bufstr_get(me.bufModels, BUFMODELS_COUNT*me.idxModels+BUFMODELS_DESC));
 139
 140         // fix the image
 141         if(draw_PictureSize(me.currentModelImage) == '0 0 0')
 142                 me.src = "nopreview_player";
 143         else
 144                 me.src = me.currentModelImage;
 145         me.updateAspect(me);
 146 }
 147
 148 void PlayerModelSelector_Next_Click(entity btn, entity me)
 149 {
 150         if (me.numModels <= 0)
 151                 return;
 152         me.go(me, +1);
 153         me.saveCvars(me);
 154 }
 155
 156 void PlayerModelSelector_Prev_Click(entity btn, entity me)
 157 {
 158         if (me.numModels <= 0)
 159                 return;
 160         me.go(me, -1);
 161         me.saveCvars(me);
 162 }
 163
 164 void XonoticPlayerModelSelector_saveCvars(entity me)
 165 {
 166         // we can't immediately apply here because of flood control
 167         cvar_set("_cl_playermodel", me.currentModel);
 168         cvar_set("_cl_playerskin", ftos(me.currentSkin));
 169 }
 170
 171 void XonoticPlayerModelSelector_draw(entity me)
 172 {
 173         float i, n;
 174         vector o;
 175
 176         if (me.numModels <= 0)
 177         {
 178                 draw_CenterText('0.5 0.5 0', _("<no model found>"), me.realFontSize, SKINCOLOR_TEXT, 0.6, FALSE);
 179                 return;
 180         }
 181
 182         SUPER(XonoticPlayerModelSelector).draw(me);
 183         // draw text on the image, handle \n in the description
 184
 185         draw_beginBoldFont();
 186
 187         draw_CenterText('0.5 0 0', me.currentModelTitle, me.realFontSize * (me.titleFontSize / me.fontSize), SKINCOLOR_MODELTITLE, SKINALPHA_MODELTITLE, FALSE);
 188
 189         draw_endBoldFont();
 190
 191         o = '0.5 1 0' - eY * me.realFontSize_y * ((n = tokenizebyseparator(me.currentModelDescription, "\n")) + 0.5);
 192         for(i = 0; i < n; ++i)
 193         {
 194                 draw_CenterText(o, argv(i), me.realFontSize, SKINCOLOR_TEXT, 1, FALSE);
 195                 o += eY * me.realFontSize_y;
 196         }
 197 }
 198
 199 void XonoticPlayerModelSelector_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 200 {
 201         SUPER(XonoticPlayerModelSelector).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 202         me.realFontSize_y = me.fontSize / absSize_y;
 203         me.realFontSize_x = me.fontSize / absSize_x;
 204 }
 205
 206 void XonoticPlayerModelSelector_showNotify(entity me)
 207 {
 208         me.configureXonoticPlayerModelSelector(me);
 209 }
 210 #endif