qcsrc/common/weapons/weapon/seeker.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(Seeker, Weapon)
   3 /* ammotype  */ ATTRIB(Seeker, ammo_field, .int, ammo_rockets)
   4 /* impulse   */ ATTRIB(Seeker, impulse, int, 8)
   5 /* flags     */ ATTRIB(Seeker, spawnflags, int, WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH);
   6 /* rating    */ ATTRIB(Seeker, bot_pickupbasevalue, float, BOT_PICKUP_RATING_HIGH);
   7 /* color     */ ATTRIB(Seeker, wpcolor, vector, '0.5 1 0');
   8 /* modelname */ ATTRIB(Seeker, mdl, string, "seeker");
   9 #ifndef MENUQC
  10 /* model     */ ATTRIB(Seeker, m_model, Model, MDL_SEEKER_ITEM);
  11 #endif
  12 /* crosshair */ ATTRIB(Seeker, w_crosshair, string, "gfx/crosshairseeker");
  13 /* crosshair */ ATTRIB(Seeker, w_crosshair_size, float, 0.8);
  14 /* wepimg    */ ATTRIB(Seeker, model2, string, "weaponseeker");
  15 /* refname   */ ATTRIB(Seeker, netname, string, "seeker");
  16 /* wepname   */ ATTRIB(Seeker, m_name, string, _("T.A.G. Seeker"));
  17
  18 #define X(BEGIN, P, END, class, prefix) \
  19         BEGIN(class) \
  20         P(class, prefix, flac_ammo, float, NONE) \
  21         P(class, prefix, flac_animtime, float, NONE) \
  22         P(class, prefix, flac_damage, float, NONE) \
  23         P(class, prefix, flac_edgedamage, float, NONE) \
  24         P(class, prefix, flac_force, float, NONE) \
  25         P(class, prefix, flac_lifetime, float, NONE) \
  26         P(class, prefix, flac_lifetime_rand, float, NONE) \
  27         P(class, prefix, flac_radius, float, NONE) \
  28         P(class, prefix, flac_refire, float, NONE) \
  29         P(class, prefix, flac_speed, float, NONE) \
  30         P(class, prefix, flac_speed_up, float, NONE) \
  31         P(class, prefix, flac_speed_z, float, NONE) \
  32         P(class, prefix, flac_spread, float, NONE) \
  33         P(class, prefix, missile_accel, float, NONE) \
  34         P(class, prefix, missile_ammo, float, NONE) \
  35         P(class, prefix, missile_animtime, float, NONE) \
  36         P(class, prefix, missile_count, float, NONE) \
  37         P(class, prefix, missile_damageforcescale, float, NONE) \
  38         P(class, prefix, missile_damage, float, NONE) \
  39         P(class, prefix, missile_decel, float, NONE) \
  40         P(class, prefix, missile_delay, float, NONE) \
  41         P(class, prefix, missile_edgedamage, float, NONE) \
  42         P(class, prefix, missile_force, float, NONE) \
  43         P(class, prefix, missile_health, float, NONE) \
  44         P(class, prefix, missile_lifetime, float, NONE) \
  45         P(class, prefix, missile_proxy, float, NONE) \
  46         P(class, prefix, missile_proxy_delay, float, NONE) \
  47         P(class, prefix, missile_proxy_maxrange, float, NONE) \
  48         P(class, prefix, missile_radius, float, NONE) \
  49         P(class, prefix, missile_refire, float, NONE) \
  50         P(class, prefix, missile_smart, float, NONE) \
  51         P(class, prefix, missile_smart_mindist, float, NONE) \
  52         P(class, prefix, missile_smart_trace_max, float, NONE) \
  53         P(class, prefix, missile_smart_trace_min, float, NONE) \
  54         P(class, prefix, missile_speed, float, NONE) \
  55         P(class, prefix, missile_speed_max, float, NONE) \
  56         P(class, prefix, missile_speed_up, float, NONE) \
  57         P(class, prefix, missile_speed_z, float, NONE) \
  58         P(class, prefix, missile_spread, float, NONE) \
  59         P(class, prefix, missile_turnrate, float, NONE) \
  60         P(class, prefix, reload_ammo, float, NONE) \
  61                 P(class, prefix, reload_time, float, NONE) \
  62                 P(class, prefix, switchdelay_drop, float, NONE) \
  63                 P(class, prefix, switchdelay_raise, float, NONE) \
  64         P(class, prefix, tag_ammo, float, NONE) \
  65         P(class, prefix, tag_animtime, float, NONE) \
  66         P(class, prefix, tag_damageforcescale, float, NONE) \
  67         P(class, prefix, tag_health, float, NONE) \
  68         P(class, prefix, tag_lifetime, float, NONE) \
  69         P(class, prefix, tag_refire, float, NONE) \
  70         P(class, prefix, tag_speed, float, NONE) \
  71         P(class, prefix, tag_spread, float, NONE) \
  72         P(class, prefix, tag_tracker_lifetime, float, NONE) \
  73                 P(class, prefix, type, float, NONE) \
  74                 P(class, prefix, weaponreplace, string, NONE) \
  75                 P(class, prefix, weaponstartoverride, float, NONE) \
  76                 P(class, prefix, weaponstart, float, NONE) \
  77                 P(class, prefix, weaponthrowable, float, NONE) \
  78         END()
  79         W_PROPS(X, Seeker, seeker)
  80 #undef X
  81 ENDCLASS(Seeker)
  82 REGISTER_WEAPON(SEEKER, seeker, NEW(Seeker));
  83
  84
  85 #ifdef SVQC
  86 .entity tag_target, wps_tag_tracker;
  87 .float tag_time;
  88 #endif
  89 #endif
  90 #ifdef IMPLEMENTATION
  91 #ifdef SVQC
  92 spawnfunc(weapon_seeker) { weapon_defaultspawnfunc(this, WEP_SEEKER); }
  93
  94 // ============================
  95 // Begin: Missile functions, these are general functions to be manipulated by other code
  96 // ============================
  97 void W_Seeker_Missile_Explode()
  98 {SELFPARAM();
  99         self.event_damage = func_null;
 100         RadiusDamage(self, self.realowner, WEP_CVAR(seeker, missile_damage), WEP_CVAR(seeker, missile_edgedamage), WEP_CVAR(seeker, missile_radius), world, world, WEP_CVAR(seeker, missile_force), self.projectiledeathtype, other);
 101
 102         remove(self);
 103 }
 104
 105 void W_Seeker_Missile_Touch()
 106 {
 107         PROJECTILE_TOUCH;
 108
 109         W_Seeker_Missile_Explode();
 110 }
 111
 112 void W_Seeker_Missile_Think()
 113 {SELFPARAM();
 114         entity e;
 115         vector desireddir, olddir, newdir, eorg;
 116         float turnrate;
 117         float dist;
 118         float spd;
 119
 120         if(time > self.cnt)
 121         {
 122                 self.projectiledeathtype |= HITTYPE_SPLASH;
 123                 W_Seeker_Missile_Explode();
 124         }
 125
 126         spd = vlen(self.velocity);
 127         spd = bound(
 128                 spd - WEP_CVAR(seeker, missile_decel) * frametime,
 129                 WEP_CVAR(seeker, missile_speed_max),
 130                 spd + WEP_CVAR(seeker, missile_accel) * frametime
 131         );
 132
 133         if(self.enemy != world)
 134                 if(self.enemy.takedamage != DAMAGE_AIM || IS_DEAD(self.enemy))
 135                         self.enemy = world;
 136
 137         if(self.enemy != world)
 138         {
 139                 e               = self.enemy;
 140                 eorg            = 0.5 * (e.absmin + e.absmax);
 141                 turnrate        = WEP_CVAR(seeker, missile_turnrate); // how fast to turn
 142                 desireddir      = normalize(eorg - self.origin);
 143                 olddir          = normalize(self.velocity); // get my current direction
 144                 dist            = vlen(eorg - self.origin);
 145
 146                 // Do evasive maneuvers for world objects? ( this should be a cpu hog. :P )
 147                 if(WEP_CVAR(seeker, missile_smart) && (dist > WEP_CVAR(seeker, missile_smart_mindist)))
 148                 {
 149                         // Is it a better idea (shorter distance) to trace to the target itself?
 150                         if( vdist(self.origin + olddir * self.wait, <, dist))
 151                                 traceline(self.origin, self.origin + olddir * self.wait, false, self);
 152                         else
 153                                 traceline(self.origin, eorg, false, self);
 154
 155                         // Setup adaptive tracelength
 156                         self.wait = bound(WEP_CVAR(seeker, missile_smart_trace_min), vlen(self.origin - trace_endpos), self.wait = WEP_CVAR(seeker, missile_smart_trace_max));
 157
 158                         // Calc how important it is that we turn and add this to the desierd (enemy) dir.
 159                         desireddir  = normalize(((trace_plane_normal * (1 - trace_fraction)) + (desireddir * trace_fraction)) * 0.5);
 160                 }
 161
 162                 newdir = normalize(olddir + desireddir * turnrate); // take the average of the 2 directions; not the best method but simple & easy
 163                 self.velocity = newdir * spd; // make me fly in the new direction at my flight speed
 164         }
 165         else
 166                 dist = 0;
 167
 168         // Proxy
 169         if(WEP_CVAR(seeker, missile_proxy))
 170         {
 171                 if(dist <= WEP_CVAR(seeker, missile_proxy_maxrange))
 172                 {
 173                         if(self.autoswitch == 0)
 174                         {
 175                                 self.autoswitch = time + WEP_CVAR(seeker, missile_proxy_delay);
 176                         }
 177                         else
 178                         {
 179                                 if(self.autoswitch <= time)
 180                                 {
 181                                         W_Seeker_Missile_Explode();
 182                                         self.autoswitch = 0;
 183                                 }
 184                         }
 185                 }
 186                 else
 187                 {
 188                         if(self.autoswitch != 0)
 189                                 self.autoswitch = 0;
 190                 }
 191         }
 192         ///////////////
 193
 194         if(IS_DEAD(self.enemy))
 195         {
 196                 self.enemy = world;
 197                 self.cnt = time + 1 + (random() * 4);
 198                 self.nextthink = self.cnt;
 199                 return;
 200         }
 201
 202         //self.angles = vectoangles(self.velocity);                     // turn model in the new flight direction
 203         self.nextthink = time;// + 0.05; // csqc projectiles
 204         UpdateCSQCProjectile(self);
 205 }
 206
 207
 208
 209 void W_Seeker_Missile_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 210 {
 211         if(this.health <= 0)
 212                 return;
 213
 214         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1)) // no exceptions
 215                 return; // g_projectiles_damage says to halt
 216
 217         if(this.realowner == attacker)
 218                 this.health = this.health - (damage * 0.25);
 219         else
 220                 this.health = this.health - damage;
 221
 222         if(this.health <= 0)
 223                 WITH(entity, self, this, W_PrepareExplosionByDamage(attacker, W_Seeker_Missile_Explode));
 224 }
 225
 226 /*
 227 void W_Seeker_Missile_Animate()
 228 {
 229         self.frame = self.frame +1;
 230         self.nextthink = time + 0.05;
 231
 232         if(self.enemy != world)
 233                 if(self.enemy.takedamage != DAMAGE_AIM || IS_DEAD(self.enemy))
 234                         self.enemy = world;
 235
 236         if(self.frame == 5)
 237         {
 238                 self.think           = W_Seeker_Missile_Think;
 239                 self.nextthink       = time;// + cvar("g_balance_seeker_missile_activate_delay"); // cant dealy with csqc projectiles
 240
 241                 if(autocvar_g_balance_seeker_missile_proxy)
 242                         self.movetype    = MOVETYPE_BOUNCEMISSILE;
 243                 else
 244                         self.movetype    = MOVETYPE_FLYMISSILE;
 245         }
 246
 247         UpdateCSQCProjectile(self);
 248 }
 249 */
 250
 251 void W_Seeker_Fire_Missile(Weapon thiswep, vector f_diff, entity m_target)
 252 {SELFPARAM();
 253         entity missile;
 254
 255         W_DecreaseAmmo(thiswep, self, WEP_CVAR(seeker, missile_ammo));
 256
 257         makevectors(self.v_angle);
 258         W_SetupShot_ProjectileSize(self, '-2 -2 -2', '2 2 2', false, 2, SND(SEEKER_FIRE), CH_WEAPON_A, 0);
 259         w_shotorg += f_diff;
 260         Send_Effect(EFFECT_SEEKER_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 261
 262         //self.detornator         = false;
 263
 264         missile                 = new(seeker_missile);
 265         missile.owner           = missile.realowner = self;
 266         missile.bot_dodge       = true;
 267         missile.bot_dodgerating = WEP_CVAR(seeker, missile_damage);
 268
 269         missile.think           = W_Seeker_Missile_Think;
 270         missile.touch           = W_Seeker_Missile_Touch;
 271         missile.event_damage    = W_Seeker_Missile_Damage;
 272         missile.nextthink       = time;// + 0.2;// + cvar("g_balance_seeker_missile_activate_delay");
 273         missile.cnt             = time + WEP_CVAR(seeker, missile_lifetime);
 274         missile.enemy           = m_target;
 275         missile.solid           = SOLID_BBOX;
 276         missile.scale           = 2;
 277         missile.takedamage      = DAMAGE_YES;
 278         missile.health          = WEP_CVAR(seeker, missile_health);
 279         missile.damageforcescale = WEP_CVAR(seeker, missile_damageforcescale);
 280         missile.damagedbycontents = true;
 281         //missile.think           = W_Seeker_Missile_Animate; // csqc projectiles.
 282
 283         if(missile.enemy != world)
 284                 missile.projectiledeathtype = WEP_SEEKER.m_id | HITTYPE_SECONDARY;
 285         else
 286                 missile.projectiledeathtype = WEP_SEEKER.m_id;
 287
 288
 289         setorigin(missile, w_shotorg);
 290         setsize(missile, '-4 -4 -4', '4 4 4');
 291         missile.movetype    = MOVETYPE_FLYMISSILE;
 292         missile.flags       = FL_PROJECTILE;
 293         missile.missile_flags = MIF_SPLASH | MIF_GUIDED_TAG;
 294
 295         W_SetupProjVelocity_UP_PRE(missile, seeker, missile_);
 296
 297         missile.angles = vectoangles(missile.velocity);
 298
 299         CSQCProjectile(missile, false, PROJECTILE_SEEKER, true);
 300
 301         MUTATOR_CALLHOOK(EditProjectile, self, missile);
 302 }
 303
 304 // ============================
 305 // Begin: FLAC, close range attack meant for defeating rockets which are coming at you.
 306 // ============================
 307 void W_Seeker_Flac_Explode()
 308 {SELFPARAM();
 309         self.event_damage = func_null;
 310
 311         RadiusDamage(self, self.realowner, WEP_CVAR(seeker, flac_damage), WEP_CVAR(seeker, flac_edgedamage), WEP_CVAR(seeker, flac_radius), world, world, WEP_CVAR(seeker, flac_force), self.projectiledeathtype, other);
 312
 313         remove(self);
 314 }
 315
 316 void W_Seeker_Flac_Touch()
 317 {
 318         PROJECTILE_TOUCH;
 319
 320         W_Seeker_Flac_Explode();
 321 }
 322
 323 void W_Seeker_Fire_Flac(Weapon thiswep)
 324 {SELFPARAM();
 325         entity missile;
 326         vector f_diff;
 327         float c;
 328
 329         W_DecreaseAmmo(thiswep, self, WEP_CVAR(seeker, flac_ammo));
 330
 331         c = self.bulletcounter % 4;
 332         switch(c)
 333         {
 334                 case 0:
 335                         f_diff = '-1.25 -3.75 0';
 336                         break;
 337                 case 1:
 338                         f_diff = '+1.25 -3.75 0';
 339                         break;
 340                 case 2:
 341                         f_diff = '-1.25 +3.75 0';
 342                         break;
 343                 case 3:
 344                 default:
 345                         f_diff = '+1.25 +3.75 0';
 346                         break;
 347         }
 348         W_SetupShot_ProjectileSize(self, '-2 -2 -2', '2 2 2', false, 2, SND(FLAC_FIRE), CH_WEAPON_A, WEP_CVAR(seeker, flac_damage));
 349         w_shotorg += f_diff;
 350
 351         Send_Effect(EFFECT_HAGAR_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 352
 353         missile                                 = new(missile);
 354         missile.owner                   = missile.realowner = self;
 355         missile.bot_dodge               = true;
 356         missile.bot_dodgerating = WEP_CVAR(seeker, flac_damage);
 357         missile.touch                   = W_Seeker_Flac_Explode;
 358         missile.use                     = W_Seeker_Flac_Explode;
 359         missile.think                   = adaptor_think2use_hittype_splash;
 360         missile.nextthink               = time + WEP_CVAR(seeker, flac_lifetime) + WEP_CVAR(seeker, flac_lifetime_rand);
 361         missile.solid                   = SOLID_BBOX;
 362         missile.movetype                = MOVETYPE_FLY;
 363         missile.projectiledeathtype = WEP_SEEKER.m_id;
 364         missile.projectiledeathtype = WEP_SEEKER.m_id | HITTYPE_SECONDARY;
 365         missile.flags                           = FL_PROJECTILE;
 366         missile.missile_flags       = MIF_SPLASH;
 367
 368         // csqc projectiles
 369         //missile.angles                                = vectoangles(missile.velocity);
 370         //missile.scale = 0.4; // BUG: the model is too big
 371
 372         setorigin(missile, w_shotorg);
 373         setsize(missile, '-2 -2 -2', '2 2 2');
 374
 375         W_SetupProjVelocity_UP_PRE(missile, seeker, flac_);
 376         CSQCProjectile(missile, true, PROJECTILE_FLAC, true);
 377
 378         MUTATOR_CALLHOOK(EditProjectile, self, missile);
 379 }
 380
 381 // ============================
 382 // Begin: Tag and rocket controllers
 383 // ============================
 384 entity W_Seeker_Tagged_Info(entity isowner, entity istarget)
 385 {
 386         entity tag;
 387         for(tag = world; (tag = find(tag, classname, "tag_tracker")); )
 388                 if((tag.realowner == isowner) && (tag.tag_target == istarget))
 389                         return tag;
 390
 391         return world;
 392 }
 393
 394 void W_Seeker_Attack()
 395 {SELFPARAM();
 396         entity tracker, closest_target;
 397
 398         closest_target = world;
 399         for(tracker = world; (tracker = find(tracker, classname, "tag_tracker")); ) if (tracker.realowner == self)
 400         {
 401                 if(closest_target)
 402                 {
 403                         if(vlen2(self.origin - tracker.tag_target.origin) < vlen2(self.origin - closest_target.origin))
 404                                 closest_target = tracker.tag_target;
 405                 }
 406                 else
 407                         closest_target = tracker.tag_target;
 408         }
 409
 410         traceline(self.origin + self.view_ofs, closest_target.origin, MOVE_NOMONSTERS, self);
 411         if((!closest_target) || ((trace_fraction < 1) && (trace_ent != closest_target)))
 412                 closest_target = world;
 413
 414         W_Seeker_Fire_Missile(WEP_SEEKER, '0 0 0', closest_target);
 415 }
 416
 417 void W_Seeker_Vollycontroller_Think() // TODO: Merge this with W_Seeker_Attack
 418 {SELFPARAM();
 419         float c;
 420         entity oldenemy;
 421         self.cnt = self.cnt - 1;
 422
 423         Weapon thiswep = WEP_SEEKER;
 424         if((!(self.realowner.items & IT_UNLIMITED_AMMO) && self.realowner.(thiswep.ammo_field) < WEP_CVAR(seeker, missile_ammo)) || (self.cnt <= -1) || (IS_DEAD(self.realowner)) || (PS(self.realowner).m_switchweapon != WEP_SEEKER))
 425         {
 426                 remove(self);
 427                 return;
 428         }
 429
 430         self.nextthink = time + WEP_CVAR(seeker, missile_delay) * W_WeaponRateFactor();
 431
 432         setself(self.realowner);
 433
 434         oldenemy = self.enemy;
 435         self.enemy = this.enemy;
 436
 437         c = self.cnt % 4;
 438         switch(c)
 439         {
 440                 case 0:
 441                         W_Seeker_Fire_Missile(WEP_SEEKER, '-1.25 -3.75 0', self.enemy);
 442                         break;
 443                 case 1:
 444                         W_Seeker_Fire_Missile(WEP_SEEKER, '+1.25 -3.75 0', self.enemy);
 445                         break;
 446                 case 2:
 447                         W_Seeker_Fire_Missile(WEP_SEEKER, '-1.25 +3.75 0', self.enemy);
 448                         break;
 449                 case 3:
 450                 default:
 451                         W_Seeker_Fire_Missile(WEP_SEEKER, '+1.25 +3.75 0', self.enemy);
 452                         break;
 453         }
 454
 455         self.enemy = oldenemy;
 456         setself(this);
 457 }
 458
 459 void W_Seeker_Tracker_Think()
 460 {SELFPARAM();
 461         // commit suicide if: You die OR target dies OR you switch away from the seeker OR commit suicide if lifetime is up
 462         if((IS_DEAD(self.realowner)) || (IS_DEAD(self.tag_target)) || (PS(self.realowner).m_switchweapon != WEP_SEEKER)
 463         || (time > self.tag_time + WEP_CVAR(seeker, tag_tracker_lifetime)))
 464         {
 465                 if(self)
 466                 {
 467                         WaypointSprite_Kill(self.tag_target.wps_tag_tracker);
 468                         remove(self);
 469                 }
 470                 return;
 471         }
 472
 473         // Update the think method information
 474         self.nextthink = time;
 475 }
 476
 477 // ============================
 478 // Begin: Tag projectile
 479 // ============================
 480 void W_Seeker_Tag_Explode(entity this)
 481 {
 482         //if(other==this.realowner)
 483         //    return;
 484         Damage_DamageInfo(this.origin, 0, 0, 0, this.velocity, WEP_SEEKER.m_id | HITTYPE_BOUNCE, other.species, this);
 485
 486         remove(this);
 487 }
 488
 489 void W_Seeker_Tag_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 490 {
 491         if(this.health <= 0)
 492                 return;
 493         this.health = this.health - damage;
 494         if(this.health <= 0)
 495                 W_Seeker_Tag_Explode(this);
 496 }
 497
 498 void W_Seeker_Tag_Touch()
 499 {SELFPARAM();
 500         vector dir;
 501         vector org2;
 502         entity e;
 503
 504         PROJECTILE_TOUCH;
 505
 506         dir     = normalize(self.realowner.origin - self.origin);
 507         org2    = findbetterlocation(self.origin, 8);
 508
 509         te_knightspike(org2);
 510
 511         self.event_damage = func_null;
 512         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER.m_id | HITTYPE_BOUNCE | HITTYPE_SECONDARY, other.species, self);
 513
 514         if(other.takedamage == DAMAGE_AIM && !IS_DEAD(other))
 515         {
 516                 // check to see if this person is already tagged by me
 517                 entity tag = W_Seeker_Tagged_Info(self.realowner, other);
 518
 519                 if(tag != world)
 520                 {
 521                         if(other.wps_tag_tracker && (WEP_CVAR(seeker, type) == 1)) // don't attach another waypointsprite without killing the old one first
 522                                 WaypointSprite_Kill(other.wps_tag_tracker);
 523
 524                         tag.tag_time = time;
 525                 }
 526                 else
 527                 {
 528                         //sprint(self.realowner, strcat("You just tagged ^2", other.netname, "^7 with a tracking device!\n"));
 529                         e             = new(tag_tracker);
 530                         e.cnt         = WEP_CVAR(seeker, missile_count);
 531                         e.owner       = self.owner;
 532                         e.realowner   = self.realowner;
 533
 534                         if(WEP_CVAR(seeker, type) == 1)
 535                         {
 536                                 e.tag_target  = other;
 537                                 e.tag_time    = time;
 538                                 e.think       = W_Seeker_Tracker_Think;
 539                         }
 540                         else
 541                         {
 542                                 e.enemy     = other;
 543                                 e.think     = W_Seeker_Vollycontroller_Think;
 544                         }
 545
 546                         e.nextthink   = time;
 547                 }
 548
 549                 if(WEP_CVAR(seeker, type) == 1)
 550                 {
 551                         WaypointSprite_Spawn(WP_Seeker, WEP_CVAR(seeker, tag_tracker_lifetime), 0, other, '0 0 64', self.realowner, 0, other, wps_tag_tracker, true, RADARICON_TAGGED);
 552                         WaypointSprite_UpdateRule(other.wps_tag_tracker, 0, SPRITERULE_DEFAULT);
 553                 }
 554         }
 555
 556         remove(self);
 557         return;
 558 }
 559
 560 void W_Seeker_Fire_Tag(Weapon thiswep)
 561 {SELFPARAM();
 562         entity missile;
 563         W_DecreaseAmmo(thiswep, self, WEP_CVAR(seeker, tag_ammo));
 564
 565         W_SetupShot_ProjectileSize(self, '-2 -2 -2', '2 2 2', false, 2, SND(TAG_FIRE), CH_WEAPON_A, WEP_CVAR(seeker, missile_damage) * WEP_CVAR(seeker, missile_count));
 566
 567         missile                 = new(seeker_tag);
 568         missile.owner           = missile.realowner = self;
 569         missile.bot_dodge       = true;
 570         missile.bot_dodgerating = 50;
 571         missile.touch           = W_Seeker_Tag_Touch;
 572         missile.think           = SUB_Remove_self;
 573         missile.nextthink       = time + WEP_CVAR(seeker, tag_lifetime);
 574         missile.movetype        = MOVETYPE_FLY;
 575         missile.solid           = SOLID_BBOX;
 576
 577         missile.takedamage       = DAMAGE_YES;
 578         missile.event_damage     = W_Seeker_Tag_Damage;
 579         missile.health           = WEP_CVAR(seeker, tag_health);
 580         missile.damageforcescale = WEP_CVAR(seeker, tag_damageforcescale);
 581
 582         setorigin(missile, w_shotorg);
 583         setsize(missile, '-2 -2 -2', '2 2 2');
 584
 585         missile.flags       = FL_PROJECTILE;
 586         //missile.missile_flags = MIF_..?;
 587
 588         missile.movetype    = MOVETYPE_FLY;
 589         W_SetupProjVelocity_PRE(missile, seeker, tag_);
 590         missile.angles = vectoangles(missile.velocity);
 591
 592         CSQCProjectile(missile, true, PROJECTILE_TAG, false); // has sound
 593
 594         MUTATOR_CALLHOOK(EditProjectile, self, missile);
 595 }
 596
 597 // ============================
 598 // Begin: Genereal weapon functions
 599 // ============================
 600
 601 METHOD(Seeker, wr_aim, void(entity thiswep))
 602 {
 603     if(WEP_CVAR(seeker, type) == 1)
 604         if(W_Seeker_Tagged_Info(self, self.enemy) != world)
 605             PHYS_INPUT_BUTTON_ATCK(self) = bot_aim(WEP_CVAR(seeker, missile_speed_max), 0, WEP_CVAR(seeker, missile_lifetime), false);
 606         else
 607             PHYS_INPUT_BUTTON_ATCK2(self) = bot_aim(WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), false);
 608     else
 609         PHYS_INPUT_BUTTON_ATCK(self) = bot_aim(WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), false);
 610 }
 611 METHOD(Seeker, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 612 {
 613     if(autocvar_g_balance_seeker_reload_ammo && actor.clip_load < min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo))) { // forced reload
 614         thiswep.wr_reload(thiswep, actor, weaponentity);
 615     } else if(fire & 1)
 616     {
 617         if(WEP_CVAR(seeker, type) == 1)
 618         {
 619             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, missile_refire)))
 620             {
 621                 W_Seeker_Attack();
 622                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, missile_animtime), w_ready);
 623             }
 624         }
 625         else
 626         {
 627             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, tag_refire)))
 628             {
 629                 W_Seeker_Fire_Tag(thiswep);
 630                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 631             }
 632         }
 633     }
 634
 635     else if(fire & 2)
 636     {
 637         if(WEP_CVAR(seeker, type) == 1)
 638         {
 639             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, tag_refire)))
 640             {
 641                 W_Seeker_Fire_Tag(thiswep);
 642                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 643             }
 644         }
 645         else
 646         {
 647             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, flac_refire)))
 648             {
 649                 W_Seeker_Fire_Flac(thiswep);
 650                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, flac_animtime), w_ready);
 651             }
 652         }
 653     }
 654 }
 655 METHOD(Seeker, wr_checkammo1, bool(entity thiswep))
 656 {
 657     float ammo_amount;
 658     if(WEP_CVAR(seeker, type) == 1)
 659     {
 660         ammo_amount = self.(thiswep.ammo_field) >= WEP_CVAR(seeker, missile_ammo);
 661         ammo_amount += self.(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, missile_ammo);
 662     }
 663     else
 664     {
 665         ammo_amount = self.(thiswep.ammo_field) >= WEP_CVAR(seeker, tag_ammo);
 666         ammo_amount += self.(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, tag_ammo);
 667     }
 668     return ammo_amount;
 669 }
 670 METHOD(Seeker, wr_checkammo2, bool(entity thiswep))
 671 {
 672     float ammo_amount;
 673     if(WEP_CVAR(seeker, type) == 1)
 674     {
 675         ammo_amount = self.(thiswep.ammo_field) >= WEP_CVAR(seeker, tag_ammo);
 676         ammo_amount += self.(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, tag_ammo);
 677     }
 678     else
 679     {
 680         ammo_amount = self.(thiswep.ammo_field) >= WEP_CVAR(seeker, flac_ammo);
 681         ammo_amount += self.(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, flac_ammo);
 682     }
 683     return ammo_amount;
 684 }
 685 METHOD(Seeker, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 686 {
 687     W_Reload(self, min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo)), SND(RELOAD));
 688 }
 689 METHOD(Seeker, wr_suicidemessage, Notification(entity thiswep))
 690 {
 691     return WEAPON_SEEKER_SUICIDE;
 692 }
 693 METHOD(Seeker, wr_killmessage, Notification(entity thiswep))
 694 {
 695     if(w_deathtype & HITTYPE_SECONDARY)
 696         return WEAPON_SEEKER_MURDER_TAG;
 697     else
 698         return WEAPON_SEEKER_MURDER_SPRAY;
 699 }
 700
 701 #endif
 702 #ifdef CSQC
 703
 704 METHOD(Seeker, wr_impacteffect, void(entity thiswep))
 705 {
 706     vector org2;
 707     org2 = w_org + w_backoff * 6;
 708     if(w_deathtype & HITTYPE_BOUNCE)
 709     {
 710         if(w_deathtype & HITTYPE_SECONDARY)
 711         {
 712             if(!w_issilent)
 713                 sound(self, CH_SHOTS, SND_TAG_IMPACT, 1, ATTEN_NORM);
 714         }
 715         else
 716         {
 717             pointparticles(EFFECT_HAGAR_EXPLODE, org2, '0 0 0', 1);
 718             if(!w_issilent)
 719             {
 720                 if(w_random<0.15)
 721                     sound(self, CH_SHOTS, SND_TAGEXP1, 1, ATTEN_NORM);
 722                 else if(w_random<0.7)
 723                     sound(self, CH_SHOTS, SND_TAGEXP2, 1, ATTEN_NORM);
 724                 else
 725                     sound(self, CH_SHOTS, SND_TAGEXP3, 1, ATTEN_NORM);
 726             }
 727         }
 728     }
 729     else
 730     {
 731         pointparticles(EFFECT_HAGAR_EXPLODE, org2, '0 0 0', 1);
 732         if(!w_issilent)
 733         {
 734             if(w_random<0.15)
 735                 sound(self, CH_SHOTS, SND_SEEKEREXP1, 1, ATTEN_NORM);
 736             else if(w_random<0.7)
 737                 sound(self, CH_SHOTS, SND_SEEKEREXP2, 1, ATTEN_NORM);
 738             else
 739                 sound(self, CH_SHOTS, SND_SEEKEREXP3, 1, ATTEN_NORM);
 740         }
 741     }
 742 }
 743
 744 #endif
 745 #endif