qcsrc/menu/xonotic/languagelist.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticLanguageList) EXTENDS(XonoticListBox)
   3         METHOD(XonoticLanguageList, configureXonoticLanguageList, void(entity))
   4         ATTRIB(XonoticLanguageList, rowsPerItem, float, 1)
   5         METHOD(XonoticLanguageList, drawListBoxItem, void(entity, float, vector, float))
   6         METHOD(XonoticLanguageList, resizeNotify, void(entity, vector, vector, vector, vector))
   7         METHOD(XonoticLanguageList, setSelected, void(entity, float))
   8         METHOD(XonoticLanguageList, loadCvars, void(entity))
   9         METHOD(XonoticLanguageList, saveCvars, void(entity))
  10
  11         ATTRIB(XonoticLanguageList, realFontSize, vector, '0 0 0')
  12         ATTRIB(XonoticLanguageList, realUpperMargin, float, 0)
  13         ATTRIB(XonoticLanguageList, columnNameOrigin, float, 0)
  14         ATTRIB(XonoticLanguageList, columnNameSize, float, 0)
  15         ATTRIB(XonoticLanguageList, columnPercentageOrigin, float, 0)
  16         ATTRIB(XonoticLanguageList, columnPercentageSize, float, 0)
  17
  18         METHOD(XonoticLanguageList, clickListBoxItem, void(entity, float, vector)) // double click handling
  19         METHOD(XonoticLanguageList, keyDown, float(entity, float, float, float)) // enter handling
  20         ATTRIB(XonoticLanguageList, lastClickedLanguage, float, -1)
  21         ATTRIB(XonoticLanguageList, lastClickedTime, float, 0)
  22
  23         METHOD(XonoticLanguageList, destroy, void(entity))
  24
  25         ATTRIB(XonoticLanguageList, languagelist, float, -1)
  26         METHOD(XonoticLanguageList, getLanguages, void(entity))
  27         METHOD(XonoticLanguageList, setLanguage, void(entity))
  28         METHOD(XonoticLanguageList, languageParameter, string(entity, float, float))
  29
  30         ATTRIB(XonoticLanguageList, name, string, "languageselector") // change this to make it noninteractive (for first run dialog)
  31 ENDCLASS(XonoticLanguageList)
  32
  33 entity makeXonoticLanguageList();
  34 void SetLanguage_Click(entity btn, entity me);
  35 #endif
  36
  37 #ifdef IMPLEMENTATION
  38
  39 #define LANGPARM_ID 0
  40 #define LANGPARM_NAME 1
  41 #define LANGPARM_NAME_LOCALIZED 2
  42 #define LANGPARM_PERCENTAGE 3
  43 #define LANGPARM_COUNT 4
  44
  45 entity makeXonoticLanguageList()
  46 {
  47         entity me;
  48         me = spawnXonoticLanguageList();
  49         me.configureXonoticLanguageList(me);
  50         return me;
  51 }
  52
  53 void XonoticLanguageList_configureXonoticLanguageList(entity me)
  54 {
  55         me.configureXonoticListBox(me);
  56         me.getLanguages(me);
  57         me.loadCvars(me);
  58 }
  59
  60 void XonoticLanguageList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
  61 {
  62         string s, p;
  63         if(isSelected)
  64                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
  65
  66         s = me.languageParameter(me, i, LANGPARM_NAME_LOCALIZED);
  67         s = draw_TextShortenToWidth(s, me.columnNameSize, 0, me.realFontSize);
  68         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
  69
  70         p = me.languageParameter(me, i, LANGPARM_PERCENTAGE);
  71         if(p != "")
  72         {
  73                 p = draw_TextShortenToWidth(p, me.columnPercentageSize, 0, me.realFontSize);
  74                 draw_Text(me.realUpperMargin * eY + (me.columnPercentageOrigin + (me.columnPercentageSize - draw_TextWidth(p, 0, me.realFontSize))) * eX, p, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
  75         }
  76 }
  77
  78 void XonoticLanguageList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  79 {
  80         SUPER(XonoticLanguageList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  81         me.realFontSize_y = me.fontSize / (absSize_y * me.itemHeight);
  82         me.realFontSize_x = me.fontSize / (absSize_x * (1 - me.controlWidth));
  83         me.realUpperMargin = 0.5 * (1 - me.realFontSize_y);
  84         me.columnPercentageSize = me.realFontSize_x * 3;
  85         me.columnPercentageOrigin = 1 - me.columnPercentageSize;
  86         me.columnNameOrigin = 0;
  87         me.columnNameSize = me.columnPercentageOrigin;
  88 }
  89
  90 void XonoticLanguageList_setSelected(entity me, float i)
  91 {
  92         SUPER(XonoticLanguageList).setSelected(me, i);
  93         me.saveCvars(me);
  94 }
  95
  96 void XonoticLanguageList_loadCvars(entity me)
  97 {
  98         string s;
  99         float i, n;
 100         s = cvar_string("_menu_prvm_language");
 101         n = me.nItems;
 102
 103         // default to English
 104         for(i = 0; i < n; ++i)
 105         {
 106                 if(me.languageParameter(me, i, LANGPARM_ID) == "en")
 107                 {
 108                         me.selectedItem = i;
 109                         break;
 110                 }
 111         }
 112
 113         // otherwise, find the language
 114         for(i = 0; i < n; ++i)
 115         {
 116                 if(me.languageParameter(me, i, LANGPARM_ID) == s)
 117                 {
 118                         me.selectedItem = i;
 119                         break;
 120                 }
 121         }
 122
 123         // save it off (turning anything unknown into "en")
 124         me.saveCvars(me);
 125 }
 126
 127 void XonoticLanguageList_saveCvars(entity me)
 128 {
 129         cvar_set("_menu_prvm_language", me.languageParameter(me, me.selectedItem, LANGPARM_ID));
 130 }
 131
 132 void XonoticLanguageList_clickListBoxItem(entity me, float i, vector where)
 133 {
 134         if(i == me.lastClickedLanguage)
 135                 if(time < me.lastClickedTime + 0.3)
 136                 {
 137                         // DOUBLE CLICK!
 138                         me.setSelected(me, i);
 139                         me.setLanguage(me);
 140                 }
 141         me.lastClickedLanguage = i;
 142         me.lastClickedTime = time;
 143 }
 144
 145 float XonoticLanguageList_keyDown(entity me, float scan, float ascii, float shift)
 146 {
 147         if(scan == K_ENTER || scan == K_KP_ENTER) {
 148                 me.setLanguage(me);
 149                 return 1;
 150         }
 151         else
 152                 return SUPER(XonoticLanguageList).keyDown(me, scan, ascii, shift);
 153 }
 154
 155 void XonoticLanguageList_destroy(entity me)
 156 {
 157         buf_del(me.languagelist);
 158 }
 159
 160 void XonoticLanguageList_getLanguages(entity me)
 161 {
 162         float buf, i, n, fh;
 163         string s;
 164
 165         buf = buf_create();
 166
 167         fh = fopen("languages.txt", FILE_READ);
 168         i = 0;
 169         while((s = fgets(fh)))
 170         {
 171                 n = tokenize_console(s);
 172                 if(n < 3)
 173                         continue;
 174                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_ID, argv(0));
 175                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_NAME, argv(1));
 176                 float k = strstrofs(argv(2), "(", 0);
 177                 if(k > 0)
 178                 if(substring(argv(2), strlen(argv(2)) - 1, 1) == ")")
 179                 {
 180                         string percent = substring(argv(2), k + 1, -2);
 181                         if(percent != "100%")
 182                                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_PERCENTAGE, percent);
 183                 }
 184                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_NAME_LOCALIZED, (k < 0) ? argv(2) : substring(argv(2), 0, k - 1));
 185                 ++i;
 186         }
 187         fclose(fh);
 188
 189         me.languagelist = buf;
 190         me.nItems = i;
 191 }
 192
 193 void XonoticLanguageList_setLanguage(entity me)
 194 {
 195         if(prvm_language != cvar_string("_menu_prvm_language"))
 196         {
 197                 if(!(gamestatus & GAME_CONNECTED))
 198                         localcmd("\nprvm_language \"$_menu_prvm_language\"; menu_restart; menu_cmd languageselect\n");
 199                 else
 200                         DialogOpenButton_Click(me, main.languageWarningDialog);
 201         }
 202 }
 203
 204 string XonoticLanguageList_languageParameter(entity me, float i, float key)
 205 {
 206         return bufstr_get(me.languagelist, i * LANGPARM_COUNT + key);
 207 }
 208
 209 void SetLanguage_Click(entity btn, entity me)
 210 {
 211         me.setLanguage(me);
 212 }
 213
 214 #endif