qcsrc/csqcmodel/cl_model.qc

   1 /*
   2  * Copyright (c) 2011 Rudolf Polzer
   3  *
   4  * Permission is hereby granted, free of charge, to any person obtaining a copy
   5  * of this software and associated documentation files (the "Software"), to
   6  * deal in the Software without restriction, including without limitation the
   7  * rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
   8  * sell copies of the Software, and to permit persons to whom the Software is
   9  * furnished to do so, subject to the following conditions:
  10  *
  11  * The above copyright notice and this permission notice shall be included in
  12  * all copies or substantial portions of the Software.
  13  *
  14  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  17  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  18  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  19  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
  20  * IN THE SOFTWARE.
  21  */
  22
  23 var float autocvar_cl_lerpanim_maxdelta_framegroups = 0.1;
  24 var float autocvar_cl_nolerp = 0;
  25
  26 .float csqcmodel_lerpfrac;
  27 .float csqcmodel_lerpfrac2;
  28 .float csqcmodel_lerpfractime;
  29 .float csqcmodel_lerpfrac2time;
  30 .float csqcmodel_teleported;
  31
  32 void CSQCModel_InterpolateAnimation_PreNote(float sf)
  33 {
  34 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
  35         if(sf & CSQCMODEL_PROPERTY_FRAME)
  36         {
  37                 self.frame3 = self.frame;
  38                 self.frame3time = self.frame1time;
  39         }
  40         if(sf & CSQCMODEL_PROPERTY_FRAME2)
  41         {
  42                 self.frame4 = self.frame2;
  43                 self.frame4time = self.frame2time;
  44         }
  45         if(sf & CSQCMODEL_PROPERTY_LERPFRAC)
  46         {
  47                 self.csqcmodel_lerpfrac2 = self.csqcmodel_lerpfrac;
  48                 self.csqcmodel_lerpfrac2time = self.csqcmodel_lerpfractime;
  49                 self.lerpfrac = self.csqcmodel_lerpfrac;
  50         }
  51 #else
  52         if(sf & CSQCMODEL_PROPERTY_FRAME)
  53         {
  54                 self.frame2 = self.frame;
  55                 self.frame2time = self.frame1time;
  56         }
  57 #endif
  58 }
  59
  60 void CSQCModel_InterpolateAnimation_Note(float sf)
  61 {
  62 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
  63         if(sf & CSQCMODEL_PROPERTY_FRAME)
  64         {
  65                 self.frame1time = time;
  66         }
  67         if(sf & CSQCMODEL_PROPERTY_FRAME2)
  68         {
  69                 self.frame2time = time;
  70         }
  71         if(sf & CSQCMODEL_PROPERTY_LERPFRAC)
  72         {
  73                 self.csqcmodel_lerpfrac = self.lerpfrac;
  74                 self.csqcmodel_lerpfractime = time;
  75         }
  76 #else
  77         if(sf & CSQCMODEL_PROPERTY_FRAME)
  78         {
  79                 self.frame1time = time;
  80         }
  81 #endif
  82 }
  83
  84 void CSQCModel_InterpolateAnimation_Do()
  85 {
  86 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
  87         if(autocvar_cl_nolerp || (autocvar_cl_lerpanim_maxdelta_framegroups == 0))
  88         {
  89                 self.lerpfrac = self.csqcmodel_lerpfrac;
  90                 self.lerpfrac3 = 0;
  91                 self.lerpfrac4 = 0;
  92         }
  93         else
  94         {
  95                 float l13, l24, llf;
  96                 float l24_13;
  97
  98                 if(self.frame3time == 0) // if frame1/3 were not previously displayed, only frame1 can make sense
  99                         l13 = 1;
 100                 else
 101                         l13 = bound(0, (time - self.frame1time) / autocvar_cl_lerpanim_maxdelta_framegroups, 1);
 102
 103                 if(self.frame4time == 0) // if frame2/4 were not previously displayed, only frame2 can make sense
 104                         l24 = 1;
 105                 else
 106                         l24 = bound(0, (time - self.frame2time) / autocvar_cl_lerpanim_maxdelta_framegroups, 1);
 107
 108                 if(self.csqcmodel_lerpfrac2time == 0) // if there is no old lerpfrac (newly displayed model), only lerpfrac makes sense
 109                         llf = 1;
 110                 else
 111                         llf = bound(0, (time - self.csqcmodel_lerpfractime) / autocvar_cl_lerpanim_maxdelta_framegroups, 1);
 112
 113                 l24_13 = self.csqcmodel_lerpfrac * llf + self.csqcmodel_lerpfrac2 * (1 - llf);
 114
 115                 self.lerpfrac  = l24 * l24_13;
 116                 self.lerpfrac4 = (1 - l24) * l24_13;
 117                 self.lerpfrac3 = (1 - l13) * (1 - l24_13);
 118
 119                 if(l24_13 == 0) // if frames 2/4 are not displayed, clear their frametime
 120                 {
 121                         self.frame2time = 0;
 122                         self.frame4time = 0;
 123                 }
 124
 125                 if(l24_13 == 1) // if frames 1/3 are not displayed, clear their frametime
 126                 {
 127                         self.frame1time = 0;
 128                         self.frame3time = 0;
 129                 }
 130         }
 131 #else
 132         if(autocvar_cl_nolerp || (autocvar_cl_lerpanim_maxdelta_framegroups == 0))
 133         {
 134                 self.lerpfrac = 0;
 135         }
 136         else
 137         {
 138                 self.lerpfrac = 1 - bound(0, (time - self.frame1time) / autocvar_cl_lerpanim_maxdelta_framegroups, 1);
 139         }
 140 #endif
 141 }
 142
 143 void CSQCModel_Draw()
 144 {
 145         // some nice flags for CSQCMODEL_IF and the hooks
 146         float isplayer = (self.entnum >= 1 && self.entnum <= maxclients);
 147         float islocalplayer = (self.entnum == player_localnum + 1);
 148         float isnolocalplayer = (isplayer && (self.entnum != player_localnum + 1));
 149
 150         // we don't do this for the local player as that one is already handled
 151         // by CSQCPlayer_SetCamera()
 152         if(!CSQCPlayer_IsLocalPlayer())
 153                 InterpolateOrigin_Do();
 154
 155         // TODO csqcplayers: run prediction here too
 156         CSQCModel_InterpolateAnimation_Do();
 157
 158         { CSQCMODEL_HOOK_PREDRAW }
 159
 160         // inherit draw flags easily
 161         entity root = self;
 162         while(root.tag_entity)
 163                 root = root.tag_entity;
 164         if(self != root)
 165         {
 166                 self.renderflags &~= RF_EXTERNALMODEL | RF_VIEWMODEL;
 167                 self.renderflags |= (root.renderflags & (RF_EXTERNALMODEL | RF_VIEWMODEL));
 168         }
 169 }
 170
 171 void CSQCModel_Read()
 172 {
 173         float sf;
 174         sf = ReadShort();
 175
 176         // some nice flags for CSQCMODEL_IF and the hooks
 177         float isplayer = (self.entnum >= 1 && self.entnum <= maxclients);
 178         float islocalplayer = (self.entnum == player_localnum + 1);
 179         float isnolocalplayer = (isplayer && (self.entnum != player_localnum + 1));
 180
 181         self.iflags |= IFLAG_ANGLES; // interpolate angles too
 182
 183         { CSQCMODEL_HOOK_PREUPDATE }
 184
 185         CSQCPlayer_PreUpdate();
 186         InterpolateOrigin_Undo();
 187         CSQCModel_InterpolateAnimation_PreNote(sf);
 188
 189 #define CSQCMODEL_IF(cond) if(cond) {
 190 #define CSQCMODEL_ENDIF }
 191 #define CSQCMODEL_PROPERTY(flag,t,r,w,f) \
 192         if(sf & flag) \
 193                 self.f = r();
 194 #define CSQCMODEL_PROPERTY_SCALED(flag,t,r,w,f,s,mi,ma) \
 195         if(sf & flag) \
 196                 self.f = r() / s;
 197         ALLPROPERTIES
 198 #undef CSQCMODEL_PROPERTY_SCALED
 199 #undef CSQCMODEL_PROPERTY
 200 #undef CSQCMODEL_ENDIF
 201 #undef CSQCMODEL_IF
 202
 203         if(sf & CSQCMODEL_PROPERTY_MODELINDEX)
 204                 setmodelindex(self, self.modelindex); // this retrieves the .model key and sets mins/maxs/absmin/absmax
 205
 206         if(sf & CSQCMODEL_PROPERTY_TELEPORTED)
 207         {
 208                 self.iflags |= IFLAG_TELEPORTED;
 209                 self.csqcmodel_teleported = 1;
 210         }
 211
 212         CSQCModel_InterpolateAnimation_Note(sf);
 213         InterpolateOrigin_Note();
 214         CSQCPlayer_PostUpdate();
 215
 216         { CSQCMODEL_HOOK_POSTUPDATE }
 217
 218 #ifdef CSQCMODEL_SUPPORT_GETTAGINFO_BEFORE_DRAW
 219         InterpolateOrigin_Do();
 220         CSQCModel_InterpolateAnimation_Do();
 221 #endif
 222
 223         // relink
 224         setorigin(self, self.origin);
 225
 226         // set obvious render flags
 227 #ifdef COMPAT_XON050_ENGINE
 228         if(self.entnum == player_localentnum || self.entnum == spectatee_status)
 229 #else
 230         if(self.entnum == player_localentnum)
 231 #endif
 232                 self.renderflags |= RF_EXTERNALMODEL;
 233         else
 234                 self.renderflags &~= RF_EXTERNALMODEL;
 235
 236         // draw it
 237         self.drawmask = MASK_NORMAL;
 238         self.predraw = CSQCModel_Draw;
 239 }
 240
 241 entity CSQCModel_server2csqc(float pl)
 242 {
 243         return findfloat(world, entnum, pl); // FIXME optimize this using an array
 244 }