qcsrc/common/util.qc

   1 #include "util.qh"
   2
   3 #if defined(CSQC)
   4         #include <client/mutators/_mod.qh>
   5         #include <common/constants.qh>
   6         #include <common/deathtypes/all.qh>
   7         #include <common/gamemodes/_mod.qh>
   8         #include <common/mapinfo.qh>
   9         #include <common/notifications/all.qh>
  10         #include <common/scores.qh>
  11 #elif defined(MENUQC)
  12 #elif defined(SVQC)
  13         #include <common/constants.qh>
  14         #include <common/deathtypes/all.qh>
  15         #include <common/gamemodes/_mod.qh>
  16         #include <common/mapinfo.qh>
  17         #include <common/notifications/all.qh>
  18         #include <common/scores.qh>
  19         #include <server/mutators/_mod.qh>
  20 #endif
  21
  22 #ifdef SVQC
  23 float tracebox_inverted (vector v1, vector mi, vector ma, vector v2, float nomonsters, entity forent, float stopatentity, entity ignorestopatentity) // returns the number of traces done, for benchmarking
  24 {
  25         vector pos, dir, t;
  26         float nudge;
  27         entity stopentity;
  28
  29         //nudge = 2 * cvar("collision_impactnudge"); // why not?
  30         nudge = 0.5;
  31
  32         dir = normalize(v2 - v1);
  33
  34         pos = v1 + dir * nudge;
  35
  36         float c;
  37         c = 0;
  38
  39         for (;;)
  40         {
  41                 if(pos * dir >= v2 * dir)
  42                 {
  43                         // went too far
  44                         trace_fraction = 1;
  45                         trace_endpos = v2;
  46                         return c;
  47                 }
  48
  49                 tracebox(pos, mi, ma, v2, nomonsters, forent);
  50                 ++c;
  51
  52                 if(c == 50)
  53                 {
  54                         LOG_TRACE("When tracing from ", vtos(v1), " to ", vtos(v2));
  55                         LOG_TRACE("  Nudging gets us nowhere at ", vtos(pos));
  56                         LOG_TRACE("  trace_endpos is ", vtos(trace_endpos));
  57                         LOG_TRACE("  trace distance is ", ftos(vlen(pos - trace_endpos)));
  58                 }
  59
  60                 stopentity = trace_ent;
  61
  62                 if(trace_startsolid)
  63                 {
  64                         // we started inside solid.
  65                         // then trace from endpos to pos
  66                         t = trace_endpos;
  67                         tracebox(t, mi, ma, pos, nomonsters, forent);
  68                         ++c;
  69                         if(trace_startsolid)
  70                         {
  71                                 // t is still inside solid? bad
  72                                 // force advance, then, and retry
  73                                 pos = t + dir * nudge;
  74
  75                                 // but if we hit an entity, stop RIGHT before it
  76                                 if(stopatentity && stopentity && stopentity != ignorestopatentity)
  77                                 {
  78                                         trace_ent = stopentity;
  79                                         trace_endpos = t;
  80                                         trace_fraction = ((trace_endpos - v1) * dir) / ((v2 - v1) * dir);
  81                                         return c;
  82                                 }
  83                         }
  84                         else
  85                         {
  86                                 // we actually LEFT solid!
  87                                 trace_fraction = ((trace_endpos - v1) * dir) / ((v2 - v1) * dir);
  88                                 return c;
  89                         }
  90                 }
  91                 else
  92                 {
  93                         // pos is outside solid?!? but why?!? never mind, just return it.
  94                         trace_endpos = pos;
  95                         trace_fraction = ((trace_endpos - v1) * dir) / ((v2 - v1) * dir);
  96                         return c;
  97                 }
  98         }
  99 }
 100
 101 void traceline_inverted (vector v1, vector v2, float nomonsters, entity forent, float stopatentity, entity ignorestopatentity)
 102 {
 103         tracebox_inverted(v1, '0 0 0', '0 0 0', v2, nomonsters, forent, stopatentity, ignorestopatentity);
 104 }
 105 #endif
 106
 107 #ifdef GAMEQC
 108 /*
 109 ==================
 110 findbetterlocation
 111
 112 Returns a point at least 12 units away from walls
 113 (useful for explosion animations, although the blast is performed where it really happened)
 114 Ripped from DPMod
 115 ==================
 116 */
 117 vector findbetterlocation (vector org, float mindist)
 118 {
 119         vector vec = mindist * '1 0 0';
 120         int c = 0;
 121         while (c < 6)
 122         {
 123                 traceline (org, org + vec, true, NULL);
 124                 vec = vec * -1;
 125                 if (trace_fraction < 1)
 126                 {
 127                         vector loc = trace_endpos;
 128                         traceline (loc, loc + vec, true, NULL);
 129                         if (trace_fraction >= 1)
 130                                 org = loc + vec;
 131                 }
 132                 if (c & 1)
 133                 {
 134                         float h = vec.y;
 135                         vec.y = vec.x;
 136                         vec.x = vec.z;
 137                         vec.z = h;
 138                 }
 139                 c = c + 1;
 140         }
 141
 142         return org;
 143 }
 144
 145 /*
 146 * Get "real" origin, in worldspace, even if ent is attached to something else.
 147 */
 148 vector real_origin(entity ent)
 149 {
 150         vector v = ((ent.absmin + ent.absmax) * 0.5);
 151         entity e = ent.tag_entity;
 152
 153         while(e)
 154         {
 155                 v = v + ((e.absmin + e.absmax) * 0.5);
 156                 e = e.tag_entity;
 157         }
 158
 159         return v;
 160 }
 161 #endif
 162
 163 string wordwrap_buffer;
 164
 165 void wordwrap_buffer_put(string s)
 166 {
 167         wordwrap_buffer = strcat(wordwrap_buffer, s);
 168 }
 169
 170 string wordwrap(string s, float l)
 171 {
 172         string r;
 173         wordwrap_buffer = "";
 174         wordwrap_cb(s, l, wordwrap_buffer_put);
 175         r = wordwrap_buffer;
 176         wordwrap_buffer = "";
 177         return r;
 178 }
 179
 180 #ifdef SVQC
 181 entity _wordwrap_buffer_sprint_ent;
 182 void wordwrap_buffer_sprint(string s)
 183 {
 184         wordwrap_buffer = strcat(wordwrap_buffer, s);
 185         if(s == "\n")
 186         {
 187                 sprint(_wordwrap_buffer_sprint_ent, wordwrap_buffer);
 188                 wordwrap_buffer = "";
 189         }
 190 }
 191
 192 void wordwrap_sprint(entity to, string s, float l)
 193 {
 194         wordwrap_buffer = "";
 195         _wordwrap_buffer_sprint_ent = to;
 196         wordwrap_cb(s, l, wordwrap_buffer_sprint);
 197         _wordwrap_buffer_sprint_ent = NULL;
 198         if(wordwrap_buffer != "")
 199                 sprint(to, strcat(wordwrap_buffer, "\n"));
 200         wordwrap_buffer = "";
 201         return;
 202 }
 203 #endif
 204
 205 #ifndef SVQC
 206 string draw_UseSkinFor(string pic)
 207 {
 208         if(substring(pic, 0, 1) == "/")
 209                 return substring(pic, 1, strlen(pic)-1);
 210         else
 211                 return strcat(draw_currentSkin, "/", pic);
 212 }
 213 #endif
 214
 215 void wordwrap_cb(string s, float l, void(string) callback)
 216 {
 217         string c;
 218         float lleft, i, j, wlen;
 219
 220         s = strzone(s);
 221         lleft = l;
 222         int len = strlen(s);
 223         for (i = 0; i < len; ++i)
 224         {
 225                 if (substring(s, i, 2) == "\\n")
 226                 {
 227                         callback("\n");
 228                         lleft = l;
 229                         ++i;
 230                 }
 231                 else if (substring(s, i, 1) == "\n")
 232                 {
 233                         callback("\n");
 234                         lleft = l;
 235                 }
 236                 else if (substring(s, i, 1) == " ")
 237                 {
 238                         if (lleft > 0)
 239                         {
 240                                 callback(" ");
 241                                 --lleft;
 242                         }
 243                 }
 244                 else
 245                 {
 246                         for (j = i+1; j < len; ++j)
 247                                 //    ^^ this skips over the first character of a word, which
 248                                 //       is ALWAYS part of the word
 249                                 //       this is safe since if i+1 == strlen(s), i will become
 250                                 //       strlen(s)-1 at the end of this block and the function
 251                                 //       will terminate. A space can't be the first character we
 252                                 //       read here, and neither can a \n be the start, since these
 253                                 //       two cases have been handled above.
 254                         {
 255                                 c = substring(s, j, 1);
 256                                 if (c == " ")
 257                                         break;
 258                                 if (c == "\\")
 259                                         break;
 260                                 if (c == "\n")
 261                                         break;
 262                                 // we need to keep this tempstring alive even if substring is
 263                                 // called repeatedly, so call strcat even though we're not
 264                                 // doing anything
 265                                 callback("");
 266                         }
 267                         wlen = j - i;
 268                         if (lleft < wlen)
 269                         {
 270                                 callback("\n");
 271                                 lleft = l;
 272                         }
 273                         callback(substring(s, i, wlen));
 274                         lleft -= wlen;
 275                         i = j - 1;
 276                 }
 277         }
 278         strunzone(s);
 279 }
 280
 281 void depthfirst(entity start, .entity up, .entity downleft, .entity right, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
 282 {
 283         entity e;
 284         e = start;
 285         funcPre(pass, e);
 286         while (e.(downleft))
 287         {
 288                 e = e.(downleft);
 289                 funcPre(pass, e);
 290         }
 291         funcPost(pass, e);
 292         while(e != start)
 293         {
 294                 if (e.(right))
 295                 {
 296                         e = e.(right);
 297                         funcPre(pass, e);
 298                         while (e.(downleft))
 299                         {
 300                                 e = e.(downleft);
 301                                 funcPre(pass, e);
 302                         }
 303                 }
 304                 else
 305                         e = e.(up);
 306                 funcPost(pass, e);
 307         }
 308 }
 309
 310 #ifdef GAMEQC
 311 string ScoreString(int pFlags, float pValue)
 312 {
 313         string valstr;
 314         float l;
 315
 316         pValue = floor(pValue + 0.5); // round
 317
 318         if((pValue == 0) && (pFlags & (SFL_HIDE_ZERO | SFL_RANK | SFL_TIME)))
 319                 valstr = "";
 320         else if(pFlags & SFL_RANK)
 321                 valstr = count_ordinal(pValue);
 322         else if(pFlags & SFL_TIME)
 323                 valstr = TIME_ENCODED_TOSTRING(pValue);
 324         else
 325                 valstr = ftos(pValue);
 326
 327         return valstr;
 328 }
 329 #endif
 330
 331 // compressed vector format:
 332 // like MD3, just even shorter
 333 //   4 bit pitch (16 angles), 0 is -90, 8 is 0, 16 would be 90
 334 //   5 bit yaw (32 angles), 0=0, 8=90, 16=180, 24=270
 335 //   7 bit length (logarithmic encoding), 1/8 .. about 7844
 336 //     length = 2^(length_encoded/8) / 8
 337 // if pitch is 90, yaw does nothing and therefore indicates the sign (yaw is then either 11111 or 11110); 11111 is pointing DOWN
 338 // thus, valid values are from 0000.11110.0000000 to 1111.11111.1111111
 339 // the special value 0 indicates the zero vector
 340
 341 float lengthLogTable[128];
 342
 343 float invertLengthLog(float dist)
 344 {
 345         int l, r, m;
 346
 347         if(dist >= lengthLogTable[127])
 348                 return 127;
 349         if(dist <= lengthLogTable[0])
 350                 return 0;
 351
 352         l = 0;
 353         r = 127;
 354
 355         while(r - l > 1)
 356         {
 357                 m = floor((l + r) / 2);
 358                 if(lengthLogTable[m] < dist)
 359                         l = m;
 360                 else
 361                         r = m;
 362         }
 363
 364         // now: r is >=, l is <
 365         float lerr = (dist - lengthLogTable[l]);
 366         float rerr = (lengthLogTable[r] - dist);
 367         if(lerr < rerr)
 368                 return l;
 369         return r;
 370 }
 371
 372 vector decompressShortVector(int data)
 373 {
 374         vector out;
 375         if(data == 0)
 376                 return '0 0 0';
 377         float p = (data & 0xF000) / 0x1000;
 378         float q = (data & 0x0F80) / 0x80;
 379         int len = (data & 0x007F);
 380
 381         //print("\ndecompress: p ", ftos(p)); print("q ", ftos(q)); print("len ", ftos(len), "\n");
 382
 383         if(p == 0)
 384         {
 385                 out.x = 0;
 386                 out.y = 0;
 387                 if(q == 31)
 388                         out.z = -1;
 389                 else
 390                         out.z = +1;
 391         }
 392         else
 393         {
 394                 q   = .19634954084936207740 * q;
 395                 p = .19634954084936207740 * p - 1.57079632679489661922;
 396                 out.x = cos(q) *  cos(p);
 397                 out.y = sin(q) *  cos(p);
 398                 out.z =          -sin(p);
 399         }
 400
 401         //print("decompressed: ", vtos(out), "\n");
 402
 403         return out * lengthLogTable[len];
 404 }
 405
 406 float compressShortVector(vector vec)
 407 {
 408         vector ang;
 409         float p, y, len;
 410         if(vec == '0 0 0')
 411                 return 0;
 412         //print("compress: ", vtos(vec), "\n");
 413         ang = vectoangles(vec);
 414         ang.x = -ang.x;
 415         if(ang.x < -90)
 416                 ang.x += 360;
 417         if(ang.x < -90 && ang.x > +90)
 418                 error("BOGUS vectoangles");
 419         //print("angles: ", vtos(ang), "\n");
 420
 421         p = floor(0.5 + (ang.x + 90) * 16 / 180) & 15; // -90..90 to 0..14
 422         if(p == 0)
 423         {
 424                 if(vec.z < 0)
 425                         y = 31;
 426                 else
 427                         y = 30;
 428         }
 429         else
 430                 y = floor(0.5 + ang.y * 32 / 360)          & 31; // 0..360 to 0..32
 431         len = invertLengthLog(vlen(vec));
 432
 433         //print("compressed: p ", ftos(p)); print("y ", ftos(y)); print("len ", ftos(len), "\n");
 434
 435         return (p * 0x1000) + (y * 0x80) + len;
 436 }
 437
 438 STATIC_INIT(compressShortVector)
 439 {
 440         float l = 1;
 441         float f = (2 ** (1/8));
 442         int i;
 443         for(i = 0; i < 128; ++i)
 444         {
 445                 lengthLogTable[i] = l;
 446                 l *= f;
 447         }
 448
 449         if(cvar("developer") > 0)
 450         {
 451                 LOG_TRACE("Verifying vector compression table...");
 452                 for(i = 0x0F00; i < 0xFFFF; ++i)
 453                         if(i != compressShortVector(decompressShortVector(i)))
 454                         {
 455                                 LOG_FATALF(
 456                                     "BROKEN vector compression: %s -> %s -> %s",
 457                                     ftos(i),
 458                                     vtos(decompressShortVector(i)),
 459                                     ftos(compressShortVector(decompressShortVector(i)))
 460                 );
 461                         }
 462                 LOG_TRACE("Done.");
 463         }
 464 }
 465
 466 #ifdef GAMEQC
 467 float CheckWireframeBox(entity forent, vector v0, vector dvx, vector dvy, vector dvz)
 468 {
 469         traceline(v0, v0 + dvx, true, forent); if(trace_fraction < 1) return 0;
 470         traceline(v0, v0 + dvy, true, forent); if(trace_fraction < 1) return 0;
 471         traceline(v0, v0 + dvz, true, forent); if(trace_fraction < 1) return 0;
 472         traceline(v0 + dvx, v0 + dvx + dvy, true, forent); if(trace_fraction < 1) return 0;
 473         traceline(v0 + dvx, v0 + dvx + dvz, true, forent); if(trace_fraction < 1) return 0;
 474         traceline(v0 + dvy, v0 + dvy + dvx, true, forent); if(trace_fraction < 1) return 0;
 475         traceline(v0 + dvy, v0 + dvy + dvz, true, forent); if(trace_fraction < 1) return 0;
 476         traceline(v0 + dvz, v0 + dvz + dvx, true, forent); if(trace_fraction < 1) return 0;
 477         traceline(v0 + dvz, v0 + dvz + dvy, true, forent); if(trace_fraction < 1) return 0;
 478         traceline(v0 + dvx + dvy, v0 + dvx + dvy + dvz, true, forent); if(trace_fraction < 1) return 0;
 479         traceline(v0 + dvx + dvz, v0 + dvx + dvy + dvz, true, forent); if(trace_fraction < 1) return 0;
 480         traceline(v0 + dvy + dvz, v0 + dvx + dvy + dvz, true, forent); if(trace_fraction < 1) return 0;
 481         return 1;
 482 }
 483 #endif
 484
 485 string fixPriorityList(string order, float from, float to, float subtract, float complete)
 486 {
 487         string neworder;
 488         float i, n, w;
 489
 490         n = tokenize_console(order);
 491         neworder = "";
 492         for(i = 0; i < n; ++i)
 493         {
 494                 w = stof(argv(i));
 495                 if(w == floor(w))
 496                 {
 497                         if(w >= from && w <= to)
 498                                 neworder = strcat(neworder, ftos(w), " ");
 499                         else
 500                         {
 501                                 w -= subtract;
 502                                 if(w >= from && w <= to)
 503                                         neworder = strcat(neworder, ftos(w), " ");
 504                         }
 505                 }
 506         }
 507
 508         if(complete)
 509         {
 510                 n = tokenize_console(neworder);
 511                 for(w = to; w >= from; --w)
 512                 {
 513                         int wflags = REGISTRY_GET(Weapons, w).spawnflags;
 514                         if(wflags & WEP_FLAG_SPECIALATTACK)
 515                                 continue;
 516                         for(i = 0; i < n; ++i)
 517                                 if(stof(argv(i)) == w)
 518                                         break;
 519                         if(i == n) // not found
 520                                 neworder = strcat(neworder, ftos(w), " ");
 521                 }
 522         }
 523
 524         return substring(neworder, 0, strlen(neworder) - 1);
 525 }
 526
 527 string mapPriorityList(string order, string(string) mapfunc)
 528 {
 529         string neworder;
 530         float n;
 531
 532         n = tokenize_console(order);
 533         neworder = "";
 534         for(float i = 0; i < n; ++i)
 535                 neworder = strcat(neworder, mapfunc(argv(i)), " ");
 536
 537         return substring(neworder, 0, strlen(neworder) - 1);
 538 }
 539
 540 string swapInPriorityList(string order, float i, float j)
 541 {
 542         float n = tokenize_console(order);
 543
 544         if(i >= 0 && i < n && j >= 0 && j < n && i != j)
 545         {
 546                 string s = "";
 547                 for(float w = 0; w < n; ++w)
 548                 {
 549                         if(w == i)
 550                                 s = strcat(s, argv(j), " ");
 551                         else if(w == j)
 552                                 s = strcat(s, argv(i), " ");
 553                         else
 554                                 s = strcat(s, argv(w), " ");
 555                 }
 556                 return substring(s, 0, strlen(s) - 1);
 557         }
 558
 559         return order;
 560 }
 561
 562 #ifdef GAMEQC
 563 void get_mi_min_max(float mode)
 564 {
 565         vector mi, ma;
 566
 567         string s = mapname;
 568         if(!strcasecmp(substring(s, 0, 5), "maps/"))
 569                 s = substring(s, 5, strlen(s) - 5);
 570         if(!strcasecmp(substring(s, strlen(s) - 4, 4), ".bsp"))
 571                 s = substring(s, 0, strlen(s) - 4);
 572         strcpy(mi_shortname, s);
 573
 574 #ifdef CSQC
 575         mi = world.mins;
 576         ma = world.maxs;
 577 #else
 578         mi = world.absmin;
 579         ma = world.absmax;
 580 #endif
 581
 582         mi_min = mi;
 583         mi_max = ma;
 584         MapInfo_Get_ByName(mi_shortname, 0, NULL);
 585         if(MapInfo_Map_mins.x < MapInfo_Map_maxs.x)
 586         {
 587                 mi_min = MapInfo_Map_mins;
 588                 mi_max = MapInfo_Map_maxs;
 589         }
 590         else
 591         {
 592                 // not specified
 593                 if(mode)
 594                 {
 595                         // be clever
 596                         tracebox('1 0 0' * mi.x,
 597                                          '0 1 0' * mi.y + '0 0 1' * mi.z,
 598                                          '0 1 0' * ma.y + '0 0 1' * ma.z,
 599                                          '1 0 0' * ma.x,
 600                                          MOVE_WORLDONLY,
 601                                          NULL);
 602                         if(!trace_startsolid)
 603                                 mi_min.x = trace_endpos.x;
 604
 605                         tracebox('0 1 0' * mi.y,
 606                                          '1 0 0' * mi.x + '0 0 1' * mi.z,
 607                                          '1 0 0' * ma.x + '0 0 1' * ma.z,
 608                                          '0 1 0' * ma.y,
 609                                          MOVE_WORLDONLY,
 610                                          NULL);
 611                         if(!trace_startsolid)
 612                                 mi_min.y = trace_endpos.y;
 613
 614                         tracebox('0 0 1' * mi.z,
 615                                          '1 0 0' * mi.x + '0 1 0' * mi.y,
 616                                          '1 0 0' * ma.x + '0 1 0' * ma.y,
 617                                          '0 0 1' * ma.z,
 618                                          MOVE_WORLDONLY,
 619                                          NULL);
 620                         if(!trace_startsolid)
 621                                 mi_min.z = trace_endpos.z;
 622
 623                         tracebox('1 0 0' * ma.x,
 624                                          '0 1 0' * mi.y + '0 0 1' * mi.z,
 625                                          '0 1 0' * ma.y + '0 0 1' * ma.z,
 626                                          '1 0 0' * mi.x,
 627                                          MOVE_WORLDONLY,
 628                                          NULL);
 629                         if(!trace_startsolid)
 630                                 mi_max.x = trace_endpos.x;
 631
 632                         tracebox('0 1 0' * ma.y,
 633                                          '1 0 0' * mi.x + '0 0 1' * mi.z,
 634                                          '1 0 0' * ma.x + '0 0 1' * ma.z,
 635                                          '0 1 0' * mi.y,
 636                                          MOVE_WORLDONLY,
 637                                          NULL);
 638                         if(!trace_startsolid)
 639                                 mi_max.y = trace_endpos.y;
 640
 641                         tracebox('0 0 1' * ma.z,
 642                                          '1 0 0' * mi.x + '0 1 0' * mi.y,
 643                                          '1 0 0' * ma.x + '0 1 0' * ma.y,
 644                                          '0 0 1' * mi.z,
 645                                          MOVE_WORLDONLY,
 646                                          NULL);
 647                         if(!trace_startsolid)
 648                                 mi_max.z = trace_endpos.z;
 649                 }
 650         }
 651 }
 652
 653 void get_mi_min_max_texcoords(float mode)
 654 {
 655         vector extend;
 656
 657         get_mi_min_max(mode);
 658
 659         mi_picmin = mi_min;
 660         mi_picmax = mi_max;
 661
 662         // extend mi_picmax to get a square aspect ratio
 663         // center the map in that area
 664         extend = mi_picmax - mi_picmin;
 665         if(extend.y > extend.x)
 666         {
 667                 mi_picmin.x -= (extend.y - extend.x) * 0.5;
 668                 mi_picmax.x += (extend.y - extend.x) * 0.5;
 669         }
 670         else
 671         {
 672                 mi_picmin.y -= (extend.x - extend.y) * 0.5;
 673                 mi_picmax.y += (extend.x - extend.y) * 0.5;
 674         }
 675
 676         // add another some percent
 677         extend = (mi_picmax - mi_picmin) * (1 / 64.0);
 678         mi_picmin -= extend;
 679         mi_picmax += extend;
 680
 681         // calculate the texcoords
 682         mi_pictexcoord0 = mi_pictexcoord1 = mi_pictexcoord2 = mi_pictexcoord3 = '0 0 0';
 683         // first the two corners of the origin
 684         mi_pictexcoord0_x = (mi_min.x - mi_picmin.x) / (mi_picmax.x - mi_picmin.x);
 685         mi_pictexcoord0_y = (mi_min.y - mi_picmin.y) / (mi_picmax.y - mi_picmin.y);
 686         mi_pictexcoord2_x = (mi_max.x - mi_picmin.x) / (mi_picmax.x - mi_picmin.x);
 687         mi_pictexcoord2_y = (mi_max.y - mi_picmin.y) / (mi_picmax.y - mi_picmin.y);
 688         // then the other corners
 689         mi_pictexcoord1_x = mi_pictexcoord0_x;
 690         mi_pictexcoord1_y = mi_pictexcoord2_y;
 691         mi_pictexcoord3_x = mi_pictexcoord2_x;
 692         mi_pictexcoord3_y = mi_pictexcoord0_y;
 693 }
 694 #endif
 695
 696 float cvar_settemp(string tmp_cvar, string tmp_value)
 697 {
 698         float created_saved_value;
 699
 700         created_saved_value = 0;
 701
 702         if (!(tmp_cvar || tmp_value))
 703         {
 704                 LOG_TRACE("Error: Invalid usage of cvar_settemp(string, string); !");
 705                 return 0;
 706         }
 707
 708         if(!cvar_type(tmp_cvar))
 709         {
 710                 LOG_INFOF("Error: cvar %s doesn't exist!", tmp_cvar);
 711                 return 0;
 712         }
 713
 714         IL_EACH(g_saved_cvars, it.netname == tmp_cvar,
 715         {
 716                 created_saved_value = -1; // skip creation
 717                 break; // no need to continue
 718         });
 719
 720         if(created_saved_value != -1)
 721         {
 722                 // creating a new entity to keep track of this cvar
 723                 entity e = new_pure(saved_cvar_value);
 724                 IL_PUSH(g_saved_cvars, e);
 725                 e.netname = strzone(tmp_cvar);
 726                 e.message = strzone(cvar_string(tmp_cvar));
 727                 created_saved_value = 1;
 728         }
 729
 730         // update the cvar to the value given
 731         cvar_set(tmp_cvar, tmp_value);
 732
 733         return created_saved_value;
 734 }
 735
 736 int cvar_settemp_restore()
 737 {
 738         int j = 0;
 739         // FIXME this new-style loop fails!
 740 #if 0
 741         FOREACH_ENTITY_CLASS("saved_cvar_value", true,
 742         {
 743                 if(cvar_type(it.netname))
 744                 {
 745                         cvar_set(it.netname, it.message);
 746                         strunzone(it.netname);
 747                         strunzone(it.message);
 748                         delete(it);
 749                         ++j;
 750                 }
 751                 else
 752                         LOG_INFOF("Error: cvar %s doesn't exist anymore! It can still be restored once it's manually recreated.", it.netname);
 753         });
 754
 755 #else
 756         entity e = NULL;
 757         while((e = find(e, classname, "saved_cvar_value")))
 758         {
 759                 if(cvar_type(e.netname))
 760                 {
 761                         cvar_set(e.netname, e.message);
 762                         delete(e);
 763                         ++j;
 764                 }
 765                 else
 766                         print(sprintf("Error: cvar %s doesn't exist anymore! It can still be restored once it's manually recreated.", e.netname));
 767         }
 768 #endif
 769
 770         return j;
 771 }
 772
 773 int skipIncompleteTag(string theText, float pos, int len)
 774 {
 775         int tag_start = -1;
 776
 777         if(substring(theText, pos - 1, 1) == "^")
 778         {
 779                 if(isCaretEscaped(theText, pos - 1) || pos >= len)
 780                         return 0;
 781
 782                 int ch = str2chr(theText, pos);
 783                 if(ch >= '0' && ch <= '9')
 784                         return 1; // ^[0-9] color code found
 785                 else if (ch == 'x')
 786                         tag_start = pos - 1; // ^x tag found
 787                 else
 788                         return 0;
 789         }
 790         else
 791         {
 792                 for(int i = 2; pos - i >= 0 && i <= 4; ++i)
 793                 {
 794                         if(substring(theText, pos - i, 2) == "^x")
 795                         {
 796                                 tag_start = pos - i; // ^x tag found
 797                                 break;
 798                         }
 799                 }
 800         }
 801
 802         if(tag_start >= 0)
 803         {
 804                 if(tag_start + 5 < len)
 805                 if(IS_HEXDIGIT(substring(theText, tag_start + 2, 1)))
 806                 if(IS_HEXDIGIT(substring(theText, tag_start + 3, 1)))
 807                 if(IS_HEXDIGIT(substring(theText, tag_start + 4, 1)))
 808                 {
 809                         if(!isCaretEscaped(theText, tag_start))
 810                                 return 5 - (pos - tag_start); // ^xRGB color code found
 811                 }
 812         }
 813         return 0;
 814 }
 815
 816 float textLengthUpToWidth(string theText, float maxWidth, vector theSize, textLengthUpToWidth_widthFunction_t w)
 817 {
 818         // STOP.
 819         // The following function is SLOW.
 820         // For your safety and for the protection of those around you...
 821         // DO NOT CALL THIS AT HOME.
 822         // No really, don't.
 823         if(w(theText, theSize) <= maxWidth)
 824                 return strlen(theText); // yeah!
 825
 826         bool colors = (w("^7", theSize) == 0);
 827
 828         // binary search for right place to cut string
 829         int len, left, right, middle;
 830         left = 0;
 831         right = len = strlen(theText);
 832         int ofs = 0;
 833         do
 834         {
 835                 middle = floor((left + right) / 2);
 836                 if(colors)
 837                         ofs = skipIncompleteTag(theText, middle, len);
 838                 if(w(substring(theText, 0, middle + ofs), theSize) <= maxWidth)
 839                         left = middle + ofs;
 840                 else
 841                         right = middle;
 842         }
 843         while(left < right - 1);
 844
 845         return left;
 846 }
 847
 848 float textLengthUpToLength(string theText, float maxWidth, textLengthUpToLength_lenFunction_t w)
 849 {
 850         // STOP.
 851         // The following function is SLOW.
 852         // For your safety and for the protection of those around you...
 853         // DO NOT CALL THIS AT HOME.
 854         // No really, don't.
 855         if(w(theText) <= maxWidth)
 856                 return strlen(theText); // yeah!
 857
 858         bool colors = (w("^7") == 0);
 859
 860         // binary search for right place to cut string
 861         int len, left, right, middle;
 862         left = 0;
 863         right = len = strlen(theText);
 864         int ofs = 0;
 865         do
 866         {
 867                 middle = floor((left + right) / 2);
 868                 if(colors)
 869                         ofs = skipIncompleteTag(theText, middle, len);
 870                 if(w(substring(theText, 0, middle + ofs)) <= maxWidth)
 871                         left = middle + ofs;
 872                 else
 873                         right = middle;
 874         }
 875         while(left < right - 1);
 876
 877         return left;
 878 }
 879
 880 string find_last_color_code(string s)
 881 {
 882         int start = strstrofs(s, "^", 0);
 883         if (start == -1) // no caret found
 884                 return "";
 885         int len = strlen(s)-1;
 886         for(int i = len; i >= start; --i)
 887         {
 888                 if(substring(s, i, 1) != "^")
 889                         continue;
 890
 891                 int carets = 1;
 892                 while (i-carets >= start && substring(s, i-carets, 1) == "^")
 893                         ++carets;
 894
 895                 // check if carets aren't all escaped
 896                 if (carets & 1)
 897                 {
 898                         if(i+1 <= len)
 899                         if(IS_DIGIT(substring(s, i+1, 1)))
 900                                 return substring(s, i, 2);
 901
 902                         if(i+4 <= len)
 903                         if(substring(s, i+1, 1) == "x")
 904                         if(IS_HEXDIGIT(substring(s, i + 2, 1)))
 905                         if(IS_HEXDIGIT(substring(s, i + 3, 1)))
 906                         if(IS_HEXDIGIT(substring(s, i + 4, 1)))
 907                                 return substring(s, i, 5);
 908                 }
 909                 i -= carets; // this also skips one char before the carets
 910         }
 911
 912         return "";
 913 }
 914
 915 string getWrappedLine(float w, vector theFontSize, textLengthUpToWidth_widthFunction_t tw)
 916 {
 917         string s = getWrappedLine_remaining;
 918
 919         if(w <= 0)
 920         {
 921                 getWrappedLine_remaining = string_null;
 922                 return s; // the line has no size ANYWAY, nothing would be displayed.
 923         }
 924
 925         int take_until = textLengthUpToWidth(s, w, theFontSize, tw);
 926         if(take_until > 0 && take_until < strlen(s))
 927         {
 928                 int last_word = take_until - 1;
 929                 while(last_word > 0 && substring(s, last_word, 1) != " ")
 930                         --last_word;
 931
 932                 int skip = 0;
 933                 if(last_word != 0)
 934                 {
 935                         take_until = last_word;
 936                         skip = 1;
 937                 }
 938
 939                 getWrappedLine_remaining = substring(s, take_until + skip, strlen(s) - take_until);
 940                 if(getWrappedLine_remaining == "")
 941                         getWrappedLine_remaining = string_null;
 942                 else if (tw("^7", theFontSize) == 0)
 943                         getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, take_until)), getWrappedLine_remaining);
 944                 return substring(s, 0, take_until);
 945         }
 946         else
 947         {
 948                 getWrappedLine_remaining = string_null;
 949                 return s;
 950         }
 951 }
 952
 953 string getWrappedLineLen(float w, textLengthUpToLength_lenFunction_t tw)
 954 {
 955         string s = getWrappedLine_remaining;
 956
 957         if(w <= 0)
 958         {
 959                 getWrappedLine_remaining = string_null;
 960                 return s; // the line has no size ANYWAY, nothing would be displayed.
 961         }
 962
 963         int take_until = textLengthUpToLength(s, w, tw);
 964         if(take_until > 0 && take_until < strlen(s))
 965         {
 966                 int last_word = take_until - 1;
 967                 while(last_word > 0 && substring(s, last_word, 1) != " ")
 968                         --last_word;
 969
 970                 int skip = 0;
 971                 if(last_word != 0)
 972                 {
 973                         take_until = last_word;
 974                         skip = 1;
 975                 }
 976
 977                 getWrappedLine_remaining = substring(s, take_until + skip, strlen(s) - take_until);
 978                 if(getWrappedLine_remaining == "")
 979                         getWrappedLine_remaining = string_null;
 980                 else if (tw("^7") == 0)
 981                         getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, take_until)), getWrappedLine_remaining);
 982                 return substring(s, 0, take_until);
 983         }
 984         else
 985         {
 986                 getWrappedLine_remaining = string_null;
 987                 return s;
 988         }
 989 }
 990
 991 string textShortenToWidth(string theText, float maxWidth, vector theFontSize, textLengthUpToWidth_widthFunction_t tw)
 992 {
 993         if(tw(theText, theFontSize) <= maxWidth)
 994                 return theText;
 995         else
 996                 return strcat(substring(theText, 0, textLengthUpToWidth(theText, maxWidth - tw("...", theFontSize), theFontSize, tw)), "...");
 997 }
 998
 999 string textShortenToLength(string theText, float maxWidth, textLengthUpToLength_lenFunction_t tw)
1000 {
1001         if(tw(theText) <= maxWidth)
1002                 return theText;
1003         else
1004                 return strcat(substring(theText, 0, textLengthUpToLength(theText, maxWidth - tw("..."), tw)), "...");
1005 }
1006
1007 float isGametypeInFilter(Gametype gt, float tp, float ts, string pattern)
1008 {
1009         string subpattern, subpattern2, subpattern3, subpattern4;
1010         subpattern = strcat(",", MapInfo_Type_ToString(gt), ",");
1011         if(tp)
1012                 subpattern2 = ",teams,";
1013         else
1014                 subpattern2 = ",noteams,";
1015         if(ts)
1016                 subpattern3 = ",teamspawns,";
1017         else
1018                 subpattern3 = ",noteamspawns,";
1019         if(gt == MAPINFO_TYPE_RACE || gt == MAPINFO_TYPE_CTS)
1020                 subpattern4 = ",race,";
1021         else
1022                 subpattern4 = string_null;
1023
1024         if(substring(pattern, 0, 1) == "-")
1025         {
1026                 pattern = substring(pattern, 1, strlen(pattern) - 1);
1027                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) >= 0)
1028                         return 0;
1029                 if(strstrofs(strcat(",", pattern, ","), subpattern2, 0) >= 0)
1030                         return 0;
1031                 if(strstrofs(strcat(",", pattern, ","), subpattern3, 0) >= 0)
1032                         return 0;
1033                 if(subpattern4 && strstrofs(strcat(",", pattern, ","), subpattern4, 0) >= 0)
1034                         return 0;
1035         }
1036         else
1037         {
1038                 if(substring(pattern, 0, 1) == "+")
1039                         pattern = substring(pattern, 1, strlen(pattern) - 1);
1040                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) < 0)
1041                 if(strstrofs(strcat(",", pattern, ","), subpattern2, 0) < 0)
1042                 if(strstrofs(strcat(",", pattern, ","), subpattern3, 0) < 0)
1043                 {
1044                         if (!subpattern4)
1045                                 return 0;
1046                         if(strstrofs(strcat(",", pattern, ","), subpattern4, 0) < 0)
1047                                 return 0;
1048                 }
1049         }
1050         return 1;
1051 }
1052
1053 vector solve_shotdirection(vector myorg, vector myvel, vector eorg, vector evel, float spd, float newton_style)
1054 {
1055         vector ret;
1056
1057         // make origin and speed relative
1058         eorg -= myorg;
1059         if(newton_style)
1060                 evel -= myvel;
1061
1062         // now solve for ret, ret normalized:
1063         //   eorg + t * evel == t * ret * spd
1064         // or, rather, solve for t:
1065         //   |eorg + t * evel| == t * spd
1066         //   eorg^2 + t^2 * evel^2 + 2 * t * (eorg * evel) == t^2 * spd^2
1067         //   t^2 * (evel^2 - spd^2) + t * (2 * (eorg * evel)) + eorg^2 == 0
1068         vector solution = solve_quadratic(evel * evel - spd * spd, 2 * (eorg * evel), eorg * eorg);
1069         // p = 2 * (eorg * evel) / (evel * evel - spd * spd)
1070         // q = (eorg * eorg) / (evel * evel - spd * spd)
1071         if(!solution.z) // no real solution
1072         {
1073                 // happens if D < 0
1074                 // (eorg * evel)^2 < (evel^2 - spd^2) * eorg^2
1075                 // (eorg * evel)^2 / eorg^2 < evel^2 - spd^2
1076                 // spd^2 < ((evel^2 * eorg^2) - (eorg * evel)^2) / eorg^2
1077                 // spd^2 < evel^2 * (1 - cos^2 angle(evel, eorg))
1078                 // spd^2 < evel^2 * sin^2 angle(evel, eorg)
1079                 // spd < |evel| * sin angle(evel, eorg)
1080                 return '0 0 0';
1081         }
1082         else if(solution.x > 0)
1083         {
1084                 // both solutions > 0: take the smaller one
1085                 // happens if p < 0 and q > 0
1086                 ret = normalize(eorg + solution.x * evel);
1087         }
1088         else if(solution.y > 0)
1089         {
1090                 // one solution > 0: take the larger one
1091                 // happens if q < 0 or q == 0 and p < 0
1092                 ret = normalize(eorg + solution.y * evel);
1093         }
1094         else
1095         {
1096                 // no solution > 0: reject
1097                 // happens if p > 0 and q >= 0
1098                 // 2 * (eorg * evel) / (evel * evel - spd * spd) > 0
1099                 // (eorg * eorg) / (evel * evel - spd * spd) >= 0
1100                 //
1101                 // |evel| >= spd
1102                 // eorg * evel > 0
1103                 //
1104                 // "Enemy is moving away from me at more than spd"
1105                 return '0 0 0';
1106         }
1107
1108         // NOTE: we always got a solution if spd > |evel|
1109
1110         if(newton_style == 2)
1111                 ret = normalize(ret * spd + myvel);
1112
1113         return ret;
1114 }
1115
1116 vector get_shotvelocity(vector myvel, vector mydir, float spd, float newton_style, float mi, float ma)
1117 {
1118         if(!newton_style)
1119                 return spd * mydir;
1120
1121         if(newton_style == 2)
1122         {
1123                 // true Newtonian projectiles with automatic aim adjustment
1124                 //
1125                 // solve: |outspeed * mydir - myvel| = spd
1126                 // outspeed^2 - 2 * outspeed * (mydir * myvel) + myvel^2 - spd^2 = 0
1127                 // outspeed = (mydir * myvel) +- sqrt((mydir * myvel)^2 - myvel^2 + spd^2)
1128                 // PLUS SIGN!
1129                 // not defined?
1130                 // then...
1131                 // myvel^2 - (mydir * myvel)^2 > spd^2
1132                 // velocity without mydir component > spd
1133                 // fire at smallest possible spd that works?
1134                 // |(mydir * myvel) * myvel - myvel| = spd
1135
1136                 vector solution = solve_quadratic(1, -2 * (mydir * myvel), myvel * myvel - spd * spd);
1137
1138                 float outspeed;
1139                 if(solution.z)
1140                         outspeed = solution.y; // the larger one
1141                 else
1142                 {
1143                         //outspeed = 0; // slowest possible shot
1144                         outspeed = solution.x; // the real part (that is, the average!)
1145                         //dprint("impossible shot, adjusting\n");
1146                 }
1147
1148                 outspeed = bound(spd * mi, outspeed, spd * ma);
1149                 return mydir * outspeed;
1150         }
1151
1152         // real Newtonian
1153         return myvel + spd * mydir;
1154 }
1155
1156 float compressShotOrigin(vector v)
1157 {
1158         float rx = rint(v.x * 2);
1159         float ry = rint(v.y * 4) + 128;
1160         float rz = rint(v.z * 4) + 128;
1161         if(rx > 255 || rx < 0)
1162         {
1163                 LOG_DEBUG("shot origin ", vtos(v), " x out of bounds\n");
1164                 rx = bound(0, rx, 255);
1165         }
1166         if(ry > 255 || ry < 0)
1167         {
1168                 LOG_DEBUG("shot origin ", vtos(v), " y out of bounds\n");
1169                 ry = bound(0, ry, 255);
1170         }
1171         if(rz > 255 || rz < 0)
1172         {
1173                 LOG_DEBUG("shot origin ", vtos(v), " z out of bounds\n");
1174                 rz = bound(0, rz, 255);
1175         }
1176         return rx * 0x10000 + ry * 0x100 + rz;
1177 }
1178 vector decompressShotOrigin(int f)
1179 {
1180         vector v;
1181         v.x = ((f & 0xFF0000) / 0x10000) / 2;
1182         v.y = ((f & 0xFF00) / 0x100 - 128) / 4;
1183         v.z = ((f & 0xFF) - 128) / 4;
1184         return v;
1185 }
1186
1187 #ifdef GAMEQC
1188 vector healtharmor_maxdamage(float h, float a, float armorblock, int deathtype)
1189 {
1190         // NOTE: we'll always choose the SMALLER value...
1191         float healthdamage, armordamage, armorideal;
1192         if (DEATH_IS(deathtype, DEATH_DROWN))  // Why should armor help here...
1193                 armorblock = 0;
1194         vector v;
1195         healthdamage = (h - 1) / (1 - armorblock); // damage we can take if we could use more health
1196         armordamage = a + (h - 1); // damage we can take if we could use more armor
1197         armorideal = healthdamage * armorblock;
1198         v.y = armorideal;
1199         if(armordamage < healthdamage)
1200         {
1201                 v.x = armordamage;
1202                 v.z = 1;
1203         }
1204         else
1205         {
1206                 v.x = healthdamage;
1207                 v.z = 0;
1208         }
1209         return v;
1210 }
1211
1212 vector healtharmor_applydamage(float a, float armorblock, int deathtype, float damage)
1213 {
1214         vector v;
1215         if (DEATH_IS(deathtype, DEATH_DROWN))  // Why should armor help here...
1216                 armorblock = 0;
1217         if (deathtype & HITTYPE_ARMORPIERCE)
1218                 armorblock = 0;
1219         v.y = bound(0, damage * armorblock, a); // save
1220         v.x = bound(0, damage - v.y, damage); // take
1221         v.z = 0;
1222         return v;
1223 }
1224 #endif
1225
1226 string getcurrentmod()
1227 {
1228         float n;
1229         string m;
1230         m = cvar_string("fs_gamedir");
1231         n = tokenize_console(m);
1232         if(n == 0)
1233                 return "data";
1234         else
1235                 return argv(n - 1);
1236 }
1237
1238 float matchacl(string acl, string str)
1239 {
1240         string t, s;
1241         float r, d;
1242         r = 0;
1243         while(acl)
1244         {
1245                 t = car(acl); acl = cdr(acl);
1246
1247                 d = 1;
1248                 if(substring(t, 0, 1) == "-")
1249                 {
1250                         d = -1;
1251                         t = substring(t, 1, strlen(t) - 1);
1252                 }
1253                 else if(substring(t, 0, 1) == "+")
1254                         t = substring(t, 1, strlen(t) - 1);
1255
1256                 if(substring(t, -1, 1) == "*")
1257                 {
1258                         t = substring(t, 0, strlen(t) - 1);
1259                         s = substring(str, 0, strlen(t));
1260                 }
1261                 else
1262                         s = str;
1263
1264                 if(s == t)
1265                 {
1266                         r = d;
1267                         break; // if we found a killing case, apply it! other settings may be allowed in the future, but this one is caught
1268                 }
1269         }
1270         return r;
1271 }
1272
1273 ERASEABLE
1274 void write_String_To_File(int fh, string str, bool alsoprint)
1275 {
1276         fputs(fh, str);
1277         if (alsoprint) LOG_INFO(str);
1278 }
1279
1280 string get_model_datafilename(string m, float sk, string fil)
1281 {
1282         if(m)
1283                 m = strcat(m, "_");
1284         else
1285                 m = "models/player/*_";
1286         if(sk >= 0)
1287                 m = strcat(m, ftos(sk));
1288         else
1289                 m = strcat(m, "*");
1290         return strcat(m, ".", fil);
1291 }
1292
1293 float get_model_parameters(string m, float sk)
1294 {
1295         get_model_parameters_modelname = string_null;
1296         get_model_parameters_modelskin = -1;
1297         get_model_parameters_name = string_null;
1298         get_model_parameters_species = -1;
1299         get_model_parameters_sex = string_null;
1300         get_model_parameters_weight = -1;
1301         get_model_parameters_age = -1;
1302         get_model_parameters_desc = string_null;
1303         get_model_parameters_bone_upperbody = string_null;
1304         get_model_parameters_bone_weapon = string_null;
1305         for(int i = 0; i < MAX_AIM_BONES; ++i)
1306         {
1307                 get_model_parameters_bone_aim[i] = string_null;
1308                 get_model_parameters_bone_aimweight[i] = 0;
1309         }
1310         get_model_parameters_fixbone = 0;
1311         get_model_parameters_hidden = false;
1312
1313 #ifdef GAMEQC
1314         MUTATOR_CALLHOOK(ClearModelParams);
1315 #endif
1316
1317         if (!m)
1318                 return 1;
1319
1320         if(substring(m, -9, 5) == "_lod1" || substring(m, -9, 5) == "_lod2")
1321                 m = strcat(substring(m, 0, -10), substring(m, -4, -1));
1322
1323         if(sk < 0)
1324         {
1325                 if(substring(m, -4, -1) != ".txt")
1326                         return 0;
1327                 if(substring(m, -6, 1) != "_")
1328                         return 0;
1329                 sk = stof(substring(m, -5, 1));
1330                 m = substring(m, 0, -7);
1331         }
1332
1333         string fn = get_model_datafilename(m, sk, "txt");
1334         int fh = fopen(fn, FILE_READ);
1335         if(fh < 0)
1336         {
1337                 sk = 0;
1338                 fn = get_model_datafilename(m, sk, "txt");
1339                 fh = fopen(fn, FILE_READ);
1340                 if(fh < 0)
1341                         return 0;
1342         }
1343
1344         get_model_parameters_modelname = m;
1345         get_model_parameters_modelskin = sk;
1346         string s, c;
1347         while((s = fgets(fh)))
1348         {
1349                 if(s == "")
1350                         break; // next lines will be description
1351                 c = car(s);
1352                 s = cdr(s);
1353                 if(c == "name")
1354                         get_model_parameters_name = s;
1355                 if(c == "species")
1356                         switch(s)
1357                         {
1358                                 case "human":       get_model_parameters_species = SPECIES_HUMAN;       break;
1359                                 case "alien":       get_model_parameters_species = SPECIES_ALIEN;       break;
1360                                 case "robot_shiny": get_model_parameters_species = SPECIES_ROBOT_SHINY; break;
1361                                 case "robot_rusty": get_model_parameters_species = SPECIES_ROBOT_RUSTY; break;
1362                                 case "robot_solid": get_model_parameters_species = SPECIES_ROBOT_SOLID; break;
1363                                 case "animal":      get_model_parameters_species = SPECIES_ANIMAL;      break;
1364                                 case "reserved":    get_model_parameters_species = SPECIES_RESERVED;    break;
1365                         }
1366                 if(c == "sex")
1367                 {
1368                         if (s == "Male")                                s = _("Male");
1369                         else if (s == "Female")                 s = _("Female");
1370                         else if (s == "Undisclosed")    s = _("Undisclosed");
1371                         get_model_parameters_sex = s;
1372                 }
1373                 if(c == "weight")
1374                         get_model_parameters_weight = stof(s);
1375                 if(c == "age")
1376                         get_model_parameters_age = stof(s);
1377                 if(c == "description")
1378                         get_model_parameters_description = s;
1379                 if(c == "bone_upperbody")
1380                         get_model_parameters_bone_upperbody = s;
1381                 if(c == "bone_weapon")
1382                         get_model_parameters_bone_weapon = s;
1383         #ifdef GAMEQC
1384                 MUTATOR_CALLHOOK(GetModelParams, c, s);
1385         #endif
1386                 for(int i = 0; i < MAX_AIM_BONES; ++i)
1387                         if(c == strcat("bone_aim", ftos(i)))
1388                         {
1389                                 get_model_parameters_bone_aimweight[i] = stof(car(s));
1390                                 get_model_parameters_bone_aim[i] = cdr(s);
1391                         }
1392                 if(c == "fixbone")
1393                         get_model_parameters_fixbone = stof(s);
1394                 if(c == "hidden")
1395                         get_model_parameters_hidden = stob(s);
1396         }
1397
1398         while((s = fgets(fh)))
1399         {
1400                 if(get_model_parameters_desc)
1401                         get_model_parameters_desc = strcat(get_model_parameters_desc, "\n");
1402                 if(s != "")
1403                         get_model_parameters_desc = strcat(get_model_parameters_desc, s);
1404         }
1405
1406         fclose(fh);
1407
1408         return 1;
1409 }
1410
1411 string translate_key(string key)
1412 {
1413         if (prvm_language == "en") return key;
1414
1415         if (substring(key, 0, 1) == "<")
1416         {
1417                 if (key == "<KEY NOT FOUND>") return _("<KEY NOT FOUND>");
1418                 if (key == "<UNKNOWN KEYNUM>") return _("<UNKNOWN KEYNUM>");
1419         }
1420
1421         switch(key)
1422         {
1423                 case "TAB":                             return _("TAB");
1424                 case "ENTER":                   return _("ENTER");
1425                 case "ESCAPE":                  return _("ESCAPE");
1426                 case "SPACE":                   return _("SPACE");
1427
1428                 case "BACKSPACE":               return _("BACKSPACE");
1429                 case "UPARROW":                 return _("UPARROW");
1430                 case "DOWNARROW":               return _("DOWNARROW");
1431                 case "LEFTARROW":               return _("LEFTARROW");
1432                 case "RIGHTARROW":              return _("RIGHTARROW");
1433
1434                 case "ALT":                             return _("ALT");
1435                 case "CTRL":                    return _("CTRL");
1436                 case "SHIFT":                   return _("SHIFT");
1437
1438                 case "INS":                             return _("INS");
1439                 case "DEL":                             return _("DEL");
1440                 case "PGDN":                    return _("PGDN");
1441                 case "PGUP":                    return _("PGUP");
1442                 case "HOME":                    return _("HOME");
1443                 case "END":                             return _("END");
1444
1445                 case "PAUSE":                   return _("PAUSE");
1446
1447                 case "NUMLOCK":                 return _("NUMLOCK");
1448                 case "CAPSLOCK":                return _("CAPSLOCK");
1449                 case "SCROLLOCK":               return _("SCROLLOCK");
1450
1451                 case "SEMICOLON":               return _("SEMICOLON");
1452                 case "TILDE":                   return _("TILDE");
1453                 case "BACKQUOTE":               return _("BACKQUOTE");
1454                 case "QUOTE":                   return _("QUOTE");
1455                 case "APOSTROPHE":              return _("APOSTROPHE");
1456                 case "BACKSLASH":               return _("BACKSLASH");
1457         }
1458
1459         if (substring(key, 0, 1) == "F")
1460         {
1461                 string subkey = substring(key, 1, -1);
1462                 if (IS_DIGIT(substring(key, 3, 1))) // check only first digit
1463                 {
1464                         return sprintf(_("F%d"), stof(subkey));
1465                 }
1466                 // continue in case there is another key name starting with F
1467         }
1468
1469         if (substring(key, 0, 3) == "KP_")
1470         {
1471                 string subkey = substring(key, 3, -1);
1472                 if (IS_DIGIT(substring(key, 3, 1))) // check only first digit
1473                 {
1474                         return sprintf(_("KP_%d"), stof(subkey));
1475                 }
1476
1477                 switch(subkey)
1478                 {
1479                         case "INS":                             return sprintf(_("KP_%s"), _("INS"));
1480                         case "END":                             return sprintf(_("KP_%s"), _("END"));
1481                         case "DOWNARROW":               return sprintf(_("KP_%s"), _("DOWNARROW"));
1482                         case "PGDN":                    return sprintf(_("KP_%s"), _("PGDN"));
1483                         case "LEFTARROW":               return sprintf(_("KP_%s"), _("LEFTARROW"));
1484                         case "RIGHTARROW":              return sprintf(_("KP_%s"), _("RIGHTARROW"));
1485                         case "HOME":                    return sprintf(_("KP_%s"), _("HOME"));
1486                         case "UPARROW":                 return sprintf(_("KP_%s"), _("UPARROW"));
1487                         case "PGUP":                    return sprintf(_("KP_%s"), _("PGUP"));
1488                         case "PERIOD":                  return sprintf(_("KP_%s"), _("PERIOD"));
1489                         case "DEL":                             return sprintf(_("KP_%s"), _("DEL"));
1490                         case "DIVIDE":                  return sprintf(_("KP_%s"), _("DIVIDE"));
1491                         case "SLASH":                   return sprintf(_("KP_%s"), _("SLASH"));
1492                         case "MULTIPLY":                return sprintf(_("KP_%s"), _("MULTIPLY"));
1493                         case "MINUS":                   return sprintf(_("KP_%s"), _("MINUS"));
1494                         case "PLUS":                    return sprintf(_("KP_%s"), _("PLUS"));
1495                         case "ENTER":                   return sprintf(_("KP_%s"), _("ENTER"));
1496                         case "EQUALS":                  return sprintf(_("KP_%s"), _("EQUALS"));
1497                         default:                                return key;
1498                 }
1499         }
1500
1501         if (key == "PRINTSCREEN") return _("PRINTSCREEN");
1502
1503         if (substring(key, 0, 5) == "MOUSE")
1504                 return sprintf(_("MOUSE%d"), stof(substring(key, 5, -1)));
1505
1506         if (key == "MWHEELUP") return _("MWHEELUP");
1507         if (key == "MWHEELDOWN") return _("MWHEELDOWN");
1508
1509         if (substring(key, 0,3) == "JOY")
1510                 return sprintf(_("JOY%d"), stof(substring(key, 3, -1)));
1511
1512         if (substring(key, 0,3) == "AUX")
1513                 return sprintf(_("AUX%d"), stof(substring(key, 3, -1)));
1514
1515         if (substring(key, 0, 4) == "X360_")
1516         {
1517                 string subkey = substring(key, 4, -1);
1518                 switch(subkey)
1519                 {
1520                         case "DPAD_UP":                                 return sprintf(_("X360_%s"), _("DPAD_UP"));
1521                         case "DPAD_DOWN":                               return sprintf(_("X360_%s"), _("DPAD_DOWN"));
1522                         case "DPAD_LEFT":                               return sprintf(_("X360_%s"), _("DPAD_LEFT"));
1523                         case "DPAD_RIGHT":                              return sprintf(_("X360_%s"), _("DPAD_RIGHT"));
1524                         case "START":                                   return sprintf(_("X360_%s"), _("START"));
1525                         case "BACK":                                    return sprintf(_("X360_%s"), _("BACK"));
1526                         case "LEFT_THUMB":                              return sprintf(_("X360_%s"), _("LEFT_THUMB"));
1527                         case "RIGHT_THUMB":                             return sprintf(_("X360_%s"), _("RIGHT_THUMB"));
1528                         case "LEFT_SHOULDER":                   return sprintf(_("X360_%s"), _("LEFT_SHOULDER"));
1529                         case "RIGHT_SHOULDER":                  return sprintf(_("X360_%s"), _("RIGHT_SHOULDER"));
1530                         case "LEFT_TRIGGER":                    return sprintf(_("X360_%s"), _("LEFT_TRIGGER"));
1531                         case "RIGHT_TRIGGER":                   return sprintf(_("X360_%s"), _("RIGHT_TRIGGER"));
1532                         case "LEFT_THUMB_UP":                   return sprintf(_("X360_%s"), _("LEFT_THUMB_UP"));
1533                         case "LEFT_THUMB_DOWN":                 return sprintf(_("X360_%s"), _("LEFT_THUMB_DOWN"));
1534                         case "LEFT_THUMB_LEFT":                 return sprintf(_("X360_%s"), _("LEFT_THUMB_LEFT"));
1535                         case "LEFT_THUMB_RIGHT":                return sprintf(_("X360_%s"), _("LEFT_THUMB_RIGHT"));
1536                         case "RIGHT_THUMB_UP":                  return sprintf(_("X360_%s"), _("RIGHT_THUMB_UP"));
1537                         case "RIGHT_THUMB_DOWN":                return sprintf(_("X360_%s"), _("RIGHT_THUMB_DOWN"));
1538                         case "RIGHT_THUMB_LEFT":                return sprintf(_("X360_%s"), _("RIGHT_THUMB_LEFT"));
1539                         case "RIGHT_THUMB_RIGHT":               return sprintf(_("X360_%s"), _("RIGHT_THUMB_RIGHT"));
1540                         default:                                                return key;
1541                 }
1542         }
1543
1544         if (substring(key, 0, 4) == "JOY_")
1545         {
1546                 string subkey = substring(key, 4, -1);
1547                 switch(subkey)
1548                 {
1549                         case "UP":                      return sprintf(_("JOY_%s"), _("UP"));
1550                         case "DOWN":            return sprintf(_("JOY_%s"), _("DOWN"));
1551                         case "LEFT":            return sprintf(_("JOY_%s"), _("LEFT"));
1552                         case "RIGHT":           return sprintf(_("JOY_%s"), _("RIGHT"));
1553                         default:                        return key;
1554                 }
1555         }
1556
1557         if (substring(key, 0, 8) == "MIDINOTE")
1558                 return sprintf(_("MIDINOTE%d"), stof(substring(key, 8, -1)));
1559
1560         return key;
1561 }
1562
1563 // x-encoding (encoding as zero length invisible string)
1564 const string XENCODE_2  = "xX";
1565 const string XENCODE_22 = "0123456789abcdefABCDEF";
1566 string xencode(int f)
1567 {
1568         float a, b, c, d;
1569         d = f % 22; f = floor(f / 22);
1570         c = f % 22; f = floor(f / 22);
1571         b = f % 22; f = floor(f / 22);
1572         a = f %  2; // f = floor(f /  2);
1573         return strcat(
1574                 "^",
1575                 substring(XENCODE_2,  a, 1),
1576                 substring(XENCODE_22, b, 1),
1577                 substring(XENCODE_22, c, 1),
1578                 substring(XENCODE_22, d, 1)
1579         );
1580 }
1581 float xdecode(string s)
1582 {
1583         float a, b, c, d;
1584         if(substring(s, 0, 1) != "^")
1585                 return -1;
1586         if(strlen(s) < 5)
1587                 return -1;
1588         a = strstrofs(XENCODE_2,  substring(s, 1, 1), 0);
1589         b = strstrofs(XENCODE_22, substring(s, 2, 1), 0);
1590         c = strstrofs(XENCODE_22, substring(s, 3, 1), 0);
1591         d = strstrofs(XENCODE_22, substring(s, 4, 1), 0);
1592         if(a < 0 || b < 0 || c < 0 || d < 0)
1593                 return -1;
1594         return ((a * 22 + b) * 22 + c) * 22 + d;
1595 }
1596
1597 /*
1598 string strlimitedlen(string input, string truncation, float strip_colors, float limit)
1599 {
1600         if(strlen((strip_colors ? strdecolorize(input) : input)) <= limit)
1601                 return input;
1602         else
1603                 return strcat(substring(input, 0, (strlen(input) - strlen(truncation))), truncation);
1604 }*/
1605
1606 float shutdown_running;
1607 #ifdef SVQC
1608 void SV_Shutdown()
1609 #endif
1610 #ifdef CSQC
1611 void CSQC_Shutdown()
1612 #endif
1613 #ifdef MENUQC
1614 void m_shutdown()
1615 #endif
1616 {
1617         if(shutdown_running)
1618         {
1619                 LOG_INFO("Recursive shutdown detected! Only restoring cvars...");
1620         }
1621         else
1622         {
1623                 shutdown_running = 1;
1624                 Shutdown();
1625                 shutdownhooks();
1626         }
1627         cvar_settemp_restore(); // this must be done LAST, but in any case
1628 }
1629
1630 #ifdef GAMEQC
1631 .float skeleton_bones_index;
1632 void Skeleton_SetBones(entity e)
1633 {
1634         // set skeleton_bones to the total number of bones on the model
1635         if(e.skeleton_bones_index == e.modelindex)
1636                 return; // same model, nothing to update
1637
1638         float skelindex;
1639         skelindex = skel_create(e.modelindex);
1640         e.skeleton_bones = skel_get_numbones(skelindex);
1641         skel_delete(skelindex);
1642         e.skeleton_bones_index = e.modelindex;
1643 }
1644 #endif
1645
1646 string to_execute_next_frame;
1647 void execute_next_frame()
1648 {
1649         if(to_execute_next_frame)
1650         {
1651                 localcmd("\n", to_execute_next_frame, "\n");
1652                 strfree(to_execute_next_frame);
1653         }
1654 }
1655 void queue_to_execute_next_frame(string s)
1656 {
1657         if(to_execute_next_frame)
1658         {
1659                 s = strcat(s, "\n", to_execute_next_frame);
1660         }
1661         strcpy(to_execute_next_frame, s);
1662 }
1663
1664 .float FindConnectedComponent_processing;
1665 void FindConnectedComponent(entity e, .entity fld, findNextEntityNearFunction_t nxt, isConnectedFunction_t iscon, entity pass)
1666 {
1667         entity queue_start, queue_end;
1668
1669         // we build a queue of to-be-processed entities.
1670         // queue_start is the next entity to be checked for neighbors
1671         // queue_end is the last entity added
1672
1673         if(e.FindConnectedComponent_processing)
1674                 error("recursion or broken cleanup");
1675
1676         // start with a 1-element queue
1677         queue_start = queue_end = e;
1678         queue_end.(fld) = NULL;
1679         queue_end.FindConnectedComponent_processing = 1;
1680
1681         // for each queued item:
1682         for (; queue_start; queue_start = queue_start.(fld))
1683         {
1684                 // find all neighbors of queue_start
1685                 entity t;
1686                 for(t = NULL; (t = nxt(t, queue_start, pass)); )
1687                 {
1688                         if(t.FindConnectedComponent_processing)
1689                                 continue;
1690                         if(iscon(t, queue_start, pass))
1691                         {
1692                                 // it is connected? ADD IT. It will look for neighbors soon too.
1693                                 queue_end.(fld) = t;
1694                                 queue_end = t;
1695                                 queue_end.(fld) = NULL;
1696                                 queue_end.FindConnectedComponent_processing = 1;
1697                         }
1698                 }
1699         }
1700
1701         // unmark
1702         for (queue_start = e; queue_start; queue_start = queue_start.(fld))
1703                 queue_start.FindConnectedComponent_processing = 0;
1704 }
1705
1706 #ifdef GAMEQC
1707 vector animfixfps(entity e, vector a, vector b)
1708 {
1709         // multi-frame anim: keep as-is
1710         if(a.y == 1)
1711         {
1712                 float dur = frameduration(e.modelindex, a.x);
1713                 if (dur <= 0 && b.y)
1714                 {
1715                         a = b;
1716                         dur = frameduration(e.modelindex, a.x);
1717                 }
1718                 if (dur > 0)
1719                         a.z = 1.0 / dur;
1720         }
1721         return a;
1722 }
1723 #endif
1724
1725 #ifdef GAMEQC
1726 Notification Announcer_PickNumber(int type, int num)
1727 {
1728     return = NULL;
1729         switch (type)
1730         {
1731                 case CNT_GAMESTART:
1732                 {
1733                         switch(num)
1734                         {
1735                                 case 10: return ANNCE_NUM_GAMESTART_10;
1736                                 case 9:  return ANNCE_NUM_GAMESTART_9;
1737                                 case 8:  return ANNCE_NUM_GAMESTART_8;
1738                                 case 7:  return ANNCE_NUM_GAMESTART_7;
1739                                 case 6:  return ANNCE_NUM_GAMESTART_6;
1740                                 case 5:  return ANNCE_NUM_GAMESTART_5;
1741                                 case 4:  return ANNCE_NUM_GAMESTART_4;
1742                                 case 3:  return ANNCE_NUM_GAMESTART_3;
1743                                 case 2:  return ANNCE_NUM_GAMESTART_2;
1744                                 case 1:  return ANNCE_NUM_GAMESTART_1;
1745                         }
1746                         break;
1747                 }
1748                 case CNT_IDLE:
1749                 {
1750                         switch(num)
1751                         {
1752                                 case 10: return ANNCE_NUM_IDLE_10;
1753                                 case 9:  return ANNCE_NUM_IDLE_9;
1754                                 case 8:  return ANNCE_NUM_IDLE_8;
1755                                 case 7:  return ANNCE_NUM_IDLE_7;
1756                                 case 6:  return ANNCE_NUM_IDLE_6;
1757                                 case 5:  return ANNCE_NUM_IDLE_5;
1758                                 case 4:  return ANNCE_NUM_IDLE_4;
1759                                 case 3:  return ANNCE_NUM_IDLE_3;
1760                                 case 2:  return ANNCE_NUM_IDLE_2;
1761                                 case 1:  return ANNCE_NUM_IDLE_1;
1762                         }
1763                         break;
1764                 }
1765                 case CNT_KILL:
1766                 {
1767                         switch(num)
1768                         {
1769                                 case 10: return ANNCE_NUM_KILL_10;
1770                                 case 9:  return ANNCE_NUM_KILL_9;
1771                                 case 8:  return ANNCE_NUM_KILL_8;
1772                                 case 7:  return ANNCE_NUM_KILL_7;
1773                                 case 6:  return ANNCE_NUM_KILL_6;
1774                                 case 5:  return ANNCE_NUM_KILL_5;
1775                                 case 4:  return ANNCE_NUM_KILL_4;
1776                                 case 3:  return ANNCE_NUM_KILL_3;
1777                                 case 2:  return ANNCE_NUM_KILL_2;
1778                                 case 1:  return ANNCE_NUM_KILL_1;
1779                         }
1780                         break;
1781                 }
1782                 case CNT_RESPAWN:
1783                 {
1784                         switch(num)
1785                         {
1786                                 case 10: return ANNCE_NUM_RESPAWN_10;
1787                                 case 9:  return ANNCE_NUM_RESPAWN_9;
1788                                 case 8:  return ANNCE_NUM_RESPAWN_8;
1789                                 case 7:  return ANNCE_NUM_RESPAWN_7;
1790                                 case 6:  return ANNCE_NUM_RESPAWN_6;
1791                                 case 5:  return ANNCE_NUM_RESPAWN_5;
1792                                 case 4:  return ANNCE_NUM_RESPAWN_4;
1793                                 case 3:  return ANNCE_NUM_RESPAWN_3;
1794                                 case 2:  return ANNCE_NUM_RESPAWN_2;
1795                                 case 1:  return ANNCE_NUM_RESPAWN_1;
1796                         }
1797                         break;
1798                 }
1799                 case CNT_ROUNDSTART:
1800                 {
1801                         switch(num)
1802                         {
1803                                 case 10: return ANNCE_NUM_ROUNDSTART_10;
1804                                 case 9:  return ANNCE_NUM_ROUNDSTART_9;
1805                                 case 8:  return ANNCE_NUM_ROUNDSTART_8;
1806                                 case 7:  return ANNCE_NUM_ROUNDSTART_7;
1807                                 case 6:  return ANNCE_NUM_ROUNDSTART_6;
1808                                 case 5:  return ANNCE_NUM_ROUNDSTART_5;
1809                                 case 4:  return ANNCE_NUM_ROUNDSTART_4;
1810                                 case 3:  return ANNCE_NUM_ROUNDSTART_3;
1811                                 case 2:  return ANNCE_NUM_ROUNDSTART_2;
1812                                 case 1:  return ANNCE_NUM_ROUNDSTART_1;
1813                         }
1814                         break;
1815                 }
1816                 default:
1817                 {
1818                         switch(num)
1819                         {
1820                                 case 10: return ANNCE_NUM_10;
1821                                 case 9:  return ANNCE_NUM_9;
1822                                 case 8:  return ANNCE_NUM_8;
1823                                 case 7:  return ANNCE_NUM_7;
1824                                 case 6:  return ANNCE_NUM_6;
1825                                 case 5:  return ANNCE_NUM_5;
1826                                 case 4:  return ANNCE_NUM_4;
1827                                 case 3:  return ANNCE_NUM_3;
1828                                 case 2:  return ANNCE_NUM_2;
1829                                 case 1:  return ANNCE_NUM_1;
1830                         }
1831                         break;
1832                 }
1833         }
1834 }
1835 #endif
1836
1837 #ifdef GAMEQC
1838 int Mod_Q1BSP_SuperContentsFromNativeContents(int nativecontents)
1839 {
1840         switch(nativecontents)
1841         {
1842                 case CONTENT_EMPTY:
1843                         return 0;
1844                 case CONTENT_SOLID:
1845                         return DPCONTENTS_SOLID | DPCONTENTS_OPAQUE;
1846                 case CONTENT_WATER:
1847                         return DPCONTENTS_WATER;
1848                 case CONTENT_SLIME:
1849                         return DPCONTENTS_SLIME;
1850                 case CONTENT_LAVA:
1851                         return DPCONTENTS_LAVA | DPCONTENTS_NODROP;
1852                 case CONTENT_SKY:
1853                         return DPCONTENTS_SKY | DPCONTENTS_NODROP | DPCONTENTS_OPAQUE; // to match behaviour of Q3 maps, let sky count as opaque
1854         }
1855         return 0;
1856 }
1857
1858 int Mod_Q1BSP_NativeContentsFromSuperContents(int supercontents)
1859 {
1860         if(supercontents & (DPCONTENTS_SOLID | DPCONTENTS_BODY))
1861                 return CONTENT_SOLID;
1862         if(supercontents & DPCONTENTS_SKY)
1863                 return CONTENT_SKY;
1864         if(supercontents & DPCONTENTS_LAVA)
1865                 return CONTENT_LAVA;
1866         if(supercontents & DPCONTENTS_SLIME)
1867                 return CONTENT_SLIME;
1868         if(supercontents & DPCONTENTS_WATER)
1869                 return CONTENT_WATER;
1870         return CONTENT_EMPTY;
1871 }
1872 #endif
1873
1874 #ifdef SVQC
1875 void attach_sameorigin(entity e, entity to, string tag)
1876 {
1877     vector org, t_forward, t_left, t_up, e_forward, e_up;
1878     float tagscale;
1879
1880     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1881     tagscale = (vlen(v_forward) ** -2); // undo a scale on the tag
1882     t_forward = v_forward * tagscale;
1883     t_left = v_right * -tagscale;
1884     t_up = v_up * tagscale;
1885
1886     e.origin_x = org * t_forward;
1887     e.origin_y = org * t_left;
1888     e.origin_z = org * t_up;
1889
1890     // current forward and up directions
1891     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1892                 e.angles = AnglesTransform_FromVAngles(e.angles);
1893         else
1894                 e.angles = AnglesTransform_FromAngles(e.angles);
1895     fixedmakevectors(e.angles);
1896
1897     // untransform forward, up!
1898     e_forward.x = v_forward * t_forward;
1899     e_forward.y = v_forward * t_left;
1900     e_forward.z = v_forward * t_up;
1901     e_up.x = v_up * t_forward;
1902     e_up.y = v_up * t_left;
1903     e_up.z = v_up * t_up;
1904
1905     e.angles = fixedvectoangles2(e_forward, e_up);
1906     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1907                 e.angles = AnglesTransform_ToVAngles(e.angles);
1908         else
1909                 e.angles = AnglesTransform_ToAngles(e.angles);
1910
1911     setattachment(e, to, tag);
1912     setorigin(e, e.origin);
1913 }
1914
1915 void detach_sameorigin(entity e)
1916 {
1917     vector org;
1918     org = gettaginfo(e, 0);
1919     e.angles = fixedvectoangles2(v_forward, v_up);
1920     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1921                 e.angles = AnglesTransform_ToVAngles(e.angles);
1922         else
1923                 e.angles = AnglesTransform_ToAngles(e.angles);
1924     setorigin(e, org);
1925     setattachment(e, NULL, "");
1926     setorigin(e, e.origin);
1927 }
1928
1929 void follow_sameorigin(entity e, entity to)
1930 {
1931     set_movetype(e, MOVETYPE_FOLLOW); // make the hole follow
1932     e.aiment = to; // make the hole follow bmodel
1933     e.punchangle = to.angles; // the original angles of bmodel
1934     e.view_ofs = e.origin - to.origin; // relative origin
1935     e.v_angle = e.angles - to.angles; // relative angles
1936 }
1937
1938 #if 0
1939 // TODO: unused, likely for a reason, possibly needs extensions (allow setting the new movetype as a parameter?)
1940 void unfollow_sameorigin(entity e)
1941 {
1942     set_movetype(e, MOVETYPE_NONE);
1943 }
1944 #endif
1945
1946 .string aiment_classname;
1947 .float aiment_deadflag;
1948 void SetMovetypeFollow(entity ent, entity e)
1949 {
1950         // FIXME this may not be warpzone aware
1951         set_movetype(ent, MOVETYPE_FOLLOW); // make the hole follow
1952         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1953         ent.aiment = e; // make the hole follow bmodel
1954         ent.punchangle = e.angles; // the original angles of bmodel
1955         ent.view_ofs = ent.origin - e.origin; // relative origin
1956         ent.v_angle = ent.angles - e.angles; // relative angles
1957         ent.aiment_classname = strzone(e.classname);
1958         ent.aiment_deadflag = e.deadflag;
1959 }
1960 void UnsetMovetypeFollow(entity ent)
1961 {
1962         set_movetype(ent, MOVETYPE_FLY);
1963         PROJECTILE_MAKETRIGGER(ent);
1964         ent.aiment = NULL;
1965 }
1966 float LostMovetypeFollow(entity ent)
1967 {
1968 /*
1969         if(ent.move_movetype != MOVETYPE_FOLLOW)
1970                 if(ent.aiment)
1971                         error("???");
1972 */
1973         if(ent.aiment)
1974         {
1975                 if(ent.aiment.classname != ent.aiment_classname)
1976                         return 1;
1977                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1978                         return 1;
1979         }
1980         return 0;
1981 }
1982 #endif
1983
1984 #ifdef GAMEQC
1985 // decolorizes and team colors the player name when needed
1986 string playername(string thename, int teamid, bool team_colorize)
1987 {
1988         TC(int, teamid);
1989         bool do_colorize = (teamplay && team_colorize);
1990 #ifdef SVQC
1991         if(do_colorize && !intermission_running)
1992 #else
1993         if(do_colorize)
1994 #endif
1995     {
1996         string t = Team_ColorCode(teamid);
1997         return strcat(t, strdecolorize(thename));
1998     }
1999     else
2000         return thename;
2001 }
2002
2003 float trace_hits_box_a0, trace_hits_box_a1;
2004
2005 float trace_hits_box_1d(float end, float thmi, float thma)
2006 {
2007     if (end == 0)
2008     {
2009         // just check if x is in range
2010         if (0 < thmi)
2011             return false;
2012         if (0 > thma)
2013             return false;
2014     }
2015     else
2016     {
2017         // do the trace with respect to x
2018         // 0 -> end has to stay in thmi -> thma
2019         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
2020         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
2021         if (trace_hits_box_a0 > trace_hits_box_a1)
2022             return false;
2023     }
2024     return true;
2025 }
2026
2027 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
2028 {
2029     end -= start;
2030     thmi -= start;
2031     thma -= start;
2032     // now it is a trace from 0 to end
2033
2034     trace_hits_box_a0 = 0;
2035     trace_hits_box_a1 = 1;
2036
2037     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
2038         return false;
2039     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
2040         return false;
2041     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
2042         return false;
2043
2044     return true;
2045 }
2046
2047 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
2048 {
2049     return trace_hits_box(start, end, thmi - ma, thma - mi);
2050 }
2051 #endif
2052
2053 ERASEABLE
2054 float cvar_or(string cv, float v)
2055 {
2056         string s = cvar_string(cv);
2057         if(s == "")
2058                 return v;
2059         else
2060                 return stof(s);
2061 }
2062
2063 // NOTE base is the central value
2064 // freq: circle frequency, = 2*pi*frequency in hertz
2065 // start_pos:
2066 //  -1 start from the lower value
2067 //   0 start from the base value
2068 //   1 start from the higher value
2069 ERASEABLE
2070 float blink_synced(float base, float range, float freq, float start_time, int start_pos)
2071 {
2072         // note:
2073         //   RMS = sqrt(base^2 + 0.5 * range^2)
2074         // thus
2075         //   base = sqrt(RMS^2 - 0.5 * range^2)
2076         // ensure RMS == 1
2077
2078         return base + range * sin((time - start_time - (M_PI / 2) * start_pos) * freq);
2079 }
2080
2081 ERASEABLE
2082 float blink(float base, float range, float freq)
2083 {
2084         return blink_synced(base, range, freq, 0, 0);
2085 }