qcsrc/common/weapons/w_electro.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ ELECTRO,
   4 /* function */ W_Electro,
   5 /* ammotype */ IT_CELLS,
   6 /* impulse  */ 5,
   7 /* flags    */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating   */ BOT_PICKUP_RATING_MID,
   9 /* model    */ "electro",
  10 /* netname  */ "electro",
  11 /* fullname */ _("Electro")
  12 );
  13
  14 #define ELECTRO_SETTINGS(w_cvar,w_prop) \
  15         w_cvar(WEP_ELECTRO, electro, MO_BOTH, ammo) \
  16         w_cvar(WEP_ELECTRO, electro, MO_BOTH, animtime) \
  17         w_cvar(WEP_ELECTRO, electro, MO_BOTH, damage) \
  18         w_cvar(WEP_ELECTRO, electro, MO_BOTH, edgedamage) \
  19         w_cvar(WEP_ELECTRO, electro, MO_BOTH, force) \
  20         w_cvar(WEP_ELECTRO, electro, MO_BOTH, radius) \
  21         w_cvar(WEP_ELECTRO, electro, MO_BOTH, refire) \
  22         w_cvar(WEP_ELECTRO, electro, MO_BOTH, speed) \
  23         w_cvar(WEP_ELECTRO, electro, MO_BOTH, spread) \
  24         w_cvar(WEP_ELECTRO, electro, MO_BOTH, lifetime) \
  25         w_cvar(WEP_ELECTRO, electro, MO_PRI,  comboradius) \
  26         w_cvar(WEP_ELECTRO, electro, MO_PRI,  midaircombo_interval) \
  27         w_cvar(WEP_ELECTRO, electro, MO_SEC,  bouncefactor) \
  28         w_cvar(WEP_ELECTRO, electro, MO_SEC,  bouncestop) \
  29         w_cvar(WEP_ELECTRO, electro, MO_SEC,  count) \
  30         w_cvar(WEP_ELECTRO, electro, MO_SEC,  damageforcescale) \
  31         w_cvar(WEP_ELECTRO, electro, MO_SEC,  damagedbycontents) \
  32         w_cvar(WEP_ELECTRO, electro, MO_SEC,  health) \
  33         w_cvar(WEP_ELECTRO, electro, MO_SEC,  refire2) \
  34         w_cvar(WEP_ELECTRO, electro, MO_SEC,  speed_up) \
  35         w_cvar(WEP_ELECTRO, electro, MO_SEC,  speed_z) \
  36         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_comboradius) \
  37         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_comboradius_thruwall) \
  38         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_damage) \
  39         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_edgedamage) \
  40         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_force) \
  41         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_radius) \
  42         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_speed) \
  43         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_safeammocheck) \
  44         w_prop(WEP_ELECTRO, electro, reloading_ammo, reload_ammo) \
  45         w_prop(WEP_ELECTRO, electro, reloading_time, reload_time) \
  46         w_prop(WEP_ELECTRO, electro, switchdelay_raise, switchdelay_raise) \
  47         w_prop(WEP_ELECTRO, electro, switchdelay_drop, switchdelay_drop)
  48
  49 #ifdef SVQC
  50 ELECTRO_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  51 .float electro_count;
  52 .float electro_secondarytime;
  53 void W_Plasma_Explode_Combo(void);
  54 #endif
  55 #else
  56 #ifdef SVQC
  57 void spawnfunc_weapon_electro() { weapon_defaultspawnfunc(WEP_ELECTRO); }
  58
  59 void W_Plasma_TriggerCombo(vector org, float rad, entity own)
  60 {
  61         entity e = WarpZone_FindRadius(org, rad, !WEP_CVAR(electro, combo_comboradius_thruwall));
  62         while(e)
  63         {
  64                 if(e.classname == "plasma")
  65                 {
  66                         // change owner to whoever caused the combo explosion
  67                         WarpZone_TraceLine(org, e.origin, MOVE_NOMONSTERS, e);
  68
  69                         if(
  70                                 (trace_fraction == 1)
  71                                 ||
  72                                 (WEP_CVAR(electro, combo_comboradius_thruwall) >= vlen(e.WarpZone_findradius_dist))
  73                         )
  74                         {
  75                                 e.realowner = own;
  76                                 e.takedamage = DAMAGE_NO;
  77                                 e.classname = "plasma_chain";
  78                                 e.think = W_Plasma_Explode_Combo;
  79                                 e.nextthink = time + vlen(e.WarpZone_findradius_dist) / WEP_CVAR(electro, combo_speed); // delay combo chains, looks cooler
  80                         }
  81                 }
  82                 e = e.chain;
  83         }
  84 }
  85
  86 void W_Plasma_Explode(void)
  87 {
  88         if(other.takedamage == DAMAGE_AIM)
  89                 if(IS_PLAYER(other))
  90                         if(DIFF_TEAM(self.realowner, other))
  91                                 if(other.deadflag == DEAD_NO)
  92                                         if(IsFlying(other))
  93                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_ELECTROBITCH);
  94
  95         self.event_damage = func_null;
  96         self.takedamage = DAMAGE_NO;
  97
  98         if(self.movetype == MOVETYPE_BOUNCE)
  99         {
 100                 RadiusDamage(
 101                         self,
 102                         self.realowner,
 103                         WEP_CVAR_SEC(electro, damage),
 104                         WEP_CVAR_SEC(electro, edgedamage),
 105                         WEP_CVAR_SEC(electro, radius),
 106                         world,
 107                         world,
 108                         WEP_CVAR_SEC(electro, force),
 109                         self.projectiledeathtype,
 110                         other
 111                 );
 112         }
 113         else
 114         {
 115                 W_Plasma_TriggerCombo(self.origin, WEP_CVAR_PRI(electro, comboradius), self.realowner);
 116                 RadiusDamage(
 117                         self,
 118                         self.realowner,
 119                         WEP_CVAR_PRI(electro, damage),
 120                         WEP_CVAR_PRI(electro, edgedamage),
 121                         WEP_CVAR_PRI(electro, radius),
 122                         world,
 123                         world,
 124                         WEP_CVAR_PRI(electro, force),
 125                         self.projectiledeathtype,
 126                         other
 127                 );
 128         }
 129
 130         remove(self);
 131 }
 132
 133 void W_Plasma_Explode_Combo(void)
 134 {
 135         W_Plasma_TriggerCombo(self.origin, WEP_CVAR(electro, combo_comboradius), self.realowner);
 136
 137         self.event_damage = func_null;
 138
 139         RadiusDamage(
 140                 self,
 141                 self.realowner,
 142                 WEP_CVAR(electro, combo_damage),
 143                 WEP_CVAR(electro, combo_edgedamage),
 144                 WEP_CVAR(electro, combo_radius),
 145                 world,
 146                 world,
 147                 WEP_CVAR(electro, combo_force),
 148                 WEP_ELECTRO | HITTYPE_BOUNCE, // use THIS type for a combo because primary can't bounce
 149                 world
 150         );
 151
 152         remove (self);
 153 }
 154
 155 void W_Plasma_Touch(void)
 156 {
 157         PROJECTILE_TOUCH;
 158         if(other.takedamage == DAMAGE_AIM)
 159                 { W_Plasma_Explode(); }
 160         else
 161         {
 162                 //UpdateCSQCProjectile(self);
 163                 spamsound(self, CH_SHOTS, "weapons/electro_bounce.wav", VOL_BASE, ATTEN_NORM);
 164                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 165         }
 166 }
 167
 168 void W_Plasma_TouchExplode(void)
 169 {
 170         PROJECTILE_TOUCH;
 171         W_Plasma_Explode();
 172 }
 173
 174 void W_Plasma_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 175 {
 176         if(self.health <= 0)
 177                 return;
 178
 179         // note: combos are usually triggered by W_Plasma_TriggerCombo, not damage
 180         float is_combo = (inflictor.classname == "plasma_chain" || inflictor.classname == "plasma_prim");
 181
 182         if(!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, (is_combo ? 1 : -1)))
 183                 return; // g_projectiles_damage says to halt
 184
 185         self.health = self.health - damage;
 186         if(self.health <= 0)
 187         {
 188                 self.takedamage = DAMAGE_NO;
 189                 self.nextthink = time;
 190                 if(is_combo)
 191                 {
 192                         // change owner to whoever caused the combo explosion
 193                         self.realowner = inflictor.realowner;
 194                         self.classname = "plasma_chain";
 195                         self.think = W_Plasma_Explode_Combo;
 196                         self.nextthink = time +
 197                                 (
 198                                         // bound the length, inflictor may be in a galaxy far far away (warpzones)
 199                                         min(
 200                                                 WEP_CVAR(electro, combo_radius),
 201                                                 vlen(self.origin - inflictor.origin)
 202                                         )
 203                                         /
 204                                         // delay combo chains, looks cooler
 205                                         WEP_CVAR(electro, combo_speed)
 206                                 );
 207                 }
 208                 else
 209                 {
 210                         self.use = W_Plasma_Explode;
 211                         self.think = adaptor_think2use; // not _hittype_splash, as this runs "immediately"
 212                 }
 213         }
 214 }
 215
 216 void W_Plasma_Think()
 217 {
 218         self.nextthink = time + WEP_CVAR_PRI(electro, midaircombo_interval);
 219
 220         if(time >= self.ltime)
 221         {
 222                 self.use();
 223                 return;
 224         }
 225
 226         W_Plasma_TriggerCombo(self.origin, WEP_CVAR_PRI(electro, comboradius), self.realowner);
 227 }
 228
 229 void W_Electro_Attack_Bolt(void)
 230 {
 231         entity proj;
 232
 233         W_DecreaseAmmo(ammo_cells, WEP_CVAR_PRI(electro, ammo), autocvar_g_balance_electro_reload_ammo);//weapontodo
 234
 235         W_SetupShot_ProjectileSize(self, '0 0 -3', '0 0 -3', FALSE, 2, "weapons/electro_fire.wav", CH_WEAPON_A, WEP_CVAR_PRI(electro, damage));
 236
 237         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 238
 239         proj = spawn ();
 240         proj.classname = "plasma_prim";
 241         proj.owner = proj.realowner = self;
 242         proj.bot_dodge = TRUE;
 243         proj.bot_dodgerating = WEP_CVAR_PRI(electro, damage);
 244         proj.use = W_Plasma_Explode;
 245         proj.think = W_Plasma_Think;
 246         proj.nextthink = time;
 247         proj.ltime = time + WEP_CVAR_PRI(electro, lifetime);
 248         PROJECTILE_MAKETRIGGER(proj);
 249         proj.projectiledeathtype = WEP_ELECTRO;
 250         setorigin(proj, w_shotorg);
 251
 252         proj.movetype = MOVETYPE_FLY;
 253         WEP_SETUPPROJVELOCITY_PRI(proj, electro);
 254         proj.angles = vectoangles(proj.velocity);
 255         proj.touch = W_Plasma_TouchExplode;
 256         setsize(proj, '0 0 -3', '0 0 -3');
 257         proj.flags = FL_PROJECTILE;
 258         proj.missile_flags = MIF_SPLASH;
 259
 260         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO_BEAM, TRUE);
 261
 262         other = proj; MUTATOR_CALLHOOK(EditProjectile);
 263 }
 264
 265 void W_Electro_Attack_Orbs(void)
 266 {
 267         W_DecreaseAmmo(ammo_cells, WEP_CVAR_SEC(electro, ammo), autocvar_g_balance_electro_reload_ammo);//weapontodo
 268
 269         W_SetupShot_ProjectileSize(self, '0 0 -4', '0 0 -4', FALSE, 2, "weapons/electro_fire2.wav", CH_WEAPON_A, WEP_CVAR_SEC(electro, damage));
 270
 271         w_shotdir = v_forward; // no TrueAim for grenades please
 272
 273         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 274
 275         entity proj = spawn();
 276         proj.classname = "plasma";
 277         proj.owner = proj.realowner = self;
 278         proj.use = W_Plasma_Explode;
 279         proj.think = adaptor_think2use_hittype_splash;
 280         proj.bot_dodge = TRUE;
 281         proj.bot_dodgerating = WEP_CVAR_SEC(electro, damage);
 282         proj.nextthink = time + WEP_CVAR_SEC(electro, lifetime);
 283         PROJECTILE_MAKETRIGGER(proj);
 284         proj.projectiledeathtype = WEP_ELECTRO | HITTYPE_SECONDARY;
 285         setorigin(proj, w_shotorg);
 286
 287         //proj.glow_size = 50;
 288         //proj.glow_color = 45;
 289         proj.movetype = MOVETYPE_BOUNCE;
 290         WEP_SETUPPROJVELOCITY_UP_SEC(proj, electro);
 291         proj.touch = W_Plasma_Touch;
 292         setsize(proj, '0 0 -4', '0 0 -4');
 293         proj.takedamage = DAMAGE_YES;
 294         proj.damageforcescale = WEP_CVAR_SEC(electro, damageforcescale);
 295         proj.health = WEP_CVAR_SEC(electro, health);
 296         proj.event_damage = W_Plasma_Damage;
 297         proj.flags = FL_PROJECTILE;
 298         proj.damagedbycontents = (WEP_CVAR_SEC(electro, damagedbycontents));
 299
 300         proj.bouncefactor = WEP_CVAR_SEC(electro, bouncefactor);
 301         proj.bouncestop = WEP_CVAR_SEC(electro, bouncestop);
 302         proj.missile_flags = MIF_SPLASH | MIF_ARC;
 303
 304 #if 0
 305         entity p2;
 306         p2 = spawn();
 307         copyentity(proj, p2);
 308         setmodel(p2, "models/ebomb.mdl");
 309         setsize(p2, proj.mins, proj.maxs);
 310 #endif
 311
 312         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO, FALSE); // no culling, it has sound
 313
 314         other = proj; MUTATOR_CALLHOOK(EditProjectile);
 315 }
 316
 317 void W_Electro_CheckAttack()
 318 {
 319         if(self.electro_count > 1)
 320         if(self.BUTTON_ATCK2)
 321         if(weapon_prepareattack(1, -1))
 322         {
 323                 W_Electro_Attack_Orbs();
 324                 self.electro_count -= 1;
 325                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(electro, animtime), W_Electro_CheckAttack);
 326                 return;
 327         }
 328         w_ready();
 329 }
 330
 331 .float bot_secondary_electromooth;
 332 float W_Electro(float req)
 333 {
 334         float ammo_amount;
 335         switch(req)
 336         {
 337                 case WR_AIM:
 338                 {
 339                         self.BUTTON_ATCK = self.BUTTON_ATCK2 = FALSE;
 340                         if(vlen(self.origin-self.enemy.origin) > 1000) { self.bot_secondary_electromooth = 0; }
 341                         if(self.bot_secondary_electromooth == 0)
 342                         {
 343                                 float shoot;
 344
 345                                 if(WEP_CVAR_PRI(electro, speed))
 346                                         shoot = bot_aim(WEP_CVAR_PRI(electro, speed), 0, WEP_CVAR_PRI(electro, lifetime), FALSE);
 347                                 else
 348                                         shoot = bot_aim(1000000, 0, 0.001, FALSE);
 349
 350                                 if(shoot)
 351                                 {
 352                                         self.BUTTON_ATCK = TRUE;
 353                                         if(random() < 0.01) self.bot_secondary_electromooth = 1;
 354                                 }
 355                         }
 356                         else
 357                         {
 358                                 if(bot_aim(WEP_CVAR_SEC(electro, speed), WEP_CVAR_SEC(electro, speed_up), WEP_CVAR_SEC(electro, lifetime), TRUE))
 359                                 {
 360                                         self.BUTTON_ATCK2 = TRUE;
 361                                         if(random() < 0.03) self.bot_secondary_electromooth = 0;
 362                                 }
 363                         }
 364
 365                         return TRUE;
 366                 }
 367                 case WR_THINK:
 368                 {
 369                         if(autocvar_g_balance_electro_reload_ammo) // forced reload // WEAPONTODO
 370                         {
 371                                 ammo_amount = 0;
 372                                 if(self.clip_load >= WEP_CVAR_PRI(electro, ammo))
 373                                         ammo_amount = 1;
 374                                 if(self.clip_load >= WEP_CVAR_SEC(electro, ammo))
 375                                         ammo_amount += 1;
 376
 377                                 if(!ammo_amount)
 378                                 {
 379                                         WEP_ACTION(self.weapon, WR_RELOAD);
 380                                         return FALSE;
 381                                 }
 382
 383                                 return TRUE;
 384                         }
 385
 386                         if(self.BUTTON_ATCK)
 387                         {
 388                                 if(weapon_prepareattack(0, WEP_CVAR_PRI(electro, refire)))
 389                                 {
 390                                                 W_Electro_Attack_Bolt();
 391                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(electro, animtime), w_ready);
 392                                 }
 393                         }
 394                         else if(self.BUTTON_ATCK2)
 395                         {
 396                                 if(time >= self.electro_secondarytime)
 397                                 if(weapon_prepareattack(1, WEP_CVAR_SEC(electro, refire)))
 398                                 {
 399                                         W_Electro_Attack_Orbs();
 400                                         self.electro_count = WEP_CVAR_SEC(electro, count);
 401                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(electro, animtime), W_Electro_CheckAttack);
 402                                         self.electro_secondarytime = time + WEP_CVAR_SEC(electro, refire2) * W_WeaponRateFactor();
 403                                 }
 404                         }
 405
 406                         return TRUE;
 407                 }
 408                 case WR_INIT:
 409                 {
 410                         precache_model("models/weapons/g_electro.md3");
 411                         precache_model("models/weapons/v_electro.md3");
 412                         precache_model("models/weapons/h_electro.iqm");
 413                         precache_sound("weapons/electro_bounce.wav");
 414                         precache_sound("weapons/electro_fire.wav");
 415                         precache_sound("weapons/electro_fire2.wav");
 416                         precache_sound("weapons/electro_impact.wav");
 417                         precache_sound("weapons/electro_impact_combo.wav");
 418                         ELECTRO_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 419                         return TRUE;
 420                 }
 421                 case WR_SETUP:
 422                 {
 423                         self.current_ammo = ammo_cells;
 424                         return TRUE;
 425                 }
 426                 case WR_CHECKAMMO1:
 427                 {
 428                         ammo_amount = self.ammo_cells >= WEP_CVAR_PRI(electro, ammo);
 429                         ammo_amount += self.(weapon_load[WEP_ELECTRO]) >= WEP_CVAR_PRI(electro, ammo);
 430                         return ammo_amount;
 431                 }
 432                 case WR_CHECKAMMO2:
 433                 {
 434                         if(WEP_CVAR(electro, combo_safeammocheck)) // true if you can fire at least one secondary blob AND one primary shot after it, otherwise false.
 435                         {
 436                                 ammo_amount = self.ammo_cells >= WEP_CVAR_SEC(electro, ammo) + WEP_CVAR_PRI(electro, ammo);
 437                                 ammo_amount += self.(weapon_load[WEP_ELECTRO]) >= WEP_CVAR_SEC(electro, ammo) + WEP_CVAR_PRI(electro, ammo);
 438                         }
 439                         else
 440                         {
 441                                 ammo_amount = self.ammo_cells >= WEP_CVAR_SEC(electro, ammo);
 442                                 ammo_amount += self.(weapon_load[WEP_ELECTRO]) >= WEP_CVAR_SEC(electro, ammo);
 443                         }
 444                         return ammo_amount;
 445                 }
 446                 case WR_CONFIG:
 447                 {
 448                         ELECTRO_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 449                         return TRUE;
 450                 }
 451                 case WR_RESETPLAYER:
 452                 {
 453                         self.electro_secondarytime = time;
 454                         return TRUE;
 455                 }
 456                 case WR_RELOAD:
 457                 {
 458                         W_Reload(min(WEP_CVAR_PRI(electro, ammo), WEP_CVAR_SEC(electro, ammo)), "weapons/reload.wav");
 459                         return TRUE;
 460                 }
 461                 case WR_SUICIDEMESSAGE:
 462                 {
 463                         if(w_deathtype & HITTYPE_SECONDARY)
 464                                 return WEAPON_ELECTRO_SUICIDE_ORBS;
 465                         else
 466                                 return WEAPON_ELECTRO_SUICIDE_BOLT;
 467                 }
 468                 case WR_KILLMESSAGE:
 469                 {
 470                         if(w_deathtype & HITTYPE_SECONDARY)
 471                         {
 472                                 return WEAPON_ELECTRO_MURDER_ORBS;
 473                         }
 474                         else
 475                         {
 476                                 if(w_deathtype & HITTYPE_BOUNCE)
 477                                         return WEAPON_ELECTRO_MURDER_COMBO;
 478                                 else
 479                                         return WEAPON_ELECTRO_MURDER_BOLT;
 480                         }
 481                 }
 482         }
 483         return TRUE;
 484 }
 485 #endif
 486 #ifdef CSQC
 487 float W_Electro(float req)
 488 {
 489         switch(req)
 490         {
 491                 case WR_IMPACTEFFECT:
 492                 {
 493                         vector org2;
 494                         org2 = w_org + w_backoff * 6;
 495                         if(w_deathtype & HITTYPE_SECONDARY)
 496                         {
 497                                 pointparticles(particleeffectnum("electro_ballexplode"), org2, '0 0 0', 1);
 498                                 if(!w_issilent)
 499                                         sound(self, CH_SHOTS, "weapons/electro_impact.wav", VOL_BASE, ATTEN_NORM);
 500                         }
 501                         else
 502                         {
 503                                 if(w_deathtype & HITTYPE_BOUNCE)
 504                                 {
 505                                         // this is sent as "primary (w_deathtype & HITTYPE_BOUNCE)" to distinguish it from (w_deathtype & HITTYPE_SECONDARY) bounced balls
 506                                         pointparticles(particleeffectnum("electro_combo"), org2, '0 0 0', 1);
 507                                         if(!w_issilent)
 508                                                 sound(self, CH_SHOTS, "weapons/electro_impact_combo.wav", VOL_BASE, ATTEN_NORM);
 509                                 }
 510                                 else
 511                                 {
 512                                         pointparticles(particleeffectnum("electro_impact"), org2, '0 0 0', 1);
 513                                         if(!w_issilent)
 514                                                 sound(self, CH_SHOTS, "weapons/electro_impact.wav", VOL_BASE, ATTEN_NORM);
 515                                 }
 516                         }
 517
 518                         return TRUE;
 519                 }
 520                 case WR_INIT:
 521                 {
 522                         precache_sound("weapons/electro_impact.wav");
 523                         precache_sound("weapons/electro_impact_combo.wav");
 524                         return TRUE;
 525                 }
 526         }
 527         return TRUE;
 528 }
 529 #endif
 530 #endif