qcsrc/lib/log.qh

   1 #pragma once
   2
   3 #include "progname.qh"
   4
   5 void print_assertfailed_severe(string expr);
   6 void print_assertfailed_fatal(string expr);
   7
   8 #define assert(expr, ...) _assert(print_assertfailed_severe, expr, __VA_ARGS__)
   9 #define devassert(...) MACRO_BEGIN if (autocvar_developer > 0) assert(__VA_ARGS__); MACRO_END
  10
  11 #define assert_once(expr, ...) \
  12         MACRO_BEGIN \
  13                 static bool __once; \
  14                 if (!__once) \
  15                 { \
  16                         assert(expr, __VA_ARGS__); \
  17                         __once = true; \
  18                 } \
  19         MACRO_END
  20 #define devassert_once(...) MACRO_BEGIN if (autocvar_developer > 0) assert_once(__VA_ARGS__); MACRO_END
  21
  22 #define demand(expr, ...) _assert(print_assertfailed_fatal, expr, __VA_ARGS__)
  23 #define devdemand(...) MACRO_BEGIN if (autocvar_developer > 0) demand(__VA_ARGS__); MACRO_END
  24
  25 #define _assert(f, expr, then) \
  26         MACRO_BEGIN \
  27                 if (!(expr)) \
  28                 { \
  29                         f(#expr); \
  30                         then; \
  31                 } \
  32         MACRO_END
  33
  34 #define ASSERT_LESS(name, var, const) noref int name[(const - var + 1)];
  35
  36
  37 // would be nice if __FUNC__ could be concatenated at compile time
  38 #if 0
  39         // less work, bigger binary
  40         #define __SOURCELOC__ (sprintf("^7%s^9(^9"__FILE__"^7:^9"STR(__LINE__)"^7)", __FUNC__))
  41 #else
  42         #define __SOURCELOC__ (sprintf("^7%s^9(^9%s^7:^9%s^7)", __FUNC__, __FILE__, STR(__LINE__)))
  43 #endif
  44
  45 #define _LOG_PREFIX(level) strcat("^9[::^7", PROGNAME, "^9::", level, "^9] ")
  46 #define _LOG_HEADER(level) strcat(_LOG_PREFIX(level), __SOURCELOC__, "\n")
  47 #define _LOG(func_header, level, func_msg, s) \
  48         MACRO_BEGIN \
  49                 func_header(autocvar_developer > 0 ? _LOG_HEADER(level) : _LOG_PREFIX(level)); \
  50                 func_msg(strcat("^7", s, "\n")); \
  51         MACRO_END
  52
  53 #define  LOG_FATAL(...) _LOG_FATAL(strcat(__VA_ARGS__))
  54 #define  LOG_FATALF(...) _LOG_FATAL(sprintf(__VA_ARGS__))
  55 #define _LOG_FATAL(s) _LOG(print, "^1FATAL", error, s)
  56
  57 #define  LOG_SEVERE(...) _LOG_SEVERE(strcat(__VA_ARGS__))
  58 #define  LOG_SEVEREF(...) _LOG_SEVERE(sprintf(__VA_ARGS__))
  59 #define _LOG_SEVERE(s) _LOG(print, "^1SEVERE", backtrace, s)
  60
  61 #define  LOG_WARN(...) _LOG_WARN(strcat(__VA_ARGS__))
  62 #define  LOG_WARNF(...) _LOG_WARN(sprintf(__VA_ARGS__))
  63 #define _LOG_WARN(s) _LOG(print, "^3WARNING", print, s)
  64
  65 #define  LOG_INFO(...) _LOG_INFO(strcat(__VA_ARGS__))
  66 #define  LOG_INFOF(...) _LOG_INFO(sprintf(__VA_ARGS__))
  67 #define _LOG_INFO(s) \
  68         MACRO_BEGIN \
  69                 if (autocvar_developer > 1) print(_LOG_HEADER("^5INFO")); \
  70                 else if (autocvar_developer > 0) print(_LOG_PREFIX("^5INFO")); \
  71                 string __s = s; \
  72                 print("^7", __s); \
  73                 /* TODO: unconditionally add a newline when possible */ \
  74                 if (str2chr(__s, strlen(__s) - 1) != '\n') { print("\n"); } \
  75         MACRO_END
  76
  77 #define  LOG_TRACE(...) _LOG_TRACE(strcat(__VA_ARGS__))
  78 #define  LOG_TRACEF(...) _LOG_TRACE(sprintf(__VA_ARGS__))
  79 #define _LOG_TRACE(s) _LOG(dprint, "^6TRACE", dprint, s)
  80
  81 #define  LOG_DEBUG(...) _LOG_DEBUG(strcat(__VA_ARGS__))
  82 #define  LOG_DEBUGF(...) _LOG_DEBUG(sprintf(__VA_ARGS__))
  83 #define _LOG_DEBUG(s) if (autocvar_developer > 1) _LOG(dprint, "^2DEBUG", dprint, s)
  84
  85 // same as LOG_INFO but without any debug information that bloats console output and compiled program files
  86 #define  LOG_HELP(...) _LOG_HELP(strcat(__VA_ARGS__))
  87 #define  LOG_HELPF(...) _LOG_HELP(sprintf(__VA_ARGS__))
  88 #define _LOG_HELP(s) \
  89         MACRO_BEGIN \
  90                 string __s = s; \
  91                 print("^7", __s, (str2chr(__s, strlen(__s) - 1) != '\n') ? "\n" : ""); \
  92         MACRO_END
  93
  94 // TODO: this sucks, lets find a better way to do backtraces?
  95 #define _backtrace() builtin_remove(NULL)
  96
  97 noref int autocvar_developer;
  98 noref bool autocvar_prvm_backtraceforwarnings;
  99
 100 #define backtrace(msg) \
 101         MACRO_BEGIN \
 102                 int dev = autocvar_developer; \
 103                 bool war = autocvar_prvm_backtraceforwarnings; \
 104                 cvar_set("developer", "1"); \
 105                 cvar_set("prvm_backtraceforwarnings", "1"); \
 106                 print("\n--- CUT HERE ---\n", msg); \
 107                 _backtrace(); \
 108                 print("\n--- CUT UNTIL HERE ---\n"); \
 109                 cvar_set("developer", ftos(dev)); \
 110                 cvar_set("prvm_backtraceforwarnings", ftos(war)); \
 111         MACRO_END
 112
 113 void print_assertfailed_severe(string expr)
 114 {
 115         // this is inside a function to avoid expanding it on compilation everytime
 116         LOG_SEVERE("assertion failed: `", expr, "`\n");
 117 }
 118
 119 void print_assertfailed_fatal(string expr)
 120 {
 121         // this is inside a function to avoid expanding it on compilation everytime
 122         LOG_FATAL("assertion failed: `", expr, "`\n");
 123 }