qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "announcer.qh"
   4 #include "hud/_mod.qh"
   5 #include "mapvoting.qh"
   6 #include "shownames.qh"
   7 #include "hud/panel/scoreboard.qh"
   8 #include "hud/panel/quickmenu.qh"
   9
  10 #include "mutators/events.qh"
  11
  12 #include <common/animdecide.qh>
  13 #include <common/ent_cs.qh>
  14 #include <common/anim.qh>
  15 #include <common/constants.qh>
  16 #include <common/net_linked.qh>
  17 #include <common/debug.qh>
  18 #include <common/mapinfo.qh>
  19 #include <common/gamemodes/_mod.qh>
  20 #include <common/physics/player.qh>
  21 #include <common/stats.qh>
  22 #include <common/triggers/target/music.qh>
  23 #include <common/teams.qh>
  24
  25 #include <common/weapons/weapon/tuba.qh>
  26
  27 #include <common/vehicles/all.qh>
  28 #include <common/weapons/_all.qh>
  29 #include <common/mutators/mutator/overkill/okvortex.qh>
  30 #include <common/viewloc.qh>
  31 #include <common/minigames/cl_minigames.qh>
  32 #include <common/minigames/cl_minigames_hud.qh>
  33
  34 #include <lib/csqcmodel/cl_player.qh>
  35 #include <lib/csqcmodel/cl_model.qh>
  36 #include "csqcmodel_hooks.qh"
  37
  38 #include <lib/warpzone/client.qh>
  39 #include <lib/warpzone/common.qh>
  40
  41 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  42
  43 float autocvar_cl_viewmodel_scale;
  44
  45 bool autocvar_cl_bobmodel;
  46 float autocvar_cl_bobmodel_speed;
  47 float autocvar_cl_bobmodel_side;
  48 float autocvar_cl_bobmodel_up;
  49
  50 float autocvar_cl_followmodel;
  51 float autocvar_cl_followmodel_speed = 0.3;
  52 float autocvar_cl_followmodel_limit = 135;
  53 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  54 float autocvar_cl_followmodel_highpass = 0.05;
  55 float autocvar_cl_followmodel_lowpass = 0.03;
  56 bool autocvar_cl_followmodel_velocity_absolute;
  57
  58 float autocvar_cl_leanmodel;
  59 float autocvar_cl_leanmodel_speed = 0.3;
  60 float autocvar_cl_leanmodel_limit = 30;
  61 float autocvar_cl_leanmodel_highpass1 = 0.2;
  62 float autocvar_cl_leanmodel_highpass = 0.2;
  63 float autocvar_cl_leanmodel_lowpass = 0.05;
  64
  65 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  66 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  67 { \
  68         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
  69 } MACRO_END
  70
  71 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  72 { \
  73         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  74         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  75 } MACRO_END
  76
  77 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  78 { \
  79         float __f = 0; lowpass(value, frac, ref_store, __f); \
  80         ret = (value) - __f; \
  81 } MACRO_END
  82
  83 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  84 { \
  85         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  86         ret = (value) - __f; \
  87 } MACRO_END
  88
  89 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  90 { \
  91         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  92         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  93 } MACRO_END
  94
  95 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  96 { \
  97         highpass(value.x, frac, ref_store.x, ref_out.x); \
  98         highpass(value.y, frac, ref_store.y, ref_out.y); \
  99 } MACRO_END
 100
 101 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 102 { \
 103         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 104         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 105 } MACRO_END
 106
 107 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 108 { \
 109         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 110         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 111         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 112 } MACRO_END
 113
 114 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 115 { \
 116         highpass(value.x, frac, ref_store.x, ref_out.x); \
 117         highpass(value.y, frac, ref_store.y, ref_out.y); \
 118         highpass(value.z, frac, ref_store.z, ref_out.z); \
 119 } MACRO_END
 120
 121 void calc_followmodel_ofs(entity view)
 122 {
 123         if(cl_followmodel_time == time)
 124                 return; // cl_followmodel_ofs already calculated for this frame
 125
 126         float frac;
 127         vector gunorg = '0 0 0';
 128         static vector vel_average;
 129         static vector gunorg_adjustment_highpass;
 130         static vector gunorg_adjustment_lowpass;
 131
 132         vector vel;
 133         if (autocvar_cl_followmodel_velocity_absolute)
 134                 vel = view.velocity;
 135         else
 136         {
 137                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 138                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 139                 vel.x = view.velocity * forward;
 140                 vel.y = view.velocity * right * -1;
 141                 vel.z = view.velocity * up;
 142         }
 143
 144         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 145         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 146         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 147
 148         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 149         lowpass3(vel, frac, vel_average, gunorg);
 150
 151         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 152
 153         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 154         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 155         frac = avg_factor(autocvar_cl_followmodel_highpass);
 156         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 157         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 158         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 159
 160         if (autocvar_cl_followmodel_velocity_absolute)
 161         {
 162                 vector fixed_gunorg;
 163                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 164                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 165                 fixed_gunorg.x = gunorg * forward;
 166                 fixed_gunorg.y = gunorg * right * -1;
 167                 fixed_gunorg.z = gunorg * up;
 168                 gunorg = fixed_gunorg;
 169         }
 170
 171         cl_followmodel_ofs = gunorg;
 172         cl_followmodel_time = time;
 173 }
 174
 175 vector leanmodel_ofs(entity view)
 176 {
 177         float frac;
 178         vector gunangles = '0 0 0';
 179         static vector gunangles_prev = '0 0 0';
 180         static vector gunangles_highpass = '0 0 0';
 181         static vector gunangles_adjustment_highpass;
 182         static vector gunangles_adjustment_lowpass;
 183
 184         if (view.csqcmodel_teleported)
 185                 gunangles_prev = view_angles;
 186
 187         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 188         gunangles_highpass += gunangles_prev;
 189         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 190         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 191         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 192         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 193         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 194         gunangles_prev = view_angles;
 195         gunangles_highpass -= gunangles_prev;
 196
 197         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 198         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 199
 200         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 201         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 202         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 203         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 204         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 205
 206         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 207
 208         return gunangles;
 209 }
 210
 211 vector bobmodel_ofs(entity view)
 212 {
 213         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 214         static bool oldonground;
 215         static float hitgroundtime;
 216         if (clonground)
 217         {
 218                 float f = time; // cl.movecmd[0].time
 219                 if (!oldonground)
 220                         hitgroundtime = f;
 221         }
 222         oldonground = clonground;
 223
 224         // calculate for swinging gun model
 225         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 226         vector gunorg = '0 0 0';
 227         static float bobmodel_scale = 0;
 228         static float time_ofs = 0; // makes the effect always restart in the same way
 229         if (clonground)
 230         {
 231                 if (time - hitgroundtime > 0.05)
 232                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 233         }
 234         else
 235                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 236
 237         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 238         if (bobmodel_scale && xyspeed)
 239         {
 240                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 241                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 242                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 243                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 244         }
 245         else
 246                 time_ofs = time;
 247
 248         return gunorg;
 249 }
 250
 251 void viewmodel_animate(entity this)
 252 {
 253         if (autocvar_chase_active) return;
 254         if (STAT(HEALTH) <= 0) return;
 255
 256         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 257
 258         if (autocvar_cl_followmodel)
 259         {
 260                 calc_followmodel_ofs(view);
 261                 this.origin += cl_followmodel_ofs;
 262         }
 263
 264         if (autocvar_cl_leanmodel)
 265                 this.angles += leanmodel_ofs(view);
 266
 267         // vertical view bobbing code
 268         // TODO: cl_bob
 269
 270         // horizontal view bobbing code
 271         // TODO: cl_bob2
 272
 273         // fall bobbing code
 274         // causes the view to swing down and back up when touching the ground
 275         // TODO: cl_bobfall
 276
 277         // gun model bobbing code
 278         if (autocvar_cl_bobmodel)
 279                 this.origin += bobmodel_ofs(view);
 280 }
 281
 282 .vector viewmodel_origin, viewmodel_angles;
 283 .float weapon_nextthink;
 284 .float weapon_eta_last;
 285 .float weapon_switchdelay;
 286
 287 .string name_last;
 288
 289 void viewmodel_draw(entity this)
 290 {
 291         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 292                 return;
 293         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 294         float a = this.alpha;
 295         static bool wasinvehicle;
 296         bool invehicle = player_localentnum > maxclients;
 297         if (invehicle) a = -1;
 298         else if (wasinvehicle) a = 1;
 299         wasinvehicle = invehicle;
 300         Weapon wep = this.activeweapon;
 301         int c = entcs_GetClientColors(current_player);
 302         vector g = weaponentity_glowmod(wep, NULL, c, this);
 303         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 304         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 305                 | EF_NODEPTHTEST)
 306                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 307         for (entity e = this; e; e = e.weaponchild)
 308         {
 309                 e.drawmask = mask;
 310                 e.alpha = a;
 311                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 312                 e.glowmod = g;
 313                 e.csqcmodel_effects = fx;
 314                 CSQCModel_Effects_Apply(e);
 315         }
 316         {
 317                 string name = wep.mdl;
 318                 string newname = wep.wr_viewmodel(wep, this);
 319                 if(newname)
 320                         name = newname;
 321                 bool swap = name != this.name_last;
 322                 // if (swap)
 323                 {
 324                         this.name_last = name;
 325                         CL_WeaponEntity_SetModel(this, name, swap);
 326                         this.viewmodel_origin = this.origin;
 327                         this.viewmodel_angles = this.angles;
 328                 }
 329                 anim_update(this);
 330                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 331                         anim_set(this, this.anim_idle, true, false, false);
 332         }
 333         float f = 0; // 0..1; 0: fully active
 334         float rate = STAT(WEAPONRATEFACTOR);
 335         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 336         if (eta <= 0) f = this.weapon_eta_last;
 337         else switch (this.state)
 338         {
 339                 case WS_RAISE:
 340                 {
 341                         f = eta / max(eta, this.weapon_switchdelay);
 342                         break;
 343                 }
 344                 case WS_DROP:
 345                 {
 346                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 347                         break;
 348                 }
 349                 case WS_CLEAR:
 350                 {
 351                         f = 1;
 352                         break;
 353                 }
 354         }
 355         this.weapon_eta_last = f;
 356         this.origin = this.viewmodel_origin;
 357         this.angles = this.viewmodel_angles;
 358         this.angles_x = (-90 * f * f);
 359         viewmodel_animate(this);
 360         MUTATOR_CALLHOOK(DrawViewModel, this);
 361         setorigin(this, this.origin);
 362 }
 363
 364 STATIC_INIT(viewmodel) {
 365     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 366         viewmodels[slot] = new(viewmodel);
 367 }
 368
 369 void Porto_Draw(entity this);
 370 STATIC_INIT(Porto)
 371 {
 372         entity e = new_pure(porto);
 373         e.draw = Porto_Draw;
 374         IL_PUSH(g_drawables, e);
 375         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 376 }
 377
 378 const int polyline_length = 16;
 379 .vector polyline[polyline_length];
 380 void Porto_Draw(entity this)
 381 {
 382         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 383         {
 384                 entity wepent = viewmodels[slot];
 385
 386                 if (wepent.activeweapon != WEP_PORTO) continue;
 387                 if (spectatee_status) continue;
 388                 if (WEP_CVAR(porto, secondary)) continue;
 389                 if (intermission == 1) continue;
 390                 if (intermission == 2) continue;
 391                 if (STAT(HEALTH) <= 0) continue;
 392
 393                 vector pos = view_origin;
 394                 vector dir = view_forward;
 395                 if (wepent.angles_held_status)
 396                 {
 397                         makevectors(wepent.angles_held);
 398                         dir = v_forward;
 399                 }
 400
 401                 wepent.polyline[0] = pos;
 402
 403                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 404                 int n = 1 + 2;  // 2 lines == 3 points
 405                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 406                 {
 407                         traceline(pos, pos + 65536 * dir, true, this);
 408                         dir = reflect(dir, trace_plane_normal);
 409                         pos = trace_endpos;
 410                         wepent.polyline[++idx] = pos;
 411                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 412                         {
 413                                 n += 1;
 414                                 continue;
 415                         }
 416                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 417                         {
 418                                 n = max(2, idx);
 419                                 break;
 420                         }
 421                         // check size
 422                         {
 423                                 vector ang = vectoangles2(trace_plane_normal, dir);
 424                                 ang.x = -ang.x;
 425                                 makevectors(ang);
 426                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 427                                 {
 428                                         n = max(2, idx);
 429                                         break;
 430                                 }
 431                         }
 432                         portal_number += 1;
 433                         if (portal_number >= portal_max) break;
 434                         if (portal_number == 1) portal1_idx = idx;
 435                 }
 436                 for (int idx = 0; idx < n - 1; ++idx)
 437                 {
 438                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 439                         if (idx == 0) p -= view_up * 16;  // line from player
 440                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 441                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 442                 }
 443         }
 444 }
 445
 446 float drawtime;
 447 float avgspeed;
 448 vector GetCurrentFov(float fov)
 449 {
 450         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 451         float velocityzoom, curspeed;
 452         vector v;
 453
 454         zoomsensitivity = autocvar_cl_zoomsensitivity;
 455         zoomfactor = autocvar_cl_zoomfactor;
 456         if(zoomfactor < 1 || zoomfactor > 30)
 457                 zoomfactor = 2.5;
 458         zoomspeed = autocvar_cl_zoomspeed;
 459         if(zoomspeed >= 0)
 460         if(zoomspeed < 0.5 || zoomspeed > 16)
 461                         zoomspeed = 3.5;
 462
 463         zoomdir = button_zoom;
 464
 465         if(hud == HUD_NORMAL && !spectatee_status)
 466         {
 467                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 468                 {
 469                         entity wepent = viewmodels[slot];
 470                         if(wepent.switchweapon == wepent.activeweapon)
 471                         if((wepent.activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (wepent.activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary)) || (wepent.activeweapon == WEP_OVERKILL_VORTEX && !WEP_CVAR(okvortex, secondary))) // do NOT use switchweapon here
 472                                 zoomdir += button_attack2;
 473                 }
 474         }
 475         if(spectatee_status > 0 || isdemo())
 476         {
 477                 if(spectatorbutton_zoom)
 478                 {
 479                         if(zoomdir)
 480                                 zoomdir = 0;
 481                         else
 482                                 zoomdir = 1;
 483                 }
 484                 // fteqcc failed twice here already, don't optimize this
 485         }
 486
 487         if(zoomdir) { zoomin_effect = 0; }
 488
 489         if(camera_active)
 490         {
 491                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 492         }
 493         else if(autocvar_cl_spawnzoom && zoomin_effect)
 494         {
 495                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 496
 497                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 498                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 499                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 500         }
 501         else
 502         {
 503                 if(zoomspeed < 0) // instant zoom
 504                 {
 505                         if(zoomdir)
 506                                 current_viewzoom = 1 / zoomfactor;
 507                         else
 508                                 current_viewzoom = 1;
 509                 }
 510                 else
 511                 {
 512                         if(zoomdir)
 513                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 514                         else
 515                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 516                 }
 517         }
 518
 519         if(almost_equals(current_viewzoom, 1))
 520                 current_zoomfraction = 0;
 521         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 522                 current_zoomfraction = 1;
 523         else
 524                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 525
 526         if(zoomsensitivity < 1)
 527                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 528         else
 529                 setsensitivityscale(1);
 530
 531         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 532         {
 533                 if(intermission) { curspeed = 0; }
 534                 else
 535                 {
 536
 537                         makevectors(view_angles);
 538                         v = pmove_vel;
 539                         if(csqcplayer)
 540                                 v = csqcplayer.velocity;
 541
 542                         switch(autocvar_cl_velocityzoom_type)
 543                         {
 544                                 case 3: curspeed = max(0, v_forward * v); break;
 545                                 case 2: curspeed = (v_forward * v); break;
 546                                 case 1: default: curspeed = vlen(v); break;
 547                         }
 548                 }
 549
 550                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 551                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 552                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 553
 554                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 555         }
 556         else
 557                 velocityzoom = 1;
 558
 559         float frustumx, frustumy, fovx, fovy;
 560         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 561         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 562         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 563         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 564
 565         return '1 0 0' * fovx + '0 1 0' * fovy;
 566 }
 567
 568 vector GetViewLocationFOV(float fov)
 569 {
 570         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 571         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 572         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 573         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 574         return '1 0 0' * fovx + '0 1 0' * fovy;
 575 }
 576
 577 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 578 {
 579         float fovx, fovy;
 580         float width = (ov_worldmax.x - ov_worldmin.x);
 581         float height = (ov_worldmax.y - ov_worldmin.y);
 582         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 583         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 584         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 585         return '1 0 0' * fovx + '0 1 0' * fovy;
 586 }
 587
 588 // this function must match W_SetupShot!
 589 float zoomscript_caught;
 590
 591 vector wcross_origin;
 592 float wcross_scale_prev, wcross_alpha_prev;
 593 vector wcross_color_prev;
 594 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 595 vector wcross_color_goal_prev;
 596 float wcross_changedonetime;
 597
 598 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 599 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 600 float wcross_name_changestarttime, wcross_name_changedonetime;
 601 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 602
 603 float wcross_ring_prev;
 604
 605 entity trueaim;
 606 entity trueaim_rifle;
 607
 608 const float SHOTTYPE_HITTEAM = 1;
 609 const float SHOTTYPE_HITOBSTRUCTION = 2;
 610 const float SHOTTYPE_HITWORLD = 3;
 611 const float SHOTTYPE_HITENEMY = 4;
 612
 613 void TrueAim_Init()
 614 {
 615         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 616         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 617 }
 618
 619 float EnemyHitCheck()
 620 {
 621         float t, n;
 622         wcross_origin = project_3d_to_2d(trace_endpos);
 623         wcross_origin.z = 0;
 624         if(trace_ent)
 625                 n = trace_ent.entnum;
 626         else
 627                 n = trace_networkentity;
 628         if(n < 1)
 629                 return SHOTTYPE_HITWORLD;
 630         if(n > maxclients)
 631                 return SHOTTYPE_HITWORLD;
 632         t = entcs_GetTeam(n - 1);
 633         if(teamplay)
 634                 if(t == myteam)
 635                         return SHOTTYPE_HITTEAM;
 636         if(t == NUM_SPECTATOR)
 637                 return SHOTTYPE_HITWORLD;
 638         return SHOTTYPE_HITENEMY;
 639 }
 640
 641 float TrueAimCheck(entity wepent)
 642 {
 643         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 644         vector vecs, trueaimpoint, w_shotorg;
 645         vector mi, ma, dv;
 646         float shottype;
 647         entity ta;
 648         float mv;
 649
 650         mi = ma = '0 0 0';
 651         ta = trueaim;
 652         mv = MOVE_NOMONSTERS;
 653
 654         switch(wepent.activeweapon) // WEAPONTODO
 655         {
 656                 case WEP_TUBA: // no aim
 657                 case WEP_PORTO: // shoots from eye
 658                 case WEP_NEXBALL: // shoots from eye
 659                 case WEP_HOOK: // no trueaim
 660                 case WEP_MORTAR: // toss curve
 661                         return SHOTTYPE_HITWORLD;
 662                 case WEP_VORTEX:
 663                 case WEP_OVERKILL_VORTEX:
 664                 case WEP_VAPORIZER:
 665                         mv = MOVE_NORMAL;
 666                         break;
 667                 case WEP_RIFLE:
 668                         ta = trueaim_rifle;
 669                         mv = MOVE_NORMAL;
 670                         if(zoomscript_caught)
 671                         {
 672                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 673                                 return EnemyHitCheck();
 674                         }
 675                         break;
 676                 case WEP_DEVASTATOR: // projectile has a size!
 677                         mi = '-3 -3 -3';
 678                         ma = '3 3 3';
 679                         break;
 680                 case WEP_FIREBALL: // projectile has a size!
 681                         mi = '-16 -16 -16';
 682                         ma = '16 16 16';
 683                         break;
 684                 case WEP_SEEKER: // projectile has a size!
 685                         mi = '-2 -2 -2';
 686                         ma = '2 2 2';
 687                         break;
 688                 case WEP_ELECTRO: // projectile has a size!
 689                         mi = '0 0 -3';
 690                         ma = '0 0 -3';
 691                         break;
 692         }
 693
 694         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 695
 696         vecs = decompressShotOrigin(STAT(SHOTORG));
 697
 698         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 699         trueaimpoint = trace_endpos;
 700
 701         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 702                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 703
 704         if(vecs.x > 0)
 705                 vecs.y = -vecs.y;
 706         else
 707                 vecs = '0 0 0';
 708
 709         dv = view_right * vecs.y + view_up * vecs.z;
 710         w_shotorg = traceorigin + dv;
 711
 712         // now move the vecs forward as much as requested if possible
 713         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 714         w_shotorg = trace_endpos - view_forward * nudge;
 715
 716         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 717         shottype = EnemyHitCheck();
 718         if(shottype != SHOTTYPE_HITWORLD)
 719                 return shottype;
 720
 721 #if 0
 722         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 723         // or rather, I know why, but see no fix
 724         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 725                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 726                 return SHOTTYPE_HITOBSTRUCTION;
 727 #endif
 728
 729         return SHOTTYPE_HITWORLD;
 730 }
 731
 732 void PostInit();
 733 void CSQC_Demo_Camera();
 734 float camera_mode;
 735 const float CAMERA_FREE = 1;
 736 const float CAMERA_CHASE = 2;
 737 float reticle_type;
 738 string NextFrameCommand;
 739
 740 vector freeze_org, freeze_ang;
 741 entity nightvision_noise, nightvision_noise2;
 742
 743 const float MAX_TIME_DIFF = 5;
 744 float pickup_crosshair_time, pickup_crosshair_size;
 745 float hitindication_crosshair_size;
 746 float use_vortex_chargepool;
 747
 748 float myhealth, myhealth_prev;
 749 float myhealth_flash;
 750
 751 float old_blurradius, old_bluralpha;
 752 float old_sharpen_intensity;
 753
 754 vector myhealth_gentlergb;
 755
 756 float contentavgalpha, liquidalpha_prev;
 757 vector liquidcolor_prev;
 758
 759 float eventchase_current_distance;
 760 float eventchase_running;
 761 bool WantEventchase(entity this)
 762 {
 763         if(autocvar_cl_orthoview)
 764                 return false;
 765         if(STAT(GAME_STOPPED) || intermission)
 766                 return true;
 767         if(this.viewloc)
 768                 return true;
 769         if(spectatee_status >= 0)
 770         {
 771                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 772                         return true;
 773                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 774                         return true;
 775                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 776                 {
 777                         if(autocvar_cl_eventchase_death == 2)
 778                         {
 779                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 780                                 if(this.velocity == '0 0 0' || eventchase_running)
 781                                         return true;
 782                         }
 783                         else return true;
 784                 }
 785         }
 786         return false;
 787 }
 788
 789 void HUD_Crosshair_Vehicle(entity this)
 790 {
 791         if(hud != HUD_BUMBLEBEE_GUN)
 792         {
 793                 Vehicle info = Vehicles_from(hud);
 794                 info.vr_crosshair(info, this);
 795         }
 796 }
 797
 798 vector damage_blurpostprocess, content_blurpostprocess;
 799
 800 float unaccounted_damage = 0;
 801 void UpdateDamage()
 802 {
 803         // accumulate damage with each stat update
 804         static float damage_total_prev = 0;
 805         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 806         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 807         damage_total_prev = damage_total;
 808
 809         static float damage_dealt_time_prev = 0;
 810         float damage_dealt_time = STAT(HIT_TIME);
 811         if (damage_dealt_time != damage_dealt_time_prev)
 812         {
 813                 unaccounted_damage += unaccounted_damage_new;
 814                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 815         }
 816         damage_dealt_time_prev = damage_dealt_time;
 817
 818         // prevent hitsound when switching spectatee
 819         static float spectatee_status_prev = 0;
 820         if (spectatee_status != spectatee_status_prev)
 821                 unaccounted_damage = 0;
 822         spectatee_status_prev = spectatee_status;
 823 }
 824
 825 void HitSound()
 826 {
 827         // varying sound pitch
 828
 829         bool have_arc = false;
 830         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 831         {
 832                 entity wepent = viewmodels[slot];
 833
 834                 if(wepent.activeweapon == WEP_ARC)
 835                         have_arc = true;
 836         }
 837
 838         static float hitsound_time_prev = 0;
 839         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 840         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 841         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 842         {
 843                 if (autocvar_cl_hitsound && unaccounted_damage)
 844                 {
 845                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 846                         float a = autocvar_cl_hitsound_max_pitch;
 847                         float b = autocvar_cl_hitsound_min_pitch;
 848                         float c = autocvar_cl_hitsound_nom_damage;
 849                         float d = unaccounted_damage;
 850                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 851
 852                         // if sound variation is disabled, set pitch_shift to 1
 853                         if (autocvar_cl_hitsound == 1)
 854                                 pitch_shift = 1;
 855
 856                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 857                         if (autocvar_cl_hitsound == 3)
 858                         {
 859                                 float mirror_value = (a-b)/2 + b;
 860                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 861                         }
 862
 863                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 864
 865                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 866                         // todo: normalize sound pressure levels? seems unnecessary
 867
 868                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 869                 }
 870                 unaccounted_damage = 0;
 871                 hitsound_time_prev = time;
 872         }
 873
 874         static float typehit_time_prev = 0;
 875         float typehit_time = STAT(TYPEHIT_TIME);
 876         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 877         {
 878                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 879                 typehit_time_prev = typehit_time;
 880         }
 881
 882         static float kill_time_prev = 0;
 883         float kill_time = STAT(KILL_TIME);
 884         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 885         {
 886                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 887                 kill_time_prev = kill_time;
 888         }
 889 }
 890
 891 vector crosshair_getcolor(entity this, float health_stat)
 892 {
 893         static float rainbow_last_flicker;
 894         static vector rainbow_prev_color;
 895         vector wcross_color = '0 0 0';
 896         switch(autocvar_crosshair_color_special)
 897         {
 898                 case 1: // crosshair_color_per_weapon
 899                 {
 900                         if(this != WEP_Null && hud == HUD_NORMAL)
 901                         {
 902                                 wcross_color = this.wpcolor;
 903                                 break;
 904                         }
 905                         else { goto normalcolor; }
 906                 }
 907
 908                 case 2: // crosshair_color_by_health
 909                 {
 910                         float hp = health_stat;
 911
 912                         //x = red
 913                         //y = green
 914                         //z = blue
 915
 916                         wcross_color.z = 0;
 917
 918                         if(hp > 200)
 919                         {
 920                                 wcross_color.x = 0;
 921                                 wcross_color.y = 1;
 922                         }
 923                         else if(hp > 150)
 924                         {
 925                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 926                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 927                         }
 928                         else if(hp > 100)
 929                         {
 930                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 931                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 932                                 wcross_color.z = 1 - (hp-100)*0.02;
 933                         }
 934                         else if(hp > 50)
 935                         {
 936                                 wcross_color.x = 1;
 937                                 wcross_color.y = 1;
 938                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 939                         }
 940                         else if(hp > 20)
 941                         {
 942                                 wcross_color.x = 1;
 943                                 wcross_color.y = (hp-20)*90/27/100;
 944                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 945                         }
 946                         else
 947                         {
 948                                 wcross_color.x = 1;
 949                                 wcross_color.y = 0;
 950                         }
 951                         break;
 952                 }
 953
 954                 case 3: // crosshair_color_rainbow
 955                 {
 956                         if(time >= rainbow_last_flicker)
 957                         {
 958                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 959                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 960                         }
 961                         wcross_color = rainbow_prev_color;
 962                         break;
 963                 }
 964 LABEL(normalcolor)
 965                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 966         }
 967
 968         return wcross_color;
 969 }
 970
 971 void HUD_Crosshair(entity this)
 972 {
 973         float f, i, j;
 974         vector v;
 975         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
 976                 spectatee_status != -1 && !csqcplayer.viewloc && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 977                 !HUD_MinigameMenu_IsOpened() )
 978         {
 979                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 980                         return;
 981
 982                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 983                         return;
 984
 985                 if (hud != HUD_NORMAL)
 986                 {
 987                         HUD_Crosshair_Vehicle(this);
 988                         return;
 989                 }
 990
 991                 string wcross_style;
 992                 float wcross_alpha, wcross_resolution;
 993                 wcross_style = autocvar_crosshair;
 994                 if (wcross_style == "0")
 995                         return;
 996                 wcross_resolution = autocvar_crosshair_size;
 997                 if (wcross_resolution == 0)
 998                         return;
 999                 wcross_alpha = autocvar_crosshair_alpha;
1000                 if (wcross_alpha == 0)
1001                         return;
1002
1003                 // TrueAim check
1004                 float shottype;
1005
1006                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1007                 wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1008                 wcross_origin.z = 0;
1009                 if(autocvar_crosshair_hittest)
1010                 {
1011                         vector wcross_oldorigin;
1012                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1013                         wcross_oldorigin = wcross_origin;
1014                         shottype = TrueAimCheck(thiswep);
1015                         if(shottype == SHOTTYPE_HITWORLD)
1016                         {
1017                                 v = wcross_origin - wcross_oldorigin;
1018                                 v.x /= vid_conwidth;
1019                                 v.y /= vid_conheight;
1020                                 if(vdist(v, >, 0.01))
1021                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1022                         }
1023                         if(!autocvar_crosshair_hittest_showimpact)
1024                                 wcross_origin = wcross_oldorigin;
1025                 }
1026                 else
1027                         shottype = SHOTTYPE_HITWORLD;
1028
1029                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1030                 string wcross_name = "";
1031                 float wcross_scale, wcross_blur;
1032
1033         entity e = WEP_Null;
1034                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1035                 {
1036                         entity wepent = viewmodels[0]; // TODO: unhardcode
1037                         e = wepent.switchingweapon;
1038                         if(e)
1039                         {
1040                                 if(autocvar_crosshair_per_weapon)
1041                                 {
1042                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1043                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1044                                         //if (wcross_resolution == 0)
1045                                                 //return;
1046
1047                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1048                                         wcross_resolution *= e.w_crosshair_size;
1049                                         wcross_name = e.w_crosshair;
1050                                 }
1051                         }
1052                 }
1053
1054                 if(wcross_name == "")
1055                         wcross_name = strcat("gfx/crosshair", wcross_style);
1056
1057                 // MAIN CROSSHAIR COLOR DECISION
1058                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1059
1060                 if(autocvar_crosshair_effect_scalefade)
1061                 {
1062                         wcross_scale = wcross_resolution;
1063                         wcross_resolution = 1;
1064                 }
1065                 else
1066                 {
1067                         wcross_scale = 1;
1068                 }
1069
1070                 if(autocvar_crosshair_pickup)
1071                 {
1072                         float stat_pickup_time = STAT(LAST_PICKUP);
1073
1074                         if(pickup_crosshair_time < stat_pickup_time)
1075                         {
1076                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1077                                         pickup_crosshair_size = 1;
1078
1079                                 pickup_crosshair_time = stat_pickup_time;
1080                         }
1081
1082                         if(pickup_crosshair_size > 0)
1083                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1084                         else
1085                                 pickup_crosshair_size = 0;
1086
1087                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1088                 }
1089
1090                 // todo: make crosshair hit indication dependent on damage dealt
1091                 if(autocvar_crosshair_hitindication)
1092                 {
1093                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1094
1095                         if(unaccounted_damage)
1096                         {
1097                                 hitindication_crosshair_size = 1;
1098                         }
1099
1100                         if(hitindication_crosshair_size > 0)
1101                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1102                         else
1103                                 hitindication_crosshair_size = 0;
1104
1105                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1106                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1107                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1108                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1109                 }
1110
1111                 if(shottype == SHOTTYPE_HITENEMY)
1112                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1113                 if(shottype == SHOTTYPE_HITTEAM)
1114                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1115
1116                 f = fabs(autocvar_crosshair_effect_time);
1117                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1118                 {
1119                         wcross_changedonetime = time + f;
1120                 }
1121                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1122                 {
1123                         wcross_name_changestarttime = time;
1124                         wcross_name_changedonetime = time + f;
1125                         if(wcross_name_goal_prev_prev)
1126                                 strunzone(wcross_name_goal_prev_prev);
1127                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1128                         wcross_name_goal_prev = strzone(wcross_name);
1129                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1130                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1131                         wcross_resolution_goal_prev = wcross_resolution;
1132                 }
1133
1134                 wcross_scale_goal_prev = wcross_scale;
1135                 wcross_alpha_goal_prev = wcross_alpha;
1136                 wcross_color_goal_prev = wcross_color;
1137
1138                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1139                 {
1140                         wcross_blur = 1;
1141                         wcross_alpha *= 0.75;
1142                 }
1143                 else
1144                         wcross_blur = 0;
1145                 // *_prev is at time-frametime
1146                 // * is at wcross_changedonetime+f
1147                 // what do we have at time?
1148                 if(time < wcross_changedonetime)
1149                 {
1150                         f = frametime / (wcross_changedonetime - time + frametime);
1151                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1152                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1153                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1154                 }
1155
1156                 wcross_scale_prev = wcross_scale;
1157                 wcross_alpha_prev = wcross_alpha;
1158                 wcross_color_prev = wcross_color;
1159
1160                 MUTATOR_CALLHOOK(UpdateCrosshair);
1161
1162                 wcross_scale *= 1 - autocvar__menu_alpha;
1163                 wcross_alpha *= 1 - autocvar__menu_alpha;
1164                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1165
1166                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1167                 {
1168                         // crosshair rings for weapon stats
1169                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1170                         {
1171                                 // declarations and stats
1172                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1173                                 string ring_image = string_null, ring_inner_image = string_null;
1174                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1175
1176                                 ring_scale = autocvar_crosshair_ring_size;
1177
1178                                 float weapon_clipload, weapon_clipsize;
1179                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1180                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1181
1182                                 float vortex_charge, vortex_chargepool;
1183                                 vortex_charge = STAT(VORTEX_CHARGE);
1184                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1185
1186                                 float okvortex_charge, okvortex_chargepool;
1187                                 okvortex_charge = STAT(OVERKILL_VORTEX_CHARGE);
1188                                 okvortex_chargepool = STAT(OVERKILL_VORTEX_CHARGEPOOL);
1189
1190                                 float arc_heat = STAT(ARC_HEAT);
1191
1192                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1193                                         vortex_charge_movingavg = vortex_charge;
1194
1195                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1196
1197                                 // handle the values
1198                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1199                                 {
1200                                         if (vortex_chargepool || use_vortex_chargepool) {
1201                                                 use_vortex_chargepool = 1;
1202                                                 ring_inner_value = vortex_chargepool;
1203                                         } else {
1204                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1205                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1206                                         }
1207
1208                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1209                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1210                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1211
1212                                         // draw the outer ring to show the current charge of the weapon
1213                                         ring_value = vortex_charge;
1214                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1215                                         ring_rgb = wcross_color;
1216                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1217                                 }
1218                                 else if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_OVERKILL_VORTEX) && okvortex_charge && autocvar_crosshair_ring_vortex)
1219                                 {
1220                                         if (okvortex_chargepool || use_vortex_chargepool) {
1221                                                 use_vortex_chargepool = 1;
1222                                                 ring_inner_value = okvortex_chargepool;
1223                                         } else {
1224                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * okvortex_charge;
1225                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (okvortex_charge - vortex_charge_movingavg), 1);
1226                                         }
1227
1228                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1229                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1230                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1231
1232                                         // draw the outer ring to show the current charge of the weapon
1233                                         ring_value = okvortex_charge;
1234                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1235                                         ring_rgb = wcross_color;
1236                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1237                                 }
1238                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1239                                 {
1240                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1241                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1242                                         ring_rgb = wcross_color;
1243                                         ring_image = "gfx/crosshair_ring.tga";
1244                                 }
1245                                 else if (wepent.activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1246                                 {
1247                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1248                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1249                                         ring_rgb = wcross_color;
1250                                         ring_image = "gfx/crosshair_ring.tga";
1251                                 }
1252                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1253                                 {
1254                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1255                                         ring_scale = autocvar_crosshair_ring_reload_size;
1256                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1257                                         ring_rgb = wcross_color;
1258
1259                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1260                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1261                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1262                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1263                                         else
1264                                                 ring_image = "gfx/crosshair_ring.tga";
1265                                 }
1266                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1267                                 {
1268                                         ring_value = arc_heat;
1269                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1270                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1271                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1272                                         ring_image = "gfx/crosshair_ring.tga";
1273                                 }
1274
1275                                 // if in weapon switch animation, fade ring out/in
1276                                 if(autocvar_crosshair_effect_time > 0)
1277                                 {
1278                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1279                                         if (f >= 1)
1280                                         {
1281                                                 wcross_ring_prev = ((ring_image) ? true : false);
1282                                         }
1283
1284                                         if(wcross_ring_prev)
1285                                         {
1286                                                 if(f < 1)
1287                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1288                                         }
1289                                         else
1290                                         {
1291                                                 if(f < 1)
1292                                                         ring_alpha *= bound(0, f, 1);
1293                                         }
1294                                 }
1295
1296                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1297                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1298
1299                                 if (ring_value)
1300                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1301                         }
1302
1303 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1304                         MACRO_BEGIN { \
1305                                 if(wcross_blur > 0) \
1306                                 { \
1307                                         for(i = -2; i <= 2; ++i) \
1308                                         for(j = -2; j <= 2; ++j) \
1309                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1310                                 } \
1311                                 else \
1312                                 { \
1313                                         M(0,0,sz,wcross_name,wcross_alpha); \
1314                                 } \
1315                         } MACRO_END
1316
1317 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1318                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1319
1320 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1321                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1322
1323                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1324                         {
1325                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1326                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1327                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1328                                 f = 1 - f;
1329                         }
1330                         else
1331                         {
1332                                 f = 1;
1333                         }
1334                         wcross_name_alpha_goal_prev = f;
1335
1336                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1337                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1338
1339                         if(autocvar_crosshair_dot)
1340                         {
1341                                 vector wcross_color_old;
1342                                 wcross_color_old = wcross_color;
1343
1344                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1345                                         wcross_color = stov(autocvar_crosshair_dot_color);
1346
1347                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1348                                 // FIXME why don't we use wcross_alpha here?
1349                                 wcross_color = wcross_color_old;
1350                         }
1351                 }
1352         }
1353         else
1354         {
1355                 wcross_scale_prev = 0;
1356                 wcross_alpha_prev = 0;
1357                 wcross_scale_goal_prev = 0;
1358                 wcross_alpha_goal_prev = 0;
1359                 wcross_changedonetime = 0;
1360                 if(wcross_name_goal_prev)
1361                         strunzone(wcross_name_goal_prev);
1362                 wcross_name_goal_prev = string_null;
1363                 if(wcross_name_goal_prev_prev)
1364                         strunzone(wcross_name_goal_prev_prev);
1365                 wcross_name_goal_prev_prev = string_null;
1366                 wcross_name_changestarttime = 0;
1367                 wcross_name_changedonetime = 0;
1368                 wcross_name_alpha_goal_prev = 0;
1369                 wcross_name_alpha_goal_prev_prev = 0;
1370                 wcross_resolution_goal_prev = 0;
1371                 wcross_resolution_goal_prev_prev = 0;
1372         }
1373 }
1374
1375 void HUD_Draw(entity this)
1376 {
1377         // if we don't know gametype and scores yet avoid drawing the scoreboard
1378         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1379         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1380         // cl_deathscoreboard would show the scoreboard and so on
1381         if(!gametype)
1382                 return;
1383
1384         if(!intermission)
1385         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1386         {
1387                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1388         }
1389         else if(STAT(FROZEN))
1390         {
1391                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1392         }
1393         if(!intermission)
1394         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1395         {
1396                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1397                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1398         }
1399         else if(STAT(CAPTURE_PROGRESS))
1400         {
1401                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1402                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1403         }
1404         else if(STAT(REVIVE_PROGRESS))
1405         {
1406                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1407                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1408         }
1409
1410         if(autocvar_r_letterbox == 0)
1411                 if(autocvar_viewsize < 120)
1412                 {
1413                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1414                                 Accuracy_LoadLevels();
1415
1416                         HUD_Main();
1417                         HUD_Scale_Disable();
1418                 }
1419
1420         // crosshair goes VERY LAST
1421         UpdateDamage();
1422         HUD_Crosshair(this);
1423         HitSound();
1424 }
1425
1426 bool ov_enabled;
1427 float oldr_nearclip;
1428 float oldr_farclip_base;
1429 float oldr_farclip_world;
1430 float oldr_novis;
1431 float oldr_useportalculling;
1432 float oldr_useinfinitefarclip;
1433
1434 void cl_notice_run();
1435
1436 float prev_myteam;
1437 int lasthud;
1438 float vh_notice_time;
1439 void WaypointSprite_Load();
1440 void CSQC_UpdateView(entity this, float w, float h)
1441 {
1442     TC(int, w); TC(int, h);
1443         entity e;
1444         float fov;
1445         float f;
1446         vector vf_size, vf_min;
1447         float a;
1448
1449         execute_next_frame();
1450
1451         ++framecount;
1452
1453         stats_get();
1454         hud = STAT(HUD);
1455
1456         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1457                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1458
1459         lasthud = hud;
1460
1461         HUD_Scale_Disable();
1462
1463         if(autocvar__hud_showbinds_reload) // menu can set this one
1464         {
1465                 db_close(binddb);
1466                 binddb = db_create();
1467                 cvar_set("_hud_showbinds_reload", "0");
1468         }
1469
1470         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1471                 view_quality = getproperty(VF_MINFPS_QUALITY);
1472         else
1473                 view_quality = 1;
1474
1475         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1476         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1477
1478         vf_size = getpropertyvec(VF_SIZE);
1479         vf_min = getpropertyvec(VF_MIN);
1480         vid_width = vf_size.x;
1481         vid_height = vf_size.y;
1482
1483         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1484         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1485
1486         WaypointSprite_Load();
1487
1488         CSQCPlayer_SetCamera();
1489
1490         if(player_localentnum <= maxclients) // is it a client?
1491                 current_player = player_localentnum - 1;
1492         else // then player_localentnum is the vehicle I'm driving
1493                 current_player = player_localnum;
1494         myteam = entcs_GetTeam(current_player);
1495
1496         if(myteam != prev_myteam)
1497         {
1498                 myteamcolors = colormapPaletteColor(myteam, 1);
1499                 FOREACH(hud_panels, true, it.update_time = time);
1500                 prev_myteam = myteam;
1501         }
1502
1503         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1504
1505         float is_dead = (STAT(HEALTH) <= 0);
1506
1507         // FIXME do we need this hack?
1508         if(isdemo())
1509         {
1510                 // in demos, input_buttons do not work
1511                 button_zoom = (autocvar__togglezoom == "-");
1512         }
1513         else if(button_zoom
1514                 && autocvar_cl_unpress_zoom_on_death
1515                 && (spectatee_status >= 0)
1516                 && (is_dead || intermission))
1517         {
1518                 // no zoom while dead or in intermission please
1519                 localcmd("-zoom\n");
1520                 button_zoom = false;
1521         }
1522
1523         // event chase camera
1524         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1525         {
1526                 if(STAT(CAMERA_SPECTATOR))
1527                 {
1528                         if(spectatee_status > 0)
1529                         {
1530                                 if(!autocvar_chase_active)
1531                                 {
1532                                         cvar_set("chase_active", "-2");
1533                                         goto skip_eventchase_death;
1534                                 }
1535                         }
1536                         else if(autocvar_chase_active == -2)
1537                                 cvar_set("chase_active", "0");
1538
1539                         if(autocvar_chase_active == -2)
1540                                 goto skip_eventchase_death;
1541                 }
1542                 else if(autocvar_chase_active == -2)
1543                         cvar_set("chase_active", "0");
1544
1545                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1546
1547                 float vehicle_viewdist = 0;
1548                 vector vehicle_viewofs = '0 0 0';
1549
1550                 if(vehicle_chase)
1551                 {
1552                         if(hud != HUD_BUMBLEBEE_GUN)
1553                         {
1554                                 Vehicle info = Vehicles_from(hud);
1555                                 vehicle_viewdist = info.height;
1556                                 vehicle_viewofs = info.view_ofs;
1557                         }
1558                 }
1559
1560                 if(WantEventchase(this))
1561                 {
1562                         vector current_view_origin_override = '0 0 0';
1563                         vector view_offset_override = '0 0 0';
1564                         float chase_distance_override = 0;
1565                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1566                         if(custom_eventchase)
1567                         {
1568                                 current_view_origin_override = M_ARGV(0, vector);
1569                                 view_offset_override = M_ARGV(1, vector);
1570                                 chase_distance_override = M_ARGV(0, float);
1571                         }
1572                         eventchase_running = true;
1573
1574                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1575                         if(!local_player)
1576                                 local_player = this; // fall back!
1577
1578                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1579                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1580                         if (custom_eventchase)
1581                                 current_view_origin = current_view_origin_override;
1582
1583                         // detect maximum viewoffset and use it
1584                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1585                         if(vehicle_chase)
1586                         {
1587                                 if(vehicle_viewofs)
1588                                         view_offset = vehicle_viewofs;
1589                                 else
1590                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1591                         }
1592                         if (custom_eventchase)
1593                                 view_offset = view_offset_override;
1594
1595                         if(view_offset)
1596                         {
1597                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1598                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1599                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1600                         }
1601
1602                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1603                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1604                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1605                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1606
1607                         // make the camera smooth back
1608                         float chase_distance = autocvar_cl_eventchase_distance;
1609                         if(vehicle_chase)
1610                         {
1611                                 if(vehicle_viewofs)
1612                                         chase_distance = vehicle_viewdist;
1613                                 else
1614                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1615                         }
1616                         if (custom_eventchase)
1617                                 chase_distance = chase_distance_override;
1618
1619                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1620                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1621                         else if(eventchase_current_distance != chase_distance)
1622                                 eventchase_current_distance = chase_distance;
1623
1624                         makevectors(view_angles);
1625
1626                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1627                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1628
1629                         // If the boxtrace fails, revert back to line tracing.
1630                         if(!local_player.viewloc)
1631                         if(trace_startsolid)
1632                         {
1633                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1634                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1635                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1636                         }
1637                         else { setproperty(VF_ORIGIN, trace_endpos); }
1638
1639                         if(!local_player.viewloc)
1640                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1641                 }
1642                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1643                 {
1644                         eventchase_running = false;
1645                         cvar_set("chase_active", "0");
1646                         eventchase_current_distance = 0; // start from 0 next time
1647                 }
1648         }
1649         // workaround for camera stuck between player's legs when using chase_active 1
1650         // because the engine stops updating the chase_active camera when the game ends
1651         else if(intermission)
1652         {
1653                 cvar_settemp("chase_active", "-1");
1654                 eventchase_current_distance = 0;
1655         }
1656
1657         LABEL(skip_eventchase_death);
1658
1659         // do lockview after event chase camera so that it still applies whenever necessary.
1660         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1661         {
1662                 setproperty(VF_ORIGIN, freeze_org);
1663                 setproperty(VF_ANGLES, freeze_ang);
1664         }
1665         else
1666         {
1667                 freeze_org = getpropertyvec(VF_ORIGIN);
1668                 freeze_ang = getpropertyvec(VF_ANGLES);
1669         }
1670
1671         WarpZone_FixView();
1672         //WarpZone_FixPMove();
1673
1674         vector ov_org = '0 0 0';
1675         vector ov_mid = '0 0 0';
1676         vector ov_worldmin = '0 0 0';
1677         vector ov_worldmax = '0 0 0';
1678         if(autocvar_cl_orthoview)
1679         {
1680                 ov_worldmin = mi_picmin;
1681                 ov_worldmax = mi_picmax;
1682
1683                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1684                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1685                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1686
1687                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1688                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1689
1690                 float ov_nearest = vlen(ov_org - vec3(
1691                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1692                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1693                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1694                 ));
1695
1696                 float ov_furthest = 0;
1697                 float dist = 0;
1698
1699                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1700                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1701                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1702                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1703                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1704                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1705                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1706                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1707
1708                 if(!ov_enabled)
1709                 {
1710                         oldr_nearclip = cvar("r_nearclip");
1711                         oldr_farclip_base = cvar("r_farclip_base");
1712                         oldr_farclip_world = cvar("r_farclip_world");
1713                         oldr_novis = cvar("r_novis");
1714                         oldr_useportalculling = cvar("r_useportalculling");
1715                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1716                 }
1717
1718                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1719                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1720                 cvar_settemp("r_farclip_world", "0");
1721                 cvar_settemp("r_novis", "1");
1722                 cvar_settemp("r_useportalculling", "0");
1723                 cvar_settemp("r_useinfinitefarclip", "0");
1724
1725                 setproperty(VF_ORIGIN, ov_org);
1726                 setproperty(VF_ANGLES, '90 0 0');
1727
1728                 ov_enabled = true;
1729
1730                 #if 0
1731                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1732                         vtos(ov_org),
1733                         vtos(getpropertyvec(VF_ANGLES)),
1734                         ov_distance,
1735                         ov_nearest,
1736                         ov_furthest);
1737                 #endif
1738         }
1739         else
1740         {
1741                 if(ov_enabled)
1742                 {
1743                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1744                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1745                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1746                         cvar_set("r_novis", ftos(oldr_novis));
1747                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1748                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1749                 }
1750                 ov_enabled = false;
1751         }
1752
1753         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1754         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1755         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1756                 viewmodel_draw(viewmodels[slot]);
1757
1758         // Render the Scene
1759         view_origin = getpropertyvec(VF_ORIGIN);
1760         view_angles = getpropertyvec(VF_ANGLES);
1761         makevectors(view_angles);
1762         view_forward = v_forward;
1763         view_right = v_right;
1764         view_up = v_up;
1765
1766 #ifdef BLURTEST
1767         if(time > blurtest_time0 && time < blurtest_time1)
1768         {
1769                 float r, t;
1770
1771                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1772                 r = t * blurtest_radius;
1773                 f = 1 / (t ** blurtest_power) - 1;
1774
1775                 cvar_set("r_glsl_postprocess", "1");
1776                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1777         }
1778         else
1779         {
1780                 cvar_set("r_glsl_postprocess", "0");
1781                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1782         }
1783 #endif
1784
1785         TargetMusic_Advance();
1786         Fog_Force();
1787
1788         if(drawtime == 0)
1789                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1790         else
1791                 drawframetime = bound(0.000001, time - drawtime, 1);
1792         drawtime = time;
1793
1794         // watch for gametype changes here...
1795         // in ParseStuffCMD the cmd isn't executed yet :/
1796         // might even be better to add the gametype to TE_CSQC_INIT...?
1797         if(!postinit)
1798                 PostInit();
1799
1800         if(intermission && !intermission_time)
1801                 intermission_time = time;
1802
1803         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1804         {
1805                 if(calledhooks & HOOK_START)
1806                 {
1807                         localcmd("\ncl_hook_gameend\n");
1808                         calledhooks |= HOOK_END;
1809                 }
1810         }
1811
1812         Announcer();
1813
1814         fov = autocvar_fov;
1815         if(fov <= 59.5)
1816         {
1817                 if(!zoomscript_caught)
1818                 {
1819                         localcmd("+button9\n");
1820                         zoomscript_caught = 1;
1821                 }
1822         }
1823         else
1824         {
1825                 if(zoomscript_caught)
1826                 {
1827                         localcmd("-button9\n");
1828                         zoomscript_caught = 0;
1829                 }
1830         }
1831
1832         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1833
1834         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1835         {
1836                 entity wepent = viewmodels[slot];
1837
1838                 if(wepent.last_switchweapon != wepent.switchweapon)
1839                 {
1840                         weapontime = time;
1841                         wepent.last_switchweapon = wepent.switchweapon;
1842                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1843                         {
1844                                 localcmd("-zoom\n");
1845                                 button_zoom = false;
1846                         }
1847                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1848                         {
1849                                 localcmd("-fire\n");
1850                                 localcmd("-fire2\n");
1851                                 button_attack2 = false;
1852                         }
1853                 }
1854                 if(wepent.last_activeweapon != wepent.activeweapon)
1855                 {
1856                         wepent.last_activeweapon = wepent.activeweapon;
1857
1858                         e = wepent.activeweapon;
1859                         if(e.netname != "")
1860                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1861                         else if(slot == 0)
1862                                 localcmd("\ncl_hook_activeweapon none\n");
1863                 }
1864         }
1865
1866         // ALWAYS Clear Current Scene First
1867         clearscene();
1868
1869         setproperty(VF_ORIGIN, view_origin);
1870         setproperty(VF_ANGLES, view_angles);
1871
1872         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1873         setproperty(VF_SIZE, vf_size);
1874         setproperty(VF_MIN, vf_min);
1875
1876         // Assign Standard Viewflags
1877         // Draw the World (and sky)
1878         setproperty(VF_DRAWWORLD, 1);
1879
1880         // Set the console size vars
1881         vid_conwidth = autocvar_vid_conwidth;
1882         vid_conheight = autocvar_vid_conheight;
1883         vid_pixelheight = autocvar_vid_pixelheight;
1884
1885         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1886         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1887         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1888
1889         if(camera_active) // Camera for demo playback
1890         {
1891                 if(autocvar_camera_enable)
1892                         CSQC_Demo_Camera();
1893                 else
1894                 {
1895                         cvar_set("chase_active", ftos(chase_active_backup));
1896                         cvar_set("cl_demo_mousegrab", "0");
1897                         camera_active = false;
1898                 }
1899         }
1900         else
1901         {
1902 #ifdef CAMERATEST
1903                 if(autocvar_camera_enable)
1904 #else
1905                 if(autocvar_camera_enable && isdemo())
1906 #endif
1907                 {
1908                         // Enable required Darkplaces cvars
1909                         chase_active_backup = autocvar_chase_active;
1910                         cvar_set("chase_active", "2");
1911                         cvar_set("cl_demo_mousegrab", "1");
1912                         camera_active = true;
1913                         camera_mode = false;
1914                 }
1915         }
1916
1917         // Draw the Crosshair
1918         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1919
1920         // Draw the Engine Status Bar (the default Quake HUD)
1921         setproperty(VF_DRAWENGINESBAR, 0);
1922
1923         // Update the mouse position
1924         /*
1925            mousepos_x = vid_conwidth;
1926            mousepos_y = vid_conheight;
1927            mousepos = mousepos*0.5 + getmousepos();
1928          */
1929
1930         IL_EACH(g_drawables, it.draw, it.draw(it));
1931
1932         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1933         renderscene();
1934
1935         // now switch to 2D drawing mode by calling a 2D drawing function
1936         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1937         // next R_RenderScene call
1938         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1939
1940         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1941         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1942         {
1943                 // apply night vision effect
1944                 vector tc_00, tc_01, tc_10, tc_11;
1945                 vector rgb = '0 0 0';
1946
1947                 if(!nightvision_noise)
1948                 {
1949                         nightvision_noise = new(nightvision_noise);
1950                 }
1951                 if(!nightvision_noise2)
1952                 {
1953                         nightvision_noise2 = new(nightvision_noise2);
1954                 }
1955
1956                 // color tint in yellow
1957                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1958
1959                 // draw BG
1960                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1961                 rgb = '1 1 1';
1962                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1963                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1964                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1965                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1966                 tc_11 = tc_01 + tc_10 - tc_00;
1967                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1968                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1969                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1970                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1971                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1972                 R_EndPolygon();
1973
1974                 // draw FG
1975                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1976                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1977                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1978                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1979                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1980                 tc_11 = tc_01 + tc_10 - tc_00;
1981                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1982                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1983                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1984                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1985                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1986                 R_EndPolygon();
1987         }
1988
1989         if(autocvar_cl_reticle)
1990         {
1991                 string reticle_image = string_null;
1992                 bool wep_zoomed = false;
1993                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1994                 {
1995                         entity wepe = viewmodels[slot];
1996                         Weapon wep = wepe.activeweapon;
1997                         if(wep != WEP_Null && wep.wr_zoom)
1998                         {
1999                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2000                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2001                                         reticle_image = wep.w_reticle;
2002                                 wep_zoomed += do_zoom;
2003                         }
2004                 }
2005                 // Draw the aiming reticle for weapons that use it
2006                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2007                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2008                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2009                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
2010                 {
2011                         // no zoom reticle while dead
2012                         reticle_type = 0;
2013                 }
2014                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2015                 {
2016                         if(reticle_image) { reticle_type = 2; }
2017                         else { reticle_type = 0; }
2018                 }
2019                 else if(button_zoom || zoomscript_caught)
2020                 {
2021                         // normal zoom
2022                         reticle_type = 1;
2023                 }
2024
2025                 if(reticle_type)
2026                 {
2027                         if(autocvar_cl_reticle_stretch)
2028                         {
2029                                 reticle_size.x = vid_conwidth;
2030                                 reticle_size.y = vid_conheight;
2031                                 reticle_pos.x = 0;
2032                                 reticle_pos.y = 0;
2033                         }
2034                         else
2035                         {
2036                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2037                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2038                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2039                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2040                         }
2041
2042                         if(zoomscript_caught)
2043                                 f = 1;
2044                         else
2045                                 f = current_zoomfraction;
2046
2047                         if(f)
2048                         {
2049                                 switch(reticle_type)
2050                                 {
2051                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2052                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2053                                 }
2054                         }
2055                 }
2056         }
2057         else
2058         {
2059                 if(reticle_type != 0) { reticle_type = 0; }
2060         }
2061
2062
2063         // improved polyblend
2064         if(autocvar_hud_contents)
2065         {
2066                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2067                 vector liquidcolor;
2068
2069                 switch(pointcontents(view_origin))
2070                 {
2071                         case CONTENT_WATER:
2072                                 liquidalpha = autocvar_hud_contents_water_alpha;
2073                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2074                                 incontent = 1;
2075                                 break;
2076
2077                         case CONTENT_LAVA:
2078                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2079                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2080                                 incontent = 1;
2081                                 break;
2082
2083                         case CONTENT_SLIME:
2084                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2085                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2086                                 incontent = 1;
2087                                 break;
2088
2089                         default:
2090                                 liquidalpha = 0;
2091                                 liquidcolor = '0 0 0';
2092                                 incontent = 0;
2093                                 break;
2094                 }
2095
2096                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2097                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2098                         contentfadetime = autocvar_hud_contents_fadeintime;
2099                         liquidalpha_prev = liquidalpha;
2100                         liquidcolor_prev = liquidcolor;
2101                 }
2102                 else
2103                         contentfadetime = autocvar_hud_contents_fadeouttime;
2104
2105                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2106                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2107
2108                 if(contentavgalpha)
2109                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2110
2111                 if(autocvar_hud_postprocessing)
2112                 {
2113                         if(autocvar_hud_contents_blur && contentavgalpha)
2114                         {
2115                                 content_blurpostprocess.x = 1;
2116                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2117                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2118                         }
2119                         else
2120                         {
2121                                 content_blurpostprocess.x = 0;
2122                                 content_blurpostprocess.y = 0;
2123                                 content_blurpostprocess.z = 0;
2124                         }
2125                 }
2126         }
2127
2128         if(autocvar_hud_damage && !STAT(FROZEN))
2129         {
2130                 splash_size.x = max(vid_conwidth, vid_conheight);
2131                 splash_size.y = max(vid_conwidth, vid_conheight);
2132                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2133                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2134
2135                 float myhealth_flash_temp;
2136                 myhealth = STAT(HEALTH);
2137
2138                 // fade out
2139                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2140                 // add new damage
2141                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2142
2143                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2144                 pain_threshold = autocvar_hud_damage_pain_threshold;
2145                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2146                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2147
2148                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2149                 {
2150                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2151                 }
2152
2153                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2154
2155                 if(myhealth_prev < 1)
2156                 {
2157                         if(myhealth >= 1)
2158                         {
2159                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2160                                 myhealth_flash_temp = 0;
2161                         }
2162                         else
2163                         {
2164                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2165                         }
2166                 }
2167
2168                 if(spectatee_status == -1 || intermission)
2169                 {
2170                         myhealth_flash = 0; // observing, or match ended
2171                         myhealth_flash_temp = 0;
2172                 }
2173
2174                 myhealth_prev = myhealth;
2175
2176                 // IDEA: change damage color/picture based on player model for robot/alien species?
2177                 // pro: matches model better
2178                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2179                 // maybe different reddish pics?
2180                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2181                 {
2182                         if(autocvar_cl_gentle_damage == 2)
2183                         {
2184                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2185                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2186                         }
2187                         else
2188                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2189
2190                         if(myhealth_flash_temp > 0)
2191                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2192                 }
2193                 else if(myhealth_flash_temp > 0)
2194                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2195
2196                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2197                 {
2198                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2199                         {
2200                                 damage_blurpostprocess.x = 1;
2201                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2202                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2203                         }
2204                         else
2205                         {
2206                                 damage_blurpostprocess.x = 0;
2207                                 damage_blurpostprocess.y = 0;
2208                                 damage_blurpostprocess.z = 0;
2209                         }
2210                 }
2211         }
2212
2213         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2214         float e2 = (autocvar_hud_powerup != 0);
2215         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2216         {
2217                 // enable or disable rendering types if they are used or not
2218                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2219                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2220
2221                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2222                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2223                 {
2224                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2225                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2226                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2227                         {
2228                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2229                                 old_blurradius = blurradius;
2230                                 old_bluralpha = bluralpha;
2231                         }
2232                 }
2233                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2234                 {
2235                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2236                         old_blurradius = 0;
2237                         old_bluralpha = 0;
2238                 }
2239
2240                 // edge detection postprocess handling done second (used by hud_powerup)
2241                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2242                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2243                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2244
2245                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2246
2247                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2248                 {
2249                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2250                         {
2251                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2252                                 old_sharpen_intensity = sharpen_intensity;
2253                         }
2254                 }
2255                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2256                 {
2257                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2258                         old_sharpen_intensity = 0;
2259                 }
2260
2261                 if(cvar("r_glsl_postprocess") == 0)
2262                         cvar_set("r_glsl_postprocess", "2");
2263         }
2264         else if(cvar("r_glsl_postprocess") == 2)
2265                 cvar_set("r_glsl_postprocess", "0");
2266
2267         /*if(gametype == MAPINFO_TYPE_CTF)
2268           {
2269           ctf_view();
2270           } else */
2271
2272         // draw 2D entities
2273         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2274         Draw_ShowNames_All();
2275 #ifdef DEBUGDRAW
2276         Debug_Draw();
2277 #endif
2278
2279         scoreboard_active = Scoreboard_WouldDraw();
2280
2281         HUD_Draw(this); // this parameter for deep vehicle function
2282
2283         if(NextFrameCommand)
2284         {
2285                 localcmd("\n", NextFrameCommand, "\n");
2286                 NextFrameCommand = string_null;
2287         }
2288
2289         // we must do this check AFTER a frame was rendered, or it won't work
2290         if(cs_project_is_b0rked == 0)
2291         {
2292                 string w0, h0;
2293                 w0 = ftos(autocvar_vid_conwidth);
2294                 h0 = ftos(autocvar_vid_conheight);
2295                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2296                 //setproperty(VF_FOV, '90 90 0');
2297                 setproperty(VF_ORIGIN, '0 0 0');
2298                 setproperty(VF_ANGLES, '0 0 0');
2299                 setproperty(VF_PERSPECTIVE, 1);
2300                 makevectors('0 0 0');
2301                 vector v1, v2;
2302                 cvar_set("vid_conwidth", "800");
2303                 cvar_set("vid_conheight", "600");
2304                 v1 = cs_project(v_forward);
2305                 cvar_set("vid_conwidth", "640");
2306                 cvar_set("vid_conheight", "480");
2307                 v2 = cs_project(v_forward);
2308                 if(v1 == v2)
2309                         cs_project_is_b0rked = 1;
2310                 else
2311                         cs_project_is_b0rked = -1;
2312                 cvar_set("vid_conwidth", w0);
2313                 cvar_set("vid_conheight", h0);
2314         }
2315
2316         if(autocvar__hud_configure)
2317                 HUD_Panel_Mouse();
2318         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2319                 HUD_Minigame_Mouse();
2320         else if(QuickMenu_IsOpened())
2321                 QuickMenu_Mouse();
2322         else
2323                 HUD_Radar_Mouse();
2324
2325         cl_notice_run();
2326         unpause_update();
2327         Net_Flush();
2328
2329         // let's reset the view back to normal for the end
2330         setproperty(VF_MIN, '0 0 0');
2331         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2332
2333         IL_ENDFRAME();
2334 }
2335
2336
2337 // following vectors must be global to allow seamless switching between camera modes
2338 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2339 void CSQC_Demo_Camera()
2340 {
2341         float speed, attenuation, dimensions;
2342         vector tmp, delta;
2343
2344         if( autocvar_camera_reset || !camera_mode )
2345         {
2346                 camera_offset = '0 0 0';
2347                 current_angles = '0 0 0';
2348                 camera_direction = '0 0 0';
2349                 camera_offset.z += 30;
2350                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2351                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2352                 current_origin = view_origin;
2353                 current_camera_offset  = camera_offset;
2354                 cvar_set("camera_reset", "0");
2355                 camera_mode = CAMERA_CHASE;
2356         }
2357
2358         // Camera angles
2359         if( camera_roll )
2360                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2361
2362         if(autocvar_camera_look_player)
2363         {
2364                 vector dir;
2365                 float n;
2366
2367                 dir = normalize(view_origin - current_position);
2368                 n = mouse_angles.z;
2369                 mouse_angles = vectoangles(dir);
2370                 mouse_angles.x = mouse_angles.x * -1;
2371                 mouse_angles.z = n;
2372         }
2373         else
2374         {
2375                 tmp = getmousepos() * 0.1;
2376                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2377                 {
2378                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2379                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2380                 }
2381         }
2382
2383         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2384         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2385         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2386         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2387
2388         // Fix difference when angles don't have the same sign
2389         delta = '0 0 0';
2390         if(mouse_angles.y < -60 && current_angles.y > 60)
2391                 delta = '0 360 0';
2392         if(mouse_angles.y > 60 && current_angles.y < -60)
2393                 delta = '0 -360 0';
2394
2395         if(autocvar_camera_look_player)
2396                 attenuation = autocvar_camera_look_attenuation;
2397         else
2398                 attenuation = autocvar_camera_speed_attenuation;
2399
2400         attenuation = 1 / max(1, attenuation);
2401         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2402
2403         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2404         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2405         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2406         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2407
2408         // Camera position
2409         tmp = '0 0 0';
2410         dimensions = 0;
2411
2412         if( camera_direction.x )
2413         {
2414                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2415                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2416                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2417                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2418                 ++dimensions;
2419         }
2420
2421         if( camera_direction.y )
2422         {
2423                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2424                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2425                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2426                 ++dimensions;
2427         }
2428
2429         if( camera_direction.z )
2430         {
2431                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2432                 ++dimensions;
2433         }
2434
2435         if(autocvar_camera_free)
2436                 speed = autocvar_camera_speed_free;
2437         else
2438                 speed = autocvar_camera_speed_chase;
2439
2440         if(dimensions)
2441         {
2442                 speed = speed * sqrt(1 / dimensions);
2443                 camera_offset += tmp * speed;
2444         }
2445
2446         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2447
2448         // Camera modes
2449         if( autocvar_camera_free )
2450         {
2451                 if ( camera_mode == CAMERA_CHASE )
2452                 {
2453                         current_camera_offset = current_origin + current_camera_offset;
2454                         camera_offset = current_origin + camera_offset;
2455                 }
2456
2457                 camera_mode = CAMERA_FREE;
2458                 current_position = current_camera_offset;
2459         }
2460         else
2461         {
2462                 if ( camera_mode == CAMERA_FREE )
2463                 {
2464                         current_origin = view_origin;
2465                         camera_offset = camera_offset - current_origin;
2466                         current_camera_offset = current_camera_offset - current_origin;
2467                 }
2468
2469                 camera_mode = CAMERA_CHASE;
2470
2471                 if(autocvar_camera_chase_smoothly)
2472                         current_origin += (view_origin - current_origin) * attenuation;
2473                 else
2474                         current_origin = view_origin;
2475
2476                 current_position = current_origin + current_camera_offset;
2477         }
2478
2479         setproperty(VF_ANGLES, current_angles);
2480         setproperty(VF_ORIGIN, current_position);
2481 }