qcsrc/lib/replicate.qh

   1 #pragma once
   2
   3 #ifdef SVQC
   4 // copies a string to a tempstring (so one can strunzone it)
   5 string strcat1(string s) = #115; // FRIK_FILE
   6 #endif
   7
   8 #if defined(CSQC)
   9 #define REPLICATE_FIELD(type, name) type name
  10 #elif defined(SVQC)
  11 #define REPLICATE_FIELD(type, name) .type name
  12 #endif
  13
  14 #ifdef GAMEQC
  15
  16     /**
  17      * \def REPLICATE(fld, type, cvar)
  18      * Replicates a client cvar into a server field
  19      *
  20      * @param fld   The field to replicate into
  21      * @param type  The field type
  22      * @param cvarname
  23      * @param fixup_func((entity this, string original_value))  optional parameter
  24      */
  25         #define REPLICATE(...) EVAL_REPLICATE(OVERLOAD(REPLICATE, __VA_ARGS__))
  26         #define EVAL_REPLICATE(...) __VA_ARGS__
  27
  28         #if defined(SVQC)
  29         ACCUMULATE void ReplicateVars(entity this, entity store, string thisname, int i) {}
  30         ACCUMULATE void ReplicateVars_ApplyChange(entity this, entity store, string thisname, int i) {}
  31     /**
  32      * \def REPLICATE_APPLYCHANGE(cvarname, ApplyChange_code)
  33      * Allows setting code that will be executed on cvar value changes
  34      *
  35      * @param cvarname
  36      * @param ApplyChange_code  code meant to be run on cvar value changes
  37      */
  38         #define REPLICATE_APPLYCHANGE(var, ApplyChange_code) \
  39                 void ReplicateVars_ApplyChange(entity this, entity store, string thisname, int i) \
  40                         { if (thisname == var) { ApplyChange_code } }
  41         #elif defined(CSQC)
  42         noref float ReplicateVars_time;
  43         ACCUMULATE void ReplicateVars(int mode)
  44         {
  45                 if (time < ReplicateVars_time)
  46                         return;
  47                 ReplicateVars_time = time + 0.8 + random() * 0.4; // check cvars periodically
  48         }
  49         #endif
  50
  51         #define REPLICATE_3(fld, type, var) REPLICATE_4(fld, type, var, )
  52         #define REPLICATE_4(fld, type, var, func) REPLICATE_##type(fld, var, func)
  53         #if defined(SVQC)
  54                 #define REPLICATE_string(fld, var, func) \
  55                         REPLICATE_7(fld, string, var, , \
  56                 { strcpy(field, it); }, \
  57                 { strfree(field); }, \
  58                 { \
  59                         /* also initialize to the default value of func when requesting cvars */ \
  60                         string s = func(this, strcat1(field)); \
  61                         if (s != field) \
  62                         { \
  63                                 strcpy(field, s); \
  64                         } \
  65                 })
  66                 #define REPLICATE_float(fld, var, func) REPLICATE_7(fld, float, var, func,  { field = stof(it); },          , )
  67                 #define REPLICATE_bool(fld, var, func) REPLICATE_7(fld, bool, var, func,   { field = boolean(stoi(it)); }, , )
  68                 #define REPLICATE_int(fld, var, func) REPLICATE_7(fld, int, var, func,    { field = stoi(it); },          , )
  69
  70                 #define REPLICATE_7(fld, type, var, func, create, destroy, after) \
  71                         void ReplicateVars(entity this, entity store, string thisname, int i) \
  72                         { \
  73                                 type field = store.fld; \
  74                                 if (i < 0) { destroy } \
  75                                 else \
  76                                 { \
  77                                         string it = func(argv(i + 1)); \
  78                                         bool current = thisname == var; \
  79                                         if (i > 0) \
  80                                         { \
  81                                                 if (current) { create } \
  82                                         } \
  83                                         else \
  84                                         { \
  85                                                 stuffcmd(this, strcat("cl_cmd sendcvar ", var, "\n")); \
  86                                         } \
  87                                         if (current) { after } \
  88                                 } \
  89                                 store.fld = field; \
  90                         }
  91         #elif defined(CSQC)
  92                 #define REPLICATE_string(fld, var, func) REPLICATE_7(fld, float, var, func, (fld != cvar_string(var)), { strcpy(fld, cvar_string(var)); }, { strfree(fld); })
  93                 #define REPLICATE_float(fld, var, func) REPLICATE_7(fld, float, var, func, (fld != cvar(var)), { fld = cvar(var); }, )
  94                 #define REPLICATE_bool(fld, var, func) REPLICATE_7(fld, bool, var, func, (fld != cvar(var)), { fld = cvar(var); }, )
  95                 #define REPLICATE_int(fld, var, func) REPLICATE_7(fld, int, var, func, (fld != cvar(var)), { fld = cvar(var); }, )
  96
  97                 #define ReplicateVars_Destroy() ReplicateVars(1)
  98                 #define ReplicateVars_Send_All() ReplicateVars(-1)
  99                 #define ReplicateVars_Check() ReplicateVars(0)
 100
 101                 void ReplicateVars_Send(string cvarname) { localcmd(strcat("cl_cmd sendcvar ", cvarname, "\n")); }
 102
 103                 #define REPLICATE_7(fld, type, var, func, check, update, destroy) \
 104                         void ReplicateVars(int mode) \
 105                         { \
 106                                 if (mode == 1) { destroy } \
 107                                 else if (mode == -1 || check) \
 108                                 { \
 109                                         ReplicateVars_Send(var); \
 110                                         update \
 111                                 } \
 112                         }
 113
 114                 #define REPLICATE_SIMPLE(field, cvarname) MACRO_BEGIN \
 115                         float thecvar = cvar(cvarname); \
 116                         if(field != thecvar) \
 117                         { \
 118                                 ReplicateVars_Send(cvarname); \
 119                                 field = thecvar; \
 120                         } \
 121                 MACRO_END
 122         #endif
 123
 124 #endif