qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "announcer.qh"
   4 #include "hud/all.qh"
   5 #include "mapvoting.qh"
   6 #include "scoreboard.qh"
   7 #include "shownames.qh"
   8 #include "quickmenu.qh"
   9
  10 #include "mutators/events.qh"
  11
  12 #include <common/animdecide.qh>
  13 #include <common/ent_cs.qh>
  14 #include <common/anim.qh>
  15 #include <common/constants.qh>
  16 #include <common/debug.qh>
  17 #include <common/mapinfo.qh>
  18 #include <common/gamemodes/all.qh>
  19 #include <common/physics/player.qh>
  20 #include <common/stats.qh>
  21 #include <common/triggers/target/music.qh>
  22 #include <common/teams.qh>
  23
  24 #include <common/vehicles/all.qh>
  25 #include <common/weapons/all.qh>
  26 #include <common/viewloc.qh>
  27 #include <common/minigames/cl_minigames.qh>
  28 #include <common/minigames/cl_minigames_hud.qh>
  29
  30 #include <lib/csqcmodel/cl_player.qh>
  31 #include <lib/csqcmodel/cl_model.qh>
  32 #include "csqcmodel_hooks.qh"
  33
  34 #include <lib/warpzone/client.qh>
  35 #include <lib/warpzone/common.qh>
  36
  37 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  38
  39 float autocvar_cl_viewmodel_scale;
  40
  41 bool autocvar_cl_bobmodel;
  42 float autocvar_cl_bobmodel_speed;
  43 float autocvar_cl_bobmodel_side;
  44 float autocvar_cl_bobmodel_up;
  45
  46 float autocvar_cl_followmodel;
  47 float autocvar_cl_followmodel_speed = 0.3;
  48 float autocvar_cl_followmodel_limit = 135;
  49 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  50 float autocvar_cl_followmodel_highpass = 0.05;
  51 float autocvar_cl_followmodel_lowpass = 0.03;
  52 bool autocvar_cl_followmodel_velocity_absolute;
  53
  54 float autocvar_cl_leanmodel;
  55 float autocvar_cl_leanmodel_speed = 0.3;
  56 float autocvar_cl_leanmodel_limit = 30;
  57 float autocvar_cl_leanmodel_highpass1 = 0.2;
  58 float autocvar_cl_leanmodel_highpass = 0.2;
  59 float autocvar_cl_leanmodel_lowpass = 0.05;
  60
  61 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  62 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  63 { \
  64         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
  65 } MACRO_END
  66
  67 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  68 { \
  69         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  70         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  71 } MACRO_END
  72
  73 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  74 { \
  75         float __f = 0; lowpass(value, frac, ref_store, __f); \
  76         ret = (value) - __f; \
  77 } MACRO_END
  78
  79 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  80 { \
  81         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  82         ret = (value) - __f; \
  83 } MACRO_END
  84
  85 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  86 { \
  87         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  88         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  89 } MACRO_END
  90
  91 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  92 { \
  93         highpass(value.x, frac, ref_store.x, ref_out.x); \
  94         highpass(value.y, frac, ref_store.y, ref_out.y); \
  95 } MACRO_END
  96
  97 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
  98 { \
  99         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 100         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 101 } MACRO_END
 102
 103 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 104 { \
 105         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 106         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 107         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 108 } MACRO_END
 109
 110 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 111 { \
 112         highpass(value.x, frac, ref_store.x, ref_out.x); \
 113         highpass(value.y, frac, ref_store.y, ref_out.y); \
 114         highpass(value.z, frac, ref_store.z, ref_out.z); \
 115 } MACRO_END
 116
 117 void viewmodel_animate(entity this)
 118 {
 119         static float prevtime;
 120         float frametime = (time - prevtime);
 121         prevtime = time;
 122
 123         if (autocvar_chase_active) return;
 124         if (STAT(HEALTH) <= 0) return;
 125
 126         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 127
 128         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 129         static bool oldonground;
 130         static float hitgroundtime;
 131         if (clonground)
 132         {
 133                 float f = time; // cl.movecmd[0].time
 134                 if (!oldonground)
 135                         hitgroundtime = f;
 136         }
 137         oldonground = clonground;
 138
 139
 140         bool teleported = view.csqcmodel_teleported;
 141
 142         float frac;
 143         if(autocvar_cl_followmodel)
 144         {
 145                 vector gunorg = '0 0 0';
 146                 static vector vel_average;
 147                 static vector gunorg_prev = '0 0 0';
 148                 static vector gunorg_adjustment_highpass;
 149                 static vector gunorg_adjustment_lowpass;
 150
 151                 vector vel;
 152                 if(autocvar_cl_followmodel_velocity_absolute)
 153                         vel = view.velocity;
 154                 else
 155                 {
 156                         vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 157                         MAKEVECTORS(makevectors, view_angles, forward, right, up);
 158                         vel.x = view.velocity * forward;
 159                         vel.y = view.velocity * right * -1;
 160                         vel.z = view.velocity * up;
 161                 }
 162
 163                 vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 164                 vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 165                 vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 166
 167                 frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 168                 lowpass3(vel, frac, vel_average, gunorg);
 169
 170                 gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 171
 172                 // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 173                 // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 174                 frac = avg_factor(autocvar_cl_followmodel_highpass);
 175                 highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 176                 frac = avg_factor(autocvar_cl_followmodel_lowpass);
 177                 lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 178
 179                 if(autocvar_cl_followmodel_velocity_absolute)
 180                 {
 181                         vector fixed_gunorg;
 182                         vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 183                         MAKEVECTORS(makevectors, view_angles, forward, right, up);
 184                         fixed_gunorg.x = gunorg * forward;
 185                         fixed_gunorg.y = gunorg * right * -1;
 186                         fixed_gunorg.z = gunorg * up;
 187                         gunorg = fixed_gunorg;
 188                 }
 189
 190                 this.origin += gunorg;
 191         }
 192
 193         if(autocvar_cl_leanmodel)
 194         {
 195                 vector gunangles = '0 0 0';
 196                 static vector gunangles_prev = '0 0 0';
 197                 static vector gunangles_highpass = '0 0 0';
 198                 static vector gunangles_adjustment_highpass;
 199                 static vector gunangles_adjustment_lowpass;
 200
 201                 if (teleported)
 202                         gunangles_prev = view_angles;
 203
 204                 // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 205                 gunangles_highpass += gunangles_prev;
 206                 PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 207                 YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 208                 ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 209                 frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 210                 highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 211                 gunangles_prev = view_angles;
 212                 gunangles_highpass -= gunangles_prev;
 213
 214                 PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 215                 YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 216
 217                 // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 218                 frac = avg_factor(autocvar_cl_leanmodel_highpass);
 219                 highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 220                 frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 221                 lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 222
 223                 gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 224                 this.angles += gunangles;
 225         }
 226
 227         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 228
 229         // vertical view bobbing code
 230         // TODO: cl_bob
 231
 232         // horizontal view bobbing code
 233         // TODO: cl_bob2
 234
 235         // fall bobbing code
 236         // causes the view to swing down and back up when touching the ground
 237         // TODO: cl_bobfall
 238
 239         // gun model bobbing code
 240         if (autocvar_cl_bobmodel)
 241         {
 242                 // calculate for swinging gun model
 243                 // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 244                 static float bobmodel_scale = 0;
 245                 static float time_ofs = 0; // makes the effect always restart in the same way
 246                 if (clonground)
 247                 {
 248                         if (time - hitgroundtime > 0.05)
 249                                 bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 250                 }
 251                 else
 252                         bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 253                 if(bobmodel_scale && xyspeed)
 254                 {
 255                         float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 256                         float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 257                         vector gunorg = '0 0 0';
 258                         gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 259                         gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 260
 261                         this.origin += gunorg;
 262                 }
 263                 else
 264                         time_ofs = time;
 265         }
 266 }
 267
 268 .vector viewmodel_origin, viewmodel_angles;
 269 .float weapon_nextthink;
 270 .float weapon_eta_last;
 271 .float weapon_switchdelay;
 272
 273 void viewmodel_draw(entity this)
 274 {
 275         if(!activeweapon)
 276                 return;
 277         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 278         float a = this.alpha;
 279         static bool wasinvehicle;
 280         bool invehicle = player_localentnum > maxclients;
 281         if (invehicle) a = -1;
 282         else if (wasinvehicle) a = 1;
 283         wasinvehicle = invehicle;
 284         Weapon wep = activeweapon;
 285         int c = stof(getplayerkeyvalue(current_player, "colors"));
 286         vector g = weaponentity_glowmod(wep, c);
 287         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 288         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 289                 | EF_NODEPTHTEST)
 290                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 291         for (entity e = this; e; e = e.weaponchild)
 292         {
 293                 e.drawmask = mask;
 294                 e.alpha = a;
 295                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 296                 e.glowmod = g;
 297                 e.csqcmodel_effects = fx;
 298                 CSQCModel_Effects_Apply(e);
 299         }
 300         {
 301                 static string name_last;
 302                 string name = wep.mdl;
 303                 if (name != name_last)
 304                 {
 305                         name_last = name;
 306                         CL_WeaponEntity_SetModel(this, name);
 307                         this.viewmodel_origin = this.origin;
 308                         this.viewmodel_angles = this.angles;
 309                 }
 310                 anim_update(this);
 311                 if (!this.animstate_override)
 312                         anim_set(this, this.anim_idle, true, false, false);
 313         }
 314         float f = 0; // 0..1; 0: fully active
 315         float eta = (this.weapon_nextthink - time) / STAT(WEAPONRATEFACTOR);
 316         if (eta <= 0) f = this.weapon_eta_last;
 317         else switch (this.state)
 318         {
 319                 case WS_RAISE:
 320                 {
 321                         f = eta / max(eta, this.weapon_switchdelay);
 322                         break;
 323                 }
 324                 case WS_DROP:
 325                 {
 326                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 327                         break;
 328                 }
 329                 case WS_CLEAR:
 330                 {
 331                         f = 1;
 332                         break;
 333                 }
 334         }
 335         this.weapon_eta_last = f;
 336         this.origin = this.viewmodel_origin;
 337         this.angles = this.viewmodel_angles;
 338         this.angles_x = (-90 * f * f);
 339         viewmodel_animate(this);
 340         setorigin(this, this.origin);
 341 }
 342
 343 entity viewmodel;
 344 STATIC_INIT(viewmodel) {
 345     viewmodel = new(viewmodel);
 346 }
 347
 348 void Porto_Draw(entity this);
 349 STATIC_INIT(Porto)
 350 {
 351         entity e = new_pure(porto);
 352         e.draw = Porto_Draw;
 353         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 354 }
 355
 356 const int polyline_length = 16;
 357 vector polyline[polyline_length];
 358 void Porto_Draw(entity this)
 359 {
 360         if (activeweapon != WEP_PORTO) return;
 361         if (spectatee_status) return;
 362         if (WEP_CVAR(porto, secondary)) return;
 363         if (intermission == 1) return;
 364         if (intermission == 2) return;
 365         if (STAT(HEALTH) <= 0) return;
 366
 367         vector pos = view_origin;
 368         vector dir = view_forward;
 369         if (angles_held_status)
 370         {
 371                 makevectors(angles_held);
 372                 dir = v_forward;
 373         }
 374
 375         polyline[0] = pos;
 376
 377         int portal_number = 0, portal1_idx = 1, portal_max = 2;
 378         int n = 1 + 2;  // 2 lines == 3 points
 379         for (int idx = 0; idx < n && idx < polyline_length - 1; )
 380         {
 381                 traceline(pos, pos + 65536 * dir, true, this);
 382                 dir = reflect(dir, trace_plane_normal);
 383                 pos = trace_endpos;
 384                 polyline[++idx] = pos;
 385                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 386                 {
 387                         n += 1;
 388                         continue;
 389                 }
 390                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 391                 {
 392                         n = max(2, idx);
 393                         break;
 394                 }
 395                 // check size
 396                 {
 397                         vector ang = vectoangles2(trace_plane_normal, dir);
 398                         ang.x = -ang.x;
 399                         makevectors(ang);
 400                         if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 401                         {
 402                                 n = max(2, idx);
 403                                 break;
 404                         }
 405                 }
 406                 portal_number += 1;
 407                 if (portal_number >= portal_max) break;
 408                 if (portal_number == 1) portal1_idx = idx;
 409         }
 410         for (int idx = 0; idx < n - 1; ++idx)
 411         {
 412                 vector p = polyline[idx], q = polyline[idx + 1];
 413                 if (idx == 0) p -= view_up * 16;  // line from player
 414                 vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 415                 Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 416         }
 417 }
 418
 419 float drawtime;
 420 float avgspeed;
 421 vector GetCurrentFov(float fov)
 422 {
 423         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 424         float velocityzoom, curspeed;
 425         vector v;
 426
 427         zoomsensitivity = autocvar_cl_zoomsensitivity;
 428         zoomfactor = autocvar_cl_zoomfactor;
 429         if(zoomfactor < 1 || zoomfactor > 30)
 430                 zoomfactor = 2.5;
 431         zoomspeed = autocvar_cl_zoomspeed;
 432         if(zoomspeed >= 0)
 433         if(zoomspeed < 0.5 || zoomspeed > 16)
 434                         zoomspeed = 3.5;
 435
 436         zoomdir = button_zoom;
 437         if(hud == HUD_NORMAL)
 438         if(switchweapon == activeweapon)
 439         if((activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 440                 zoomdir += button_attack2;
 441         if(spectatee_status > 0 || isdemo())
 442         {
 443                 if(spectatorbutton_zoom)
 444                 {
 445                         if(zoomdir)
 446                                 zoomdir = 0;
 447                         else
 448                                 zoomdir = 1;
 449                 }
 450                 // fteqcc failed twice here already, don't optimize this
 451         }
 452
 453         if(zoomdir) { zoomin_effect = 0; }
 454
 455         if(camera_active)
 456         {
 457                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 458         }
 459         else if(autocvar_cl_spawnzoom && zoomin_effect)
 460         {
 461                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 462
 463                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 464                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 465                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 466         }
 467         else
 468         {
 469                 if(zoomspeed < 0) // instant zoom
 470                 {
 471                         if(zoomdir)
 472                                 current_viewzoom = 1 / zoomfactor;
 473                         else
 474                                 current_viewzoom = 1;
 475                 }
 476                 else
 477                 {
 478                         if(zoomdir)
 479                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 480                         else
 481                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 482                 }
 483         }
 484
 485         if(almost_equals(current_viewzoom, 1))
 486                 current_zoomfraction = 0;
 487         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 488                 current_zoomfraction = 1;
 489         else
 490                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 491
 492         if(zoomsensitivity < 1)
 493                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 494         else
 495                 setsensitivityscale(1);
 496
 497         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 498         {
 499                 if(intermission) { curspeed = 0; }
 500                 else
 501                 {
 502
 503                         makevectors(view_angles);
 504                         v = pmove_vel;
 505                         if(csqcplayer)
 506                                 v = csqcplayer.velocity;
 507
 508                         switch(autocvar_cl_velocityzoom_type)
 509                         {
 510                                 case 3: curspeed = max(0, v_forward * v); break;
 511                                 case 2: curspeed = (v_forward * v); break;
 512                                 case 1: default: curspeed = vlen(v); break;
 513                         }
 514                 }
 515
 516                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 517                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 518                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 519
 520                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 521         }
 522         else
 523                 velocityzoom = 1;
 524
 525         float frustumx, frustumy, fovx, fovy;
 526         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 527         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 528         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 529         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 530
 531         return '1 0 0' * fovx + '0 1 0' * fovy;
 532 }
 533
 534 vector GetViewLocationFOV(float fov)
 535 {
 536         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 537         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 538         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 539         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 540         return '1 0 0' * fovx + '0 1 0' * fovy;
 541 }
 542
 543 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 544 {
 545         float fovx, fovy;
 546         float width = (ov_worldmax.x - ov_worldmin.x);
 547         float height = (ov_worldmax.y - ov_worldmin.y);
 548         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 549         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 550         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 551         return '1 0 0' * fovx + '0 1 0' * fovy;
 552 }
 553
 554 // this function must match W_SetupShot!
 555 float zoomscript_caught;
 556
 557 vector wcross_origin;
 558 float wcross_scale_prev, wcross_alpha_prev;
 559 vector wcross_color_prev;
 560 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 561 vector wcross_color_goal_prev;
 562 float wcross_changedonetime;
 563
 564 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 565 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 566 float wcross_name_changestarttime, wcross_name_changedonetime;
 567 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 568
 569 float wcross_ring_prev;
 570
 571 entity trueaim;
 572 entity trueaim_rifle;
 573
 574 const float SHOTTYPE_HITTEAM = 1;
 575 const float SHOTTYPE_HITOBSTRUCTION = 2;
 576 const float SHOTTYPE_HITWORLD = 3;
 577 const float SHOTTYPE_HITENEMY = 4;
 578
 579 void TrueAim_Init()
 580 {
 581         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 582         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 583 }
 584
 585 float EnemyHitCheck()
 586 {
 587         float t, n;
 588         wcross_origin = project_3d_to_2d(trace_endpos);
 589         wcross_origin.z = 0;
 590         if(trace_ent)
 591                 n = trace_ent.entnum;
 592         else
 593                 n = trace_networkentity;
 594         if(n < 1)
 595                 return SHOTTYPE_HITWORLD;
 596         if(n > maxclients)
 597                 return SHOTTYPE_HITWORLD;
 598         t = entcs_GetTeam(n - 1);
 599         if(teamplay)
 600                 if(t == myteam)
 601                         return SHOTTYPE_HITTEAM;
 602         if(t == NUM_SPECTATOR)
 603                 return SHOTTYPE_HITWORLD;
 604         return SHOTTYPE_HITENEMY;
 605 }
 606
 607 float TrueAimCheck()
 608 {
 609         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 610         vector vecs, trueaimpoint, w_shotorg;
 611         vector mi, ma, dv;
 612         float shottype;
 613         entity ta;
 614         float mv;
 615
 616         mi = ma = '0 0 0';
 617         ta = trueaim;
 618         mv = MOVE_NOMONSTERS;
 619
 620         switch(activeweapon) // WEAPONTODO
 621         {
 622                 case WEP_TUBA: // no aim
 623                 case WEP_PORTO: // shoots from eye
 624                 case WEP_NEXBALL: // shoots from eye
 625                 case WEP_HOOK: // no trueaim
 626                 case WEP_MORTAR: // toss curve
 627                         return SHOTTYPE_HITWORLD;
 628                 case WEP_VORTEX:
 629                 case WEP_VAPORIZER:
 630                         mv = MOVE_NORMAL;
 631                         break;
 632                 case WEP_RIFLE:
 633                         ta = trueaim_rifle;
 634                         mv = MOVE_NORMAL;
 635                         if(zoomscript_caught)
 636                         {
 637                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 638                                 return EnemyHitCheck();
 639                         }
 640                         break;
 641                 case WEP_DEVASTATOR: // projectile has a size!
 642                         mi = '-3 -3 -3';
 643                         ma = '3 3 3';
 644                         break;
 645                 case WEP_FIREBALL: // projectile has a size!
 646                         mi = '-16 -16 -16';
 647                         ma = '16 16 16';
 648                         break;
 649                 case WEP_SEEKER: // projectile has a size!
 650                         mi = '-2 -2 -2';
 651                         ma = '2 2 2';
 652                         break;
 653                 case WEP_ELECTRO: // projectile has a size!
 654                         mi = '0 0 -3';
 655                         ma = '0 0 -3';
 656                         break;
 657         }
 658
 659         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 660
 661         vecs = decompressShotOrigin(STAT(SHOTORG));
 662
 663         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 664         trueaimpoint = trace_endpos;
 665
 666         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 667                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 668
 669         if(vecs.x > 0)
 670                 vecs.y = -vecs.y;
 671         else
 672                 vecs = '0 0 0';
 673
 674         dv = view_right * vecs.y + view_up * vecs.z;
 675         w_shotorg = traceorigin + dv;
 676
 677         // now move the vecs forward as much as requested if possible
 678         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 679         w_shotorg = trace_endpos - view_forward * nudge;
 680
 681         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 682         shottype = EnemyHitCheck();
 683         if(shottype != SHOTTYPE_HITWORLD)
 684                 return shottype;
 685
 686 #if 0
 687         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 688         // or rather, I know why, but see no fix
 689         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 690                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 691                 return SHOTTYPE_HITOBSTRUCTION;
 692 #endif
 693
 694         return SHOTTYPE_HITWORLD;
 695 }
 696
 697 void PostInit();
 698 void CSQC_Demo_Camera();
 699 float HUD_WouldDrawScoreboard();
 700 float camera_mode;
 701 const float CAMERA_FREE = 1;
 702 const float CAMERA_CHASE = 2;
 703 float reticle_type;
 704 string reticle_image;
 705 string NextFrameCommand;
 706
 707 vector freeze_org, freeze_ang;
 708 entity nightvision_noise, nightvision_noise2;
 709
 710 const float MAX_TIME_DIFF = 5;
 711 float pickup_crosshair_time, pickup_crosshair_size;
 712 float hitindication_crosshair_size;
 713 float use_vortex_chargepool;
 714
 715 float myhealth, myhealth_prev;
 716 float myhealth_flash;
 717
 718 float old_blurradius, old_bluralpha;
 719 float old_sharpen_intensity;
 720
 721 vector myhealth_gentlergb;
 722
 723 float contentavgalpha, liquidalpha_prev;
 724 vector liquidcolor_prev;
 725
 726 float eventchase_current_distance;
 727 float eventchase_running;
 728 bool WantEventchase(entity this)
 729 {
 730         if(autocvar_cl_orthoview)
 731                 return false;
 732         if(intermission)
 733                 return true;
 734         if(this.viewloc)
 735                 return true;
 736         if(spectatee_status >= 0)
 737         {
 738                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 739                         return true;
 740                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 741                         return true;
 742                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WEPSET(NEXBALL)))
 743                         return true;
 744                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 745                 {
 746                         if(autocvar_cl_eventchase_death == 2)
 747                         {
 748                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 749                                 if(this.velocity == '0 0 0' || eventchase_running)
 750                                         return true;
 751                         }
 752                         else return true;
 753                 }
 754         }
 755         return false;
 756 }
 757
 758 void HUD_Crosshair_Vehicle()
 759 {
 760         if(hud != HUD_BUMBLEBEE_GUN)
 761         {
 762                 Vehicle info = Vehicles_from(hud);
 763                 info.vr_crosshair(info);
 764         }
 765 }
 766
 767 vector damage_blurpostprocess, content_blurpostprocess;
 768
 769 float unaccounted_damage = 0;
 770 void UpdateDamage()
 771 {
 772         // accumulate damage with each stat update
 773         static float damage_total_prev = 0;
 774         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 775         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 776         damage_total_prev = damage_total;
 777
 778         static float damage_dealt_time_prev = 0;
 779         float damage_dealt_time = STAT(HIT_TIME);
 780         if (damage_dealt_time != damage_dealt_time_prev)
 781         {
 782                 unaccounted_damage += unaccounted_damage_new;
 783                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 784         }
 785         damage_dealt_time_prev = damage_dealt_time;
 786
 787         // prevent hitsound when switching spectatee
 788         static float spectatee_status_prev = 0;
 789         if (spectatee_status != spectatee_status_prev)
 790                 unaccounted_damage = 0;
 791         spectatee_status_prev = spectatee_status;
 792 }
 793
 794 void HitSound()
 795 {
 796         // varying sound pitch
 797
 798         static float hitsound_time_prev = 0;
 799         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 800         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
 801         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 802         {
 803                 if (autocvar_cl_hitsound && unaccounted_damage)
 804                 {
 805                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 806                         float a = autocvar_cl_hitsound_max_pitch;
 807                         float b = autocvar_cl_hitsound_min_pitch;
 808                         float c = autocvar_cl_hitsound_nom_damage;
 809                         float x = unaccounted_damage;
 810                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 811
 812                         // if sound variation is disabled, set pitch_shift to 1
 813                         if (autocvar_cl_hitsound == 1)
 814                                 pitch_shift = 1;
 815
 816                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 817                         if (autocvar_cl_hitsound == 3)
 818                         {
 819                                 float mirror_value = (a-b)/2 + b;
 820                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 821                         }
 822
 823                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 824
 825                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 826                         // todo: normalize sound pressure levels? seems unnecessary
 827
 828                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 829                 }
 830                 unaccounted_damage = 0;
 831                 hitsound_time_prev = time;
 832         }
 833
 834         static float typehit_time_prev = 0;
 835         float typehit_time = STAT(TYPEHIT_TIME);
 836         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 837         {
 838                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 839                 typehit_time_prev = typehit_time;
 840         }
 841 }
 842
 843 void HUD_Crosshair()
 844 {SELFPARAM();
 845         static float rainbow_last_flicker;
 846         static vector rainbow_prev_color;
 847         entity e = this;
 848         float f, i, j;
 849         vector v;
 850         if(!scoreboard_active && !camera_active && intermission != 2 &&
 851                 spectatee_status != -1 && !csqcplayer.viewloc &&
 852                 !HUD_MinigameMenu_IsOpened() )
 853         {
 854                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 855                         return;
 856
 857                 if (hud != HUD_NORMAL)
 858                 {
 859                         HUD_Crosshair_Vehicle();
 860                         return;
 861                 }
 862
 863                 string wcross_style;
 864                 float wcross_alpha, wcross_resolution;
 865                 wcross_style = autocvar_crosshair;
 866                 if (wcross_style == "0")
 867                         return;
 868                 wcross_resolution = autocvar_crosshair_size;
 869                 if (wcross_resolution == 0)
 870                         return;
 871                 wcross_alpha = autocvar_crosshair_alpha;
 872                 if (wcross_alpha == 0)
 873                         return;
 874
 875                 // TrueAim check
 876                 float shottype;
 877
 878                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 879                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 880                 wcross_origin.z = 0;
 881                 if(autocvar_crosshair_hittest)
 882                 {
 883                         vector wcross_oldorigin;
 884                         wcross_oldorigin = wcross_origin;
 885                         shottype = TrueAimCheck();
 886                         if(shottype == SHOTTYPE_HITWORLD)
 887                         {
 888                                 v = wcross_origin - wcross_oldorigin;
 889                                 v.x /= vid_conwidth;
 890                                 v.y /= vid_conheight;
 891                                 if(vlen(v) > 0.01)
 892                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 893                         }
 894                         if(!autocvar_crosshair_hittest_showimpact)
 895                                 wcross_origin = wcross_oldorigin;
 896                 }
 897                 else
 898                         shottype = SHOTTYPE_HITWORLD;
 899
 900                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 901                 string wcross_name = "";
 902                 float wcross_scale, wcross_blur;
 903
 904                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 905                 {
 906                         e = switchingweapon;
 907                         if(e)
 908                         {
 909                                 if(autocvar_crosshair_per_weapon)
 910                                 {
 911                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 912                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 913                                         //if (wcross_resolution == 0)
 914                                                 //return;
 915
 916                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 917                                         wcross_resolution *= e.w_crosshair_size;
 918                                         wcross_name = e.w_crosshair;
 919                                 }
 920                         }
 921                 }
 922
 923                 if(wcross_name == "")
 924                         wcross_name = strcat("gfx/crosshair", wcross_style);
 925
 926                 // MAIN CROSSHAIR COLOR DECISION
 927                 switch(autocvar_crosshair_color_special)
 928                 {
 929                         case 1: // crosshair_color_per_weapon
 930                         {
 931                                 if(e)
 932                                 {
 933                                         wcross_color = e.wpcolor;
 934                                         break;
 935                                 }
 936                                 else { goto normalcolor; }
 937                         }
 938
 939                         case 2: // crosshair_color_by_health
 940                         {
 941                                 float x = STAT(HEALTH);
 942
 943                                 //x = red
 944                                 //y = green
 945                                 //z = blue
 946
 947                                 wcross_color.z = 0;
 948
 949                                 if(x > 200)
 950                                 {
 951                                         wcross_color.x = 0;
 952                                         wcross_color.y = 1;
 953                                 }
 954                                 else if(x > 150)
 955                                 {
 956                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 957                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 958                                 }
 959                                 else if(x > 100)
 960                                 {
 961                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 962                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 963                                         wcross_color.z = 1 - (x-100)*0.02;
 964                                 }
 965                                 else if(x > 50)
 966                                 {
 967                                         wcross_color.x = 1;
 968                                         wcross_color.y = 1;
 969                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 970                                 }
 971                                 else if(x > 20)
 972                                 {
 973                                         wcross_color.x = 1;
 974                                         wcross_color.y = (x-20)*90/27/100;
 975                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 976                                 }
 977                                 else
 978                                 {
 979                                         wcross_color.x = 1;
 980                                         wcross_color.y = 0;
 981                                 }
 982                                 break;
 983                         }
 984
 985                         case 3: // crosshair_color_rainbow
 986                         {
 987                                 if(time >= rainbow_last_flicker)
 988                                 {
 989                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 990                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 991                                 }
 992                                 wcross_color = rainbow_prev_color;
 993                                 break;
 994                         }
 995                         :normalcolor
 996                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
 997                 }
 998
 999                 if(autocvar_crosshair_effect_scalefade)
1000                 {
1001                         wcross_scale = wcross_resolution;
1002                         wcross_resolution = 1;
1003                 }
1004                 else
1005                 {
1006                         wcross_scale = 1;
1007                 }
1008
1009                 if(autocvar_crosshair_pickup)
1010                 {
1011                         float stat_pickup_time = STAT(LAST_PICKUP);
1012
1013                         if(pickup_crosshair_time < stat_pickup_time)
1014                         {
1015                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1016                                         pickup_crosshair_size = 1;
1017
1018                                 pickup_crosshair_time = stat_pickup_time;
1019                         }
1020
1021                         if(pickup_crosshair_size > 0)
1022                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1023                         else
1024                                 pickup_crosshair_size = 0;
1025
1026                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1027                 }
1028
1029                 // todo: make crosshair hit indication dependent on damage dealt
1030                 if(autocvar_crosshair_hitindication)
1031                 {
1032                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1033
1034                         if(unaccounted_damage)
1035                         {
1036                                 hitindication_crosshair_size = 1;
1037                         }
1038
1039                         if(hitindication_crosshair_size > 0)
1040                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1041                         else
1042                                 hitindication_crosshair_size = 0;
1043
1044                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1045                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1046                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1047                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1048                 }
1049
1050                 if(shottype == SHOTTYPE_HITENEMY)
1051                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1052                 if(shottype == SHOTTYPE_HITTEAM)
1053                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1054
1055                 f = fabs(autocvar_crosshair_effect_time);
1056                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1057                 {
1058                         wcross_changedonetime = time + f;
1059                 }
1060                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1061                 {
1062                         wcross_name_changestarttime = time;
1063                         wcross_name_changedonetime = time + f;
1064                         if(wcross_name_goal_prev_prev)
1065                                 strunzone(wcross_name_goal_prev_prev);
1066                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1067                         wcross_name_goal_prev = strzone(wcross_name);
1068                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1069                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1070                         wcross_resolution_goal_prev = wcross_resolution;
1071                 }
1072
1073                 wcross_scale_goal_prev = wcross_scale;
1074                 wcross_alpha_goal_prev = wcross_alpha;
1075                 wcross_color_goal_prev = wcross_color;
1076
1077                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1078                 {
1079                         wcross_blur = 1;
1080                         wcross_alpha *= 0.75;
1081                 }
1082                 else
1083                         wcross_blur = 0;
1084                 // *_prev is at time-frametime
1085                 // * is at wcross_changedonetime+f
1086                 // what do we have at time?
1087                 if(time < wcross_changedonetime)
1088                 {
1089                         f = frametime / (wcross_changedonetime - time + frametime);
1090                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1091                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1092                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1093                 }
1094
1095                 wcross_scale_prev = wcross_scale;
1096                 wcross_alpha_prev = wcross_alpha;
1097                 wcross_color_prev = wcross_color;
1098
1099                 MUTATOR_CALLHOOK(UpdateCrosshair);
1100
1101                 wcross_scale *= 1 - autocvar__menu_alpha;
1102                 wcross_alpha *= 1 - autocvar__menu_alpha;
1103                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1104
1105                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1106                 {
1107                         // crosshair rings for weapon stats
1108                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1109                         {
1110                                 // declarations and stats
1111                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1112                                 string ring_image = string_null, ring_inner_image = string_null;
1113                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1114
1115                                 ring_scale = autocvar_crosshair_ring_size;
1116
1117                                 float weapon_clipload, weapon_clipsize;
1118                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1119                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1120
1121                                 float ok_ammo_charge, ok_ammo_chargepool;
1122                                 ok_ammo_charge = STAT(OK_AMMO_CHARGE);
1123                                 ok_ammo_chargepool = STAT(OK_AMMO_CHARGEPOOL);
1124
1125                                 float vortex_charge, vortex_chargepool;
1126                                 vortex_charge = STAT(VORTEX_CHARGE);
1127                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1128
1129                                 float arc_heat = STAT(ARC_HEAT);
1130
1131                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1132                                         vortex_charge_movingavg = vortex_charge;
1133
1134
1135                                 // handle the values
1136                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1137                                 {
1138                                         if (vortex_chargepool || use_vortex_chargepool) {
1139                                                 use_vortex_chargepool = 1;
1140                                                 ring_inner_value = vortex_chargepool;
1141                                         } else {
1142                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1143                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1144                                         }
1145
1146                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1147                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1148                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1149
1150                                         // draw the outer ring to show the current charge of the weapon
1151                                         ring_value = vortex_charge;
1152                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1153                                         ring_rgb = wcross_color;
1154                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1155                                 }
1156                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1157                                 {
1158                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1159                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1160                                         ring_rgb = wcross_color;
1161                                         ring_image = "gfx/crosshair_ring.tga";
1162                                 }
1163                                 else if (activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1164                                 {
1165                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1166                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1167                                         ring_rgb = wcross_color;
1168                                         ring_image = "gfx/crosshair_ring.tga";
1169                                 }
1170                                 else if (ok_ammo_charge)
1171                                 {
1172                                         ring_value = ok_ammo_chargepool;
1173                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1174                                         ring_rgb = wcross_color;
1175                                         ring_image = "gfx/crosshair_ring.tga";
1176                                 }
1177                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1178                                 {
1179                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1180                                         ring_scale = autocvar_crosshair_ring_reload_size;
1181                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1182                                         ring_rgb = wcross_color;
1183
1184                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1185                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1186                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1187                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1188                                         else
1189                                                 ring_image = "gfx/crosshair_ring.tga";
1190                                 }
1191                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
1192                                 {
1193                                         ring_value = arc_heat;
1194                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1195                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1196                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1197                                         ring_image = "gfx/crosshair_ring.tga";
1198                                 }
1199
1200                                 // if in weapon switch animation, fade ring out/in
1201                                 if(autocvar_crosshair_effect_time > 0)
1202                                 {
1203                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1204                                         if (f >= 1)
1205                                         {
1206                                                 wcross_ring_prev = ((ring_image) ? true : false);
1207                                         }
1208
1209                                         if(wcross_ring_prev)
1210                                         {
1211                                                 if(f < 1)
1212                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1213                                         }
1214                                         else
1215                                         {
1216                                                 if(f < 1)
1217                                                         ring_alpha *= bound(0, f, 1);
1218                                         }
1219                                 }
1220
1221                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1222                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1223
1224                                 if (ring_value)
1225                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1226                         }
1227
1228 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1229                         MACRO_BEGIN { \
1230                                 if(wcross_blur > 0) \
1231                                 { \
1232                                         for(i = -2; i <= 2; ++i) \
1233                                         for(j = -2; j <= 2; ++j) \
1234                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1235                                 } \
1236                                 else \
1237                                 { \
1238                                         M(0,0,sz,wcross_name,wcross_alpha); \
1239                                 } \
1240                         } MACRO_END
1241
1242 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1243                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1244
1245 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1246                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1247
1248                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1249                         {
1250                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1251                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1252                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1253                                 f = 1 - f;
1254                         }
1255                         else
1256                         {
1257                                 f = 1;
1258                         }
1259                         wcross_name_alpha_goal_prev = f;
1260
1261                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1262                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1263
1264                         if(autocvar_crosshair_dot)
1265                         {
1266                                 vector wcross_color_old;
1267                                 wcross_color_old = wcross_color;
1268
1269                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1270                                         wcross_color = stov(autocvar_crosshair_dot_color);
1271
1272                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1273                                 // FIXME why don't we use wcross_alpha here?
1274                                 wcross_color = wcross_color_old;
1275                         }
1276                 }
1277         }
1278         else
1279         {
1280                 wcross_scale_prev = 0;
1281                 wcross_alpha_prev = 0;
1282                 wcross_scale_goal_prev = 0;
1283                 wcross_alpha_goal_prev = 0;
1284                 wcross_changedonetime = 0;
1285                 if(wcross_name_goal_prev)
1286                         strunzone(wcross_name_goal_prev);
1287                 wcross_name_goal_prev = string_null;
1288                 if(wcross_name_goal_prev_prev)
1289                         strunzone(wcross_name_goal_prev_prev);
1290                 wcross_name_goal_prev_prev = string_null;
1291                 wcross_name_changestarttime = 0;
1292                 wcross_name_changedonetime = 0;
1293                 wcross_name_alpha_goal_prev = 0;
1294                 wcross_name_alpha_goal_prev_prev = 0;
1295                 wcross_resolution_goal_prev = 0;
1296                 wcross_resolution_goal_prev_prev = 0;
1297         }
1298 }
1299
1300 void HUD_Draw()
1301 {
1302         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1303         {
1304                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, MUTATOR_ARGV(0, vector), autocvar_hud_colorflash_alpha * MUTATOR_ARGV(0, float), DRAWFLAG_ADDITIVE);
1305         }
1306         else if(STAT(FROZEN))
1307         {
1308                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1309         }
1310         if(!intermission)
1311         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1312         {
1313                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1314                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1315         }
1316         else if(STAT(REVIVE_PROGRESS))
1317         {
1318                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1319                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1320         }
1321
1322         if(autocvar_r_letterbox == 0)
1323                 if(autocvar_viewsize < 120)
1324                 {
1325                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1326                                 Accuracy_LoadLevels();
1327
1328                         HUD_Main();
1329                         HUD_DrawScoreboard();
1330                 }
1331
1332         // crosshair goes VERY LAST
1333         UpdateDamage();
1334         HUD_Crosshair();
1335         HitSound();
1336 }
1337
1338 bool ov_enabled;
1339 float oldr_nearclip;
1340 float oldr_farclip_base;
1341 float oldr_farclip_world;
1342 float oldr_novis;
1343 float oldr_useportalculling;
1344 float oldr_useinfinitefarclip;
1345
1346 void cl_notice_run();
1347 float prev_myteam;
1348 int lasthud;
1349 float vh_notice_time;
1350 void WaypointSprite_Load();
1351 void CSQC_UpdateView(float w, float h)
1352 {SELFPARAM();
1353         entity e;
1354         float fov;
1355         float f;
1356         vector vf_size, vf_min;
1357         float a;
1358
1359         execute_next_frame();
1360
1361         ++framecount;
1362
1363         stats_get();
1364         hud = STAT(HUD);
1365
1366         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1367                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1368
1369         lasthud = hud;
1370
1371         if(autocvar__hud_showbinds_reload) // menu can set this one
1372         {
1373                 db_close(binddb);
1374                 binddb = db_create();
1375                 cvar_set("_hud_showbinds_reload", "0");
1376         }
1377
1378         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1379                 view_quality = getproperty(VF_MINFPS_QUALITY);
1380         else
1381                 view_quality = 1;
1382
1383         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1384         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1385
1386         vf_size = getpropertyvec(VF_SIZE);
1387         vf_min = getpropertyvec(VF_MIN);
1388         vid_width = vf_size.x;
1389         vid_height = vf_size.y;
1390
1391         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1392         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1393
1394         WaypointSprite_Load();
1395
1396         CSQCPlayer_SetCamera();
1397
1398         if(player_localentnum <= maxclients) // is it a client?
1399                 current_player = player_localentnum - 1;
1400         else // then player_localentnum is the vehicle I'm driving
1401                 current_player = player_localnum;
1402         myteam = entcs_GetTeam(current_player);
1403
1404         if(myteam != prev_myteam)
1405         {
1406                 myteamcolors = colormapPaletteColor(myteam, 1);
1407                 FOREACH(hud_panels, true, it.update_time = time);
1408                 prev_myteam = myteam;
1409         }
1410
1411         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1412
1413         float is_dead = (STAT(HEALTH) <= 0);
1414
1415         // FIXME do we need this hack?
1416         if(isdemo())
1417         {
1418                 // in demos, input_buttons do not work
1419                 button_zoom = (autocvar__togglezoom == "-");
1420         }
1421         else if(button_zoom
1422                 && autocvar_cl_unpress_zoom_on_death
1423                 && (spectatee_status >= 0)
1424                 && (is_dead || intermission))
1425         {
1426                 // no zoom while dead or in intermission please
1427                 localcmd("-zoom\n");
1428                 button_zoom = false;
1429         }
1430
1431         // event chase camera
1432         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1433         {
1434                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1435                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && STAT(ROUNDLOST));
1436                 entity gen = world;
1437
1438                 float vehicle_viewdist = 0;
1439                 vector vehicle_viewofs = '0 0 0';
1440
1441                 if(vehicle_chase)
1442                 {
1443                         if(hud != HUD_BUMBLEBEE_GUN)
1444                         {
1445                                 Vehicle info = Vehicles_from(hud);
1446                                 vehicle_viewdist = info.height;
1447                                 vehicle_viewofs = info.view_ofs;
1448                         }
1449                 }
1450
1451                 if(ons_roundlost)
1452                 {
1453                         FOREACH_ENTITY_CLASS("onslaught_generator", it.health <= 0, {
1454                                 gen = it;
1455                                 break;
1456                         });
1457                         if(!gen)
1458                                 ons_roundlost = false; // don't enforce the 3rd person camera if there is no dead generator to show
1459                 }
1460                 if(WantEventchase(self) || (!autocvar_cl_orthoview && ons_roundlost))
1461                 {
1462                         eventchase_running = true;
1463
1464                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1465                         if(!local_player)
1466                                 local_player = self; // fall back!
1467
1468                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1469                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1470                         if(ons_roundlost) { current_view_origin = gen.origin; }
1471
1472                         // detect maximum viewoffset and use it
1473                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1474                         if(vehicle_chase)
1475                         {
1476                                 if(vehicle_viewofs)
1477                                         view_offset = vehicle_viewofs;
1478                                 else
1479                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1480                         }
1481                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1482
1483                         if(view_offset)
1484                         {
1485                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1486                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1487                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1488                         }
1489
1490                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1491                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1492                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1493                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1494
1495                         // make the camera smooth back
1496                         float chase_distance = autocvar_cl_eventchase_distance;
1497                         if(vehicle_chase)
1498                         {
1499                                 if(vehicle_viewofs)
1500                                         chase_distance = vehicle_viewdist;
1501                                 else
1502                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1503                         }
1504                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1505
1506                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1507                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1508                         else if(eventchase_current_distance != chase_distance)
1509                                 eventchase_current_distance = chase_distance;
1510
1511                         makevectors(view_angles);
1512
1513                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1514                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1515
1516                         // If the boxtrace fails, revert back to line tracing.
1517                         if(!local_player.viewloc)
1518                         if(trace_startsolid)
1519                         {
1520                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1521                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1522                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1523                         }
1524                         else { setproperty(VF_ORIGIN, trace_endpos); }
1525
1526                         if(!local_player.viewloc)
1527                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1528                 }
1529                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1530                 {
1531                         eventchase_running = false;
1532                         cvar_set("chase_active", "0");
1533                         eventchase_current_distance = 0; // start from 0 next time
1534                 }
1535         }
1536         // workaround for camera stuck between player's legs when using chase_active 1
1537         // because the engine stops updating the chase_active camera when the game ends
1538         else if(intermission)
1539         {
1540                 cvar_settemp("chase_active", "-1");
1541                 eventchase_current_distance = 0;
1542         }
1543
1544         // do lockview after event chase camera so that it still applies whenever necessary.
1545         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1546         {
1547                 setproperty(VF_ORIGIN, freeze_org);
1548                 setproperty(VF_ANGLES, freeze_ang);
1549         }
1550         else
1551         {
1552                 freeze_org = getpropertyvec(VF_ORIGIN);
1553                 freeze_ang = getpropertyvec(VF_ANGLES);
1554         }
1555
1556         WarpZone_FixView();
1557         //WarpZone_FixPMove();
1558
1559         vector ov_org = '0 0 0';
1560         vector ov_mid = '0 0 0';
1561         vector ov_worldmin = '0 0 0';
1562         vector ov_worldmax = '0 0 0';
1563         if(autocvar_cl_orthoview)
1564         {
1565                 ov_worldmin = mi_picmin;
1566                 ov_worldmax = mi_picmax;
1567
1568                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1569                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1570                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1571
1572                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1573                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1574
1575                 float ov_nearest = vlen(ov_org - vec3(
1576                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1577                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1578                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1579                 ));
1580
1581                 float ov_furthest = 0;
1582                 float dist = 0;
1583
1584                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1585                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1586                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1587                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1588                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1589                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1590                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1591                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1592
1593                 if(!ov_enabled)
1594                 {
1595                         oldr_nearclip = cvar("r_nearclip");
1596                         oldr_farclip_base = cvar("r_farclip_base");
1597                         oldr_farclip_world = cvar("r_farclip_world");
1598                         oldr_novis = cvar("r_novis");
1599                         oldr_useportalculling = cvar("r_useportalculling");
1600                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1601                 }
1602
1603                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1604                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1605                 cvar_settemp("r_farclip_world", "0");
1606                 cvar_settemp("r_novis", "1");
1607                 cvar_settemp("r_useportalculling", "0");
1608                 cvar_settemp("r_useinfinitefarclip", "0");
1609
1610                 setproperty(VF_ORIGIN, ov_org);
1611                 setproperty(VF_ANGLES, '90 0 0');
1612
1613                 ov_enabled = true;
1614
1615                 #if 0
1616                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1617                         vtos(ov_org),
1618                         vtos(getpropertyvec(VF_ANGLES)),
1619                         ov_distance,
1620                         ov_nearest,
1621                         ov_furthest);
1622                 #endif
1623         }
1624         else
1625         {
1626                 if(ov_enabled)
1627                 {
1628                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1629                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1630                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1631                         cvar_set("r_novis", ftos(oldr_novis));
1632                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1633                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1634                 }
1635                 ov_enabled = false;
1636         }
1637
1638         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1639         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1640         viewmodel_draw(viewmodel);
1641
1642         // Render the Scene
1643         view_origin = getpropertyvec(VF_ORIGIN);
1644         view_angles = getpropertyvec(VF_ANGLES);
1645         makevectors(view_angles);
1646         view_forward = v_forward;
1647         view_right = v_right;
1648         view_up = v_up;
1649
1650 #ifdef BLURTEST
1651         if(time > blurtest_time0 && time < blurtest_time1)
1652         {
1653                 float r, t;
1654
1655                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1656                 r = t * blurtest_radius;
1657                 f = 1 / pow(t, blurtest_power) - 1;
1658
1659                 cvar_set("r_glsl_postprocess", "1");
1660                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1661         }
1662         else
1663         {
1664                 cvar_set("r_glsl_postprocess", "0");
1665                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1666         }
1667 #endif
1668
1669         TargetMusic_Advance();
1670         Fog_Force();
1671
1672         if(drawtime == 0)
1673                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1674         else
1675                 drawframetime = bound(0.000001, time - drawtime, 1);
1676         drawtime = time;
1677
1678         // watch for gametype changes here...
1679         // in ParseStuffCMD the cmd isn't executed yet :/
1680         // might even be better to add the gametype to TE_CSQC_INIT...?
1681         if(!postinit)
1682                 PostInit();
1683
1684         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1685         {
1686                 if(calledhooks & HOOK_START)
1687                 {
1688                         localcmd("\ncl_hook_gameend\n");
1689                         calledhooks |= HOOK_END;
1690                 }
1691         }
1692
1693         Announcer();
1694
1695         fov = autocvar_fov;
1696         if(fov <= 59.5)
1697         {
1698                 if(!zoomscript_caught)
1699                 {
1700                         localcmd("+button9\n");
1701                         zoomscript_caught = 1;
1702                 }
1703         }
1704         else
1705         {
1706                 if(zoomscript_caught)
1707                 {
1708                         localcmd("-button9\n");
1709                         zoomscript_caught = 0;
1710                 }
1711         }
1712
1713         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1714
1715         // currently switching-to weapon (for crosshair)
1716         switchingweapon = Weapons_from(STAT(SWITCHINGWEAPON));
1717
1718         // actually active weapon (for zoom)
1719         activeweapon = Weapons_from(STAT(ACTIVEWEAPON));
1720
1721         switchweapon = Weapons_from(STAT(SWITCHWEAPON));
1722
1723         f = (serverflags & SERVERFLAG_TEAMPLAY);
1724         if(f != teamplay)
1725         {
1726                 teamplay = f;
1727                 HUD_InitScores();
1728         }
1729
1730         if(last_switchweapon != switchweapon)
1731         {
1732                 weapontime = time;
1733                 last_switchweapon = switchweapon;
1734                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1735                 {
1736                         localcmd("-zoom\n");
1737                         button_zoom = false;
1738                 }
1739                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1740                 {
1741                         localcmd("-fire\n");
1742                         localcmd("-fire2\n");
1743                         button_attack2 = false;
1744                 }
1745         }
1746         if(last_activeweapon != activeweapon)
1747         {
1748                 last_activeweapon = activeweapon;
1749
1750                 e = activeweapon;
1751                 if(e.netname != "")
1752                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1753                 else
1754                         localcmd("\ncl_hook_activeweapon none\n");
1755         }
1756
1757         // ALWAYS Clear Current Scene First
1758         clearscene();
1759
1760         setproperty(VF_ORIGIN, view_origin);
1761         setproperty(VF_ANGLES, view_angles);
1762
1763         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1764         setproperty(VF_SIZE, vf_size);
1765         setproperty(VF_MIN, vf_min);
1766
1767         // Assign Standard Viewflags
1768         // Draw the World (and sky)
1769         setproperty(VF_DRAWWORLD, 1);
1770
1771         // Set the console size vars
1772         vid_conwidth = autocvar_vid_conwidth;
1773         vid_conheight = autocvar_vid_conheight;
1774         vid_pixelheight = autocvar_vid_pixelheight;
1775
1776         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1777         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1778         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1779
1780         // Camera for demo playback
1781         if(camera_active)
1782         {
1783                 if(autocvar_camera_enable)
1784                         CSQC_Demo_Camera();
1785                 else
1786                 {
1787                         cvar_set("chase_active", ftos(chase_active_backup));
1788                         cvar_set("cl_demo_mousegrab", "0");
1789                         camera_active = false;
1790                 }
1791         }
1792         else
1793         {
1794 #ifdef CAMERATEST
1795                 if(autocvar_camera_enable)
1796 #else
1797                 if(autocvar_camera_enable && isdemo())
1798 #endif
1799                 {
1800                         // Enable required Darkplaces cvars
1801                         chase_active_backup = autocvar_chase_active;
1802                         cvar_set("chase_active", "2");
1803                         cvar_set("cl_demo_mousegrab", "1");
1804                         camera_active = true;
1805                         camera_mode = false;
1806                 }
1807         }
1808
1809         // Draw the Crosshair
1810         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1811
1812         // Draw the Engine Status Bar (the default Quake HUD)
1813         setproperty(VF_DRAWENGINESBAR, 0);
1814
1815         // Update the mouse position
1816         /*
1817            mousepos_x = vid_conwidth;
1818            mousepos_y = vid_conheight;
1819            mousepos = mousepos*0.5 + getmousepos();
1820          */
1821
1822         FOREACH_ENTITY(it.draw, it.draw(it));
1823
1824         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1825         renderscene();
1826
1827         // now switch to 2D drawing mode by calling a 2D drawing function
1828         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1829         // next R_RenderScene call
1830         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1831
1832         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1833         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1834         {
1835                 // apply night vision effect
1836                 vector tc_00, tc_01, tc_10, tc_11;
1837                 vector rgb = '0 0 0';
1838
1839                 if(!nightvision_noise)
1840                 {
1841                         nightvision_noise = new(nightvision_noise);
1842                 }
1843                 if(!nightvision_noise2)
1844                 {
1845                         nightvision_noise2 = new(nightvision_noise2);
1846                 }
1847
1848                 // color tint in yellow
1849                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1850
1851                 // draw BG
1852                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1853                 rgb = '1 1 1';
1854                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1855                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1856                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1857                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1858                 tc_11 = tc_01 + tc_10 - tc_00;
1859                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1860                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1861                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1862                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1863                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1864                 R_EndPolygon();
1865
1866                 // draw FG
1867                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1868                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1869                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1870                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1871                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1872                 tc_11 = tc_01 + tc_10 - tc_00;
1873                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1874                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1875                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1876                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1877                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1878                 R_EndPolygon();
1879         }
1880
1881         if(autocvar_cl_reticle)
1882         {
1883                 Weapon wep = activeweapon;
1884                 // Draw the aiming reticle for weapons that use it
1885                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1886                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1887                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1888                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1889                 {
1890                         // no zoom reticle while dead
1891                         reticle_type = 0;
1892                 }
1893                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1894                 {
1895                         if(reticle_image != "") { reticle_type = 2; }
1896                         else { reticle_type = 0; }
1897                 }
1898                 else if(button_zoom || zoomscript_caught)
1899                 {
1900                         // normal zoom
1901                         reticle_type = 1;
1902                 }
1903
1904                 if(reticle_type)
1905                 {
1906                         if(autocvar_cl_reticle_stretch)
1907                         {
1908                                 reticle_size.x = vid_conwidth;
1909                                 reticle_size.y = vid_conheight;
1910                                 reticle_pos.x = 0;
1911                                 reticle_pos.y = 0;
1912                         }
1913                         else
1914                         {
1915                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1916                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1917                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1918                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1919                         }
1920
1921                         if(zoomscript_caught)
1922                                 f = 1;
1923                         else
1924                                 f = current_zoomfraction;
1925
1926                         if(f)
1927                         {
1928                                 switch(reticle_type)
1929                                 {
1930                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1931                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1932                                 }
1933                         }
1934                 }
1935         }
1936         else
1937         {
1938                 if(reticle_type != 0) { reticle_type = 0; }
1939         }
1940
1941
1942         // improved polyblend
1943         if(autocvar_hud_contents)
1944         {
1945                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1946                 vector liquidcolor;
1947
1948                 switch(pointcontents(view_origin))
1949                 {
1950                         case CONTENT_WATER:
1951                                 liquidalpha = autocvar_hud_contents_water_alpha;
1952                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1953                                 incontent = 1;
1954                                 break;
1955
1956                         case CONTENT_LAVA:
1957                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1958                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1959                                 incontent = 1;
1960                                 break;
1961
1962                         case CONTENT_SLIME:
1963                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1964                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1965                                 incontent = 1;
1966                                 break;
1967
1968                         default:
1969                                 liquidalpha = 0;
1970                                 liquidcolor = '0 0 0';
1971                                 incontent = 0;
1972                                 break;
1973                 }
1974
1975                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1976                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1977                         contentfadetime = autocvar_hud_contents_fadeintime;
1978                         liquidalpha_prev = liquidalpha;
1979                         liquidcolor_prev = liquidcolor;
1980                 }
1981                 else
1982                         contentfadetime = autocvar_hud_contents_fadeouttime;
1983
1984                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1985                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1986
1987                 if(contentavgalpha)
1988                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1989
1990                 if(autocvar_hud_postprocessing)
1991                 {
1992                         if(autocvar_hud_contents_blur && contentavgalpha)
1993                         {
1994                                 content_blurpostprocess.x = 1;
1995                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1996                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1997                         }
1998                         else
1999                         {
2000                                 content_blurpostprocess.x = 0;
2001                                 content_blurpostprocess.y = 0;
2002                                 content_blurpostprocess.z = 0;
2003                         }
2004                 }
2005         }
2006
2007         if(autocvar_hud_damage && !STAT(FROZEN))
2008         {
2009                 splash_size.x = max(vid_conwidth, vid_conheight);
2010                 splash_size.y = max(vid_conwidth, vid_conheight);
2011                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2012                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2013
2014                 float myhealth_flash_temp;
2015                 myhealth = STAT(HEALTH);
2016
2017                 // fade out
2018                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2019                 // add new damage
2020                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2021
2022                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2023                 pain_threshold = autocvar_hud_damage_pain_threshold;
2024                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2025                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2026
2027                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2028                 {
2029                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2030                 }
2031
2032                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2033
2034                 if(myhealth_prev < 1)
2035                 {
2036                         if(myhealth >= 1)
2037                         {
2038                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2039                                 myhealth_flash_temp = 0;
2040                         }
2041                         else
2042                         {
2043                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2044                         }
2045                 }
2046
2047                 if(spectatee_status == -1 || intermission)
2048                 {
2049                         myhealth_flash = 0; // observing, or match ended
2050                         myhealth_flash_temp = 0;
2051                 }
2052
2053                 myhealth_prev = myhealth;
2054
2055                 // IDEA: change damage color/picture based on player model for robot/alien species?
2056                 // pro: matches model better
2057                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2058                 // maybe different reddish pics?
2059                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2060                 {
2061                         if(autocvar_cl_gentle_damage == 2)
2062                         {
2063                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2064                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2065                         }
2066                         else
2067                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2068
2069                         if(myhealth_flash_temp > 0)
2070                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2071                 }
2072                 else if(myhealth_flash_temp > 0)
2073                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2074
2075                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2076                 {
2077                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2078                         {
2079                                 damage_blurpostprocess.x = 1;
2080                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2081                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2082                         }
2083                         else
2084                         {
2085                                 damage_blurpostprocess.x = 0;
2086                                 damage_blurpostprocess.y = 0;
2087                                 damage_blurpostprocess.z = 0;
2088                         }
2089                 }
2090         }
2091
2092         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2093         float e2 = (autocvar_hud_powerup != 0);
2094         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2095         {
2096                 // enable or disable rendering types if they are used or not
2097                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2098                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2099
2100                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2101                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2102                 {
2103                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2104                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2105                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2106                         {
2107                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2108                                 old_blurradius = blurradius;
2109                                 old_bluralpha = bluralpha;
2110                         }
2111                 }
2112                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2113                 {
2114                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2115                         old_blurradius = 0;
2116                         old_bluralpha = 0;
2117                 }
2118
2119                 // edge detection postprocess handling done second (used by hud_powerup)
2120                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2121                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2122                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2123
2124                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2125
2126                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2127                 {
2128                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2129                         {
2130                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2131                                 old_sharpen_intensity = sharpen_intensity;
2132                         }
2133                 }
2134                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2135                 {
2136                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2137                         old_sharpen_intensity = 0;
2138                 }
2139
2140                 if(cvar("r_glsl_postprocess") == 0)
2141                         cvar_set("r_glsl_postprocess", "2");
2142         }
2143         else if(cvar("r_glsl_postprocess") == 2)
2144                 cvar_set("r_glsl_postprocess", "0");
2145
2146         /*if(gametype == MAPINFO_TYPE_CTF)
2147           {
2148           ctf_view();
2149           } else */
2150
2151         // draw 2D entities
2152         FOREACH_ENTITY(it.draw2d, it.draw2d(it));
2153         Draw_ShowNames_All();
2154         Debug_Draw();
2155
2156         scoreboard_active = HUD_WouldDrawScoreboard();
2157
2158         HUD_Draw();
2159
2160         if(NextFrameCommand)
2161         {
2162                 localcmd("\n", NextFrameCommand, "\n");
2163                 NextFrameCommand = string_null;
2164         }
2165
2166         // we must do this check AFTER a frame was rendered, or it won't work
2167         if(cs_project_is_b0rked == 0)
2168         {
2169                 string w0, h0;
2170                 w0 = ftos(autocvar_vid_conwidth);
2171                 h0 = ftos(autocvar_vid_conheight);
2172                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2173                 //setproperty(VF_FOV, '90 90 0');
2174                 setproperty(VF_ORIGIN, '0 0 0');
2175                 setproperty(VF_ANGLES, '0 0 0');
2176                 setproperty(VF_PERSPECTIVE, 1);
2177                 makevectors('0 0 0');
2178                 vector v1, v2;
2179                 cvar_set("vid_conwidth", "800");
2180                 cvar_set("vid_conheight", "600");
2181                 v1 = cs_project(v_forward);
2182                 cvar_set("vid_conwidth", "640");
2183                 cvar_set("vid_conheight", "480");
2184                 v2 = cs_project(v_forward);
2185                 if(v1 == v2)
2186                         cs_project_is_b0rked = 1;
2187                 else
2188                         cs_project_is_b0rked = -1;
2189                 cvar_set("vid_conwidth", w0);
2190                 cvar_set("vid_conheight", h0);
2191         }
2192
2193         if(autocvar__hud_configure)
2194                 HUD_Panel_Mouse();
2195         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
2196                 HUD_Minigame_Mouse();
2197         else if(QuickMenu_IsOpened())
2198                 QuickMenu_Mouse();
2199         else
2200                 HUD_Radar_Mouse();
2201
2202         cl_notice_run();
2203         unpause_update();
2204         Net_Flush();
2205
2206         // let's reset the view back to normal for the end
2207         setproperty(VF_MIN, '0 0 0');
2208         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2209 }
2210
2211
2212 // following vectors must be global to allow seamless switching between camera modes
2213 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2214 void CSQC_Demo_Camera()
2215 {
2216         float speed, attenuation, dimensions;
2217         vector tmp, delta;
2218
2219         if( autocvar_camera_reset || !camera_mode )
2220         {
2221                 camera_offset = '0 0 0';
2222                 current_angles = '0 0 0';
2223                 camera_direction = '0 0 0';
2224                 camera_offset.z += 30;
2225                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2226                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2227                 current_origin = view_origin;
2228                 current_camera_offset  = camera_offset;
2229                 cvar_set("camera_reset", "0");
2230                 camera_mode = CAMERA_CHASE;
2231         }
2232
2233         // Camera angles
2234         if( camera_roll )
2235                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2236
2237         if(autocvar_camera_look_player)
2238         {
2239                 vector dir;
2240                 float n;
2241
2242                 dir = normalize(view_origin - current_position);
2243                 n = mouse_angles.z;
2244                 mouse_angles = vectoangles(dir);
2245                 mouse_angles.x = mouse_angles.x * -1;
2246                 mouse_angles.z = n;
2247         }
2248         else
2249         {
2250                 tmp = getmousepos() * 0.1;
2251                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2252                 {
2253                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2254                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2255                 }
2256         }
2257
2258         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2259         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2260         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2261         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2262
2263         // Fix difference when angles don't have the same sign
2264         delta = '0 0 0';
2265         if(mouse_angles.y < -60 && current_angles.y > 60)
2266                 delta = '0 360 0';
2267         if(mouse_angles.y > 60 && current_angles.y < -60)
2268                 delta = '0 -360 0';
2269
2270         if(autocvar_camera_look_player)
2271                 attenuation = autocvar_camera_look_attenuation;
2272         else
2273                 attenuation = autocvar_camera_speed_attenuation;
2274
2275         attenuation = 1 / max(1, attenuation);
2276         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2277
2278         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2279         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2280         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2281         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2282
2283         // Camera position
2284         tmp = '0 0 0';
2285         dimensions = 0;
2286
2287         if( camera_direction.x )
2288         {
2289                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2290                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2291                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2292                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2293                 ++dimensions;
2294         }
2295
2296         if( camera_direction.y )
2297         {
2298                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2299                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2300                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2301                 ++dimensions;
2302         }
2303
2304         if( camera_direction.z )
2305         {
2306                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2307                 ++dimensions;
2308         }
2309
2310         if(autocvar_camera_free)
2311                 speed = autocvar_camera_speed_free;
2312         else
2313                 speed = autocvar_camera_speed_chase;
2314
2315         if(dimensions)
2316         {
2317                 speed = speed * sqrt(1 / dimensions);
2318                 camera_offset += tmp * speed;
2319         }
2320
2321         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2322
2323         // Camera modes
2324         if( autocvar_camera_free )
2325         {
2326                 if ( camera_mode == CAMERA_CHASE )
2327                 {
2328                         current_camera_offset = current_origin + current_camera_offset;
2329                         camera_offset = current_origin + camera_offset;
2330                 }
2331
2332                 camera_mode = CAMERA_FREE;
2333                 current_position = current_camera_offset;
2334         }
2335         else
2336         {
2337                 if ( camera_mode == CAMERA_FREE )
2338                 {
2339                         current_origin = view_origin;
2340                         camera_offset = camera_offset - current_origin;
2341                         current_camera_offset = current_camera_offset - current_origin;
2342                 }
2343
2344                 camera_mode = CAMERA_CHASE;
2345
2346                 if(autocvar_camera_chase_smoothly)
2347                         current_origin += (view_origin - current_origin) * attenuation;
2348                 else
2349                         current_origin = view_origin;
2350
2351                 current_position = current_origin + current_camera_offset;
2352         }
2353
2354         setproperty(VF_ANGLES, current_angles);
2355         setproperty(VF_ORIGIN, current_position);
2356 }