qcsrc/common/mutators/mutator/overkill/okmachinegun.qc

   1 #include "okmachinegun.qh"
   2
   3 #ifdef SVQC
   4
   5 void W_OverkillMachineGun_Attack_Auto(Weapon thiswep, entity actor, .entity weaponentity, int fire)
   6 {
   7         float okmachinegun_spread;
   8
   9         if(!(fire & 1))
  10         {
  11                 w_ready(thiswep, actor, weaponentity, fire);
  12                 return;
  13         }
  14
  15         if(!thiswep.wr_checkammo1(thiswep, actor, weaponentity))
  16         if(!(actor.items & IT_UNLIMITED_AMMO))
  17         {
  18                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
  19                 w_ready(thiswep, actor, weaponentity, fire);
  20                 return;
  21         }
  22
  23         W_DecreaseAmmo(WEP_OVERKILL_MACHINEGUN, actor, WEP_CVAR_PRI(WEP_OVERKILL_MACHINEGUN, ammo), weaponentity);
  24
  25         W_SetupShot(actor, weaponentity, true, 0, SND_UZI_FIRE, CH_WEAPON_A, WEP_CVAR_PRI(WEP_OVERKILL_MACHINEGUN, damage), WEP_OVERKILL_MACHINEGUN.m_id);
  26         if(!autocvar_g_norecoil)
  27         {
  28                 actor.punchangle_x = random() - 0.5;
  29                 actor.punchangle_y = random() - 0.5;
  30         }
  31
  32         okmachinegun_spread = bound(WEP_CVAR_PRI(WEP_OVERKILL_MACHINEGUN, spread_min), WEP_CVAR_PRI(WEP_OVERKILL_MACHINEGUN, spread_min) + (WEP_CVAR_PRI(WEP_OVERKILL_MACHINEGUN, spread_add) * actor.(weaponentity).misc_bulletcounter), WEP_CVAR_PRI(WEP_OVERKILL_MACHINEGUN, spread_max));
  33         fireBullet(actor, weaponentity, w_shotorg, w_shotdir, okmachinegun_spread, WEP_CVAR_PRI(WEP_OVERKILL_MACHINEGUN, solidpenetration), WEP_CVAR_PRI(WEP_OVERKILL_MACHINEGUN, damage), 0, WEP_CVAR_PRI(WEP_OVERKILL_MACHINEGUN, force), WEP_OVERKILL_MACHINEGUN.m_id, EFFECT_RIFLE);
  34
  35         actor.(weaponentity).misc_bulletcounter = actor.(weaponentity).misc_bulletcounter + 1;
  36
  37         W_MuzzleFlash(thiswep, actor, weaponentity, w_shotorg, w_shotdir);
  38
  39         if(autocvar_g_casings >= 2) // casing code
  40         {
  41                 makevectors(actor.v_angle); // for some reason, this is lost
  42                 SpawnCasing(((random() * 50 + 50) * v_right) - (v_forward * (random() * 25 + 25)) - ((random() * 5 - 70) * v_up), vectoangles(v_forward), 3, actor, weaponentity);
  43         }
  44
  45         ATTACK_FINISHED(actor, weaponentity) = time + WEP_CVAR_PRI(WEP_OVERKILL_MACHINEGUN, refire) * W_WeaponRateFactor(actor);
  46         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(WEP_OVERKILL_MACHINEGUN, refire), W_OverkillMachineGun_Attack_Auto);
  47 }
  48
  49 METHOD(OverkillMachineGun, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
  50 {
  51         if(vdist(actor.origin - actor.enemy.origin, <, 3000 - bound(0, skill, 10) * 200))
  52                 PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false, true);
  53 }
  54
  55 METHOD(OverkillMachineGun, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
  56 {
  57         if ((WEP_CVAR_SEC(WEP_OVERKILL_MACHINEGUN, refire_type) == 1) && (fire & 2) && (time >= actor.jump_interval))
  58         {
  59                 // Secondary uses it's own refire timer if refire_type is 1.
  60                 actor.jump_interval = time + WEP_CVAR_PRI(WEP_BLASTER, refire) * W_WeaponRateFactor(actor);
  61                 makevectors(actor.v_angle);
  62                 W_Blaster_Attack(actor, weaponentity);
  63                 if ((actor.(weaponentity).wframe == WFRAME_IDLE) ||
  64                         (actor.(weaponentity).wframe == WFRAME_FIRE2))
  65                 {
  66                         // Set secondary fire animation.
  67                         actor.(weaponentity).wframe = WFRAME_FIRE2;
  68                         FOREACH_CLIENT(true, LAMBDA(
  69                                 if (it == actor || (IS_SPEC(it) && it.enemy == actor))
  70                                 {
  71                                         wframe_send(it, actor.(weaponentity), WFRAME_FIRE2, autocvar_g_weaponratefactor, true);
  72                                 }
  73                         ));
  74                         animdecide_setaction(actor, ANIMACTION_SHOOT, true);
  75                 }
  76         }
  77         if (WEP_CVAR(WEP_OVERKILL_MACHINEGUN, reload_ammo) && actor.(weaponentity).clip_load < WEP_CVAR_PRI(WEP_OVERKILL_MACHINEGUN, ammo))
  78         {
  79                 // Forced reload
  80                 thiswep.wr_reload(thiswep, actor, weaponentity);
  81                 return;
  82         }
  83         if (fire & 1) // Primary attack
  84         {
  85                 if (!weapon_prepareattack(thiswep, actor, weaponentity, false, 0))
  86                 {
  87                         return;
  88                 }
  89                 actor.(weaponentity).misc_bulletcounter = 0;
  90                 W_OverkillMachineGun_Attack_Auto(thiswep, actor, weaponentity, fire);
  91                 return;
  92         }
  93         if ((fire & 2) && (WEP_CVAR_SEC(WEP_OVERKILL_MACHINEGUN, refire_type) == 0)) // Secondary attack
  94         {
  95                 if (!weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_PRI(WEP_BLASTER, refire)))
  96                 {
  97                         return;
  98                 }
  99                 makevectors(actor.v_angle);
 100                 W_Blaster_Attack(actor, weaponentity);
 101                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_PRI(WEP_BLASTER, animtime), w_ready);
 102         }
 103 }
 104
 105 METHOD(OverkillMachineGun, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 106 {
 107         float ammo_amount;
 108         ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(WEP_OVERKILL_MACHINEGUN, ammo);
 109         if (WEP_CVAR(WEP_OVERKILL_MACHINEGUN, reload_ammo))
 110         {
 111                 ammo_amount += actor.(weaponentity).(weapon_load[WEP_OVERKILL_MACHINEGUN.m_id]) >= WEP_CVAR_PRI(WEP_OVERKILL_MACHINEGUN, ammo);
 112         }
 113         return ammo_amount;
 114 }
 115
 116 METHOD(OverkillMachineGun, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 117 {
 118         return true; // Blaster secondary is unlimited.
 119 }
 120
 121 METHOD(OverkillMachineGun, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 122 {
 123         W_Reload(actor, weaponentity, WEP_CVAR_PRI(WEP_OVERKILL_MACHINEGUN, ammo), SND_RELOAD);
 124 }
 125
 126 METHOD(OverkillMachineGun, wr_suicidemessage, Notification(entity thiswep))
 127 {
 128         return WEAPON_THINKING_WITH_PORTALS;
 129 }
 130
 131 METHOD(OverkillMachineGun, wr_killmessage, Notification(entity thiswep))
 132 {
 133         return WEAPON_OVERKILL_MACHINEGUN_MURDER;
 134 }
 135
 136 #endif
 137 #ifdef CSQC
 138
 139 METHOD(OverkillMachineGun, wr_impacteffect, void(entity thiswep, entity actor))
 140 {
 141         vector org2 = w_org + w_backoff * 2;
 142         pointparticles(EFFECT_MACHINEGUN_IMPACT, org2, w_backoff * 1000, 1);
 143         if(!w_issilent)
 144                 sound(actor, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTN_NORM);
 145 }
 146
 147 #endif