qcsrc/common/mutators/mutator/powerups/sv_powerups.qc

   1 #include "sv_powerups.qh"
   2
   3 MUTATOR_HOOKFUNCTION(powerups, W_PlayStrengthSound)
   4 {
   5         entity player = M_ARGV(0, entity);
   6
   7         if(StatusEffects_active(STATUSEFFECT_Strength, player)
   8                 && ((time > player.prevstrengthsound + autocvar_sv_strengthsound_antispam_time) // prevent insane sound spam
   9                 || (time > player.prevstrengthsoundattempt + autocvar_sv_strengthsound_antispam_refire_threshold)))
  10                 {
  11                         sound(player, CH_TRIGGER, SND_STRENGTH_FIRE, VOL_BASE, ATTEN_NORM);
  12                         player.prevstrengthsound = time;
  13                 }
  14         player.prevstrengthsoundattempt = time;
  15 }
  16
  17 MUTATOR_HOOKFUNCTION(powerups, LogDeath_AppendItemCodes)
  18 {
  19         entity player = M_ARGV(0, entity);
  20
  21         if(StatusEffects_active(STATUSEFFECT_Strength, player))
  22                 M_ARGV(1, string) = strcat(M_ARGV(1, string), "S");
  23
  24         if(StatusEffects_active(STATUSEFFECT_Shield, player))
  25                 M_ARGV(1, string) = strcat(M_ARGV(1, string), "I");
  26
  27         // TODO: item codes for other powerups?
  28 }
  29
  30 MUTATOR_HOOKFUNCTION(powerups, Damage_Calculate)
  31 {
  32         entity attacker = M_ARGV(1, entity);
  33         entity targ = M_ARGV(2, entity);
  34
  35         // apply strength multiplier
  36         if(StatusEffects_active(STATUSEFFECT_Strength, attacker))
  37         {
  38                 if(targ == attacker)
  39                 {
  40                         M_ARGV(4, float) = M_ARGV(4, float) * autocvar_g_balance_powerup_strength_selfdamage;
  41                         M_ARGV(6, vector) = M_ARGV(6, vector) * autocvar_g_balance_powerup_strength_selfforce;
  42                 }
  43                 else
  44                 {
  45                         M_ARGV(4, float) = M_ARGV(4, float) * autocvar_g_balance_powerup_strength_damage;
  46                         M_ARGV(6, vector) = M_ARGV(6, vector) * autocvar_g_balance_powerup_strength_force;
  47                 }
  48         }
  49
  50         // apply shield multiplier
  51         if(StatusEffects_active(STATUSEFFECT_Shield, targ))
  52         {
  53                 M_ARGV(4, float) = M_ARGV(4, float) * autocvar_g_balance_powerup_invincible_takedamage;
  54                 if (targ != attacker)
  55                 {
  56                         M_ARGV(6, vector) = M_ARGV(6, vector) * autocvar_g_balance_powerup_invincible_takeforce;
  57                 }
  58         }
  59 }
  60
  61 MUTATOR_HOOKFUNCTION(powerups, CustomizeWaypoint)
  62 {
  63         entity wp = M_ARGV(0, entity);
  64         entity player = M_ARGV(1, entity);
  65
  66         entity e = WaypointSprite_getviewentity(player);
  67
  68         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
  69         // but only apply this to real players, not to spectators
  70         if(IS_CLIENT(wp.owner) && (e == player) && DIFF_TEAM(wp.owner, e) && StatusEffects_active(STATUSEFFECT_Invisibility, wp.owner))
  71                 return true;
  72 }
  73
  74 MUTATOR_HOOKFUNCTION(powerups, MonsterValidTarget)
  75 {
  76         entity targ = M_ARGV(1, entity);
  77         return StatusEffects_active(STATUSEFFECT_Invisibility, targ);
  78 }
  79
  80 void powerups_DropItem(entity this, StatusEffects effect)
  81 {
  82         entity item = Item_DefinitionFromInternalName(effect.netname);
  83         float t = StatusEffects_gettime(effect, this);
  84         float timeleft = t - time;
  85
  86         if(timeleft <= 1 || !item)
  87                 return;
  88         entity e = spawn();
  89
  90         // If we want the timer to keep running, we enable expiring then use the exact time the powerup will finish at.
  91         // If we want the timer to freeze, we disable expiring and we just use the time left of the powerup.
  92         // See Item_SetExpiring() below.
  93         float finished_time = (autocvar_g_powerups_dropondeath == 2 ? timeleft : t);
  94
  95         // If the timer is frozen, the item will stay on the floor for 60 secs (TODO hardcoded for now),
  96         // otherwise it'll disappear after the timer runs out.
  97         float time_to_live = (autocvar_g_powerups_dropondeath == 2 ? 60 : timeleft);
  98
  99         // TODO: items cannot hold their "item field" yet, so we need to list all the powerups here!
 100         switch(item)
 101         {
 102                 case ITEM_Strength: e.strength_finished = finished_time; break;
 103                 case ITEM_Shield: e.invincible_finished = finished_time; break;
 104                 case ITEM_Invisibility: e.invisibility_finished = finished_time; break;
 105                 case ITEM_Speed: e.speed_finished = finished_time; break;
 106         }
 107         Item_InitializeLoot(e, item.m_canonical_spawnfunc, this.origin + '0 0 32', randomvec() * 175 + '0 0 175', time_to_live);
 108
 109         if(autocvar_g_powerups_dropondeath != 2)
 110                 Item_SetExpiring(e, true);
 111 }
 112
 113 MUTATOR_HOOKFUNCTION(powerups, PlayerDies)
 114 {
 115         if(!autocvar_g_powerups_dropondeath)
 116                 return;
 117
 118         entity frag_target = M_ARGV(2, entity);
 119
 120         FOREACH(StatusEffect, it.instanceOfPowerups,
 121         {
 122                 if(StatusEffects_active(it, frag_target))
 123                         powerups_DropItem(frag_target, it);
 124         });
 125 }
 126
 127 MUTATOR_HOOKFUNCTION(powerups, PlayerPhysics_UpdateStats)
 128 {
 129         entity player = M_ARGV(0, entity);
 130         // these automatically reset, no need to worry
 131
 132         if(StatusEffects_active(STATUSEFFECT_Speed, player))
 133                 STAT(MOVEVARS_HIGHSPEED, player) *= autocvar_g_balance_powerup_speed_highspeed;
 134 }
 135
 136 MUTATOR_HOOKFUNCTION(powerups, WeaponRateFactor)
 137 {
 138         entity player = M_ARGV(1, entity);
 139
 140         if(StatusEffects_active(STATUSEFFECT_Speed, player))
 141                 M_ARGV(0, float) *= autocvar_g_balance_powerup_speed_attackrate;
 142 }
 143
 144 MUTATOR_HOOKFUNCTION(powerups, BuildMutatorsPrettyString)
 145 {
 146         if(autocvar_g_powerups == 0)
 147                 M_ARGV(0, string) = strcat(M_ARGV(0, string), ", No powerups");
 148         if(autocvar_g_powerups > 0)
 149                 M_ARGV(0, string) = strcat(M_ARGV(0, string), ", Powerups");
 150 }
 151
 152 MUTATOR_HOOKFUNCTION(powerups, BotShouldAttack)
 153 {
 154         entity targ = M_ARGV(1, entity);
 155
 156         if(StatusEffects_active(STATUSEFFECT_Invisibility, targ))
 157                 return true;
 158 }
 159
 160 MUTATOR_HOOKFUNCTION(powerups, BuildMutatorsString)
 161 {
 162         if(autocvar_g_powerups == 0)
 163                 M_ARGV(0, string) = strcat(M_ARGV(0, string), ":no_powerups");
 164         if(autocvar_g_powerups > 0)
 165                 M_ARGV(0, string) = strcat(M_ARGV(0, string), ":powerups");
 166 }