qcsrc/common/mapinfo.qc

   1 #include "mapinfo.qh"
   2 #if defined(CSQC)
   3     #include "../client/defs.qh"
   4     #include "util.qh"
   5     #include <common/weapons/_all.qh>
   6 #elif defined(MENUQC)
   7 #elif defined(SVQC)
   8     #include "util.qh"
   9     #include <common/monsters/_mod.qh>
  10 #endif
  11
  12 #ifdef MENUQC
  13 #define WARN_COND false
  14 #else
  15 bool autocvar_g_mapinfo_ignore_warnings;
  16 #define WARN_COND (!autocvar_g_mapinfo_ignore_warnings && MapInfo_Map_bspname == mi_shortname)
  17 #endif
  18
  19 // generic string stuff
  20
  21 int _MapInfo_Cache_Active;
  22 int _MapInfo_Cache_DB_NameToIndex;
  23 int _MapInfo_Cache_Buf_IndexToMapData;
  24
  25 void MapInfo_Cache_Destroy()
  26 {
  27         if(!_MapInfo_Cache_Active)
  28                 return;
  29
  30         db_close(_MapInfo_Cache_DB_NameToIndex);
  31         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  32         _MapInfo_Cache_Active = 0;
  33 }
  34
  35 void MapInfo_Cache_Create()
  36 {
  37         MapInfo_Cache_Destroy();
  38         _MapInfo_Cache_DB_NameToIndex = db_create();
  39         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  40         _MapInfo_Cache_Active = 1;
  41 }
  42
  43 void MapInfo_Cache_Invalidate()
  44 {
  45         if(!_MapInfo_Cache_Active)
  46                 return;
  47
  48         MapInfo_Cache_Create();
  49 }
  50
  51 void MapInfo_Cache_Store()
  52 {
  53         float i;
  54         string s;
  55         if(!_MapInfo_Cache_Active)
  56                 return;
  57
  58         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  59         if(s == "")
  60         {
  61                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
  62                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
  63         }
  64         else
  65                 i = stof(s);
  66
  67         // now store all the stuff
  68         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
  69         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
  70         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_titlestring);
  71         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
  72         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
  73         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
  74         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
  75         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
  76 }
  77
  78 float MapInfo_Cache_Retrieve(string map)
  79 {
  80         float i;
  81         string s;
  82         if(!_MapInfo_Cache_Active)
  83                 return 0;
  84
  85         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
  86         if(s == "")
  87                 return 0;
  88         i = stof(s);
  89
  90         // now retrieve all the stuff
  91         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
  92         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  93         MapInfo_Map_titlestring = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  94         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  95         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  96         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  97         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  98         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  99
 100         return 1;
 101 }
 102
 103 // GLOB HANDLING (for all BSP files)
 104 float _MapInfo_globopen;
 105 float _MapInfo_globcount;
 106 float _MapInfo_globhandle;
 107 string _MapInfo_GlobItem(float i)
 108 {
 109         string s;
 110         if(!_MapInfo_globopen)
 111                 return string_null;
 112         s = search_getfilename(_MapInfo_globhandle, i);
 113         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
 114 }
 115
 116 void MapInfo_Enumerate()
 117 {
 118         if(_MapInfo_globopen)
 119         {
 120                 search_end(_MapInfo_globhandle);
 121                 _MapInfo_globopen = 0;
 122         }
 123         MapInfo_Cache_Invalidate();
 124         _MapInfo_globhandle = search_begin("maps/*.bsp", true, true);
 125         if(_MapInfo_globhandle >= 0)
 126         {
 127                 _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 128                 _MapInfo_globopen = 1;
 129         }
 130         else
 131                 _MapInfo_globcount = 0;
 132 }
 133
 134 // filter the info by game type mask (updates MapInfo_count)
 135 //
 136 float _MapInfo_filtered;
 137 float _MapInfo_filtered_allocated;
 138 float MapInfo_FilterList_Lookup(float i)
 139 {
 140         return stof(bufstr_get(_MapInfo_filtered, i));
 141 }
 142
 143 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 144 {
 145         string h;
 146         h = bufstr_get(_MapInfo_filtered, i);
 147         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 148         bufstr_set(_MapInfo_filtered, j, h);
 149 }
 150
 151 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 152 {
 153         string a, b;
 154         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 155         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 156         return strcasecmp(a, b);
 157 }
 158
 159 float MapInfo_FilterGametype(Gametype pGametype, int pFeatures, int pFlagsRequired, int pFlagsForbidden, bool pAbortOnGenerate)
 160 {
 161         return _MapInfo_FilterGametype(pGametype.m_flags, pFeatures, pFlagsRequired, pFlagsForbidden, pAbortOnGenerate);
 162 }
 163 float _MapInfo_FilterGametype(int pGametype, int pFeatures, int pFlagsRequired, int pFlagsForbidden, bool pAbortOnGenerate)
 164 {
 165         float i, j;
 166         if (!_MapInfo_filtered_allocated)
 167         {
 168                 _MapInfo_filtered_allocated = 1;
 169                 _MapInfo_filtered = buf_create();
 170         }
 171         MapInfo_count = 0;
 172         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 173         {
 174                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, NULL) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 175                         if(pAbortOnGenerate)
 176                         {
 177                                 LOG_TRACE("Autogenerated a .mapinfo, doing the rest later.");
 178                                 MapInfo_progress = i / _MapInfo_globcount;
 179                                 return 0;
 180                         }
 181                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 182                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 183                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 184                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 185                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 186         }
 187         MapInfo_count = j + 1;
 188         MapInfo_ClearTemps();
 189
 190         // sometimes the glob isn't sorted nicely, so fix it here...
 191         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, NULL);
 192
 193         return 1;
 194 }
 195 void MapInfo_FilterString(string sf)
 196 {
 197         // this function further filters _MapInfo_filtered, which is prepared by MapInfo_FilterGametype by string
 198         float i, j;
 199         string title;
 200
 201         for(i = 0, j = -1; i < MapInfo_count; ++i)
 202         {
 203                 if (MapInfo_Get_ByID(i))
 204                 {
 205                         // prepare for keyword filter
 206                         if (MapInfo_Map_title && strstrofs(MapInfo_Map_title, "<TITLE>", 0) == -1)
 207                                 title = MapInfo_Map_title;
 208                         else
 209                                 title = MapInfo_Map_bspname;
 210                         // keyword filter
 211                         if((strstrofs(strtolower(title), strtolower(sf), 0)) >= 0)
 212                                 bufstr_set(_MapInfo_filtered, ++j, bufstr_get(_MapInfo_filtered, i));
 213                 }
 214         }
 215         MapInfo_count = j + 1;
 216         MapInfo_ClearTemps();
 217
 218         // sometimes the glob isn't sorted nicely, so fix it here...
 219         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, NULL);
 220 }
 221
 222 void MapInfo_Filter_Free()
 223 {
 224         if(_MapInfo_filtered_allocated)
 225         {
 226                 buf_del(_MapInfo_filtered);
 227                 _MapInfo_filtered_allocated = 0;
 228         }
 229 }
 230
 231 // load info about the i-th map into the MapInfo_Map_* globals
 232 string MapInfo_BSPName_ByID(float i)
 233 {
 234         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 235 }
 236
 237 string unquote(string s)
 238 {
 239         float l = strlen(s);
 240         for(float i = 0; i < l; ++i)
 241         {
 242                 string ch = substring(s, i, 1);
 243                 if((ch != " ") && (ch != "\""))
 244                 {
 245                         for(float j = l - i - 1; j > 0; --j)
 246                         {
 247                                 ch = substring(s, i+j, 1);
 248                                 if(ch != " ") if(ch != "\"")
 249                                         return substring(s, i, j+1);
 250                         }
 251                         return substring(s, i, 1);
 252                 }
 253         }
 254         return "";
 255 }
 256
 257 float MapInfo_Get_ByID(float i)
 258 {
 259         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, NULL))
 260                 return 1;
 261         return 0;
 262 }
 263
 264 string _MapInfo_Map_worldspawn_music;
 265
 266 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 267 {
 268         string fn;
 269         float fh;
 270         string s, k, v;
 271         vector o;
 272         float i;
 273         float inWorldspawn;
 274         float r;
 275         float diameter, spawnpoints;
 276         float spawnplaces;
 277
 278         vector mapMins, mapMaxs;
 279
 280         r = 1;
 281         fn = strcat("maps/", pFilename, ".ent");
 282         fh = fopen(fn, FILE_READ);
 283         if(fh < 0)
 284         {
 285                 r = 2;
 286                 fn = strcat("maps/", pFilename, ".bsp");
 287                 fh = fopen(fn, FILE_READ);
 288         }
 289         if(fh < 0)
 290                 return 0;
 291         LOG_INFO("Analyzing ", fn, " to generate initial mapinfo");
 292
 293         inWorldspawn = 2;
 294         MapInfo_Map_flags = 0;
 295         MapInfo_Map_supportedGametypes = 0;
 296         spawnpoints = 0;
 297         spawnplaces = 0;
 298         _MapInfo_Map_worldspawn_music = "";
 299         mapMins = '0 0 0';
 300         mapMaxs = '0 0 0';
 301
 302         for (;;)
 303         {
 304                 if (!((s = fgets(fh))))
 305                         break;
 306                 if(inWorldspawn == 1)
 307                         if(startsWith(s, "}"))
 308                                 inWorldspawn = 0;
 309                 k = unquote(car(s));
 310                 v = unquote(cdr(s));
 311                 if(inWorldspawn)
 312                 {
 313                         if(k == "classname" && v == "worldspawn")
 314                                 inWorldspawn = 1;
 315                         else if(k == "author")
 316                                 MapInfo_Map_author = v;
 317                         else if(k == "_description")
 318                                 MapInfo_Map_description = v;
 319                         else if(k == "music")
 320                                 _MapInfo_Map_worldspawn_music = v;
 321                         else if(k == "noise")
 322                                 _MapInfo_Map_worldspawn_music = v;
 323                         else if(k == "message")
 324                         {
 325                                 i = strstrofs(v, " by ", 0);
 326                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 327                                 {
 328                                         MapInfo_Map_title = substring(v, 0, i);
 329                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 330                                 }
 331                                 else
 332                                         MapInfo_Map_title = v;
 333                         }
 334                 }
 335                 else
 336                 {
 337                         if(k == "origin")
 338                         {
 339                                 o = stov(strcat("'", v, "'"));
 340                                 mapMins.x = min(mapMins.x, o.x);
 341                                 mapMins.y = min(mapMins.y, o.y);
 342                                 mapMins.z = min(mapMins.z, o.z);
 343                                 mapMaxs.x = max(mapMaxs.x, o.x);
 344                                 mapMaxs.y = max(mapMaxs.y, o.y);
 345                                 mapMaxs.z = max(mapMaxs.z, o.z);
 346                         }
 347                         else if(k == "race_place")
 348                         {
 349                                 if(stof(v) > 0)
 350                                         spawnplaces = 1;
 351                         }
 352                         else if(k == "classname")
 353                         {
 354                                 if(v == "info_player_team1")
 355                                         ++spawnpoints;
 356                                 else if(v == "info_player_team2")
 357                                         ++spawnpoints;
 358                                 else if(v == "info_player_start")
 359                                         ++spawnpoints;
 360                                 else if(v == "info_player_deathmatch")
 361                                         ++spawnpoints;
 362                                 else if(v == "weapon_nex")
 363                                         { }
 364                                 else if(v == "weapon_railgun")
 365                                         { }
 366                                 else if(startsWith(v, "weapon_"))
 367                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 368                                 else if(startsWith(v, "turret_"))
 369                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 370                                 else if(startsWith(v, "vehicle_"))
 371                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 372                                 else if(startsWith(v, "monster_"))
 373                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
 374                                 else if(v == "target_music" || v == "trigger_music")
 375                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
 376                                 else
 377                                         FOREACH(Gametypes, true, it.m_generate_mapinfo(it, v));
 378                         }
 379                 }
 380         }
 381         if(inWorldspawn)
 382         {
 383                 LOG_WARN(fn, " ended still in worldspawn, BUG");
 384                 return 0;
 385         }
 386         diameter = vlen(mapMaxs - mapMins);
 387
 388         int twoBaseModes = 0;
 389         FOREACH(Gametypes, it.m_isTwoBaseMode(), twoBaseModes |= it.m_flags);
 390         if(twoBaseModes && (twoBaseModes &= MapInfo_Map_supportedGametypes))
 391         {
 392                 // we have a symmetrical map, don't add the modes without bases
 393         }
 394         else
 395         {
 396                 FOREACH(Gametypes, it.m_isAlwaysSupported(it, spawnpoints, diameter), MapInfo_Map_supportedGametypes |= it.m_flags);
 397         }
 398
 399         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE.m_flags)
 400         if(!spawnplaces)
 401         {
 402                 MapInfo_Map_supportedGametypes &= ~MAPINFO_TYPE_RACE.m_flags;
 403                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS.m_flags;
 404         }
 405
 406         LOG_TRACE("-> diameter ",    ftos(diameter));
 407         LOG_TRACE(";  spawnpoints ", ftos(spawnpoints));
 408         LOG_TRACE(";  modes ",       ftos(MapInfo_Map_supportedGametypes));
 409
 410         fclose(fh);
 411
 412         return r;
 413 }
 414
 415 void _MapInfo_Map_Reset()
 416 {
 417         MapInfo_Map_title = "<TITLE>";
 418         MapInfo_Map_titlestring = "<TITLE>";
 419         MapInfo_Map_description = "<DESCRIPTION>";
 420         MapInfo_Map_author = "<AUTHOR>";
 421         MapInfo_Map_supportedGametypes = 0;
 422         MapInfo_Map_supportedFeatures = 0;
 423         MapInfo_Map_flags = 0;
 424         MapInfo_Map_clientstuff = "";
 425         MapInfo_Map_fog = "";
 426         MapInfo_Map_mins = '0 0 0';
 427         MapInfo_Map_maxs = '0 0 0';
 428 }
 429
 430 string _MapInfo_GetDefault(Gametype t)
 431 {
 432         return t.m_legacydefaults;
 433 }
 434
 435 void _MapInfo_Map_ApplyGametype(string s, Gametype pWantedType, Gametype pThisType, int load_default)
 436 {
 437         string sa;
 438         MapInfo_Map_supportedGametypes |= pThisType.m_flags;
 439         if(!(pThisType.m_flags & pWantedType.m_flags))
 440                 return;
 441
 442         if(load_default)
 443                 _MapInfo_Map_ApplyGametype(_MapInfo_GetDefault(pThisType), pWantedType, pThisType, false);
 444
 445         if(!pWantedType.frags) // these modes don't use fraglimit
 446         {
 447                 cvar_set("fraglimit", "0");
 448         }
 449         else
 450         {
 451                 sa = car(s);
 452                 if(sa != "")
 453                         cvar_set("fraglimit", sa);
 454                 s = cdr(s);
 455         }
 456
 457         sa = car(s);
 458         if(sa != "")
 459                 cvar_set("timelimit", sa);
 460         s = cdr(s);
 461
 462         if(pWantedType.m_setTeams)
 463         {
 464                 sa = car(s);
 465                 if(sa != "")
 466                         pWantedType.m_setTeams(sa);
 467                 s = cdr(s);
 468         }
 469
 470         // rc = timelimit timelimit_qualification laps laps_teamplay
 471         if(pWantedType == MAPINFO_TYPE_RACE)
 472         {
 473                 cvar_set("fraglimit", "0"); // special case!
 474
 475                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 476                 cvar_set("g_race_qualifying_timelimit", sa);
 477                 s = cdr(s);
 478
 479                 sa = car(s);
 480                 if(sa != "")
 481                         if(cvar("g_race_teams") < 2)
 482                                 cvar_set("fraglimit", sa);
 483                 s = cdr(s);
 484
 485                 sa = car(s);
 486                 if(sa != "")
 487                         if(cvar("g_race_teams") >= 2)
 488                                 cvar_set("fraglimit", sa);
 489                 s = cdr(s);
 490         }
 491
 492         if(!pWantedType.frags) // these modes don't use fraglimit
 493         {
 494                 cvar_set("leadlimit", "0");
 495         }
 496         else
 497         {
 498                 sa = car(s);
 499                 if(sa != "")
 500                         cvar_set("leadlimit", sa);
 501                 s = cdr(s);
 502         }
 503 }
 504
 505 string _MapInfo_GetDefaultEx(Gametype t)
 506 {
 507         return t ? t.model2 : "";
 508 }
 509
 510 float _MapInfo_GetTeamPlayBool(Gametype t)
 511 {
 512         return t ? t.team : false;
 513 }
 514
 515 void _MapInfo_Map_ApplyGametypeEx(string s, Gametype pWantedType, Gametype pThisType)
 516 {
 517         MapInfo_Map_supportedGametypes |= pThisType.m_flags;
 518         if (!(pThisType.m_flags & pWantedType.m_flags))
 519                 return;
 520
 521         // reset all the cvars to their defaults
 522
 523         cvar_set("timelimit", cvar_defstring("timelimit"));
 524         cvar_set("leadlimit", cvar_defstring("leadlimit"));
 525         cvar_set("fraglimit", cvar_defstring("fraglimit"));
 526         FOREACH(Gametypes, true, it.m_parse_mapinfo(string_null, string_null));
 527
 528         string fraglimit_normal = string_null;
 529         string fraglimit_teams = string_null;
 530
 531         for (s = strcat(_MapInfo_GetDefaultEx(pWantedType), " ", s); s != ""; s = cdr(s)) {
 532                 string sa = car(s);
 533                 if (sa == "") continue;
 534                 int p = strstrofs(sa, "=", 0);
 535                 if (p < 0) {
 536                         if(WARN_COND)
 537                                 LOG_WARNF("Invalid gametype setting in mapinfo for gametype %s: %s", MapInfo_Type_ToString(pWantedType), sa);
 538                         continue;
 539                 }
 540                 string k = substring(sa, 0, p);
 541                 string v = substring(sa, p + 1, -1);
 542                 bool handled = true;
 543                 switch (k) {
 544                         case "timelimit":
 545                         {
 546                                 cvar_set("timelimit", v);
 547                                 break;
 548                         }
 549                         case "leadlimit":
 550                         {
 551                                 cvar_set("leadlimit", v);
 552                                 break;
 553                         }
 554                         case "pointlimit":
 555                         case "fraglimit":
 556                         case "lives":
 557                         case "laplimit":
 558                         case "caplimit":
 559                         {
 560                                 fraglimit_normal = v;
 561                                 break;
 562                         }
 563                         case "teampointlimit":
 564                         case "teamlaplimit":
 565                         {
 566                                 fraglimit_teams = v;
 567                                 break;
 568                         }
 569                         default:
 570                         {
 571                             handled = false;
 572                             break;
 573                         }
 574                 }
 575                 FOREACH(Gametypes, true, handled |= it.m_parse_mapinfo(k, v));
 576                 if (!handled && WARN_COND)
 577             LOG_WARNF("Invalid gametype setting in mapinfo for gametype %s: %s", MapInfo_Type_ToString(pWantedType), sa);
 578         }
 579
 580         if (pWantedType == MAPINFO_TYPE_RACE && cvar("g_race_teams") >= 2)
 581         {
 582                 if(fraglimit_teams)
 583                         cvar_set("fraglimit", fraglimit_teams);
 584         }
 585         else
 586         {
 587                 if(fraglimit_normal)
 588                         cvar_set("fraglimit", fraglimit_normal);
 589         }
 590 }
 591
 592 Gametype MapInfo_Type_FromString(string gtype)
 593 {
 594         string replacement = "";
 595         bool do_warn = true;
 596         switch (gtype)
 597         {
 598                 case "nexball":   replacement = "nb"; break;
 599                 case "freezetag": replacement = "ft"; break;
 600                 case "keepaway":  replacement = "ka"; break;
 601                 case "invasion":  replacement = "inv"; break;
 602                 case "assault":   replacement = "as"; break;
 603                 case "race":      replacement = "rc"; break;
 604                 // quake 3 compat
 605                 case "ffa":       replacement = "dm"; do_warn = false; break;
 606                 case "cctf":
 607                 case "oneflag":   replacement = "ctf"; do_warn = false; break;
 608                 case "team":      replacement = "tdm"; do_warn = false; break;
 609                 case "tourney":   replacement = "duel"; do_warn = false; break;
 610         }
 611         if (replacement != "")
 612         {
 613                 if(do_warn && WARN_COND)
 614                         LOG_WARNF("MapInfo_Type_FromString (probably %s): using deprecated name '%s'. Should use '%s'.", MapInfo_Map_bspname, gtype, replacement);
 615                 gtype = replacement;
 616         }
 617         FOREACH(Gametypes, it.mdl == gtype, return it);
 618         return NULL;
 619 }
 620
 621 string MapInfo_Type_Description(Gametype t)
 622 {
 623         return t ? t.gametype_description : "";
 624 }
 625
 626 string MapInfo_Type_ToString(Gametype t)
 627 {
 628         return t ? t.mdl : "";
 629 }
 630
 631 string MapInfo_Type_ToText(Gametype t)
 632 {
 633         /* xgettext:no-c-format */
 634         return t ? t.message : _("@!#%'n Tuba Throwing");
 635 }
 636
 637 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 638 {
 639         string t;
 640         float fh, o;
 641         t = car(s); s = cdr(s);
 642
 643         // limited support of "" and comments
 644         //   remove trailing and leading " of t
 645         if(substring(t, 0, 1) == "\"")
 646         {
 647                 if(substring(t, -1, 1) == "\"")
 648                         t = substring(t, 1, -2);
 649         }
 650
 651         //   remove leading " of s
 652         if(substring(s, 0, 1) == "\"")
 653         {
 654                 s = substring(s, 1, -1);
 655         }
 656         //   remove trailing " of s, and all that follows (cvar description)
 657         o = strstrofs(s, "\"", 0);
 658         if(o >= 0)
 659                 s = substring(s, 0, o);
 660
 661         //   remove // comments
 662         o = strstrofs(s, "//", 0);
 663         if(o >= 0)
 664                 s = substring(s, 0, o);
 665
 666         //   remove trailing spaces
 667         while(substring(s, -1, 1) == " ")
 668                 s = substring(s, 0, -2);
 669
 670         if(t == "#include")
 671         {
 672                 if(recurse > 0)
 673                 {
 674                         fh = fopen(s, FILE_READ);
 675                         if(fh < 0)
 676                         {
 677                                 if(WARN_COND)
 678                                         LOG_WARN("Map ", pFilename, " references not existing config file ", s);
 679                         }
 680                         else
 681                         {
 682                                 while((s = fgets(fh)))
 683                                 {
 684                                         // catch different sorts of comments
 685                                         if(s == "")                    // empty lines
 686                                                 continue;
 687                                         if(substring(s, 0, 1) == "#")  // UNIX style
 688                                                 continue;
 689                                         if(substring(s, 0, 2) == "//") // C++ style
 690                                                 continue;
 691                                         if(substring(s, 0, 1) == "_")  // q3map style
 692                                                 continue;
 693
 694                                         if(substring(s, 0, 4) == "set ")
 695                                                 s = substring(s, 4, -1);
 696                                         if(substring(s, 0, 5) == "seta ")
 697                                                 s = substring(s, 5, -1);
 698
 699                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 700                                 }
 701                                 fclose(fh);
 702                         }
 703                 }
 704                 else if(WARN_COND)
 705                         LOG_WARN("Map ", pFilename, " uses too many levels of inclusion");
 706         }
 707         else if(t == ""
 708                 || !cvar_value_issafe(t)
 709                 || !cvar_value_issafe(s)
 710                 || matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
 711         {
 712                 if (WARN_COND)
 713                         LOG_WARN("Map ", pFilename, " contains a potentially harmful setting, ignored");
 714         }
 715         else if(matchacl(acl, t) <= 0)
 716         {
 717                 if (WARN_COND)
 718                         LOG_WARN("Map ", pFilename, " contains a denied setting, ignored");
 719         }
 720         else
 721         {
 722                 if(type == 0) // server set
 723                 {
 724                         LOG_TRACE("Applying temporary setting ", t, " := ", s);
 725                 #if 0
 726                         if(cvar("g_campaign"))
 727                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 728                         else
 729                 #endif
 730                                 cvar_settemp(t, s);
 731                 }
 732                 else
 733                 {
 734                         LOG_TRACE("Applying temporary client setting ", t, " := ", s);
 735                         MapInfo_Map_clientstuff = strcat(
 736                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 737                                         );
 738                 }
 739         }
 740 }
 741
 742 float MapInfo_isRedundant(string fn, string t)
 743 {
 744         // normalize file name
 745         fn = strreplace("_", "", fn);
 746         fn = strreplace("-", "", fn);
 747
 748         // normalize visible title
 749         t = strreplace(":", "", t);
 750         t = strreplace(" ", "", t);
 751         t = strreplace("_", "", t);
 752         t = strreplace("-", "", t);
 753         t = strreplace("'", "", t);
 754         t = strdecolorize(t);
 755
 756         // we allow the visible title to have punctuation the file name does
 757         // not, but not vice versa
 758         if(!strcasecmp(fn, t))
 759                 return true;
 760
 761         return false;
 762 }
 763
 764 bool _MapInfo_ParseArena(string arena_filename, int fh, string pFilename, Gametype pGametypeToSet, bool isdefi)
 765 {
 766         // NOTE: .arena files can hold more than 1 map's information!
 767         // to handle this, we're going to store gathered information in local variables and save it if we encounter the correct map name
 768         bool in_brackets = false; // testing a potential mapinfo section (within brackets)
 769         bool dosave = (arena_filename == strcat("scripts/", pFilename, ((isdefi) ? ".defi" : ".arena"))); // if the map is using the fallback, just accept the first found mapinfo (it's probably correct!)
 770         string stored_Map_description = "";
 771         string stored_Map_title = "";
 772         string stored_Map_author = "";
 773         int stored_supportedGametypes = 0;
 774         string t, s;
 775         for (;;)
 776         {
 777                 if (!((s = fgets(fh))))
 778                         break;
 779
 780                 // catch different sorts of comments
 781                 if(s == "")                    // empty lines
 782                         continue;
 783                 if(substring(s, 0, 1) == "#")  // UNIX style
 784                         continue;
 785                 if(substring(s, 0, 2) == "//") // C++ style
 786                         continue;
 787                 if(substring(s, 0, 1) == "_")  // q3map style
 788                         continue;
 789                 if(strstrofs(s, "{", 0) >= 0)
 790                 {
 791                         if(in_brackets)
 792                                 return false; // edge case? already in a bracketed section!
 793                         in_brackets = true;
 794                         continue;
 795                 }
 796                 else if(!in_brackets)
 797                 {
 798                         // if we're not inside a bracket, don't process map info
 799                         continue;
 800                 }
 801                 if(strstrofs(s, "}", 0) >= 0)
 802                 {
 803                         if(!in_brackets)
 804                                 return false; // no starting bracket! let the mapinfo generation system handle it
 805                         in_brackets = false;
 806                         if(dosave)
 807                         {
 808                                 MapInfo_Map_description = stored_Map_description;
 809                                 if(stored_Map_title != "")
 810                                         MapInfo_Map_title = stored_Map_title;
 811                                 MapInfo_Map_author = stored_Map_author;
 812                                 FOREACH(Gametypes, it.m_flags & stored_supportedGametypes,
 813                                 {
 814                                         _MapInfo_Map_ApplyGametype ("", pGametypeToSet, it, true);
 815                                 });
 816                                 return true; // no need to continue through the file, we have our map!
 817                         }
 818                         else
 819                         {
 820                                 // discard any gathered locals, we're not using the correct map!
 821                                 stored_Map_description = "";
 822                                 stored_Map_title = "";
 823                                 stored_Map_author = "";
 824                                 stored_supportedGametypes = 0;
 825                                 continue;
 826                         }
 827                 }
 828
 829                 s = strreplace("\t", " ", s);
 830
 831                 float p = strstrofs(s, "//", 0);
 832                 if(p >= 0)
 833                         s = substring(s, 0, p);
 834
 835                 // perform an initial trim to ensure the first argument is properly obtained
 836                 //   remove leading spaces
 837                 while(substring(s, 0, 1) == " ")
 838                         s = substring(s, 1, -1);
 839
 840                 t = car(s); s = cdr(s);
 841                 t = strtolower(t); // apparently some q3 maps use capitalized parameters
 842
 843                 //   remove trailing spaces
 844                 while(substring(t, -1, 1) == " ")
 845                         t = substring(t, 0, -2);
 846
 847                 //   remove trailing spaces
 848                 while(substring(s, -1, 1) == " ")
 849                         s = substring(s, 0, -2);
 850                 //   remove leading spaces
 851                 while(substring(s, 0, 1) == " ")
 852                         s = substring(s, 1, -1);
 853                 // limited support of ""
 854                 //   remove trailing and leading " of s
 855                 if(substring(s, 0, 1) == "\"")
 856                 {
 857                         if(substring(s, -1, 1) == "\"")
 858                                 s = substring(s, 1, -2);
 859                 }
 860                 if(t == "longname")
 861                         stored_Map_title = s;
 862                 else if(t == "author")
 863                         stored_Map_author = s;
 864                 else if(t == "type")
 865                 {
 866                         // if there is a valid gametype in this .arena file, include it in the menu
 867                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 868                         // type in quake 3 holds all the supported gametypes, so we must loop through all of them
 869                         FOREACH_WORD(s, true,
 870                         {
 871                                 Gametype f = MapInfo_Type_FromString(it);
 872                                 if(f)
 873                                         stored_supportedGametypes |= f.m_flags;
 874                         });
 875                 }
 876                 else if(t == "style" && isdefi)
 877                 {
 878                         // we have a defrag map on our hands, add CTS!
 879                         // TODO: styles
 880                         stored_supportedGametypes |= MAPINFO_TYPE_CTS.m_flags;
 881                 }
 882                 else if(t == "map")
 883                 {
 884                         if(strtolower(s) == strtolower(pFilename))
 885                                 dosave = true; // yay, found our map!
 886                 }
 887                 else if(t == "quote")
 888                         stored_Map_description = s;
 889                 // TODO: fraglimit
 890         }
 891
 892         // if the map wasn't found in the .arena, fall back to generated .mapinfo
 893         return false;
 894 }
 895
 896 #if defined(CSQC) || defined(MENUQC)
 897 string(string filename) whichpack = #503;
 898 #endif
 899 string _MapInfo_FindArenaFile(string pFilename, string extension)
 900 {
 901         string base_pack = whichpack(strcat("maps/", pFilename, ".bsp"));
 902         string fallback = strcat("scripts/", pFilename, extension);
 903         if(base_pack == "") // this map isn't packaged!
 904                 return fallback;
 905
 906         int glob = search_begin(strcat("scripts/*", extension), true, true);
 907         if(glob < 0)
 908                 return fallback;
 909         int n = search_getsize(glob);
 910         for(int j = 0; j < n; ++j)
 911         {
 912                 string file = search_getfilename(glob, j);
 913                 if(whichpack(file) != base_pack)
 914                         continue; // not in the same pk3!
 915
 916                 int fh = fopen(file, FILE_READ);
 917                 if(fh < 0)
 918                         continue; // how?
 919                 for(string s; (s = fgets(fh)); )
 920                 {
 921                         int offset = strstrofs(s, "map", 0);
 922                         if(offset >= 0)
 923                         {
 924                                 if(strstrofs(strtolower(s), strcat("\"", strtolower(pFilename), "\""), offset) >= 0) // quake 3 is case insensitive
 925                                 {
 926                                         fclose(fh);
 927                                         search_end(glob);
 928                                         return file; // FOUND IT!
 929                                 }
 930                         }
 931                 }
 932                 fclose(fh);
 933         }
 934
 935         search_end(glob);
 936         return fallback; // if we get here, a valid .arena file could not be found
 937 }
 938
 939 // load info about a map by name into the MapInfo_Map_* globals
 940 float MapInfo_Get_ByName_NoFallbacks(string pFilename, int pAllowGenerate, Gametype pGametypeToSet)
 941 {
 942         string fn;
 943         string s, t;
 944         float fh;
 945         int f, i;
 946         float r, n;
 947         string acl;
 948
 949         acl = MAPINFO_SETTEMP_ACL_USER;
 950
 951         if(strstrofs(pFilename, "/", 0) >= 0)
 952         {
 953                 LOG_WARN("Invalid character in map name, ignored");
 954                 return 0;
 955         }
 956
 957         if(pGametypeToSet == NULL)
 958                 if(MapInfo_Cache_Retrieve(pFilename))
 959                         return 1;
 960
 961         r = 1;
 962
 963         MapInfo_Map_bspname = pFilename;
 964
 965         // default all generic fields so they have "good" values in case something fails
 966         fn = strcat("maps/", pFilename, ".mapinfo");
 967         fh = fopen(fn, FILE_READ);
 968         if(fh < 0)
 969         {
 970                 bool isdefi = false;
 971                 // try for a .arena or .defi file if no .mapinfo exists
 972                 fn = _MapInfo_FindArenaFile(pFilename, ".arena");
 973                 fh = fopen(fn, FILE_READ);
 974                 if(fh < 0)
 975                 {
 976                         isdefi = true;
 977                         fn = _MapInfo_FindArenaFile(pFilename, ".defi");
 978                         fh = fopen(fn, FILE_READ);
 979                 }
 980                 if(fh >= 0)
 981                 {
 982                         _MapInfo_Map_Reset();
 983                         if(_MapInfo_ParseArena(fn, fh, pFilename, pGametypeToSet, isdefi))
 984                                 goto mapinfo_handled; // skip generation
 985                 }
 986
 987                 fn = strcat("maps/autogenerated/", pFilename, ".mapinfo");
 988                 fh = fopen(fn, FILE_READ);
 989                 if(fh < 0)
 990                 {
 991                         if(!pAllowGenerate)
 992                                 return 0;
 993                         _MapInfo_Map_Reset();
 994                         r = _MapInfo_Generate(pFilename);
 995                         if(!r)
 996                                 return 0;
 997                         fh = fopen(fn, FILE_WRITE);
 998                         fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 999                         fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
1000                         fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
1001                         if(_MapInfo_Map_worldspawn_music != "")
1002                         {
1003                                 if(
1004                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
1005                                         ||
1006                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
1007                                 )
1008                                         fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
1009                                 else
1010                                         fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
1011                         }
1012                         else
1013                         {
1014                                 n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
1015                                 s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
1016                                 for (;;)
1017                                 {
1018                                         i = floor(random() * n);
1019                                         if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
1020                                                 break;
1021                                 }
1022                                 fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
1023                         }
1024                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
1025                                 fputs(fh, "has weapons\n");
1026                         else
1027                                 fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
1028                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_TURRETS)
1029                                 fputs(fh, "has turrets\n");
1030                         else
1031                                 fputs(fh, "// uncomment this if you added turrets: has turrets\n");
1032                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_VEHICLES)
1033                                 fputs(fh, "has vehicles\n");
1034                         else
1035                                 fputs(fh, "// uncomment this if you added vehicles: has vehicles\n");
1036                         if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
1037                                 fputs(fh, "frustrating\n");
1038
1039                         FOREACH(Gametypes, MapInfo_Map_supportedGametypes & it.m_flags, {
1040                                 fputs(fh, sprintf("gametype %s // defaults: %s\n", MapInfo_Type_ToString(it), _MapInfo_GetDefaultEx(it)));
1041                         });
1042
1043                         fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
1044                         fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
1045                         fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
1046                         fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1047                         fputs(fh, "// optional: hidden\n");
1048
1049                         fclose(fh);
1050                         r = 2;
1051                         // return r;
1052                         fh = fopen(fn, FILE_READ);
1053                         if(fh < 0)
1054                                 error("... but I just wrote it!");
1055                 }
1056
1057                 if(WARN_COND)
1058                         LOG_WARN("autogenerated mapinfo file ", fn, " has been loaded; please edit that file and move it to maps/", pFilename, ".mapinfo");
1059         }
1060
1061         _MapInfo_Map_Reset();
1062         for (;;)
1063         {
1064                 if (!((s = fgets(fh))))
1065                         break;
1066
1067                 // catch different sorts of comments
1068                 if(s == "")                    // empty lines
1069                         continue;
1070                 if(substring(s, 0, 1) == "#")  // UNIX style
1071                         continue;
1072                 if(substring(s, 0, 2) == "//") // C++ style
1073                         continue;
1074                 if(substring(s, 0, 1) == "_")  // q3map style
1075                         continue;
1076
1077                 float p = strstrofs(s, "//", 0);
1078                 if(p >= 0)
1079                         s = substring(s, 0, p);
1080
1081                 t = car(s); s = cdr(s);
1082                 if(t == "title")
1083                         MapInfo_Map_title = s;
1084                 else if(t == "description")
1085                         MapInfo_Map_description = s;
1086                 else if(t == "author")
1087                         MapInfo_Map_author = s;
1088                 else if(t == "has")
1089                 {
1090                         t = car(s); // s = cdr(s);
1091                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
1092                         else if(t == "turrets") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
1093                         else if(t == "vehicles") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
1094                         else if(t == "monsters") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
1095                         else if(t == "new_toys") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
1096                         else if(WARN_COND)
1097                                 LOG_WARN("Map ", pFilename, " supports unknown feature ", t, ", ignored");
1098                 }
1099                 else if(t == "hidden")
1100                 {
1101                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
1102                 }
1103                 else if(t == "forbidden")
1104                 {
1105                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
1106                 }
1107                 else if(t == "frustrating")
1108                 {
1109                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
1110                 }
1111                 else if(t == "noautomaplist")
1112                 {
1113                         MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
1114                 }
1115                 else if(t == "gameversion_min")
1116                 {
1117                         if (cvar("gameversion") < stof(s))
1118                                 MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
1119                 }
1120                 else if(t == "type")
1121                 {
1122                         t = car(s); s = cdr(s);
1123                         Gametype f = MapInfo_Type_FromString(t);
1124                         //if(WARN_COND)
1125                                 //LOG_WARN("Map ", pFilename, " contains the legacy 'type' keyword which is deprecated and will be removed in the future. Please migrate the mapinfo file to 'gametype'.");
1126                         if(f)
1127                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, true);
1128                         else if(WARN_COND)
1129                                 LOG_DEBUG("Map ", pFilename, " supports unknown game type ", t, ", ignored");
1130                 }
1131                 else if(t == "gametype")
1132                 {
1133                         t = car(s); s = cdr(s);
1134                         Gametype f = MapInfo_Type_FromString(t);
1135                         if(f)
1136                                 _MapInfo_Map_ApplyGametypeEx (s, pGametypeToSet, f);
1137                         else if(WARN_COND)
1138                                 LOG_DEBUG("Map ", pFilename, " supports unknown game type ", t, ", ignored");
1139                 }
1140                 else if(t == "size")
1141                 {
1142                         float a, b, c, d, e;
1143                         t = car(s); s = cdr(s); a = stof(t);
1144                         t = car(s); s = cdr(s); b = stof(t);
1145                         t = car(s); s = cdr(s); c = stof(t);
1146                         t = car(s); s = cdr(s); d = stof(t);
1147                         t = car(s); s = cdr(s); e = stof(t);
1148                         if(s == "")
1149                         {
1150                                 if(WARN_COND)
1151                                         LOG_WARN("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z");
1152                         }
1153                         else
1154                         {
1155                                 t = car(s); s = cdr(s); f = stof(t);
1156                                 if(s != "")
1157                                 {
1158                                         if(WARN_COND)
1159                                                 LOG_WARN("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z");
1160                                 }
1161                                 else
1162                                 {
1163                                         if(a >= d || b >= e || c >= f)
1164                                         {
1165                                                 if(WARN_COND)
1166                                                         LOG_WARN("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs");
1167                                         }
1168                                         else
1169                                         {
1170                                                 MapInfo_Map_mins.x = a;
1171                                                 MapInfo_Map_mins.y = b;
1172                                                 MapInfo_Map_mins.z = c;
1173                                                 MapInfo_Map_maxs.x = d;
1174                                                 MapInfo_Map_maxs.y = e;
1175                                                 MapInfo_Map_maxs.z = f;
1176                                         }
1177                                 }
1178                         }
1179                 }
1180                 else if(t == "settemp_for_type")
1181                 {
1182                         t = car(s); s = cdr(s);
1183                         bool all = t == "all";
1184                         Gametype f = NULL;
1185                         if(all || (f = MapInfo_Type_FromString(t)))
1186                         {
1187                                 if((all ? MAPINFO_TYPE_ALL : f.m_flags) & pGametypeToSet.m_flags)
1188                                 {
1189                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
1190                                 }
1191                         }
1192                         else
1193                         {
1194                                 LOG_DEBUG("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored");
1195                         }
1196                 }
1197                 else if(t == "clientsettemp_for_type")
1198                 {
1199                         t = car(s); s = cdr(s);
1200                         bool all = t == "all";
1201                         Gametype f = NULL;
1202                         if(all || (f = MapInfo_Type_FromString(t)))
1203                         {
1204                                 if((all ? MAPINFO_TYPE_ALL : f.m_flags) & pGametypeToSet.m_flags)
1205                                 {
1206                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
1207                                 }
1208                         }
1209                         else
1210                         {
1211                                 LOG_DEBUG("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored");
1212                         }
1213                 }
1214                 else if(t == "fog")
1215                 {
1216                         if (!cvar_value_issafe(s))
1217                         {
1218                                 if(WARN_COND)
1219                                         LOG_WARN("Map ", pFilename, " contains a potentially harmful fog setting, ignored");
1220                         }
1221                         else
1222                                 MapInfo_Map_fog = s;
1223                 }
1224                 else if(t == "cdtrack")
1225                 {
1226                         t = car(s); s = cdr(s);
1227                         // We do this only if pGametypeToSet even though this
1228                         // content is theoretically game type independent,
1229                         // because MapInfo_Map_clientstuff contains otherwise
1230                         // game type dependent stuff. That way this value stays
1231                         // empty when not setting a game type to not set any
1232                         // false expectations.
1233                         if(pGametypeToSet)
1234                         {
1235                                 if (!cvar_value_issafe(t))
1236                                 {
1237                                         if(WARN_COND)
1238                                                 LOG_WARN("Map ", pFilename, " contains a potentially harmful cdtrack, ignored");
1239                                 }
1240                                 else
1241                                         MapInfo_Map_clientstuff = strcat(
1242                                                 MapInfo_Map_clientstuff, "cd loop \"", t, "\"\n"
1243                                         );
1244                         }
1245                 }
1246                 else if(WARN_COND)
1247                         LOG_WARN("Map ", pFilename, " provides unknown info item ", t, ", ignored");
1248         }
1249         LABEL(mapinfo_handled)
1250         fclose(fh);
1251
1252         if(MapInfo_Map_title == "<TITLE>")
1253                 MapInfo_Map_titlestring = MapInfo_Map_bspname;
1254         else if(MapInfo_isRedundant(MapInfo_Map_bspname, MapInfo_Map_title))
1255                 MapInfo_Map_titlestring = MapInfo_Map_title;
1256         else
1257                 MapInfo_Map_titlestring = sprintf("%s: %s", MapInfo_Map_bspname, MapInfo_Map_title);
1258
1259         MapInfo_Cache_Store();
1260         if(MapInfo_Map_supportedGametypes != 0)
1261                 return r;
1262         if (WARN_COND)
1263                 LOG_WARN("Map ", pFilename, " supports no game types, ignored");
1264         return 0;
1265 }
1266 int MapInfo_Get_ByName(string pFilename, float pAllowGenerate, Gametype pGametypeToSet)
1267 {
1268         int r = MapInfo_Get_ByName_NoFallbacks(pFilename, pAllowGenerate, pGametypeToSet);
1269
1270         FOREACH(Gametypes, it.m_isForcedSupported(it), _MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, it));
1271
1272         if(pGametypeToSet)
1273         {
1274                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet.m_flags))
1275                 {
1276                         error("Can't select the requested game type. This should never happen as the caller should prevent it!\n");
1277                         //_MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
1278                         //return;
1279                 }
1280         }
1281
1282         return r;
1283 }
1284
1285 float MapInfo_FindName(string s)
1286 {
1287         // if there is exactly one map of prefix s, return it
1288         // if not, return the null string
1289         // note that DP sorts glob results... so I can use a binary search
1290         float l, r, m, cmp;
1291         l = 0;
1292         r = MapInfo_count;
1293         // invariants: r is behind s, l-1 is equal or before
1294         while(l != r)
1295         {
1296                 m = floor((l + r) / 2);
1297                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
1298                 cmp = strcasecmp(MapInfo_FindName_match, s);
1299                 if(cmp == 0)
1300                         return m; // found and good
1301                 if(cmp < 0)
1302                         l = m + 1; // l-1 is before s
1303                 else
1304                         r = m; // behind s
1305         }
1306         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
1307         MapInfo_FindName_firstResult = l;
1308         // r == l, so: l is behind s, l-1 is before
1309         // SO: if there is any, l is the one with the right prefix
1310         //     and l+1 may be one too
1311         if(l == MapInfo_count)
1312         {
1313                 MapInfo_FindName_match = string_null;
1314                 MapInfo_FindName_firstResult = -1;
1315                 return -1; // no MapInfo_FindName_match, behind last item
1316         }
1317         if(!startsWithNocase(MapInfo_FindName_match, s))
1318         {
1319                 MapInfo_FindName_match = string_null;
1320                 MapInfo_FindName_firstResult = -1;
1321                 return -1; // wrong prefix
1322         }
1323         if(l == MapInfo_count - 1)
1324                 return l; // last one, nothing can follow => unique
1325         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
1326         {
1327                 MapInfo_FindName_match = string_null;
1328                 return -1; // ambigous MapInfo_FindName_match
1329         }
1330         return l;
1331 }
1332
1333 string MapInfo_FixName(string s)
1334 {
1335         MapInfo_FindName(s);
1336         return MapInfo_FindName_match;
1337 }
1338
1339 int MapInfo_CurrentFeatures()
1340 {
1341         int req = 0;
1342     // TODO: find a better way to check if weapons are required on the map
1343         if(!(cvar("g_instagib") || cvar("g_overkill") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items")
1344                 || cvar("g_race") || cvar("g_cts") || cvar("g_nexball") || cvar("g_ca") || cvar("g_freezetag") || cvar("g_lms")))
1345                 req |= MAPINFO_FEATURE_WEAPONS;
1346         return req;
1347 }
1348
1349 Gametype MapInfo_CurrentGametype()
1350 {
1351         Gametype prev = REGISTRY_GET(Gametypes, cvar("gamecfg"));
1352         FOREACH(Gametypes, cvar(it.netname) && it != prev, return it);
1353         return prev ? prev : MAPINFO_TYPE_DEATHMATCH;
1354 }
1355
1356 float _MapInfo_CheckMap(string s, bool gametype_only) // returns 0 if the map can't be played with the current settings, 1 otherwise
1357 {
1358         if(!MapInfo_Get_ByName(s, 1, NULL))
1359                 return 0;
1360         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype().m_flags) == 0)
1361                 return 0;
1362         if (gametype_only)
1363                 return 1;
1364         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1365                 return 0;
1366         return 1;
1367 }
1368
1369 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1370 {
1371         float r;
1372         r = _MapInfo_CheckMap(s, false);
1373         MapInfo_ClearTemps();
1374         return r;
1375 }
1376
1377 void MapInfo_SwitchGameType(Gametype t)
1378 {
1379         FOREACH(Gametypes, true, cvar_set(it.netname, (it == t) ? "1" : "0"));
1380 }
1381
1382 void MapInfo_LoadMap(string s, float reinit)
1383 {
1384         MapInfo_Map_supportedGametypes = 0;
1385         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1386         //if(!MapInfo_CheckMap(s))
1387         //{
1388         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1389         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH.m_flags);
1390         //}
1391
1392         LOG_INFO("Switching to map ", s);
1393
1394         cvar_settemp_restore();
1395         if(reinit)
1396                 localcmd(strcat("\nmap ", s, "\n"));
1397         else
1398                 localcmd(strcat("\nchangelevel ", s, "\n"));
1399 }
1400
1401 string MapInfo_ListAllowedMaps(Gametype type, float pRequiredFlags, float pForbiddenFlags)
1402 {
1403         string out;
1404
1405         // to make absolutely sure:
1406         MapInfo_Enumerate();
1407         MapInfo_FilterGametype(type, MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1408
1409         out = "";
1410         for(float i = 0; i < MapInfo_count; ++i)
1411                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1412         return substring(out, 1, strlen(out) - 1);
1413 }
1414
1415 string MapInfo_ListAllAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1416 {
1417         string out;
1418
1419         // to make absolutely sure:
1420         MapInfo_Enumerate();
1421         _MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, pRequiredFlags, pForbiddenFlags, 0);
1422
1423         out = "";
1424         for(float i = 0; i < MapInfo_count; ++i)
1425                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1426
1427         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1428
1429         return substring(out, 1, strlen(out) - 1);
1430 }
1431
1432 void MapInfo_LoadMapSettings_SaveGameType(Gametype t)
1433 {
1434         MapInfo_SwitchGameType(t);
1435         cvar_set("gamecfg", ftos(t.m_id));
1436         MapInfo_LoadedGametype = t;
1437 }
1438
1439 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1440 {
1441         Gametype t = MapInfo_CurrentGametype();
1442         MapInfo_LoadMapSettings_SaveGameType(t);
1443
1444         if(!_MapInfo_CheckMap(s, true)) // with underscore, it keeps temps
1445         {
1446                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1447                 {
1448                         LOG_SEVERE("can't play the selected map in the given game mode. Working with only the override settings.");
1449                         _MapInfo_Map_ApplyGametypeEx("", t, t);
1450                         return; // do not call Get_ByName!
1451                 }
1452
1453                 if(MapInfo_Map_supportedGametypes == 0)
1454                 {
1455                         LOG_SEVERE("Mapinfo system is not functional at all. Assuming deathmatch.");
1456                         MapInfo_Map_supportedGametypes = MAPINFO_TYPE_DEATHMATCH.m_flags;
1457                         MapInfo_LoadMapSettings_SaveGameType(MAPINFO_TYPE_DEATHMATCH);
1458                         _MapInfo_Map_ApplyGametypeEx("", MAPINFO_TYPE_DEATHMATCH, MAPINFO_TYPE_DEATHMATCH);
1459                         return; // do not call Get_ByName!
1460                 }
1461
1462                 int _t = 1;
1463                 while(!(MapInfo_Map_supportedGametypes & 1))
1464                 {
1465                         _t <<= 1;
1466                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes >> 1);
1467                 }
1468                 Gametype t_prev = t;
1469                 FOREACH(Gametypes, it.m_flags == _t, { t = it; break; });
1470
1471                 // t is now a supported mode!
1472                 LOG_WARNF("can't play the selected map in the given game mode (%s). Falling back to a supported mode (%s).", t_prev.mdl, t.mdl);
1473                 MapInfo_LoadMapSettings_SaveGameType(t);
1474         }
1475         if(!_MapInfo_CheckMap(s, false)) { // with underscore, it keeps temps
1476                 LOG_WARNF("the selected map lacks features required by current settings; playing anyway.");
1477         }
1478         MapInfo_Get_ByName(s, 1, t);
1479 }
1480
1481 void MapInfo_ClearTemps()
1482 {
1483         MapInfo_Map_bspname = string_null;
1484         MapInfo_Map_title = string_null;
1485         MapInfo_Map_titlestring = string_null;
1486         MapInfo_Map_description = string_null;
1487         MapInfo_Map_author = string_null;
1488         MapInfo_Map_clientstuff = string_null;
1489         MapInfo_Map_supportedGametypes = 0;
1490         MapInfo_Map_supportedFeatures = 0;
1491 }
1492
1493 void MapInfo_Shutdown()
1494 {
1495         MapInfo_ClearTemps();
1496         MapInfo_Filter_Free();
1497         MapInfo_Cache_Destroy();
1498         if(_MapInfo_globopen)
1499         {
1500                 search_end(_MapInfo_globhandle);
1501                 _MapInfo_globhandle = -1;
1502                 _MapInfo_globopen = false;
1503         }
1504 }
1505
1506 int MapInfo_ForbiddenFlags()
1507 {
1508         int f = MAPINFO_FLAG_FORBIDDEN;
1509
1510 #ifdef GAMEQC
1511         if (!cvar("g_maplist_allow_hidden"))
1512 #endif
1513                 f |= MAPINFO_FLAG_HIDDEN;
1514
1515         if (!cvar("g_maplist_allow_frustrating"))
1516                 f |= MAPINFO_FLAG_FRUSTRATING;
1517
1518         return f;
1519 }
1520
1521 int MapInfo_RequiredFlags()
1522 {
1523         int f = 0;
1524
1525         if(cvar("g_maplist_allow_frustrating") > 1)
1526                 f |= MAPINFO_FLAG_FRUSTRATING;
1527
1528         return f;
1529 }