qcsrc/common/weapons/all.qc

   1 #include "all.qh"
   2 #ifndef WEAPONS_ALL_C
   3 #define WEAPONS_ALL_C
   4
   5 #if defined(CSQC)
   6         #include <client/main.qh>
   7         #include <common/constants.qh>
   8         #include <common/deathtypes/all.qh>
   9         #include <common/physics/movetypes/movetypes.qh>
  10         #include <common/stats.qh>
  11         #include <common/util.qh>
  12         #include <common/weapons/calculations.qc>
  13         #include <common/weapons/weapon/_mod.inc>
  14         #include <lib/csqcmodel/cl_model.qh>
  15         #include <lib/csqcmodel/interpolate.qh>
  16         #include <lib/warpzone/anglestransform.qh>
  17         #include <lib/warpzone/client.qh>
  18         #include <lib/warpzone/common.qh>
  19 #elif defined(MENUQC)
  20         #include <common/weapons/weapon/_mod.inc>
  21 #elif defined(SVQC)
  22         #include <common/constants.qh>
  23         #include <common/deathtypes/all.qh>
  24         #include <common/items/_mod.qh>
  25         #include <common/mapinfo.qh>
  26         #include <common/monsters/_mod.qh>
  27         #include <common/notifications/all.qh>
  28         #include <common/stats.qh>
  29         #include <common/teams.qh>
  30         #include <common/util.qh>
  31         #include <common/weapons/calculations.qc>
  32         #include <common/weapons/config.qc>
  33         #include <common/weapons/config.qh>
  34         #include <common/weapons/weapon/_mod.inc>
  35         #include <lib/csqcmodel/sv_model.qh>
  36         #include <lib/warpzone/anglestransform.qh>
  37         #include <lib/warpzone/common.qh>
  38         #include <lib/warpzone/server.qh>
  39         #include <lib/warpzone/util_server.qh>
  40         #include <server/command/_mod.qh>
  41         #include <server/hook.qh>
  42         #include <server/items/spawning.qh>
  43         #include <server/mutators/_mod.qh>
  44         #include <server/portals.qh>
  45         #include <server/weapons/common.qh>
  46         #include <server/weapons/csqcprojectile.qh>
  47         #include <server/weapons/tracing.qh>
  48 #endif
  49
  50
  51 // WEAPON PLUGIN SYSTEM
  52
  53 WepSet _WepSet_FromWeapon(int a)
  54 {
  55         a -= WEP_FIRST;
  56         if (REGISTRY_MAX(Weapons) > 24)
  57                 if (a >= 24)
  58                 {
  59                         a -= 24;
  60                         if (REGISTRY_MAX(Weapons) > 48)
  61                                 if (a >= 24)
  62                                 {
  63                                         a -= 24;
  64                                         return '0 0 1' * BIT(a);
  65                                 }
  66                         return '0 1 0' * BIT(a);
  67                 }
  68         return '1 0 0' * BIT(a);
  69 }
  70 #ifdef SVQC
  71         void WriteWepSet(float dst, WepSet w)
  72         {
  73                 if (REGISTRY_MAX(Weapons) > 48) WriteInt72_t(dst, w);
  74                 else if (REGISTRY_MAX(Weapons) > 24) WriteInt48_t(dst, w);
  75                 else WriteInt24_t(dst, w.x);
  76         }
  77 #endif
  78 #ifdef CSQC
  79         WepSet WepSet_GetFromStat()
  80         {
  81                 return STAT(WEAPONS);
  82         }
  83         WepSet WepSet_GetFromStat_InMap()
  84         {
  85                 return STAT(WEAPONSINMAP);
  86         }
  87         WepSet ReadWepSet()
  88         {
  89                 if (REGISTRY_MAX(Weapons) > 48) return ReadInt72_t();
  90                 if (REGISTRY_MAX(Weapons) > 24) return ReadInt48_t();
  91                 return ReadInt24_t() * '1 0 0';
  92         }
  93 #endif
  94
  95 string W_FixWeaponOrder(string order, float complete)
  96 {
  97         return fixPriorityList(order, WEP_FIRST, WEP_LAST, WEP_IMPULSE_BEGIN - WEP_FIRST, complete);
  98 }
  99 string W_NameWeaponOrder_MapFunc(string s)
 100 {
 101         int i = stof(s);
 102         if (s == "0" || i)
 103         {
 104                 entity wi = REGISTRY_GET(Weapons, i);
 105                 if (wi != WEP_Null) return wi.netname;
 106         }
 107         return s;
 108 }
 109
 110 string W_NameWeaponOrder(string order)
 111 {
 112         return mapPriorityList(order, W_NameWeaponOrder_MapFunc);
 113 }
 114 string W_NumberWeaponOrder_MapFunc(string s)
 115 {
 116         if (s == "0" || stof(s)) return s;
 117         FOREACH(Weapons, it != WEP_Null && (it.netname == s || it.m_deprecated_netname == s), return ftos(i));
 118         return s;
 119 }
 120 string W_NumberWeaponOrder(string order)
 121 {
 122         return mapPriorityList(order, W_NumberWeaponOrder_MapFunc);
 123 }
 124
 125 float W_FixWeaponOrder_BuildImpulseList_buf[REGISTRY_MAX(Weapons)];
 126 string W_FixWeaponOrder_BuildImpulseList_order;
 127 void W_FixWeaponOrder_BuildImpulseList_swap(int i, int j, entity pass)
 128 {
 129         float h;
 130         h = W_FixWeaponOrder_BuildImpulseList_buf[i];
 131         W_FixWeaponOrder_BuildImpulseList_buf[i] = W_FixWeaponOrder_BuildImpulseList_buf[j];
 132         W_FixWeaponOrder_BuildImpulseList_buf[j] = h;
 133 }
 134 float W_FixWeaponOrder_BuildImpulseList_cmp(int i, int j, entity pass)
 135 {
 136         int si = W_FixWeaponOrder_BuildImpulseList_buf[i];
 137         Weapon e1 = REGISTRY_GET(Weapons, si);
 138         int sj = W_FixWeaponOrder_BuildImpulseList_buf[j];
 139         Weapon e2 = REGISTRY_GET(Weapons, sj);
 140         int d = (e1.impulse + 9) % 10 - (e2.impulse + 9) % 10;
 141         if (d != 0) return -d;  // high impulse first!
 142         string s = strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " ");
 143         return strstrofs(s, sprintf(" %d ", si), 0)
 144                 - strstrofs(s, sprintf(" %d ", sj), 0); // low char index first!
 145 }
 146 string W_FixWeaponOrder_BuildImpulseList(string o)
 147 {
 148         int i;
 149         W_FixWeaponOrder_BuildImpulseList_order = o;
 150         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 151                 W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST] = i;
 152         heapsort(WEP_LAST - WEP_FIRST + 1, W_FixWeaponOrder_BuildImpulseList_swap, W_FixWeaponOrder_BuildImpulseList_cmp,
 153                 NULL);
 154         o = "";
 155         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 156                 o = strcat(o, " ", ftos(W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST]));
 157         W_FixWeaponOrder_BuildImpulseList_order = string_null;
 158         return substring(o, 1, -1);
 159 }
 160
 161 string W_FixWeaponOrder_AllowIncomplete(entity this, string order)
 162 {
 163         return W_FixWeaponOrder(order, 0);
 164 }
 165
 166 string W_FixWeaponOrder_ForceComplete(string order)
 167 {
 168         if (order == "") order = W_NumberWeaponOrder(cvar_defstring("cl_weaponpriority"));
 169         return W_FixWeaponOrder(order, 1);
 170 }
 171
 172 WepSet W_RandomWeapons(entity e, WepSet remaining, int n)
 173 {
 174         WepSet result = '0 0 0';
 175         for (int j = 0; j < n; ++j)
 176         {
 177                 RandomSelection_Init();
 178                 FOREACH(Weapons, it != WEP_Null, {
 179                         if (remaining & (it.m_wepset))
 180                                 RandomSelection_AddEnt(it, 1, 1);
 181                 });
 182                 Weapon w = RandomSelection_chosen_ent;
 183                 result |= WepSet_FromWeapon(w);
 184                 remaining &= ~WepSet_FromWeapon(w);
 185         }
 186         return result;
 187 }
 188
 189 // TODO: registry handles for below functions
 190 string GetAmmoPicture(Resource ammotype)
 191 {
 192         switch (ammotype)
 193         {
 194                 case RES_SHELLS:  return ITEM_Shells.m_icon;
 195                 case RES_BULLETS: return ITEM_Bullets.m_icon;
 196                 case RES_ROCKETS: return ITEM_Rockets.m_icon;
 197                 case RES_CELLS:   return ITEM_Cells.m_icon;
 198                 case RES_PLASMA:  return ITEM_Plasma.m_icon;
 199                 case RES_FUEL:    return ITEM_JetpackFuel.m_icon;
 200                 default: return "";  // wtf, no ammo type?
 201         }
 202 }
 203
 204 string GetAmmoName(Resource ammotype)
 205 {
 206         switch (ammotype)
 207         {
 208                 case RES_SHELLS:  return ITEM_Shells.m_name;
 209                 case RES_BULLETS: return ITEM_Bullets.m_name;
 210                 case RES_ROCKETS: return ITEM_Rockets.m_name;
 211                 case RES_CELLS:   return ITEM_Cells.m_name;
 212                 case RES_PLASMA:  return ITEM_Plasma.m_name;
 213                 case RES_FUEL:    return ITEM_JetpackFuel.m_name;
 214                 default:          return "batteries";
 215         }
 216 }
 217
 218 entity GetAmmoItem(Resource ammotype)
 219 {
 220         switch (ammotype)
 221         {
 222                 case RES_SHELLS:  return ITEM_Shells;
 223                 case RES_BULLETS: return ITEM_Bullets;
 224                 case RES_ROCKETS: return ITEM_Rockets;
 225                 case RES_CELLS:   return ITEM_Cells;
 226                 case RES_PLASMA:  return ITEM_Plasma;
 227                 case RES_FUEL:    return ITEM_JetpackFuel;
 228         }
 229         LOG_WARNF("Invalid ammo type %d ", ammotype.m_id);
 230         return NULL;
 231         // WEAPONTODO: use this generic func to reduce duplication ?
 232         // GetAmmoPicture  GetAmmoName  notif_arg_item_wepammo  ammo_pickupevalfunc ?
 233 }
 234
 235 #ifdef CSQC
 236 int GetAmmoStat(Resource ammotype)
 237 {
 238         switch (ammotype)
 239         {
 240                 case RES_SHELLS: return STAT_SHELLS;
 241                 case RES_BULLETS: return STAT_NAILS;
 242                 case RES_ROCKETS: return STAT_ROCKETS;
 243                 case RES_CELLS: return STAT_CELLS;
 244                 case RES_PLASMA: return STAT_PLASMA.m_id;
 245                 case RES_FUEL: return STAT_FUEL.m_id;
 246                 default: return -1;
 247         }
 248 }
 249 #endif
 250
 251 string W_Sound(string w_snd)
 252 {
 253         string output = strcat("weapons/", w_snd);
 254         MUTATOR_CALLHOOK(WeaponSound, w_snd, output);
 255         return M_ARGV(1, string);
 256 }
 257
 258 string W_Model(string w_mdl)
 259 {
 260         string output = strcat("models/weapons/", w_mdl);
 261         MUTATOR_CALLHOOK(WeaponModel, w_mdl, output);
 262         return M_ARGV(1, string);
 263 }
 264
 265 #ifdef GAMEQC
 266 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float algn)
 267 {
 268         switch (algn)
 269         {
 270                 default:
 271                 case 3:
 272                         // right alignment
 273                         break;
 274                 case 4:
 275                         // left
 276                         vecs.y = -vecs.y;
 277                         break;
 278                 case 1:
 279                 case 2:
 280                         // center
 281                         vecs.y = 0;
 282                         vecs.z -= 2;
 283                         break;
 284         }
 285         return vecs;
 286 }
 287
 288 vector shotorg_adjust(vector vecs, bool y_is_right, bool visual, int algn)
 289 {
 290         string s;
 291         if (visual)
 292         {
 293                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 294         }
 295         else if (STAT(SHOOTFROMEYE))
 296         {
 297                 vecs.y = vecs.z = 0;
 298         }
 299         else if (STAT(SHOOTFROMCENTER))
 300         {
 301                 vecs.y = 0;
 302                 vecs.z -= 2;
 303         }
 304         else if ((s = G_SHOOTFROMFIXEDORIGIN) != "")
 305         {
 306                 vector v = stov(s);
 307                 if (y_is_right) v.y = -v.y;
 308                 if (v.x != 0) vecs.x = v.x;
 309                 vecs.y = v.y;
 310                 vecs.z = v.z;
 311         }
 312         else  // just do the same as top
 313         {
 314                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 315         }
 316
 317         return vecs;
 318 }
 319
 320
 321 /**
 322  * supported formats:
 323  *
 324  * 1. simple animated model, muzzle flash handling on h_ model:
 325  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 326  *      tags:
 327  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 328  *        shell = casings ejection point (must be on the right hand side of the gun)
 329  *        weapon = attachment for v_tuba.md3
 330  *    v_tuba.md3 - first and third person model
 331  *    g_tuba.md3 - pickup model
 332  *
 333  * 2. simple animated model, muzzle flash handling on v_ model:
 334  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 335  *      tags:
 336  *        weapon = attachment for v_tuba.md3
 337  *    v_tuba.md3 - first and third person model
 338  *      tags:
 339  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 340  *        shell = casings ejection point (must be on the right hand side of the gun)
 341  *    g_tuba.md3 - pickup model
 342  *
 343  * 3. fully animated model, muzzle flash handling on h_ model:
 344  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 345  *      tags:
 346  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 347  *        shell = casings ejection point (must be on the right hand side of the gun)
 348  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 349  *    v_tuba.md3 - third person model
 350  *    g_tuba.md3 - pickup model
 351  *
 352  * 4. fully animated model, muzzle flash handling on v_ model:
 353  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 354  *      tags:
 355  *        shot = muzzle end (shot origin)
 356  *        shell = casings ejection point (must be on the right hand side of the gun)
 357  *    v_tuba.md3 - third person model
 358  *      tags:
 359  *        shot = muzzle end (for muzzle flashes)
 360  *    g_tuba.md3 - pickup model
 361  *
 362  * writes:
 363  *   this.origin, this.angles
 364  *   this.weaponchild
 365  *   this.movedir, this.view_ofs, this.movedir_aligned
 366  *   this.spawnorigin (SVQC only)
 367  *   attachment stuff
 368  *   anim stuff
 369  * to free:
 370  *   call again with ""
 371  *   remove the ent
 372  */
 373 void CL_WeaponEntity_SetModel(entity this, string name, bool _anim)
 374 {
 375         if (name == "")
 376         {
 377                 vector oldmin = this.mins, oldmax = this.maxs;
 378                 setmodel(this, MDL_Null);
 379                 setsize(this, oldmin, oldmax);
 380                 if (this.weaponchild) delete(this.weaponchild);
 381                 this.weaponchild = NULL;
 382                 this.movedir = '0 0 0';
 383 #ifdef SVQC
 384                 this.spawnorigin = '0 0 0';
 385 #endif
 386                 this.oldorigin = '0 0 0';
 387                 this.anim_fire1  = '0 1 0.01';
 388                 this.anim_fire2  = '0 1 0.01';
 389                 this.anim_idle   = '0 1 0.01';
 390                 this.anim_reload = '0 1 0.01';
 391         }
 392         else
 393         {
 394                 // if there is a child entity, hide it until we're sure we use it
 395                 if (this.weaponchild) this.weaponchild.model = "";
 396                 _setmodel(this, W_Model(strcat("v_", name, ".md3")));
 397                 int v_shot_idx;  // used later
 398                 (v_shot_idx = gettagindex(this, "shot")) || (v_shot_idx = gettagindex(this, "tag_shot"));
 399
 400                 _setmodel(this, W_Model(strcat("h_", name, ".iqm")));
 401                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 402                 this.anim_fire1  = animfixfps(this, '0 1 0.01', '0 0 0');
 403                 this.anim_fire2  = animfixfps(this, '1 1 0.01', '0 0 0');
 404                 this.anim_idle   = animfixfps(this, '2 1 0.01', '0 0 0');
 405                 this.anim_reload = animfixfps(this, '3 1 0.01', '0 0 0');
 406
 407                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 408                 // if we don't, this is a "real" animated model
 409                 string t;
 410                 if ((t = "weapon", gettagindex(this, t)) || (t = "tag_weapon", gettagindex(this, t)))
 411                 {
 412                         if (!this.weaponchild)
 413                         {
 414                                 this.weaponchild = new(weaponchild);
 415 #ifdef CSQC
 416                                 this.weaponchild.drawmask = MASK_NORMAL;
 417                                 this.weaponchild.renderflags |= RF_VIEWMODEL;
 418 #endif
 419                         }
 420                         _setmodel(this.weaponchild, W_Model(strcat("v_", name, ".md3")));
 421                         setsize(this.weaponchild, '0 0 0', '0 0 0');
 422                         setattachment(this.weaponchild, this, t);
 423                 }
 424                 else
 425                 {
 426                         if (this.weaponchild) delete(this.weaponchild);
 427                         this.weaponchild = NULL;
 428                 }
 429
 430                 setsize(this, '0 0 0', '0 0 0');
 431                 setorigin(this, '0 0 0');
 432                 this.angles = '0 0 0';
 433                 this.frame = 0;
 434 #ifdef SVQC
 435                 this.viewmodelforclient = NULL;
 436 #else
 437                 this.renderflags &= ~RF_VIEWMODEL;
 438 #endif
 439                 if (v_shot_idx)  // v_ model attached to invisible h_ model
 440                 {
 441                         this.movedir = gettaginfo(this.weaponchild, v_shot_idx);
 442                 }
 443                 else
 444                 {
 445                         int idx;
 446                         if ((idx = gettagindex(this, "shot")) || (idx = gettagindex(this, "tag_shot")))
 447                         {
 448                                 this.movedir = gettaginfo(this, idx);
 449                         }
 450                         else
 451                         {
 452                                 LOG_WARNF("weapon model %s does not support the 'shot' tag, will display shots TOTALLY wrong",
 453                                         this.model);
 454                                 this.movedir = '0 0 0';
 455                         }
 456                 }
 457 #ifdef SVQC
 458                 {
 459                         int idx = 0;
 460                         // v_ model attached to invisible h_ model
 461                         if (this.weaponchild
 462                                 && ((idx = gettagindex(this.weaponchild, "shell")) || (idx = gettagindex(this.weaponchild, "tag_shell"))))
 463                         {
 464                                 this.spawnorigin = gettaginfo(this.weaponchild, idx);
 465                         }
 466                         else if ((idx = gettagindex(this, "shell")) || (idx = gettagindex(this, "tag_shell")))
 467                         {
 468                                 this.spawnorigin = gettaginfo(this, idx);
 469                         }
 470                         else
 471                         {
 472                                 LOG_WARNF("weapon model %s does not support the 'shell' tag, will display casings wrong",
 473                                         this.model);
 474                                 this.spawnorigin = this.movedir;
 475                         }
 476                 }
 477 #endif
 478                 if (v_shot_idx)
 479                 {
 480                         this.oldorigin = '0 0 0';  // use regular attachment
 481                 }
 482                 else
 483                 {
 484                         int idx;
 485                         if (this.weaponchild)
 486                                 (idx = gettagindex(this, "weapon")) || (idx = gettagindex(this, "tag_weapon"));
 487                         else
 488                                 (idx = gettagindex(this, "handle")) || (idx = gettagindex(this, "tag_handle"));
 489                         if (idx)
 490                         {
 491                                 this.oldorigin = this.movedir - gettaginfo(this, idx);
 492                         }
 493                         else
 494                         {
 495                                 LOG_WARNF(
 496                                         "weapon model %s does not support the 'handle' tag "
 497                                         "and neither does the v_ model support the 'shot' tag, "
 498                                         "will display muzzle flashes TOTALLY wrong\n",
 499                                         this.model);
 500                                 this.oldorigin = '0 0 0';  // there is no way to recover from this
 501                         }
 502                 }
 503
 504 #ifdef SVQC
 505                 this.viewmodelforclient = this.owner;
 506 #else
 507                 this.renderflags |= RF_VIEWMODEL;
 508 #endif
 509         }
 510
 511         this.view_ofs = '0 0 0';
 512         this.movedir_aligned = this.movedir;
 513
 514         if (this.movedir.x >= 0)
 515         {
 516                 //int algn = STAT(GUNALIGN, this.owner);
 517                 int algn = W_GunAlign(this, STAT(GUNALIGN, this.owner));
 518         #ifdef SVQC
 519                 this.m_gunalign = algn;
 520         #endif
 521                 vector v = this.movedir;
 522                 this.movedir = shotorg_adjust(v, false, false, algn);
 523                 this.movedir_aligned = shotorg_adjust(v, false, true, algn);
 524                 this.view_ofs = this.movedir_aligned - v;
 525         }
 526
 527         // shotorg_adjust can give negative .x from shootfromfixedorigin
 528         // recheck .x here due to it
 529         if (this.movedir.x >= 0)
 530         {
 531                 int compressed_shotorg = compressShotOrigin(this.movedir);
 532                 // make them match perfectly
 533         #ifdef SVQC
 534                 // null during init
 535                 if (this.owner) STAT(SHOTORG, this.owner) = compressed_shotorg;
 536         #endif
 537                 this.movedir = decompressShotOrigin(compressed_shotorg);
 538         }
 539         else
 540         {
 541                 // don't support negative x shotorgs
 542                 this.movedir = '0 0 0';
 543
 544                 // reset _aligned here too even though as a side effect
 545                 // g_shootfromfixedorigin can make it reset
 546                 // it'd be only slightly better if it was checked individually
 547                 this.movedir_aligned = '0 0 0';
 548
 549         #ifdef SVQC
 550                 // null during init
 551                 if (this.owner) STAT(SHOTORG, this.owner) = 0;
 552         #endif
 553         }
 554
 555 #ifdef SVQC
 556         this.spawnorigin += this.view_ofs;  // offset the casings origin by the same amount
 557 #endif
 558
 559         // check if an instant weapon switch occurred
 560         setorigin(this, this.view_ofs);
 561         if (!_anim) return;
 562         // reset animstate now
 563         this.wframe = WFRAME_IDLE;
 564         setanim(this, this.anim_idle, true, false, true);
 565 }
 566 #endif
 567
 568 #ifdef GAMEQC
 569
 570 REGISTER_NET_TEMP(wframe)
 571 #ifdef CSQC
 572 NET_HANDLE(wframe, bool isNew)
 573 {
 574         WFRAME fr = ReadByte();
 575         float t = ReadFloat();
 576         int slot = ReadByte();
 577         bool restartanim = ReadByte();
 578         entity wepent = viewmodels[slot];
 579         if(fr == WFRAME_IDLE)
 580                 wepent.animstate_looping = false; // we don't need to enforce idle animation
 581         else
 582         {
 583                 vector a = '0 0 0';
 584                 switch(fr)
 585                 {
 586                         default:
 587                         case WFRAME_IDLE: a = wepent.anim_idle; break;
 588                         case WFRAME_FIRE1: a = wepent.anim_fire1; break;
 589                         case WFRAME_FIRE2: a = wepent.anim_fire2; break;
 590                         case WFRAME_RELOAD: a = wepent.anim_reload; break;
 591                 }
 592                 a.z *= t;
 593                 anim_set(wepent, a, !restartanim, restartanim, restartanim);
 594         }
 595         wepent.state = ReadByte();
 596         wepent.weapon_nextthink = ReadFloat();
 597         switch (wepent.state)
 598         {
 599                 case WS_RAISE:
 600                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_raise;
 601                         break;
 602                 case WS_DROP:
 603                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_drop;
 604                         break;
 605                 default:
 606                         wepent.weapon_switchdelay = 0;
 607                         break;
 608         }
 609         return true;
 610 }
 611 #endif
 612
 613 #ifdef SVQC
 614 void wframe_send(entity actor, entity weaponentity, int wepframe, float attackrate, bool restartanim)
 615 {
 616         if (!IS_REAL_CLIENT(actor)) return;
 617         int channel = MSG_ONE;
 618         msg_entity = actor;
 619         WriteHeader(channel, wframe);
 620         WriteByte(channel, wepframe);
 621         WriteFloat(channel, attackrate);
 622         WriteByte(channel, weaponslot(weaponentity.weaponentity_fld));
 623         WriteByte(channel, restartanim);
 624         WriteByte(channel, weaponentity.state);
 625         WriteFloat(channel, weaponentity.weapon_nextthink);
 626 }
 627 #endif
 628
 629 REGISTER_NET_C2S(w_whereis)
 630 #ifdef SVQC
 631 void Weapon_whereis(Weapon this, entity cl);
 632 NET_HANDLE(w_whereis, bool)
 633 {
 634         Weapon wpn = ReadRegistered(Weapons);
 635         if (wpn != WEP_Null) Weapon_whereis(wpn, sender);
 636         return true;
 637 }
 638 #else
 639 void w_whereis(Weapon this)
 640 {
 641         int channel = MSG_C2S;
 642         WriteHeader(channel, w_whereis);
 643         WriteRegistered(Weapons, channel, this);
 644 }
 645 CLIENT_COMMAND(weapon_find, "Show spawn locations of a weapon")
 646 {
 647         switch (request)
 648         {
 649                 case CMD_REQUEST_COMMAND:
 650                 {
 651                         string s = argv(1);
 652                         if (s == "all")
 653                         {
 654                                 FOREACH(Weapons, it != WEP_Null, w_whereis(it));
 655                                 return;
 656                         }
 657                         if (s == "unowned")
 658                         {
 659                                 FOREACH(Weapons, it != WEP_Null && !(STAT(WEAPONS) & it.m_wepset), w_whereis(it));
 660                                 return;
 661                         }
 662                         FOREACH(Weapons, it != WEP_Null && it.netname == s,
 663                         {
 664                                 w_whereis(it);
 665                                 return;
 666                         });
 667                 }
 668                 default:
 669                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 670                 case CMD_REQUEST_USAGE:
 671                 {
 672                         LOG_HELP("Usage:^3 cl_cmd weapon_find <weapon>");
 673                         LOG_HELP("  Where <weapon> is the lowercase weapon name, 'all' or 'unowned'.");
 674                         return;
 675                 }
 676         }
 677 }
 678 #endif
 679
 680 #ifdef SVQC
 681 void W_MuzzleFlash_Model_AttachToShotorg(entity actor, .entity weaponentity, entity flash, vector offset)
 682 {
 683         flash.owner = actor;
 684         flash.angles_z = random() * 360;
 685
 686         entity view = actor.(weaponentity);
 687         entity exterior = actor.exteriorweaponentity;
 688
 689         if (view.oldorigin.x > 0)
 690         {
 691                 setattachment(flash, exterior, "");
 692                 setorigin(flash, view.oldorigin + offset);
 693         }
 694         else
 695         {
 696                 if (gettagindex(exterior, "shot")) setattachment(flash, exterior, "shot");
 697                 else setattachment(flash, exterior, "tag_shot");
 698                 setorigin(flash, offset);
 699         }
 700 }
 701 #elif defined(CSQC)
 702 void W_MuzzleFlash_Model_AttachToShotorg(entity wepent, entity flash, vector offset)
 703 {
 704         flash.owner = wepent;
 705         flash.angles_z = random() * 360;
 706
 707         if (gettagindex(wepent, "shot")) setattachment(flash, wepent, "shot");
 708         else setattachment(flash, wepent, "tag_shot");
 709         setorigin(flash, offset);
 710 }
 711 #endif
 712
 713 void W_MuzzleFlash_Model_Think(entity this)
 714 {
 715         this.frame += 2;
 716         this.scale *= 0.5;
 717         this.alpha -= 0.25;
 718         this.nextthink = time + 0.05;
 719
 720         if(this.alpha <= 0)
 721         {
 722                 setthink(this, SUB_Remove);
 723                 this.nextthink = time;
 724                 this.realowner.muzzle_flash = NULL;
 725                 return;
 726         }
 727 }
 728
 729 void W_MuzzleFlash_Model(entity wepent, entity muzzlemodel)
 730 {
 731         if(wepent.muzzle_flash == NULL)
 732                 wepent.muzzle_flash = spawn();
 733
 734         entity flash = wepent.muzzle_flash;
 735         setmodel(flash, muzzlemodel); // precision set below
 736
 737         flash.scale = 0.75;
 738         setthink(flash, W_MuzzleFlash_Model_Think);
 739         flash.nextthink = time + 0.02;
 740         flash.frame = 2;
 741         flash.alpha = 0.75;
 742         flash.angles_z = random() * 180;
 743         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
 744         flash.owner = flash.realowner = wepent;
 745
 746 #ifdef CSQC
 747         flash.drawmask = MASK_NORMAL;
 748 #endif
 749 }
 750
 751 REGISTER_NET_TEMP(w_muzzleflash)
 752
 753 #ifdef SVQC
 754 void W_MuzzleFlash(Weapon thiswep, entity actor, .entity weaponentity, vector shotorg, vector shotdir)
 755 {
 756         // don't show an exterior muzzle effect for the off-hand
 757         if(weaponslot(weaponentity) == 0)
 758         {
 759                 Send_Effect_Except(thiswep.m_muzzleeffect, shotorg, shotdir * 1000, 1, actor);
 760
 761                 if(thiswep.m_muzzlemodel != MDL_Null)
 762                 {
 763                         W_MuzzleFlash_Model(actor.exteriorweaponentity, thiswep.m_muzzlemodel);
 764                         W_MuzzleFlash_Model_AttachToShotorg(actor, weaponentity, actor.exteriorweaponentity.muzzle_flash, '5 0 0');
 765                 }
 766         }
 767
 768         FOREACH_CLIENT(it == actor || (IS_SPEC(it) && it.enemy == actor),
 769         {
 770                 if(!IS_REAL_CLIENT(it))
 771                         continue;
 772                 int channel = MSG_ONE;
 773                 msg_entity = it;
 774                 WriteHeader(channel, w_muzzleflash);
 775                 WriteByte(channel, thiswep.m_id);
 776                 WriteByte(channel, weaponslot(weaponentity));
 777                 WriteVector(channel, shotorg);
 778         });
 779 }
 780 #elif defined(CSQC)
 781 NET_HANDLE(w_muzzleflash, bool isNew)
 782 {
 783         return = true;
 784         int weapon_id = ReadByte();
 785         int slot = ReadByte();
 786         vector sv_shotorg = ReadVector();
 787
 788         Weapon thiswep = REGISTRY_GET(Weapons, weapon_id);
 789         vector viewangles = getpropertyvec(VF_CL_VIEWANGLES);
 790         vector forward, right, up;
 791         MAKE_VECTORS(viewangles, forward, right, up);
 792
 793         if(autocvar_chase_active)
 794         {
 795                 // in third person mode, show the muzzle flash from the server side weapon position
 796                 // we don't have a view model to reference in this case
 797                 pointparticles(thiswep.m_muzzleeffect, sv_shotorg, forward * 1000, 1);
 798                 return;
 799         }
 800         if(!autocvar_r_drawviewmodel) return;
 801
 802         entity wepent = viewmodels[slot];
 803         // get the local player entity to calculate shot origin
 804         entity rlplayer = CSQCModel_server2csqc(player_localentnum - 1);
 805         if(!rlplayer)
 806                 rlplayer = csqcplayer; // fall back to the global
 807
 808         vector md = wepent.movedir_aligned;
 809         vector dv = forward * md.x + right * -md.y + up * md.z;
 810         vector org = rlplayer.origin + rlplayer.view_ofs + dv;
 811
 812         pointparticles(thiswep.m_muzzleeffect, org, forward * 1000, 1);
 813
 814         if(thiswep.m_muzzlemodel != MDL_Null)
 815         {
 816                 W_MuzzleFlash_Model(wepent, thiswep.m_muzzlemodel);
 817                 W_MuzzleFlash_Model_AttachToShotorg(wepent, wepent.muzzle_flash, '5 0 0');
 818         }
 819 }
 820 #endif
 821
 822
 823 #endif
 824
 825 #endif
 826
 827 #ifdef SVQC
 828 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
 829 {
 830         string o = W_FixWeaponOrder_ForceComplete(wo);
 831         strcpy(CS_CVAR(this).weaponorder_byimpulse, W_FixWeaponOrder_BuildImpulseList(o));
 832         return o;
 833 }
 834 #endif
 835
 836 #ifdef CSQC
 837 REPLICATE(cvar_cl_accuracy_data_share, bool, "cl_accuracy_data_share");
 838 REPLICATE(cvar_cl_accuracy_data_receive, bool, "cl_accuracy_data_receive");
 839 #endif
 840
 841 #ifdef GAMEQC
 842 REPLICATE(cvar_cl_gunalign, int, "cl_gunalign");
 843 REPLICATE(cvar_cl_weapon_switch_reload, bool, "cl_weapon_switch_reload");
 844 REPLICATE(cvar_cl_weapon_switch_fallback_to_impulse, bool, "cl_weapon_switch_fallback_to_impulse");
 845 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
 846 REPLICATE(cvar_cl_weaponpriority, string, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 847 REPLICATE(cvar_cl_weaponpriorities[0], string, "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 848 REPLICATE(cvar_cl_weaponpriorities[1], string, "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 849 REPLICATE(cvar_cl_weaponpriorities[2], string, "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 850 REPLICATE(cvar_cl_weaponpriorities[3], string, "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 851 REPLICATE(cvar_cl_weaponpriorities[4], string, "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 852 REPLICATE(cvar_cl_weaponpriorities[5], string, "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 853 REPLICATE(cvar_cl_weaponpriorities[6], string, "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 854 REPLICATE(cvar_cl_weaponpriorities[7], string, "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 855 REPLICATE(cvar_cl_weaponpriorities[8], string, "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 856 REPLICATE(cvar_cl_weaponpriorities[9], string, "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 857 #endif