qcsrc/common/mutators/mutator/buffs/sv_buffs.qc

   1 #include "sv_buffs.qh"
   2
   3 #include <common/mapobjects/target/music.qh>
   4 #include <common/mutators/mutator/instagib/_mod.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <server/items/items.qh>
   7
   8 bool buffs_BuffModel_Customize(entity this, entity client)
   9 {
  10         entity player = WaypointSprite_getviewentity(client);
  11         entity myowner = this.owner;
  12
  13         if(myowner.alpha <= 0.5 && DIFF_TEAM(player, myowner) && myowner.alpha != 0)
  14                 return false;
  15
  16         if(MUTATOR_CALLHOOK(BuffModel_Customize, this, player))
  17                 return false;
  18
  19         if(player == myowner)
  20         {
  21                 // somewhat hide the model, but keep the glow
  22                 this.effects = 0;
  23                 this.alpha = -1;
  24         }
  25         else
  26         {
  27                 this.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
  28                 this.alpha = 1;
  29         }
  30         return true;
  31 }
  32
  33 void buffs_BuffModel_Spawn(entity player)
  34 {
  35         player.buff_model = new(buff_model);
  36         setmodel(player.buff_model, MDL_BUFF);
  37         setsize(player.buff_model, '0 0 -40', '0 0 40');
  38         setattachment(player.buff_model, player, "");
  39         setorigin(player.buff_model, '0 0 1' * (player.buff_model.maxs.z * 1));
  40         player.buff_model.owner = player;
  41         player.buff_model.scale = 0.7;
  42         player.buff_model.pflags = PFLAGS_FULLDYNAMIC;
  43         player.buff_model.light_lev = 200;
  44         setcefc(player.buff_model, buffs_BuffModel_Customize);
  45 }
  46
  47 void buffs_BuffModel_Remove(entity player)
  48 {
  49         if(player.buff_model)
  50                 delete(player.buff_model);
  51         player.buff_model = NULL;
  52 }
  53
  54 vector buff_GlowColor(entity buff)
  55 {
  56         //if(buff.team_forced) { return Team_ColorRGB(buff.team_forced); }
  57         return buff.m_color;
  58 }
  59
  60 void buff_Effect(entity player, string eff)
  61 {
  62         if(!autocvar_g_buffs_effects) { return; }
  63
  64         if(time >= player.buff_effect_delay)
  65         {
  66                 Send_Effect_(eff, player.origin + ((player.mins + player.maxs) * 0.5), '0 0 0', 1);
  67                 player.buff_effect_delay = time + 0.05; // prevent spam
  68         }
  69 }
  70
  71 // buff item
  72 bool buff_Waypoint_visible_for_player(entity this, entity player, entity view)
  73 {
  74         if(!this.owner.buff_active && !this.owner.buff_activetime)
  75                 return false;
  76
  77         if (STAT(BUFFS, view))
  78         {
  79                 return CS_CVAR(view).cvar_cl_buffs_autoreplace == false || STAT(BUFFS, view) != STAT(BUFFS, this.owner);
  80         }
  81
  82         return WaypointSprite_visible_for_player(this, player, view);
  83 }
  84
  85 void buff_Waypoint_Spawn(entity e)
  86 {
  87         if(autocvar_g_buffs_waypoint_distance <= 0) return;
  88
  89         entity buff = buff_FirstFromFlags(STAT(BUFFS, e));
  90         entity wp = WaypointSprite_Spawn(WP_Buff, 0, autocvar_g_buffs_waypoint_distance, e, '0 0 1' * e.maxs.z, NULL, e.team_forced, e, buff_waypoint, true, RADARICON_Buff);
  91         wp.wp_extra = buff.m_id;
  92         WaypointSprite_UpdateTeamRadar(e.buff_waypoint, RADARICON_Buff, e.glowmod);
  93         e.buff_waypoint.waypointsprite_visible_for_player = buff_Waypoint_visible_for_player;
  94 }
  95
  96 void buff_SetCooldown(entity this, float cd)
  97 {
  98         cd = max(0, cd);
  99
 100         if(!this.buff_waypoint)
 101                 buff_Waypoint_Spawn(this);
 102
 103         if(this.buff_waypoint)
 104                 WaypointSprite_UpdateBuildFinished(this.buff_waypoint, time + cd);
 105
 106         this.buff_activetime = cd;
 107         this.buff_active = !cd;
 108 }
 109
 110 void buff_Respawn(entity this)
 111 {
 112         if(game_stopped) return;
 113
 114         vector oldbufforigin = this.origin;
 115         this.velocity = '0 0 200';
 116
 117         if(!MoveToRandomMapLocation(this, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY,
 118                 ((autocvar_g_buffs_random_location_attempts > 0) ? autocvar_g_buffs_random_location_attempts : 10), 1024, 256))
 119         {
 120                 entity spot = SelectSpawnPoint(this, true);
 121                 setorigin(this, spot.origin);
 122                 this.velocity = ((randomvec() * 100) + '0 0 200');
 123                 this.angles = spot.angles;
 124         }
 125
 126         tracebox(this.origin, this.mins * 1.5, this.maxs * 1.5, this.origin, MOVE_NOMONSTERS, this);
 127
 128         setorigin(this, trace_endpos); // attempt to unstick
 129
 130         set_movetype(this, MOVETYPE_TOSS);
 131
 132         makevectors(this.angles);
 133         this.angles = '0 0 0';
 134         if(autocvar_g_buffs_random_lifetime > 0)
 135                 this.lifetime = time + autocvar_g_buffs_random_lifetime;
 136
 137         Send_Effect(EFFECT_ELECTRO_COMBO, oldbufforigin + ((this.mins + this.maxs) * 0.5), '0 0 0', 1);
 138         Send_Effect(EFFECT_ELECTRO_COMBO, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 139
 140         WaypointSprite_Ping(this.buff_waypoint);
 141
 142         sound(this, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 143 }
 144
 145 void buff_Touch(entity this, entity toucher)
 146 {
 147         if(game_stopped) return;
 148
 149         if(ITEM_TOUCH_NEEDKILL())
 150         {
 151                 buff_Respawn(this);
 152                 return;
 153         }
 154
 155         if(!this.buff_active)
 156                 return;
 157
 158         if(MUTATOR_CALLHOOK(BuffTouch, this, toucher))
 159                 return;
 160         toucher = M_ARGV(1, entity);
 161
 162         if(!IS_PLAYER(toucher))
 163                 return; // incase mutator changed toucher
 164
 165         if((this.team_forced && toucher.team != this.team_forced)
 166         || (STAT(FROZEN, toucher))
 167         || (toucher.vehicle)
 168         || (time < PS(toucher).buff_shield)
 169         )
 170         {
 171                 // can't touch this
 172                 return;
 173         }
 174
 175         if (STAT(BUFFS, toucher))
 176         {
 177                 if (CS_CVAR(toucher).cvar_cl_buffs_autoreplace && STAT(BUFFS, toucher) != STAT(BUFFS, this))
 178                 {
 179                         // TODO: lost-gained notification for this case
 180                         int buffid = buff_FirstFromFlags(STAT(BUFFS, toucher)).m_id;
 181                         Send_Notification(NOTIF_ONE, toucher, MSG_INFO, INFO_ITEM_BUFF_LOST, toucher.netname, buffid);
 182                         if(!IS_INDEPENDENT_PLAYER(toucher))
 183                                 Send_Notification(NOTIF_ALL_EXCEPT, toucher, MSG_INFO, INFO_ITEM_BUFF_LOST, toucher.netname, buffid);
 184
 185                         STAT(BUFFS, toucher) = 0;
 186                         //sound(toucher, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 187                 }
 188                 else { return; } // do nothing
 189         }
 190
 191         this.owner = toucher;
 192         this.buff_active = false;
 193         this.lifetime = 0;
 194         entity thebuff = buff_FirstFromFlags(STAT(BUFFS, this));
 195         Send_Notification(NOTIF_ONE, toucher, MSG_MULTI, ITEM_BUFF_GOT, thebuff.m_id);
 196         if(!IS_INDEPENDENT_PLAYER(toucher))
 197                 Send_Notification(NOTIF_ALL_EXCEPT, toucher, MSG_INFO, INFO_ITEM_BUFF, toucher.netname, thebuff.m_id);
 198
 199         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 200         sound(toucher, CH_TRIGGER, SND_SHIELD_RESPAWN, VOL_BASE, ATTN_NORM);
 201         STAT(BUFFS, toucher) |= (STAT(BUFFS, this));
 202         STAT(LAST_PICKUP, toucher) = time;
 203         float bufftime = ((this.count) ? this.count : thebuff.m_time(thebuff));
 204         if(bufftime)
 205                 STAT(BUFF_TIME, toucher) = min(time + bufftime, max(STAT(BUFF_TIME, toucher), time) + bufftime);
 206 }
 207
 208 float buff_Available(entity buff)
 209 {
 210         if (buff == BUFF_Null)
 211                 return false;
 212         if (buff == BUFF_AMMO && ((start_items & IT_UNLIMITED_AMMO) || cvar("g_melee_only")))
 213                 return false;
 214         if (buff == BUFF_VAMPIRE && cvar("g_vampire"))
 215                 return false;
 216         return cvar(strcat("g_buffs_", buff.netname));
 217 }
 218
 219 .int buff_seencount;
 220
 221 void buff_NewType(entity ent)
 222 {
 223         RandomSelection_Init();
 224         FOREACH(Buffs, buff_Available(it),
 225         {
 226                 // if it's already been chosen, give it a lower priority
 227                 float myseencount = (it.buff_seencount > 0) ? it.buff_seencount : 1; // no division by zero please!
 228                 RandomSelection_AddEnt(it, max(0.2, 1 / myseencount), 1);
 229         });
 230         entity newbuff = RandomSelection_chosen_ent;
 231         newbuff.buff_seencount += 1; // lower chances of seeing this buff again soon
 232         STAT(BUFFS, ent) = newbuff.m_itemid;
 233 }
 234
 235 void buff_Think(entity this)
 236 {
 237         if(this.buff_waypoint && autocvar_g_buffs_waypoint_distance <= 0)
 238                 WaypointSprite_Kill(this.buff_waypoint);
 239
 240         if(STAT(BUFFS, this) != this.oldbuffs)
 241         {
 242                 entity buff = buff_FirstFromFlags(STAT(BUFFS, this));
 243                 this.color = buff.m_color;
 244                 this.glowmod = buff_GlowColor(buff);
 245                 this.skin = buff.m_skin;
 246
 247                 setmodel(this, MDL_BUFF);
 248                 setsize(this, BUFF_MIN, BUFF_MAX);
 249
 250                 if(this.buff_waypoint)
 251                 {
 252                         //WaypointSprite_Disown(this.buff_waypoint, 1);
 253                         WaypointSprite_Kill(this.buff_waypoint);
 254                         buff_Waypoint_Spawn(this);
 255                         if(this.buff_activetime)
 256                                 WaypointSprite_UpdateBuildFinished(this.buff_waypoint, time + this.buff_activetime - frametime);
 257                 }
 258
 259                 this.oldbuffs = STAT(BUFFS, this);
 260         }
 261
 262         if(!game_stopped)
 263         if((round_handler_IsActive() && round_handler_IsRoundStarted()) || time >= game_starttime)
 264         if(!this.buff_activetime_updated)
 265         {
 266                 buff_SetCooldown(this, this.buff_activetime);
 267                 this.buff_activetime_updated = true;
 268         }
 269
 270         if(!this.buff_active && !this.buff_activetime)
 271         if(!this.owner || STAT(FROZEN, this.owner) || IS_DEAD(this.owner) || !this.owner.iscreature || this.owner.vehicle || !(STAT(BUFFS, this.owner) & STAT(BUFFS, this)) || this.pickup_anyway > 0 || (this.pickup_anyway >= 0 && autocvar_g_buffs_pickup_anyway))
 272         {
 273                 buff_SetCooldown(this, autocvar_g_buffs_cooldown_respawn + frametime);
 274                 this.owner = NULL;
 275                 if(autocvar_g_buffs_randomize && (!teamplay || autocvar_g_buffs_randomize_teamplay))
 276                         buff_NewType(this);
 277
 278                 if(autocvar_g_buffs_random_location || (this.spawnflags & 64))
 279                         buff_Respawn(this);
 280         }
 281
 282         if(this.buff_activetime)
 283         if(!game_stopped)
 284         if((round_handler_IsActive() && round_handler_IsRoundStarted()) || time >= game_starttime)
 285         {
 286                 this.buff_activetime = max(0, this.buff_activetime - frametime);
 287
 288                 if(!this.buff_activetime)
 289                 {
 290                         this.buff_active = true;
 291                         sound(this, CH_TRIGGER, SND_STRENGTH_RESPAWN, VOL_BASE, ATTN_NORM);
 292                         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 293                 }
 294         }
 295
 296         if(this.buff_active)
 297         {
 298                 if(this.team_forced && !this.buff_waypoint)
 299                         buff_Waypoint_Spawn(this);
 300
 301                 if(this.lifetime && time >= this.lifetime)
 302                         buff_Respawn(this);
 303         }
 304
 305         this.nextthink = time;
 306         //this.angles_y = time * 110.1;
 307 }
 308
 309 void buff_Waypoint_Reset(entity this)
 310 {
 311         WaypointSprite_Kill(this.buff_waypoint);
 312
 313         if(this.buff_activetime) { buff_Waypoint_Spawn(this); }
 314 }
 315
 316 void buff_Reset(entity this)
 317 {
 318         if(autocvar_g_buffs_randomize && (!teamplay || autocvar_g_buffs_randomize_teamplay))
 319                 buff_NewType(this);
 320         this.owner = NULL;
 321         buff_SetCooldown(this, autocvar_g_buffs_cooldown_activate);
 322         buff_Waypoint_Reset(this);
 323         this.buff_activetime_updated = false;
 324
 325         if(autocvar_g_buffs_random_location || (this.spawnflags & 64))
 326                 buff_Respawn(this);
 327 }
 328
 329 bool buff_Customize(entity this, entity client)
 330 {
 331         entity player = WaypointSprite_getviewentity(client);
 332         if(!this.buff_active || (this.team_forced && player.team != this.team_forced))
 333         {
 334                 this.alpha = 0.3;
 335                 if(this.effects & EF_FULLBRIGHT) { this.effects &= ~(EF_FULLBRIGHT); }
 336                 this.pflags = 0;
 337         }
 338         else
 339         {
 340                 this.alpha = 1;
 341                 if(!(this.effects & EF_FULLBRIGHT)) { this.effects |= EF_FULLBRIGHT; }
 342                 this.light_lev = 220 + 36 * sin(time);
 343                 this.pflags = PFLAGS_FULLDYNAMIC;
 344         }
 345         return true;
 346 }
 347
 348 void buff_Delete(entity this)
 349 {
 350         WaypointSprite_Kill(this.buff_waypoint);
 351         delete_fn(this);
 352 }
 353
 354 void buff_Init(entity this)
 355 {
 356         if(!cvar("g_buffs")) { delete(this); return; }
 357
 358         entity buff = buff_FirstFromFlags(STAT(BUFFS, this));
 359
 360         if(!STAT(BUFFS, this) || !buff_Available(buff))
 361                 buff_NewType(this);
 362
 363         this.classname = "item_buff";
 364         this.solid = SOLID_TRIGGER;
 365         this.flags = FL_ITEM;
 366         this.bot_pickup = true;
 367         this.bot_pickupevalfunc = generic_pickupevalfunc;
 368         this.bot_pickupbasevalue = 1000;
 369         IL_PUSH(g_items, this);
 370         setthink(this, buff_Think);
 371         settouch(this, buff_Touch);
 372         this.reset = buff_Reset;
 373         this.nextthink = time + 0.1;
 374         this.gravity = 1;
 375         set_movetype(this, MOVETYPE_TOSS);
 376         this.scale = 1;
 377         this.skin = buff.m_skin;
 378         this.effects = EF_FULLBRIGHT | EF_STARDUST | EF_NOSHADOW;
 379         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 380         setcefc(this, buff_Customize);
 381         //this.gravity = 100;
 382         this.color = buff.m_color;
 383         this.glowmod = buff_GlowColor(this);
 384         buff_SetCooldown(this, autocvar_g_buffs_cooldown_activate + max(0, game_starttime - time));
 385         this.buff_active = !this.buff_activetime;
 386         this.pflags = PFLAGS_FULLDYNAMIC;
 387         this.dtor = buff_Delete;
 388
 389         if(this.spawnflags & 1)
 390                 this.noalign = true;
 391
 392         if(this.noalign)
 393                 set_movetype(this, MOVETYPE_NONE); // reset by random location
 394
 395         setmodel(this, MDL_BUFF);
 396         setsize(this, BUFF_MIN, BUFF_MAX);
 397
 398         if(cvar("g_buffs_random_location") || (this.spawnflags & 64))
 399                 buff_Respawn(this);
 400 }
 401
 402 void buff_Init_Compat(entity ent, entity replacement)
 403 {
 404         if (teamplay)
 405         {
 406                 if (ent.spawnflags & 2)
 407                         ent.team_forced = NUM_TEAM_1;
 408                 else if (ent.spawnflags & 4)
 409                         ent.team_forced = NUM_TEAM_2;
 410         }
 411
 412         STAT(BUFFS, ent) = replacement.m_itemid;
 413
 414         buff_Init(ent);
 415 }
 416
 417 void buff_SpawnReplacement(entity ent, entity old)
 418 {
 419         setorigin(ent, old.origin);
 420         ent.angles = old.angles;
 421         ent.noalign = Item_ShouldKeepPosition(old);
 422
 423         buff_Init(ent);
 424 }
 425
 426 void buff_Vengeance_DelayedDamage(entity this)
 427 {
 428         if(this.enemy)
 429                 Damage(this.enemy, this.owner, this.owner, this.dmg, DEATH_BUFF.m_id, DMG_NOWEP, this.enemy.origin, '0 0 0');
 430
 431         delete(this);
 432         return;
 433 }
 434
 435 float buff_Inferno_CalculateTime(float damg, float offset_x, float offset_y, float intersect_x, float intersect_y, float base)
 436 {
 437         return offset_y + (intersect_y - offset_y) * logn(((damg - offset_x) * ((base - 1) / intersect_x)) + 1, base);
 438 }
 439
 440 // mutator hooks
 441 MUTATOR_HOOKFUNCTION(buffs, Damage_Calculate)
 442 {
 443         entity frag_attacker = M_ARGV(1, entity);
 444         entity frag_target = M_ARGV(2, entity);
 445         float frag_deathtype = M_ARGV(3, float);
 446         float frag_damage = M_ARGV(4, float);
 447         vector frag_force = M_ARGV(6, vector);
 448
 449         if(frag_deathtype == DEATH_BUFF.m_id) { return; }
 450
 451         if(STAT(BUFFS, frag_target) & BUFF_RESISTANCE.m_itemid)
 452         {
 453                 float reduced = frag_damage * autocvar_g_buffs_resistance_blockpercent;
 454                 frag_damage = bound(0, frag_damage - reduced, frag_damage);
 455         }
 456
 457         if(STAT(BUFFS, frag_target) & BUFF_SPEED.m_itemid)
 458         if(frag_target != frag_attacker)
 459                 frag_damage *= autocvar_g_buffs_speed_damage_take;
 460
 461         if(STAT(BUFFS, frag_target) & BUFF_MEDIC.m_itemid)
 462         if((GetResource(frag_target, RES_HEALTH) - frag_damage) <= 0)
 463         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 464         if(frag_attacker)
 465         if(random() <= autocvar_g_buffs_medic_survive_chance)
 466                 frag_damage = max(5, GetResource(frag_target, RES_HEALTH) - autocvar_g_buffs_medic_survive_health);
 467
 468         if(STAT(BUFFS, frag_target) & BUFF_JUMP.m_itemid)
 469         if(frag_deathtype == DEATH_FALL.m_id)
 470                 frag_damage = 0;
 471
 472         if(STAT(BUFFS, frag_target) & BUFF_VENGEANCE.m_itemid)
 473         if(frag_attacker)
 474         if(frag_attacker != frag_target)
 475         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 476         {
 477                 entity dmgent = new_pure(dmgent);
 478
 479                 dmgent.dmg = frag_damage * autocvar_g_buffs_vengeance_damage_multiplier;
 480                 dmgent.enemy = frag_attacker;
 481                 dmgent.owner = frag_target;
 482                 setthink(dmgent, buff_Vengeance_DelayedDamage);
 483                 dmgent.nextthink = time + 0.1;
 484         }
 485
 486         if(STAT(BUFFS, frag_target) & BUFF_BASH.m_itemid)
 487         if(frag_attacker != frag_target)
 488                 frag_force = '0 0 0';
 489
 490         if(STAT(BUFFS, frag_attacker) & BUFF_BASH.m_itemid)
 491         if(frag_force)
 492         {
 493                 if(frag_attacker == frag_target)
 494                         frag_force *= autocvar_g_buffs_bash_force_self;
 495                 else
 496                         frag_force *= autocvar_g_buffs_bash_force;
 497         }
 498
 499         if(STAT(BUFFS, frag_attacker) & BUFF_DISABILITY.m_itemid)
 500         if(frag_target != frag_attacker)
 501                 frag_target.buff_disability_time = time + autocvar_g_buffs_disability_slowtime;
 502
 503         if(STAT(BUFFS, frag_target) & BUFF_INFERNO.m_itemid)
 504         {
 505                 if(frag_deathtype == DEATH_FIRE.m_id)
 506                         frag_damage = 0;
 507                 if(frag_deathtype == DEATH_LAVA.m_id)
 508                         frag_damage *= 0.5; // TODO: cvarize?
 509         }
 510
 511         if(STAT(BUFFS, frag_attacker) & BUFF_LUCK.m_itemid)
 512         if(frag_attacker != frag_target)
 513         if(autocvar_g_buffs_luck_damagemultiplier > 0)
 514         if(random() <= autocvar_g_buffs_luck_chance)
 515                 frag_damage *= autocvar_g_buffs_luck_damagemultiplier;
 516
 517         if(STAT(BUFFS, frag_attacker) & BUFF_INFERNO.m_itemid)
 518         if(frag_target != frag_attacker) {
 519                 float btime = buff_Inferno_CalculateTime(
 520                         frag_damage,
 521                         0,
 522                         autocvar_g_buffs_inferno_burntime_min_time,
 523                         autocvar_g_buffs_inferno_burntime_target_damage,
 524                         autocvar_g_buffs_inferno_burntime_target_time,
 525                         autocvar_g_buffs_inferno_burntime_factor
 526                 );
 527                 Fire_AddDamage(frag_target, frag_attacker, (frag_damage * autocvar_g_buffs_inferno_damagemultiplier), btime, DEATH_BUFF.m_id);
 528         }
 529
 530         M_ARGV(4, float) = frag_damage;
 531         M_ARGV(6, vector) = frag_force;
 532 }
 533
 534 MUTATOR_HOOKFUNCTION(buffs, PlayerDamage_SplitHealthArmor)
 535 {
 536         entity frag_attacker = M_ARGV(1, entity);
 537         entity frag_target = M_ARGV(2, entity);
 538         if(!(STAT(BUFFS, frag_attacker) & BUFF_VAMPIRE.m_itemid))
 539                 return;
 540         float health_take = bound(0, M_ARGV(4, float), GetResource(frag_target, RES_HEALTH));
 541
 542         if(time >= frag_target.spawnshieldtime &&
 543                 frag_target != frag_attacker &&
 544                 IS_PLAYER(frag_attacker) &&
 545                 !IS_DEAD(frag_target) && !STAT(FROZEN, frag_target))
 546         {
 547                 GiveResource(frag_attacker, RES_HEALTH,
 548                         autocvar_g_buffs_vampire_damage_steal * health_take);
 549         }
 550 }
 551
 552 MUTATOR_HOOKFUNCTION(buffs, PlayerSpawn)
 553 {
 554         entity player = M_ARGV(0, entity);
 555
 556         buffs_BuffModel_Remove(player);
 557         player.oldbuffs = 0;
 558         // reset timers here to prevent them continuing after re-spawn
 559         player.buff_disability_time = 0;
 560         player.buff_disability_effect_time = 0;
 561 }
 562
 563 MUTATOR_HOOKFUNCTION(buffs, PlayerPhysics_UpdateStats)
 564 {
 565         entity player = M_ARGV(0, entity);
 566         // these automatically reset, no need to worry
 567
 568         if(STAT(BUFFS, player) & BUFF_SPEED.m_itemid)
 569                 STAT(MOVEVARS_HIGHSPEED, player) *= autocvar_g_buffs_speed_speed;
 570
 571         if(time < player.buff_disability_time)
 572                 STAT(MOVEVARS_HIGHSPEED, player) *= autocvar_g_buffs_disability_speed;
 573 }
 574
 575 MUTATOR_HOOKFUNCTION(buffs, PlayerPhysics)
 576 {
 577         entity player = M_ARGV(0, entity);
 578         // these automatically reset, no need to worry
 579
 580         if(STAT(BUFFS, player) & BUFF_JUMP.m_itemid)
 581                 STAT(MOVEVARS_JUMPVELOCITY, player) = autocvar_g_buffs_jump_height;
 582 }
 583
 584 MUTATOR_HOOKFUNCTION(buffs, MonsterMove)
 585 {
 586         entity mon = M_ARGV(0, entity);
 587
 588         if(time < mon.buff_disability_time)
 589         {
 590                 M_ARGV(1, float) *= autocvar_g_buffs_disability_speed; // run speed
 591                 M_ARGV(2, float) *= autocvar_g_buffs_disability_speed; // walk speed
 592         }
 593 }
 594
 595 MUTATOR_HOOKFUNCTION(buffs, PlayerDies)
 596 {
 597         entity frag_target = M_ARGV(2, entity);
 598
 599         if(STAT(BUFFS, frag_target))
 600         {
 601                 int buffid = buff_FirstFromFlags(STAT(BUFFS, frag_target)).m_id;
 602                 if(!IS_INDEPENDENT_PLAYER(frag_target))
 603                         Send_Notification(NOTIF_ALL_EXCEPT, frag_target, MSG_INFO, INFO_ITEM_BUFF_LOST, frag_target.netname, buffid);
 604                 STAT(BUFFS, frag_target) = 0;
 605                 STAT(BUFF_TIME, frag_target) = 0;
 606
 607                 buffs_BuffModel_Remove(frag_target);
 608         }
 609 }
 610
 611 MUTATOR_HOOKFUNCTION(buffs, PlayerUseKey, CBC_ORDER_FIRST)
 612 {
 613         if(MUTATOR_RETURNVALUE || game_stopped || !autocvar_g_buffs_drop) return;
 614
 615         entity player = M_ARGV(0, entity);
 616
 617         if(STAT(BUFFS, player))
 618         {
 619                 int buffid = buff_FirstFromFlags(STAT(BUFFS, player)).m_id;
 620                 Send_Notification(NOTIF_ONE, player, MSG_MULTI, ITEM_BUFF_DROP, buffid);
 621                 if(!IS_INDEPENDENT_PLAYER(player))
 622                         Send_Notification(NOTIF_ALL_EXCEPT, player, MSG_INFO, INFO_ITEM_BUFF_LOST, player.netname, buffid);
 623
 624                 STAT(BUFFS, player) = 0;
 625                 STAT(BUFF_TIME, player) = 0;
 626                 PS(player).buff_shield = time + max(0, autocvar_g_buffs_pickup_delay);
 627                 sound(player, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 628                 return true;
 629         }
 630 }
 631
 632 MUTATOR_HOOKFUNCTION(buffs, ForbidThrowCurrentWeapon)
 633 {
 634         if(MUTATOR_RETURNVALUE || game_stopped) return;
 635         entity player = M_ARGV(0, entity);
 636
 637         if(STAT(BUFFS, player) & BUFF_SWAPPER.m_itemid)
 638         {
 639                 float best_distance = autocvar_g_buffs_swapper_range;
 640                 entity closest = NULL;
 641                 FOREACH_CLIENT(IS_PLAYER(it), {
 642                         if(!IS_DEAD(it) && !STAT(FROZEN, it) && !it.vehicle)
 643                         if(DIFF_TEAM(it, player))
 644                         {
 645                                 float test = vlen2(player.origin - it.origin);
 646                                 if(test <= best_distance * best_distance)
 647                                 {
 648                                         best_distance = sqrt(test);
 649                                         closest = it;
 650                                 }
 651                         }
 652                 });
 653
 654                 if(closest)
 655                 {
 656                         vector my_org, my_vel, my_ang, their_org, their_vel, their_ang;
 657
 658                         my_org = player.origin;
 659                         my_vel = player.velocity;
 660                         my_ang = player.angles;
 661                         their_org = closest.origin;
 662                         their_vel = closest.velocity;
 663                         their_ang = closest.angles;
 664
 665                         Drop_Special_Items(closest);
 666
 667                         MUTATOR_CALLHOOK(PortalTeleport, player); // initiate flag dropper
 668
 669                         setorigin(player, their_org);
 670                         setorigin(closest, my_org);
 671
 672                         closest.velocity = my_vel;
 673                         closest.angles = my_ang;
 674                         if (IS_BOT_CLIENT(closest))
 675                         {
 676                                 closest.v_angle = closest.angles;
 677                                 bot_aim_reset(closest);
 678                         }
 679                         closest.fixangle = true;
 680                         closest.oldorigin = my_org;
 681                         closest.oldvelocity = my_vel;
 682                         player.velocity = their_vel;
 683                         player.angles = their_ang;
 684                         if (IS_BOT_CLIENT(player))
 685                         {
 686                                 player.v_angle = player.angles;
 687                                 bot_aim_reset(player);
 688                         }
 689                         player.fixangle = true;
 690                         player.oldorigin = their_org;
 691                         player.oldvelocity = their_vel;
 692
 693                         // set pusher so player gets the kill if they fall into void
 694                         closest.pusher = player;
 695                         closest.pushltime = time + autocvar_g_maxpushtime;
 696                         closest.istypefrag = PHYS_INPUT_BUTTON_CHAT(closest);
 697
 698                         Send_Effect(EFFECT_ELECTRO_COMBO, their_org, '0 0 0', 1);
 699                         Send_Effect(EFFECT_ELECTRO_COMBO, my_org, '0 0 0', 1);
 700
 701                         sound(player, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NORM);
 702                         sound(closest, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NORM);
 703
 704                         // TODO: add a counter to handle how many times one can teleport, and a delay to prevent spam
 705                         STAT(BUFFS, player) = 0;
 706                         return true;
 707                 }
 708         }
 709 }
 710
 711 bool buffs_RemovePlayer(entity player)
 712 {
 713         buffs_BuffModel_Remove(player);
 714
 715         // also reset timers here to prevent them continuing after spectating
 716         player.buff_disability_time = 0;
 717         player.buff_disability_effect_time = 0;
 718
 719         return false;
 720 }
 721 MUTATOR_HOOKFUNCTION(buffs, MakePlayerObserver) { entity player = M_ARGV(0, entity); return buffs_RemovePlayer(player); }
 722 MUTATOR_HOOKFUNCTION(buffs, ClientDisconnect) { entity player = M_ARGV(0, entity); return buffs_RemovePlayer(player); }
 723
 724 MUTATOR_HOOKFUNCTION(buffs, CustomizeWaypoint)
 725 {
 726         entity wp = M_ARGV(0, entity);
 727         entity player = M_ARGV(1, entity);
 728
 729         entity e = WaypointSprite_getviewentity(player);
 730
 731         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
 732         // but only apply this to real players, not to spectators
 733         if((wp.owner.flags & FL_CLIENT) && (STAT(BUFFS, wp.owner) & BUFF_INVISIBLE.m_itemid) && (e == player))
 734         if(DIFF_TEAM(wp.owner, e))
 735                 return true;
 736 }
 737
 738 MUTATOR_HOOKFUNCTION(buffs, FilterItem)
 739 {
 740         if(autocvar_g_buffs < 0)
 741                 return false; // no auto replacing of entities in this mode
 742
 743         entity item = M_ARGV(0, entity);
 744
 745         if(autocvar_g_buffs_replace_powerups)
 746         {
 747                 switch(item.classname)
 748                 {
 749                         case "item_strength":
 750                         case "item_shield":
 751                         {
 752                                 entity e = spawn();
 753                                 buff_SpawnReplacement(e, item);
 754                                 return true;
 755                         }
 756                 }
 757         }
 758
 759         return false;
 760 }
 761
 762 MUTATOR_HOOKFUNCTION(buffs, WeaponRateFactor)
 763 {
 764         entity player = M_ARGV(1, entity);
 765
 766         if(STAT(BUFFS, player) & BUFF_SPEED.m_itemid)
 767                 M_ARGV(0, float) *= autocvar_g_buffs_speed_rate;
 768
 769         if(time < player.buff_disability_time)
 770                 M_ARGV(0, float) *= autocvar_g_buffs_disability_rate;
 771 }
 772
 773 MUTATOR_HOOKFUNCTION(buffs, WeaponSpeedFactor)
 774 {
 775         entity player = M_ARGV(1, entity);
 776
 777         if(STAT(BUFFS, player) & BUFF_SPEED.m_itemid)
 778                 M_ARGV(0, float) *= autocvar_g_buffs_speed_weaponspeed;
 779
 780         if(time < player.buff_disability_time)
 781                 M_ARGV(0, float) *= autocvar_g_buffs_disability_weaponspeed;
 782 }
 783
 784 .bool buff_flight_crouchheld;
 785
 786 MUTATOR_HOOKFUNCTION(buffs, PlayerPreThink)
 787 {
 788         entity player = M_ARGV(0, entity);
 789
 790         if(game_stopped || IS_DEAD(player) || frametime || !IS_PLAYER(player)) return;
 791
 792         if(STAT(BUFFS, player) & BUFF_FLIGHT.m_itemid)
 793         {
 794                 if(!PHYS_INPUT_BUTTON_CROUCH(player))
 795                         player.buff_flight_crouchheld = false;
 796                 else if(!player.buff_flight_crouchheld)
 797                 {
 798                         player.buff_flight_crouchheld = true;
 799                         player.gravity *= -1;
 800                 }
 801         }
 802
 803         if(time < player.buff_disability_time)
 804         if(time >= player.buff_disability_effect_time)
 805         {
 806                 Send_Effect(EFFECT_SMOKING, player.origin + ((player.mins + player.maxs) * 0.5), '0 0 0', 1);
 807                 player.buff_disability_effect_time = time + 0.5;
 808         }
 809
 810         // handle buff lost status
 811         // 1: notify everyone else
 812         // 2: notify carrier as well
 813         int buff_lost = 0;
 814
 815         if(STAT(BUFF_TIME, player) && STAT(BUFFS, player))
 816         if(time >= STAT(BUFF_TIME, player))
 817         {
 818                 STAT(BUFF_TIME, player) = 0;
 819                 buff_lost = 2;
 820         }
 821
 822         if(STAT(FROZEN, player)) { buff_lost = 1; }
 823
 824         if(buff_lost)
 825         {
 826                 if(STAT(BUFFS, player))
 827                 {
 828                         int buffid = buff_FirstFromFlags(STAT(BUFFS, player)).m_id;
 829                         if(buff_lost == 2)
 830                         {
 831                                 Send_Notification(NOTIF_ONE, player, MSG_MULTI, ITEM_BUFF_DROP, buffid); // TODO: special timeout message?
 832                                 sound(player, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 833                         }
 834                         else if(!IS_INDEPENDENT_PLAYER(player))
 835                                 Send_Notification(NOTIF_ALL_EXCEPT, player, MSG_INFO, INFO_ITEM_BUFF_LOST, player.netname, buffid);
 836                         STAT(BUFFS, player) = 0;
 837                         PS(player).buff_shield = time + max(0, autocvar_g_buffs_pickup_delay); // always put in a delay, even if small
 838                 }
 839         }
 840
 841         if(STAT(BUFFS, player) & BUFF_MAGNET.m_itemid)
 842         {
 843                 vector pickup_size;
 844                 IL_EACH(g_items, it.itemdef,
 845                 {
 846                         if(STAT(BUFFS, it))
 847                                 pickup_size = '1 1 1' * autocvar_g_buffs_magnet_range_buff;
 848                         else
 849                                 pickup_size = '1 1 1' * autocvar_g_buffs_magnet_range_item;
 850
 851                         if(boxesoverlap(player.absmin - pickup_size, player.absmax + pickup_size, it.absmin, it.absmax))
 852                         {
 853                                 if(gettouch(it))
 854                                         gettouch(it)(it, player);
 855                         }
 856                 });
 857         }
 858
 859         if(STAT(BUFFS, player) & BUFF_AMMO.m_itemid)
 860         {
 861                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 862                 {
 863                         .entity weaponentity = weaponentities[slot];
 864                         if(player.(weaponentity).clip_size)
 865                                 player.(weaponentity).clip_load = player.(weaponentity).(weapon_load[player.(weaponentity).m_switchweapon.m_id]) = player.(weaponentity).clip_size;
 866                 }
 867         }
 868
 869         if((STAT(BUFFS, player) & BUFF_INVISIBLE.m_itemid) && (player.oldbuffs & BUFF_INVISIBLE.m_itemid))
 870                 player.alpha = ((autocvar_g_buffs_invisible_alpha) ? autocvar_g_buffs_invisible_alpha : -1); // powerups reset alpha, so we must enforce this (TODO)
 871
 872 #define BUFF_ONADD(b) if ( (STAT(BUFFS, player) & (b).m_itemid) && !(player.oldbuffs & (b).m_itemid))
 873 #define BUFF_ONREM(b) if (!(STAT(BUFFS, player) & (b).m_itemid) &&  (player.oldbuffs & (b).m_itemid))
 874
 875         if(STAT(BUFFS, player) != player.oldbuffs)
 876         {
 877                 entity buff = buff_FirstFromFlags(STAT(BUFFS, player));
 878                 float bufftime = buff != BUFF_Null ? buff.m_time(buff) : 0;
 879                 if(STAT(BUFF_TIME, player) <= time) // if the player still has a buff countdown, don't reset it!
 880                         STAT(BUFF_TIME, player) = (bufftime) ? time + bufftime : 0;
 881
 882                 BUFF_ONADD(BUFF_AMMO)
 883                 {
 884                         player.buff_ammo_prev_infitems = (player.items & IT_UNLIMITED_AMMO);
 885                         player.items |= IT_UNLIMITED_AMMO;
 886
 887                         if(STAT(BUFFS, player) & BUFF_AMMO.m_itemid)
 888                         {
 889                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 890                                 {
 891                                         .entity weaponentity = weaponentities[slot];
 892                                         if(player.(weaponentity).clip_load)
 893                                                 player.(weaponentity).buff_ammo_prev_clipload = player.(weaponentity).clip_load;
 894                                         if(player.(weaponentity).clip_size)
 895                                                 player.(weaponentity).clip_load = player.(weaponentity).(weapon_load[player.(weaponentity).m_switchweapon.m_id]) = player.(weaponentity).clip_size;
 896                                 }
 897                         }
 898                 }
 899
 900                 BUFF_ONREM(BUFF_AMMO)
 901                 {
 902                         if(player.buff_ammo_prev_infitems)
 903                                 player.items |= IT_UNLIMITED_AMMO;
 904                         else
 905                                 player.items &= ~IT_UNLIMITED_AMMO;
 906
 907                         if(STAT(BUFFS, player) & BUFF_AMMO.m_itemid)
 908                         {
 909                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 910                                 {
 911                                         .entity weaponentity = weaponentities[slot];
 912                                         if(player.(weaponentity).buff_ammo_prev_clipload)
 913                                                 player.(weaponentity).clip_load = player.(weaponentity).buff_ammo_prev_clipload;
 914                                 }
 915                         }
 916                 }
 917
 918                 BUFF_ONADD(BUFF_INVISIBLE)
 919                 {
 920                         if(time < STAT(STRENGTH_FINISHED, player) && MUTATOR_IS_ENABLED(mutator_instagib))
 921                                 player.buff_invisible_prev_alpha = default_player_alpha; // we don't want to save the powerup's alpha, as player may lose the powerup while holding the buff
 922                         else
 923                                 player.buff_invisible_prev_alpha = player.alpha;
 924                         player.alpha = autocvar_g_buffs_invisible_alpha;
 925                 }
 926
 927                 BUFF_ONREM(BUFF_INVISIBLE)
 928                 {
 929                         if(time < STAT(STRENGTH_FINISHED, player) && MUTATOR_IS_ENABLED(mutator_instagib))
 930                                 player.alpha = autocvar_g_instagib_invis_alpha;
 931                         else
 932                                 player.alpha = player.buff_invisible_prev_alpha;
 933                 }
 934
 935                 BUFF_ONADD(BUFF_FLIGHT)
 936                 {
 937                         player.buff_flight_oldgravity = player.gravity;
 938                         if(!player.gravity)
 939                                 player.gravity = 1;
 940                 }
 941
 942                 BUFF_ONREM(BUFF_FLIGHT)
 943                         player.gravity = ((player.trigger_gravity_check) ? player.trigger_gravity_check.enemy.gravity : player.buff_flight_oldgravity);
 944
 945                 player.oldbuffs = STAT(BUFFS, player);
 946                 if(STAT(BUFFS, player))
 947                 {
 948                         if(!player.buff_model)
 949                                 buffs_BuffModel_Spawn(player);
 950
 951                         player.buff_model.color = buff.m_color;
 952                         player.buff_model.glowmod = buff_GlowColor(player.buff_model);
 953                         player.buff_model.skin = buff.m_skin;
 954
 955                         player.effects |= EF_NOSHADOW;
 956                 }
 957                 else
 958                 {
 959                         buffs_BuffModel_Remove(player);
 960
 961                         player.effects &= ~(EF_NOSHADOW);
 962                 }
 963         }
 964
 965         if(player.buff_model)
 966         {
 967                 player.buff_model.effects = player.effects;
 968                 player.buff_model.effects |= EF_LOWPRECISION;
 969                 player.buff_model.effects = player.buff_model.effects & EFMASK_CHEAP; // eat performance
 970
 971                 player.buff_model.alpha = player.alpha;
 972         }
 973
 974 #undef BUFF_ONADD
 975 #undef BUFF_ONREM
 976 }
 977
 978 MUTATOR_HOOKFUNCTION(buffs, SpectateCopy)
 979 {
 980         entity spectatee = M_ARGV(0, entity);
 981         entity client = M_ARGV(1, entity);
 982
 983         STAT(BUFFS, client) = STAT(BUFFS, spectatee);
 984         STAT(BUFF_TIME, client) = STAT(BUFF_TIME, spectatee);
 985 }
 986
 987 MUTATOR_HOOKFUNCTION(buffs, PlayerRegen)
 988 {
 989         entity player = M_ARGV(0, entity);
 990
 991         if(STAT(BUFFS, player) & BUFF_MEDIC.m_itemid)
 992         {
 993                 M_ARGV(2, float) = autocvar_g_buffs_medic_rot; // rot_mod
 994                 M_ARGV(4, float) = M_ARGV(1, float) = autocvar_g_buffs_medic_max; // limit_mod = max_mod
 995                 M_ARGV(2, float) = autocvar_g_buffs_medic_regen; // regen_mod
 996         }
 997
 998         if(STAT(BUFFS, player) & BUFF_SPEED.m_itemid)
 999                 M_ARGV(2, float) = autocvar_g_buffs_speed_regen; // regen_mod
1000 }
1001
1002 REPLICATE(cvar_cl_buffs_autoreplace, bool, "cl_buffs_autoreplace");
1003
1004 MUTATOR_HOOKFUNCTION(buffs, BuildMutatorsString)
1005 {
1006         if(autocvar_g_buffs > 0) // only report as a mutator if they're enabled
1007                 M_ARGV(0, string) = strcat(M_ARGV(0, string), ":Buffs");
1008 }
1009
1010 MUTATOR_HOOKFUNCTION(buffs, BuildMutatorsPrettyString)
1011 {
1012         if(autocvar_g_buffs > 0)
1013                 M_ARGV(0, string) = strcat(M_ARGV(0, string), ", Buffs");
1014 }
1015
1016 void buffs_DelayedInit(entity this)
1017 {
1018         if(autocvar_g_buffs_spawn_count > 0)
1019         if(find(NULL, classname, "item_buff") == NULL)
1020         {
1021                 float i;
1022                 for(i = 0; i < autocvar_g_buffs_spawn_count; ++i)
1023                 {
1024                         entity e = spawn();
1025                         e.spawnflags |= 64; // always randomize
1026                         e.velocity = randomvec() * 250; // this gets reset anyway if random location works
1027                         buff_Init(e);
1028                 }
1029         }
1030 }
1031
1032 void buffs_Initialize()
1033 {
1034         // if buffs are above 0, allow random spawning
1035         if(autocvar_g_buffs > 0 && autocvar_g_buffs_spawn_count > 0)
1036                 InitializeEntity(NULL, buffs_DelayedInit, INITPRIO_FINDTARGET);
1037 }