qcsrc/common/weapons/w_vaporizer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ VAPORIZER,
   4 /* function */ w_vaporizer,
   5 /* ammotype */ ammo_cells,
   6 /* impulse  */ 7,
   7 /* flags    */ WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_FLAG_SUPERWEAPON | WEP_TYPE_HITSCAN,
   8 /* rating   */ BOT_PICKUP_RATING_HIGH,
   9 /* color        */ '0.5 1 1',
  10 /* model    */ "minstanex",
  11 /* netname  */ "minstanex",
  12 /* fullname */ _("Vaporizer")
  13 );
  14
  15 #define VAPORIZER_SETTINGS(w_cvar,w_prop) VAPORIZER_SETTINGS_LIST(w_cvar, w_prop, VAPORIZER, vaporizer)
  16 #define VAPORIZER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  17         w_cvar(id, sn, PRI, ammo) \
  18         w_cvar(id, sn, PRI, animtime) \
  19         w_cvar(id, sn, PRI, refire) \
  20         w_cvar(id, sn, SEC, ammo) \
  21         w_cvar(id, sn, SEC, animtime) \
  22         w_cvar(id, sn, SEC, damage) \
  23         w_cvar(id, sn, SEC, delay) \
  24         w_cvar(id, sn, SEC, edgedamage) \
  25         w_cvar(id, sn, SEC, force) \
  26         w_cvar(id, sn, SEC, lifetime) \
  27         w_cvar(id, sn, SEC, radius) \
  28         w_cvar(id, sn, SEC, refire) \
  29         w_cvar(id, sn, SEC, shotangle) \
  30         w_cvar(id, sn, SEC, speed) \
  31         w_cvar(id, sn, SEC, spread) \
  32         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  33         w_prop(id, sn, float,  reloading_time, reload_time) \
  34         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  35         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  36         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  37         w_prop(id, sn, float,  weaponstart, weaponstart) \
  38         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  39
  40 #ifdef SVQC
  41 VAPORIZER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  42 .float vaporizer_lasthit;
  43 .float jump_interval;
  44 #endif
  45 #else
  46 #ifdef SVQC
  47 void spawnfunc_weapon_vaporizer (void) { weapon_defaultspawnfunc(WEP_VAPORIZER); }
  48
  49 void W_Vaporizer_Attack (void)
  50 {
  51         float flying;
  52         flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
  53
  54         W_SetupShot (self, TRUE, 0, "weapons/minstanexfire.wav", CH_WEAPON_A, 10000);
  55
  56         yoda = 0;
  57         damage_goodhits = 0;
  58         FireRailgunBullet (w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, 10000, 800, 0, 0, 0, 0, WEP_VAPORIZER);
  59
  60         if(yoda && flying)
  61                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_YODA);
  62         if(damage_goodhits && self.vaporizer_lasthit)
  63         {
  64                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_IMPRESSIVE);
  65                 damage_goodhits = 0; // only every second time
  66         }
  67
  68         self.vaporizer_lasthit = damage_goodhits;
  69
  70         pointparticles(particleeffectnum("nex_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  71
  72         // teamcolor / hit beam effect
  73         vector v;
  74         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  75         switch(self.team)
  76         {
  77                 case NUM_TEAM_1:   // Red
  78                         if(damage_goodhits)
  79                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3RED_HIT"), w_shotorg, v);
  80                         else
  81                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3RED"), w_shotorg, v);
  82                         break;
  83                 case NUM_TEAM_2:   // Blue
  84                         if(damage_goodhits)
  85                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3BLUE_HIT"), w_shotorg, v);
  86                         else
  87                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3BLUE"), w_shotorg, v);
  88                         break;
  89                 case NUM_TEAM_3:   // Yellow
  90                         if(damage_goodhits)
  91                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3YELLOW_HIT"), w_shotorg, v);
  92                         else
  93                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3YELLOW"), w_shotorg, v);
  94                         break;
  95                 case NUM_TEAM_4:   // Pink
  96                         if(damage_goodhits)
  97                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3PINK_HIT"), w_shotorg, v);
  98                         else
  99                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3PINK"), w_shotorg, v);
 100                         break;
 101                 default:
 102                         if(damage_goodhits)
 103                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3_HIT"), w_shotorg, v);
 104                         else
 105                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3"), w_shotorg, v);
 106                         break;
 107         }
 108
 109         W_DecreaseAmmo(((g_minstagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo)));
 110 }
 111
 112 float w_vaporizer(float req)
 113 {
 114         float ammo_amount;
 115         float vaporizer_ammo;
 116
 117         // now multiple WR_s use this
 118         vaporizer_ammo = ((g_minstagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo));
 119
 120         switch(req)
 121         {
 122                 case WR_AIM:
 123                 {
 124                         if(self.AMMO_VAL(WEP_VAPORIZER) > 0)
 125                                 self.BUTTON_ATCK = bot_aim(1000000, 0, 1, FALSE);
 126                         else
 127                                 self.BUTTON_ATCK2 = bot_aim(WEP_CVAR_SEC(vaporizer, speed), 0, WEP_CVAR_SEC(vaporizer, lifetime), FALSE); // WEAPONTODO: replace with proper vaporizer cvars
 128
 129                         return TRUE;
 130                 }
 131                 case WR_THINK:
 132                 {
 133                         // if the laser uses load, we also consider its ammo for reloading
 134                         if(WEP_CVAR(vaporizer, reload_ammo) && WEP_CVAR_SEC(vaporizer, ammo) && self.clip_load < min(vaporizer_ammo, WEP_CVAR_SEC(vaporizer, ammo))) // forced reload
 135                                 WEP_ACTION(self.weapon, WR_RELOAD);
 136                         else if(WEP_CVAR(vaporizer, reload_ammo) && self.clip_load < vaporizer_ammo) // forced reload
 137                                 WEP_ACTION(self.weapon, WR_RELOAD);
 138                         else if (self.BUTTON_ATCK)
 139                         {
 140                                 if (weapon_prepareattack(0, WEP_CVAR_PRI(vaporizer, refire)))
 141                                 {
 142                                         W_Vaporizer_Attack();
 143                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(vaporizer, animtime), w_ready);
 144                                 }
 145                         }
 146                         else if (self.BUTTON_ATCK2)
 147                         {
 148                                 if (self.jump_interval <= time)
 149                                 if (weapon_prepareattack(1, -1))
 150                                 {
 151                                         // handle refire manually, so that primary and secondary can be fired without conflictions (important for minstagib)
 152                                         self.jump_interval = time + WEP_CVAR_SEC(vaporizer, refire) * W_WeaponRateFactor();
 153
 154                                         // decrease ammo for the laser?
 155                                         if(WEP_CVAR_SEC(vaporizer, ammo))
 156                                                 W_DecreaseAmmo(WEP_CVAR_SEC(vaporizer, ammo));
 157
 158                                         // ugly minstagib hack to reuse the fire mode of the laser
 159                                         float w;
 160                                         w = self.weapon;
 161                                         self.weapon = WEP_BLASTER;
 162                                         W_Blaster_Attack(
 163                                                 WEP_CVAR_SEC(vaporizer, shotangle),
 164                                                 WEP_CVAR_SEC(vaporizer, damage),
 165                                                 WEP_CVAR_SEC(vaporizer, edgedamage),
 166                                                 WEP_CVAR_SEC(vaporizer, radius),
 167                                                 WEP_CVAR_SEC(vaporizer, force),
 168                                                 WEP_CVAR_SEC(vaporizer, speed),
 169                                                 WEP_CVAR_SEC(vaporizer, spread),
 170                                                 WEP_CVAR_SEC(vaporizer, delay),
 171                                                 WEP_CVAR_SEC(vaporizer, lifetime)
 172                                         );
 173                                         self.weapon = w;
 174
 175                                         // now do normal refire
 176                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(vaporizer, animtime), w_ready);
 177                                 }
 178                         }
 179
 180                         return TRUE;
 181                 }
 182                 case WR_INIT:
 183                 {
 184                         precache_model("models/nexflash.md3");
 185                         precache_model("models/weapons/g_minstanex.md3");
 186                         precache_model("models/weapons/v_minstanex.md3");
 187                         precache_model("models/weapons/h_minstanex.iqm");
 188                         precache_sound("weapons/minstanexfire.wav");
 189                         precache_sound("weapons/nexwhoosh1.wav");
 190                         precache_sound("weapons/nexwhoosh2.wav");
 191                         precache_sound("weapons/nexwhoosh3.wav");
 192                         //W_Blaster(WR_INIT); // Samual: Is this really the proper thing to do? Didn't we already run this previously?
 193                         VAPORIZER_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 194                         return TRUE;
 195                 }
 196                 case WR_SETUP:
 197                 {
 198                         self.current_ammo = AMMO_VAL(WEP_VAPORIZER);
 199                         self.vaporizer_lasthit = 0;
 200                         return TRUE;
 201                 }
 202                 case WR_CHECKAMMO1:
 203                 {
 204                         ammo_amount = self.AMMO_VAL(WEP_VAPORIZER) >= vaporizer_ammo;
 205                         ammo_amount += self.(weapon_load[WEP_VAPORIZER]) >= vaporizer_ammo;
 206                         return ammo_amount;
 207                 }
 208                 case WR_CHECKAMMO2:
 209                 {
 210                         if(!WEP_CVAR_SEC(vaporizer, ammo))
 211                                 return TRUE;
 212                         ammo_amount = self.AMMO_VAL(WEP_VAPORIZER) >= WEP_CVAR_SEC(vaporizer, ammo);
 213                         ammo_amount += self.(weapon_load[WEP_VAPORIZER]) >= WEP_CVAR_SEC(vaporizer, ammo);
 214                         return ammo_amount;
 215                 }
 216                 case WR_CONFIG:
 217                 {
 218                         VAPORIZER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 219                         return TRUE;
 220                 }
 221                 case WR_RESETPLAYER:
 222                 {
 223                         self.vaporizer_lasthit = 0;
 224                         return TRUE;
 225                 }
 226                 case WR_RELOAD:
 227                 {
 228                         float used_ammo;
 229                         if(WEP_CVAR_SEC(vaporizer, ammo))
 230                                 used_ammo = min(vaporizer_ammo, WEP_CVAR_SEC(vaporizer, ammo));
 231                         else
 232                                 used_ammo = vaporizer_ammo;
 233
 234                         W_Reload(used_ammo, "weapons/reload.wav");
 235                         return TRUE;
 236                 }
 237                 case WR_SUICIDEMESSAGE:
 238                 {
 239                         return WEAPON_THINKING_WITH_PORTALS;
 240                 }
 241                 case WR_KILLMESSAGE:
 242                 {
 243                         return WEAPON_VAPORIZER_MURDER;
 244                 }
 245         }
 246         return TRUE;
 247 }
 248 #endif
 249 #ifdef CSQC
 250 float w_vaporizer(float req)
 251 {
 252         switch(req)
 253         {
 254                 case WR_IMPACTEFFECT:
 255                 {
 256                         vector org2;
 257                         org2 = w_org + w_backoff * 6;
 258                         pointparticles(particleeffectnum("nex_impact"), org2, '0 0 0', 1);
 259                         if(!w_issilent)
 260                                 sound(self, CH_SHOTS, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM);
 261
 262                         return TRUE;
 263                 }
 264                 case WR_INIT:
 265                 {
 266                         precache_sound("weapons/neximpact.wav");
 267                         return TRUE;
 268                 }
 269         }
 270         return TRUE;
 271 }
 272 #endif
 273 #endif