qcsrc/common/weapons/weapon/shotgun.qc

   1 #include "shotgun.qh"
   2
   3 #ifdef SVQC
   4
   5 // enable to debug melee range
   6 //#define SHOTGUN_MELEEDEBUG
   7
   8 void W_Shotgun_Attack(Weapon thiswep, entity actor, .entity weaponentity,
   9                       float isprimary, float ammocount, float damage,
  10                       float falloff_halflife, float falloff_mindist, float falloff_maxdist,
  11                       float bullets, float spread, float solidpenetration,
  12                       float force, float falloff_forcehalflife, entity bullet_trail_effect)
  13 {
  14         W_DecreaseAmmo(thiswep, actor, ammocount, weaponentity);
  15
  16         W_SetupShot(actor, weaponentity, true, 5, SND_SHOTGUN_FIRE,
  17                 ((isprimary) ? CH_WEAPON_A : CH_WEAPON_SINGLE), damage * bullets, thiswep.m_id);
  18
  19         // TRICK: do the antilag outside the regular fireBullet function,
  20         // so it isn't performed unnecessarily on every single bullet!
  21         float lag = antilag_getlag(actor);
  22         if(lag && bullets > 0)
  23                 antilag_takeback_all(actor, lag);
  24
  25         for(int sc = 0;sc < bullets;sc = sc + 1)
  26                 fireBullet_falloff(actor, weaponentity, w_shotorg, w_shotdir, spread, solidpenetration,
  27                         damage, falloff_halflife, falloff_mindist, falloff_maxdist, 0, force,
  28                         falloff_forcehalflife, thiswep.m_id, bullet_trail_effect, false);
  29
  30         if(lag && bullets > 0)
  31                 antilag_restore_all(actor);
  32
  33         W_MuzzleFlash(thiswep, actor, weaponentity, w_shotorg, w_shotdir);
  34
  35         // casing code
  36         if(autocvar_g_casings >= 1)
  37         {
  38                 makevectors(actor.v_angle); // for some reason, this is lost
  39                 //for(int sc = 0;sc < WEP_CVAR_PRI(shotgun, ammo);sc = sc + 1)
  40                         SpawnCasing(((random() * 50 + 50) * v_right) - (v_forward * (random() * 25 + 25)) - ((random() * 5 - 30) * v_up), vectoangles(v_forward), 1, actor, weaponentity);
  41         }
  42 }
  43
  44 .float swing_prev;
  45 .entity swing_alreadyhit;
  46 void W_Shotgun_Melee_Think(entity this)
  47 {
  48         // declarations
  49         float i, f, swing, swing_factor, swing_damage, meleetime, is_player;
  50         entity target_victim;
  51         vector targpos;
  52
  53         if(!this.cnt) // set start time of melee
  54         {
  55                 this.cnt = time;
  56                 W_PlayStrengthSound(this.realowner);
  57         }
  58
  59         makevectors(this.realowner.v_angle); // update values for v_* vectors
  60
  61         // calculate swing percentage based on time
  62         meleetime = WEP_CVAR_SEC(shotgun, melee_time) * W_WeaponRateFactor(this.realowner);
  63         swing = bound(0, (this.cnt + meleetime - time) / meleetime, 10);
  64         f = ((1 - swing) * WEP_CVAR_SEC(shotgun, melee_traces));
  65
  66         // check to see if we can still continue, otherwise give up now
  67         if(IS_DEAD(this.realowner) && WEP_CVAR_SEC(shotgun, melee_no_doubleslap))
  68         {
  69                 delete(this);
  70                 return;
  71         }
  72
  73         // if okay, perform the traces needed for this frame
  74         for(i=this.swing_prev; i < f; ++i)
  75         {
  76                 swing_factor = ((1 - (i / WEP_CVAR_SEC(shotgun, melee_traces))) * 2 - 1);
  77
  78                 targpos = (this.realowner.origin + this.realowner.view_ofs
  79                         + (v_forward * WEP_CVAR_SEC(shotgun, melee_range))
  80                         + (v_up * swing_factor * WEP_CVAR_SEC(shotgun, melee_swing_up))
  81                         + (v_right * swing_factor * WEP_CVAR_SEC(shotgun, melee_swing_side)));
  82
  83                 WarpZone_traceline_antilag(this.realowner, this.realowner.origin + this.realowner.view_ofs, targpos, false, this.realowner, ((IS_CLIENT(this.realowner)) ? ANTILAG_LATENCY(this.realowner) : 0));
  84
  85                 // draw lightning beams for debugging
  86         #ifdef SHOTGUN_MELEEDEBUG
  87                 te_lightning2(NULL, targpos, this.realowner.origin + this.realowner.view_ofs + v_forward * 5 - v_up * 5);
  88                 te_customflash(targpos, 40,  2, '1 1 1');
  89         #endif
  90
  91                 is_player = (IS_PLAYER(trace_ent) || trace_ent.classname == "body" || IS_MONSTER(trace_ent));
  92
  93                 if((trace_fraction < 1) // if trace is good, apply the damage and remove this
  94                         && (trace_ent.takedamage != DAMAGE_NO)
  95                         && (trace_ent != this.swing_alreadyhit)
  96                         && (is_player || WEP_CVAR_SEC(shotgun, melee_nonplayerdamage)))
  97                 {
  98                         target_victim = trace_ent; // so it persists through other calls
  99
 100                         if(is_player) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught.
 101                                 swing_damage = (WEP_CVAR_SEC(shotgun, damage) * min(1, swing_factor + 1));
 102                         else
 103                                 swing_damage = (WEP_CVAR_SEC(shotgun, melee_nonplayerdamage) * min(1, swing_factor + 1));
 104
 105                         //print(strcat(this.realowner.netname, " hitting ", target_victim.netname, " with ", strcat(ftos(swing_damage), " damage (factor: ", ftos(swing_factor), ") at "), ftos(time), " seconds.\n"));
 106
 107                         Damage(target_victim, this.realowner, this.realowner,
 108                                 swing_damage, WEP_SHOTGUN.m_id | HITTYPE_SECONDARY, this.weaponentity_fld,
 109                                 this.realowner.origin + this.realowner.view_ofs,
 110                                 v_forward * WEP_CVAR_SEC(shotgun, force));
 111
 112                         if(accuracy_isgooddamage(this.realowner, target_victim)) { accuracy_add(this.realowner, WEP_SHOTGUN, 0, swing_damage); }
 113
 114                         // draw large red flash for debugging
 115                 #ifdef SHOTGUN_MELEEDEBUG
 116                         te_customflash(targpos, 200, 2, '15 0 0');
 117                 #endif
 118
 119                         if(WEP_CVAR_SEC(shotgun, melee_multihit)) // allow multiple hits with one swing, but not against the same player twice.
 120                         {
 121                                 this.swing_alreadyhit = target_victim;
 122                                 continue; // move along to next trace
 123                         }
 124                         else
 125                         {
 126                                 delete(this);
 127                                 return;
 128                         }
 129                 }
 130         }
 131
 132         if(time >= this.cnt + meleetime)
 133         {
 134                 // melee is finished
 135                 delete(this);
 136                 return;
 137         }
 138         else
 139         {
 140                 // set up next frame
 141                 this.swing_prev = i;
 142                 this.nextthink = time;
 143         }
 144 }
 145
 146 void W_Shotgun_Attack2(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 147 {
 148         sound(actor, CH_WEAPON_A, SND_SHOTGUN_MELEE, VOL_BASE, ATTEN_NORM);
 149         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(shotgun, animtime), w_ready);
 150
 151         entity meleetemp = new_pure(meleetemp);
 152         meleetemp.realowner = actor;
 153         setthink(meleetemp, W_Shotgun_Melee_Think);
 154         meleetemp.nextthink = time + WEP_CVAR_SEC(shotgun, melee_delay) * W_WeaponRateFactor(actor);
 155         meleetemp.weaponentity_fld = weaponentity;
 156         W_SetupShot_Range(actor, weaponentity, true, 0, SND_Null, 0, WEP_CVAR_SEC(shotgun, damage), WEP_CVAR_SEC(shotgun, melee_range), WEP_SHOTGUN.m_id | HITTYPE_SECONDARY);
 157 }
 158
 159 // alternate secondary weapon frames
 160 void W_Shotgun_Attack3_Frame2(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 161 {
 162         if (!thiswep.wr_checkammo2(thiswep, actor, weaponentity))
 163         if (!(actor.items & IT_UNLIMITED_AMMO))
 164         {
 165                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
 166                 w_ready(thiswep, actor, weaponentity, fire);
 167                 return;
 168         }
 169
 170         sound(actor, CH_WEAPON_SINGLE, SND_Null, VOL_BASE, ATTN_NORM); // kill previous sound
 171         W_Shotgun_Attack(thiswep, actor, weaponentity, true,
 172                 WEP_CVAR_PRI(shotgun, ammo),
 173                 WEP_CVAR_PRI(shotgun, damage),
 174                 WEP_CVAR_PRI(shotgun, damagefalloff_halflife),
 175                 WEP_CVAR_PRI(shotgun, damagefalloff_mindist),
 176                 WEP_CVAR_PRI(shotgun, damagefalloff_maxdist),
 177                 WEP_CVAR_PRI(shotgun, bullets),
 178                 WEP_CVAR_PRI(shotgun, spread),
 179                 WEP_CVAR_PRI(shotgun, solidpenetration),
 180                 WEP_CVAR_PRI(shotgun, force),
 181                 WEP_CVAR_PRI(shotgun, damagefalloff_forcehalflife),
 182                 EFFECT_BULLET_WEAK); // actually is secondary, but we trick the last shot into playing full reload sound
 183         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), w_ready);
 184 }
 185 void W_Shotgun_Attack3_Frame1(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 186 {
 187         if (!thiswep.wr_checkammo2(thiswep, actor, weaponentity))
 188         if (!(actor.items & IT_UNLIMITED_AMMO))
 189         {
 190                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
 191                 w_ready(thiswep, actor, weaponentity, fire);
 192                 return;
 193         }
 194
 195         W_Shotgun_Attack(thiswep, actor, weaponentity, false,
 196                 WEP_CVAR_PRI(shotgun, ammo),
 197                 WEP_CVAR_PRI(shotgun, damage),
 198                 WEP_CVAR_PRI(shotgun, damagefalloff_halflife),
 199                 WEP_CVAR_PRI(shotgun, damagefalloff_mindist),
 200                 WEP_CVAR_PRI(shotgun, damagefalloff_maxdist),
 201                 WEP_CVAR_PRI(shotgun, bullets),
 202                 WEP_CVAR_PRI(shotgun, spread),
 203                 WEP_CVAR_PRI(shotgun, solidpenetration),
 204                 WEP_CVAR_PRI(shotgun, force),
 205                 WEP_CVAR_PRI(shotgun, damagefalloff_forcehalflife),
 206                 EFFECT_BULLET_WEAK);
 207         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), W_Shotgun_Attack3_Frame2);
 208 }
 209
 210 .float shotgun_primarytime;
 211
 212 METHOD(Shotgun, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 213 {
 214     if(vdist(actor.origin - actor.enemy.origin, <=, WEP_CVAR_SEC(shotgun, melee_range)))
 215         PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false, false);
 216     else
 217         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false, false);
 218 }
 219
 220 METHOD(Shotgun, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 221 {
 222     // force reload weapon when clip is empty or insufficent
 223     if(WEP_CVAR(shotgun, reload_ammo) && actor.(weaponentity).clip_load < WEP_CVAR_PRI(shotgun, ammo))
 224     {
 225         if(actor.(weaponentity).clip_load >= 0 && GetResource(actor, thiswep.ammo_type) > 0)
 226         {
 227             thiswep.wr_reload(thiswep, actor, weaponentity);
 228             return;
 229         }
 230     }
 231
 232     if(actor.(weaponentity).clip_load >= 0) // we are not currently reloading
 233     {
 234         if(fire & 1)
 235         {
 236             if(time >= actor.(weaponentity).shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 237             {
 238                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(shotgun, animtime)))
 239                 {
 240                     W_Shotgun_Attack(thiswep, actor, weaponentity, true,
 241                                                 WEP_CVAR_PRI(shotgun, ammo),
 242                                                 WEP_CVAR_PRI(shotgun, damage),
 243                                                 WEP_CVAR_PRI(shotgun, damagefalloff_halflife),
 244                                                 WEP_CVAR_PRI(shotgun, damagefalloff_mindist),
 245                                                 WEP_CVAR_PRI(shotgun, damagefalloff_maxdist),
 246                                                 WEP_CVAR_PRI(shotgun, bullets),
 247                                                 WEP_CVAR_PRI(shotgun, spread),
 248                                                 WEP_CVAR_PRI(shotgun, solidpenetration),
 249                                                 WEP_CVAR_PRI(shotgun, force),
 250                                                 WEP_CVAR_PRI(shotgun, damagefalloff_forcehalflife),
 251                                                 EFFECT_BULLET_WEAK);
 252                     actor.(weaponentity).shotgun_primarytime = time + WEP_CVAR_PRI(shotgun, refire) * W_WeaponRateFactor(actor);
 253                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(shotgun, animtime), w_ready);
 254                     return;
 255                 }
 256             }
 257         }
 258         else if((fire & 2) && WEP_CVAR(shotgun, secondary) == 2)
 259         {
 260             if(time >= actor.(weaponentity).shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 261             {
 262                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_SEC(shotgun, alt_animtime)))
 263                 {
 264                     W_Shotgun_Attack(thiswep, actor, weaponentity, false,
 265                                                 WEP_CVAR_PRI(shotgun, ammo),
 266                                                 WEP_CVAR_PRI(shotgun, damage),
 267                                                 WEP_CVAR_PRI(shotgun, damagefalloff_halflife),
 268                                                 WEP_CVAR_PRI(shotgun, damagefalloff_mindist),
 269                                                 WEP_CVAR_PRI(shotgun, damagefalloff_maxdist),
 270                                                 WEP_CVAR_PRI(shotgun, bullets),
 271                                                 WEP_CVAR_PRI(shotgun, spread),
 272                                                 WEP_CVAR_PRI(shotgun, solidpenetration),
 273                                                 WEP_CVAR_PRI(shotgun, force),
 274                                                 WEP_CVAR_PRI(shotgun, damagefalloff_forcehalflife),
 275                                                 EFFECT_BULLET_WEAK);
 276                     actor.(weaponentity).shotgun_primarytime = time + WEP_CVAR_SEC(shotgun, alt_refire) * W_WeaponRateFactor(actor);
 277                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), W_Shotgun_Attack3_Frame1);
 278                     return;
 279                 }
 280             }
 281         }
 282     }
 283
 284     if(actor.(weaponentity).clip_load >= 0) // we are not currently reloading
 285     if(WEP_CVAR(shotgun, secondary) == 1)
 286     if(((fire & 1) && !IS_BOT_CLIENT(actor) && GetResource(actor, thiswep.ammo_type) <= 0 && actor.(weaponentity).clip_load == 0 && !(actor.items & IT_UNLIMITED_AMMO)) || (fire & 2))
 287     if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(shotgun, refire)))
 288     {
 289         // melee attack
 290         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 291         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 292     }
 293 }
 294 METHOD(Shotgun, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 295 {
 296     float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(shotgun, ammo);
 297     ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR_PRI(shotgun, ammo);
 298     return ammo_amount;
 299 }
 300 METHOD(Shotgun, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 301 {
 302     switch(WEP_CVAR(shotgun, secondary))
 303     {
 304         case 1: return true; // melee does not use ammo
 305         case 2: // secondary triple shot
 306         {
 307             float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(shotgun, ammo);
 308             ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR_PRI(shotgun, ammo);
 309             return ammo_amount;
 310         }
 311         default: return false; // secondary unavailable
 312     }
 313 }
 314 METHOD(Shotgun, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 315 {
 316     W_Reload(actor, weaponentity, WEP_CVAR_PRI(shotgun, ammo), SND_RELOAD); // WEAPONTODO
 317 }
 318 METHOD(Shotgun, wr_suicidemessage, Notification(entity thiswep))
 319 {
 320     return WEAPON_THINKING_WITH_PORTALS;
 321 }
 322 METHOD(Shotgun, wr_killmessage, Notification(entity thiswep))
 323 {
 324     if(w_deathtype & HITTYPE_SECONDARY)
 325         return WEAPON_SHOTGUN_MURDER_SLAP;
 326     else
 327         return WEAPON_SHOTGUN_MURDER;
 328 }
 329
 330 #endif
 331 #ifdef CSQC
 332 .float prevric;
 333
 334 METHOD(Shotgun, wr_impacteffect, void(entity thiswep, entity actor))
 335 {
 336     vector org2 = w_org + w_backoff * 2;
 337     pointparticles(EFFECT_SHOTGUN_IMPACT, org2, w_backoff * 1000, 1);
 338     if(!w_issilent && time - actor.prevric > 0.25)
 339     {
 340         if(w_random < 0.05)
 341             sound(actor, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTEN_NORM);
 342         actor.prevric = time;
 343     }
 344 }
 345
 346 #endif