qcsrc/menu/item/slider.qc

   1 // Note:
   2 //   to use this, you FIRST call configureSliderVisuals, then configureSliderValues
   3 #ifndef ITEM_SLIDER_H
   4 #define ITEM_SLIDER_H
   5 #include "label.qc"
   6 CLASS(Slider, Label)
   7         METHOD(Slider, resizeNotify, void(entity, vector, vector, vector, vector));
   8         METHOD(Slider, configureSliderVisuals, void(entity, float, float, float, string));
   9         METHOD(Slider, configureSliderValues, void(entity, float, float, float, float, float, float));
  10         METHOD(Slider, draw, void(entity));
  11         METHOD(Slider, keyDown, float(entity, float, float, float));
  12         METHOD(Slider, keyUp, float(entity, float, float, float));
  13         METHOD(Slider, mousePress, float(entity, vector));
  14         METHOD(Slider, mouseDrag, float(entity, vector));
  15         METHOD(Slider, mouseRelease, float(entity, vector));
  16         METHOD(Slider, valueToText, string(entity, float));
  17         METHOD(Slider, toString, string(entity));
  18         METHOD(Slider, setValue_allowAnim, void(entity, float, bool));
  19         METHOD(Slider, setValue_noAnim, void(entity, float));
  20         METHOD(Slider, setValue, void(entity, float));
  21         METHOD(Slider, setSliderValue, void(entity, float));
  22         METHOD(Slider, showNotify, void(entity));
  23         ATTRIB(Slider, src, string, string_null)
  24         ATTRIB(Slider, focusable, float, 1)
  25         ATTRIB(Slider, allowFocusSound, float, 1)
  26         ATTRIB(Slider, value, float, 0)
  27         ATTRIB(Slider, animated, float, 1)
  28         ATTRIB(Slider, sliderValue, float, 0)
  29         ATTRIB(Slider, sliderAnim, entity, world)
  30         ATTRIB(Slider, valueMin, float, 0)
  31         ATTRIB(Slider, valueMax, float, 0)
  32         ATTRIB(Slider, valueStep, float, 0)
  33         ATTRIB(Slider, valueDigits, float, 0)
  34         ATTRIB(Slider, valueKeyStep, float, 0)
  35         ATTRIB(Slider, valuePageStep, float, 0)
  36         ATTRIB(Slider, valueDisplayMultiplier, float, 1.0)
  37         ATTRIB(Slider, textSpace, float, 0)
  38         ATTRIB(Slider, controlWidth, float, 0)
  39         ATTRIB(Slider, pressed, float, 0)
  40         ATTRIB(Slider, pressOffset, float, 0)
  41         ATTRIB(Slider, previousValue, float, 0)
  42         ATTRIB(Slider, tolerance, vector, '0 0 0')
  43         ATTRIB(Slider, disabled, float, 0)
  44         ATTRIB(Slider, color, vector, '1 1 1')
  45         ATTRIB(Slider, color2, vector, '1 1 1')
  46         ATTRIB(Slider, colorD, vector, '1 1 1')
  47         ATTRIB(Slider, colorC, vector, '1 1 1')
  48         ATTRIB(Slider, colorF, vector, '1 1 1')
  49         ATTRIB(Slider, disabledAlpha, float, 0.3)
  50 ENDCLASS(Slider)
  51 #endif
  52
  53 #ifdef IMPLEMENTATION
  54 void Slider_setValue_allowAnim(entity me, float val, bool allowAnim)
  55 {
  56         if(allowAnim && me.animated) {
  57                 float t = 0.5;
  58                 if(me.pressed == 2)
  59                         t = 0.3; // slightly more responsive while dragging the handle
  60                 if(!me.sliderAnim)
  61                         me.sliderAnim = makeHostedEasing(me, Slider_setSliderValue, easingQuadOut, t, me.sliderValue, val);
  62                 else
  63                         me.sliderAnim.update(me.sliderAnim, t, me.sliderValue, val);
  64         } else {
  65                 me.setSliderValue(me, val);
  66         }
  67         me.value = val;
  68 }
  69 void Slider_setValue_noAnim(entity me, float val)
  70 {
  71         Slider_setValue_allowAnim(me, val, false);
  72 }
  73 void Slider_setValue(entity me, float val)
  74 {
  75         Slider_setValue_allowAnim(me, val, true);
  76 }
  77 void Slider_setSliderValue(entity me, float val)
  78 {
  79         me.sliderValue = val;
  80 }
  81 string Slider_toString(entity me)
  82 {
  83         return sprintf("%d (%s)", me.value, me.valueToText(me, me.value));
  84 }
  85 void Slider_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  86 {
  87         SUPER(Slider).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  88         me.controlWidth = absSize.y / absSize.x;
  89 }
  90 string Slider_valueToText(entity me, float val)
  91 {
  92         if(almost_in_bounds(me.valueMin, val, me.valueMax))
  93                 return ftos_decimals(val * me.valueDisplayMultiplier, me.valueDigits);
  94         return "";
  95 }
  96 void Slider_configureSliderVisuals(entity me, float sz, float theAlign, float theTextSpace, string gfx)
  97 {
  98         SUPER(Slider).configureLabel(me, string_null, sz, theAlign);
  99         me.textSpace = theTextSpace;
 100         me.keepspaceLeft = (theTextSpace == 0) ? 0 : (1 - theTextSpace);
 101         me.src = gfx;
 102 }
 103 void Slider_configureSliderValues(entity me, float theValueMin, float theValue, float theValueMax, float theValueStep, float theValueKeyStep, float theValuePageStep)
 104 {
 105         me.value = theValue;
 106         me.sliderValue = theValue;
 107         me.valueStep = theValueStep;
 108         me.valueMin = theValueMin;
 109         me.valueMax = theValueMax;
 110         me.valueKeyStep = theValueKeyStep;
 111         me.valuePageStep = theValuePageStep;
 112         me.valueDigits = 3;
 113         if(fabs(floor(me.valueStep * 100 + 0.5) - (me.valueStep * 100)) < 0.01) // about a whole number of 100ths
 114                 me.valueDigits = 2;
 115         if(fabs(floor(me.valueStep * 10 + 0.5) - (me.valueStep * 10)) < 0.01) // about a whole number of 10ths
 116                 me.valueDigits = 1;
 117         if(fabs(floor(me.valueStep * 1 + 0.5) - (me.valueStep * 1)) < 0.01) // about a whole number
 118                 me.valueDigits = 0;
 119 }
 120 float Slider_keyDown(entity me, float key, float ascii, float shift)
 121 {
 122         float inRange;
 123         if(me.disabled)
 124                 return 0;
 125         inRange = (almost_in_bounds(me.valueMin, me.value, me.valueMax));
 126         if(key == K_LEFTARROW || key == K_KP_LEFTARROW || key == K_MWHEELDOWN)
 127         {
 128                 if(inRange)
 129                         me.setValue(me, median(me.valueMin, me.value - me.valueKeyStep, me.valueMax));
 130                 else
 131                         me.setValue(me, me.valueMax);
 132                 return 1;
 133         }
 134         if(key == K_RIGHTARROW || key == K_KP_RIGHTARROW || key == K_MWHEELUP)
 135         {
 136                 if(inRange)
 137                         me.setValue(me, median(me.valueMin, me.value + me.valueKeyStep, me.valueMax));
 138                 else
 139                         me.setValue(me, me.valueMin);
 140                 return 1;
 141         }
 142         if(key == K_PGDN || key == K_KP_PGDN)
 143         {
 144                 if(inRange)
 145                         me.setValue(me, median(me.valueMin, me.value - me.valuePageStep, me.valueMax));
 146                 else
 147                         me.setValue(me, me.valueMax);
 148                 return 1;
 149         }
 150         if(key == K_PGUP || key == K_KP_PGUP)
 151         {
 152                 if(inRange)
 153                         me.setValue(me, median(me.valueMin, me.value + me.valuePageStep, me.valueMax));
 154                 else
 155                         me.setValue(me, me.valueMin);
 156                 return 1;
 157         }
 158         if(key == K_HOME || key == K_KP_HOME)
 159         {
 160                 me.setValue(me, me.valueMin);
 161                 return 1;
 162         }
 163         if(key == K_END || key == K_KP_END)
 164         {
 165                 me.setValue(me, me.valueMax);
 166                 return 1;
 167         }
 168         // TODO more keys (NOTE also add them to Slider_keyUp)
 169         return 0;
 170 }
 171 float Slider_keyUp(entity me, float key, float ascii, float shift)
 172 {
 173         if(me.disabled)
 174                 return 0;
 175         switch(key)
 176         {
 177                 case K_LEFTARROW:
 178                 case K_KP_LEFTARROW:
 179                 case K_RIGHTARROW:
 180                 case K_KP_RIGHTARROW:
 181                 case K_PGUP:
 182                 case K_KP_PGUP:
 183                 case K_PGDN:
 184                 case K_KP_PGDN:
 185                 case K_HOME:
 186                 case K_KP_HOME:
 187                 case K_END:
 188                 case K_KP_END:
 189                         m_play_click_sound(MENU_SOUND_SLIDE);
 190         }
 191         return 0;
 192 }
 193 float Slider_mouseDrag(entity me, vector pos)
 194 {
 195         float hit;
 196         float v;
 197         if(me.disabled)
 198                 return 0;
 199
 200         if(me.pressed)
 201         {
 202                 hit = 1;
 203                 if(pos.x < 0 - me.tolerance.x) hit = 0;
 204                 if(pos.y < 0 - me.tolerance.y) hit = 0;
 205                 if(pos.x >= 1 - me.textSpace + me.tolerance.x) hit = 0;
 206                 if(pos.y >= 1 + me.tolerance.y) hit = 0;
 207                 if(hit)
 208                 {
 209                         // handle dragging
 210                         me.pressed = 2;
 211
 212                         v = median(0, (pos.x - me.pressOffset - 0.5 * me.controlWidth) / (1 - me.textSpace - me.controlWidth), 1) * (me.valueMax - me.valueMin) + me.valueMin;
 213                         if(me.valueStep)
 214                                 v = floor(0.5 + v / me.valueStep) * me.valueStep;
 215                         me.setValue(me, v);
 216                 }
 217                 else
 218                         me.setValue(me, me.previousValue);
 219         }
 220
 221         return 1;
 222 }
 223 float Slider_mousePress(entity me, vector pos)
 224 {
 225         float controlCenter;
 226         if(me.disabled)
 227                 return 0;
 228         if(pos.x < 0) return 0;
 229         if(pos.y < 0) return 0;
 230         if(pos.x >= 1 - me.textSpace) return 0;
 231         if(pos.y >= 1) return 0;
 232         controlCenter = (me.value - me.valueMin) / (me.valueMax - me.valueMin) * (1 - me.textSpace - me.controlWidth) + 0.5 * me.controlWidth;
 233         if(fabs(pos.x - controlCenter) <= 0.5 * me.controlWidth)
 234         {
 235                 me.pressed = 1;
 236                 me.pressOffset = pos.x - controlCenter;
 237                 me.previousValue = me.value;
 238                 //me.mouseDrag(me, pos);
 239         }
 240         else
 241         {
 242                 float clickValue, pageValue, inRange;
 243                 clickValue = median(0, (pos.x - me.pressOffset - 0.5 * me.controlWidth) / (1 - me.textSpace - me.controlWidth), 1) * (me.valueMax - me.valueMin) + me.valueMin;
 244                 inRange = (almost_in_bounds(me.valueMin, me.value, me.valueMax));
 245                 if(pos.x < controlCenter)
 246                 {
 247                         pageValue = me.value - me.valuePageStep;
 248                         if(me.valueStep)
 249                                 clickValue = floor(clickValue / me.valueStep) * me.valueStep;
 250                         pageValue = max(pageValue, clickValue);
 251                         if(inRange)
 252                                 me.setValue(me, median(me.valueMin, pageValue, me.valueMax));
 253                         else
 254                                 me.setValue(me, me.valueMax);
 255                 }
 256                 else
 257                 {
 258                         pageValue = me.value + me.valuePageStep;
 259                         if(me.valueStep)
 260                                 clickValue = ceil(clickValue / me.valueStep) * me.valueStep;
 261                         pageValue = min(pageValue, clickValue);
 262                         if(inRange)
 263                                 me.setValue(me, median(me.valueMin, pageValue, me.valueMax));
 264                         else
 265                                 me.setValue(me, me.valueMax);
 266                 }
 267                 if(pageValue == clickValue)
 268                 {
 269                         controlCenter = (me.value - me.valueMin) / (me.valueMax - me.valueMin) * (1 - me.textSpace - me.controlWidth) + 0.5 * me.controlWidth;
 270                         me.pressed = 1;
 271                         me.pressOffset = pos.x - controlCenter;
 272                         me.previousValue = me.value;
 273                         //me.mouseDrag(me, pos);
 274                 }
 275         }
 276         return 1;
 277 }
 278 float Slider_mouseRelease(entity me, vector pos)
 279 {
 280         me.pressed = 0;
 281         if(me.disabled)
 282                 return 0;
 283         m_play_click_sound(MENU_SOUND_SLIDE);
 284         return 1;
 285 }
 286 void Slider_showNotify(entity me)
 287 {
 288         me.focusable = !me.disabled;
 289 }
 290 void Slider_draw(entity me)
 291 {
 292         float controlLeft;
 293         float save;
 294         me.focusable = !me.disabled;
 295         save = draw_alpha;
 296         if(me.disabled)
 297                 draw_alpha *= me.disabledAlpha;
 298         draw_ButtonPicture('0 0 0', strcat(me.src, "_s"), eX * (1 - me.textSpace) + eY, me.color2, 1);
 299         if(almost_in_bounds(me.valueMin, me.sliderValue, me.valueMax))
 300         {
 301                 controlLeft = (me.sliderValue - me.valueMin) / (me.valueMax - me.valueMin) * (1 - me.textSpace - me.controlWidth);
 302                 if(me.disabled)
 303                         draw_Picture(eX * controlLeft, strcat(me.src, "_d"), eX * me.controlWidth + eY, me.colorD, 1);
 304                 else if(me.pressed)
 305                         draw_Picture(eX * controlLeft, strcat(me.src, "_c"), eX * me.controlWidth + eY, me.colorC, 1);
 306                 else if(me.focused)
 307                         draw_Picture(eX * controlLeft, strcat(me.src, "_f"), eX * me.controlWidth + eY, me.colorF, 1);
 308                 else
 309                         draw_Picture(eX * controlLeft, strcat(me.src, "_n"), eX * me.controlWidth + eY, me.color, 1);
 310         }
 311
 312         if(me.sliderAnim)
 313         if(me.sliderAnim.isFinished(me.sliderAnim))
 314         {
 315                 anim.removeObjAnim(anim, me);
 316                 me.sliderAnim = world;
 317         }
 318
 319         me.setText(me, me.valueToText(me, me.value));
 320         draw_alpha = save;
 321         SUPER(Slider).draw(me);
 322         me.text = string_null; // TEMPSTRING!
 323 }
 324 #endif