qcsrc/common/ent_cs.qc

   1 #include "ent_cs.qh"
   2
   3 #if defined(CSQC)
   4         #include <common/gamemodes/_mod.qh>
   5         #include <common/resources/resources.qh>
   6 #elif defined(MENUQC)
   7 #elif defined(SVQC)
   8         #include <common/gamemodes/_mod.qh>
   9         #include <common/resources/resources.qh>
  10         #include <common/resources/sv_resources.qh>
  11 #endif
  12
  13 REGISTRY(EntCSProps, BITS(16) - 1)
  14 REGISTER_REGISTRY(EntCSProps)
  15 REGISTRY_SORT(EntCSProps)
  16 REGISTRY_CHECK(EntCSProps)
  17
  18 REGISTRY_DEFINE_GET(EntCSProps, NULL)
  19 STATIC_INIT(EntCSProps_renumber) { FOREACH(EntCSProps, true, it.m_id = i); }
  20
  21 // these entcs_props ids need to be referenced directly
  22 int ENTCS_PROP_ENTNUM_id = 0;
  23 int ENTCS_PROP_ORIGIN_id = 0;
  24 int ENTCS_PROP_HEALTH_id = 0;
  25 STATIC_INIT(EntCSProps_setglobalids)
  26 {
  27         FOREACH(EntCSProps, true, {
  28                 if (it.registered_id == "ENTCS_PROP_ENTNUM") ENTCS_PROP_ENTNUM_id = it.m_id;
  29                 if (it.registered_id == "ENTCS_PROP_ORIGIN") ENTCS_PROP_ORIGIN_id = it.m_id;
  30                 if (it.registered_id == "ENTCS_PROP_HEALTH") ENTCS_PROP_HEALTH_id = it.m_id;
  31         });
  32 }
  33
  34 #ifdef SVQC
  35 // Force an origin update, for player sounds
  36 void entcs_force_origin(entity player)
  37 {
  38         CS(player).entcs.m_forceupdate = BIT(ENTCS_PROP_ORIGIN_id);
  39 }
  40 #endif
  41
  42 .bool m_public;
  43 .bool(entity ent, entity player) m_check;
  44 .void(entity ent, entity player) m_set;
  45 .void(int chan, entity ent) m_send;
  46 .void(entity ent) m_receive;
  47
  48 #ifdef SVQC
  49 #define _ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive) \
  50         void id##_set(entity ent, entity player) { setprop(ent.(checkprop), player.(checkprop_pl)); } \
  51         void id##_send(int chan, entity ent) { LAMBDA(svsend); } \
  52         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
  53                 this.m_public = ispublic; \
  54                 this.m_check = id##_check; \
  55                 this.m_set = id##_set; \
  56                 this.m_send = id##_send; \
  57         }
  58
  59 #define ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive) \
  60         bool id##_check(entity ent, entity player) { return (ent.(checkprop) != player.(checkprop_pl)); } \
  61         _ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive)
  62
  63 #define ENTCS_PROP_CODED(id, ispublic, checkprop, checkprop_pl, setprop, decfactor, svsend, clreceive) \
  64         bool id##_check(entity ent, entity player) { \
  65                 return (floor(ent.(checkprop)) / decfactor != floor(player.(checkprop_pl)) / decfactor); \
  66         } \
  67         _ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive)
  68
  69 #elif defined(CSQC)
  70 #define ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive) \
  71         void id##_receive(entity ent) { LAMBDA(clreceive); } \
  72         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
  73                 this.m_public = ispublic; \
  74                 this.m_receive = id##_receive; \
  75         }
  76
  77 #define ENTCS_PROP_CODED(id, ispublic, checkprop, checkprop_pl, setprop, decfactor, svsend, clreceive) \
  78         ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive)
  79 #endif
  80
  81 #ifdef SVQC
  82 #define ENTCS_PROP_RESOURCE(id, ispublic, checkprop, setprop, decfactor, svsend, clreceive) \
  83         bool id##_check(entity ent, entity player) { \
  84                 return (floor(GetResource(ent, checkprop) / decfactor) != floor(GetResource(player, checkprop) / decfactor)); \
  85         } \
  86         void id##_set(entity ent, entity player) { SetResourceExplicit(ent, checkprop, GetResource(player, checkprop)); } \
  87         void id##_send(int chan, entity ent) { LAMBDA(svsend); } \
  88         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
  89                 this.m_public = ispublic; \
  90                 this.m_check = id##_check; \
  91                 this.m_set = id##_set; \
  92                 this.m_send = id##_send; \
  93         }
  94 #elif defined(CSQC)
  95 #define ENTCS_PROP_RESOURCE(id, ispublic, checkprop, setprop, decfactor, svsend, clreceive) \
  96         void id##_receive(entity ent) { LAMBDA(clreceive); } \
  97         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
  98                 this.m_public = ispublic; \
  99                 this.m_receive = id##_receive; \
 100         }
 101 #endif
 102
 103 #define ENTCS_SET_NORMAL(var, x) MACRO_BEGIN \
 104         var = x; \
 105 MACRO_END
 106
 107 /** the engine player name strings are mutable! */
 108 #define ENTCS_SET_MUTABLE_STRING(var, x) MACRO_BEGIN \
 109         strcpy(var, x); \
 110 MACRO_END
 111
 112 ENTCS_PROP(ENTNUM, false, sv_entnum, sv_entnum, ENTCS_SET_NORMAL, {}, {}) /* sentinel */
 113
 114 ENTCS_PROP(ORIGIN, false, origin, origin, ENTCS_SET_NORMAL,
 115         { WriteVector(chan, ent.origin); },
 116         { ent.has_sv_origin = true; vector v = ReadVector(); setorigin(ent, v); })
 117
 118 #define DEC_FACTOR (360 / 64)
 119 ENTCS_PROP_CODED(ANGLES, false, angles_y, angles_y, ENTCS_SET_NORMAL, DEC_FACTOR,
 120         { WriteByte(chan, ent.angles.y / DEC_FACTOR); },
 121         { vector v = '0 0 0'; v.y = ReadByte() * DEC_FACTOR; ent.angles = v; })
 122 #undef DEC_FACTOR
 123
 124 // FIXME: use a better scale?
 125 #define DEC_FACTOR 10
 126 ENTCS_PROP_RESOURCE(HEALTH, false, RES_HEALTH, ENTCS_SET_NORMAL, DEC_FACTOR,
 127         { WriteByte(chan, bound(0, GetResource(ent, RES_HEALTH) / DEC_FACTOR, 255)); },
 128         { ent.healthvalue = ReadByte() * DEC_FACTOR; })
 129
 130 ENTCS_PROP_RESOURCE(ARMOR, false, RES_ARMOR, ENTCS_SET_NORMAL, DEC_FACTOR,
 131         { WriteByte(chan, bound(0, GetResource(ent, RES_ARMOR) / DEC_FACTOR, 255)); },
 132         { SetResourceExplicit(ent, RES_ARMOR, ReadByte() * DEC_FACTOR); })
 133 #undef DEC_FACTOR
 134
 135 ENTCS_PROP(NAME, true, netname, netname, ENTCS_SET_MUTABLE_STRING,
 136         { WriteString(chan, ent.netname); },
 137         { strcpy(ent.netname, ReadString()); })
 138
 139 ENTCS_PROP(MODEL, true, model, model, ENTCS_SET_NORMAL,
 140         { WriteString(chan, ent.model); },
 141         { strcpy(ent.model, ReadString()); })
 142
 143 ENTCS_PROP(SKIN, true, skin, skin, ENTCS_SET_NORMAL,
 144         { WriteByte(chan, ent.skin); },
 145         { ent.skin = ReadByte(); })
 146
 147 ENTCS_PROP(CLIENTCOLORS, true, clientcolors, clientcolors, ENTCS_SET_NORMAL,
 148         { WriteByte(chan, ent.clientcolors); },
 149         { ent.colormap = ReadByte(); })
 150
 151 ENTCS_PROP(FRAGS, true, frags, frags, ENTCS_SET_NORMAL,
 152         { WriteShort(chan, ent.frags); },
 153         { ent.frags = ReadShort(); })
 154
 155 ENTCS_PROP(COUNTRYCODE, true, countrycode, countrycode, ENTCS_SET_NORMAL,
 156         { WriteByte(chan, ent.countrycode); },
 157         { ent.countrycode = ReadByte(); })
 158
 159 ENTCS_PROP(RANK, true, rank, rank, ENTCS_SET_NORMAL,
 160         { WriteString(chan, ent.rank); },
 161         { strcpy(ent.rank, ReadString()); })
 162
 163 ENTCS_PROP(WANTSJOIN, true, wants_join, wants_join, ENTCS_SET_NORMAL,
 164         { WriteByte(chan, ent.wants_join); },
 165         { ent.wants_join = ReadByte(); })
 166
 167 // use sv_solid to avoid changing solidity state of entcs entities
 168 ENTCS_PROP(SOLID, true, sv_solid, solid, ENTCS_SET_NORMAL,
 169         { WriteByte(chan, ent.sv_solid); },
 170         { ent.sv_solid = ReadByte(); })
 171
 172 // z411 weapon
 173 ENTCS_PROP(ACTIVEWEPID, false, activewepid, activewepid, ENTCS_SET_NORMAL,
 174         { WriteByte(chan, ent.activewepid); },
 175         { ent.activewepid = ReadByte(); })
 176
 177 // gamemode specific player survival status (independent of score and frags)
 178 ENTCS_PROP(SURVIVAL_STATUS, true, survival_status, survival_status, ENTCS_SET_NORMAL,
 179         { WriteShort(chan, ent.survival_status); },
 180         { ent.survival_status = ReadShort(); })
 181
 182 #ifdef SVQC
 183
 184         int ENTCS_PUBLICMASK = 0, ENTCS_PRIVATEMASK = 0;
 185         STATIC_INIT(ENTCS_PUBLICMASK)
 186         {
 187                 FOREACH(EntCSProps, true,
 188                 {
 189                         if (it.m_public)
 190                                 ENTCS_PUBLICMASK |= BIT(it.m_id);
 191                         else
 192                                 ENTCS_PRIVATEMASK |= BIT(it.m_id);
 193                 });
 194         }
 195
 196         void entcs_update_players(entity player)
 197         {
 198                 FOREACH_CLIENT(it != player && IS_PLAYER(it),
 199                 {
 200                         CS(it).entcs.SendFlags |= ENTCS_PRIVATEMASK;
 201                 });
 202         }
 203
 204         bool _entcs_send(entity this, entity to, int sf, int chan)
 205         {
 206                 entity player = this.owner;
 207                 sf |= BIT(ENTCS_PROP_ENTNUM_id); // assume private
 208                 do {
 209                         if (IS_PLAYER(player))
 210                         {
 211                                 if (radar_showenemies) break;
 212                                 if (SAME_TEAM(to, player)) break;
 213                                 if (!(IS_PLAYER(to) || INGAME(to))) break;
 214                         }
 215                         sf &= ENTCS_PUBLICMASK; // no private updates
 216                 } while (0);
 217
 218                 sf |= this.m_forceupdate;
 219                 this.m_forceupdate = 0;
 220                 if (chan == MSG_ENTITY)
 221                         WriteHeader(chan, ENT_CLIENT_ENTCS);
 222                 else
 223                         WriteHeader(chan, CLIENT_ENTCS);
 224                 WriteByte(chan, etof(player) - 1);
 225                 WriteShort(chan, sf);
 226                 FOREACH(EntCSProps, sf & BIT(it.m_id),
 227                 {
 228                         it.m_send(chan, this);
 229                 });
 230                 return true;
 231         }
 232
 233         bool entcs_send(entity this, entity to, int sf)
 234         {
 235                 return _entcs_send(this, to, sf, MSG_ENTITY);
 236         }
 237
 238         void entcs_think(entity this)
 239         {
 240                 this.nextthink = time + 0.033333333333;  // TODO: increase this to like 0.15 once the client can do smoothing
 241                 entity player = this.owner;
 242                 FOREACH(EntCSProps, it.m_check(this, player),
 243                 {
 244                         it.m_set(this, player);
 245                         this.SendFlags |= BIT(it.m_id);
 246                 });
 247
 248                 if (intermission_running)
 249                 {
 250                         // health is set to special values after the game ends, ignore any change
 251                         this.SendFlags &= ~BIT(ENTCS_PROP_HEALTH_id);
 252                 }
 253
 254                 // always send origin of players even if they stand still otherwise
 255                 // if a teammate isn't in my pvs and their health (or view angle or name
 256                 // etc...) changes then their tag disappears
 257                 if (IS_PLAYER(this.owner))
 258                         this.SendFlags |= BIT(ENTCS_PROP_ORIGIN_id);
 259
 260                 // not needed, origin is just data to be sent
 261                 //setorigin(this, this.origin); // relink
 262         }
 263
 264         void entcs_attach(entity player)
 265         {
 266                 entity e = CS(player).entcs = new_pure(entcs_sender);
 267                 e.owner = player;
 268                 setthink(e, entcs_think);
 269                 e.nextthink = time;
 270                 Net_LinkEntity(e, false, 0, entcs_send);
 271                 // NOTE: the following code block has been disabled as a workaround for https://gitlab.com/xonotic/xonotic-data.pk3dir/-/issues/1824
 272 #if 0
 273                 if (!IS_REAL_CLIENT(player)) return;
 274                 FOREACH_CLIENT(true, {
 275                         assert(CS(it).entcs);
 276                         _entcs_send(CS(it).entcs, msg_entity = player, BITS(23), MSG_ONE);
 277                 });
 278 #endif
 279         }
 280
 281         void entcs_detach(entity player)
 282         {
 283                 if (!CS(player).entcs) return;
 284                 delete(CS(player).entcs);
 285                 CS(player).entcs = NULL;
 286         }
 287
 288 #endif
 289
 290 #ifdef CSQC
 291
 292         void Ent_RemoveEntCS(entity this)
 293         {
 294                 int n = this.sv_entnum;
 295                 entity e = entcs_receiver(n);
 296                 entcs_receiver(n, NULL);
 297                 strfree(e.netname);
 298                 strfree(e.model);
 299                 if (e != this) delete(e);
 300         }
 301
 302         void entcs_think(entity this)
 303         {
 304                 entity e = CSQCModel_server2csqc(this.sv_entnum);
 305                 if (e == NULL)
 306                 {
 307                         // player model is NOT in client's PVS
 308                         InterpolateOrigin_Do(this);
 309                         this.has_origin = this.has_sv_origin;
 310                         return;
 311                 }
 312                 this.has_origin = true;
 313                 // when a player model is in client's PVS we use its origin directly
 314                 // (entcs networked origin is overriden)
 315                 this.origin = e.origin;
 316                 InterpolateOrigin_Reset(this);
 317                 setorigin(this, this.origin);
 318                 // `cl_forceplayermodels 1` sounds will be wrong until the player has been in the PVS, but so be it
 319                 if (this.model != e.model)
 320                 {
 321                         strcpy(this.model, e.model);
 322                 }
 323         }
 324
 325         bool ReadEntcs(entity this)
 326         {
 327                 int n = ReadByte();
 328                 entity e = entcs_receiver(n);
 329                 if (e == NULL)
 330                 {
 331                         if (!this)
 332                                 // initial = temp
 333                                 e = new_pure(ENT_CLIENT_ENTCS);
 334                         else
 335                                 // initial = linked
 336                                 e = this;
 337                         setthink(e, entcs_think);
 338                         entcs_receiver(n, e);
 339                 }
 340                 else if (e != this && this)
 341                 {
 342                         // upgrade to linked
 343                         delete(e);
 344                         e = this;
 345                         setthink(e, entcs_think);
 346                         entcs_receiver(n, e);
 347                 }
 348
 349                 InterpolateOrigin_Undo(e);
 350                 e.sv_entnum = n;
 351                 int sf = ReadShort();
 352                 e.has_sv_origin = false;
 353                 e.m_entcs_private = boolean(sf & BIT(ENTCS_PROP_ENTNUM_id));
 354                 FOREACH(EntCSProps, sf & BIT(it.m_id),
 355                 {
 356                         it.m_receive(e);
 357                 });
 358                 e.iflags |= IFLAG_ORIGIN;
 359                 InterpolateOrigin_Note(e);
 360                 getthink(e)(e);
 361                 return true;
 362         }
 363
 364         NET_HANDLE(ENT_CLIENT_ENTCS, bool isnew)
 365         {
 366                 if (isnew)
 367                 {
 368                         make_pure(this);
 369                         this.entremove = Ent_RemoveEntCS;
 370                 }
 371                 return ReadEntcs(this);
 372         }
 373
 374         NET_HANDLE(CLIENT_ENTCS, bool isnew)
 375         {
 376                 return ReadEntcs(NULL);
 377         }
 378
 379 #endif