qcsrc/common/mapinfo.qc

   1 #include "mapinfo.qh"
   2 #if defined(CSQC)
   3     #include "../client/defs.qh"
   4     #include "util.qh"
   5     #include <common/weapons/_all.qh>
   6 #elif defined(MENUQC)
   7 #elif defined(SVQC)
   8     #include "util.qh"
   9     #include <common/monsters/_mod.qh>
  10 #endif
  11
  12 bool autocvar_g_mapinfo_arena_compat = true;
  13 bool autocvar_g_mapinfo_arena_generate = false;
  14
  15 #ifdef MENUQC
  16 #define WARN_COND false
  17 #else
  18 bool autocvar_g_mapinfo_ignore_warnings;
  19 #define WARN_COND (!autocvar_g_mapinfo_ignore_warnings && MapInfo_Map_bspname == mi_shortname)
  20 #endif
  21
  22 // generic string stuff
  23
  24 int _MapInfo_Cache_Active;
  25 int _MapInfo_Cache_DB_NameToIndex;
  26 int _MapInfo_Cache_Buf_IndexToMapData;
  27
  28 void MapInfo_Cache_Destroy()
  29 {
  30         if(!_MapInfo_Cache_Active)
  31                 return;
  32
  33         db_close(_MapInfo_Cache_DB_NameToIndex);
  34         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  35         _MapInfo_Cache_Active = 0;
  36 }
  37
  38 void MapInfo_Cache_Create()
  39 {
  40         MapInfo_Cache_Destroy();
  41         _MapInfo_Cache_DB_NameToIndex = db_create();
  42         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  43         _MapInfo_Cache_Active = 1;
  44 }
  45
  46 void MapInfo_Cache_Invalidate()
  47 {
  48         if(!_MapInfo_Cache_Active)
  49                 return;
  50
  51         MapInfo_Cache_Create();
  52 }
  53
  54 void MapInfo_Cache_Store()
  55 {
  56         float i;
  57         string s;
  58         if(!_MapInfo_Cache_Active)
  59                 return;
  60
  61         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  62         if(s == "")
  63         {
  64                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
  65                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
  66         }
  67         else
  68                 i = stof(s);
  69
  70         // now store all the stuff
  71         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
  72         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
  73         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_titlestring);
  74         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
  75         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
  76         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
  77         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
  78         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
  79 }
  80
  81 float MapInfo_Cache_Retrieve(string map)
  82 {
  83         float i;
  84         string s;
  85         if(!_MapInfo_Cache_Active)
  86                 return 0;
  87
  88         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
  89         if(s == "")
  90                 return 0;
  91         i = stof(s);
  92
  93         // now retrieve all the stuff
  94         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
  95         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  96         MapInfo_Map_titlestring = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  97         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  98         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  99         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
 100         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
 101         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
 102
 103         return 1;
 104 }
 105
 106 // GLOB HANDLING (for all BSP files)
 107 float _MapInfo_globopen;
 108 float _MapInfo_globcount;
 109 float _MapInfo_globhandle;
 110 string _MapInfo_GlobItem(float i)
 111 {
 112         string s;
 113         if(!_MapInfo_globopen)
 114                 return string_null;
 115         s = search_getfilename(_MapInfo_globhandle, i);
 116         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
 117 }
 118
 119 void MapInfo_Enumerate()
 120 {
 121         if(_MapInfo_globopen)
 122         {
 123                 search_end(_MapInfo_globhandle);
 124                 _MapInfo_globopen = 0;
 125         }
 126         MapInfo_Cache_Invalidate();
 127         _MapInfo_globhandle = search_begin("maps/*.bsp", true, true);
 128         if(_MapInfo_globhandle >= 0)
 129         {
 130                 _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 131                 _MapInfo_globopen = 1;
 132         }
 133         else
 134                 _MapInfo_globcount = 0;
 135 }
 136
 137 // filter the info by game type mask (updates MapInfo_count)
 138 //
 139 float _MapInfo_filtered;
 140 float _MapInfo_filtered_allocated;
 141 float MapInfo_FilterList_Lookup(float i)
 142 {
 143         return stof(bufstr_get(_MapInfo_filtered, i));
 144 }
 145
 146 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 147 {
 148         string h;
 149         h = bufstr_get(_MapInfo_filtered, i);
 150         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 151         bufstr_set(_MapInfo_filtered, j, h);
 152 }
 153
 154 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 155 {
 156         string a, b;
 157         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 158         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 159         return strcasecmp(a, b);
 160 }
 161
 162 float MapInfo_FilterGametype(Gametype pGametype, int pFeatures, int pFlagsRequired, int pFlagsForbidden, bool pAbortOnGenerate)
 163 {
 164         return _MapInfo_FilterGametype(pGametype.m_flags, pFeatures, pFlagsRequired, pFlagsForbidden, pAbortOnGenerate);
 165 }
 166 float _MapInfo_FilterGametype(int pGametype, int pFeatures, int pFlagsRequired, int pFlagsForbidden, bool pAbortOnGenerate)
 167 {
 168         float i, j;
 169         if (!_MapInfo_filtered_allocated)
 170         {
 171                 _MapInfo_filtered_allocated = 1;
 172                 _MapInfo_filtered = buf_create();
 173         }
 174         MapInfo_count = 0;
 175         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 176         {
 177                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, NULL) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 178                         if(pAbortOnGenerate)
 179                         {
 180                                 LOG_TRACE("Autogenerated a .mapinfo, doing the rest later.");
 181                                 MapInfo_progress = i / _MapInfo_globcount;
 182                                 return 0;
 183                         }
 184                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 185                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 186                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 187                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 188                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 189         }
 190         MapInfo_count = j + 1;
 191         MapInfo_ClearTemps();
 192
 193         // sometimes the glob isn't sorted nicely, so fix it here...
 194         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, NULL);
 195
 196         return 1;
 197 }
 198 void MapInfo_FilterString(string sf)
 199 {
 200         // this function further filters _MapInfo_filtered, which is prepared by MapInfo_FilterGametype by string
 201         float i, j;
 202         string title;
 203
 204         for(i = 0, j = -1; i < MapInfo_count; ++i)
 205         {
 206                 if (MapInfo_Get_ByID(i))
 207                 {
 208                         // prepare for keyword filter
 209                         if (MapInfo_Map_title && strstrofs(MapInfo_Map_title, "<TITLE>", 0) == -1)
 210                                 title = MapInfo_Map_title;
 211                         else
 212                                 title = MapInfo_Map_bspname;
 213                         // keyword filter
 214                         if((strstrofs(strtolower(title), strtolower(sf), 0)) >= 0)
 215                                 bufstr_set(_MapInfo_filtered, ++j, bufstr_get(_MapInfo_filtered, i));
 216                 }
 217         }
 218         MapInfo_count = j + 1;
 219         MapInfo_ClearTemps();
 220
 221         // sometimes the glob isn't sorted nicely, so fix it here...
 222         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, NULL);
 223 }
 224
 225 void MapInfo_Filter_Free()
 226 {
 227         if(_MapInfo_filtered_allocated)
 228         {
 229                 buf_del(_MapInfo_filtered);
 230                 _MapInfo_filtered_allocated = 0;
 231         }
 232 }
 233
 234 // load info about the i-th map into the MapInfo_Map_* globals
 235 string MapInfo_BSPName_ByID(float i)
 236 {
 237         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 238 }
 239
 240 string unquote(string s)
 241 {
 242         float l = strlen(s);
 243         for(float i = 0; i < l; ++i)
 244         {
 245                 string ch = substring(s, i, 1);
 246                 if((ch != " ") && (ch != "\""))
 247                 {
 248                         for(float j = l - i - 1; j > 0; --j)
 249                         {
 250                                 ch = substring(s, i+j, 1);
 251                                 if(ch != " ") if(ch != "\"")
 252                                         return substring(s, i, j+1);
 253                         }
 254                         return substring(s, i, 1);
 255                 }
 256         }
 257         return "";
 258 }
 259
 260 float MapInfo_Get_ByID(float i)
 261 {
 262         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, NULL))
 263                 return 1;
 264         return 0;
 265 }
 266
 267 string _MapInfo_Map_worldspawn_music;
 268
 269 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 270 {
 271         string fn;
 272         float fh;
 273         string s, k, v;
 274         vector o;
 275         float i;
 276         float inWorldspawn;
 277         float r;
 278         float diameter, spawnpoints;
 279         float spawnplaces;
 280
 281         vector mapMins, mapMaxs;
 282
 283         r = 1;
 284         fn = strcat("maps/", pFilename, ".ent");
 285         fh = fopen(fn, FILE_READ);
 286         if(fh < 0)
 287         {
 288                 r = 2;
 289                 fn = strcat("maps/", pFilename, ".bsp");
 290                 fh = fopen(fn, FILE_READ);
 291         }
 292         if(fh < 0)
 293                 return 0;
 294         LOG_INFO("Analyzing ", fn, " to generate initial mapinfo");
 295
 296         inWorldspawn = 2;
 297         MapInfo_Map_flags = 0;
 298         MapInfo_Map_supportedGametypes = 0;
 299         spawnpoints = 0;
 300         spawnplaces = 0;
 301         _MapInfo_Map_worldspawn_music = "";
 302         mapMins = '0 0 0';
 303         mapMaxs = '0 0 0';
 304
 305         if(autocvar_g_mapinfo_arena_generate)
 306         {
 307                 // try for .arena or .defi files, as they may have more accurate information
 308                 bool isdefi = false;
 309                 string arena_fn = _MapInfo_FindArenaFile(pFilename, ".arena");
 310                 int arena_fh = fopen(arena_fn, FILE_READ);
 311                 if(arena_fh < 0)
 312                 {
 313                         isdefi = true;
 314                         arena_fn = _MapInfo_FindArenaFile(pFilename, ".defi");
 315                         arena_fh = fopen(arena_fn, FILE_READ);
 316                 }
 317                 if(arena_fh >= 0)
 318                 {
 319                         _MapInfo_ParseArena(arena_fn, arena_fh, pFilename, NULL, isdefi, true);
 320                         fclose(arena_fh);
 321                 }
 322         }
 323
 324         for (;;)
 325         {
 326                 if (!((s = fgets(fh))))
 327                         break;
 328                 if(inWorldspawn == 1)
 329                         if(startsWith(s, "}"))
 330                                 inWorldspawn = 0;
 331                 k = unquote(car(s));
 332                 v = unquote(cdr(s));
 333                 if(inWorldspawn)
 334                 {
 335                         if(k == "classname" && v == "worldspawn")
 336                                 inWorldspawn = 1;
 337                         else if(k == "author")
 338                                 MapInfo_Map_author = v;
 339                         else if(k == "_description")
 340                                 MapInfo_Map_description = v;
 341                         else if(k == "music")
 342                                 _MapInfo_Map_worldspawn_music = v;
 343                         else if(k == "noise")
 344                                 _MapInfo_Map_worldspawn_music = v;
 345                         else if(k == "message")
 346                         {
 347                                 i = strstrofs(v, " by ", 0);
 348                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 349                                 {
 350                                         MapInfo_Map_title = substring(v, 0, i);
 351                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 352                                 }
 353                                 else
 354                                         MapInfo_Map_title = v;
 355                         }
 356                 }
 357                 else
 358                 {
 359                         if(k == "origin")
 360                         {
 361                                 o = stov(strcat("'", v, "'"));
 362                                 mapMins.x = min(mapMins.x, o.x);
 363                                 mapMins.y = min(mapMins.y, o.y);
 364                                 mapMins.z = min(mapMins.z, o.z);
 365                                 mapMaxs.x = max(mapMaxs.x, o.x);
 366                                 mapMaxs.y = max(mapMaxs.y, o.y);
 367                                 mapMaxs.z = max(mapMaxs.z, o.z);
 368                         }
 369                         else if(k == "race_place")
 370                         {
 371                                 if(stof(v) > 0)
 372                                         spawnplaces = 1;
 373                         }
 374                         else if(k == "classname")
 375                         {
 376                                 if(v == "info_player_team1")
 377                                         ++spawnpoints;
 378                                 else if(v == "info_player_team2")
 379                                         ++spawnpoints;
 380                                 else if(v == "info_player_start")
 381                                         ++spawnpoints;
 382                                 else if(v == "info_player_deathmatch")
 383                                         ++spawnpoints;
 384                                 else if(v == "weapon_nex")
 385                                         { }
 386                                 else if(v == "weapon_railgun")
 387                                         { }
 388                                 else if(startsWith(v, "weapon_"))
 389                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 390                                 else if(startsWith(v, "turret_"))
 391                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 392                                 else if(startsWith(v, "vehicle_"))
 393                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 394                                 else if(startsWith(v, "monster_"))
 395                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
 396                                 else if(v == "target_music" || v == "trigger_music")
 397                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
 398                                 else
 399                                         FOREACH(Gametypes, true, it.m_generate_mapinfo(it, v));
 400                         }
 401                 }
 402         }
 403         if(inWorldspawn)
 404         {
 405                 LOG_WARN(fn, " ended still in worldspawn, BUG");
 406                 return 0;
 407         }
 408         diameter = vlen(mapMaxs - mapMins);
 409
 410         int twoBaseModes = 0;
 411         FOREACH(Gametypes, it.m_isTwoBaseMode(), twoBaseModes |= it.m_flags);
 412         if(twoBaseModes && (twoBaseModes &= MapInfo_Map_supportedGametypes))
 413         {
 414                 // we have a symmetrical map, don't add the modes without bases
 415         }
 416         else
 417         {
 418                 FOREACH(Gametypes, it.m_isAlwaysSupported(it, spawnpoints, diameter), MapInfo_Map_supportedGametypes |= it.m_flags);
 419         }
 420
 421         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE.m_flags)
 422         if(!spawnplaces)
 423         {
 424                 MapInfo_Map_supportedGametypes &= ~MAPINFO_TYPE_RACE.m_flags;
 425                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS.m_flags;
 426         }
 427
 428         LOG_TRACE("-> diameter ",    ftos(diameter));
 429         LOG_TRACE(";  spawnpoints ", ftos(spawnpoints));
 430         LOG_TRACE(";  modes ",       ftos(MapInfo_Map_supportedGametypes));
 431
 432         fclose(fh);
 433
 434         return r;
 435 }
 436
 437 void _MapInfo_Map_Reset()
 438 {
 439         MapInfo_Map_title = "<TITLE>";
 440         MapInfo_Map_titlestring = "<TITLE>";
 441         MapInfo_Map_description = "<DESCRIPTION>";
 442         MapInfo_Map_author = "<AUTHOR>";
 443         MapInfo_Map_supportedGametypes = 0;
 444         MapInfo_Map_supportedFeatures = 0;
 445         MapInfo_Map_flags = 0;
 446         MapInfo_Map_clientstuff = "";
 447         MapInfo_Map_fog = "";
 448         MapInfo_Map_mins = '0 0 0';
 449         MapInfo_Map_maxs = '0 0 0';
 450 }
 451
 452 string _MapInfo_GetDefault(Gametype t)
 453 {
 454         return t.m_legacydefaults;
 455 }
 456
 457 void _MapInfo_Map_ApplyGametype(string s, Gametype pWantedType, Gametype pThisType, int load_default)
 458 {
 459         string sa;
 460         MapInfo_Map_supportedGametypes |= pThisType.m_flags;
 461         if(!(pThisType.m_flags & pWantedType.m_flags))
 462                 return;
 463
 464         if(load_default)
 465                 _MapInfo_Map_ApplyGametype(_MapInfo_GetDefault(pThisType), pWantedType, pThisType, false);
 466
 467         if(!pWantedType.frags) // these modes don't use fraglimit
 468         {
 469                 cvar_set("fraglimit", "0");
 470         }
 471         else
 472         {
 473                 sa = car(s);
 474                 if(sa != "")
 475                         cvar_set("fraglimit", sa);
 476                 s = cdr(s);
 477         }
 478
 479         sa = car(s);
 480         if(sa != "")
 481                 cvar_set("timelimit", sa);
 482         s = cdr(s);
 483
 484         if(pWantedType.m_setTeams)
 485         {
 486                 sa = car(s);
 487                 if(sa != "")
 488                         pWantedType.m_setTeams(sa);
 489                 s = cdr(s);
 490         }
 491
 492         // rc = timelimit timelimit_qualification laps laps_teamplay
 493         if(pWantedType == MAPINFO_TYPE_RACE)
 494         {
 495                 cvar_set("fraglimit", "0"); // special case!
 496
 497                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 498                 cvar_set("g_race_qualifying_timelimit", sa);
 499                 s = cdr(s);
 500
 501                 sa = car(s);
 502                 if(sa != "")
 503                         if(cvar("g_race_teams") < 2)
 504                                 cvar_set("fraglimit", sa);
 505                 s = cdr(s);
 506
 507                 sa = car(s);
 508                 if(sa != "")
 509                         if(cvar("g_race_teams") >= 2)
 510                                 cvar_set("fraglimit", sa);
 511                 s = cdr(s);
 512         }
 513
 514         if(!pWantedType.frags) // these modes don't use fraglimit
 515         {
 516                 cvar_set("leadlimit", "0");
 517         }
 518         else
 519         {
 520                 sa = car(s);
 521                 if(sa != "")
 522                         cvar_set("leadlimit", sa);
 523                 s = cdr(s);
 524         }
 525 }
 526
 527 string _MapInfo_GetDefaultEx(Gametype t)
 528 {
 529         return t ? t.model2 : "";
 530 }
 531
 532 float _MapInfo_GetTeamPlayBool(Gametype t)
 533 {
 534         return t ? t.team : false;
 535 }
 536
 537 void _MapInfo_Map_ApplyGametypeEx(string s, Gametype pWantedType, Gametype pThisType)
 538 {
 539         MapInfo_Map_supportedGametypes |= pThisType.m_flags;
 540         if (!(pThisType.m_flags & pWantedType.m_flags))
 541                 return;
 542
 543         // reset all the cvars to their defaults
 544
 545         cvar_set("timelimit", cvar_defstring("timelimit"));
 546         cvar_set("leadlimit", cvar_defstring("leadlimit"));
 547         cvar_set("fraglimit", cvar_defstring("fraglimit"));
 548         FOREACH(Gametypes, true, it.m_parse_mapinfo(string_null, string_null));
 549
 550         string fraglimit_normal = string_null;
 551         string fraglimit_teams = string_null;
 552
 553         for (s = strcat(_MapInfo_GetDefaultEx(pWantedType), " ", s); s != ""; s = cdr(s)) {
 554                 string sa = car(s);
 555                 if (sa == "") continue;
 556                 int p = strstrofs(sa, "=", 0);
 557                 if (p < 0) {
 558                         if(WARN_COND)
 559                                 LOG_WARNF("Invalid gametype setting in mapinfo for gametype %s: %s", MapInfo_Type_ToString(pWantedType), sa);
 560                         continue;
 561                 }
 562                 string k = substring(sa, 0, p);
 563                 string v = substring(sa, p + 1, -1);
 564                 bool handled = true;
 565                 switch (k) {
 566                         case "timelimit":
 567                         {
 568                                 cvar_set("timelimit", v);
 569                                 break;
 570                         }
 571                         case "leadlimit":
 572                         {
 573                                 cvar_set("leadlimit", v);
 574                                 break;
 575                         }
 576                         case "pointlimit":
 577                         case "fraglimit":
 578                         case "lives":
 579                         case "laplimit":
 580                         case "caplimit":
 581                         {
 582                                 fraglimit_normal = v;
 583                                 break;
 584                         }
 585                         case "teampointlimit":
 586                         case "teamlaplimit":
 587                         {
 588                                 fraglimit_teams = v;
 589                                 break;
 590                         }
 591                         default:
 592                         {
 593                             handled = false;
 594                             break;
 595                         }
 596                 }
 597                 FOREACH(Gametypes, true, handled |= it.m_parse_mapinfo(k, v));
 598                 if (!handled && WARN_COND)
 599             LOG_WARNF("Invalid gametype setting in mapinfo for gametype %s: %s", MapInfo_Type_ToString(pWantedType), sa);
 600         }
 601
 602         if (pWantedType == MAPINFO_TYPE_RACE && cvar("g_race_teams") >= 2)
 603         {
 604                 if(fraglimit_teams)
 605                         cvar_set("fraglimit", fraglimit_teams);
 606         }
 607         else
 608         {
 609                 if(fraglimit_normal)
 610                         cvar_set("fraglimit", fraglimit_normal);
 611         }
 612 }
 613
 614 Gametype MapInfo_Type_FromString(string gtype)
 615 {
 616         string replacement = "";
 617         bool do_warn = true;
 618         switch (gtype)
 619         {
 620                 case "nexball":   replacement = "nb"; break;
 621                 case "freezetag": replacement = "ft"; break;
 622                 case "keepaway":  replacement = "ka"; break;
 623                 case "invasion":  replacement = "inv"; break;
 624                 case "assault":   replacement = "as"; break;
 625                 case "race":      replacement = "rc"; break;
 626                 // quake 3 compat
 627                 case "ffa":       replacement = "dm"; do_warn = false; break;
 628                 case "cctf":
 629                 case "oneflag":   replacement = "ctf"; do_warn = false; break;
 630                 case "team":      replacement = "tdm"; do_warn = false; break;
 631                 case "tourney":   replacement = "duel"; do_warn = false; break;
 632         }
 633         if (replacement != "")
 634         {
 635                 if(do_warn && WARN_COND)
 636                         LOG_WARNF("MapInfo_Type_FromString (probably %s): using deprecated name '%s'. Should use '%s'.", MapInfo_Map_bspname, gtype, replacement);
 637                 gtype = replacement;
 638         }
 639         FOREACH(Gametypes, it.mdl == gtype, return it);
 640         return NULL;
 641 }
 642
 643 string MapInfo_Type_Description(Gametype t)
 644 {
 645         return t ? t.gametype_description : "";
 646 }
 647
 648 string MapInfo_Type_ToString(Gametype t)
 649 {
 650         return t ? t.mdl : "";
 651 }
 652
 653 string MapInfo_Type_ToText(Gametype t)
 654 {
 655         /* xgettext:no-c-format */
 656         return t ? t.message : _("@!#%'n Tuba Throwing");
 657 }
 658
 659 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 660 {
 661         string t;
 662         float fh, o;
 663         t = car(s); s = cdr(s);
 664
 665         // limited support of "" and comments
 666         //   remove trailing and leading " of t
 667         if(substring(t, 0, 1) == "\"")
 668         {
 669                 if(substring(t, -1, 1) == "\"")
 670                         t = substring(t, 1, -2);
 671         }
 672
 673         //   remove leading " of s
 674         if(substring(s, 0, 1) == "\"")
 675         {
 676                 s = substring(s, 1, -1);
 677         }
 678         //   remove trailing " of s, and all that follows (cvar description)
 679         o = strstrofs(s, "\"", 0);
 680         if(o >= 0)
 681                 s = substring(s, 0, o);
 682
 683         //   remove // comments
 684         o = strstrofs(s, "//", 0);
 685         if(o >= 0)
 686                 s = substring(s, 0, o);
 687
 688         //   remove trailing spaces
 689         while(substring(s, -1, 1) == " ")
 690                 s = substring(s, 0, -2);
 691
 692         if(t == "#include")
 693         {
 694                 if(recurse > 0)
 695                 {
 696                         fh = fopen(s, FILE_READ);
 697                         if(fh < 0)
 698                         {
 699                                 if(WARN_COND)
 700                                         LOG_WARN("Map ", pFilename, " references not existing config file ", s);
 701                         }
 702                         else
 703                         {
 704                                 while((s = fgets(fh)))
 705                                 {
 706                                         // catch different sorts of comments
 707                                         if(s == "")                    // empty lines
 708                                                 continue;
 709                                         if(substring(s, 0, 1) == "#")  // UNIX style
 710                                                 continue;
 711                                         if(substring(s, 0, 2) == "//") // C++ style
 712                                                 continue;
 713                                         if(substring(s, 0, 1) == "_")  // q3map style
 714                                                 continue;
 715
 716                                         if(substring(s, 0, 4) == "set ")
 717                                                 s = substring(s, 4, -1);
 718                                         if(substring(s, 0, 5) == "seta ")
 719                                                 s = substring(s, 5, -1);
 720
 721                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 722                                 }
 723                                 fclose(fh);
 724                         }
 725                 }
 726                 else if(WARN_COND)
 727                         LOG_WARN("Map ", pFilename, " uses too many levels of inclusion");
 728         }
 729         else if(t == ""
 730                 || !cvar_value_issafe(t)
 731                 || !cvar_value_issafe(s)
 732                 || matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
 733         {
 734                 if (WARN_COND)
 735                         LOG_WARN("Map ", pFilename, " contains a potentially harmful setting, ignored");
 736         }
 737         else if(matchacl(acl, t) <= 0)
 738         {
 739                 if (WARN_COND)
 740                         LOG_WARN("Map ", pFilename, " contains a denied setting, ignored");
 741         }
 742         else
 743         {
 744                 if(type == 0) // server set
 745                 {
 746                         LOG_TRACE("Applying temporary setting ", t, " := ", s);
 747                 #if 0
 748                         if(cvar("g_campaign"))
 749                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 750                         else
 751                 #endif
 752                                 cvar_settemp(t, s);
 753                 }
 754                 else
 755                 {
 756                         LOG_TRACE("Applying temporary client setting ", t, " := ", s);
 757                         MapInfo_Map_clientstuff = strcat(
 758                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 759                                         );
 760                 }
 761         }
 762 }
 763
 764 float MapInfo_isRedundant(string fn, string t)
 765 {
 766         // normalize file name
 767         fn = strreplace("_", "", fn);
 768         fn = strreplace("-", "", fn);
 769
 770         // normalize visible title
 771         t = strreplace(":", "", t);
 772         t = strreplace(" ", "", t);
 773         t = strreplace("_", "", t);
 774         t = strreplace("-", "", t);
 775         t = strreplace("'", "", t);
 776         t = strdecolorize(t);
 777
 778         // we allow the visible title to have punctuation the file name does
 779         // not, but not vice versa
 780         if(!strcasecmp(fn, t))
 781                 return true;
 782
 783         return false;
 784 }
 785
 786 bool _MapInfo_ParseArena(string arena_filename, int fh, string pFilename, Gametype pGametypeToSet, bool isdefi, bool isgenerator)
 787 {
 788         // NOTE: .arena files can hold more than 1 map's information!
 789         // to handle this, we're going to store gathered information in local variables and save it if we encounter the correct map name
 790         bool in_brackets = false; // testing a potential mapinfo section (within brackets)
 791         bool dosave = (arena_filename == strcat("scripts/", pFilename, ((isdefi) ? ".defi" : ".arena"))); // if the map is using the fallback, just accept the first found mapinfo (it's probably correct!)
 792         string stored_Map_description = "";
 793         string stored_Map_title = "";
 794         string stored_Map_author = "";
 795         int stored_supportedGametypes = 0;
 796         string t, s;
 797         for (;;)
 798         {
 799                 if (!((s = fgets(fh))))
 800                         break;
 801
 802                 // catch different sorts of comments
 803                 if(s == "")                    // empty lines
 804                         continue;
 805                 if(substring(s, 0, 1) == "#")  // UNIX style
 806                         continue;
 807                 if(substring(s, 0, 2) == "//") // C++ style
 808                         continue;
 809                 if(substring(s, 0, 1) == "_")  // q3map style
 810                         continue;
 811                 if(strstrofs(s, "{", 0) >= 0)
 812                 {
 813                         if(in_brackets)
 814                                 return false; // edge case? already in a bracketed section!
 815                         in_brackets = true;
 816                         continue;
 817                 }
 818                 else if(!in_brackets)
 819                 {
 820                         // if we're not inside a bracket, don't process map info
 821                         continue;
 822                 }
 823                 if(strstrofs(s, "}", 0) >= 0)
 824                 {
 825                         if(!in_brackets)
 826                                 return false; // no starting bracket! let the mapinfo generation system handle it
 827                         in_brackets = false;
 828                         if(dosave)
 829                         {
 830                                 MapInfo_Map_description = stored_Map_description;
 831                                 if(stored_Map_title != "")
 832                                         MapInfo_Map_title = stored_Map_title;
 833                                 MapInfo_Map_author = stored_Map_author;
 834                                 if(isgenerator)
 835                                         MapInfo_Map_supportedGametypes = stored_supportedGametypes;
 836                                 else
 837                                 {
 838                                         FOREACH(Gametypes, it.m_flags & stored_supportedGametypes,
 839                                         {
 840                                                 _MapInfo_Map_ApplyGametype ("", pGametypeToSet, it, true);
 841                                         });
 842                                 }
 843                                 return true; // no need to continue through the file, we have our map!
 844                         }
 845                         else
 846                         {
 847                                 // discard any gathered locals, we're not using the correct map!
 848                                 stored_Map_description = "";
 849                                 stored_Map_title = "";
 850                                 stored_Map_author = "";
 851                                 stored_supportedGametypes = 0;
 852                                 continue;
 853                         }
 854                 }
 855
 856                 s = strreplace("\t", " ", s);
 857
 858                 float p = strstrofs(s, "//", 0);
 859                 if(p >= 0)
 860                         s = substring(s, 0, p);
 861
 862                 // perform an initial trim to ensure the first argument is properly obtained
 863                 //   remove leading spaces
 864                 while(substring(s, 0, 1) == " ")
 865                         s = substring(s, 1, -1);
 866
 867                 t = car(s); s = cdr(s);
 868                 t = strtolower(t); // apparently some q3 maps use capitalized parameters
 869
 870                 //   remove trailing spaces
 871                 while(substring(t, -1, 1) == " ")
 872                         t = substring(t, 0, -2);
 873
 874                 //   remove trailing spaces
 875                 while(substring(s, -1, 1) == " ")
 876                         s = substring(s, 0, -2);
 877                 //   remove leading spaces
 878                 while(substring(s, 0, 1) == " ")
 879                         s = substring(s, 1, -1);
 880                 // limited support of ""
 881                 //   remove trailing and leading " of s
 882                 if(substring(s, 0, 1) == "\"")
 883                 {
 884                         if(substring(s, -1, 1) == "\"")
 885                                 s = substring(s, 1, -2);
 886                 }
 887                 if(t == "longname")
 888                         stored_Map_title = s;
 889                 else if(t == "author")
 890                         stored_Map_author = s;
 891                 else if(t == "type")
 892                 {
 893                         // if there is a valid gametype in this .arena file, include it in the menu
 894                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 895                         // type in quake 3 holds all the supported gametypes, so we must loop through all of them
 896                         FOREACH_WORD(s, true,
 897                         {
 898                                 Gametype f = MapInfo_Type_FromString(it);
 899                                 if(f)
 900                                         stored_supportedGametypes |= f.m_flags;
 901                         });
 902                 }
 903                 else if(t == "style" && isdefi)
 904                 {
 905                         // we have a defrag map on our hands, add CTS!
 906                         // TODO: styles
 907                         stored_supportedGametypes |= MAPINFO_TYPE_CTS.m_flags;
 908                 }
 909                 else if(t == "map")
 910                 {
 911                         if(strtolower(s) == strtolower(pFilename))
 912                                 dosave = true; // yay, found our map!
 913                 }
 914                 else if(t == "quote")
 915                         stored_Map_description = s;
 916                 // TODO: fraglimit
 917         }
 918
 919         // if the map wasn't found in the .arena, fall back to generated .mapinfo
 920         return false;
 921 }
 922
 923 #if defined(CSQC) || defined(MENUQC)
 924 string(string filename) whichpack = #503;
 925 #endif
 926 string _MapInfo_FindArenaFile(string pFilename, string extension)
 927 {
 928         string fallback = strcat("scripts/", pFilename, extension);
 929         if(!checkextension("DP_QC_FS_SEARCH_PACKFILE"))
 930                 return fallback;
 931         string base_pack = whichpack(strcat("maps/", pFilename, ".bsp"));
 932         if(base_pack == "") // this map isn't packaged!
 933                 return fallback;
 934
 935         int glob = search_packfile_begin(strcat("scripts/*", extension), true, true, base_pack);
 936         if(glob < 0)
 937                 return fallback;
 938         int n = search_getsize(glob);
 939         for(int j = 0; j < n; ++j)
 940         {
 941                 string file = search_getfilename(glob, j);
 942
 943                 int fh = fopen(file, FILE_READ);
 944                 if(fh < 0)
 945                         continue; // how?
 946                 for(string s; (s = fgets(fh)); )
 947                 {
 948                         int offset = strstrofs(s, "map", 0);
 949                         if(offset >= 0)
 950                         {
 951                                 if(strstrofs(strtolower(s), strcat("\"", strtolower(pFilename), "\""), offset) >= 0) // quake 3 is case insensitive
 952                                 {
 953                                         fclose(fh);
 954                                         search_end(glob);
 955                                         return file; // FOUND IT!
 956                                 }
 957                         }
 958                 }
 959                 fclose(fh);
 960         }
 961
 962         search_end(glob);
 963         return fallback; // if we get here, a valid .arena file could not be found
 964 }
 965
 966 // load info about a map by name into the MapInfo_Map_* globals
 967 float MapInfo_Get_ByName_NoFallbacks(string pFilename, int pAllowGenerate, Gametype pGametypeToSet)
 968 {
 969         string fn;
 970         string s, t;
 971         float fh;
 972         int f, i;
 973         float r, n;
 974         string acl;
 975
 976         acl = MAPINFO_SETTEMP_ACL_USER;
 977
 978         if(strstrofs(pFilename, "/", 0) >= 0)
 979         {
 980                 LOG_WARN("Invalid character in map name, ignored");
 981                 return 0;
 982         }
 983
 984         if(pGametypeToSet == NULL)
 985                 if(MapInfo_Cache_Retrieve(pFilename))
 986                         return 1;
 987
 988         r = 1;
 989
 990         MapInfo_Map_bspname = pFilename;
 991
 992         // default all generic fields so they have "good" values in case something fails
 993         fn = strcat("maps/", pFilename, ".mapinfo");
 994         fh = fopen(fn, FILE_READ);
 995         if(fh < 0)
 996         {
 997                 if(autocvar_g_mapinfo_arena_compat)
 998                 {
 999                         // try for .arena or .defi files if no .mapinfo exists
1000                         bool isdefi = false;
1001                         fn = _MapInfo_FindArenaFile(pFilename, ".arena");
1002                         fh = fopen(fn, FILE_READ);
1003                         if(fh < 0)
1004                         {
1005                                 isdefi = true;
1006                                 fn = _MapInfo_FindArenaFile(pFilename, ".defi");
1007                                 fh = fopen(fn, FILE_READ);
1008                         }
1009                         if(fh >= 0)
1010                         {
1011                                 _MapInfo_Map_Reset();
1012                                 if(_MapInfo_ParseArena(fn, fh, pFilename, pGametypeToSet, isdefi, false))
1013                                         goto mapinfo_handled; // skip generation
1014                         }
1015                 }
1016
1017                 fn = strcat("maps/autogenerated/", pFilename, ".mapinfo");
1018                 fh = fopen(fn, FILE_READ);
1019                 if(fh < 0)
1020                 {
1021                         if(!pAllowGenerate)
1022                                 return 0;
1023                         _MapInfo_Map_Reset();
1024                         r = _MapInfo_Generate(pFilename);
1025                         if(!r)
1026                                 return 0;
1027                         fh = fopen(fn, FILE_WRITE);
1028                         fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
1029                         fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
1030                         fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
1031                         if(_MapInfo_Map_worldspawn_music != "")
1032                         {
1033                                 if(
1034                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
1035                                         ||
1036                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
1037                                 )
1038                                         fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
1039                                 else
1040                                         fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
1041                         }
1042                         else
1043                         {
1044                                 n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
1045                                 s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
1046                                 for (;;)
1047                                 {
1048                                         i = floor(random() * n);
1049                                         if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
1050                                                 break;
1051                                 }
1052                                 fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
1053                         }
1054                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
1055                                 fputs(fh, "has weapons\n");
1056                         else
1057                                 fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
1058                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_TURRETS)
1059                                 fputs(fh, "has turrets\n");
1060                         else
1061                                 fputs(fh, "// uncomment this if you added turrets: has turrets\n");
1062                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_VEHICLES)
1063                                 fputs(fh, "has vehicles\n");
1064                         else
1065                                 fputs(fh, "// uncomment this if you added vehicles: has vehicles\n");
1066                         if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
1067                                 fputs(fh, "frustrating\n");
1068
1069                         FOREACH(Gametypes, MapInfo_Map_supportedGametypes & it.m_flags, {
1070                                 fputs(fh, sprintf("gametype %s // defaults: %s\n", MapInfo_Type_ToString(it), _MapInfo_GetDefaultEx(it)));
1071                         });
1072
1073                         fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
1074                         fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
1075                         fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
1076                         fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1077                         fputs(fh, "// optional: hidden\n");
1078
1079                         fclose(fh);
1080                         r = 2;
1081                         // return r;
1082                         fh = fopen(fn, FILE_READ);
1083                         if(fh < 0)
1084                                 error("... but I just wrote it!");
1085                 }
1086
1087                 if(WARN_COND)
1088                         LOG_WARN("autogenerated mapinfo file ", fn, " has been loaded; please edit that file and move it to maps/", pFilename, ".mapinfo");
1089         }
1090
1091         _MapInfo_Map_Reset();
1092         for (;;)
1093         {
1094                 if (!((s = fgets(fh))))
1095                         break;
1096
1097                 // catch different sorts of comments
1098                 if(s == "")                    // empty lines
1099                         continue;
1100                 if(substring(s, 0, 1) == "#")  // UNIX style
1101                         continue;
1102                 if(substring(s, 0, 2) == "//") // C++ style
1103                         continue;
1104                 if(substring(s, 0, 1) == "_")  // q3map style
1105                         continue;
1106
1107                 float p = strstrofs(s, "//", 0);
1108                 if(p >= 0)
1109                         s = substring(s, 0, p);
1110
1111                 t = car(s); s = cdr(s);
1112                 if(t == "title")
1113                         MapInfo_Map_title = s;
1114                 else if(t == "description")
1115                         MapInfo_Map_description = s;
1116                 else if(t == "author")
1117                         MapInfo_Map_author = s;
1118                 else if(t == "has")
1119                 {
1120                         t = car(s); // s = cdr(s);
1121                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
1122                         else if(t == "turrets") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
1123                         else if(t == "vehicles") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
1124                         else if(t == "monsters") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
1125                         else if(t == "new_toys") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
1126                         else if(WARN_COND)
1127                                 LOG_WARN("Map ", pFilename, " supports unknown feature ", t, ", ignored");
1128                 }
1129                 else if(t == "hidden")
1130                 {
1131                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
1132                 }
1133                 else if(t == "forbidden")
1134                 {
1135                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
1136                 }
1137                 else if(t == "frustrating")
1138                 {
1139                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
1140                 }
1141                 else if(t == "noautomaplist")
1142                 {
1143                         MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
1144                 }
1145                 else if(t == "gameversion_min")
1146                 {
1147                         if (cvar("gameversion") < stof(s))
1148                                 MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
1149                 }
1150                 else if(t == "type")
1151                 {
1152                         t = car(s); s = cdr(s);
1153                         Gametype f = MapInfo_Type_FromString(t);
1154                         //if(WARN_COND)
1155                                 //LOG_WARN("Map ", pFilename, " contains the legacy 'type' keyword which is deprecated and will be removed in the future. Please migrate the mapinfo file to 'gametype'.");
1156                         if(f)
1157                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, true);
1158                         else if(WARN_COND)
1159                                 LOG_DEBUG("Map ", pFilename, " supports unknown game type ", t, ", ignored");
1160                 }
1161                 else if(t == "gametype")
1162                 {
1163                         t = car(s); s = cdr(s);
1164                         Gametype f = MapInfo_Type_FromString(t);
1165                         if(f)
1166                                 _MapInfo_Map_ApplyGametypeEx (s, pGametypeToSet, f);
1167                         else if(WARN_COND)
1168                                 LOG_DEBUG("Map ", pFilename, " supports unknown game type ", t, ", ignored");
1169                 }
1170                 else if(t == "size")
1171                 {
1172                         float a, b, c, d, e;
1173                         t = car(s); s = cdr(s); a = stof(t);
1174                         t = car(s); s = cdr(s); b = stof(t);
1175                         t = car(s); s = cdr(s); c = stof(t);
1176                         t = car(s); s = cdr(s); d = stof(t);
1177                         t = car(s); s = cdr(s); e = stof(t);
1178                         if(s == "")
1179                         {
1180                                 if(WARN_COND)
1181                                         LOG_WARN("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z");
1182                         }
1183                         else
1184                         {
1185                                 t = car(s); s = cdr(s); f = stof(t);
1186                                 if(s != "")
1187                                 {
1188                                         if(WARN_COND)
1189                                                 LOG_WARN("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z");
1190                                 }
1191                                 else
1192                                 {
1193                                         if(a >= d || b >= e || c >= f)
1194                                         {
1195                                                 if(WARN_COND)
1196                                                         LOG_WARN("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs");
1197                                         }
1198                                         else
1199                                         {
1200                                                 MapInfo_Map_mins.x = a;
1201                                                 MapInfo_Map_mins.y = b;
1202                                                 MapInfo_Map_mins.z = c;
1203                                                 MapInfo_Map_maxs.x = d;
1204                                                 MapInfo_Map_maxs.y = e;
1205                                                 MapInfo_Map_maxs.z = f;
1206                                         }
1207                                 }
1208                         }
1209                 }
1210                 else if(t == "settemp_for_type")
1211                 {
1212                         t = car(s); s = cdr(s);
1213                         bool all = t == "all";
1214                         Gametype f = NULL;
1215                         if(all || (f = MapInfo_Type_FromString(t)))
1216                         {
1217                                 if((all ? MAPINFO_TYPE_ALL : f.m_flags) & pGametypeToSet.m_flags)
1218                                 {
1219                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
1220                                 }
1221                         }
1222                         else
1223                         {
1224                                 LOG_DEBUG("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored");
1225                         }
1226                 }
1227                 else if(t == "clientsettemp_for_type")
1228                 {
1229                         t = car(s); s = cdr(s);
1230                         bool all = t == "all";
1231                         Gametype f = NULL;
1232                         if(all || (f = MapInfo_Type_FromString(t)))
1233                         {
1234                                 if((all ? MAPINFO_TYPE_ALL : f.m_flags) & pGametypeToSet.m_flags)
1235                                 {
1236                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
1237                                 }
1238                         }
1239                         else
1240                         {
1241                                 LOG_DEBUG("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored");
1242                         }
1243                 }
1244                 else if(t == "fog")
1245                 {
1246                         if (!cvar_value_issafe(s))
1247                         {
1248                                 if(WARN_COND)
1249                                         LOG_WARN("Map ", pFilename, " contains a potentially harmful fog setting, ignored");
1250                         }
1251                         else
1252                                 MapInfo_Map_fog = s;
1253                 }
1254                 else if(t == "cdtrack")
1255                 {
1256                         t = car(s); s = cdr(s);
1257                         // We do this only if pGametypeToSet even though this
1258                         // content is theoretically game type independent,
1259                         // because MapInfo_Map_clientstuff contains otherwise
1260                         // game type dependent stuff. That way this value stays
1261                         // empty when not setting a game type to not set any
1262                         // false expectations.
1263                         if(pGametypeToSet)
1264                         {
1265                                 if (!cvar_value_issafe(t))
1266                                 {
1267                                         if(WARN_COND)
1268                                                 LOG_WARN("Map ", pFilename, " contains a potentially harmful cdtrack, ignored");
1269                                 }
1270                                 else
1271                                         MapInfo_Map_clientstuff = strcat(
1272                                                 MapInfo_Map_clientstuff, "cd loop \"", t, "\"\n"
1273                                         );
1274                         }
1275                 }
1276                 else if(WARN_COND)
1277                         LOG_WARN("Map ", pFilename, " provides unknown info item ", t, ", ignored");
1278         }
1279         LABEL(mapinfo_handled)
1280         fclose(fh);
1281
1282         if(MapInfo_Map_title == "<TITLE>")
1283                 MapInfo_Map_titlestring = MapInfo_Map_bspname;
1284         else if(MapInfo_isRedundant(MapInfo_Map_bspname, MapInfo_Map_title))
1285                 MapInfo_Map_titlestring = MapInfo_Map_title;
1286         else
1287                 MapInfo_Map_titlestring = sprintf("%s: %s", MapInfo_Map_bspname, MapInfo_Map_title);
1288
1289         MapInfo_Cache_Store();
1290         if(MapInfo_Map_supportedGametypes != 0)
1291                 return r;
1292         if (WARN_COND)
1293                 LOG_WARN("Map ", pFilename, " supports no game types, ignored");
1294         return 0;
1295 }
1296 int MapInfo_Get_ByName(string pFilename, float pAllowGenerate, Gametype pGametypeToSet)
1297 {
1298         int r = MapInfo_Get_ByName_NoFallbacks(pFilename, pAllowGenerate, pGametypeToSet);
1299
1300         FOREACH(Gametypes, it.m_isForcedSupported(it), _MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, it));
1301
1302         if(pGametypeToSet)
1303         {
1304                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet.m_flags))
1305                 {
1306                         error("Can't select the requested game type. This should never happen as the caller should prevent it!\n");
1307                         //_MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
1308                         //return;
1309                 }
1310         }
1311
1312         return r;
1313 }
1314
1315 float MapInfo_FindName(string s)
1316 {
1317         // if there is exactly one map of prefix s, return it
1318         // if not, return the null string
1319         // note that DP sorts glob results... so I can use a binary search
1320         float l, r, m, cmp;
1321         l = 0;
1322         r = MapInfo_count;
1323         // invariants: r is behind s, l-1 is equal or before
1324         while(l != r)
1325         {
1326                 m = floor((l + r) / 2);
1327                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
1328                 cmp = strcasecmp(MapInfo_FindName_match, s);
1329                 if(cmp == 0)
1330                         return m; // found and good
1331                 if(cmp < 0)
1332                         l = m + 1; // l-1 is before s
1333                 else
1334                         r = m; // behind s
1335         }
1336         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
1337         MapInfo_FindName_firstResult = l;
1338         // r == l, so: l is behind s, l-1 is before
1339         // SO: if there is any, l is the one with the right prefix
1340         //     and l+1 may be one too
1341         if(l == MapInfo_count)
1342         {
1343                 MapInfo_FindName_match = string_null;
1344                 MapInfo_FindName_firstResult = -1;
1345                 return -1; // no MapInfo_FindName_match, behind last item
1346         }
1347         if(!startsWithNocase(MapInfo_FindName_match, s))
1348         {
1349                 MapInfo_FindName_match = string_null;
1350                 MapInfo_FindName_firstResult = -1;
1351                 return -1; // wrong prefix
1352         }
1353         if(l == MapInfo_count - 1)
1354                 return l; // last one, nothing can follow => unique
1355         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
1356         {
1357                 MapInfo_FindName_match = string_null;
1358                 return -1; // ambigous MapInfo_FindName_match
1359         }
1360         return l;
1361 }
1362
1363 string MapInfo_FixName(string s)
1364 {
1365         MapInfo_FindName(s);
1366         return MapInfo_FindName_match;
1367 }
1368
1369 int MapInfo_CurrentFeatures()
1370 {
1371         int req = 0;
1372     // TODO: find a better way to check if weapons are required on the map
1373         if(!(cvar("g_instagib") || cvar("g_overkill") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items")
1374                 || cvar("g_race") || cvar("g_cts") || cvar("g_nexball") || cvar("g_ca") || cvar("g_freezetag") || cvar("g_lms")))
1375                 req |= MAPINFO_FEATURE_WEAPONS;
1376         return req;
1377 }
1378
1379 Gametype MapInfo_CurrentGametype()
1380 {
1381         Gametype prev = REGISTRY_GET(Gametypes, cvar("gamecfg"));
1382         FOREACH(Gametypes, cvar(it.netname) && it != prev, return it);
1383         return prev ? prev : MAPINFO_TYPE_DEATHMATCH;
1384 }
1385
1386 float _MapInfo_CheckMap(string s, bool gametype_only) // returns 0 if the map can't be played with the current settings, 1 otherwise
1387 {
1388         if(!MapInfo_Get_ByName(s, 1, NULL))
1389                 return 0;
1390         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype().m_flags) == 0)
1391                 return 0;
1392         if (gametype_only)
1393                 return 1;
1394         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1395                 return 0;
1396         return 1;
1397 }
1398
1399 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1400 {
1401         float r;
1402         r = _MapInfo_CheckMap(s, false);
1403         MapInfo_ClearTemps();
1404         return r;
1405 }
1406
1407 void MapInfo_SwitchGameType(Gametype t)
1408 {
1409         FOREACH(Gametypes, true, cvar_set(it.netname, (it == t) ? "1" : "0"));
1410 }
1411
1412 void MapInfo_LoadMap(string s, float reinit)
1413 {
1414         MapInfo_Map_supportedGametypes = 0;
1415         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1416         //if(!MapInfo_CheckMap(s))
1417         //{
1418         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1419         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH.m_flags);
1420         //}
1421
1422         LOG_INFO("Switching to map ", s);
1423
1424         cvar_settemp_restore();
1425         if(reinit)
1426                 localcmd(strcat("\nmap ", s, "\n"));
1427         else
1428                 localcmd(strcat("\nchangelevel ", s, "\n"));
1429 }
1430
1431 string MapInfo_ListAllowedMaps(Gametype type, float pRequiredFlags, float pForbiddenFlags)
1432 {
1433         string out;
1434
1435         // to make absolutely sure:
1436         MapInfo_Enumerate();
1437         MapInfo_FilterGametype(type, MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1438
1439         out = "";
1440         for(float i = 0; i < MapInfo_count; ++i)
1441                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1442         return substring(out, 1, strlen(out) - 1);
1443 }
1444
1445 string MapInfo_ListAllAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1446 {
1447         string out;
1448
1449         // to make absolutely sure:
1450         MapInfo_Enumerate();
1451         _MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, pRequiredFlags, pForbiddenFlags, 0);
1452
1453         out = "";
1454         for(float i = 0; i < MapInfo_count; ++i)
1455                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1456
1457         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1458
1459         return substring(out, 1, strlen(out) - 1);
1460 }
1461
1462 void MapInfo_LoadMapSettings_SaveGameType(Gametype t)
1463 {
1464         MapInfo_SwitchGameType(t);
1465         cvar_set("gamecfg", ftos(t.m_id));
1466         MapInfo_LoadedGametype = t;
1467 }
1468
1469 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1470 {
1471         Gametype t = MapInfo_CurrentGametype();
1472         MapInfo_LoadMapSettings_SaveGameType(t);
1473
1474         if(!_MapInfo_CheckMap(s, true)) // with underscore, it keeps temps
1475         {
1476                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1477                 {
1478                         LOG_SEVERE("can't play the selected map in the given game mode. Working with only the override settings.");
1479                         _MapInfo_Map_ApplyGametypeEx("", t, t);
1480                         return; // do not call Get_ByName!
1481                 }
1482
1483                 if(MapInfo_Map_supportedGametypes == 0)
1484                 {
1485                         LOG_SEVERE("Mapinfo system is not functional at all. Assuming deathmatch.");
1486                         MapInfo_Map_supportedGametypes = MAPINFO_TYPE_DEATHMATCH.m_flags;
1487                         MapInfo_LoadMapSettings_SaveGameType(MAPINFO_TYPE_DEATHMATCH);
1488                         _MapInfo_Map_ApplyGametypeEx("", MAPINFO_TYPE_DEATHMATCH, MAPINFO_TYPE_DEATHMATCH);
1489                         return; // do not call Get_ByName!
1490                 }
1491
1492                 int _t = 1;
1493                 while(!(MapInfo_Map_supportedGametypes & 1))
1494                 {
1495                         _t <<= 1;
1496                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes >> 1);
1497                 }
1498                 Gametype t_prev = t;
1499                 FOREACH(Gametypes, it.m_flags == _t, { t = it; break; });
1500
1501                 // t is now a supported mode!
1502                 LOG_WARNF("can't play the selected map in the given game mode (%s). Falling back to a supported mode (%s).", t_prev.mdl, t.mdl);
1503                 MapInfo_LoadMapSettings_SaveGameType(t);
1504         }
1505         if(!_MapInfo_CheckMap(s, false)) { // with underscore, it keeps temps
1506                 LOG_WARNF("the selected map lacks features required by current settings; playing anyway.");
1507         }
1508         MapInfo_Get_ByName(s, 1, t);
1509 }
1510
1511 void MapInfo_ClearTemps()
1512 {
1513         MapInfo_Map_bspname = string_null;
1514         MapInfo_Map_title = string_null;
1515         MapInfo_Map_titlestring = string_null;
1516         MapInfo_Map_description = string_null;
1517         MapInfo_Map_author = string_null;
1518         MapInfo_Map_clientstuff = string_null;
1519         MapInfo_Map_supportedGametypes = 0;
1520         MapInfo_Map_supportedFeatures = 0;
1521 }
1522
1523 void MapInfo_Shutdown()
1524 {
1525         MapInfo_ClearTemps();
1526         MapInfo_Filter_Free();
1527         MapInfo_Cache_Destroy();
1528         if(_MapInfo_globopen)
1529         {
1530                 search_end(_MapInfo_globhandle);
1531                 _MapInfo_globhandle = -1;
1532                 _MapInfo_globopen = false;
1533         }
1534 }
1535
1536 int MapInfo_ForbiddenFlags()
1537 {
1538         int f = MAPINFO_FLAG_FORBIDDEN;
1539
1540 #ifdef GAMEQC
1541         if (!cvar("g_maplist_allow_hidden"))
1542 #endif
1543                 f |= MAPINFO_FLAG_HIDDEN;
1544
1545         if (!cvar("g_maplist_allow_frustrating"))
1546                 f |= MAPINFO_FLAG_FRUSTRATING;
1547
1548         return f;
1549 }
1550
1551 int MapInfo_RequiredFlags()
1552 {
1553         int f = 0;
1554
1555         if(cvar("g_maplist_allow_frustrating") > 1)
1556                 f |= MAPINFO_FLAG_FRUSTRATING;
1557
1558         return f;
1559 }