qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <client/command/cl_cmd.qh>
   4 #include <client/draw.qh>
   5 #include <client/hud/_mod.qh>
   6 #include <client/hud/panel/centerprint.qh>
   7 #include <client/hud/panel/chat.qh>
   8 #include <client/hud/panel/quickmenu.qh>
   9 #include <client/hud/panel/scoreboard.qh>
  10 #include <client/items/items.qh>
  11 #include <client/mapvoting.qh>
  12 #include <client/mutators/_mod.qh>
  13 #include <client/shownames.qh>
  14 #include <client/view.qh>
  15 #include <client/weapons/projectile.qh>
  16 #include <common/deathtypes/all.qh>
  17 #include <common/effects/all.inc>
  18 #include <common/effects/all.qh>
  19 #include <common/effects/effect.qh>
  20 #include <common/effects/qc/_mod.qh>
  21 #include <common/ent_cs.qh>
  22 #include <common/gamemodes/gamemode/nexball/cl_nexball.qh>
  23 #include <common/items/_mod.qh>
  24 #include <common/mapinfo.qh>
  25 #include <common/mapobjects/_mod.qh>
  26 #include <common/minigames/cl_minigames.qh>
  27 #include <common/minigames/cl_minigames_hud.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/scores.qh>
  31 #include <common/vehicles/all.qh>
  32 #include <lib/csqcmodel/cl_model.qh>
  33 #include <lib/csqcmodel/interpolate.qh>
  34 #include <lib/warpzone/client.qh>
  35
  36 // --------------------------------------------------------------------------
  37 // BEGIN REQUIRED CSQC FUNCTIONS
  38 //include "main.qh"
  39
  40 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  41
  42 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  43 // Useful for precaching things
  44
  45 void CSQC_Init()
  46 {
  47         prvm_language = strzone(cvar_string("prvm_language"));
  48
  49 #ifdef WATERMARK
  50         LOG_TRACEF("^4CSQC Build information: ^1%s", WATERMARK);
  51 #endif
  52
  53         {
  54                 int i = 0;
  55                 for ( ; i < 255; ++i)
  56                         if (getplayerkeyvalue(i, "viewentity") == "")
  57                                 break;
  58                 maxclients = i;
  59         }
  60
  61         // needs to be done so early because of the constants they create
  62         static_init();
  63         static_init_late();
  64         static_init_precache();
  65
  66         binddb = db_create();
  67         tempdb = db_create();
  68         ClientProgsDB = db_load("client.db");
  69
  70         draw_endBoldFont();
  71
  72         //registercommand("hud_configure");
  73         //registercommand("hud_save");
  74         //registercommand("menu_action");
  75
  76         ConsoleCommand_macro_init();
  77
  78         registercvar("hud_usecsqc", "1");
  79         registercvar("scoreboard_columns", "default");
  80
  81         registercvar("cl_nade_type", "3");
  82         registercvar("cl_pokenade_type", "zombie");
  83
  84         registercvar("cl_jumpspeedcap_min", "");
  85         registercvar("cl_jumpspeedcap_max", "");
  86
  87         registercvar("cl_shootfromfixedorigin", "");
  88
  89         registercvar("cl_multijump", "-1");
  90
  91         registercvar("cl_dodging", "0");
  92
  93         registercvar("cl_spawn_near_teammate", "1");
  94
  95         registercvar("cl_weapon_switch_reload", "1");
  96         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
  97
  98         registercvar("cl_allow_uidranking", "1");
  99
 100         // z411
 101         registercvar("cl_chat_sounds", "1");
 102
 103         if(autocvar_cl_lockview)
 104                 cvar_set("cl_lockview", "0");
 105
 106         if (cvar_type("_scoreboard_team_selection_available") & CVAR_TYPEFLAG_EXISTS)
 107                 cvar_settemp("_scoreboard_team_selection_available", "1");
 108         cvar_set("_scoreboard_team_selection", "0"); // in case it has been left set to 1
 109
 110         gametype = NULL;
 111
 112         postinit = false;
 113
 114         calledhooks = 0;
 115
 116         teams = Sort_Spawn();
 117         players = Sort_Spawn();
 118
 119         GetTeam(NUM_SPECTATOR, true); // add specs first
 120
 121         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 122                 weapon_accuracy[w] = -1;
 123
 124         // precaches
 125
 126         if(autocvar_cl_reticle)
 127         {
 128                 precache_pic("gfx/reticle_normal");
 129                 // weapon reticles are precached in weapon files
 130         }
 131
 132         {
 133                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 134                 minimapname = strcat("gfx/", mi_shortname, "_radar");
 135
 136                 if (precache_pic(minimapname) == "")
 137                 {
 138                         // but maybe we have a non-clever minimap
 139                         minimapname = strcat("gfx/", mi_shortname, "_mini");
 140                         if (precache_pic(minimapname) == "")
 141                                 minimapname = ""; // FAIL
 142                         else
 143                                 get_mi_min_max_texcoords(0); // load new texcoords
 144                 }
 145
 146                 mi_center = (mi_min + mi_max) * 0.5;
 147                 mi_scale = mi_max - mi_min;
 148                 minimapname = strzone(minimapname);
 149         }
 150
 151         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 152         LoadMenuSkinValues();
 153 }
 154
 155 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 156 void Shutdown()
 157 {
 158         WarpZone_Shutdown();
 159
 160         delete(teams);
 161         delete(players);
 162         db_close(binddb);
 163         db_close(tempdb);
 164         if(autocvar_cl_db_saveasdump)
 165                 db_dump(ClientProgsDB, "client.db");
 166         else
 167                 db_save(ClientProgsDB, "client.db");
 168         db_close(ClientProgsDB);
 169
 170         if(camera_active)
 171                 cvar_set("chase_active",ftos(chase_active_backup));
 172
 173         // unset the event chasecam's chase_active
 174         if(autocvar_chase_active < 0)
 175                 cvar_set("chase_active", "0");
 176
 177         if (autocvar_r_drawviewmodel < 0)
 178                 cvar_set("r_drawviewmodel", "0");
 179
 180         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 181
 182         if (!isdemo())
 183         {
 184                 if (!(calledhooks & HOOK_START))
 185                         localcmd("\n_cl_hook_gamestart nop\n");
 186                 if (!(calledhooks & HOOK_END))
 187                 {
 188                         int gamecount = cvar("cl_matchcount");
 189                         localcmd("\ncl_hook_gameend\n");
 190                         // NOTE: using localcmd here to ensure it's executed AFTER cl_hook_gameend
 191                         // earlier versions of the game abuse the hook to set this cvar
 192                         localcmd(strcat("cl_matchcount ", itos(gamecount + 1), "\n"));
 193                         //cvar_set("cl_matchcount", itos(gamecount + 1));
 194                 }
 195         }
 196
 197         localcmd("\ncl_hook_shutdown\n");
 198
 199         localcmd("\n-button12\n");
 200
 201         deactivate_minigame();
 202         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 203
 204         ReplicateVars(REPLICATEVARS_DESTROY);
 205 }
 206
 207 void AuditLists()
 208 {
 209         entity e;
 210         entity prev;
 211
 212         prev = players;
 213         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 214         {
 215                 if(prev != e.sort_prev)
 216                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 217         }
 218
 219         prev = teams;
 220         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 221         {
 222                 if(prev != e.sort_prev)
 223                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 224         }
 225 }
 226
 227 float RegisterPlayer(entity player)
 228 {
 229         entity pl;
 230         AuditLists();
 231         for(pl = players.sort_next; pl; pl = pl.sort_next)
 232                 if(pl == player)
 233                         error("Player already registered!");
 234         player.sort_next = players.sort_next;
 235         player.sort_prev = players;
 236         if(players.sort_next)
 237                 players.sort_next.sort_prev = player;
 238         players.sort_next = player;
 239         AuditLists();
 240         return true;
 241 }
 242
 243 void RemovePlayer(entity player)
 244 {
 245         entity pl, parent;
 246         AuditLists();
 247         parent = players;
 248         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
 249                 parent = pl;
 250
 251         if(!pl)
 252         {
 253                 error("Trying to remove a player which is not in the playerlist!");
 254                 return;
 255         }
 256         parent.sort_next = player.sort_next;
 257         if(player.sort_next)
 258                 player.sort_next.sort_prev = parent;
 259         AuditLists();
 260 }
 261
 262 void MoveToLast(entity e)
 263 {
 264         AuditLists();
 265         entity ent = e.sort_next;
 266         while(ent)
 267         {
 268                 SORT_SWAP(ent, e);
 269                 ent = e.sort_next;
 270         }
 271         AuditLists();
 272 }
 273
 274 float RegisterTeam(entity Team)
 275 {
 276         assert_once(Team.team, eprint(Team));
 277         entity tm;
 278         AuditLists();
 279         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 280                 if(tm == Team)
 281                         error("Team already registered!");
 282         Team.sort_next = teams.sort_next;
 283         Team.sort_prev = teams;
 284         if(teams.sort_next)
 285                 teams.sort_next.sort_prev = Team;
 286         teams.sort_next = Team;
 287         if(Team.team && Team.team != NUM_SPECTATOR)
 288                 ++team_count;
 289         AuditLists();
 290         return true;
 291 }
 292
 293 void RemoveTeam(entity Team)
 294 {
 295         entity tm, parent;
 296         AuditLists();
 297         parent = teams;
 298         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 299                 parent = tm;
 300
 301         if(!tm)
 302         {
 303                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
 304                 return;
 305         }
 306         parent.sort_next = Team.sort_next;
 307         if(Team.sort_next)
 308                 Team.sort_next.sort_prev = parent;
 309         if(Team.team && Team.team != NUM_SPECTATOR)
 310                 --team_count;
 311         AuditLists();
 312 }
 313
 314 entity GetTeam(int Team, bool add)
 315 {
 316         TC(int, Team); TC(bool, add);
 317         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
 318         if(teamslots[num])
 319                 return teamslots[num];
 320         if (!add)
 321                 return NULL;
 322         entity tm = new_pure(team);
 323         tm.team = Team;
 324         teamslots[num] = tm;
 325         RegisterTeam(tm);
 326         return tm;
 327 }
 328
 329 .float has_team;
 330 bool SetTeam(entity o, int Team)
 331 {
 332         TC(int, Team);
 333         //devassert_once(Team);
 334         entity tm;
 335         if(teamplay)
 336         {
 337                 switch(Team)
 338                 {
 339                         case -1:
 340                         case NUM_TEAM_1:
 341                         case NUM_TEAM_2:
 342                         case NUM_TEAM_3:
 343                         case NUM_TEAM_4:
 344                                 break;
 345                         default:
 346                                 if(GetTeam(Team, false) == NULL)
 347                                 {
 348                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 349                                         Team = NUM_SPECTATOR;
 350                                 }
 351                                 break;
 352                 }
 353         }
 354         else
 355         {
 356                 switch(Team)
 357                 {
 358                         case -1:
 359                         case 0:
 360                                 break;
 361                         default:
 362                                 if(GetTeam(Team, false) == NULL)
 363                                 {
 364                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 365                                         Team = NUM_SPECTATOR;
 366                                 }
 367                                 break;
 368                 }
 369         }
 370         if(Team == -1) // leave
 371         {
 372                 if(o.has_team)
 373                 {
 374                         tm = GetTeam(o.team, false);
 375                         tm.team_size -= 1;
 376                         o.has_team = 0;
 377                         return true;
 378                 }
 379         }
 380         else
 381         {
 382                 if (!o.has_team)
 383                 {
 384                         o.team = Team;
 385                         tm = GetTeam(Team, true);
 386                         tm.team_size += 1;
 387                         o.has_team = 1;
 388                         return true;
 389                 }
 390                 else if(Team != o.team)
 391                 {
 392                         tm = GetTeam(o.team, false);
 393                         tm.team_size -= 1;
 394                         o.team = Team;
 395                         tm = GetTeam(Team, true);
 396                         tm.team_size += 1;
 397                         return true;
 398                 }
 399         }
 400         return false;
 401 }
 402
 403 void Playerchecker_Think(entity this)
 404 {
 405         int i;
 406         entity e;
 407         for(i = 0; i < maxclients; ++i)
 408         {
 409                 e = playerslots[i];
 410                 if(entcs_GetName(i) == "")
 411                 {
 412                         if(e.sort_prev)
 413                         {
 414                                 // player disconnected
 415                                 SetTeam(e, -1);
 416                                 RemovePlayer(e);
 417                                 e.sort_prev = NULL;
 418                                 //e.gotscores = 0;
 419                         }
 420                 }
 421                 else
 422                 {
 423                         if (!e.sort_prev)
 424                         {
 425                                 // player connected
 426                                 if (!e)
 427                                 {
 428                                         playerslots[i] = e = new_pure(playerslot);
 429                                 }
 430                                 e.sv_entnum = i;
 431                                 e.ping = 0;
 432                                 e.ping_packetloss = 0;
 433                                 e.ping_movementloss = 0;
 434                                 //e.gotscores = 0; // we might already have the scores...
 435                                 int t = entcs_GetScoreTeam(i);
 436                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 437                                 RegisterPlayer(e);
 438                                 Scoreboard_UpdatePlayerPos(e);
 439                         }
 440                 }
 441         }
 442         this.nextthink = time + 0.2;
 443 }
 444
 445 void PostInit()
 446 {
 447         entity playerchecker = new_pure(playerchecker);
 448         setthink(playerchecker, Playerchecker_Think);
 449         playerchecker.nextthink = time + 0.2;
 450
 451         TrueAim_Init();
 452
 453         // this can't be called in CSQC_Init as it'd send cvars too early
 454         ReplicateVars_Start();
 455
 456         postinit = true;
 457 }
 458
 459 void Release_Common_Keys()
 460 {
 461         localcmd("-fire\n");
 462         localcmd("-fire2\n");
 463         localcmd("-use\n");
 464         localcmd("-hook\n");
 465         localcmd("-jump\n");
 466 }
 467
 468 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 469 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 470 // All keys are in ascii.
 471 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 472 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 473 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 474 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 475 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 476 {
 477         TC(int, bInputType);
 478         bool override = false;
 479
 480         override |= HUD_Scoreboard_InputEvent(bInputType, nPrimary, nSecondary);
 481         if (override)
 482                 return true;
 483
 484         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 485         if (override)
 486                 return true;
 487
 488         override |= HUD_Panel_Chat_InputEvent(bInputType, nPrimary, nSecondary);
 489
 490         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 491
 492         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 493
 494         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 495
 496         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 497
 498         if(override)
 499                 return true;
 500
 501         if(bInputType == 3 || bInputType == 2)
 502                 return false;
 503
 504         // at this point bInputType can only be 0 or 1 (key pressed or released)
 505         bool key_pressed = (bInputType == 0);
 506
 507         if(key_pressed) {
 508                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 509                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 510                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 511                 if(nPrimary == K_TAB) hudShiftState |= S_TAB;
 512         }
 513         else {
 514                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 515                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 516                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 517                 if(nPrimary == K_TAB) hudShiftState -= (hudShiftState & S_TAB);
 518         }
 519
 520         // NOTE: Shift-Escape must be filtered out because it's the hardcoded console shortcut
 521         if (nPrimary == K_ESCAPE && !(hudShiftState & S_SHIFT) && key_pressed)
 522         {
 523                 if (hudShiftState & S_TAB)
 524                 {
 525                         Scoreboard_UI_Enable(0);
 526                         return true;
 527                 }
 528                 if (!isdemo() && cvar("_menu_gamemenu_dialog_available"))
 529                 {
 530                         localcmd("\nmenu_showgamemenudialog\n");
 531                         return true;
 532                 }
 533         }
 534
 535         return false;
 536 }
 537
 538 // END REQUIRED CSQC FUNCTIONS
 539 // --------------------------------------------------------------------------
 540
 541 // --------------------------------------------------------------------------
 542 // BEGIN OPTIONAL CSQC FUNCTIONS
 543
 544 void Ent_RemovePlayerScore(entity this)
 545 {
 546         if(this.owner) {
 547                 SetTeam(this.owner, -1);
 548                 this.owner.gotscores = 0;
 549                 FOREACH(Scores, true, {
 550                         this.owner.(scores(it)) = 0; // clear all scores
 551                 });
 552         }
 553 }
 554
 555 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 556 {
 557         make_pure(this);
 558         entity o;
 559
 560         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 561         // (no I've never heard of M-x replace-string, sed, or anything like that)
 562         bool isNew = !this.owner; // workaround for DP bug
 563         int n = ReadByte()-1;
 564
 565 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 566         if(!isNew && n != this.sv_entnum)
 567         {
 568                 //print("A CSQC entity changed its owner!\n");
 569                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 570                 isNew = true;
 571                 Ent_Remove(this);
 572         }
 573 #endif
 574
 575         this.sv_entnum = n;
 576
 577         o = playerslots[this.sv_entnum];
 578         if (!o)
 579         {
 580                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 581         }
 582         this.owner = o;
 583         o.sv_entnum = this.sv_entnum;
 584         o.gotscores = 1;
 585
 586         //if (!o.sort_prev)
 587         //      RegisterPlayer(o);
 588         //playerchecker will do this for us later, if it has not already done so
 589
 590         int sf = ReadShort();
 591         int lf = ReadShort();
 592         FOREACH(Scores, true, {
 593                 int p = 1 << (i % 16);
 594                 if (sf & p)
 595                 {
 596                         if (lf & p)
 597                                 o.(scores(it)) = ReadInt24_t();
 598                         else
 599                                 o.(scores(it)) = ReadChar();
 600                 }
 601         });
 602
 603         return = true;
 604
 605         if(o.sort_prev)
 606                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 607
 608         this.entremove = Ent_RemovePlayerScore;
 609 }
 610
 611 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 612 {
 613         make_pure(this);
 614         int i;
 615
 616         this.team = ReadByte();
 617         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 618
 619 #if MAX_TEAMSCORE <= 8
 620         int sf = ReadByte();
 621         int lf = ReadByte();
 622 #else
 623         int sf = ReadShort();
 624         int lf = ReadShort();
 625 #endif
 626         for(i = 0; i < MAX_TEAMSCORE; ++i)
 627                 if(sf & BIT(i))
 628                 {
 629                         if(lf & BIT(i))
 630                                 o.(teamscores(i)) = ReadInt24_t();
 631                         else
 632                                 o.(teamscores(i)) = ReadChar();
 633                 }
 634
 635         return = true;
 636
 637         Scoreboard_UpdateTeamPos(o);
 638 }
 639
 640 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 641 {
 642         make_pure(this);
 643         float newspectatee_status;
 644
 645         int f = ReadByte();
 646
 647         scoreboard_showscores_force = (f & BIT(0));
 648
 649         if(f & BIT(1))
 650         {
 651                 newspectatee_status = ReadByte();
 652                 if(newspectatee_status == player_localnum + 1)
 653                         newspectatee_status = -1; // observing
 654         }
 655         else
 656                 newspectatee_status = 0;
 657
 658         spectatorbutton_zoom = (f & BIT(2));
 659         observe_blocked = (f & BIT(3));
 660
 661         if(f & BIT(4))
 662         {
 663                 num_spectators = ReadByte();
 664
 665                 float i, slot;
 666
 667                 for(i = 0; i < MAX_SPECTATORS; ++i)
 668                         spectatorlist[i] = 0; // reset list first
 669
 670                 int limit = min(num_spectators, MAX_SPECTATORS);
 671                 for(i = 0; i < limit; ++i)
 672                 {
 673                         slot = ReadByte();
 674                         spectatorlist[i] = slot - 1;
 675                 }
 676         }
 677         else
 678         {
 679                 for(int j = 0; j < MAX_SPECTATORS; ++j)
 680                         spectatorlist[j] = 0; // reset list if showspectators has been turned off
 681                 num_spectators = 0;
 682         }
 683
 684         return = true;
 685
 686         if(newspectatee_status != spectatee_status)
 687         {
 688                 // clear race stuff
 689                 race_laptime = 0;
 690                 race_checkpointtime = 0;
 691                 hud_dynamic_shake_factor = -1;
 692                 spectatee_status_changed_time = time;
 693         }
 694         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 695         {
 696                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 697                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 698                 )
 699                         prev_p_health = -1;
 700                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 701                         prev_health = -1;
 702         }
 703         spectatee_status = newspectatee_status;
 704
 705         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 706 }
 707
 708 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 709 {
 710         make_pure(this);
 711         int i, j, b, f;
 712
 713         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 714
 715         if(!(nags & BIT(2)))
 716         {
 717                 strfree(vote_called_vote);
 718                 vote_active = 0;
 719         }
 720         else
 721         {
 722                 vote_active = 1;
 723         }
 724
 725         if(nags & BIT(6))
 726         {
 727                 vote_yescount = ReadByte();
 728                 vote_nocount = ReadByte();
 729                 vote_needed = ReadByte();
 730                 vote_highlighted = ReadChar();
 731         }
 732
 733         if(nags & BIT(7))
 734         {
 735                 strcpy(vote_called_vote, ReadString());
 736         }
 737
 738         if(nags & 1)
 739         {
 740                 for(j = 0; j < maxclients; ++j)
 741                         if(playerslots[j])
 742                                 playerslots[j].ready = true;
 743                 for(i = 1; i <= maxclients; i += 8)
 744                 {
 745                         f = ReadByte();
 746                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 747                                 if (!(f & b))
 748                                         if(playerslots[j])
 749                                                 playerslots[j].ready = false;
 750                 }
 751         }
 752
 753         return = true;
 754
 755         ready_waiting = (nags & BIT(0));
 756         ready_waiting_for_me = (nags & BIT(1));
 757         vote_waiting = (nags & BIT(2));
 758         vote_waiting_for_me = (nags & BIT(3));
 759         warmup_stage = (nags & BIT(4));
 760 }
 761
 762 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 763 {
 764         make_pure(this);
 765         int sf = 0;
 766         serialize(byte, 0, sf);
 767         if (sf & 1) {
 768                 for (int j = 0; j < maxclients; ++j) {
 769                         if (playerslots[j]) {
 770                                 playerslots[j].eliminated = true;
 771                         }
 772                 }
 773                 for (int i = 1; i <= maxclients; i += 8) {
 774                         int f = 0;
 775                         serialize(byte, 0, f);
 776                         for (int b = 0; b < 8; ++b) {
 777                                 if (f & BIT(b)) continue;
 778                                 int j = i - 1 + b;
 779                                 if (playerslots[j]) {
 780                                         playerslots[j].eliminated = false;
 781                                 }
 782                         }
 783                 }
 784         }
 785         return true;
 786 }
 787
 788 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 789 {
 790         make_pure(this);
 791         prandom_debug();
 792         float s = ReadShort();
 793         psrandom(s);
 794         return true;
 795 }
 796
 797 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 798 {
 799         make_pure(this);
 800         float entnum = ReadByte();
 801
 802         int sf = ReadInt24_t();
 803         if (sf == 0) {
 804                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 805                         weapon_accuracy[w] = -1;
 806                 return true;
 807         }
 808
 809         int f = 1;
 810         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 811                 if (sf & f) {
 812                         if(entnum > 0) {
 813                                 playerslots[entnum-1].accuracy_frags[w] = ReadByte();
 814                                 playerslots[entnum-1].accuracy_hit[w] = ReadShort();
 815                                 playerslots[entnum-1].accuracy_cnt_hit[w] = ReadShort();
 816                                 playerslots[entnum-1].accuracy_cnt_fired[w] = ReadShort();
 817
 818                                 //LOG_INFOF("Duel stats ?/%d", playerslots[entnum-1].accuracy_cnt_fired[w]);
 819                         } else {
 820                                 int b = ReadByte();
 821                                 if (b == 0)
 822                                         weapon_accuracy[w] = -1;
 823                                 else if (b == 255)
 824                                         weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 825                                 else
 826                                         weapon_accuracy[w] = (b - 1.0) / 100.0;
 827                         }
 828                 }
 829                 f = (f == 0x800000) ? 1 : f * 2;
 830         }
 831         return true;
 832 }
 833
 834 void Spawn_Draw(entity this)
 835 {
 836         bool dodraw = autocvar_cl_spawn_point_particles;
 837         if(dodraw && autocvar_cl_spawn_point_dist_max)
 838         {
 839                 vector org = getpropertyvec(VF_ORIGIN);
 840                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
 841         }
 842
 843         if(dodraw)
 844                 pointparticles(((!teamplay) ? EFFECT_SPAWNPOINT_NEUTRAL : EFFECT_SPAWNPOINT(this.team - 1)), this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 845 }
 846
 847 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 848 {
 849         float teamnum = (ReadByte() - 1);
 850         vector spn_origin = ReadVector();
 851
 852         this.team = (teamnum + 1);
 853
 854         //if(is_new)
 855         //{
 856                 this.origin = spn_origin;
 857                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 858                 //droptofloor();
 859
 860                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 861                 {
 862                         this.mdl = "models/spawnpoint.md3";
 863                         this.colormod = Team_ColorRGB(teamnum);
 864                         precache_model(this.mdl);
 865                         setmodel(this, this.mdl);
 866                         this.drawmask = MASK_NORMAL;
 867                         //this.move_movetype = MOVETYPE_NOCLIP;
 868                         //this.draw = Spawn_Draw;
 869                         IL_PUSH(g_drawables, this);
 870                 }*/
 871                 this.draw = Spawn_Draw;
 872                 if (is_new) IL_PUSH(g_drawables, this);
 873         //}
 874
 875         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 876         return true;
 877 }
 878
 879 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 880 {
 881         // If entnum is 0, ONLY do the local spawn actions
 882         // this way the server can disable the sending of
 883         // spawn origin or such to clients if wanted.
 884         float entnum = ReadByte();
 885
 886         if(entnum)
 887         {
 888                 this.origin = ReadVector();
 889
 890                 if(is_new)
 891                 {
 892                         float teamnum = entcs_GetTeam(entnum - 1);
 893
 894                         if(autocvar_cl_spawn_event_particles)
 895                         {
 896                                 switch(teamnum)
 897                                 {
 898                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 899                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 900                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 901                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 902                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 903                                 }
 904                         }
 905                         if(autocvar_cl_spawn_event_sound)
 906                         {
 907                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 908                         }
 909                 }
 910         }
 911         return = true;
 912
 913         // local spawn actions
 914         if(is_new && (!entnum || (entnum == player_localentnum)))
 915         {
 916                 if(autocvar_cl_spawnzoom && !autocvar_cl_lockview)
 917                 {
 918                         zoomin_effect = 1;
 919                         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 920                 }
 921
 922                 if(autocvar_cl_unpress_zoom_on_spawn)
 923                 {
 924                         localcmd("-zoom\n");
 925                         button_zoom = false;
 926                 }
 927                 HUD_Radar_Hide_Maximized();
 928         }
 929         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 930 }
 931
 932 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 933 // The parameter isnew reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 934 void CSQC_Ent_Update(entity this, bool isnew)
 935 {
 936         this.sourceLoc = __FILE__":"STR(__LINE__);
 937         int t = ReadByte();
 938
 939         // set up the "time" global for received entities to be correct for interpolation purposes
 940         float savetime = time;
 941         if(servertime)
 942         {
 943                 time = servertime;
 944         }
 945         else
 946         {
 947                 serverprevtime = time;
 948                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 949                 time = serverprevtime + serverdeltatime;
 950         }
 951
 952 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 953         if (this.enttype)
 954         {
 955                 if (t != this.enttype || isnew)
 956                 {
 957                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 958                         Ent_Remove(this);
 959                         ONREMOVE(this);
 960                         clearentity(this);
 961                         isnew = true;
 962                 }
 963         }
 964         else
 965         {
 966                 if (!isnew)
 967                 {
 968                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 969                         isnew = true;
 970                 }
 971         }
 972 #endif
 973         this.enttype = t;
 974         bool done = false;
 975         FOREACH(LinkedEntities, it.m_id == t, {
 976                 if (isnew) this.classname = it.netname;
 977                 if (autocvar_developer_csqcentities)
 978                         LOG_INFOF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 979                 done = it.m_read(this, NULL, isnew);
 980                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 981                 break;
 982         });
 983         time = savetime;
 984         if (!done)
 985         {
 986                 LOG_FATALF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 987         }
 988 }
 989
 990 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 991 // used when an entity changes its type. For an entity that someone interacts
 992 // with others, make sure it can no longer do so.
 993 void Ent_Remove(entity this)
 994 {
 995         if(this.entremove) this.entremove(this);
 996
 997         if(this.skeletonindex)
 998         {
 999                 skel_delete(this.skeletonindex);
1000                 this.skeletonindex = 0;
1001         }
1002
1003         if(this.snd_looping > 0)
1004         {
1005                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
1006                 this.snd_looping = 0;
1007         }
1008
1009         this.enttype = 0;
1010         this.classname = "";
1011         this.draw = func_null;
1012         this.entremove = func_null;
1013         // TODO possibly set more stuff to defaults
1014 }
1015 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
1016 void CSQC_Ent_Remove(entity this)
1017 {
1018         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
1019         if (wasfreed(this))
1020         {
1021                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
1022                 return;
1023         }
1024         if (this.enttype) Ent_Remove(this);
1025         delete(this);
1026 }
1027
1028 void Gamemode_Init()
1029 {
1030         if (!isdemo())
1031         {
1032                 if(!(calledhooks & HOOK_START))
1033                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
1034                 calledhooks |= HOOK_START;
1035         }
1036 }
1037 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1038 void CSQC_Parse_StuffCmd(string strMessage)
1039 {
1040         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
1041         localcmd(strMessage);
1042 }
1043 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1044 void CSQC_Parse_Print(string strMessage)
1045 {
1046         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
1047         print(ColorTranslateRGB(strMessage));
1048 }
1049
1050 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
1051 void CSQC_Parse_CenterPrint(string strMessage)
1052 {
1053         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
1054         centerprint_AddStandard(strMessage);
1055 }
1056
1057 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1058 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1059 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1060 bool CSQC_Parse_TempEntity()
1061 {
1062         // Acquire TE ID
1063         int nTEID = ReadByte();
1064
1065         FOREACH(TempEntities, it.m_id == nTEID, {
1066                 if (autocvar_developer_csqcentities)
1067                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
1068                 return it.m_read(NULL, NULL, true);
1069         });
1070
1071         if (autocvar_developer_csqcentities)
1072                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
1073
1074         // No special logic for this temporary entity; return 0 so the engine can handle it
1075         return false;
1076 }
1077
1078 string forcefog;
1079 void Fog_Force()
1080 {
1081         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1082                 localcmd("\nr_drawfog 0\n");
1083         else if (forcefog != "")
1084                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
1085 }
1086
1087 bool net_handle_ServerWelcome();
1088 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
1089 {
1090         make_pure(this);
1091         gametype = ReadRegistered(Gametypes);
1092         teamplay = _MapInfo_GetTeamPlayBool(gametype);
1093         HUD_ModIcons_SetFunc();
1094         FOREACH(Scores, true, {
1095                 strcpy(scores_label(it), ReadString());
1096                 scores_flags(it) = ReadByte();
1097         });
1098         for (int i = 0; i < MAX_TEAMSCORE; ++i)
1099         {
1100                 strcpy(teamscores_label(i), ReadString());
1101                 teamscores_flags(i) = ReadByte();
1102         }
1103         bool welcome_msg_too = ReadByte();
1104         if (welcome_msg_too)
1105                 net_handle_ServerWelcome();
1106         return = true;
1107         Scoreboard_InitScores();
1108         Gamemode_Init();
1109 }
1110
1111 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
1112 {
1113         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1114
1115         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1116         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1117         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1118         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1119         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1120         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1121         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1122         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1123
1124         strcpy(forcefog, ReadString());
1125
1126         armorblockpercent = ReadByte() / 255.0;
1127         damagepush_speedfactor = ReadByte() / 255.0;
1128
1129         serverflags = ReadByte();
1130
1131         g_trueaim_minrange = ReadCoord();
1132
1133         strcpy(hostname_full, ReadString());
1134         strcpy(motd_permanent, ReadString());
1135
1136         sv_timer_countdown = ReadByte();
1137
1138         return = true;
1139
1140         MUTATOR_CALLHOOK(Ent_Init);
1141
1142         if (!postinit) PostInit();
1143 }
1144
1145 NET_HANDLE(TE_CSQC_TEAMNAMES, bool isNew)
1146 {
1147         teamname_red = strzone(ReadString());
1148         teamname_blue = strzone(ReadString());
1149         teamname_yellow = strzone(ReadString());
1150         teamname_pink = strzone(ReadString());
1151
1152         return = true;
1153 }
1154
1155 NET_HANDLE(TE_CSQC_CHATSOUND, bool isNew)
1156 {
1157         string snd = ReadString();
1158         snd = strcat("chat/", snd, ".ogg");
1159
1160         precache_sound(snd);
1161         _sound(NULL, CH_INFO, snd, VOL_BASE, ATTN_NONE);
1162
1163         return = true;
1164 }
1165
1166 float GetSpeedUnitFactor(int speed_unit)
1167 {
1168         switch(speed_unit)
1169         {
1170                 default:
1171                 case 1: return 1.0;
1172                 case 2: return 0.0254;
1173                 case 3: return 0.0254 * 3.6;
1174                 case 4: return 0.0254 * 3.6 * 0.6213711922;
1175                 case 5: return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1176         }
1177 }
1178
1179 string GetSpeedUnit(int speed_unit)
1180 {
1181         switch(speed_unit)
1182         {
1183                 // translator-friendly strings without the initial space
1184                 default:
1185                 case 1: return strcat(" ", _("qu/s"));
1186                 case 2: return strcat(" ", _("m/s"));
1187                 case 3: return strcat(" ", _("km/h"));
1188                 case 4: return strcat(" ", _("mph"));
1189                 case 5: return strcat(" ", _("knots"));
1190         }
1191 }
1192
1193 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1194 {
1195         int b = ReadByte();
1196
1197         switch (b)
1198         {
1199                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1200                         race_checkpoint = ReadByte();
1201                         race_time = ReadInt24_t();
1202                         race_previousbesttime = ReadInt24_t();
1203                         race_mypreviousbesttime = ReadInt24_t();
1204                         string pbestname = ReadString();
1205                         if(autocvar_cl_race_cptimes_onlyself)
1206                         {
1207                                 race_previousbesttime = race_mypreviousbesttime;
1208                                 race_mypreviousbesttime = 0;
1209                                 strcpy(race_previousbestname, "");
1210                         }
1211                         else
1212                                 strcpy(race_previousbestname, pbestname);
1213
1214                         race_checkpointtime = time;
1215
1216                         if(race_checkpoint == 0 || race_checkpoint == 254)
1217                         {
1218                                 race_penaltyaccumulator = 0;
1219                                 race_laptime = time; // valid
1220                         }
1221                         break;
1222
1223                 case RACE_NET_CHECKPOINT_CLEAR:
1224                         race_laptime = 0;
1225                         race_checkpointtime = 0;
1226                         break;
1227
1228                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1229                         race_laptime = ReadCoord();
1230                         race_checkpointtime = -99999;
1231                         // fall through
1232                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1233                         race_nextcheckpoint = ReadByte();
1234
1235                         race_nextbesttime = ReadInt24_t();
1236                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1237                                 race_mybesttime = ReadInt24_t();
1238                         string newname = ReadString();
1239                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1240                         {
1241                                 race_nextbesttime = race_mybesttime;
1242                                 race_mybesttime = 0;
1243                                 strcpy(race_nextbestname, "");
1244                         }
1245                         else
1246                                 strcpy(race_nextbestname, newname);
1247                         break;
1248
1249                 case RACE_NET_CHECKPOINT_HIT_RACE:
1250                         race_mycheckpoint = ReadByte();
1251                         race_mycheckpointtime = time;
1252                         race_mycheckpointdelta = ReadInt24_t();
1253                         race_mycheckpointlapsdelta = ReadByte();
1254                         if(race_mycheckpointlapsdelta >= 128)
1255                                 race_mycheckpointlapsdelta -= 256;
1256                         int who = ReadByte();
1257                         if(who)
1258                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1259                         else
1260                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1261                         break;
1262
1263                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1264                         race_othercheckpoint = ReadByte();
1265                         race_othercheckpointtime = time;
1266                         race_othercheckpointdelta = ReadInt24_t();
1267                         race_othercheckpointlapsdelta = ReadByte();
1268                         if(race_othercheckpointlapsdelta >= 128)
1269                                 race_othercheckpointlapsdelta -= 256;
1270                         int what = ReadByte();
1271                         if(what)
1272                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1273                         else
1274                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1275                         break;
1276
1277                 case RACE_NET_PENALTY_RACE:
1278                 case RACE_NET_PENALTY_QUALIFYING:
1279                         race_penaltyeventtime = time;
1280                         race_penaltytime = ReadShort();
1281                         string reason = ReadString();
1282                         if (reason == "missing a checkpoint")
1283                                 reason = _("missing a checkpoint");
1284                         strcpy(race_penaltyreason, reason);
1285                         if (b == RACE_NET_PENALTY_QUALIFYING)
1286                                 race_penaltyaccumulator += race_penaltytime;
1287                         break;
1288
1289                 case RACE_NET_SERVER_RECORD:
1290                         race_server_record = ReadInt24_t();
1291                         break;
1292                 case RACE_NET_SPEED_AWARD:
1293                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1294                         strcpy(race_speedaward_holder, ReadString());
1295                         break;
1296                 case RACE_NET_SPEED_AWARD_BEST:
1297                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1298                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1299                         break;
1300                 case RACE_NET_RANKINGS_CNT:
1301                         RANKINGS_DISPLAY_CNT = ReadByte();
1302                         break;
1303                 case RACE_NET_SERVER_RANKINGS:
1304                         float prevpos, del;
1305                         int pos = ReadShort();
1306                         prevpos = ReadShort();
1307                         del = ReadShort();
1308
1309                         // move other rankings out of the way
1310                         int i;
1311                         if (prevpos) {
1312                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1313                                 for (i=m-1; i>pos-1; --i) {
1314                                         grecordtime[i] = grecordtime[i-1];
1315                                         strcpy(grecordholder[i], grecordholder[i-1]);
1316                                 }
1317                         } else if (del) { // a record has been deleted by the admin
1318                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1319                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1320                                                 grecordtime[i] = 0;
1321                                                 strfree(grecordholder[i]);
1322                                         }
1323                                         else {
1324                                                 grecordtime[i] = grecordtime[i+1];
1325                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1326                                         }
1327                                 }
1328                         } else { // player has no ranked record yet
1329                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1330                                         grecordtime[i] = grecordtime[i-1];
1331                                         strcpy(grecordholder[i], grecordholder[i-1]);
1332                                 }
1333                         }
1334
1335                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1336                                 // kick off the player who fell from the last displayed position
1337                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1338                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1339                         }
1340
1341                         // store new ranking
1342                         strcpy(grecordholder[pos-1], ReadString());
1343                         grecordtime[pos-1] = ReadInt24_t();
1344                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1345                                 race_myrank = pos;
1346                         break;
1347                 case RACE_NET_SERVER_STATUS:
1348                         race_status = ReadShort();
1349                         strcpy(race_status_name, ReadString());
1350         }
1351         return true;
1352 }
1353
1354 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1355 {
1356         teamnagger = 1;
1357         return true;
1358 }
1359
1360 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1361 {
1362         int i = ReadByte();
1363         int pi = ReadShort();
1364         int pl = ReadByte();
1365         int ml = ReadByte();
1366         return = true;
1367         entity e = playerslots[i];
1368         if (!e) return;
1369         e.ping = pi;
1370         e.ping_packetloss = pl / 255.0;
1371         e.ping_movementloss = ml / 255.0;
1372 }
1373
1374 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1375 {
1376         int weapon_id = ReadByte();
1377         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1378         complain_weapon_type = ReadByte();
1379         return = true;
1380
1381         complain_weapon_time = time;
1382         weapontime = time; // ping the weapon panel
1383
1384         switch(complain_weapon_type)
1385         {
1386                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1387                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1388                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1389         }
1390 }
1391
1392 string translate_modifications(string s)
1393 {
1394         return build_mutator_list(s);
1395 }
1396
1397 string translate_weaponarena(string s)
1398 {
1399         if (s == "") return s;
1400         if (s == "All Weapons Arena") return _("All Weapons Arena");
1401         if (s == "All Available Weapons Arena") return _("All Available Weapons Arena");
1402         if (s == "Most Weapons Arena") return _("Most Weapons Arena");
1403         if (s == "Most Available Weapons Arena") return _("Most Available Weapons Arena");
1404         if (s == "Dev All Weapons Arena") return s; // development option, do not translate
1405         if (s == "Dev All Available Weapons Arena") return s; // development option, do not translate
1406         if (s == "No Weapons Arena") return _("No Weapons Arena");
1407
1408         int n = tokenizebyseparator(s, " & ");
1409         string wpn_list = "";
1410         for (int i = 0; i < n; i++)
1411         {
1412                 Weapon wep = Weapon_from_name(argv(i));
1413                 if (wep == WEP_Null)
1414                         LOG_INFO("^3Warning: ^7server sent an invalid weapon name\n");
1415                 wpn_list = cons_mid(wpn_list, " & ", wep.m_name);
1416         }
1417         if (wpn_list != "")
1418                 return sprintf(_("%s Arena"), wpn_list);
1419         else
1420                 return _("No Weapons Arena");
1421 }
1422
1423 string GetVersionMessage(string hostversion, bool version_mismatch, bool version_check)
1424 {
1425         string xonotic_hostversion = strcat("Xonotic ", hostversion);
1426         if (version_mismatch)
1427         {
1428                 if(!version_check)
1429                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1430                                 _("Your client version is outdated."), "\n\n\n",
1431                                 _("### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###"), "\n\n\n",
1432                                 _("Please update!"));
1433                 else
1434                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1435                                 _("This server is using an outdated Xonotic version."), "\n\n\n",
1436                                 _("### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###"));
1437         }
1438         return sprintf(_("Welcome to %s"), xonotic_hostversion);
1439 }
1440
1441 bool net_handle_ServerWelcome()
1442 {
1443         bool campaign = ReadByte();
1444         if (campaign)
1445         {
1446                 string campaign_title = ReadString();
1447                 int campaign_level = ReadByte();
1448                 string campaign_msg = ReadString();
1449                 string welcomedialog_args;
1450                 welcomedialog_args = strcat("HOSTNAME \"", campaign_title, "\"");
1451                 string key = getcommandkey(_("jump"), "+jump");
1452                 string msg = strcat(
1453                         CCR("^F1"), sprintf(_("Level %d:"), campaign_level),
1454                         sprintf(CCR(" ^BG%s\n^3\n"), campaign_msg),
1455                         sprintf(CCR(_("^BGPress ^F2%s^BG to enter the game")), key));
1456                 msg = MakeConsoleSafe(strreplace("\n", "\\n", msg));
1457                 welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1458                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1459                 return true;
1460         }
1461
1462         strcpy(hostname, ReadString());
1463         string hostversion = ReadString();
1464         bool version_mismatch = ReadByte();
1465         bool version_check = ReadByte();
1466         srv_minplayers = ReadByte();
1467         srv_maxplayers = ReadByte();
1468         string modifications = translate_modifications(ReadString());
1469         string weaponarena_list = translate_weaponarena(ReadString());
1470         string cache_mutatormsg = ReadString();
1471         string motd = ReadString();
1472
1473         string msg = GetVersionMessage(hostversion, version_mismatch, version_check);
1474
1475         msg = strcat(msg, "\n\n", _("Gametype:"), " ^1", MapInfo_Type_ToText(gametype), "\n");
1476
1477         msg = strcat(msg, "\n", _("Map:"), " ^2");
1478         if (world.message == "")
1479                 msg = strcat(msg, mi_shortname, "\n");
1480         else
1481         {
1482                 int i = strstrofs(world.message, " by ", 0); // matches _MapInfo_Generate()
1483                 string longname = i >= 0 ? substring(world.message, 0, i) : world.message;
1484                 msg = strcat(msg, (strcasecmp(longname, mi_shortname) ? strcat(mi_shortname, " ^7// ^2") : ""), longname, "\n");
1485         }
1486
1487         if (srv_minplayers || srv_maxplayers)
1488         {
1489                 msg = strcat(msg, "\n", _("This match supports"), " ^5");
1490                 if (srv_minplayers == srv_maxplayers)
1491                         msg = strcat(msg, sprintf(_("%d players"), srv_maxplayers), "\n");
1492                 else if (srv_minplayers && srv_maxplayers)
1493                         msg = strcat(msg, sprintf(_("%d to %d players"), srv_minplayers, srv_maxplayers), "\n");
1494                 else if (srv_maxplayers)
1495                         msg = strcat(msg, sprintf(_("%d players maximum"), srv_maxplayers), "\n");
1496                 else
1497                         msg = strcat(msg, sprintf(_("%d players minimum"), srv_minplayers), "\n");
1498         }
1499
1500         modifications = cons_mid(modifications, ", ", weaponarena_list);
1501         if(modifications != "")
1502                 msg = strcat(msg, "\n", _("Active modifications:"), " ^3", modifications, "\n");
1503
1504         if (cache_mutatormsg != "")
1505                 msg = strcat(msg, "\n", _("Special gameplay tips:"), " ^7", cache_mutatormsg, "\n");
1506         string mutator_msg = "";
1507         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1508         mutator_msg = M_ARGV(0, string);
1509         msg = strcat(msg, mutator_msg); // trust that the mutator will do proper formatting
1510
1511         if (motd != "")
1512                 msg = strcat(msg, "\n^9↓ ", _("Server's message"), " ↓\n", motd);
1513
1514         strcpy(welcome_msg, msg);
1515         welcome_msg_menu_check_maxtime = time + 1; // wait for menu to load before showing the welcome dialog
1516         return true;
1517 }
1518
1519 void Welcome_Message_Show_Try()
1520 {
1521         if (!welcome_msg_menu_check_maxtime)
1522                 return;
1523
1524         // if want dialog check if menu is initialized but for a short time
1525         if (cvar("_menu_initialized") == 2 || time > welcome_msg_menu_check_maxtime)
1526         {
1527                 if (cvar("_menu_welcome_dialog_available"))
1528                 {
1529                         string welcomedialog_args = strcat("HOSTNAME \"", hostname, "\"");
1530                         string msg = MakeConsoleSafe(strreplace("\n", "\\n", welcome_msg));
1531                         welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1532
1533                         if (intermission || isdemo() || !autocvar_cl_welcome)
1534                         {
1535                                 if (cvar("_menu_cmd_closemenu_available"))
1536                                 {
1537                                         // initialize the dialog without opening it
1538                                         localcmd("\nmenu_cmd closemenu Welcome ", welcomedialog_args, "\n");
1539                                 }
1540                                 else
1541                                 {
1542                                         // legacy code for clients with old menus
1543                                         // since togglemenu 0 doesn't close the dialog but only hides it,
1544                                         // playing back a demo the Welcome dialog will pop up on the first ESC press
1545                                         localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1546                                         // close it after it's been initialized so it can still be opened manually
1547                                         localcmd("\ntogglemenu 0\n");
1548                                 }
1549                         }
1550                         else
1551                                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1552                 }
1553
1554                 strfree(welcome_msg);
1555                 welcome_msg_menu_check_maxtime = 0;
1556         }
1557 }
1558
1559 NET_HANDLE(TE_CSQC_SERVERWELCOME, bool isNew)
1560 {
1561         return net_handle_ServerWelcome();
1562 }
1563
1564 string _getcommandkey(string cmd_name, string command, bool forcename)
1565 {
1566         string keys;
1567         float n, j, k, l = 0;
1568
1569         if (!autocvar_hud_showbinds)
1570                 return cmd_name;
1571
1572         keys = db_get(binddb, command);
1573         if (keys == "")
1574         {
1575                 bool joy_active = cvar("joy_active");
1576                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1577                 for(j = 0; j < n; ++j)
1578                 {
1579                         k = stof(argv(j));
1580                         if(k != -1)
1581                         {
1582                                 string key = keynumtostring(k);
1583                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1584                                         continue;
1585
1586                                 key = translate_key(key);
1587
1588                                 if (keys == "")
1589                                         keys = key;
1590                                 else
1591                                         keys = strcat(keys, ", ", key);
1592
1593                                 ++l;
1594                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1595                                         break;
1596                         }
1597
1598                 }
1599                 if (keys == "")
1600                         keys = "NO_KEY";
1601                 db_put(binddb, command, keys);
1602         }
1603
1604         if (keys == "NO_KEY") {
1605                 if (autocvar_hud_showbinds > 1)
1606                         return sprintf(_("%s (not bound)"), cmd_name);
1607                 else
1608                         return cmd_name;
1609         }
1610         else if (autocvar_hud_showbinds > 1 || forcename)
1611                 return sprintf("%s (%s)", cmd_name, keys);
1612         else
1613                 return keys;
1614 }
1615
1616 /** engine callback */
1617 void URI_Get_Callback(int id, int status, string data)
1618 {
1619         TC(int, id); TC(int, status);
1620         if(url_URI_Get_Callback(id, status, data))
1621         {
1622                 // handled
1623         }
1624         else if (id == URI_GET_DISCARD)
1625         {
1626                 // discard
1627         }
1628         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1629         {
1630                 // sv_cmd curl
1631                 Curl_URI_Get_Callback(id, status, data);
1632         }
1633         else
1634         {
1635                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
1636         }
1637 }