qcsrc/common/monsters/sv_monsters.qc

   1 // =========================
   2 //  SVQC Monster Properties
   3 // =========================
   4
   5
   6 void monster_item_spawn()
   7 {
   8         if(self.monster_loot)
   9                 self.monster_loot();
  10
  11         self.gravity = 1;
  12         self.velocity = randomvec() * 175 + '0 0 325';
  13         self.classname = "droppedweapon"; // hax
  14         self.wait = time + 0.7;
  15
  16         SUB_SetFade(self, time + autocvar_g_monsters_drop_time, 1);
  17 }
  18
  19 void monster_dropitem()
  20 {
  21         if(!self.candrop || !self.monster_loot)
  22                 return;
  23
  24         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  25         entity e = spawn();
  26
  27         setorigin(e, org);
  28
  29         e.monster_loot = self.monster_loot;
  30
  31         other = e;
  32         MUTATOR_CALLHOOK(MonsterDropItem);
  33         e = other;
  34
  35         if(e)
  36         {
  37                 e.think = monster_item_spawn;
  38                 e.nextthink = time + 0.3;
  39         }
  40 }
  41
  42 float monster_isvalidtarget (entity targ, entity ent)
  43 {
  44         if(!targ || !ent)
  45                 return FALSE; // someone doesn't exist
  46
  47         if(targ == ent)
  48                 return FALSE; // don't attack ourselves
  49
  50         traceline(ent.origin, targ.origin, MOVE_NORMAL, ent);
  51
  52         if(trace_ent != targ)
  53                 return FALSE;
  54
  55         if(targ.vehicle_flags & VHF_ISVEHICLE)
  56         if not((get_monsterinfo(ent.monsterid)).spawnflags & MON_FLAG_RANGED)
  57                 return FALSE; // melee attacks are useless against vehicles
  58
  59         if(time < game_starttime)
  60                 return FALSE; // monsters do nothing before the match has started
  61
  62         if(vlen(targ.origin - ent.origin) >= ent.target_range)
  63                 return FALSE; // enemy is too far away
  64
  65         if(targ.takedamage == DAMAGE_NO)
  66                 return FALSE; // enemy can't be damaged
  67
  68         if(targ.items & IT_INVISIBILITY)
  69                 return FALSE; // enemy is invisible
  70
  71         if(substring(targ.classname, 0, 10) == "onslaught_")
  72                 return FALSE; // don't attack onslaught targets
  73
  74         if(IS_SPEC(targ) || IS_OBSERVER(targ))
  75                 return FALSE; // enemy is a spectator
  76
  77         if not(targ.vehicle_flags & VHF_ISVEHICLE)
  78         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
  79                 return FALSE; // enemy/self is dead
  80
  81         if(ent.monster_owner == targ)
  82                 return FALSE; // don't attack our master
  83
  84         if(targ.monster_owner == ent)
  85                 return FALSE; // don't attack our pet
  86
  87         if not(targ.vehicle_flags & VHF_ISVEHICLE)
  88         if(targ.flags & FL_NOTARGET)
  89                 return FALSE; // enemy can't be targeted
  90
  91         if not(autocvar_g_monsters_typefrag)
  92         if(targ.BUTTON_CHAT)
  93                 return FALSE; // no typefragging!
  94
  95         if(SAME_TEAM(targ, ent))
  96                 return FALSE; // enemy is on our team
  97
  98         if (targ.frozen == 1 || (targ.frozen == 2 && ent.monsterid != MON_SPIDER))
  99                 return FALSE; // ignore frozen
 100
 101         if(autocvar_g_monsters_target_infront || ent.spawnflags & MONSTERFLAG_INFRONT)
 102         if(ent.enemy != targ)
 103         {
 104                 float dot;
 105
 106                 makevectors (ent.angles);
 107                 dot = normalize (targ.origin - ent.origin) * v_forward;
 108
 109                 if(dot <= 0.3)
 110                         return FALSE;
 111         }
 112
 113         return TRUE;
 114 }
 115
 116 entity FindTarget (entity ent)
 117 {
 118         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 119
 120         entity head, closest_target = world;
 121         head = findradius(ent.origin, ent.target_range);
 122
 123         while(head) // find the closest acceptable target to pass to
 124         {
 125                 if(head.monster_attack)
 126                 if(monster_isvalidtarget(head, ent))
 127                 {
 128                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
 129                         vector head_center = CENTER_OR_VIEWOFS(head);
 130                         vector ent_center = CENTER_OR_VIEWOFS(ent);
 131
 132                         //if(ctf_CheckPassDirection(head_center, ent_center, ent.v_angle, head.WarpZone_findradius_nearest))
 133                         if(closest_target)
 134                         {
 135                                 vector closest_target_center = CENTER_OR_VIEWOFS(closest_target);
 136                                 if(vlen(ent_center - head_center) < vlen(ent_center - closest_target_center))
 137                                         { closest_target = head; }
 138                         }
 139                         else { closest_target = head; }
 140                 }
 141
 142                 head = head.chain;
 143         }
 144
 145         return closest_target;
 146 }
 147
 148 void MonsterTouch ()
 149 {
 150         if(other == world)
 151                 return;
 152
 153         if(self.enemy != other)
 154         if not(other.flags & FL_MONSTER)
 155         if(monster_isvalidtarget(other, self))
 156                 self.enemy = other;
 157 }
 158
 159 string get_monster_model_datafilename(string m, float sk, string fil)
 160 {
 161         if(m)
 162                 m = strcat(m, "_");
 163         else
 164                 m = "models/monsters/*_";
 165         if(sk >= 0)
 166                 m = strcat(m, ftos(sk));
 167         else
 168                 m = strcat(m, "*");
 169         return strcat(m, ".", fil);
 170 }
 171
 172 void PrecacheMonsterSounds(string f)
 173 {
 174         float fh;
 175         string s;
 176         fh = fopen(f, FILE_READ);
 177         if(fh < 0)
 178                 return;
 179         while((s = fgets(fh)))
 180         {
 181                 if(tokenize_console(s) != 3)
 182                 {
 183                         dprint("Invalid sound info line: ", s, "\n");
 184                         continue;
 185                 }
 186                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
 187         }
 188         fclose(fh);
 189 }
 190
 191 void precache_monstersounds()
 192 {
 193         string m = (get_monsterinfo(self.monsterid)).model;
 194         float globhandle, n, i;
 195         string f;
 196
 197         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
 198         if (globhandle < 0)
 199                 return;
 200         n = search_getsize(globhandle);
 201         for (i = 0; i < n; ++i)
 202         {
 203                 //print(search_getfilename(globhandle, i), "\n");
 204                 f = search_getfilename(globhandle, i);
 205                 PrecacheMonsterSounds(f);
 206         }
 207         search_end(globhandle);
 208 }
 209
 210 void ClearMonsterSounds()
 211 {
 212 #define _MSOUND(m) if(self.monstersound_##m) { strunzone(self.monstersound_##m); self.monstersound_##m = string_null; }
 213         ALLMONSTERSOUNDS
 214 #undef _MSOUND
 215 }
 216
 217 .string GetMonsterSoundSampleField(string type)
 218 {
 219         GetMonsterSoundSampleField_notFound = 0;
 220         switch(type)
 221         {
 222 #define _MSOUND(m) case #m: return monstersound_##m;
 223                 ALLMONSTERSOUNDS
 224 #undef _MSOUND
 225         }
 226         GetMonsterSoundSampleField_notFound = 1;
 227         return string_null;
 228 }
 229
 230 float LoadMonsterSounds(string f, float first)
 231 {
 232         float fh;
 233         string s;
 234         var .string field;
 235         fh = fopen(f, FILE_READ);
 236         if(fh < 0)
 237         {
 238                 dprint("Monster sound file not found: ", f, "\n");
 239                 return 0;
 240         }
 241         while((s = fgets(fh)))
 242         {
 243                 if(tokenize_console(s) != 3)
 244                         continue;
 245                 field = GetMonsterSoundSampleField(argv(0));
 246                 if(GetMonsterSoundSampleField_notFound)
 247                         continue;
 248                 if(self.field)
 249                         strunzone(self.field);
 250                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 251         }
 252         fclose(fh);
 253         return 1;
 254 }
 255
 256 .float skin_for_monstersound;
 257 void UpdateMonsterSounds()
 258 {
 259         entity mon = get_monsterinfo(self.monsterid);
 260
 261         if(self.skin == self.skin_for_monstersound)
 262                 return;
 263         self.skin_for_monstersound = self.skin;
 264         ClearMonsterSounds();
 265         //LoadMonsterSounds("sound/monsters/default.sounds", 1);
 266         if(!autocvar_g_debug_defaultsounds)
 267         if(!LoadMonsterSounds(get_monster_model_datafilename(mon.model, self.skin, "sounds"), 0))
 268                 LoadMonsterSounds(get_monster_model_datafilename(mon.model, 0, "sounds"), 0);
 269 }
 270
 271 void MonsterSound(.string samplefield, float sound_delay, float delaytoo, float chan)
 272 {
 273         if(delaytoo && time < self.msound_delay)
 274                 return; // too early
 275         GlobalSound(self.samplefield, chan, VOICETYPE_PLAYERSOUND);
 276
 277         self.msound_delay = time + sound_delay;
 278 }
 279
 280 void monster_makevectors(entity e)
 281 {
 282         vector v;
 283
 284         v = e.origin + (e.mins + e.maxs) * 0.5;
 285         self.v_angle = vectoangles(v - (self.origin + self.view_ofs));
 286         self.v_angle_x = -self.v_angle_x;
 287
 288         makevectors(self.v_angle);
 289 }
 290
 291 float monster_melee(entity targ, float damg, float anim, float er, float anim_finished, float deathtype, float dostop)
 292 {
 293         float rdmg = damg * random();
 294
 295         if (self.health <= 0)
 296                 return FALSE; // attacking while dead?!
 297
 298         if(dostop)
 299         {
 300                 self.velocity_x = 0;
 301                 self.velocity_y = 0;
 302                 self.state = MONSTER_STATE_ATTACK_MELEE;
 303         }
 304
 305         self.frame = anim;
 306
 307         if(anim_finished != 0)
 308                 self.attack_finished_single = time + anim_finished;
 309
 310         monster_makevectors(targ);
 311
 312         traceline(self.origin + self.view_ofs, self.origin + v_forward * er, 0, self);
 313
 314         if(trace_ent.takedamage)
 315                 Damage(trace_ent, self, self, rdmg * monster_skill, deathtype, trace_ent.origin, normalize(trace_ent.origin - self.origin));
 316
 317         return TRUE;
 318 }
 319
 320 void Monster_CheckMinibossFlag ()
 321 {
 322         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 323                 return;
 324
 325         float chance = random() * 100;
 326
 327         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 328         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 329         {
 330                 self.health += autocvar_g_monsters_miniboss_healthboost;
 331                 self.effects |= EF_RED;
 332                 if not(self.weapon)
 333                         self.weapon = WEP_NEX;
 334         }
 335 }
 336
 337 float Monster_CanRespawn(entity ent)
 338 {
 339         other = ent;
 340         if(MUTATOR_CALLHOOK(MonsterRespawn))
 341                 return TRUE; // enabled by a mutator
 342
 343         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 344                 return FALSE;
 345
 346         if not(autocvar_g_monsters_respawn)
 347                 return FALSE;
 348
 349         return TRUE;
 350 }
 351
 352 void Monster_Fade ()
 353 {
 354         if(Monster_CanRespawn(self))
 355         {
 356                 self.monster_respawned = TRUE;
 357                 self.think = self.monster_spawnfunc;
 358                 self.nextthink = time + self.respawntime;
 359                 self.ltime = 0;
 360                 self.deadflag = DEAD_RESPAWNING;
 361                 if(self.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
 362                 {
 363                         self.pos1 = self.origin;
 364                         self.pos2 = self.angles;
 365                 }
 366                 self.event_damage = func_null;
 367                 self.takedamage = DAMAGE_NO;
 368                 setorigin(self, self.pos1);
 369                 self.angles = self.pos2;
 370                 self.health = self.max_health;
 371                 setmodel(self, "null");
 372         }
 373         else
 374         {
 375                 if(IS_CLIENT(self.realowner))
 376                 if not(self.monster_respawned)
 377                         self.realowner.monstercount -= 1;
 378
 379                 SUB_SetFade(self, time + 3, 1);
 380         }
 381 }
 382
 383 float Monster_CanJump (vector vel)
 384 {
 385         if(self.state)
 386                 return FALSE; // already attacking
 387         if not(self.flags & FL_ONGROUND)
 388                 return FALSE; // not on the ground
 389         if(self.health <= 0)
 390                 return FALSE; // called when dead?
 391         if(time < self.attack_finished_single)
 392                 return FALSE; // still attacking
 393
 394         vector old = self.velocity;
 395
 396         self.velocity = vel;
 397         tracetoss(self, self);
 398         self.velocity = old;
 399         if (trace_ent != self.enemy)
 400                 return FALSE;
 401
 402         return TRUE;
 403 }
 404
 405 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 406 {
 407         if(!Monster_CanJump(vel))
 408                 return FALSE;
 409
 410         self.frame = anm;
 411         self.state = MONSTER_STATE_ATTACK_LEAP;
 412         self.touch = touchfunc;
 413         self.origin_z += 1;
 414         self.velocity = vel;
 415         self.flags &= ~FL_ONGROUND;
 416
 417         self.attack_finished_single = time + anim_finished;
 418
 419         return TRUE;
 420 }
 421
 422 void monster_checkattack(entity e, entity targ)
 423 {
 424         if(e == world)
 425                 return;
 426         if(targ == world)
 427                 return;
 428
 429         if not(e.monster_attackfunc)
 430                 return;
 431
 432         if(time < e.attack_finished_single)
 433                 return;
 434
 435         if(vlen(targ.origin - e.origin) <= e.attack_range)
 436         if(e.monster_attackfunc(MONSTER_ATTACK_MELEE))
 437         {
 438                 MonsterSound(monstersound_melee, 0, FALSE, CH_VOICE);
 439                 return;
 440         }
 441
 442         if(vlen(targ.origin - e.origin) > e.attack_range)
 443         if(e.monster_attackfunc(MONSTER_ATTACK_RANGED))
 444         {
 445                 MonsterSound(monstersound_ranged, 0, FALSE, CH_VOICE);
 446                 return;
 447         }
 448 }
 449
 450 void monster_use ()
 451 {
 452         if not(self.enemy)
 453         if(self.health > 0)
 454         if(monster_isvalidtarget(activator, self))
 455                 self.enemy = activator;
 456 }
 457
 458 .float last_trace;
 459 .float last_enemycheck; // for checking enemy
 460 vector monster_pickmovetarget(entity targ)
 461 {
 462         // enemy is always preferred target
 463         if(self.enemy)
 464         {
 465                 makevectors(self.angles);
 466                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 467                 self.last_trace = time + 1.2;
 468                 return self.enemy.origin;
 469         }
 470
 471         switch(self.monster_moveflags)
 472         {
 473                 case MONSTER_MOVE_OWNER:
 474                 {
 475                         self.monster_movestate = MONSTER_MOVE_OWNER;
 476                         self.last_trace = time + 0.3;
 477                         return (self.monster_owner) ? self.monster_owner.origin : self.origin;
 478                 }
 479                 case MONSTER_MOVE_SPAWNLOC:
 480                 {
 481                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 482                         self.last_trace = time + 2;
 483                         return self.pos1;
 484                 }
 485                 case MONSTER_MOVE_NOMOVE:
 486                 {
 487                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 488                         self.last_trace = time + 2;
 489                         return self.origin;
 490                 }
 491                 default:
 492                 case MONSTER_MOVE_WANDER:
 493                 {
 494                         vector pos;
 495                         self.monster_movestate = MONSTER_MOVE_WANDER;
 496                         self.last_trace = time + 2;
 497
 498                         self.angles_y = rint(random() * 500);
 499                         makevectors(self.angles);
 500                         pos = self.origin + v_forward * 600;
 501
 502                         if(self.flags & FL_FLY || self.flags & FL_SWIM)
 503                         if(self.spawnflags & MONSTERFLAG_FLY_VERTICAL)
 504                         {
 505                                 pos_z = random() * 200;
 506                                 if(random() >= 0.5)
 507                                         pos_z *= -1;
 508                         }
 509
 510                         if(targ)
 511                         {
 512                                 self.last_trace = time + 0.5;
 513                                 pos = targ.origin;
 514                         }
 515
 516                         return pos;
 517                 }
 518         }
 519 }
 520
 521 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 522 {
 523         fixedmakevectors(self.angles);
 524
 525         if(self.target2)
 526                 self.goalentity = find(world, targetname, self.target2);
 527
 528         entity targ;
 529
 530         if(self.frozen)
 531         {
 532                 self.revive_progress = bound(0, self.revive_progress + self.ticrate * self.revive_speed, 1);
 533                 self.health = max(1, self.max_health * self.revive_progress);
 534
 535                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 536
 537                 movelib_beak_simple(stopspeed);
 538
 539                 self.frame = manim_idle;
 540
 541                 self.enemy = world;
 542                 self.nextthink = time + self.ticrate;
 543
 544                 if(self.revive_progress >= 1)
 545                         Unfreeze(self); // wait for next think before attacking
 546
 547                 return; // no moving while frozen
 548         }
 549
 550         if(self.flags & FL_SWIM)
 551         {
 552                 if(self.waterlevel < WATERLEVEL_WETFEET)
 553                 {
 554                         if(time >= self.last_trace)
 555                         {
 556                                 self.fish_wasdrowning = TRUE;
 557                                 self.last_trace = time + 0.4;
 558
 559                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 560                                 self.angles = '90 90 0';
 561                                 if(random() < 0.5)
 562                                 {
 563                                         self.velocity_y += random() * 50;
 564                                         self.velocity_x -= random() * 50;
 565                                 }
 566                                 else
 567                                 {
 568                                         self.velocity_y -= random() * 50;
 569                                         self.velocity_x += random() * 50;
 570                                 }
 571                                 self.velocity_z += random() * 150;
 572                         }
 573
 574
 575                         self.movetype = MOVETYPE_BOUNCE;
 576                         //self.velocity_z = -200;
 577
 578                         return;
 579                 }
 580                 else if(self.fish_wasdrowning)
 581                 {
 582                         self.fish_wasdrowning = FALSE;
 583                         self.angles_x = 0;
 584                         self.movetype = MOVETYPE_WALK;
 585                 }
 586         }
 587
 588         targ = self.goalentity;
 589
 590         monster_target = targ;
 591         monster_speed_run = runspeed;
 592         monster_speed_walk = walkspeed;
 593
 594         if(MUTATOR_CALLHOOK(MonsterMove) || gameover || (round_handler_IsActive() && !round_handler_IsRoundStarted()) || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < self.spawn_time)
 595         {
 596                 runspeed = walkspeed = 0;
 597                 if(time >= self.spawn_time)
 598                         self.frame = manim_idle;
 599                 movelib_beak_simple(stopspeed);
 600                 return;
 601         }
 602
 603         targ = monster_target;
 604         runspeed = monster_speed_run;
 605         walkspeed = monster_speed_walk;
 606
 607         if(teamplay)
 608         if(autocvar_g_monsters_teams)
 609         if(DIFF_TEAM(self.monster_owner, self))
 610                 self.monster_owner = world;
 611
 612         if(self.enemy && self.enemy.health < 1)
 613                 self.enemy = world; // enough!
 614
 615         if(time >= self.last_enemycheck)
 616         {
 617                 if not(monster_isvalidtarget(self.enemy, self))
 618                         self.enemy = world;
 619
 620                 if not(self.enemy)
 621                 {
 622                         self.enemy = FindTarget(self);
 623                         if(self.enemy)
 624                                 MonsterSound(monstersound_sight, 0, FALSE, CH_VOICE);
 625                 }
 626
 627                 self.last_enemycheck = time + 0.5;
 628         }
 629
 630         if(self.state == MONSTER_STATE_ATTACK_MELEE && time >= self.attack_finished_single)
 631                 self.state = 0;
 632
 633         if(self.state != MONSTER_STATE_ATTACK_MELEE) // don't move if set
 634         if(time >= self.last_trace || self.enemy) // update enemy instantly
 635                 self.moveto = monster_pickmovetarget(targ);
 636
 637         if not(self.enemy)
 638                 MonsterSound(monstersound_idle, 5, TRUE, CH_VOICE);
 639
 640         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 641                 self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 642
 643         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 644         {
 645                 self.state = 0;
 646                 self.touch = MonsterTouch;
 647         }
 648
 649         //self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 650
 651         float turny = 0;
 652         vector real_angle = vectoangles(self.steerto) - self.angles;
 653
 654         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 655                 turny = 20;
 656
 657         if(self.flags & FL_SWIM)
 658                 turny = vlen(self.angles - self.moveto);
 659
 660         if(turny)
 661         {
 662                 turny = bound(turny * -1, shortangle_f(real_angle_y, self.angles_y), turny);
 663                 self.angles_y += turny;
 664         }
 665
 666         if(self.state == MONSTER_STATE_ATTACK_MELEE)
 667                 self.moveto = self.origin;
 668
 669         if(self.enemy && self.enemy.vehicle)
 670                 runspeed = 0;
 671
 672         if(((self.flags & FL_FLY) || (self.flags & FL_SWIM)) && self.spawnflags & MONSTERFLAG_FLY_VERTICAL)
 673                 v_forward = normalize(self.moveto - self.origin);
 674         else
 675                 self.moveto_z = self.origin_z;
 676
 677         if(vlen(self.origin - self.moveto) > 64)
 678         {
 679                 if(self.flags & FL_FLY || self.flags & FL_SWIM)
 680                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 681                 else
 682                         movelib_move(v_forward, ((self.enemy) ? runspeed : walkspeed), 0, 200, 0.6);
 683
 684                 if(time > self.pain_finished)
 685                 if(time > self.attack_finished_single)
 686                 if(vlen(self.velocity) > 10)
 687                         self.frame = ((self.enemy) ? manim_run : manim_walk);
 688                 else
 689                         self.frame = manim_idle;
 690         }
 691         else
 692         {
 693                 entity e = find(world, targetname, self.target2);
 694                 if(e.target2)
 695                         self.target2 = e.target2;
 696                 else if(e.target)
 697                         self.target2 = e.target;
 698
 699                 movelib_beak_simple(stopspeed);
 700                 if(time > self.attack_finished_single)
 701                 if(time > self.pain_finished)
 702                 if (vlen(self.velocity) <= 30)
 703                         self.frame = manim_idle;
 704         }
 705
 706         monster_checkattack(self, self.enemy);
 707 }
 708
 709 void monster_dead_think()
 710 {
 711         self.think = monster_dead_think;
 712         self.nextthink = time + self.ticrate;
 713
 714         self.deadflag = DEAD_DEAD;
 715
 716         if(self.ltime != 0)
 717         if(time >= self.ltime)
 718         {
 719                 Monster_Fade();
 720                 return;
 721         }
 722
 723         CSQCMODEL_AUTOUPDATE();
 724 }
 725
 726 void monsters_setstatus()
 727 {
 728         self.stat_monsters_total = monsters_total;
 729         self.stat_monsters_killed = monsters_killed;
 730 }
 731
 732 void Monster_Appear()
 733 {
 734         self.enemy = activator;
 735         self.spawnflags &= ~MONSTERFLAG_APPEAR;
 736         self.monster_spawnfunc();
 737 }
 738
 739 float Monster_CheckAppearFlags(entity ent)
 740 {
 741         if not(ent.spawnflags & MONSTERFLAG_APPEAR)
 742                 return FALSE;
 743
 744         ent.think = func_null;
 745         ent.nextthink = 0;
 746         ent.use = Monster_Appear;
 747         ent.flags = FL_MONSTER; // set so this monster can get butchered
 748
 749         return TRUE;
 750 }
 751
 752 void monsters_reset()
 753 {
 754         setorigin(self, self.pos1);
 755         self.angles = self.pos2;
 756
 757         Unfreeze(self); // remove any icy remains
 758
 759         self.health = self.max_health;
 760         self.velocity = '0 0 0';
 761         self.enemy = world;
 762         self.goalentity = world;
 763         self.attack_finished_single = 0;
 764         self.moveto = self.origin;
 765 }
 766
 767 void monsters_corpse_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 768 {
 769         self.health -= damage;
 770
 771         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 772
 773         if(self.health <= -100) // 100 health until gone?
 774         {
 775                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 776
 777                 if(IS_CLIENT(self.realowner))
 778                 if not(self.monster_respawned)
 779                         self.realowner.monstercount -= 1;
 780
 781                 self.think = SUB_Remove;
 782                 self.nextthink = time + 0.1;
 783         }
 784 }
 785
 786 void monster_die(entity attacker)
 787 {
 788         self.think = monster_dead_think;
 789         self.nextthink = self.ticrate;
 790         self.ltime = time + 5;
 791
 792         Unfreeze(self); // remove any icy remains
 793         self.health = 0; // reset by Unfreeze
 794
 795         monster_dropitem();
 796
 797         MonsterSound(monstersound_death, 0, FALSE, CH_VOICE);
 798
 799         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned)
 800                 monsters_killed += 1;
 801
 802         if(IS_PLAYER(attacker))
 803         if( autocvar_g_monsters_score_spawned ||
 804                         ( !(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned) )
 805                 PlayerScore_Add(attacker, SP_SCORE, +autocvar_g_monsters_score_kill);
 806
 807
 808         if(self.candrop && self.weapon)
 809                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
 810
 811         self.event_damage       = monsters_corpse_damage;
 812         self.solid                      = SOLID_CORPSE;
 813         self.takedamage         = DAMAGE_AIM;
 814         self.enemy                      = world;
 815         self.movetype           = MOVETYPE_TOSS;
 816         self.moveto                     = self.origin;
 817         self.touch                      = MonsterTouch; // reset incase monster was pouncing
 818         self.reset                      = func_null;
 819         self.state                      = 0;
 820         self.attack_finished_single = 0;
 821
 822         if not(self.flags & FL_FLY)
 823                 self.velocity = '0 0 0';
 824
 825         // number of monsters spawned with mobspawn command
 826         totalspawned -= 1;
 827
 828         MON_ACTION(self.monsterid, MR_DEATH);
 829 }
 830
 831 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 832 {
 833         if(self.frozen && deathtype != DEATH_KILL)
 834                 return;
 835
 836         if(time < self.pain_finished && deathtype != DEATH_KILL)
 837                 return;
 838
 839         if(time < self.spawnshieldtime && deathtype != DEATH_KILL)
 840                 return;
 841
 842         vector v;
 843         float take, save;
 844
 845         v = healtharmor_applydamage(self.armorvalue, self.m_armor_blockpercent, deathtype, damage);
 846         take = v_x;
 847         save = v_y;
 848
 849         self.health -= take;
 850
 851         WaypointSprite_UpdateHealth(self.sprite, self.health);
 852
 853         self.dmg_time = time;
 854
 855         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 856                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 857
 858         self.velocity += force * self.damageforcescale;
 859
 860         if(deathtype != DEATH_DROWN)
 861         {
 862                 Violence_GibSplash_At(hitloc, force, 2, bound(0, take, 200) / 16, self, attacker);
 863                 if (take > 50)
 864                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 865                 if (take > 100)
 866                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 867         }
 868
 869         if(self.health <= 0)
 870         {
 871                 if(deathtype == DEATH_KILL)
 872                         self.candrop = FALSE; // killed by mobkill command
 873
 874                 // TODO: fix this?
 875                 activator = attacker;
 876                 other = self.enemy;
 877                 SUB_UseTargets();
 878                 self.target2 = self.oldtarget2; // reset to original target on death, incase we respawn
 879
 880                 monster_die(attacker);
 881
 882                 WaypointSprite_Kill(self.sprite);
 883
 884                 frag_attacker = attacker;
 885                 frag_target = self;
 886                 MUTATOR_CALLHOOK(MonsterDies);
 887
 888                 if(self.health <= -100 || deathtype == DEATH_KILL) // check if we're already gibbed
 889                 {
 890                         Violence_GibSplash(self, 1, 0.5, attacker);
 891
 892                         if(IS_CLIENT(self.realowner))
 893                         if not(self.monster_respawned)
 894                                 self.realowner.monstercount -= 1;
 895
 896                         self.think = SUB_Remove;
 897                         self.nextthink = time + 0.1;
 898                 }
 899         }
 900 }
 901
 902 void monster_think()
 903 {
 904         self.think = monster_think;
 905         self.nextthink = self.ticrate;
 906
 907         if(self.ltime)
 908         if(time >= self.ltime)
 909         {
 910                 Damage(self, self, self, self.health + self.max_health, DEATH_KILL, self.origin, self.origin);
 911                 return;
 912         }
 913
 914         MON_ACTION(self.monsterid, MR_THINK);
 915
 916         CSQCMODEL_AUTOUPDATE();
 917 }
 918
 919 void monster_spawn()
 920 {
 921         MON_ACTION(self.monsterid, MR_SETUP);
 922
 923         if not(self.monster_respawned)
 924                 Monster_CheckMinibossFlag();
 925
 926         self.max_health = self.health;
 927         self.pain_finished = self.nextthink;
 928
 929         if(IS_PLAYER(self.monster_owner))
 930                 self.effects |= EF_DIMLIGHT;
 931
 932         if not(self.monster_respawned)
 933         if not(self.skin)
 934                 self.skin = rint(random() * 4);
 935
 936         if not(self.attack_range)
 937                 self.attack_range = autocvar_g_monsters_attack_range;
 938
 939         precache_monstersounds();
 940         UpdateMonsterSounds();
 941
 942         if(teamplay)
 943                 self.monster_attack = TRUE; // we can have monster enemies in team games
 944
 945         MonsterSound(monstersound_spawn, 0, FALSE, CH_VOICE);
 946
 947         WaypointSprite_Spawn(M_NAME(self.monsterid), 0, 1024, self, '0 0 1' * (self.maxs_z + 15), world, self.team, self, sprite, TRUE, RADARICON_DANGER, ((self.team) ? Team_ColorRGB(self.team) : '1 0 0'));
 948         WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 949         WaypointSprite_UpdateHealth(self.sprite, self.health);
 950
 951         self.think = monster_think;
 952         self.nextthink = time + self.ticrate;
 953
 954         MUTATOR_CALLHOOK(MonsterSpawn);
 955 }
 956
 957 float monster_initialize(float mon_id, float nodrop)
 958 {
 959         if not(autocvar_g_monsters)
 960                 return FALSE;
 961
 962         entity mon = get_monsterinfo(mon_id);
 963
 964         // support for quake style removing monsters based on skill
 965         if(monster_skill <= 1) if(self.spawnflags & MONSTERSKILL_NOTEASY) { return FALSE; }
 966         if(monster_skill == 2) if(self.spawnflags & MONSTERSKILL_NOTMEDIUM) { return FALSE; }
 967         if(monster_skill >= 3) if(self.spawnflags & MONSTERSKILL_NOTHARD) { return FALSE; }
 968
 969         if(self.team && !teamplay)
 970                 self.team = 0;
 971
 972         if not(self.spawnflags & MONSTERFLAG_SPAWNED) // naturally spawned monster
 973         if not(self.monster_respawned)
 974                 monsters_total += 1;
 975
 976         setmodel(self, mon.model);
 977         setsize(self, mon.mins, mon.maxs);
 978         self.flags                              = FL_MONSTER;
 979         self.takedamage                 = DAMAGE_AIM;
 980         self.bot_attack                 = TRUE;
 981         self.iscreature                 = TRUE;
 982         self.teleportable               = TRUE;
 983         self.damagedbycontents  = TRUE;
 984         self.monsterid                  = mon_id;
 985         self.damageforcescale   = 0;
 986         self.event_damage               = monsters_damage;
 987         self.touch                              = MonsterTouch;
 988         self.use                                = monster_use;
 989         self.solid                              = SOLID_BBOX;
 990         self.movetype                   = MOVETYPE_WALK;
 991         self.spawnshieldtime    = time + autocvar_g_monsters_spawnshieldtime;
 992         self.enemy                              = world;
 993         self.velocity                   = '0 0 0';
 994         self.moveto                             = self.origin;
 995         self.pos1                               = self.origin;
 996         self.pos2                               = self.angles;
 997         self.reset                              = monsters_reset;
 998         self.netname                    = mon.netname;
 999         self.monster_name               = M_NAME(mon_id);
1000         self.candrop                    = TRUE;
1001         self.view_ofs                   = '0 0 1' * (self.maxs_z * 0.5);
1002         self.oldtarget2                 = self.target2;
1003         self.deadflag                   = DEAD_NO;
1004         self.scale                              = 1;
1005         self.noalign                    = nodrop;
1006         self.spawn_time                 = time;
1007         self.gravity                    = 1;
1008         self.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1009
1010         if(autocvar_g_fullbrightplayers)
1011                 self.effects |= EF_FULLBRIGHT;
1012
1013         if(autocvar_g_nodepthtestplayers)
1014                 self.effects |= EF_NODEPTHTEST;
1015
1016         if(mon.spawnflags & MONSTER_TYPE_SWIM)
1017                 self.flags |= FL_SWIM;
1018
1019         if(mon.spawnflags & MONSTER_TYPE_FLY)
1020         {
1021                 self.flags |= FL_FLY;
1022                 self.movetype = MOVETYPE_FLY;
1023         }
1024
1025         if(mon.spawnflags & MONSTER_SIZE_BROKEN)
1026                 self.scale = 1.3;
1027
1028         if not(self.ticrate)
1029                 self.ticrate = autocvar_g_monsters_think_delay;
1030
1031         self.ticrate = bound(sys_frametime, self.ticrate, 60);
1032
1033         if not(self.m_armor_blockpercent)
1034                 self.m_armor_blockpercent = 0.5;
1035
1036         if not(self.target_range)
1037                 self.target_range = autocvar_g_monsters_target_range;
1038
1039         if not(self.respawntime)
1040                 self.respawntime = autocvar_g_monsters_respawn_delay;
1041
1042         if not(self.monster_moveflags)
1043                 self.monster_moveflags = MONSTER_MOVE_WANDER;
1044
1045         if not(self.noalign)
1046         {
1047                 setorigin(self, self.origin + '0 0 20');
1048                 tracebox(self.origin + '0 0 64', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
1049                 setorigin(self, trace_endpos);
1050         }
1051
1052         monster_spawn();
1053
1054         CSQCMODEL_AUTOINIT();
1055
1056         return TRUE;
1057 }