qcsrc/common/mapinfo.qc

   1 #if defined(CSQC)
   2     #include "../client/defs.qh"
   3     #include "util.qh"
   4     #include "buffs/all.qh"
   5     #include "weapons/all.qh"
   6     #include "mapinfo.qh"
   7 #elif defined(MENUQC)
   8 #elif defined(SVQC)
   9     #include "util.qh"
  10     #include "buffs/all.qh"
  11     #include "monsters/all.qh"
  12     #include "mapinfo.qh"
  13 #endif
  14
  15 // generic string stuff
  16
  17 int _MapInfo_Cache_Active;
  18 int _MapInfo_Cache_DB_NameToIndex;
  19 int _MapInfo_Cache_Buf_IndexToMapData;
  20
  21 void MapInfo_Cache_Destroy()
  22 {
  23         if(!_MapInfo_Cache_Active)
  24                 return;
  25
  26         db_close(_MapInfo_Cache_DB_NameToIndex);
  27         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  28         _MapInfo_Cache_Active = 0;
  29 }
  30
  31 void MapInfo_Cache_Create()
  32 {
  33         MapInfo_Cache_Destroy();
  34         _MapInfo_Cache_DB_NameToIndex = db_create();
  35         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  36         _MapInfo_Cache_Active = 1;
  37 }
  38
  39 void MapInfo_Cache_Invalidate()
  40 {
  41         if(!_MapInfo_Cache_Active)
  42                 return;
  43
  44         MapInfo_Cache_Create();
  45 }
  46
  47 void MapInfo_Cache_Store()
  48 {
  49         float i;
  50         string s;
  51         if(!_MapInfo_Cache_Active)
  52                 return;
  53
  54         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  55         if(s == "")
  56         {
  57                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
  58                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
  59         }
  60         else
  61                 i = stof(s);
  62
  63         // now store all the stuff
  64         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
  65         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
  66         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_titlestring);
  67         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
  68         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
  69         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
  70         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
  71         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
  72 }
  73
  74 float MapInfo_Cache_Retrieve(string map)
  75 {
  76         float i;
  77         string s;
  78         if(!_MapInfo_Cache_Active)
  79                 return 0;
  80
  81         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
  82         if(s == "")
  83                 return 0;
  84         i = stof(s);
  85
  86         // now retrieve all the stuff
  87         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
  88         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  89         MapInfo_Map_titlestring = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  90         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  91         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  92         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  93         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  94         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  95
  96         return 1;
  97 }
  98
  99 // GLOB HANDLING (for all BSP files)
 100 float _MapInfo_globopen;
 101 float _MapInfo_globcount;
 102 float _MapInfo_globhandle;
 103 string _MapInfo_GlobItem(float i)
 104 {
 105         string s;
 106         if(!_MapInfo_globopen)
 107                 return string_null;
 108         s = search_getfilename(_MapInfo_globhandle, i);
 109         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
 110 }
 111
 112 void MapInfo_Enumerate()
 113 {
 114         if(_MapInfo_globopen)
 115         {
 116                 search_end(_MapInfo_globhandle);
 117                 _MapInfo_globopen = 0;
 118         }
 119         MapInfo_Cache_Invalidate();
 120         _MapInfo_globhandle = search_begin("maps/*.bsp", true, true);
 121         if(_MapInfo_globhandle >= 0)
 122         {
 123                 _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 124                 _MapInfo_globopen = 1;
 125         }
 126         else
 127                 _MapInfo_globcount = 0;
 128 }
 129
 130 // filter the info by game type mask (updates MapInfo_count)
 131 //
 132 float _MapInfo_filtered;
 133 float _MapInfo_filtered_allocated;
 134 float MapInfo_FilterList_Lookup(float i)
 135 {
 136         return stof(bufstr_get(_MapInfo_filtered, i));
 137 }
 138
 139 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 140 {
 141         string h;
 142         h = bufstr_get(_MapInfo_filtered, i);
 143         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 144         bufstr_set(_MapInfo_filtered, j, h);
 145 }
 146
 147 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 148 {
 149         string a, b;
 150         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 151         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 152         return strcasecmp(a, b);
 153 }
 154
 155 float MapInfo_FilterGametype(int pGametype, int pFeatures, int pFlagsRequired, int pFlagsForbidden, bool pAbortOnGenerate)
 156 {
 157         float i, j;
 158         if (!_MapInfo_filtered_allocated)
 159         {
 160                 _MapInfo_filtered_allocated = 1;
 161                 _MapInfo_filtered = buf_create();
 162         }
 163         MapInfo_count = 0;
 164         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 165         {
 166                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 167                         if(pAbortOnGenerate)
 168                         {
 169                                 LOG_TRACE("Autogenerated a .mapinfo, doing the rest later.\n");
 170                                 MapInfo_progress = i / _MapInfo_globcount;
 171                                 return 0;
 172                         }
 173                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 174                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 175                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 176                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 177                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 178         }
 179         MapInfo_count = j + 1;
 180         MapInfo_ClearTemps();
 181
 182         // sometimes the glob isn't sorted nicely, so fix it here...
 183         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, world);
 184
 185         return 1;
 186 }
 187 void MapInfo_FilterString(string sf)
 188 {
 189         // this function further filters _MapInfo_filtered, which is prepared by MapInfo_FilterGametype by string
 190         float i, j;
 191         string title;
 192
 193         for(i = 0, j = -1; i < MapInfo_count; ++i)
 194         {
 195                 if (MapInfo_Get_ByID(i))
 196                 {
 197                         // prepare for keyword filter
 198                         if (MapInfo_Map_title && strstrofs(MapInfo_Map_title, "<TITLE>", 0) == -1)
 199                                 title = MapInfo_Map_title;
 200                         else
 201                                 title = MapInfo_Map_bspname;
 202                         // keyword filter
 203                         if((strstrofs(strtolower(title), strtolower(sf), 0)) >= 0)
 204                                 bufstr_set(_MapInfo_filtered, ++j, bufstr_get(_MapInfo_filtered, i));
 205                 }
 206         }
 207         MapInfo_count = j + 1;
 208         MapInfo_ClearTemps();
 209
 210         // sometimes the glob isn't sorted nicely, so fix it here...
 211         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, world);
 212 }
 213
 214 void MapInfo_Filter_Free()
 215 {
 216         if(_MapInfo_filtered_allocated)
 217         {
 218                 buf_del(_MapInfo_filtered);
 219                 _MapInfo_filtered_allocated = 0;
 220         }
 221 }
 222
 223 // load info about the i-th map into the MapInfo_Map_* globals
 224 string MapInfo_BSPName_ByID(float i)
 225 {
 226         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 227 }
 228
 229 string unquote(string s)
 230 {
 231         float i, j, l;
 232         l = strlen(s);
 233         j = -1;
 234         for(i = 0; i < l; ++i)
 235         {
 236                 string ch;
 237                 ch = substring(s, i, 1);
 238                 if(ch != " ") if(ch != "\"")
 239                 {
 240                         for(j = strlen(s) - i - 1; j > 0; --j)
 241                         {
 242                                 ch = substring(s, i+j, 1);
 243                                 if(ch != " ") if(ch != "\"")
 244                                         return substring(s, i, j+1);
 245                         }
 246                         return substring(s, i, 1);
 247                 }
 248         }
 249         return "";
 250 }
 251
 252 float MapInfo_Get_ByID(float i)
 253 {
 254         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
 255                 return 1;
 256         return 0;
 257 }
 258
 259 string _MapInfo_Map_worldspawn_music;
 260
 261 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 262 {
 263         string fn;
 264         float fh;
 265         string s, k, v;
 266         vector o;
 267         float i;
 268         float inWorldspawn;
 269         float r;
 270         float twoBaseModes;
 271         float diameter, spawnpoints;
 272         float spawnplaces;
 273
 274         vector mapMins, mapMaxs;
 275
 276         r = 1;
 277         fn = strcat("maps/", pFilename, ".ent");
 278         fh = fopen(fn, FILE_READ);
 279         if(fh < 0)
 280         {
 281                 r = 2;
 282                 fn = strcat("maps/", pFilename, ".bsp");
 283                 fh = fopen(fn, FILE_READ);
 284         }
 285         if(fh < 0)
 286                 return 0;
 287         LOG_INFO("Analyzing ", fn, " to generate initial mapinfo\n");
 288
 289         inWorldspawn = 2;
 290         MapInfo_Map_flags = 0;
 291         MapInfo_Map_supportedGametypes = 0;
 292         spawnpoints = 0;
 293         spawnplaces = 0;
 294         _MapInfo_Map_worldspawn_music = "";
 295         mapMins = '0 0 0';
 296         mapMaxs = '0 0 0';
 297
 298         for (;;)
 299         {
 300                 if (!((s = fgets(fh))))
 301                         break;
 302                 if(inWorldspawn == 1)
 303                         if(startsWith(s, "}"))
 304                                 inWorldspawn = 0;
 305                 k = unquote(car(s));
 306                 v = unquote(cdr(s));
 307                 if(inWorldspawn)
 308                 {
 309                         if(k == "classname" && v == "worldspawn")
 310                                 inWorldspawn = 1;
 311                         else if(k == "author")
 312                                 MapInfo_Map_author = v;
 313                         else if(k == "_description")
 314                                 MapInfo_Map_description = v;
 315                         else if(k == "music")
 316                                 _MapInfo_Map_worldspawn_music = v;
 317                         else if(k == "noise")
 318                                 _MapInfo_Map_worldspawn_music = v;
 319                         else if(k == "message")
 320                         {
 321                                 i = strstrofs(v, " by ", 0);
 322                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 323                                 {
 324                                         MapInfo_Map_title = substring(v, 0, i);
 325                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 326                                 }
 327                                 else
 328                                         MapInfo_Map_title = v;
 329                         }
 330                 }
 331                 else
 332                 {
 333                         if(k == "origin")
 334                         {
 335                                 o = stov(strcat("'", v, "'"));
 336                                 mapMins.x = min(mapMins.x, o.x);
 337                                 mapMins.y = min(mapMins.y, o.y);
 338                                 mapMins.z = min(mapMins.z, o.z);
 339                                 mapMaxs.x = max(mapMaxs.x, o.x);
 340                                 mapMaxs.y = max(mapMaxs.y, o.y);
 341                                 mapMaxs.z = max(mapMaxs.z, o.z);
 342                         }
 343                         else if(k == "race_place")
 344                         {
 345                                 if(stof(v) > 0)
 346                                         spawnplaces = 1;
 347                         }
 348                         else if(k == "classname")
 349                         {
 350                                 if(v == "dom_controlpoint")
 351                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
 352                                 else if(v == "item_flag_team2")
 353                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 354                                 else if(v == "team_CTF_blueflag")
 355                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 356                                 else if(v == "invasion_spawnpoint")
 357                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_INVASION;
 358                                 else if(v == "target_assault_roundend")
 359                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
 360                                 else if(v == "onslaught_generator")
 361                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
 362                                 else if(substring(v, 0, 8) == "nexball_" || substring(v, 0, 4) == "ball")
 363                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_NEXBALL;
 364                                 else if(v == "info_player_team1")
 365                                         ++spawnpoints;
 366                                 else if(v == "info_player_team2")
 367                                         ++spawnpoints;
 368                                 else if(v == "info_player_start")
 369                                         ++spawnpoints;
 370                                 else if(v == "info_player_deathmatch")
 371                                         ++spawnpoints;
 372                                 else if(v == "trigger_race_checkpoint")
 373                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RACE;
 374                                 else if(v == "target_startTimer")
 375                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 376                                 else if(v == "weapon_nex")
 377                                         { }
 378                                 else if(v == "weapon_railgun")
 379                                         { }
 380                                 else if(startsWith(v, "weapon_"))
 381                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 382                                 else if(startsWith(v, "turret_"))
 383                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 384                                 else if(startsWith(v, "vehicle_"))
 385                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 386                                 else if(startsWith(v, "monster_"))
 387                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
 388                                 else if(v == "target_music" || v == "trigger_music")
 389                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
 390                         }
 391                 }
 392         }
 393         if(inWorldspawn)
 394         {
 395                 LOG_INFO(fn, " ended still in worldspawn, BUG\n");
 396                 return 0;
 397         }
 398         diameter = vlen(mapMaxs - mapMins);
 399
 400         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT | MAPINFO_TYPE_RACE | MAPINFO_TYPE_NEXBALL);
 401         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
 402         {
 403                 // we have a CTF-only or Assault-only map. Don't add other modes then,
 404                 // as the map is too symmetric for them.
 405         }
 406         else
 407         {
 408                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
 409                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
 410                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEEPAWAY;                // Keepaway always works
 411
 412                 if(spawnpoints >= 8  && diameter > 4096) {
 413                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
 414                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_FREEZETAG;
 415                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CA;
 416                 }
 417                 if(spawnpoints >= 12 && diameter > 5120)
 418                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
 419         }
 420
 421         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)
 422         if(!spawnplaces)
 423         {
 424                 MapInfo_Map_supportedGametypes &= ~MAPINFO_TYPE_RACE;
 425                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 426         }
 427
 428         LOG_TRACE("-> diameter ",    ftos(diameter));
 429         LOG_TRACE(";  spawnpoints ", ftos(spawnpoints));
 430         LOG_TRACE(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
 431
 432         fclose(fh);
 433
 434         return r;
 435 }
 436
 437 void _MapInfo_Map_Reset()
 438 {
 439         MapInfo_Map_title = "<TITLE>";
 440         MapInfo_Map_titlestring = "<TITLE>";
 441         MapInfo_Map_description = "<DESCRIPTION>";
 442         MapInfo_Map_author = "<AUTHOR>";
 443         MapInfo_Map_supportedGametypes = 0;
 444         MapInfo_Map_supportedFeatures = 0;
 445         MapInfo_Map_flags = 0;
 446         MapInfo_Map_clientstuff = "";
 447         MapInfo_Map_fog = "";
 448         MapInfo_Map_mins = '0 0 0';
 449         MapInfo_Map_maxs = '0 0 0';
 450 }
 451
 452 string _MapInfo_GetDefault(float t)
 453 {
 454         switch(t)
 455         {
 456                 case MAPINFO_TYPE_DEATHMATCH:      return "30 20 0";
 457                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "50 20 2 0";
 458                 case MAPINFO_TYPE_DOMINATION:      return "200 20 0";
 459                 case MAPINFO_TYPE_CTF:             return "300 20 10 0";
 460                 case MAPINFO_TYPE_LMS:             return "9 20 0";
 461                 case MAPINFO_TYPE_CA:              return "10 20 0";
 462                 case MAPINFO_TYPE_KEYHUNT:         return "1000 20 3 0";
 463                 case MAPINFO_TYPE_ASSAULT:         return "20 0";
 464                 case MAPINFO_TYPE_RACE:            return "20 5 7 15 0";
 465                 case MAPINFO_TYPE_ONSLAUGHT:       return "20 0";
 466                 case MAPINFO_TYPE_NEXBALL:         return "5 20 0";
 467                 case MAPINFO_TYPE_CTS:             return "20 0 0";
 468                 case MAPINFO_TYPE_FREEZETAG:       return "10 20 0";
 469                 // NOTE: DO NOT ADD ANY MORE GAME TYPES HERE
 470                 // THIS IS JUST LEGACY SUPPORT FOR NEXUIZ MAPS
 471                 // ONLY ADD NEW STUFF TO _MapInfo_GetDefaultEx
 472                 // THIS FUNCTION WILL EVENTUALLY BE REMOVED
 473                 default:                           return "";
 474         }
 475 }
 476
 477 void _MapInfo_Map_ApplyGametype(string s, int pWantedType, int pThisType, int load_default)
 478 {
 479         string sa;
 480         MapInfo_Map_supportedGametypes |= pThisType;
 481         if(!(pThisType & pWantedType))
 482                 return;
 483
 484         if(load_default)
 485                 _MapInfo_Map_ApplyGametype(_MapInfo_GetDefault(pThisType), pWantedType, pThisType, false);
 486
 487         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_RACE || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 488         {
 489                 cvar_set("fraglimit", "0");
 490         }
 491         else
 492         {
 493                 sa = car(s);
 494                 if(sa != "")
 495                         cvar_set("fraglimit", sa);
 496                 s = cdr(s);
 497         }
 498
 499         sa = car(s);
 500         if(sa != "")
 501                 cvar_set("timelimit", sa);
 502         s = cdr(s);
 503
 504         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
 505         {
 506                 sa = car(s);
 507                 if(sa != "")
 508                         cvar_set("g_tdm_teams", sa);
 509                 s = cdr(s);
 510         }
 511
 512         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
 513         {
 514                 sa = car(s);
 515                 if(sa != "")
 516                         cvar_set("g_keyhunt_teams", sa);
 517                 s = cdr(s);
 518         }
 519
 520         if(pWantedType == MAPINFO_TYPE_CA)
 521         {
 522                 sa = car(s);
 523                 if(sa != "")
 524                         cvar_set("g_ca_teams", sa);
 525                 s = cdr(s);
 526         }
 527
 528         if(pWantedType == MAPINFO_TYPE_FREEZETAG)
 529         {
 530                 sa = car(s);
 531                 if(sa != "")
 532                         cvar_set("g_freezetag_teams", sa);
 533                 s = cdr(s);
 534         }
 535
 536         if(pWantedType == MAPINFO_TYPE_CTF)
 537         {
 538                 sa = car(s);
 539                 if(sa != "")
 540                         cvar_set("fraglimit", sa);
 541                 s = cdr(s);
 542         }
 543
 544         /* keepaway wuz here
 545         if(pWantedType == MAPINFO_TYPE_KEEPAWAY)
 546         {
 547                 sa = car(s);
 548                 if(sa != "")
 549                         cvar_set("fraglimit", sa);
 550                 s = cdr(s);
 551         }
 552         */
 553
 554         // rc = timelimit timelimit_qualification laps laps_teamplay
 555         if(pWantedType == MAPINFO_TYPE_RACE)
 556         {
 557                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 558                 cvar_set("g_race_qualifying_timelimit", sa);
 559                 s = cdr(s);
 560
 561                 sa = car(s);
 562                 if(sa != "")
 563                         if(cvar("g_race_teams") < 2)
 564                                 cvar_set("fraglimit", sa);
 565                 s = cdr(s);
 566
 567                 sa = car(s);
 568                 if(sa != "")
 569                         if(cvar("g_race_teams") >= 2)
 570                                 cvar_set("fraglimit", sa);
 571                 s = cdr(s);
 572         }
 573
 574         if(pWantedType == MAPINFO_TYPE_CTS)
 575         {
 576                 sa = car(s);
 577
 578                 // this is the skill of the map
 579                 // not parsed by anything yet
 580                 // for map databases
 581                 //if(sa != "")
 582                 //      cvar_set("fraglimit", sa);
 583
 584                 s = cdr(s);
 585         }
 586
 587         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 588         {
 589                 cvar_set("leadlimit", "0");
 590         }
 591         else
 592         {
 593                 sa = car(s);
 594                 if(sa != "")
 595                         cvar_set("leadlimit", sa);
 596                 s = cdr(s);
 597         }
 598 }
 599
 600 string _MapInfo_GetDefaultEx(float t)
 601 {
 602         FOREACH(Gametypes, it.items == t, LAMBDA(return it.model2));
 603         return "";
 604 }
 605
 606 float _MapInfo_GetTeamPlayBool(float t)
 607 {
 608         FOREACH(Gametypes, it.items == t, LAMBDA(return it.team));
 609         return false;
 610 }
 611
 612 void _MapInfo_Map_ApplyGametypeEx(string s, int pWantedType, int pThisType)
 613 {
 614         MapInfo_Map_supportedGametypes |= pThisType;
 615         if (!(pThisType & pWantedType))
 616                 return;
 617
 618         // reset all the cvars to their defaults
 619
 620         cvar_set("timelimit", cvar_defstring("timelimit"));
 621         cvar_set("leadlimit", cvar_defstring("leadlimit"));
 622         cvar_set("fraglimit", cvar_defstring("fraglimit"));
 623         FOREACH(Gametypes, true, LAMBDA(it.m_parse_mapinfo(string_null, string_null)));
 624
 625         string fraglimit_normal = string_null;
 626         string fraglimit_teams = string_null;
 627
 628         for (s = strcat(_MapInfo_GetDefaultEx(pWantedType), " ", s); s != ""; s = cdr(s)) {
 629                 string sa = car(s);
 630                 if (sa == "") continue;
 631                 int p = strstrofs(sa, "=", 0);
 632                 if (p < 0) {
 633                         LOG_WARNINGF("Invalid gametype setting in mapinfo for gametype %s: %s\n", MapInfo_Type_ToString(pWantedType), sa);
 634                         continue;
 635                 }
 636                 string k = substring(sa, 0, p);
 637                 string v = substring(sa, p + 1, -1);
 638                 bool handled = true;
 639                 switch (k) {
 640                         case "timelimit":
 641                         {
 642                                 cvar_set("timelimit", v);
 643                                 break;
 644                         }
 645                         case "leadlimit":
 646                         {
 647                                 cvar_set("leadlimit", v);
 648                                 break;
 649                         }
 650                         case "pointlimit":
 651                         case "fraglimit":
 652                         case "lives":
 653                         case "laplimit":
 654                         case "caplimit":
 655                         {
 656                                 fraglimit_normal = v;
 657                                 break;
 658                         }
 659                         case "teampointlimit":
 660                         case "teamlaplimit":
 661                         {
 662                                 fraglimit_teams = v;
 663                                 break;
 664                         }
 665                         default:
 666                         {
 667                             handled = false;
 668                             break;
 669                         }
 670                 }
 671                 FOREACH(Gametypes, true, LAMBDA(handled |= it.m_parse_mapinfo(k, v)));
 672                 if (!handled)
 673             LOG_WARNINGF("Invalid gametype setting in mapinfo for gametype %s: %s\n", MapInfo_Type_ToString(pWantedType), sa);
 674         }
 675
 676         if (pWantedType == MAPINFO_TYPE_RACE && cvar("g_race_teams") >= 2)
 677         {
 678                 if(fraglimit_teams)
 679                         cvar_set("fraglimit", fraglimit_teams);
 680         }
 681         else
 682         {
 683                 if(fraglimit_normal)
 684                         cvar_set("fraglimit", fraglimit_normal);
 685         }
 686 }
 687
 688 int MapInfo_Type_FromString(string t)
 689 {
 690 #define deprecate(from, to) do { \
 691         if (t == #from) { \
 692                 string replacement = #to; \
 693                 LOG_WARNINGF("MapInfo_Type_FromString (probably %s): using deprecated name '%s'. Should use '%s'.\n", MapInfo_Map_bspname, t, replacement); \
 694                 t = replacement; \
 695         } \
 696 } while (0)
 697         deprecate(nexball, nb);
 698         deprecate(freezetag, ft);
 699         deprecate(keepaway, ka);
 700         deprecate(invasion, inv);
 701         deprecate(assault, as);
 702         deprecate(race, rc);
 703         if (t == "all") return MAPINFO_TYPE_ALL;
 704         FOREACH(Gametypes, it.mdl == t, LAMBDA(return it.items));
 705         return 0;
 706 #undef deprecate
 707 }
 708
 709 string MapInfo_Type_Description(float t)
 710 {
 711         FOREACH(Gametypes, it.items == t, LAMBDA(return it.gametype_description));
 712         return "";
 713 }
 714
 715 string MapInfo_Type_ToString(float t)
 716 {
 717         if(t == MAPINFO_TYPE_ALL)
 718                 return "all";
 719         FOREACH(Gametypes, it.items == t, LAMBDA(return it.mdl));
 720         return "";
 721 }
 722
 723 string MapInfo_Type_ToText(float t)
 724 {
 725         FOREACH(Gametypes, it.items == t, LAMBDA(return it.message));
 726         /* xgettext:no-c-format */
 727         return _("@!#%'n Tuba Throwing");
 728 }
 729
 730 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 731 {
 732         string t;
 733         float fh, o;
 734         t = car(s); s = cdr(s);
 735
 736         // limited support of "" and comments
 737         //   remove trailing and leading " of t
 738         if(substring(t, 0, 1) == "\"")
 739         {
 740                 if(substring(t, -1, 1) == "\"")
 741                         t = substring(t, 1, -2);
 742         }
 743
 744         //   remove leading " of s
 745         if(substring(s, 0, 1) == "\"")
 746         {
 747                 s = substring(s, 1, -1);
 748         }
 749         //   remove trailing " of s, and all that follows (cvar description)
 750         o = strstrofs(s, "\"", 0);
 751         if(o >= 0)
 752                 s = substring(s, 0, o);
 753
 754         //   remove // comments
 755         o = strstrofs(s, "//", 0);
 756         if(o >= 0)
 757                 s = substring(s, 0, o);
 758
 759         //   remove trailing spaces
 760         while(substring(s, -1, 1) == " ")
 761                 s = substring(s, 0, -2);
 762
 763         if(t == "#include")
 764         {
 765                 if(recurse > 0)
 766                 {
 767                         fh = fopen(s, FILE_READ);
 768                         if(fh < 0)
 769                                 LOG_INFO("Map ", pFilename, " references not existing config file ", s, "\n");
 770                         else
 771                         {
 772                                 for (;;)
 773                                 {
 774                                         if (!((s = fgets(fh))))
 775                                                 break;
 776
 777                                         // catch different sorts of comments
 778                                         if(s == "")                    // empty lines
 779                                                 continue;
 780                                         if(substring(s, 0, 1) == "#")  // UNIX style
 781                                                 continue;
 782                                         if(substring(s, 0, 2) == "//") // C++ style
 783                                                 continue;
 784                                         if(substring(s, 0, 1) == "_")  // q3map style
 785                                                 continue;
 786
 787                                         if(substring(s, 0, 4) == "set ")
 788                                                 s = substring(s, 4, -1);
 789                                         if(substring(s, 0, 5) == "seta ")
 790                                                 s = substring(s, 5, -1);
 791
 792                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 793                                 }
 794                                 fclose(fh);
 795                         }
 796                 }
 797                 else
 798                         LOG_INFO("Map ", pFilename, " uses too many levels of inclusion\n");
 799         }
 800         else if(t == "")
 801                 LOG_INFO("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 802         else if (!cvar_value_issafe(t))
 803                 LOG_INFO("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 804         else if (!cvar_value_issafe(s))
 805                 LOG_INFO("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 806         else if(matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
 807                 LOG_INFO("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 808         else if(matchacl(acl, t) <= 0)
 809                 LOG_INFO("Map ", pFilename, " contains a denied setting, ignored\n");
 810         else
 811         {
 812                 if(type == 0) // server set
 813                 {
 814                         LOG_TRACE("Applying temporary setting ", t, " := ", s, "\n");
 815                         if(cvar("g_campaign"))
 816                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 817                         else
 818                                 cvar_settemp(t, s);
 819                 }
 820                 else
 821                 {
 822                         LOG_TRACE("Applying temporary client setting ", t, " := ", s, "\n");
 823                         MapInfo_Map_clientstuff = strcat(
 824                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 825                                         );
 826                 }
 827         }
 828 }
 829
 830 float MapInfo_isRedundant(string fn, string t)
 831 {
 832         // normalize file name
 833         fn = strreplace("_", "-", fn);
 834
 835         // normalize visible title
 836         t = strreplace(": ", "-", t);
 837         t = strreplace(":", "-", t);
 838         t = strreplace(" ", "-", t);
 839         t = strreplace("_", "-", t);
 840         t = strreplace("'", "-", t);
 841
 842         if(!strcasecmp(fn, t))
 843                 return true;
 844
 845         // we allow the visible title to have punctuation the file name does
 846         // not, but not vice versa
 847         t = strreplace("-", "", t);
 848
 849         if(!strcasecmp(fn, t))
 850                 return true;
 851
 852         return false;
 853 }
 854
 855 // load info about a map by name into the MapInfo_Map_* globals
 856 float MapInfo_Get_ByName_NoFallbacks(string pFilename, int pAllowGenerate, int pGametypeToSet)
 857 {
 858         string fn;
 859         string s, t;
 860         float fh;
 861         int f, i;
 862         float r, n, p;
 863         string acl;
 864
 865         acl = MAPINFO_SETTEMP_ACL_USER;
 866
 867         if(strstrofs(pFilename, "/", 0) >= 0)
 868         {
 869                 LOG_INFO("Invalid character in map name, ignored\n");
 870                 return 0;
 871         }
 872
 873         if(pGametypeToSet == 0)
 874                 if(MapInfo_Cache_Retrieve(pFilename))
 875                         return 1;
 876
 877         r = 1;
 878
 879         MapInfo_Map_bspname = pFilename;
 880
 881         // default all generic fields so they have "good" values in case something fails
 882         fn = strcat("maps/", pFilename, ".mapinfo");
 883         fh = fopen(fn, FILE_READ);
 884         if(fh < 0)
 885         {
 886                 fn = strcat("maps/autogenerated/", pFilename, ".mapinfo");
 887                 fh = fopen(fn, FILE_READ);
 888                 if(fh < 0)
 889                 {
 890                         if(!pAllowGenerate)
 891                                 return 0;
 892                         _MapInfo_Map_Reset();
 893                         r = _MapInfo_Generate(pFilename);
 894                         if(!r)
 895                                 return 0;
 896                         fh = fopen(fn, FILE_WRITE);
 897                         fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 898                         fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 899                         fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 900                         if(_MapInfo_Map_worldspawn_music != "")
 901                         {
 902                                 if(
 903                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
 904                                         ||
 905                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
 906                                 )
 907                                         fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
 908                                 else
 909                                         fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
 910                         }
 911                         else
 912                         {
 913                                 n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
 914                                 s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
 915                                 for (;;)
 916                                 {
 917                                         i = floor(random() * n);
 918                                         if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
 919                                                 break;
 920                                 }
 921                                 fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
 922                         }
 923                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
 924                                 fputs(fh, "has weapons\n");
 925                         else
 926                                 fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
 927                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_TURRETS)
 928                                 fputs(fh, "has turrets\n");
 929                         else
 930                                 fputs(fh, "// uncomment this if you added turrets: has turrets\n");
 931                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_VEHICLES)
 932                                 fputs(fh, "has vehicles\n");
 933                         else
 934                                 fputs(fh, "// uncomment this if you added vehicles: has vehicles\n");
 935                         if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
 936                                 fputs(fh, "frustrating\n");
 937
 938                         for(i = 1; i <= MapInfo_Map_supportedGametypes; i *= 2)
 939                                 if(MapInfo_Map_supportedGametypes & i)
 940                                         fputs(fh, sprintf("gametype %s // defaults: %s\n", MapInfo_Type_ToString(i), _MapInfo_GetDefaultEx(i)));
 941
 942                         if(fexists(strcat("scripts/", pFilename, ".arena")))
 943                                 fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 944
 945                         fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
 946                         fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
 947                         fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
 948                         fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 949                         fputs(fh, "// optional: hidden\n");
 950
 951                         fclose(fh);
 952                         r = 2;
 953                         // return r;
 954                         fh = fopen(fn, FILE_READ);
 955                         if(fh < 0)
 956                                 error("... but I just wrote it!");
 957                 }
 958
 959                 LOG_INFO("WARNING: autogenerated mapinfo file ", fn, " has been loaded; please edit that file and move it to maps/", pFilename, ".mapinfo\n");
 960         }
 961
 962         _MapInfo_Map_Reset();
 963         for (;;)
 964         {
 965                 if (!((s = fgets(fh))))
 966                         break;
 967
 968                 // catch different sorts of comments
 969                 if(s == "")                    // empty lines
 970                         continue;
 971                 if(substring(s, 0, 1) == "#")  // UNIX style
 972                         continue;
 973                 if(substring(s, 0, 2) == "//") // C++ style
 974                         continue;
 975                 if(substring(s, 0, 1) == "_")  // q3map style
 976                         continue;
 977
 978                 p = strstrofs(s, "//", 0);
 979                 if(p >= 0)
 980                         s = substring(s, 0, p);
 981
 982                 t = car(s); s = cdr(s);
 983                 if(t == "title")
 984                         MapInfo_Map_title = s;
 985                 else if(t == "description")
 986                         MapInfo_Map_description = s;
 987                 else if(t == "author")
 988                         MapInfo_Map_author = s;
 989                 else if(t == "has")
 990                 {
 991                         t = car(s); // s = cdr(s);
 992                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 993                         else if(t == "turrets") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 994                         else if(t == "vehicles") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 995                         else if(t == "monsters") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
 996                         else if(t == "new_toys") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 997                         else
 998                                 LOG_TRACE("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
 999                 }
1000                 else if(t == "hidden")
1001                 {
1002                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
1003                 }
1004                 else if(t == "forbidden")
1005                 {
1006                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
1007                 }
1008                 else if(t == "frustrating")
1009                 {
1010                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
1011                 }
1012                 else if(t == "noautomaplist")
1013                 {
1014                         MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
1015                 }
1016                 else if(t == "type")
1017                 {
1018                         t = car(s); s = cdr(s);
1019                         f = MapInfo_Type_FromString(t);
1020                         LOG_WARNING("Map ", pFilename, " contains the legacy 'type' keyword which is deprecated and will be removed in the future. Please migrate the mapinfo file to 'gametype'.\n");
1021                         if(f)
1022                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, true);
1023                         else
1024                                 LOG_TRACE("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
1025                 }
1026                 else if(t == "gametype")
1027                 {
1028                         t = car(s); s = cdr(s);
1029                         f = MapInfo_Type_FromString(t);
1030                         if(f)
1031                                 _MapInfo_Map_ApplyGametypeEx (s, pGametypeToSet, f);
1032                         else
1033                                 LOG_TRACE("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
1034                 }
1035                 else if(t == "size")
1036                 {
1037                         float a, b, c, d, e;
1038                         t = car(s); s = cdr(s); a = stof(t);
1039                         t = car(s); s = cdr(s); b = stof(t);
1040                         t = car(s); s = cdr(s); c = stof(t);
1041                         t = car(s); s = cdr(s); d = stof(t);
1042                         t = car(s); s = cdr(s); e = stof(t);
1043                         if(s == "")
1044                                 LOG_INFO("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1045                         else
1046                         {
1047                                 t = car(s); s = cdr(s); f = stof(t);
1048                                 if(s != "")
1049                                         LOG_INFO("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1050                                 else
1051                                 {
1052                                         if(a >= d || b >= e || c >= f)
1053                                                 LOG_INFO("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs\n");
1054                                         else
1055                                         {
1056                                                 MapInfo_Map_mins.x = a;
1057                                                 MapInfo_Map_mins.y = b;
1058                                                 MapInfo_Map_mins.z = c;
1059                                                 MapInfo_Map_maxs.x = d;
1060                                                 MapInfo_Map_maxs.y = e;
1061                                                 MapInfo_Map_maxs.z = f;
1062                                         }
1063                                 }
1064                         }
1065                 }
1066                 else if(t == "settemp_for_type")
1067                 {
1068                         t = car(s); s = cdr(s);
1069                         if((f = MapInfo_Type_FromString(t)))
1070                         {
1071                                 if(f & pGametypeToSet)
1072                                 {
1073                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
1074                                 }
1075                         }
1076                         else
1077                         {
1078                                 LOG_TRACE("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
1079                         }
1080                 }
1081                 else if(t == "clientsettemp_for_type")
1082                 {
1083                         t = car(s); s = cdr(s);
1084                         if((f = MapInfo_Type_FromString(t)))
1085                         {
1086                                 if(f & pGametypeToSet)
1087                                 {
1088                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
1089                                 }
1090                         }
1091                         else
1092                         {
1093                                 LOG_TRACE("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored\n");
1094                         }
1095                 }
1096                 else if(t == "fog")
1097                 {
1098                         if (!cvar_value_issafe(s))
1099                                 LOG_INFO("Map ", pFilename, " contains a potentially harmful fog setting, ignored\n");
1100                         else
1101                                 MapInfo_Map_fog = s;
1102                 }
1103                 else if(t == "cdtrack")
1104                 {
1105                         t = car(s); s = cdr(s);
1106                         // We do this only if pGametypeToSet even though this
1107                         // content is theoretically game type independent,
1108                         // because MapInfo_Map_clientstuff contains otherwise
1109                         // game type dependent stuff. That way this value stays
1110                         // empty when not setting a game type to not set any
1111                         // false expectations.
1112                         if(pGametypeToSet)
1113                         {
1114                                 if (!cvar_value_issafe(t))
1115                                         LOG_INFO("Map ", pFilename, " contains a potentially harmful cdtrack, ignored\n");
1116                                 else
1117                                         MapInfo_Map_clientstuff = strcat(
1118                                                 MapInfo_Map_clientstuff, "cd loop \"", t, "\"\n"
1119                                         );
1120                         }
1121                 }
1122                 else
1123                         LOG_TRACE("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
1124         }
1125         fclose(fh);
1126
1127         if(MapInfo_Map_title == "<TITLE>")
1128                 MapInfo_Map_titlestring = MapInfo_Map_bspname;
1129         else if(MapInfo_isRedundant(MapInfo_Map_bspname, MapInfo_Map_title))
1130                 MapInfo_Map_titlestring = MapInfo_Map_title;
1131         else
1132                 MapInfo_Map_titlestring = sprintf("%s: %s", MapInfo_Map_bspname, MapInfo_Map_title);
1133
1134         MapInfo_Cache_Store();
1135         if(MapInfo_Map_supportedGametypes != 0)
1136                 return r;
1137         LOG_TRACE("Map ", pFilename, " supports no game types, ignored\n");
1138         return 0;
1139 }
1140 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, int pGametypeToSet)
1141 {
1142         float r = MapInfo_Get_ByName_NoFallbacks(pFilename, pAllowGenerate, pGametypeToSet);
1143
1144         if(cvar("g_tdm_on_dm_maps"))
1145         {
1146                 // if this is set, all DM maps support TDM too
1147                 if (!(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_TEAM_DEATHMATCH))
1148                         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DEATHMATCH)
1149                                 _MapInfo_Map_ApplyGametypeEx ("", pGametypeToSet, MAPINFO_TYPE_TEAM_DEATHMATCH);
1150         }
1151
1152         if(pGametypeToSet)
1153         {
1154                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
1155                 {
1156                         error("Can't select the requested game type. This should never happen as the caller should prevent it!\n");
1157                         //_MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
1158                         //return;
1159                 }
1160         }
1161
1162         return r;
1163 }
1164
1165 float MapInfo_FindName(string s)
1166 {
1167         // if there is exactly one map of prefix s, return it
1168         // if not, return the null string
1169         // note that DP sorts glob results... so I can use a binary search
1170         float l, r, m, cmp;
1171         l = 0;
1172         r = MapInfo_count;
1173         // invariants: r is behind s, l-1 is equal or before
1174         while(l != r)
1175         {
1176                 m = floor((l + r) / 2);
1177                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
1178                 cmp = strcasecmp(MapInfo_FindName_match, s);
1179                 if(cmp == 0)
1180                         return m; // found and good
1181                 if(cmp < 0)
1182                         l = m + 1; // l-1 is before s
1183                 else
1184                         r = m; // behind s
1185         }
1186         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
1187         MapInfo_FindName_firstResult = l;
1188         // r == l, so: l is behind s, l-1 is before
1189         // SO: if there is any, l is the one with the right prefix
1190         //     and l+1 may be one too
1191         if(l == MapInfo_count)
1192         {
1193                 MapInfo_FindName_match = string_null;
1194                 MapInfo_FindName_firstResult = -1;
1195                 return -1; // no MapInfo_FindName_match, behind last item
1196         }
1197         if(!startsWithNocase(MapInfo_FindName_match, s))
1198         {
1199                 MapInfo_FindName_match = string_null;
1200                 MapInfo_FindName_firstResult = -1;
1201                 return -1; // wrong prefix
1202         }
1203         if(l == MapInfo_count - 1)
1204                 return l; // last one, nothing can follow => unique
1205         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
1206         {
1207                 MapInfo_FindName_match = string_null;
1208                 return -1; // ambigous MapInfo_FindName_match
1209         }
1210         return l;
1211 }
1212
1213 string MapInfo_FixName(string s)
1214 {
1215         MapInfo_FindName(s);
1216         return MapInfo_FindName_match;
1217 }
1218
1219 int MapInfo_CurrentFeatures()
1220 {
1221         int req = 0;
1222         if(!(cvar("g_lms") || cvar("g_instagib") || cvar("g_overkill") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items") || cvar("g_race") || cvar("g_cts") || cvar("g_nexball")))
1223                 req |= MAPINFO_FEATURE_WEAPONS;
1224         return req;
1225 }
1226
1227 int MapInfo_CurrentGametype()
1228 {
1229         int prev = cvar("gamecfg");
1230         FOREACH(Gametypes, cvar(it.netname) && it.items != prev, LAMBDA(return it.items));
1231         if (prev) return prev;
1232         return MAPINFO_TYPE_DEATHMATCH;
1233 }
1234
1235 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1236 {
1237         if(!MapInfo_Get_ByName(s, 1, 0))
1238                 return 0;
1239         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
1240                 return 0;
1241         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1242                 return 0;
1243         return 1;
1244 }
1245
1246 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1247 {
1248         float r;
1249         r = _MapInfo_CheckMap(s);
1250         MapInfo_ClearTemps();
1251         return r;
1252 }
1253
1254 void MapInfo_SwitchGameType(int t)
1255 {
1256         FOREACH(Gametypes, true, LAMBDA(
1257                 cvar_set(it.netname, (it.items == t) ? "1" : "0")
1258         ));
1259 }
1260
1261 void MapInfo_LoadMap(string s, float reinit)
1262 {
1263         MapInfo_Map_supportedGametypes = 0;
1264         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1265         //if(!MapInfo_CheckMap(s))
1266         //{
1267         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1268         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
1269         //}
1270
1271         cvar_settemp_restore();
1272         if(reinit)
1273                 localcmd(strcat("\nmap ", s, "\n"));
1274         else
1275                 localcmd(strcat("\nchangelevel ", s, "\n"));
1276 }
1277
1278 string MapInfo_ListAllowedMaps(float type, float pRequiredFlags, float pForbiddenFlags)
1279 {
1280         string out;
1281         float i;
1282
1283         // to make absolutely sure:
1284         MapInfo_Enumerate();
1285         MapInfo_FilterGametype(type, MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1286
1287         out = "";
1288         for(i = 0; i < MapInfo_count; ++i)
1289                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1290         return substring(out, 1, strlen(out) - 1);
1291 }
1292
1293 string MapInfo_ListAllAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1294 {
1295         string out;
1296         float i;
1297
1298         // to make absolutely sure:
1299         MapInfo_Enumerate();
1300         MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, pRequiredFlags, pForbiddenFlags, 0);
1301
1302         out = "";
1303         for(i = 0; i < MapInfo_count; ++i)
1304                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1305
1306         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1307
1308         return substring(out, 1, strlen(out) - 1);
1309 }
1310
1311 void MapInfo_LoadMapSettings_SaveGameType(float t)
1312 {
1313         MapInfo_SwitchGameType(t);
1314         cvar_set("gamecfg", ftos(t));
1315         MapInfo_LoadedGametype = t;
1316 }
1317
1318 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1319 {
1320         float t;
1321
1322         t = MapInfo_CurrentGametype();
1323         MapInfo_LoadMapSettings_SaveGameType(t);
1324
1325         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
1326         {
1327                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1328                 {
1329                         LOG_INFO("EMERGENCY: can't play the selected map in the given game mode. Working with only the override settings.\n");
1330                         _MapInfo_Map_ApplyGametypeEx("", t, t);
1331                         return; // do not call Get_ByName!
1332                 }
1333
1334                 if(MapInfo_Map_supportedGametypes == 0)
1335                 {
1336                         LOG_INFO("Mapinfo system is not functional at all. Assuming deathmatch.\n");
1337                         MapInfo_Map_supportedGametypes = MAPINFO_TYPE_DEATHMATCH;
1338                         MapInfo_LoadMapSettings_SaveGameType(MAPINFO_TYPE_DEATHMATCH);
1339                         _MapInfo_Map_ApplyGametypeEx("", MAPINFO_TYPE_DEATHMATCH, MAPINFO_TYPE_DEATHMATCH);
1340                         return; // do not call Get_ByName!
1341                 }
1342
1343                 t = 1;
1344                 while(!(MapInfo_Map_supportedGametypes & 1))
1345                 {
1346                         t *= 2;
1347                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
1348                 }
1349
1350                 // t is now a supported mode!
1351                 LOG_INFO("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
1352                 MapInfo_LoadMapSettings_SaveGameType(t);
1353         }
1354         MapInfo_Get_ByName(s, 1, t);
1355 }
1356
1357 void MapInfo_ClearTemps()
1358 {
1359         MapInfo_Map_bspname = string_null;
1360         MapInfo_Map_title = string_null;
1361         MapInfo_Map_titlestring = string_null;
1362         MapInfo_Map_description = string_null;
1363         MapInfo_Map_author = string_null;
1364         MapInfo_Map_clientstuff = string_null;
1365         MapInfo_Map_supportedGametypes = 0;
1366         MapInfo_Map_supportedFeatures = 0;
1367 }
1368
1369 void MapInfo_Shutdown()
1370 {
1371         MapInfo_ClearTemps();
1372         MapInfo_Filter_Free();
1373         MapInfo_Cache_Destroy();
1374         if(_MapInfo_globopen)
1375         {
1376                 search_end(_MapInfo_globhandle);
1377                 _MapInfo_globhandle = -1;
1378                 _MapInfo_globopen = false;
1379         }
1380 }
1381
1382 int MapInfo_ForbiddenFlags()
1383 {
1384         int f = MAPINFO_FLAG_FORBIDDEN;
1385
1386 #ifndef MENUQC
1387         if (!cvar("g_maplist_allow_hidden"))
1388 #endif
1389                 f |= MAPINFO_FLAG_HIDDEN;
1390
1391         if (!cvar("g_maplist_allow_frustrating"))
1392                 f |= MAPINFO_FLAG_FRUSTRATING;
1393
1394         return f;
1395 }
1396
1397 int MapInfo_RequiredFlags()
1398 {
1399         int f = 0;
1400
1401         if(cvar("g_maplist_allow_frustrating") > 1)
1402                 f |= MAPINFO_FLAG_FRUSTRATING;
1403
1404         return f;
1405 }