qcsrc/common/turrets/sv_turrets.qc

   1 #include "sv_turrets.qh"
   2
   3 #ifdef SVQC
   4 #include <common/mapobjects/defs.qh>
   5 #include <server/bot/api.qh>
   6 #include <server/damage.qh>
   7 #include <server/weapons/common.qh>
   8 #include <server/weapons/weaponsystem.qh>
   9 #include <server/world.qh>
  10
  11 // Generic aiming
  12 vector turret_aim_generic(entity this)
  13 {
  14
  15         vector pre_pos, prep;
  16         float distance, impact_time = 0, i, mintime;
  17
  18         turret_tag_fire_update(this);
  19
  20         if(this.aim_flags & TFL_AIM_SIMPLE)
  21                 return real_origin(this.enemy);
  22
  23         mintime = max(this.attack_finished_single[0] - time,0) + sys_frametime;
  24
  25         // Baseline
  26         pre_pos = real_origin(this.enemy);
  27
  28         // Lead?
  29         if (this.aim_flags & TFL_AIM_LEAD)
  30         {
  31                 if (this.aim_flags & TFL_AIM_SHOTTIMECOMPENSATE)           // Need to conpensate for shot traveltime
  32                 {
  33                         prep = pre_pos;
  34
  35                         distance = vlen(prep - this.tur_shotorg);
  36                         impact_time = distance / this.shot_speed;
  37
  38                         prep = pre_pos + (this.enemy.velocity * (impact_time + mintime));
  39
  40                         if(this.aim_flags & TFL_AIM_ZPREDICT)
  41                         if(!IS_ONGROUND(this.enemy))
  42                         if(this.enemy.move_movetype == MOVETYPE_WALK || this.enemy.move_movetype == MOVETYPE_TOSS || this.enemy.move_movetype == MOVETYPE_BOUNCE)
  43                         {
  44                                 float vz;
  45                                 prep_z = pre_pos_z;
  46                                 vz = this.enemy.velocity_z;
  47                                 for(i = 0; i < impact_time; i += sys_frametime)
  48                                 {
  49                                         vz = vz - (autocvar_sv_gravity * sys_frametime);
  50                                         prep_z = prep_z + vz * sys_frametime;
  51                                 }
  52                         }
  53                         pre_pos = prep;
  54                 }
  55                 else
  56                         pre_pos = pre_pos + this.enemy.velocity * mintime;
  57         }
  58
  59         if(this.aim_flags & TFL_AIM_SPLASH)
  60         {
  61                 //tracebox(pre_pos + '0 0 32',this.enemy.mins,this.enemy.maxs,pre_pos -'0 0 64',MOVE_WORLDONLY,this.enemy);
  62                 traceline(pre_pos + '0 0 32',pre_pos -'0 0 64',MOVE_WORLDONLY,this.enemy);
  63                 if(trace_fraction != 1.0)
  64                         pre_pos = trace_endpos;
  65         }
  66
  67         return pre_pos;
  68 }
  69
  70 float turret_targetscore_support(entity _turret,entity _target)
  71 {
  72         float score;            // Total score
  73         float s_score = 0, d_score;
  74
  75         if (_turret.enemy == _target) s_score = 1;
  76
  77         d_score = min(_turret.target_range_optimal,tvt_dist) / max(_turret.target_range_optimal,tvt_dist);
  78
  79         score = (d_score * _turret.target_select_rangebias) +
  80                         (s_score * _turret.target_select_samebias);
  81
  82         return score;
  83 }
  84
  85 /*
  86 * Generic bias aware score system.
  87 */
  88 float turret_targetscore_generic(entity _turret, entity _target)
  89 {
  90         float d_dist;      // Defendmode Distance
  91         float score;            // Total score
  92         float d_score;    // Distance score
  93         float a_score;    // Angular score
  94         float m_score = 0;  // missile score
  95         float p_score = 0;  // player score
  96         float ikr;                // ideal kill range
  97
  98         if (_turret.tur_defend)
  99         {
 100                 d_dist = vlen(real_origin(_target) - _turret.tur_defend.origin);
 101                 ikr = vlen(_turret.origin - _turret.tur_defend.origin);
 102                 d_score = 1 - d_dist / _turret.target_range;
 103         }
 104         else
 105         {
 106                 // Make a normlized value base on the targets distance from our optimal killzone
 107                 ikr = _turret.target_range_optimal;
 108                 d_score = min(ikr, tvt_dist) / max(ikr, tvt_dist);
 109         }
 110
 111         a_score = 1 - tvt_thadf / _turret.aim_maxrot;
 112
 113         if ((_turret.target_select_missilebias > 0) && (_target.flags & FL_PROJECTILE))
 114                 m_score = 1;
 115
 116         if ((_turret.target_select_playerbias > 0) && IS_CLIENT(_target))
 117                 p_score = 1;
 118
 119         d_score = max(d_score, 0);
 120         a_score = max(a_score, 0);
 121         m_score = max(m_score, 0);
 122         p_score = max(p_score, 0);
 123
 124         score = (d_score * _turret.target_select_rangebias) +
 125                         (a_score * _turret.target_select_anglebias) +
 126                         (m_score * _turret.target_select_missilebias) +
 127                         (p_score * _turret.target_select_playerbias);
 128
 129         if(vdist((_turret.tur_shotorg - real_origin(_target)), >, _turret.target_range))
 130         {
 131                 //dprint("Wtf?\n");
 132                 score *= 0.001;
 133         }
 134
 135 #ifdef TURRET_DEBUG
 136         string sd,sa,sm,sp,ss;
 137         string sdt,sat,smt,spt;
 138
 139         sd = ftos(d_score);
 140         d_score *= _turret.target_select_rangebias;
 141         sdt = ftos(d_score);
 142
 143         //sv = ftos(v_score);
 144         //v_score *= _turret.target_select_samebias;
 145         //svt = ftos(v_score);
 146
 147         sa = ftos(a_score);
 148         a_score *= _turret.target_select_anglebias;
 149         sat = ftos(a_score);
 150
 151         sm = ftos(m_score);
 152         m_score *= _turret.target_select_missilebias;
 153         smt = ftos(m_score);
 154
 155         sp = ftos(p_score);
 156         p_score *= _turret.target_select_playerbias;
 157         spt = ftos(p_score);
 158
 159
 160         ss = ftos(score);
 161         bprint("^3Target scores^7 \[  ",_turret.netname, "  \] ^3for^7 \[  ", _target.netname,"  \]\n");
 162         bprint("^5Range:\[  ",sd,  "  \]^2+bias:\[  ",sdt,"  \]\n");
 163         bprint("^5Angle:\[  ",sa,  "  \]^2+bias:\[  ",sat,"  \]\n");
 164         bprint("^5Missile:\[  ",sm,"  \]^2+bias:\[  ",smt,"  \]\n");
 165         bprint("^5Player:\[  ",sp, "  \]^2+bias:\[  ",spt,"  \]\n");
 166         bprint("^3Total (w/bias):\[^1",ss,"\]\n");
 167
 168 #endif
 169
 170         return score;
 171 }
 172
 173 // Generic damage handling
 174 void turret_hide(entity this)
 175 {
 176         this.effects   |= EF_NODRAW;
 177         this.nextthink = time + this.respawntime - 0.2;
 178         setthink(this, turret_respawn);
 179 }
 180
 181 void turret_die(entity this)
 182 {
 183         this.deadflag             = DEAD_DEAD;
 184         this.tur_head.deadflag = this.deadflag;
 185
 186 // Unsolidify and hide real parts
 187         this.solid                       = SOLID_NOT;
 188         this.tur_head.solid      = this.solid;
 189
 190         this.event_damage                 = func_null;
 191         this.event_heal = func_null;
 192         this.takedamage                  = DAMAGE_NO;
 193
 194         SetResourceExplicit(this, RES_HEALTH, 0);
 195
 196 // Go boom
 197         //RadiusDamage (this,this, min(this.ammo,50),min(this.ammo,50) * 0.25,250,NULL,min(this.ammo,50)*5,DEATH_TURRET,NULL);
 198
 199         Turret tur = get_turretinfo(this.m_id);
 200         if(this.damage_flags & TFL_DMG_DEATH_NORESPAWN)
 201         {
 202                 // do a simple explosion effect here, since CSQC can't do it on a to-be-removed entity
 203                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 204                 Send_Effect(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
 205
 206                 tur.tr_death(tur, this);
 207
 208                 delete(this.tur_head);
 209                 delete(this);
 210         }
 211         else
 212         {
 213                 // Setup respawn
 214                 this.SendFlags    |= TNSF_STATUS;
 215                 this.nextthink   = time + 0.2;
 216                 setthink(this, turret_hide);
 217
 218                 tur.tr_death(tur, this);
 219         }
 220 }
 221
 222 void turret_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector vforce)
 223 {
 224         // Enough already!
 225         if(this.deadflag == DEAD_DEAD)
 226                 return;
 227
 228         // Inactive turrets take no damage. (hm..)
 229         if(!this.active)
 230                 return;
 231
 232         if(SAME_TEAM(this, attacker))
 233         {
 234                 if(autocvar_g_friendlyfire)
 235                         damage = damage * autocvar_g_friendlyfire;
 236                 else
 237                         return;
 238         }
 239
 240         TakeResource(this, RES_HEALTH, damage);
 241
 242         // thorw head slightly off aim when hit?
 243         if (this.damage_flags & TFL_DMG_HEADSHAKE)
 244         {
 245                 this.tur_head.angles_x = this.tur_head.angles_x + (-0.5 + random()) * damage;
 246                 this.tur_head.angles_y = this.tur_head.angles_y + (-0.5 + random()) * damage;
 247
 248                 this.SendFlags  |= TNSF_ANG;
 249         }
 250
 251         if (this.turret_flags & TUR_FLAG_MOVE)
 252                 this.velocity = this.velocity + vforce;
 253
 254         if (GetResource(this, RES_HEALTH) <= 0)
 255         {
 256                 this.event_damage                 = func_null;
 257                 this.tur_head.event_damage = func_null;
 258                 this.event_heal = func_null;
 259                 this.tur_head.event_heal = func_null;
 260                 this.takedamage                  = DAMAGE_NO;
 261                 this.nextthink = time;
 262                 setthink(this, turret_die);
 263         }
 264
 265         this.SendFlags  |= TNSF_STATUS;
 266 }
 267
 268 bool turret_heal(entity targ, entity inflictor, float amount, float limit)
 269 {
 270         float true_limit = ((limit != RES_LIMIT_NONE) ? limit : targ.max_health);
 271         if(GetResource(targ, RES_HEALTH) <= 0 || GetResource(targ, RES_HEALTH) >= true_limit)
 272                 return false;
 273
 274         GiveResourceWithLimit(targ, RES_HEALTH, amount, true_limit);
 275         targ.SendFlags |= TNSF_STATUS;
 276         return true;
 277 }
 278
 279 void turret_think(entity this);
 280 void turret_respawn(entity this)
 281 {
 282         // Make sure all parts belong to the same team since
 283         // this function doubles as "teamchange" function.
 284         this.tur_head.team      = this.team;
 285         this.effects                       &= ~EF_NODRAW;
 286         this.deadflag                           = DEAD_NO;
 287         this.effects                            = EF_LOWPRECISION;
 288         this.solid                                      = SOLID_BBOX;
 289         this.takedamage                         = DAMAGE_AIM;
 290         this.event_damage                       = turret_damage;
 291         this.event_heal                         = turret_heal;
 292         this.avelocity                          = '0 0 0';
 293         this.tur_head.avelocity         = this.avelocity;
 294         this.tur_head.angles            = this.idle_aim;
 295         SetResourceExplicit(this, RES_HEALTH, this.max_health);
 296         this.enemy                                      = NULL;
 297         this.volly_counter                      = this.shot_volly;
 298         this.ammo                                       = this.ammo_max;
 299
 300         this.nextthink = time + this.ticrate;
 301         setthink(this, turret_think);
 302
 303         this.SendFlags = TNSF_FULL_UPDATE;
 304
 305         Turret tur = get_turretinfo(this.m_id);
 306         tur.tr_setup(tur, this);
 307
 308         setorigin(this, this.origin); // make sure it's linked to the area grid
 309 }
 310
 311
 312 // Main functions
 313 .float clientframe;
 314 void turrets_setframe(entity this, float _frame, float client_only)
 315 {
 316         if((client_only ? this.clientframe : this.frame ) != _frame)
 317         {
 318                 this.SendFlags |= TNSF_ANIM;
 319                 this.anim_start_time = time;
 320         }
 321
 322          if(client_only)
 323                 this.clientframe = _frame;
 324         else
 325                 this.frame = _frame;
 326
 327 }
 328
 329 bool turret_send(entity this, entity to, float sf)
 330 {
 331         WriteHeader(MSG_ENTITY, ENT_CLIENT_TURRET);
 332         WriteByte(MSG_ENTITY, sf);
 333         if(sf & TNSF_SETUP)
 334         {
 335                 WriteByte(MSG_ENTITY, this.m_id);
 336
 337                 WriteVector(MSG_ENTITY, this.origin);
 338
 339                 WriteAngleVector2D(MSG_ENTITY, this.angles);
 340         }
 341
 342         if(sf & TNSF_ANG)
 343         {
 344                 WriteShort(MSG_ENTITY, rint(this.tur_head.angles_x));
 345                 WriteShort(MSG_ENTITY, rint(this.tur_head.angles_y));
 346         }
 347
 348         if(sf & TNSF_AVEL)
 349         {
 350                 WriteShort(MSG_ENTITY, rint(this.tur_head.avelocity_x));
 351                 WriteShort(MSG_ENTITY, rint(this.tur_head.avelocity_y));
 352         }
 353
 354         if(sf & TNSF_MOVE)
 355         {
 356                 WriteVector(MSG_ENTITY, this.origin);
 357
 358                 WriteVector(MSG_ENTITY, this.velocity);
 359
 360                 WriteShort(MSG_ENTITY, rint(this.angles_y));
 361         }
 362
 363         if(sf & TNSF_ANIM)
 364         {
 365                 WriteCoord(MSG_ENTITY, this.anim_start_time);
 366                 WriteByte(MSG_ENTITY, this.frame);
 367         }
 368
 369         if(sf & TNSF_STATUS)
 370         {
 371                 WriteByte(MSG_ENTITY, this.team);
 372
 373                 if(GetResource(this, RES_HEALTH) <= 0)
 374                         WriteByte(MSG_ENTITY, 0);
 375                 else
 376                         WriteByte(MSG_ENTITY, ceil((GetResource(this, RES_HEALTH) / this.max_health) * 255));
 377         }
 378
 379         return true;
 380 }
 381
 382 void load_unit_settings(entity ent, bool is_reload)
 383 {
 384         if (ent == NULL)
 385                 return;
 386
 387         if(!ent.turret_scale_damage)    ent.turret_scale_damage = 1;
 388         if(!ent.turret_scale_range)             ent.turret_scale_range  = 1;
 389         if(!ent.turret_scale_refire)    ent.turret_scale_refire = 1;
 390         if(!ent.turret_scale_ammo)              ent.turret_scale_ammo   = 1;
 391         if(!ent.turret_scale_aim)               ent.turret_scale_aim     = 1;
 392         if(!ent.turret_scale_health)    ent.turret_scale_health = 1;
 393         if(!ent.turret_scale_respawn)   ent.turret_scale_respawn = 1;
 394
 395         if (is_reload)
 396         {
 397                 ent.enemy = NULL;
 398                 ent.tur_head.avelocity = '0 0 0';
 399
 400                 ent.tur_head.angles = '0 0 0';
 401         }
 402
 403         string unitname = ent.netname;
 404         #define X(class, prefix, fld, type) ent.fld = cvar(strcat("g_turrets_unit_", prefix, "_", #fld));
 405         TR_PROPS_COMMON(X, , unitname)
 406         #undef X
 407
 408         ent.ammo_max             *= ent.turret_scale_ammo;
 409         ent.ammo_recharge        *= ent.turret_scale_ammo;
 410         ent.aim_speed            *= ent.turret_scale_aim;
 411         SetResourceExplicit(ent, RES_HEALTH, GetResource(ent, RES_HEALTH) * ent.turret_scale_health);
 412         ent.respawntime          *= ent.turret_scale_respawn;
 413         ent.shot_dmg             *= ent.turret_scale_damage;
 414         ent.shot_refire          *= ent.turret_scale_refire;
 415         ent.shot_radius          *= ent.turret_scale_damage;
 416         ent.shot_force           *= ent.turret_scale_damage;
 417         ent.shot_volly_refire    *= ent.turret_scale_refire;
 418         ent.target_range         *= ent.turret_scale_range;
 419         ent.target_range_min     *= ent.turret_scale_range;
 420         ent.target_range_optimal *= ent.turret_scale_range;
 421
 422         if(is_reload) {
 423                 Turret tur = get_turretinfo(ent.m_id);
 424                 tur.tr_setup(tur, ent);
 425         }
 426 }
 427
 428 void turret_projectile_explode(entity this)
 429 {
 430
 431         this.takedamage = DAMAGE_NO;
 432         this.event_damage = func_null;
 433 #ifdef TURRET_DEBUG
 434         float d;
 435         d = RadiusDamage (this, this.owner, this.owner.shot_dmg, 0, this.owner.shot_radius, this, NULL, this.owner.shot_force, this.projectiledeathtype, DMG_NOWEP, NULL);
 436         this.owner.tur_debug_dmg_t_h = this.owner.tur_debug_dmg_t_h + d;
 437         this.owner.tur_debug_dmg_t_f = this.owner.tur_debug_dmg_t_f + this.owner.shot_dmg;
 438 #else
 439         RadiusDamage (this, this.realowner, this.owner.shot_dmg, 0, this.owner.shot_radius, this, NULL, this.owner.shot_force, this.projectiledeathtype, DMG_NOWEP, NULL);
 440 #endif
 441         delete(this);
 442 }
 443
 444 void turret_projectile_touch(entity this, entity toucher)
 445 {
 446         PROJECTILE_TOUCH(this, toucher);
 447         turret_projectile_explode(this);
 448 }
 449
 450 void turret_projectile_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector vforce)
 451 {
 452         this.velocity  += vforce;
 453         TakeResource(this, RES_HEALTH, damage);
 454         //this.realowner = attacker; // Dont change realowner, it does not make much sense for turrets
 455         if(GetResource(this, RES_HEALTH) <= 0)
 456                 W_PrepareExplosionByDamage(this, this.owner, turret_projectile_explode);
 457 }
 458
 459 entity turret_projectile(entity actor, Sound _snd, float _size, float _health, float _death, float _proj_type, float _cull, float _cli_anim)
 460 {
 461         TC(Sound, _snd);
 462         entity proj;
 463
 464         sound (actor, CH_WEAPON_A, _snd, VOL_BASE, ATTEN_NORM);
 465         proj                             = spawn ();
 466         setorigin(proj, actor.tur_shotorg);
 467         setsize(proj, '-0.5 -0.5 -0.5' * _size, '0.5 0.5 0.5' * _size);
 468         proj.owner                = actor;
 469         proj.realowner    = actor;
 470         proj.bot_dodge    = true;
 471         proj.bot_dodgerating = actor.shot_dmg;
 472         setthink(proj, turret_projectile_explode);
 473         settouch(proj, turret_projectile_touch);
 474         proj.nextthink    = time + 9;
 475         set_movetype(proj, MOVETYPE_FLYMISSILE);
 476         proj.velocity           = normalize(actor.tur_shotdir_updated + randomvec() * actor.shot_spread) * actor.shot_speed;
 477         proj.flags = FL_PROJECTILE;
 478         IL_PUSH(g_projectiles, proj);
 479         IL_PUSH(g_bot_dodge, proj);
 480         proj.enemy                = actor.enemy;
 481         proj.projectiledeathtype         = _death;
 482         PROJECTILE_MAKETRIGGER(proj);
 483         if(_health)
 484         {
 485                 SetResourceExplicit(proj, RES_HEALTH, _health);
 486                 proj.takedamage  = DAMAGE_YES;
 487                 proj.event_damage  = turret_projectile_damage;
 488         }
 489         else
 490                 proj.flags |= FL_NOTARGET;
 491
 492         CSQCProjectile(proj, _cli_anim, _proj_type, _cull);
 493
 494         return proj;
 495 }
 496
 497 /**
 498 ** updates enemy distances, predicted impact point/time
 499 ** and updated aim<->predict impact distance.
 500 **/
 501 void turret_do_updates(entity t_turret)
 502 {
 503         vector enemy_pos = real_origin(t_turret.enemy);
 504
 505         turret_tag_fire_update(t_turret);
 506
 507         t_turret.tur_shotdir_updated = v_forward;
 508         t_turret.tur_dist_enemy = vlen(t_turret.tur_shotorg - enemy_pos);
 509         t_turret.tur_dist_aimpos = vlen(t_turret.tur_shotorg - t_turret.tur_aimpos);
 510
 511         /*if((t_turret.firecheck_flags & TFL_FIRECHECK_VERIFIED) && (t_turret.enemy))
 512         {
 513                 oldpos = t_turret.enemy.origin;
 514                 setorigin(t_turret.enemy, t_turret.tur_aimpos);
 515                 tracebox(t_turret.tur_shotorg, '-1 -1 -1', '1 1 1', t_turret.tur_shotorg + (t_turret.tur_shotdir_updated * t_turret.tur_dist_aimpos), MOVE_NORMAL,t_turret);
 516                 setorigin(t_turret.enemy, oldpos);
 517
 518                 if(trace_ent == t_turret.enemy)
 519                         t_turret.tur_dist_impact_to_aimpos = 0;
 520                 else
 521                         t_turret.tur_dist_impact_to_aimpos = vlen(trace_endpos - t_turret.tur_aimpos);
 522         }
 523         else*/
 524                 tracebox(t_turret.tur_shotorg, '-1 -1 -1','1 1 1', t_turret.tur_shotorg + (t_turret.tur_shotdir_updated * t_turret.tur_dist_aimpos), MOVE_NORMAL,t_turret);
 525
 526         t_turret.tur_dist_impact_to_aimpos = vlen(trace_endpos - t_turret.tur_aimpos) - (vlen(t_turret.enemy.maxs - t_turret.enemy.mins) * 0.5);
 527         t_turret.tur_impactent                   = trace_ent;
 528         t_turret.tur_impacttime                 = vlen(t_turret.tur_shotorg - trace_endpos) / t_turret.shot_speed;
 529 }
 530
 531 /**
 532 ** Handles head rotation according to
 533 ** the units .track_type and .track_flags
 534 **/
 535 .float turret_framecounter;
 536 void turret_track(entity this)
 537 {
 538         vector target_angle; // This is where we want to aim
 539         vector move_angle;   // This is where we can aim
 540         float f_tmp;
 541         vector v1, v2;
 542         v1 = this.tur_head.angles;
 543         v2 = this.tur_head.avelocity;
 544
 545         if (this.track_flags == TFL_TRACK_NO)
 546                 return;
 547
 548         if(!this.active)
 549                 target_angle = this.idle_aim - ('1 0 0' * this.aim_maxpitch);
 550         else if (this.enemy == NULL)
 551         {
 552                 if(time > this.lip)
 553                         target_angle = this.idle_aim + this.angles;
 554                 else
 555                         target_angle = vectoangles(normalize(this.tur_aimpos - this.tur_shotorg));
 556         }
 557         else
 558         {
 559                 target_angle = vectoangles(normalize(this.tur_aimpos - this.tur_shotorg));
 560         }
 561
 562         this.tur_head.angles_x = anglemods(this.tur_head.angles_x);
 563         this.tur_head.angles_y = anglemods(this.tur_head.angles_y);
 564
 565         // Find the diffrence between where we currently aim and where we want to aim
 566         //move_angle = target_angle - (this.angles + this.tur_head.angles);
 567         //move_angle = shortangle_vxy(move_angle,(this.angles + this.tur_head.angles));
 568
 569         move_angle = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(this.angles), AnglesTransform_FromAngles(target_angle))) - this.tur_head.angles;
 570         move_angle = shortangle_vxy(move_angle, this.tur_head.angles);
 571
 572         switch(this.track_type)
 573         {
 574                 case TFL_TRACKTYPE_STEPMOTOR:
 575                         f_tmp = this.aim_speed * this.ticrate; // dgr/sec -> dgr/tic
 576                         if (this.track_flags & TFL_TRACK_PITCH)
 577                         {
 578                                 this.tur_head.angles_x += bound(-f_tmp,move_angle_x, f_tmp);
 579                                 if(this.tur_head.angles_x > this.aim_maxpitch)
 580                                         this.tur_head.angles_x = this.aim_maxpitch;
 581
 582                                 if(this.tur_head.angles_x  < -this.aim_maxpitch)
 583                                         this.tur_head.angles_x = this.aim_maxpitch;
 584                         }
 585
 586                         if (this.track_flags & TFL_TRACK_ROTATE)
 587                         {
 588                                 this.tur_head.angles_y += bound(-f_tmp, move_angle_y, f_tmp);
 589                                 if(this.tur_head.angles_y > this.aim_maxrot)
 590                                         this.tur_head.angles_y = this.aim_maxrot;
 591
 592                                 if(this.tur_head.angles_y  < -this.aim_maxrot)
 593                                         this.tur_head.angles_y = this.aim_maxrot;
 594                         }
 595
 596                         // CSQC
 597                         this.SendFlags  |= TNSF_ANG;
 598
 599                         return;
 600
 601                 case TFL_TRACKTYPE_FLUIDINERTIA:
 602                         f_tmp = this.aim_speed * this.ticrate; // dgr/sec -> dgr/tic
 603                         move_angle_x = bound(-this.aim_speed, move_angle_x * this.track_accel_pitch * f_tmp, this.aim_speed);
 604                         move_angle_y = bound(-this.aim_speed, move_angle_y * this.track_accel_rot * f_tmp, this.aim_speed);
 605                         move_angle = (this.tur_head.avelocity * this.track_blendrate) + (move_angle * (1 - this.track_blendrate));
 606                         break;
 607
 608                 case TFL_TRACKTYPE_FLUIDPRECISE:
 609
 610                         move_angle_y = bound(-this.aim_speed, move_angle_y, this.aim_speed);
 611                         move_angle_x = bound(-this.aim_speed, move_angle_x, this.aim_speed);
 612
 613                         break;
 614         }
 615
 616         //  pitch
 617         if (this.track_flags & TFL_TRACK_PITCH)
 618         {
 619                 this.tur_head.avelocity_x = move_angle_x;
 620                 if((this.tur_head.angles_x + this.tur_head.avelocity_x * this.ticrate) > this.aim_maxpitch)
 621                 {
 622                         this.tur_head.avelocity_x = 0;
 623                         this.tur_head.angles_x = this.aim_maxpitch;
 624
 625                         this.SendFlags  |= TNSF_ANG;
 626                 }
 627
 628                 if((this.tur_head.angles_x + this.tur_head.avelocity_x * this.ticrate) < -this.aim_maxpitch)
 629                 {
 630                         this.tur_head.avelocity_x = 0;
 631                         this.tur_head.angles_x = -this.aim_maxpitch;
 632
 633                         this.SendFlags  |= TNSF_ANG;
 634                 }
 635         }
 636
 637         //  rot
 638         if (this.track_flags & TFL_TRACK_ROTATE)
 639         {
 640                 this.tur_head.avelocity_y = move_angle_y;
 641
 642                 if((this.tur_head.angles_y + this.tur_head.avelocity_y * this.ticrate) > this.aim_maxrot)
 643                 {
 644                         this.tur_head.avelocity_y = 0;
 645                         this.tur_head.angles_y = this.aim_maxrot;
 646
 647                         this.SendFlags  |= TNSF_ANG;
 648                 }
 649
 650                 if((this.tur_head.angles_y + this.tur_head.avelocity_y * this.ticrate) < -this.aim_maxrot)
 651                 {
 652                         this.tur_head.avelocity_y = 0;
 653                         this.tur_head.angles_y = -this.aim_maxrot;
 654
 655                         this.SendFlags  |= TNSF_ANG;
 656                 }
 657         }
 658
 659         this.SendFlags  |= TNSF_AVEL;
 660
 661         // Force a angle update every 10'th frame
 662         this.turret_framecounter += 1;
 663         if(this.turret_framecounter >= 10)
 664         {
 665                 this.SendFlags |= TNSF_ANG;
 666                 this.turret_framecounter = 0;
 667         }
 668 }
 669
 670 /*
 671  + TFL_TARGETSELECT_NO
 672  + TFL_TARGETSELECT_LOS
 673  + TFL_TARGETSELECT_PLAYERS
 674  + TFL_TARGETSELECT_MISSILES
 675  + TFL_TARGETSELECT_VEHICLES
 676  - TFL_TARGETSELECT_TRIGGERTARGET
 677  + TFL_TARGETSELECT_ANGLELIMITS
 678  + TFL_TARGETSELECT_RANGELIMITS
 679  + TFL_TARGETSELECT_TEAMCHECK
 680  - TFL_TARGETSELECT_NOBUILTIN
 681  + TFL_TARGETSELECT_OWNTEAM
 682 */
 683
 684 /**
 685 ** Evaluate a entity for target valitity based on validate_flags
 686 ** NOTE: the caller must check takedamage before calling this, to inline this check.
 687 **/
 688 float turret_validate_target(entity e_turret, entity e_target, float validate_flags)
 689 {
 690         vector v_tmp;
 691
 692         //if(!validate_flags & TFL_TARGETSELECT_NOBUILTIN)
 693         //      return -0.5;
 694
 695         if(!e_target)
 696                 return -2;
 697
 698         if(e_target.owner == e_turret)
 699                 return -0.5;
 700
 701         if(!checkpvs(e_target.origin, e_turret))
 702                 return -1;
 703
 704         if(e_target.alpha != 0 && e_target.alpha <= 0.3)
 705                 return -1;
 706
 707         if(MUTATOR_CALLHOOK(TurretValidateTarget, e_turret, e_target, validate_flags))
 708                 return M_ARGV(3, float);
 709
 710         if (validate_flags & TFL_TARGETSELECT_NO)
 711                 return -4;
 712
 713         // If only this was used more..
 714         if (e_target.flags & FL_NOTARGET)
 715                 return -5;
 716
 717         // Cant touch this
 718         if (GetResource(e_target, RES_HEALTH) <= 0)
 719                 return -6;
 720         else if (STAT(FROZEN, e_target))
 721                 return -6;
 722
 723         // vehicle
 724         if(IS_VEHICLE(e_target))
 725         {
 726                 if ((validate_flags & TFL_TARGETSELECT_VEHICLES) && !e_target.owner)
 727                         return -7;
 728         }
 729
 730         // player
 731         if (IS_CLIENT(e_target))
 732         {
 733                 if(!(validate_flags & TFL_TARGETSELECT_PLAYERS))
 734                         return -7;
 735
 736                 if (IS_DEAD(e_target))
 737                         return -8;
 738         }
 739
 740         // enemy turrets
 741         if(validate_flags & TFL_TARGETSELECT_NOTURRETS)
 742         if(e_target.owner.tur_head == e_target)
 743         if(e_target.team != e_turret.team) // Dont break support units.
 744                 return -9;
 745
 746         // Missile
 747         if (e_target.flags & FL_PROJECTILE)
 748         if(!(validate_flags & TFL_TARGETSELECT_MISSILES))
 749                 return -10;
 750
 751         if (validate_flags & TFL_TARGETSELECT_MISSILESONLY)
 752         if(!(e_target.flags & FL_PROJECTILE))
 753                 return -10.5;
 754
 755         // Team check
 756         if (validate_flags & TFL_TARGETSELECT_TEAMCHECK)
 757         {
 758                 if (validate_flags & TFL_TARGETSELECT_OWNTEAM)
 759                 {
 760                         if (e_target.team != e_turret.team)
 761                                 return -11;
 762
 763                         if (e_turret.team != e_target.owner.team)
 764                                 return -12;
 765
 766                         if (e_turret.team != e_target.aiment.team)
 767                                 return -12; // portals
 768                 }
 769                 else
 770                 {
 771                         if (e_target.team == e_turret.team)
 772                                 return -13;
 773
 774                         if (e_turret.team == e_target.owner.team)
 775                                 return -14;
 776
 777                         if (e_turret.team == e_target.aiment.team)
 778                                 return -14; // portals
 779                 }
 780         }
 781
 782         // Range limits?
 783         tvt_dist = vlen(e_turret.origin - real_origin(e_target));
 784         if (validate_flags & TFL_TARGETSELECT_RANGELIMITS)
 785         {
 786                 if (tvt_dist < e_turret.target_range_min)
 787                         return -15;
 788
 789                 if (tvt_dist > e_turret.target_range)
 790                         return -16;
 791         }
 792
 793         // Can we even aim this thing?
 794         tvt_thadv = angleofs3(e_turret.tur_head.origin, e_turret.angles + e_turret.tur_head.angles, e_target.origin);
 795         tvt_tadv = shortangle_vxy(angleofs(e_turret, e_target), e_turret.angles);
 796         tvt_thadf = vlen(tvt_thadv);
 797
 798         /*
 799         if(validate_flags & TFL_TARGETSELECT_FOV)
 800         {
 801                 if(e_turret.target_select_fov < tvt_thadf)
 802                         return -21;
 803         }
 804         */
 805
 806         if (validate_flags & TFL_TARGETSELECT_ANGLELIMITS)
 807         {
 808                 if (fabs(tvt_tadv_x) > e_turret.aim_maxpitch)
 809                         return -17;
 810
 811                 if (fabs(tvt_tadv_y) > e_turret.aim_maxrot)
 812                         return -18;
 813         }
 814
 815         // Line of sight?
 816         if (validate_flags & TFL_TARGETSELECT_LOS)
 817         {
 818                 v_tmp = real_origin(e_target) + ((e_target.mins + e_target.maxs) * 0.5);
 819
 820                 traceline(e_turret.origin + '0 0 16', v_tmp, 0, e_turret);
 821
 822                 if(vdist(v_tmp - trace_endpos, >, e_turret.aim_firetolerance_dist))
 823                         return -19;
 824         }
 825
 826         if (e_target.classname == "grapplinghook")
 827                 return -20;
 828
 829         /*
 830         if (e_target.classname == "func_button")
 831                 return -21;
 832         */
 833
 834 #ifdef TURRET_DEBUG_TARGETSELECT
 835         LOG_TRACE("Target:",e_target.netname," is a valid target for ",e_turret.netname);
 836 #endif
 837
 838         return 1;
 839 }
 840
 841 entity turret_select_target(entity this)
 842 {
 843         entity e;               // target looper entity
 844         float  score;   // target looper entity score
 845         entity e_enemy;  // currently best scoreing target
 846         float  m_score;  // currently best scoreing target's score
 847
 848         m_score = 0;
 849         if(this.enemy && this.enemy.takedamage && turret_validate_target(this,this.enemy,this.target_validate_flags) > 0)
 850         {
 851                 e_enemy = this.enemy;
 852                 m_score = this.turret_score_target(this,e_enemy) * this.target_select_samebias;
 853         }
 854         else
 855                 e_enemy = this.enemy = NULL;
 856
 857         e = findradius(this.origin, this.target_range);
 858
 859         // Nothing to aim at?
 860         if (!e)
 861                 return NULL;
 862
 863         while (e)
 864         {
 865                 if(e.takedamage)
 866                 {
 867                         float f = turret_validate_target(this, e, this.target_select_flags);
 868                         //dprint("F is: ", ftos(f), "\n");
 869                         if ( f > 0)
 870                         {
 871                                 score = this.turret_score_target(this,e);
 872                                 if ((score > m_score) && (score > 0))
 873                                 {
 874                                         e_enemy = e;
 875                                         m_score = score;
 876                                 }
 877                         }
 878                 }
 879                 e = e.chain;
 880         }
 881
 882         return e_enemy;
 883 }
 884
 885
 886 /*
 887  + = implemented
 888  - = not implemented
 889
 890  + TFL_FIRECHECK_NO
 891  + TFL_FIRECHECK_WORLD
 892  + TFL_FIRECHECK_DEAD
 893  + TFL_FIRECHECK_DISTANCES
 894  - TFL_FIRECHECK_LOS
 895  + TFL_FIRECHECK_AIMDIST
 896  + TFL_FIRECHECK_REALDIST
 897  - TFL_FIRECHECK_ANGLEDIST
 898  - TFL_FIRECHECK_TEAMCECK
 899  + TFL_FIRECHECK_AFF
 900  + TFL_FIRECHECK_AMMO_OWN
 901  + TFL_FIRECHECK_AMMO_OTHER
 902  + TFL_FIRECHECK_REFIRE
 903 */
 904
 905 /**
 906 ** Preforms pre-fire checks based on the uints firecheck_flags
 907 **/
 908 bool turret_firecheck(entity this)
 909 {
 910         // This one just dont care =)
 911         if (this.firecheck_flags & TFL_FIRECHECK_NO)
 912                 return true;
 913
 914         if (this.enemy == NULL)
 915                 return false;
 916
 917         // Ready?
 918         if (this.firecheck_flags & TFL_FIRECHECK_REFIRE)
 919                 if (this.attack_finished_single[0] > time) return false;
 920
 921         // Special case: volly fire turret that has to fire a full volly if a shot was fired.
 922         if (this.shoot_flags & TFL_SHOOT_VOLLYALWAYS)
 923                 if (this.volly_counter != this.shot_volly)
 924                         if(this.ammo >= this.shot_dmg)
 925                                 return true;
 926
 927         // Lack of zombies makes shooting dead things unnecessary :P
 928         if (this.firecheck_flags & TFL_FIRECHECK_DEAD)
 929                 if (IS_DEAD(this.enemy))
 930                         return false;
 931
 932         // Own ammo?
 933         if (this.firecheck_flags & TFL_FIRECHECK_AMMO_OWN)
 934                 if (this.ammo < this.shot_dmg)
 935                         return false;
 936
 937         // Other's ammo? (support-supply units)
 938         if (this.firecheck_flags & TFL_FIRECHECK_AMMO_OTHER)
 939                 if (this.enemy.ammo >= this.enemy.ammo_max)
 940                         return false;
 941
 942         // Target of opertunity?
 943         if(turret_validate_target(this, this.tur_impactent, this.target_validate_flags) > 0)
 944         {
 945                 this.enemy = this.tur_impactent;
 946                 return true;
 947         }
 948
 949         if (this.firecheck_flags & TFL_FIRECHECK_DISTANCES)
 950         {
 951                 // To close?
 952                 if (this.tur_dist_aimpos < this.target_range_min)
 953                 {
 954                         if(turret_validate_target(this, this.tur_impactent, this.target_validate_flags) > 0)
 955                                 return true; // Target of opertunity?
 956                         return false;
 957                 }
 958         }
 959
 960         // Try to avoid FF?
 961         if (this.firecheck_flags & TFL_FIRECHECK_AFF)
 962                 if (this.tur_impactent.team == this.team)
 963                         return false;
 964
 965         // aim<->predicted impact
 966         if (this.firecheck_flags & TFL_FIRECHECK_AIMDIST)
 967                 if (this.tur_dist_impact_to_aimpos > this.aim_firetolerance_dist)
 968                         return false;
 969
 970         // Volly status
 971         if (this.shot_volly > 1)
 972                 if (this.volly_counter == this.shot_volly)
 973                         if (this.ammo < (this.shot_dmg * this.shot_volly))
 974                                 return false;
 975
 976         /*if(this.firecheck_flags & TFL_FIRECHECK_VERIFIED)
 977                 if(this.tur_impactent != this.enemy)
 978                         return false;*/
 979
 980         return true;
 981 }
 982
 983 bool turret_checkfire(entity this)
 984 {
 985         if(MUTATOR_CALLHOOK(Turret_CheckFire, this))
 986                 return M_ARGV(1, bool);
 987
 988         return this.turret_firecheckfunc(this);
 989 }
 990
 991 void turret_fire(entity this)
 992 {
 993         if (autocvar_g_turrets_nofire != 0)
 994                 return;
 995
 996         if(MUTATOR_CALLHOOK(TurretFire, this))
 997                 return;
 998
 999         Turret info = get_turretinfo(this.m_id);
1000         info.tr_attack(info, this);
1001
1002         this.attack_finished_single[0] = time + this.shot_refire;
1003         this.ammo -= this.shot_dmg;
1004         this.volly_counter = this.volly_counter - 1;
1005
1006         if (this.volly_counter <= 0)
1007         {
1008                 this.volly_counter = this.shot_volly;
1009
1010                 if (this.shoot_flags & TFL_SHOOT_CLEARTARGET)
1011                         this.enemy = NULL;
1012
1013                 if (this.shot_volly > 1)
1014                         this.attack_finished_single[0] = time + this.shot_volly_refire;
1015         }
1016
1017 #ifdef TURRET_DEBUG
1018         if (this.enemy) paint_target3(this.tur_aimpos, 64, this.tur_debug_rvec, this.tur_impacttime + 0.25);
1019 #endif
1020 }
1021
1022 void turret_think(entity this)
1023 {
1024         this.nextthink = time + this.ticrate;
1025
1026         MUTATOR_CALLHOOK(TurretThink, this);
1027
1028 #ifdef TURRET_DEBUG
1029         if (this.tur_debug_tmr1 < time)
1030         {
1031                 if (this.enemy) paint_target (this.enemy,128,this.tur_debug_rvec,0.9);
1032                 paint_target(this,256,this.tur_debug_rvec,0.9);
1033                 this.tur_debug_tmr1 = time + 1;
1034         }
1035 #endif
1036
1037         // Handle ammo
1038         if (!(this.spawnflags & TSF_NO_AMMO_REGEN))
1039         if (this.ammo < this.ammo_max)
1040                 this.ammo = min(this.ammo + this.ammo_recharge, this.ammo_max);
1041
1042         // Inactive turrets needs to run the think loop,
1043         // So they can handle animation and wake up if need be.
1044         if(!this.active)
1045         {
1046                 turret_track(this);
1047                 return;
1048         }
1049
1050         // This is typicaly used for zaping every target in range
1051         // turret_fusionreactor uses this to recharge friendlys.
1052         if (this.shoot_flags & TFL_SHOOT_HITALLVALID)
1053         {
1054                 // Do a this.turret_fire for every valid target.
1055                 entity e = findradius(this.origin,this.target_range);
1056                 while (e)
1057                 {
1058                         if(e.takedamage)
1059                         {
1060                                 if (turret_validate_target(this,e,this.target_validate_flags))
1061                                 {
1062                                         this.enemy = e;
1063
1064                                         turret_do_updates(this);
1065
1066                                         if (turret_checkfire(this))
1067                                                 turret_fire(this);
1068                                 }
1069                         }
1070
1071                         e = e.chain;
1072                 }
1073                 this.enemy = NULL;
1074         }
1075         else if(this.shoot_flags & TFL_SHOOT_CUSTOM)
1076         {
1077                 // This one is doing something.. oddball. assume its handles what needs to be handled.
1078
1079                 // Predict?
1080                 if(!(this.aim_flags & TFL_AIM_NO))
1081                         this.tur_aimpos = turret_aim_generic(this);
1082
1083                 // Turn & pitch?
1084                 if(!(this.track_flags & TFL_TRACK_NO))
1085                         turret_track(this);
1086
1087                 turret_do_updates(this);
1088
1089                 // Fire?
1090                 if (turret_checkfire(this))
1091                         turret_fire(this);
1092         }
1093         else
1094         {
1095                 // Special case for volly always. if it fired once it must compleate the volly.
1096                 if(this.shoot_flags & TFL_SHOOT_VOLLYALWAYS)
1097                         if(this.volly_counter != this.shot_volly)
1098                         {
1099                                 // Predict or whatnot
1100                                 if(!(this.aim_flags & TFL_AIM_NO))
1101                                         this.tur_aimpos = turret_aim_generic(this);
1102
1103                                 // Turn & pitch
1104                                 if(!(this.track_flags & TFL_TRACK_NO))
1105                                         turret_track(this);
1106
1107                                 turret_do_updates(this);
1108
1109                                 // Fire!
1110                                 if (turret_checkfire(this))
1111                                         turret_fire(this);
1112
1113                                 Turret tur = get_turretinfo(this.m_id);
1114                                 tur.tr_think(tur, this);
1115
1116                                 return;
1117                         }
1118
1119                 // Check if we have a vailid enemy, and try to find one if we dont.
1120
1121                 // g_turrets_targetscan_maxdelay forces a target re-scan at least this often
1122                 float do_target_scan = 0;
1123                 if((this.target_select_time + autocvar_g_turrets_targetscan_maxdelay) < time)
1124                         do_target_scan = 1;
1125
1126                 // Old target (if any) invalid?
1127                 if(this.target_validate_time < time)
1128                 if (turret_validate_target(this, this.enemy, this.target_validate_flags) <= 0)
1129                 {
1130                         this.enemy = NULL;
1131                         this.target_validate_time = time + 0.5;
1132                         do_target_scan = 1;
1133                 }
1134
1135                 // But never more often then g_turrets_targetscan_mindelay!
1136                 if (this.target_select_time + autocvar_g_turrets_targetscan_mindelay > time)
1137                         do_target_scan = 0;
1138
1139                 if(do_target_scan)
1140                 {
1141                         this.enemy = turret_select_target(this);
1142                         this.target_select_time = time;
1143                 }
1144
1145                 // No target, just go to idle, do any custom stuff and bail.
1146                 if (this.enemy == NULL)
1147                 {
1148                         // Turn & pitch
1149                         if(!(this.track_flags & TFL_TRACK_NO))
1150                                 turret_track(this);
1151
1152                         Turret tur = get_turretinfo(this.m_id);
1153                         tur.tr_think(tur, this);
1154
1155                         // And bail.
1156                         return;
1157                 }
1158                 else
1159                         this.lip = time + autocvar_g_turrets_aimidle_delay; // Keep track of the last time we had a target.
1160
1161                 // Predict?
1162                 if(!(this.aim_flags & TFL_AIM_NO))
1163                         this.tur_aimpos = turret_aim_generic(this);
1164
1165                 // Turn & pitch?
1166                 if(!(this.track_flags & TFL_TRACK_NO))
1167                         turret_track(this);
1168
1169                 turret_do_updates(this);
1170
1171                 // Fire?
1172                 if (turret_checkfire(this))
1173                         turret_fire(this);
1174         }
1175
1176         Turret tur = get_turretinfo(this.m_id);
1177         tur.tr_think(tur, this);
1178 }
1179
1180 /*
1181         When .used a turret switch team to activator.team.
1182         If activator is NULL, the turret go inactive.
1183 */
1184 void turret_use(entity this, entity actor, entity trigger)
1185 {
1186         LOG_TRACE("Turret ",this.netname, " used by ", actor.classname);
1187
1188         this.team = actor.team;
1189
1190         if(this.team == 0)
1191                 this.active = ACTIVE_NOT;
1192         else
1193                 this.active = ACTIVE_ACTIVE;
1194
1195 }
1196
1197 void turret_link(entity this)
1198 {
1199         Net_LinkEntity(this, true, 0, turret_send);
1200         setthink(this, turret_think);
1201         this.nextthink = time;
1202         this.tur_head.effects = EF_NODRAW;
1203 }
1204
1205 void turrets_manager_think(entity this)
1206 {
1207         this.nextthink = time + 1;
1208
1209         if (autocvar_g_turrets_reloadcvars == 1)
1210         {
1211                 IL_EACH(g_turrets, true,
1212                 {
1213                         load_unit_settings(it, true);
1214                         Turret tur = get_turretinfo(it.m_id);
1215                         tur.tr_think(tur, it);
1216                 });
1217                 cvar_set("g_turrets_reloadcvars", "0");
1218         }
1219 }
1220
1221 void turret_initparams(entity tur)
1222 {
1223         #define TRY(x) (x) ? (x)
1224         tur.respawntime                 = max  (-1,              (TRY(tur.respawntime)               :  60                                         ));
1225         tur.shot_refire                 = bound(0.01,            (TRY(tur.shot_refire)               :  1                                          ), 9999);
1226         tur.shot_dmg                    = max  (1,               (TRY(tur.shot_dmg)                  :  tur.shot_refire * 50                       ));
1227         tur.shot_radius                 = max  (1,               (TRY(tur.shot_radius)               :  tur.shot_dmg * 0.5                         ));
1228         tur.shot_speed                  = max  (1,               (TRY(tur.shot_speed)                :  2500                                       ));
1229         tur.shot_spread                 = bound(0.0001,          (TRY(tur.shot_spread)               :  0.0125                                     ), 500);
1230         tur.shot_force                  = bound(0.001,           (TRY(tur.shot_force)                :  tur.shot_dmg * 0.5 + tur.shot_radius * 0.5 ), 5000);
1231         tur.shot_volly                  = bound(1,               (TRY(tur.shot_volly)                :  1                                          ), floor(tur.ammo_max / tur.shot_dmg));
1232         tur.shot_volly_refire           = bound(tur.shot_refire, (TRY(tur.shot_volly_refire)         :  tur.shot_refire * tur.shot_volly           ), 60);
1233         tur.target_range                = bound(0,               (TRY(tur.target_range)              :  tur.shot_speed * 0.5                       ), max_shot_distance);
1234         tur.target_range_min            = bound(0,               (TRY(tur.target_range_min)          :  tur.shot_radius * 2                        ), max_shot_distance);
1235         tur.target_range_optimal        = bound(0,               (TRY(tur.target_range_optimal)      :  tur.target_range * 0.5                     ), max_shot_distance);
1236         tur.aim_maxrot                  = bound(0,               (TRY(tur.aim_maxrot)                :  90                                         ), 360);
1237         tur.aim_maxpitch                = bound(0,               (TRY(tur.aim_maxpitch)              :  20                                         ), 90);
1238         tur.aim_speed                   = bound(0.1,             (TRY(tur.aim_speed)                 :  36                                         ), 1000);
1239         tur.aim_firetolerance_dist      = bound(0.1,             (TRY(tur.aim_firetolerance_dist)    :  5 + (tur.shot_radius * 2)                  ), max_shot_distance);
1240         tur.target_select_rangebias     = bound(-10,             (TRY(tur.target_select_rangebias)   :  1                                          ), 10);
1241         tur.target_select_samebias      = bound(-10,             (TRY(tur.target_select_samebias)    :  1                                          ), 10);
1242         tur.target_select_anglebias     = bound(-10,             (TRY(tur.target_select_anglebias)   :  1                                          ), 10);
1243         tur.target_select_missilebias   = bound(-10,             (TRY(tur.target_select_missilebias) :  1                                          ), 10);
1244         tur.target_select_playerbias    = bound(-10,             (TRY(tur.target_select_playerbias)  :  1                                          ), 10);
1245         tur.ammo_max                    = max  (tur.shot_dmg,    (TRY(tur.ammo_max)                  :  tur.shot_dmg * 10                          ));
1246         tur.ammo_recharge               = max  (0,               (TRY(tur.ammo_recharge)             :  tur.shot_dmg * 0.5                         ));
1247         #undef TRY
1248 }
1249
1250 bool turret_closetotarget(entity this, vector targ, float range)
1251 {
1252         vector path_extra_size = '1 1 1' * range;
1253         return boxesoverlap(targ - path_extra_size, targ + path_extra_size, this.absmin - path_extra_size, this.absmax + path_extra_size);
1254 }
1255
1256 void turret_findtarget(entity this)
1257 {
1258         entity e = find(NULL, classname, "turret_manager");
1259         if(!e)
1260         {
1261                 e = new_pure(turret_manager);
1262                 setthink(e, turrets_manager_think);
1263                 e.nextthink = time + 2;
1264         }
1265
1266         entity targ = find(NULL, targetname, this.target);
1267         if(targ.classname == "turret_checkpoint")
1268                 return; // turrets don't defend checkpoints?
1269
1270         if (!targ)
1271         {
1272                 this.target = "";
1273                 LOG_TRACE("Turret has invalid defendpoint!");
1274         }
1275
1276         this.tur_defend = targ;
1277         this.idle_aim = this.tur_head.angles + angleofs(this.tur_head, targ);
1278 }
1279
1280 void turret_reset(entity this)
1281 {
1282         turret_respawn(this);
1283 }
1284
1285 bool turret_initialize(entity this, Turret tur)
1286 {
1287         if(!autocvar_g_turrets)
1288                 return false;
1289
1290         if(tur.m_id == 0)
1291                 return false; // invalid turret
1292
1293         // if tur_head exists, we can assume this turret re-spawned
1294         if(!this.tur_head) {
1295                 tur.tr_precache(tur);
1296                 IL_PUSH(g_turrets, this);
1297                 IL_PUSH(g_bot_targets, this);
1298         }
1299
1300         if(!(this.spawnflags & TSF_SUSPENDED))
1301                 droptofloor(this);
1302
1303         this.netname = tur.netname;
1304         load_unit_settings(this, 0);
1305
1306         if(!this.team || !teamplay)             { this.team = FLOAT_MAX; }
1307         if(!this.ticrate)                               { this.ticrate = ((this.turret_flags & TUR_FLAG_SUPPORT) ? 0.2 : 0.1); }
1308         if(!GetResource(this, RES_HEALTH)) { SetResourceExplicit(this, RES_HEALTH, 1000); }
1309         if(!this.shot_refire)                   { this.shot_refire = 1; }
1310         if(!this.tur_shotorg)                   { this.tur_shotorg = '50 0 50'; }
1311         if(!this.turret_flags)                  { this.turret_flags = TUR_FLAG_SPLASH | TUR_FLAG_MEDPROJ | TUR_FLAG_PLAYER; }
1312         if(!this.damage_flags)                  { this.damage_flags = TFL_DMG_YES | TFL_DMG_RETALIATE | TFL_DMG_AIMSHAKE; }
1313         if(!this.aim_flags)                             { this.aim_flags = TFL_AIM_LEAD | TFL_AIM_SHOTTIMECOMPENSATE; }
1314         if(!this.track_type)                    { this.track_type = TFL_TRACKTYPE_STEPMOTOR; }
1315         if(!this.track_flags)                   { this.track_flags = TFL_TRACK_PITCH | TFL_TRACK_ROTATE; }
1316         if(!this.ammo_flags)                    { this.ammo_flags = TFL_AMMO_ENERGY | TFL_AMMO_RECHARGE; }
1317         if(!this.target_select_flags)   { this.target_select_flags = TFL_TARGETSELECT_LOS | TFL_TARGETSELECT_TEAMCHECK | TFL_TARGETSELECT_RANGELIMITS | TFL_TARGETSELECT_ANGLELIMITS; }
1318         if(!this.firecheck_flags)               { this.firecheck_flags = TFL_FIRECHECK_DEAD | TFL_FIRECHECK_DISTANCES | TFL_FIRECHECK_LOS
1319                                                                                                                    | TFL_FIRECHECK_AIMDIST | TFL_FIRECHECK_TEAMCHECK | TFL_FIRECHECK_AMMO_OWN | TFL_FIRECHECK_REFIRE; }
1320
1321         if(this.track_type != TFL_TRACKTYPE_STEPMOTOR)
1322         {
1323                 // Fluid / Ineria mode. Looks mutch nicer.
1324                 // Can reduce aim preformance alot, needs a bit diffrent aimspeed
1325
1326                 this.aim_speed = bound(0.1, ((!this.aim_speed) ? 180 : this.aim_speed), 1000);
1327
1328                 if(!this.track_accel_pitch)             { this.track_accel_pitch = 0.5; }
1329                 if(!this.track_accel_rot)               { this.track_accel_rot = 0.5; }
1330                 if(!this.track_blendrate)               { this.track_blendrate = 0.35; }
1331         }
1332
1333         turret_initparams(this);
1334
1335         this.turret_flags = TUR_FLAG_ISTURRET | (tur.spawnflags);
1336
1337         if(this.turret_flags & TUR_FLAG_SPLASH)
1338                 this.aim_flags |= TFL_AIM_SPLASH;
1339
1340         if(this.turret_flags & TUR_FLAG_MISSILE)
1341                 this.target_select_flags |= TFL_TARGETSELECT_MISSILES;
1342
1343         if(this.turret_flags & TUR_FLAG_PLAYER)
1344                 this.target_select_flags |= TFL_TARGETSELECT_PLAYERS;
1345
1346         if(this.spawnflags & TSL_NO_RESPAWN)
1347                 this.damage_flags |= TFL_DMG_DEATH_NORESPAWN;
1348
1349         if (this.turret_flags & TUR_FLAG_SUPPORT)
1350                 this.turret_score_target = turret_targetscore_support;
1351         else
1352                 this.turret_score_target = turret_targetscore_generic;
1353
1354         ++turret_count;
1355
1356         _setmodel(this, tur.model);
1357         setsize(this, tur.m_mins, tur.m_maxs);
1358
1359         this.m_id                                       = tur.m_id;
1360         this.active                                     = ACTIVE_ACTIVE;
1361         this.effects                            = EF_NODRAW;
1362         this.netname                            = tur.turret_name;
1363         this.ticrate                            = bound(sys_frametime, this.ticrate, 60);
1364         this.max_health                         = GetResource(this, RES_HEALTH);
1365         this.target_validate_flags      = this.target_select_flags;
1366         this.ammo                                       = this.ammo_max;
1367         this.ammo_recharge                 *= this.ticrate;
1368         this.solid                                      = SOLID_BBOX;
1369         this.takedamage                         = DAMAGE_AIM;
1370         set_movetype(this, MOVETYPE_NOCLIP);
1371         this.view_ofs                           = '0 0 0';
1372         this.idle_aim                           = '0 0 0';
1373         this.turret_firecheckfunc       = turret_firecheck;
1374         this.event_damage                       = turret_damage;
1375         this.event_heal                         = turret_heal;
1376         this.use                                        = turret_use;
1377         this.bot_attack                         = true;
1378         this.nextthink                          = time + 1 + turret_count * sys_frametime;
1379         this.reset                                      = turret_reset;
1380
1381         this.tur_head = new(turret_head);
1382         _setmodel(this.tur_head, tur.head_model);
1383         setsize(this.tur_head, '0 0 0', '0 0 0');
1384         setorigin(this.tur_head, '0 0 0');
1385         setattachment(this.tur_head, this, "tag_head");
1386
1387         this.tur_head.netname           = this.tur_head.classname;
1388         this.tur_head.team                      = this.team;
1389         this.tur_head.owner                     = this;
1390         this.tur_head.takedamage        = DAMAGE_NO;
1391         this.tur_head.solid                     = SOLID_NOT;
1392         set_movetype(this.tur_head, this.move_movetype);
1393
1394         this.weaponentities[0] = this; // lol
1395
1396         if(!this.tur_defend && this.target != "")
1397                 InitializeEntity(this, turret_findtarget, INITPRIO_FINDTARGET);
1398
1399 #ifdef TURRET_DEBUG
1400         this.tur_debug_start = this.nextthink;
1401         while(vdist(this.tur_debug_rvec, <, 2))
1402                 this.tur_debug_rvec = randomvec() * 4;
1403
1404         this.tur_debug_rvec_x = fabs(this.tur_debug_rvec_x);
1405         this.tur_debug_rvec_y = fabs(this.tur_debug_rvec_y);
1406         this.tur_debug_rvec_z = fabs(this.tur_debug_rvec_z);
1407 #endif
1408
1409         turret_link(this);
1410         turret_respawn(this);
1411         turret_tag_fire_update(this);
1412
1413         tur.tr_setup(tur, this);
1414
1415         if(MUTATOR_CALLHOOK(TurretSpawn, this))
1416                 return false;
1417
1418         return true;
1419 }
1420 #endif