qcsrc/lib/string.qh

   1 #pragma once
   2
   3 #include "nil.qh"
   4 #include "sort.qh"
   5 #include "oo.qh"
   6
   7 // string logic
   8 //
   9 // true: is truthy
  10 // == "": is equal to ""
  11 // is "": has the same string index as the string constant ""
  12 // strunzone: can be strunzoned
  13 //
  14 // |              | true | == "" | is "" | strunzone |
  15 // | :----------: | :--: | :---: | :---: | :-------: |
  16 // | nil          |      | yes   |       |           |
  17 // | strcat(nil)  | yes  | yes   |       |           |
  18 // | strzone(nil) | yes  | yes   |       | yes       |
  19 // | ""           | yes  | yes   | yes   |           |
  20 // | strcat("")   | yes  | yes   |       |           |
  21 // | strzone("")  | yes  | yes   |       | yes       |
  22 // | "s"          | yes  |       |       |           |
  23 // | strcat("s")  | yes  |       |       |           |
  24 // | strzone("s") | yes  |       |       | yes       |
  25
  26 #ifdef CSQC
  27         float stringwidth_colors(string s, vector theSize)
  28         {
  29                 return stringwidth_builtin(s, true, theSize);
  30         }
  31
  32         float stringwidth_nocolors(string s, vector theSize)
  33         {
  34                 return stringwidth_builtin(s, false, theSize);
  35         }
  36 #endif
  37 #ifdef MENUQC
  38         float stringwidth_colors(string s, vector theSize)
  39         {
  40                 return stringwidth(s, true, theSize);
  41         }
  42
  43         float stringwidth_nocolors(string s, vector theSize)
  44         {
  45                 return stringwidth(s, false, theSize);
  46         }
  47 #endif
  48
  49 #define strcpy(this, s) MACRO_BEGIN \
  50         if (this) { \
  51                 strunzone(this); \
  52         } \
  53         this = strzone(s); \
  54 MACRO_END
  55
  56 #define strfree(this) MACRO_BEGIN \
  57         if (this) { \
  58                 strunzone(this); \
  59         } \
  60         this = string_null; \
  61 MACRO_END
  62
  63 // Returns the number of days since 0000-03-01 (March 1, year 0)
  64 // Starting counting from March, as the 1st month of the year, February becomes the 12th and last month,
  65 // so its variable duration does not affect, given that the 29th is the last day of the period
  66 ERASEABLE
  67 int days_up_to_date(int Y, int M, int D)
  68 {
  69         int years = (M <= 2) ? Y - 1 : Y;
  70
  71         int leap_days = floor(years / 4) - floor(years / 100) + floor(years / 400);
  72
  73         // using these 2 formulas to save 2 arrays or switches (performance isn't important here)
  74         int months = (M <= 2) ? (M + 9) : (M - 3); // 10, 11, 0, 1, 2, 3, 4, 5, 6, 7, 8, 9
  75         int leftover_days = (M <= 2) ? (M + 5) : floor(0.58 * M - 1.1); // 6, 7, 0, 1, 1, 2, 2, 3, 4, 4, 5, 5
  76
  77         int month_days = 30 * months + leftover_days;
  78
  79         return 365 * years + month_days + D + leap_days;
  80 }
  81
  82 #define DAYS_UP_TO_EPOCH 719469 // days_up_to_date(1970, 1, 1);
  83
  84 // Returns the number of seconds since the Epoch, 1970-01-01 00:00:00 +0000 (UTC).
  85 // This function exists only as a replacement for strftime(false, "%s") which doesn't work
  86 // on Windows (%s is not supported) and at least in some linux systems doesn't return the
  87 // correct result
  88 // NOTE: at the current date, the number (string) returned by both strftime(false, "%s") and
  89 // strftime_s() is so high that can't be converted to int (with ftos) without precision loss
  90 ERASEABLE
  91 string strftime_s()
  92 {
  93         string date = strftime(false, "%Y-%m-%d %H:%M:%S");
  94         int i, seconds = 0;
  95         i =0; int Y = stof(substring(date, i, 4)); // years
  96         i+=5; int M = stof(substring(date, i, 2)); // months
  97         i+=3; int D = stof(substring(date, i, 2)); // days
  98
  99         i+=3; seconds += stof(substring(date, i, 2)) * 60 * 60; // hours
 100         i+=3; seconds += stof(substring(date, i, 2)) * 60; // minutes
 101         i+=3; seconds += stof(substring(date, i, 2)); // seconds
 102
 103         // doing so we loose precision
 104         //seconds += (days_up_to_date(Y, M, D) - DAYS_UP_TO_EPOCH) * 24 * 60 * 60;
 105         //return ftos(seconds);
 106
 107         int days_since_epoch = days_up_to_date(Y, M, D) - DAYS_UP_TO_EPOCH;
 108         // use hundreds of seconds as unit to avoid precision loss
 109         int hundreds_of_seconds = days_since_epoch * 24 * 6 * 6;
 110         hundreds_of_seconds += floor(seconds / 100);
 111
 112         // tens of seconds and seconds
 113         string seconds_str = ftos(seconds % 100);
 114         if ((seconds % 100) < 10)
 115                 seconds_str = strcat("0", seconds_str);
 116
 117         return strcat(ftos(hundreds_of_seconds), seconds_str);
 118 }
 119
 120 ERASEABLE
 121 string seconds_tostring(float sec)
 122 {
 123         float minutes = floor(sec / 60);
 124         sec -= minutes * 60;
 125         return sprintf("%d:%02d", minutes, sec);
 126 }
 127
 128 ERASEABLE
 129 string format_time(float seconds)
 130 {
 131         seconds = floor(seconds + 0.5);
 132         float days = floor(seconds / 864000);
 133         seconds -= days * 864000;
 134         float hours = floor(seconds / 36000);
 135         seconds -= hours * 36000;
 136         float minutes = floor(seconds / 600);
 137         seconds -= minutes * 600;
 138         if (days > 0) return sprintf(_("%d days, %02d:%02d:%02d"), days, hours, minutes, seconds);
 139         else return sprintf(_("%02d:%02d:%02d"), hours, minutes, seconds);
 140 }
 141
 142 ERASEABLE
 143 string mmsss(float tenths)
 144 {
 145         tenths = floor(tenths + 0.5);
 146         float minutes = floor(tenths / 600);
 147         tenths -= minutes * 600;
 148         string s = ftos(1000 + tenths);
 149         return strcat(ftos(minutes), ":", substring(s, 1, 2), ".", substring(s, 3, 1));
 150 }
 151
 152 ERASEABLE
 153 string mmssss(float hundredths)
 154 {
 155         hundredths = floor(hundredths + 0.5);
 156         float minutes = floor(hundredths / 6000);
 157         hundredths -= minutes * 6000;
 158         string s = ftos(10000 + hundredths);
 159         return strcat(ftos(minutes), ":", substring(s, 1, 2), ".", substring(s, 3, 2));
 160 }
 161
 162 int ColorTranslateMode;
 163
 164 ERASEABLE
 165 string ColorTranslateRGB(string s)
 166 {
 167         return (ColorTranslateMode & 1) ? strdecolorize(s) : s;
 168 }
 169
 170 #ifdef GAMEQC
 171 // color code replace, place inside of sprintf and parse the string... defaults described as constants
 172 // foreground/normal colors
 173 string autocvar_hud_colorset_foreground_1 = "2"; // F1 - Green  // primary priority (important names, etc)
 174 string autocvar_hud_colorset_foreground_2 = "3"; // F2 - Yellow // secondary priority (items, locations, numbers, etc)
 175 string autocvar_hud_colorset_foreground_3 = "4"; // F3 - Blue   // tertiary priority or relatively inconsequential text
 176 string autocvar_hud_colorset_foreground_4 = "1"; // F4 - Red    // notice/attention grabbing texting
 177 // "kill" colors
 178 string autocvar_hud_colorset_kill_1 = "1";       // K1 - Red    // "bad" or "dangerous" text (death messages against you, kill notifications, etc)
 179 string autocvar_hud_colorset_kill_2 = "3";       // K2 - Yellow // similar to above, but less important... OR, a highlight out of above message type
 180 string autocvar_hud_colorset_kill_3 = "4";       // K3 - Blue   // "good" or "beneficial" text (you fragging someone, etc)
 181 // background color
 182 string autocvar_hud_colorset_background = "7";   // BG - White // neutral/unimportant text
 183
 184 /** color code replace, place inside of sprintf and parse the string */
 185 string CCR(string input)
 186 {
 187         // foreground/normal colors
 188         input = strreplace("^F1", strcat("^", autocvar_hud_colorset_foreground_1), input);
 189         input = strreplace("^F2", strcat("^", autocvar_hud_colorset_foreground_2), input);
 190         input = strreplace("^F3", strcat("^", autocvar_hud_colorset_foreground_3), input);
 191         input = strreplace("^F4", strcat("^", autocvar_hud_colorset_foreground_4), input);
 192
 193         // "kill" colors
 194         input = strreplace("^K1", strcat("^", autocvar_hud_colorset_kill_1), input);
 195         input = strreplace("^K2", strcat("^", autocvar_hud_colorset_kill_2), input);
 196         input = strreplace("^K3", strcat("^", autocvar_hud_colorset_kill_3), input);
 197
 198         // background colors
 199         input = strreplace("^BG", strcat("^", autocvar_hud_colorset_background), input);
 200         input = strreplace("^N", "^7", input);  // "none"-- reset to white...
 201         return input;
 202 }
 203 #endif
 204
 205 #define startsWith(haystack, needle) (strstrofs(haystack, needle, 0) == 0)
 206
 207 ERASEABLE
 208 bool startsWithNocase(string haystack, string needle)
 209 {
 210         return strcasecmp(substring(haystack, 0, strlen(needle)), needle) == 0;
 211 }
 212
 213 noref string _endsWith_suffix;
 214 #define endsWith(this, suffix) (_endsWith_suffix = suffix, substring(this, -strlen(_endsWith_suffix), -1) == _endsWith_suffix)
 215
 216 /** unzone the string, and return it as tempstring. Safe to be called on string_null */
 217 ERASEABLE
 218 string fstrunzone(string s)
 219 {
 220         if (!s) return s;
 221         string sc = strcat(s, "");
 222         strunzone(s);
 223         return sc;
 224 }
 225
 226 /** returns first word */
 227 ERASEABLE
 228 string car(string s)
 229 {
 230         int o = strstrofs(s, " ", 0);
 231         if (o < 0) return s;
 232         return substring(s, 0, o);
 233 }
 234
 235 /** returns all but first word */
 236 ERASEABLE
 237 string cdr(string s)
 238 {
 239         int o = strstrofs(s, " ", 0);
 240         if (o < 0) return string_null;
 241         return substring(s, o + 1, strlen(s) - (o + 1));
 242 }
 243
 244 ERASEABLE
 245 string cons(string a, string b)
 246 {
 247         if (a == "") return b;
 248         if (b == "") return a;
 249         return strcat(a, " ", b);
 250 }
 251
 252 ERASEABLE
 253 string cons_mid(string a, string mid, string b)
 254 {
 255         if (a == "") return b;
 256         if (b == "") return a;
 257         return strcat(a, mid, b);
 258 }
 259
 260 ERASEABLE
 261 string substring_range(string s, float b, float e)
 262 {
 263         return substring(s, b, e - b);
 264 }
 265
 266 ERASEABLE
 267 string swapwords(string str, float i, float j)
 268 {
 269         float n;
 270         string s1, s2, s3, s4, s5;
 271         float si, ei, sj, ej, s0, en;
 272         n = tokenizebyseparator(str, " ");  // must match g_maplist processing in ShuffleMaplist and "shuffle"
 273         si = argv_start_index(i);
 274         sj = argv_start_index(j);
 275         ei = argv_end_index(i);
 276         ej = argv_end_index(j);
 277         s0 = argv_start_index(0);
 278         en = argv_end_index(n - 1);
 279         s1 = substring_range(str, s0, si);
 280         s2 = substring_range(str, si, ei);
 281         s3 = substring_range(str, ei, sj);
 282         s4 = substring_range(str, sj, ej);
 283         s5 = substring_range(str, ej, en);
 284         return strcat(s1, s4, s3, s2, s5);
 285 }
 286
 287 string _shufflewords_str;
 288 ERASEABLE
 289 void _shufflewords_swapfunc(float i, float j, entity pass)
 290 {
 291         _shufflewords_str = swapwords(_shufflewords_str, i, j);
 292 }
 293
 294 ERASEABLE
 295 string shufflewords(string str)
 296 {
 297         _shufflewords_str = str;
 298         int n = tokenizebyseparator(str, " ");
 299         shuffle(n, _shufflewords_swapfunc, NULL);
 300         str = _shufflewords_str;
 301         _shufflewords_str = string_null;
 302         return str;
 303 }
 304
 305 ERASEABLE
 306 string unescape(string in)
 307 {
 308         in = strzone(in);  // but it doesn't seem to be necessary in my tests at least
 309
 310         int len = strlen(in);
 311         string str = "";
 312         for (int i = 0; i < len; ++i)
 313         {
 314                 string s = substring(in, i, 1);
 315                 if (s == "\\")
 316                 {
 317                         s = substring(in, i + 1, 1);
 318                         if (s == "n") str = strcat(str, "\n");
 319                         else if (s == "\\") str = strcat(str, "\\");
 320                         else str = strcat(str, substring(in, i, 2));
 321                         ++i;
 322                         continue;
 323                 }
 324                 str = strcat(str, s);
 325         }
 326         strunzone(in);
 327         return str;
 328 }
 329
 330 ERASEABLE
 331 string strwords(string s, int w)
 332 {
 333         int endpos = 0;
 334         for ( ; w && endpos >= 0; --w)
 335                 endpos = strstrofs(s, " ", endpos + 1);
 336         if (endpos < 0) return s;
 337         return substring(s, 0, endpos);
 338 }
 339
 340 #define strhasword(s, w) (strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0)
 341
 342 ERASEABLE
 343 int u8_strsize(string s)
 344 {
 345         int l = 0;
 346         for (int i = 0, c; (c = str2chr(s, i)) > 0; ++i, ++l)
 347         {
 348                 l += (c >= 0x80);
 349                 l += (c >= 0x800);
 350                 l += (c >= 0x10000);
 351         }
 352         return l;
 353 }
 354
 355 // List of Unicode spaces: http://jkorpela.fi/chars/spaces.html
 356 ERASEABLE
 357 bool isInvisibleString(string s)
 358 {
 359         s = strdecolorize(s);
 360         bool utf8 = cvar("utf8_enable");
 361         for (int i = 0, n = strlen(s); i < n; ++i)
 362         {
 363                 int c = str2chr(s, i);
 364                 switch (c)
 365                 {
 366                         case 0:
 367                         case 32:           // space
 368                                 break;
 369                         case 192:          // charmap space
 370                                 if (!utf8) break;
 371                                 return false;
 372                         case 0xE000: // invisible char of the utf8 quake charmap
 373                         case 0xE00A: // invisible char of the utf8 quake charmap
 374                         case 0xE0A0: // invisible char of the utf8 quake charmap
 375                         case 0xE020: // invisible char of the utf8 quake charmap
 376                         case 0x00A0: // NO-BREAK SPACE
 377                         //case 0x1680: // OGHAM SPACE MARK
 378                         case 0x180E: // MONGOLIAN VOWEL SEPARATOR
 379                         case 0x2000: // EN QUAD
 380                         case 0x2001: // EM QUAD
 381                         case 0x2002: // EN SPACE
 382                         case 0x2003: // EM SPACE
 383                         case 0x2004: // THREE-PER-EM SPACE
 384                         case 0x2005: // FOUR-PER-EM SPACE
 385                         case 0x2006: // SIX-PER-EM SPACE
 386                         case 0x2007: // FIGURE SPACE
 387                         case 0x2008: // PUNCTUATION SPACE
 388                         case 0x2009: // THIN SPACE
 389                         case 0x200A: // HAIR SPACE
 390                         case 0x200B: // ZERO WIDTH SPACE
 391                         case 0x202F: // NARROW NO-BREAK SPACE
 392                         case 0x205F: // MEDIUM MATHEMATICAL SPACE
 393                         case 0x3000: // IDEOGRAPHIC SPACE
 394                         case 0xFEFF: // ZERO WIDTH NO-BREAK SPACE
 395                                 if (utf8) break;
 396                         default:
 397                                 return false;
 398                 }
 399         }
 400         return true;
 401 }
 402
 403 // Multiline text file buffers
 404
 405 ERASEABLE
 406 int buf_load(string pFilename)
 407 {
 408         int buf = buf_create();
 409         if (buf < 0) return -1;
 410         int fh = fopen(pFilename, FILE_READ);
 411         if (fh < 0)
 412         {
 413                 buf_del(buf);
 414                 return -1;
 415         }
 416         string l;
 417         for (int i = 0; (l = fgets(fh)); ++i)
 418                 bufstr_set(buf, i, l);
 419         fclose(fh);
 420         return buf;
 421 }
 422
 423 ERASEABLE
 424 void buf_save(float buf, string pFilename)
 425 {
 426         int fh = fopen(pFilename, FILE_WRITE);
 427         if (fh < 0) error(strcat("Can't write buf to ", pFilename));
 428         int n = buf_getsize(buf);
 429         for (int i = 0; i < n; ++i)
 430                 fputs(fh, strcat(bufstr_get(buf, i), "\n"));
 431         fclose(fh);
 432 }
 433
 434 /**
 435  * converts a number to a string with the indicated number of decimals
 436  */
 437 ERASEABLE
 438 string ftos_decimals(float number, int decimals)
 439 {
 440         // inhibit stupid negative zero
 441         if (number == 0) number = 0;
 442         return sprintf("%.*f", decimals, number);
 443 }
 444
 445 /**
 446  * converts a number to a string with the minimum number of decimals
 447  */
 448 ERASEABLE
 449 string ftos_mindecimals(float number)
 450 {
 451         // inhibit stupid negative zero
 452         if (number == 0) number = 0;
 453         return sprintf("%.7g", number);
 454 }
 455
 456 ERASEABLE
 457 int vercmp_recursive(string v1, string v2)
 458 {
 459         int dot1 = strstrofs(v1, ".", 0);
 460         int dot2 = strstrofs(v2, ".", 0);
 461         string s1 = (dot1 == -1) ? v1 : substring(v1, 0, dot1);
 462         string s2 = (dot2 == -1) ? v2 : substring(v2, 0, dot2);
 463
 464         float r;
 465         r = stof(s1) - stof(s2);
 466         if (r != 0) return r;
 467
 468         r = strcasecmp(s1, s2);
 469         if (r != 0) return r;
 470
 471         if (dot1 == -1) return (dot2 == -1) ? 0 : -1;
 472         else return (dot2 == -1) ? 1 : vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
 473 }
 474
 475 ERASEABLE
 476 int vercmp(string v1, string v2)
 477 {
 478         if (strcasecmp(v1, v2) == 0) return 0;  // early out check
 479
 480         // "git" beats all
 481         if (v1 == "git") return 1;
 482         if (v2 == "git") return -1;
 483
 484         return vercmp_recursive(v1, v2);
 485 }
 486
 487 const string HEXDIGITS_MINSET = "0123456789ABCDEFabcdef";
 488 const string HEXDIGITS = "0123456789ABCDEF0123456789abcdef";
 489 #define HEXDIGIT_TO_DEC_RAW(d) (strstrofs(HEXDIGITS, (d), 0))
 490 #define HEXDIGIT_TO_DEC(d) ((HEXDIGIT_TO_DEC_RAW(d) | 0x10) - 0x10)
 491 #define DEC_TO_HEXDIGIT(d) (substring(HEXDIGITS_MINSET, (d), 1))
 492 #define IS_HEXDIGIT(d) (strstrofs(HEXDIGITS_MINSET, (d), 0) >= 0)
 493
 494 const string DIGITS = "0123456789";
 495 #define IS_DIGIT(d) (strstrofs(DIGITS, (d), 0) >= 0)
 496
 497 // returns true if the caret at position pos is escaped
 498 ERASEABLE
 499 bool isCaretEscaped(string theText, float pos)
 500 {
 501         // count all the previous carets
 502         int carets = 0;
 503         while(pos - carets >= 1 && substring(theText, pos - carets - 1, 1) == "^")
 504                 ++carets;
 505         // if number of previous carets is odd then this carets is escaped
 506         return (carets & 1);
 507 }
 508
 509 ERASEABLE
 510 bool isValidColorCodeValue(string theText, int cc_len, int tag_start)
 511 {
 512         if (cc_len == 2)
 513                 return IS_DIGIT(substring(theText, tag_start + 1, 1));
 514         if (cc_len == 5)
 515                 return (IS_HEXDIGIT(substring(theText, tag_start + 2, 1))
 516                         && IS_HEXDIGIT(substring(theText, tag_start + 3, 1))
 517                         && IS_HEXDIGIT(substring(theText, tag_start + 4, 1)));
 518         return false;
 519 }
 520
 521 // it returns 0 if pos is NOT in the middle or at the end of a color code
 522 // otherwise it returns a vector with color code length as the first component
 523 // and the offset from '^' position to pos as the second component
 524 // e.g.:
 525 // "j^2kl" | returns 0 if pos == 0 or 1 or 4
 526 //    ^^   | returns '2 1' or '2 2' if pos == 2 or 3
 527 ERASEABLE
 528 vector checkColorCode(string theText, int text_len, int pos, bool check_at_the_end)
 529 {
 530         if (text_len == 0)
 531                 text_len = strlen(theText);
 532         string tag_type = "^";
 533         int cc_len = 2;
 534         int tag_len = 1;
 535
 536         LABEL(check_color_tag)
 537
 538         int ofs = cc_len;
 539         if (!check_at_the_end)
 540                 ofs--;
 541         for (; ofs >= 1; ofs--)
 542         {
 543                 if (!(pos >= ofs && text_len >= pos + (cc_len - ofs)))
 544                         continue;
 545                 if(substring(theText, pos - ofs, tag_len) == tag_type)
 546                 {
 547                         if (!isCaretEscaped(theText, pos - ofs) && isValidColorCodeValue(theText, cc_len, pos - ofs))
 548                                 return eX * cc_len + eY * ofs;
 549                 }
 550         }
 551         if (cc_len == 2)
 552         {
 553                 tag_type = "^x";
 554                 cc_len = 5;
 555                 tag_len = 2;
 556                 goto check_color_tag;
 557         }
 558         return '0 0 0';
 559 }