qcsrc/lib/warpzone/common.qc

   1 #include "common.qh"
   2
   3 #if defined(CSQC)
   4     #include <client/items/items.qh>
   5 #elif defined(MENUQC)
   6 #elif defined(SVQC)
   7     #include <common/weapons/_all.qh>
   8 #endif
   9
  10 void WarpZone_Accumulator_Clear(entity acc)
  11 {
  12         acc.warpzone_transform = '0 0 0';
  13         acc.warpzone_shift = '0 0 0';
  14 }
  15 void WarpZone_Accumulator_AddTransform(entity acc, vector t, vector s)
  16 {
  17         vector tr, st;
  18         tr = AnglesTransform_Multiply(t, acc.warpzone_transform);
  19         st = AnglesTransform_Multiply_GetPostShift(t, s, acc.warpzone_transform, acc.warpzone_shift);
  20         acc.warpzone_transform = tr;
  21         acc.warpzone_shift = st;
  22 }
  23 void WarpZone_Accumulator_Add(entity acc, entity wz)
  24 {
  25         WarpZone_Accumulator_AddTransform(acc, wz.warpzone_transform, wz.warpzone_shift);
  26 }
  27 void WarpZone_Accumulator_AddInverseTransform(entity acc, vector t, vector s)
  28 {
  29         vector tt, ss;
  30         tt = AnglesTransform_Invert(t);
  31         ss = AnglesTransform_PrePostShift_GetPostShift(s, tt, '0 0 0');
  32         WarpZone_Accumulator_AddTransform(acc, tt, ss);
  33         // yes, this probably can be done simpler... but this way is "obvious" :)
  34 }
  35 void WarpZone_Accumulator_AddInverse(entity acc, entity wz)
  36 {
  37         WarpZone_Accumulator_AddInverseTransform(acc, wz.warpzone_transform, wz.warpzone_shift);
  38 }
  39
  40 float autocvar_cl_warpzone_usetrace = 1;
  41 vector WarpZone_camera_transform(entity this, vector org, vector ang)
  42 {
  43         vector vf, vr, vu;
  44         if(this.warpzone_fadestart)
  45                 if(vdist(org - this.origin - 0.5 * (this.mins + this.maxs), >, this.warpzone_fadeend + 400))
  46                         return org;
  47                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
  48                         // unneeded on client, on server this helps a lot
  49         vf = v_forward;
  50         vr = v_right;
  51         vu = v_up;
  52         org = WarpZone_TransformOrigin(this, org);
  53         vf = WarpZone_TransformVelocity(this, vf);
  54         vr = WarpZone_TransformVelocity(this, vr);
  55         vu = WarpZone_TransformVelocity(this, vu);
  56         if(autocvar_cl_warpzone_usetrace)
  57                 traceline(this.warpzone_targetorigin, org, MOVE_NOMONSTERS, NULL);
  58         else
  59                 trace_endpos = this.warpzone_targetorigin;
  60         v_forward = vf;
  61         v_right = vr;
  62         v_up = vu;
  63         return org;
  64 }
  65
  66 void WarpZone_SetUp(entity e, vector my_org, vector my_ang, vector other_org, vector other_ang)
  67 {
  68         e.warpzone_transform = AnglesTransform_RightDivide(other_ang, AnglesTransform_TurnDirectionFR(my_ang));
  69         e.warpzone_shift = AnglesTransform_PrePostShift_GetPostShift(my_org, e.warpzone_transform, other_org);
  70         e.warpzone_origin = my_org;
  71         e.warpzone_targetorigin = other_org;
  72         e.warpzone_angles = my_ang;
  73         e.warpzone_targetangles = other_ang;
  74         vector forward, right, up;
  75         FIXED_MAKE_VECTORS(my_ang, forward, right, up);
  76         e.warpzone_forward = forward;
  77         FIXED_MAKE_VECTORS(other_ang, forward, right, up);
  78         e.warpzone_targetforward = forward;
  79         setcamera_transform(e, WarpZone_camera_transform);
  80 }
  81
  82 vector WarpZone_Camera_camera_transform(entity this, vector org, vector ang)
  83 {
  84         // a fixed camera view
  85         if(this.warpzone_fadestart)
  86                 if(vdist(org - this.origin - 0.5 * (this.mins + this.maxs), >, this.warpzone_fadeend + 400))
  87                         return org;
  88                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
  89                         // unneeded on client, on server this helps a lot
  90         trace_endpos = this.warpzone_origin;
  91         makevectors(this.warpzone_angles);
  92         return this.warpzone_origin;
  93 }
  94
  95 void WarpZone_Camera_SetUp(entity e, vector my_org, vector my_ang) // we assume that e.oldorigin and e.avelocity point to view origin and direction
  96 {
  97         e.warpzone_origin = my_org;
  98         e.warpzone_angles = my_ang;
  99         setcamera_transform(e, WarpZone_Camera_camera_transform);
 100 }
 101
 102 .entity enemy;
 103
 104 float WarpZoneLib_BoxTouchesBrush_Recurse(vector mi, vector ma, entity e, entity ig)
 105 {
 106         float f, s;
 107         entity se;
 108
 109         tracebox('0 0 0', mi, ma, '0 0 0', MOVE_NOMONSTERS, ig);
 110 #ifdef CSQC
 111         if (trace_networkentity)
 112         {
 113                 LOG_TRACE("hit a network ent, cannot continue WarpZoneLib_BoxTouchesBrush");
 114                 // we cannot continue, as a player blocks us...
 115                 // so, abort
 116                 return 0;
 117         }
 118 #endif
 119         if (!trace_ent)
 120                 return 0;
 121         if (trace_ent == e)
 122                 return 1;
 123
 124         se = trace_ent;
 125         s = se.solid;
 126         se.solid = SOLID_NOT;
 127         setorigin(se, se.origin); // unlink
 128         f = WarpZoneLib_BoxTouchesBrush_Recurse(mi, ma, e, ig);
 129         se.solid = s;
 130         setorigin(se, se.origin); // relink
 131
 132         return f;
 133 }
 134
 135 float WarpZoneLib_BoxTouchesBrush(vector mi, vector ma, entity e, entity ig)
 136 {
 137         // bones_was_here: TODO: when findbox() builtin is available, use it to
 138         // optimise this into a single non-recursive function that only calls tracebox once
 139
 140         float f, s;
 141
 142         if(!e.modelindex || e.warpzone_isboxy)
 143                 return 1;
 144
 145         // work around trigger_hurt on geit3ctf1 not being detected by tracebox
 146         // bones_was_here: FIXME: WHY do these triggers only have supercontents == 128 ?!
 147         if (Q3COMPAT_COMMON && ig != world)
 148                 ig.dphitcontentsmask |= 128;
 149
 150         s = e.solid;
 151         if (e.solid != SOLID_BSP)
 152         {
 153                 e.solid = SOLID_BSP;
 154                 setorigin(e, e.origin); // update linking
 155         }
 156         f = WarpZoneLib_BoxTouchesBrush_Recurse(mi, ma, e, ig);
 157         if (e.solid != s) // if we needed to change .solid temporarily
 158         {
 159                 e.solid = s; // restore it
 160                 setorigin(e, e.origin); // update linking
 161         }
 162
 163         if (Q3COMPAT_COMMON && ig != world)
 164                 ig.dphitcontentsmask &= ~128;
 165
 166         return f;
 167 }
 168
 169 entity WarpZone_Find(vector mi, vector ma)
 170 {
 171         // if we are near any warpzone planes - MOVE AWAY (work around nearclip)
 172         if(!warpzone_warpzones_exist)
 173                 return NULL;
 174         IL_EACH(g_warpzones, WarpZoneLib_BoxTouchesBrush(mi, ma, it, NULL),
 175         {
 176                 return it;
 177         });
 178         return NULL;
 179 }
 180
 181 void WarpZone_MakeAllSolid()
 182 {
 183         if(!warpzone_warpzones_exist)
 184                 return;
 185         IL_EACH(g_warpzones, true,
 186         {
 187                 it.solid = SOLID_BSP;
 188         });
 189 }
 190
 191 void WarpZone_MakeAllOther()
 192 {
 193         if(!warpzone_warpzones_exist)
 194                 return;
 195         IL_EACH(g_warpzones, true,
 196         {
 197                 it.solid = SOLID_TRIGGER;
 198         });
 199 }
 200
 201 void WarpZone_Trace_InitTransform()
 202 {
 203         if(!WarpZone_trace_transform)
 204         {
 205                 WarpZone_trace_transform = new_pure(warpzone_trace_transform);
 206         }
 207         WarpZone_Accumulator_Clear(WarpZone_trace_transform);
 208 }
 209 void WarpZone_Trace_AddTransform(entity wz)
 210 {
 211         WarpZone_Accumulator_Add(WarpZone_trace_transform, wz);
 212 }
 213
 214 void WarpZone_TraceBox_ThroughZone(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent, entity zone, WarpZone_trace_callback_t cb)
 215 {
 216         float nomonsters_adjusted;
 217         float frac, sol, i;
 218         float contentshack;
 219         entity wz;
 220         vector vf, vr, vu;
 221
 222         WarpZone_trace_forent = forent;
 223         WarpZone_trace_firstzone = NULL;
 224         WarpZone_trace_lastzone = NULL;
 225         WarpZone_Trace_InitTransform();
 226         if(!warpzone_warpzones_exist)
 227         {
 228                 if(nomonsters == MOVE_NOTHING)
 229                 {
 230                         trace_endpos = end;
 231                         trace_fraction = 1;
 232                         if(cb)
 233                                 cb(org, trace_endpos, end);
 234                         return;
 235                 }
 236                 else
 237                 {
 238                         tracebox(org, mi, ma, end, nomonsters, WarpZone_trace_forent);
 239                         if(cb)
 240                                 cb(org, trace_endpos, end);
 241                         return;
 242                 }
 243         }
 244
 245         vf = v_forward;
 246         vr = v_right;
 247         vu = v_up;
 248
 249         switch(nomonsters)
 250         {
 251                 case MOVE_WORLDONLY:
 252                 case MOVE_NOTHING:
 253                         nomonsters_adjusted = MOVE_NOMONSTERS;
 254                         break;
 255                 default:
 256                         nomonsters_adjusted = nomonsters;
 257                         break;
 258         }
 259         if((contentshack = (WarpZone_trace_forent.dphitcontentsmask && !(WarpZone_trace_forent.dphitcontentsmask & DPCONTENTS_SOLID))))
 260                 BITSET_ASSIGN(WarpZone_trace_forent.dphitcontentsmask, DPCONTENTS_SOLID);
 261
 262         // if starting in warpzone, first transform
 263         wz = WarpZone_Find(org + mi, org + ma);
 264         if(wz)
 265         {
 266                 WarpZone_trace_firstzone = wz;
 267                 WarpZone_trace_lastzone = wz;
 268                 if(zone && wz != zone)
 269                 {
 270                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 271                         sol = 1;
 272                         trace_fraction = 0;
 273                         trace_endpos = org;
 274                         goto fail;
 275                 }
 276                 WarpZone_Trace_AddTransform(wz);
 277                 org = WarpZone_TransformOrigin(wz, org);
 278                 end = WarpZone_TransformOrigin(wz, end);
 279         }
 280         WarpZone_MakeAllSolid();
 281         sol = -1;
 282         frac = 0;
 283         i = 16;
 284         for (;;)
 285         {
 286                 if(--i < 1)
 287                 {
 288                         LOG_TRACE("Too many warpzones in sequence, aborting trace.");
 289                         trace_ent = NULL;
 290                         break;
 291                 }
 292                 tracebox(org, mi, ma, end, nomonsters_adjusted, WarpZone_trace_forent);
 293                 if(cb)
 294                         cb(org, trace_endpos, end);
 295                 if(sol < 0)
 296                         sol = trace_startsolid;
 297
 298                 frac = trace_fraction = frac + (1 - frac) * trace_fraction;
 299                 if(trace_fraction >= 1)
 300                         break;
 301                 if(trace_ent.classname != "trigger_warpzone")
 302                 {
 303                         if((nomonsters == MOVE_NOTHING) || ((nomonsters == MOVE_WORLDONLY) && trace_ent) || (contentshack && (trace_dphitcontents & WarpZone_trace_forent.dphitcontentsmask) == DPCONTENTS_SOLID))
 304                         {
 305                                 // continue the trace, ignoring this hit (we only care for warpzones)
 306                                 org = trace_endpos + normalize(end - org);
 307                                 continue;
 308                                 // we cannot do an inverted trace here, as we do care for further warpzones inside that "solid" to be found
 309                                 // otherwise, players could block entrances that way
 310                         }
 311                         break;
 312                 }
 313                 /*if(trace_ent == wz)
 314                 {
 315                         // FIXME can this check be removed? Do we really need it?
 316                         LOG_TRACE("I transformed into the same zone again, wtf, aborting the trace");
 317                         trace_ent = NULL;
 318                         break;
 319                 }*/
 320                 wz = trace_ent;
 321                 if(!WarpZone_trace_firstzone)
 322                         WarpZone_trace_firstzone = wz;
 323                 WarpZone_trace_lastzone = wz;
 324                 if(zone && wz != zone)
 325                         break;
 326                 WarpZone_Trace_AddTransform(wz);
 327                 // we hit a warpzone... so, let's perform the trace after the warp again
 328                 org = WarpZone_TransformOrigin(wz, trace_endpos);
 329                 end = WarpZone_TransformOrigin(wz, end);
 330
 331                 // we got warped, so let's step back a bit
 332                 tracebox(org, mi, ma, org + normalize(org - end) * 32, nomonsters_adjusted, WarpZone_trace_forent);
 333                 org = trace_endpos;
 334         }
 335         WarpZone_MakeAllOther();
 336 LABEL(fail)
 337         if(contentshack)
 338                 BITCLR_ASSIGN(WarpZone_trace_forent.dphitcontentsmask, DPCONTENTS_SOLID);
 339         trace_startsolid = sol;
 340         v_forward = vf;
 341         v_right = vr;
 342         v_up = vu;
 343 }
 344
 345 void WarpZone_TraceBox(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent)
 346 {
 347         WarpZone_TraceBox_ThroughZone(org, mi, ma, end, nomonsters, forent, NULL, WarpZone_trace_callback_t_null);
 348 }
 349
 350 void WarpZone_TraceLine(vector org, vector end, float nomonsters, entity forent)
 351 {
 352         WarpZone_TraceBox(org, '0 0 0', '0 0 0', end, nomonsters, forent);
 353 }
 354
 355 void WarpZone_TraceToss_ThroughZone(entity e, entity forent, entity zone, WarpZone_trace_callback_t cb)
 356 {
 357         float g, dt, i;
 358         vector vf, vr, vu, v0, o0;
 359         entity wz;
 360
 361         o0 = e.origin;
 362         v0 = e.velocity;
 363         g = cvar("sv_gravity") * e.gravity;
 364
 365         WarpZone_trace_forent = forent;
 366         WarpZone_trace_firstzone = NULL;
 367         WarpZone_trace_lastzone = NULL;
 368         WarpZone_Trace_InitTransform();
 369         WarpZone_tracetoss_time = 0;
 370         if(!warpzone_warpzones_exist)
 371         {
 372                 tracetoss(e, WarpZone_trace_forent);
 373                 if(cb)
 374                         cb(e.origin, trace_endpos, trace_endpos);
 375                 dt = vlen(e.origin - o0) / vlen(e.velocity);
 376                 WarpZone_tracetoss_time += dt;
 377                 e.velocity_z -= dt * g;
 378                 WarpZone_tracetoss_velocity = e.velocity;
 379                 e.velocity = v0;
 380                 return;
 381         }
 382
 383         vf = v_forward;
 384         vr = v_right;
 385         vu = v_up;
 386
 387         // if starting in warpzone, first transform
 388         wz = WarpZone_Find(e.origin + e.mins, e.origin + e.maxs);
 389         if(wz)
 390         {
 391                 WarpZone_trace_firstzone = wz;
 392                 WarpZone_trace_lastzone = wz;
 393                 if(zone && wz != zone)
 394                 {
 395                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 396
 397                         WarpZone_tracetoss_time = 0;
 398                         trace_endpos = o0;
 399                         goto fail;
 400                 }
 401                 WarpZone_Trace_AddTransform(wz);
 402                 vector org = WarpZone_TransformOrigin(wz, e.origin);
 403                 setorigin(e, org);
 404                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 405         }
 406         WarpZone_MakeAllSolid();
 407         i = 16;
 408         for (;;)
 409         {
 410                 if(--i < 1)
 411                 {
 412                         LOG_TRACE("Too many warpzones in sequence, aborting trace.");
 413                         trace_ent = NULL;
 414                         break;
 415                 }
 416                 tracetoss(e, WarpZone_trace_forent);
 417                 if(cb)
 418                         cb(e.origin, trace_endpos, trace_endpos);
 419                 dt = vlen(trace_endpos - e.origin) / vlen(e.velocity);
 420                 WarpZone_tracetoss_time += dt;
 421                 e.origin = trace_endpos;
 422                 e.velocity_z -= dt * g;
 423                 if(trace_fraction >= 1)
 424                         break;
 425                 if(trace_ent.classname != "trigger_warpzone")
 426                         break;
 427                 if(trace_ent == wz)
 428                 {
 429                         // FIXME can this check be removed? Do we really need it?
 430                         LOG_TRACE("I transformed into the same zone again, wtf, aborting the trace");
 431                         trace_ent = NULL;
 432                         break;
 433                 }
 434                 wz = trace_ent;
 435                 if(!WarpZone_trace_firstzone)
 436                         WarpZone_trace_firstzone = wz;
 437                 WarpZone_trace_lastzone = wz;
 438                 if(zone && wz != zone)
 439                         break;
 440                 WarpZone_Trace_AddTransform(wz);
 441                 // we hit a warpzone... so, let's perform the trace after the warp again
 442                 e.origin = WarpZone_TransformOrigin(wz, e.origin);
 443                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 444
 445                 // we got warped, so let's step back a bit
 446                 e.velocity = -e.velocity;
 447                 tracetoss(e, WarpZone_trace_forent);
 448                 dt = vlen(trace_endpos - e.origin) / vlen(e.velocity);
 449                 WarpZone_tracetoss_time -= dt;
 450                 e.origin = trace_endpos;
 451                 e.velocity = -e.velocity;
 452         }
 453         WarpZone_MakeAllOther();
 454 LABEL(fail)
 455         WarpZone_tracetoss_velocity = e.velocity;
 456         v_forward = vf;
 457         v_right = vr;
 458         v_up = vu;
 459         // restore old entity data (caller just uses trace_endpos, WarpZone_tracetoss_velocity and the transform)
 460         e.velocity = v0;
 461         e.origin = o0;
 462 }
 463
 464 void WarpZone_TraceToss(entity e, entity forent)
 465 {
 466         WarpZone_TraceToss_ThroughZone(e, forent, NULL, WarpZone_trace_callback_t_null);
 467 }
 468
 469 entity WarpZone_TrailParticles_trace_callback_own;
 470 float WarpZone_TrailParticles_trace_callback_eff;
 471 void WarpZone_TrailParticles_trace_callback(vector from, vector endpos, vector to)
 472 {
 473         __trailparticles(WarpZone_TrailParticles_trace_callback_own, WarpZone_TrailParticles_trace_callback_eff, from, endpos);
 474 }
 475
 476 void WarpZone_TrailParticles(entity own, float eff, vector org, vector end)
 477 {
 478         WarpZone_TrailParticles_trace_callback_own = own;
 479         WarpZone_TrailParticles_trace_callback_eff = eff;
 480         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, NULL, NULL, WarpZone_TrailParticles_trace_callback);
 481 }
 482
 483 #ifdef CSQC
 484 float WarpZone_TrailParticles_trace_callback_f;
 485 float WarpZone_TrailParticles_trace_callback_flags;
 486 void WarpZone_TrailParticles_WithMultiplier_trace_callback(vector from, vector endpos, vector to)
 487 {
 488         boxparticles(WarpZone_TrailParticles_trace_callback_eff, WarpZone_TrailParticles_trace_callback_own, from, endpos, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_f, WarpZone_TrailParticles_trace_callback_flags);
 489 }
 490
 491 void WarpZone_TrailParticles_WithMultiplier(entity own, float eff, vector org, vector end, float f, int boxflags)
 492 {
 493         WarpZone_TrailParticles_trace_callback_own = own;
 494         WarpZone_TrailParticles_trace_callback_eff = eff;
 495         WarpZone_TrailParticles_trace_callback_f = f;
 496         WarpZone_TrailParticles_trace_callback_flags = boxflags | PARTICLES_DRAWASTRAIL;
 497         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, NULL, NULL, WarpZone_TrailParticles_WithMultiplier_trace_callback);
 498 }
 499 #endif
 500
 501 float WarpZone_PlaneDist(entity wz, vector v)
 502 {
 503         return (v - wz.warpzone_origin) * wz.warpzone_forward;
 504 }
 505
 506 float WarpZone_TargetPlaneDist(entity wz, vector v)
 507 {
 508         return (v - wz.warpzone_targetorigin) * wz.warpzone_targetforward;
 509 }
 510
 511 vector WarpZone_TransformOrigin(entity wz, vector v)
 512 {
 513         return wz.warpzone_shift + AnglesTransform_Apply(wz.warpzone_transform, v);
 514 }
 515
 516 vector WarpZone_TransformVelocity(entity wz, vector v)
 517 {
 518         return AnglesTransform_Apply(wz.warpzone_transform, v);
 519 }
 520
 521 vector WarpZone_TransformAngles(entity wz, vector v)
 522 {
 523         return AnglesTransform_ApplyToAngles(wz.warpzone_transform, v);
 524 }
 525
 526 vector WarpZone_TransformVAngles(entity wz, vector ang)
 527 {
 528 #ifdef KEEP_ROLL
 529         float roll;
 530         roll = ang.z;
 531         ang.z = 0;
 532 #endif
 533
 534         ang = AnglesTransform_ApplyToVAngles(wz.warpzone_transform, ang);
 535
 536 #ifdef KEEP_ROLL
 537         ang = AnglesTransform_Normalize(ang, true);
 538         ang = AnglesTransform_CancelRoll(ang);
 539         ang.z = roll;
 540 #else
 541         ang = AnglesTransform_Normalize(ang, false);
 542 #endif
 543
 544         return ang;
 545 }
 546
 547 vector WarpZone_UnTransformOrigin(entity wz, vector v)
 548 {
 549         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v - wz.warpzone_shift);
 550 }
 551
 552 vector WarpZone_UnTransformVelocity(entity wz, vector v)
 553 {
 554         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v);
 555 }
 556
 557 vector WarpZone_UnTransformAngles(entity wz, vector v)
 558 {
 559         return AnglesTransform_ApplyToAngles(AnglesTransform_Invert(wz.warpzone_transform), v);
 560 }
 561
 562 vector WarpZone_UnTransformVAngles(entity wz, vector ang)
 563 {
 564         float roll;
 565
 566         roll = ang.z;
 567         ang.z = 0;
 568
 569         ang = AnglesTransform_ApplyToVAngles(AnglesTransform_Invert(wz.warpzone_transform), ang);
 570         ang = AnglesTransform_Normalize(ang, true);
 571         ang = AnglesTransform_CancelRoll(ang);
 572
 573         ang.z = roll;
 574         return ang;
 575 }
 576
 577 vector WarpZoneLib_NearestPointOnBox(vector mi, vector ma, vector org)
 578 {
 579         vector nearest;
 580         nearest.x = bound(mi.x, org.x, ma.x);
 581         nearest.y = bound(mi.y, org.y, ma.y);
 582         nearest.z = bound(mi.z, org.z, ma.z);
 583         return nearest;
 584 }
 585
 586 // blacklist of entities that WarpZone_FindRadius doesn't care about
 587 bool WarpZoneLib_BadEntity(entity e)
 588 {
 589         if (is_pure(e)) return true;
 590         string s = e.classname;
 591
 592         switch(s)
 593         {
 594                 case "weaponentity":
 595                 case "exteriorweaponentity":
 596                 case "sprite_waypoint":
 597                 case "waypoint":
 598                 case "spawnfunc":
 599                 case "weaponchild":
 600                 case "chatbubbleentity":
 601                 case "buff_model":
 602                 //case "net_linked": // actually some real entities are linked without classname, fail
 603                 case "":
 604                         return true;
 605         }
 606
 607         if (startsWith(s, "target_")) return true;
 608
 609         if (startsWith(s, "info_")) return true;
 610
 611         return false;
 612 }
 613
 614 .float WarpZone_findradius_hit;
 615 .entity WarpZone_findradius_next;
 616 void WarpZone_FindRadius_Recurse(
 617     /** blast origin of current search */
 618     vector org,
 619     float rad,
 620     /** original blast origin */
 621     vector org0,
 622     /** how to untransform (victim to blast system) */
 623     vector transform,
 624     vector shift,
 625     bool needlineofsight)
 626 {
 627         if (rad <= 0) return;
 628         entity wz = NULL;
 629         FOREACH_ENTITY_RADIUS(org, rad, !WarpZoneLib_BadEntity(it), {
 630                 vector p = WarpZoneLib_NearestPointOnBox(it.origin + it.mins, it.origin + it.maxs, org0);
 631                 if (needlineofsight)
 632                 {
 633                         traceline(org, p, MOVE_NOMONSTERS, it);
 634                         if (trace_fraction < 1) continue;
 635                 }
 636                 if (!it.WarpZone_findradius_hit || vlen2(it.WarpZone_findradius_dist) > vlen2(org0 - p))
 637                 {
 638                         it.WarpZone_findradius_nearest = p;
 639                         it.WarpZone_findradius_dist = org0 - p;
 640                         it.WarpZone_findradius_findorigin = org;
 641                         it.WarpZone_findradius_findradius = rad;
 642                         if (it.classname == "warpzone_refsys")
 643                         {
 644                                 // ignore, especially: do not overwrite the refsys parameters
 645                         }
 646                         else if (it.classname == "trigger_warpzone")
 647                         {
 648                                 it.WarpZone_findradius_next = wz;
 649                                 wz = it;
 650                                 it.WarpZone_findradius_hit = 1;
 651                                 it.enemy.WarpZone_findradius_dist = '0 0 0'; // we don't want to go through this zone ever again
 652                                 it.enemy.WarpZone_findradius_hit = 1;
 653                         }
 654                         else
 655                         {
 656                                 it.warpzone_transform = transform;
 657                                 it.warpzone_shift = shift;
 658                                 it.WarpZone_findradius_hit = 1;
 659                         }
 660                 }
 661     });
 662         for(entity e = wz; e; e = e.WarpZone_findradius_next)
 663         {
 664                 if (WarpZoneLib_BadEntity(e)) continue;
 665
 666                 vector org0_new = WarpZone_TransformOrigin(e, org);
 667                 traceline(e.warpzone_targetorigin, org0_new, MOVE_NOMONSTERS, e);
 668                 vector org_new = trace_endpos;
 669
 670                 vector transform_new = AnglesTransform_Multiply(e.warpzone_transform, transform);
 671                 vector shift_new = AnglesTransform_Multiply_GetPostShift(e.warpzone_transform, e.warpzone_shift, transform, shift);
 672                 WarpZone_FindRadius_Recurse(
 673                         org_new,
 674                         bound(0, rad - vlen(org_new - org0_new), rad - 8),
 675                         org0_new,
 676                         transform_new, shift_new,
 677                         needlineofsight);
 678                 e.WarpZone_findradius_hit = 0;
 679                 e.enemy.WarpZone_findradius_hit = 0;
 680         }
 681 }
 682 entity WarpZone_FindRadius(vector org, float rad, bool needlineofsight)
 683 {
 684     // FIXME: why can't we do this? (sometimes finds nothing, breaking explosions)
 685     // if (!warpzone_warpzones_exist && !needlineofsight) return findradius(org, rad);
 686         WarpZone_FindRadius_Recurse(org, rad, org, '0 0 0', '0 0 0', needlineofsight);
 687         entity list_first = findchainfloat(WarpZone_findradius_hit, 1);
 688         FOREACH_LIST(list, chain, true, it.WarpZone_findradius_hit = 0);
 689         return list_first;
 690 }
 691
 692 .entity WarpZone_refsys;
 693 void WarpZone_RefSys_GC(entity this)
 694 {
 695         // garbage collect unused reference systems
 696         this.nextthink = time + 1;
 697         if(this.owner.WarpZone_refsys != this)
 698                 delete(this);
 699 }
 700 void WarpZone_RefSys_CheckCreate(entity me)
 701 {
 702         if(me.WarpZone_refsys.owner != me)
 703         {
 704                 me.WarpZone_refsys = new(warpzone_refsys);
 705                 me.WarpZone_refsys.owner = me;
 706                 setthink(me.WarpZone_refsys, WarpZone_RefSys_GC);
 707                 me.WarpZone_refsys.nextthink = time + 1;
 708                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
 709         }
 710 }
 711 void WarpZone_RefSys_Clear(entity me)
 712 {
 713         if(me.WarpZone_refsys)
 714         {
 715                 delete(me.WarpZone_refsys);
 716                 me.WarpZone_refsys = NULL;
 717         }
 718 }
 719 void WarpZone_RefSys_AddTransform(entity me, vector t, vector s)
 720 {
 721         if(t != '0 0 0' || s != '0 0 0')
 722         {
 723                 WarpZone_RefSys_CheckCreate(me);
 724                 WarpZone_Accumulator_AddTransform(me.WarpZone_refsys, t, s);
 725         }
 726 }
 727 void WarpZone_RefSys_Add(entity me, entity wz)
 728 {
 729         WarpZone_RefSys_AddTransform(me, wz.warpzone_transform, wz.warpzone_shift);
 730 }
 731 void WarpZone_RefSys_AddInverseTransform(entity me, vector t, vector s)
 732 {
 733         if(t != '0 0 0' || s != '0 0 0')
 734         {
 735                 WarpZone_RefSys_CheckCreate(me);
 736                 WarpZone_Accumulator_AddInverseTransform(me.WarpZone_refsys, t, s);
 737         }
 738 }
 739 void WarpZone_RefSys_AddInverse(entity me, entity wz)
 740 {
 741         WarpZone_RefSys_AddInverseTransform(me, wz.warpzone_transform, wz.warpzone_shift);
 742 }
 743 .vector WarpZone_refsys_incremental_shift;
 744 .vector WarpZone_refsys_incremental_transform;
 745 void WarpZone_RefSys_AddIncrementally(entity me, entity ref)
 746 {
 747         //vector t, s;
 748         if(me.WarpZone_refsys_incremental_transform == ref.WarpZone_refsys.warpzone_transform)
 749         if(me.WarpZone_refsys_incremental_shift == ref.WarpZone_refsys.warpzone_shift)
 750                 return;
 751         WarpZone_Accumulator_AddInverseTransform(me.WarpZone_refsys, me.WarpZone_refsys_incremental_transform, me.WarpZone_refsys_incremental_shift);
 752         WarpZone_Accumulator_Add(me.WarpZone_refsys, ref.WarpZone_refsys);
 753         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 754         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 755 }
 756 void WarpZone_RefSys_BeginAddingIncrementally(entity me, entity ref)
 757 {
 758         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 759         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 760 }
 761 vector WarpZone_RefSys_TransformOrigin(entity from, entity to, vector org)
 762 {
 763         if(from.WarpZone_refsys)
 764                 org = WarpZone_UnTransformOrigin(from.WarpZone_refsys, org);
 765         if(to.WarpZone_refsys)
 766                 org = WarpZone_TransformOrigin(to.WarpZone_refsys, org);
 767         return org;
 768 }
 769 vector WarpZone_RefSys_TransformVelocity(entity from, entity to, vector vel)
 770 {
 771         if(from.WarpZone_refsys)
 772                 vel = WarpZone_UnTransformVelocity(from.WarpZone_refsys, vel);
 773         if(to.WarpZone_refsys)
 774                 vel = WarpZone_TransformVelocity(to.WarpZone_refsys, vel);
 775         return vel;
 776 }
 777 vector WarpZone_RefSys_TransformAngles(entity from, entity to, vector ang)
 778 {
 779         if(from.WarpZone_refsys)
 780                 ang = WarpZone_UnTransformAngles(from.WarpZone_refsys, ang);
 781         if(to.WarpZone_refsys)
 782                 ang = WarpZone_TransformAngles(to.WarpZone_refsys, ang);
 783         return ang;
 784 }
 785 vector WarpZone_RefSys_TransformVAngles(entity from, entity to, vector ang)
 786 {
 787         if(from.WarpZone_refsys)
 788                 ang = WarpZone_UnTransformVAngles(from.WarpZone_refsys, ang);
 789         if(to.WarpZone_refsys)
 790                 ang = WarpZone_TransformVAngles(to.WarpZone_refsys, ang);
 791         return ang;
 792 }
 793 void WarpZone_RefSys_Copy(entity me, entity from)
 794 {
 795         if(from.WarpZone_refsys)
 796         {
 797                 WarpZone_RefSys_CheckCreate(me);
 798                 me.WarpZone_refsys.warpzone_shift = from.WarpZone_refsys.warpzone_shift;
 799                 me.WarpZone_refsys.warpzone_transform = from.WarpZone_refsys.warpzone_transform;
 800         }
 801         else
 802                 WarpZone_RefSys_Clear(me);
 803 }
 804 entity WarpZone_RefSys_SpawnSameRefSys(entity me)
 805 {
 806         entity e = spawn();
 807         WarpZone_RefSys_Copy(e, me);
 808         return e;
 809 }
 810
 811 bool WarpZoneLib_ExactTrigger_Touch(entity this, entity toucher, bool touchfunc)
 812 {
 813         vector emin = toucher.absmin, emax = toucher.absmax;
 814         if (!Q3COMPAT_COMMON)
 815         {
 816                 // Xonotic and Nexuiz maps assume triggers will be activated by adjacent players
 817                 // prior to sv_legacy_bbox_expand 0 DP always did this for SVQC and never for CSQC
 818                 emin -= '1 1 1';
 819                 emax += '1 1 1';
 820         }
 821
 822         // if called from a touch func, we can assume the boxes do overlap
 823         if (!touchfunc && !boxesoverlap(emin, emax, this.absmin, this.absmax)) // quick
 824                 return false;
 825
 826         return WarpZoneLib_BoxTouchesBrush(emin, emax, this, toucher); // accurate
 827 }
 828
 829
 830 void WarpZoneLib_MoveOutOfSolid_Expand(entity e, vector by)
 831 {
 832         const float eps = 0.0625;
 833         tracebox(e.origin, e.mins - '1 1 1' * eps, e.maxs + '1 1 1' * eps, e.origin + by, MOVE_WORLDONLY, e);
 834         if (trace_startsolid)
 835                 return;
 836         if (trace_fraction < 1)
 837         {
 838                 // hit something
 839                 // adjust origin in the other direction...
 840                 setorigin(e, e.origin - by * (1 - trace_fraction));
 841         }
 842 }
 843
 844 bool WarpZoneLib_MoveOutOfSolid(entity e)
 845 {
 846         vector o = e.origin;
 847         traceline(o, o, MOVE_WORLDONLY, e);
 848         if (trace_startsolid)
 849                 return false;
 850
 851         tracebox(o, e.mins, e.maxs, o, MOVE_WORLDONLY, e);
 852         if (!trace_startsolid)
 853                 return true;
 854
 855         vector m0 = e.mins;
 856         vector m1 = e.maxs;
 857         e.mins = '0 0 0';
 858         e.maxs = '0 0 0';
 859         WarpZoneLib_MoveOutOfSolid_Expand(e, eX * m0.x); e.mins_x = m0.x;
 860         WarpZoneLib_MoveOutOfSolid_Expand(e, eX * m1.x); e.maxs_x = m1.x;
 861         WarpZoneLib_MoveOutOfSolid_Expand(e, eY * m0.y); e.mins_y = m0.y;
 862         WarpZoneLib_MoveOutOfSolid_Expand(e, eY * m1.y); e.maxs_y = m1.y;
 863         WarpZoneLib_MoveOutOfSolid_Expand(e, eZ * m0.z); e.mins_z = m0.z;
 864         WarpZoneLib_MoveOutOfSolid_Expand(e, eZ * m1.z); e.maxs_z = m1.z;
 865         setorigin(e, e.origin);
 866
 867         tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_WORLDONLY, e);
 868         if (trace_startsolid)
 869         {
 870                 setorigin(e, o);
 871                 return false;
 872         }
 873
 874         return true;
 875 }