qcsrc/common/items/inventory.qh

   1 #pragma once
   2
   3 #include "all.qh"
   4
   5 #ifdef GAMEQC
   6 CLASS(Inventory, Object)
   7     /** Stores counts of items, the id being the index */
   8     ATTRIBARRAY(Inventory, inv_items, int, Items_MAX);
   9 ENDCLASS(Inventory)
  10
  11 /** Player inventory */
  12 .Inventory inventory;
  13 /** Player inventory storage (holds previous state) */
  14 .Inventory inventory_store;
  15
  16 REGISTER_NET_LINKED(ENT_CLIENT_INVENTORY)
  17
  18 const int Inventory_groups_major = 16;
  19 const int Inventory_groups_minor = 8; // ceil(Items_MAX / Inventory_groups_major)
  20
  21 #define G_MAJOR(id) (floor((id) / Inventory_groups_minor))
  22 #define G_MINOR(id) ((id) % Inventory_groups_minor)
  23 #endif
  24
  25 #ifdef CSQC
  26 Inventory g_inventory;
  27 NET_HANDLE(ENT_CLIENT_INVENTORY, bool isnew)
  28 {
  29     make_pure(this);
  30     g_inventory = this;
  31     const int majorBits = ReadShort();
  32     for (int i = 0; i < Inventory_groups_major; ++i) {
  33         if (!(majorBits & BIT(i))) {
  34             continue;
  35         }
  36         const int minorBits = ReadByte();
  37         for (int j = 0; j < Inventory_groups_minor; ++j) {
  38             if (!(minorBits & BIT(j))) {
  39                 continue;
  40             }
  41             const GameItem it = Items_from(Inventory_groups_minor * i + j);
  42             .int fld = inv_items[it.m_id];
  43             int prev = this.(fld);
  44             int next = this.(fld) = ReadByte();
  45             LOG_TRACEF("%s: %.0f -> %.0f", it.m_name, prev, next);
  46         }
  47     }
  48     return true;
  49 }
  50 #endif
  51
  52 #ifdef SVQC
  53 int minorBitsArr[Inventory_groups_major];
  54 void Inventory_Write(Inventory data, Inventory store)
  55 {
  56     if (!data) {
  57         WriteShort(MSG_ENTITY, 0);
  58         return;
  59     }
  60     TC(Inventory, data);
  61
  62         for (int i = 0; i < Inventory_groups_major; ++i)
  63                 minorBitsArr[i] = 0;
  64
  65     int majorBits = 0;
  66     FOREACH(Items, true, {
  67         .int fld = inv_items[it.m_id];
  68         const bool changed = store.(fld) != data.(fld);
  69         store.(fld) = data.(fld);
  70         if (changed) {
  71                         int maj = G_MAJOR(it.m_id);
  72                         majorBits = BITSET(majorBits, BIT(maj), true);
  73                         minorBitsArr[maj] = BITSET(minorBitsArr[maj], BIT(G_MINOR(it.m_id)), true);
  74         }
  75     });
  76     WriteShort(MSG_ENTITY, majorBits);
  77
  78         for (int i = 0; i < Inventory_groups_major; ++i)
  79         {
  80                 if (!(majorBits & BIT(i)))
  81                         continue;
  82
  83                 const int minorBits = minorBitsArr[i];
  84                 WriteByte(MSG_ENTITY, minorBits);
  85                 for (int j = 0; j < Inventory_groups_minor; ++j)
  86                 {
  87                         if (!(minorBits & BIT(j)))
  88                                 continue;
  89
  90                         const entity it = Items_from(Inventory_groups_minor * i + j);
  91                         WriteByte(MSG_ENTITY, data.inv_items[it.m_id]);
  92                 }
  93         }
  94 }
  95 #endif
  96
  97 #undef G_MAJOR
  98 #undef G_MINOR
  99
 100 #ifdef SVQC
 101 bool Inventory_Send(Inventory this, Client to, int sf)
 102 {
 103     TC(Inventory, this);
 104     WriteHeader(MSG_ENTITY, ENT_CLIENT_INVENTORY);
 105     TC(PlayerState, this.owner);
 106     Inventory_Write(this, to.inventory_store);
 107     return true;
 108 }
 109
 110 bool Inventory_customize(entity this, entity client)
 111 {
 112     // sends to spectators too!
 113     return (PS(client) && PS(client).inventory == this);
 114 }
 115
 116 void Inventory_new(PlayerState this)
 117 {
 118     Inventory inv = NEW(Inventory);
 119     setcefc(inv, Inventory_customize);
 120     Net_LinkEntity((inv.owner = this).inventory = inv, false, 0, Inventory_Send);
 121 }
 122 void Inventory_delete(entity e) { delete(e.inventory); }
 123 void Inventory_update(entity e) { e.inventory.SendFlags = 0xFFFFFF; }
 124
 125 void InventoryStorage_attach(entity e) { e.inventory_store = NEW(Inventory); e.inventory_store.drawonlytoclient = e; }
 126 void InventoryStorage_detach(entity e) { delete(e.inventory_store); }
 127 #endif