qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <client/command/cl_cmd.qh>
   4 #include <client/draw.qh>
   5 #include <client/hud/_mod.qh>
   6 #include <client/hud/panel/centerprint.qh>
   7 #include <client/hud/panel/chat.qh>
   8 #include <client/hud/panel/quickmenu.qh>
   9 #include <client/hud/panel/scoreboard.qh>
  10 #include <client/items/items.qh>
  11 #include <client/mapvoting.qh>
  12 #include <client/mutators/_mod.qh>
  13 #include <client/shownames.qh>
  14 #include <client/view.qh>
  15 #include <client/weapons/projectile.qh>
  16 #include <common/deathtypes/all.qh>
  17 #include <common/effects/all.inc>
  18 #include <common/effects/all.qh>
  19 #include <common/effects/effect.qh>
  20 #include <common/effects/qc/_mod.qh>
  21 #include <common/ent_cs.qh>
  22 #include <common/gamemodes/gamemode/nexball/cl_nexball.qh>
  23 #include <common/items/_mod.qh>
  24 #include <common/mapinfo.qh>
  25 #include <common/mapobjects/_mod.qh>
  26 #include <common/minigames/cl_minigames.qh>
  27 #include <common/minigames/cl_minigames_hud.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/scores.qh>
  31 #include <common/vehicles/all.qh>
  32 #include <lib/csqcmodel/cl_model.qh>
  33 #include <lib/csqcmodel/interpolate.qh>
  34 #include <lib/warpzone/client.qh>
  35
  36 // --------------------------------------------------------------------------
  37 // BEGIN REQUIRED CSQC FUNCTIONS
  38 //include "main.qh"
  39
  40 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  41
  42 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  43 // Useful for precaching things
  44
  45 void CSQC_Init()
  46 {
  47         prvm_language = strzone(cvar_string("prvm_language"));
  48
  49 #ifdef WATERMARK
  50         LOG_TRACEF("^4CSQC Build information: ^1%s", WATERMARK);
  51 #endif
  52
  53         {
  54                 int i = 0;
  55                 for ( ; i < 255; ++i)
  56                         if (getplayerkeyvalue(i, "viewentity") == "")
  57                                 break;
  58                 maxclients = i;
  59         }
  60
  61         // needs to be done so early because of the constants they create
  62         static_init();
  63         static_init_late();
  64         static_init_precache();
  65
  66         binddb = db_create();
  67         tempdb = db_create();
  68         ClientProgsDB = db_load("client.db");
  69
  70         draw_endBoldFont();
  71
  72         //registercommand("hud_configure");
  73         //registercommand("hud_save");
  74         //registercommand("menu_action");
  75
  76         ConsoleCommand_macro_init();
  77
  78         registercvar("hud_usecsqc", "1");
  79         registercvar("scoreboard_columns", "default");
  80
  81         registercvar("cl_nade_type", "3");
  82         registercvar("cl_pokenade_type", "zombie");
  83
  84         registercvar("cl_jumpspeedcap_min", "");
  85         registercvar("cl_jumpspeedcap_max", "");
  86
  87         registercvar("cl_shootfromfixedorigin", "");
  88
  89         registercvar("cl_multijump", "-1");
  90
  91         registercvar("cl_dodging", "0");
  92
  93         registercvar("cl_spawn_near_teammate", "1");
  94
  95         registercvar("cl_weapon_switch_reload", "1");
  96         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
  97
  98         registercvar("cl_allow_uidranking", "1");
  99
 100         // z411
 101         registercvar("cl_chat_sounds", "1");
 102
 103         if(autocvar_cl_lockview)
 104                 cvar_set("cl_lockview", "0");
 105
 106         if (cvar_type("_scoreboard_team_selection_available") & CVAR_TYPEFLAG_EXISTS)
 107                 cvar_settemp("_scoreboard_team_selection_available", "1");
 108         cvar_set("_scoreboard_team_selection", "0"); // in case it has been left set to 1
 109
 110         gametype = NULL;
 111
 112         postinit = false;
 113
 114         calledhooks = 0;
 115
 116         teams = Sort_Spawn();
 117         players = Sort_Spawn();
 118
 119         GetTeam(NUM_SPECTATOR, true); // add specs first
 120
 121         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 122                 weapon_accuracy[w] = -1;
 123
 124         // precaches
 125
 126         if(autocvar_cl_reticle)
 127         {
 128                 precache_pic("gfx/reticle_normal");
 129                 // weapon reticles are precached in weapon files
 130         }
 131
 132         {
 133                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 134                 minimapname = strcat("gfx/", mi_shortname, "_radar");
 135
 136                 if (precache_pic(minimapname) == "")
 137                 {
 138                         // but maybe we have a non-clever minimap
 139                         minimapname = strcat("gfx/", mi_shortname, "_mini");
 140                         if (precache_pic(minimapname) == "")
 141                                 minimapname = ""; // FAIL
 142                         else
 143                                 get_mi_min_max_texcoords(0); // load new texcoords
 144                 }
 145
 146                 mi_center = (mi_min + mi_max) * 0.5;
 147                 mi_scale = mi_max - mi_min;
 148                 minimapname = strzone(minimapname);
 149         }
 150
 151         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 152         LoadMenuSkinValues();
 153 }
 154
 155 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 156 void Shutdown()
 157 {
 158         WarpZone_Shutdown();
 159
 160         delete(teams);
 161         delete(players);
 162         db_close(binddb);
 163         db_close(tempdb);
 164         if(autocvar_cl_db_saveasdump)
 165                 db_dump(ClientProgsDB, "client.db");
 166         else
 167                 db_save(ClientProgsDB, "client.db");
 168         db_close(ClientProgsDB);
 169
 170         if(camera_active)
 171                 cvar_set("chase_active",ftos(chase_active_backup));
 172
 173         // unset the event chasecam's chase_active
 174         if(autocvar_chase_active < 0)
 175                 cvar_set("chase_active", "0");
 176
 177         if (autocvar_r_drawviewmodel < 0)
 178                 cvar_set("r_drawviewmodel", "0");
 179
 180         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 181
 182         if (!isdemo())
 183         {
 184                 if (!(calledhooks & HOOK_START))
 185                         localcmd("\n_cl_hook_gamestart nop\n");
 186                 if (!(calledhooks & HOOK_END))
 187                 {
 188                         int gamecount = cvar("cl_matchcount");
 189                         localcmd("\ncl_hook_gameend\n");
 190                         // NOTE: using localcmd here to ensure it's executed AFTER cl_hook_gameend
 191                         // earlier versions of the game abuse the hook to set this cvar
 192                         localcmd(strcat("cl_matchcount ", itos(gamecount + 1), "\n"));
 193                         //cvar_set("cl_matchcount", itos(gamecount + 1));
 194                 }
 195         }
 196
 197         localcmd("\ncl_hook_shutdown\n");
 198
 199         localcmd("\n-button12\n");
 200
 201         deactivate_minigame();
 202         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 203
 204         ReplicateVars(REPLICATEVARS_DESTROY);
 205 }
 206
 207 void AuditLists()
 208 {
 209         entity e;
 210         entity prev;
 211
 212         prev = players;
 213         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 214         {
 215                 if(prev != e.sort_prev)
 216                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 217         }
 218
 219         prev = teams;
 220         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 221         {
 222                 if(prev != e.sort_prev)
 223                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 224         }
 225 }
 226
 227 float RegisterPlayer(entity player)
 228 {
 229         entity pl;
 230         AuditLists();
 231         for(pl = players.sort_next; pl; pl = pl.sort_next)
 232                 if(pl == player)
 233                         error("Player already registered!");
 234         player.sort_next = players.sort_next;
 235         player.sort_prev = players;
 236         if(players.sort_next)
 237                 players.sort_next.sort_prev = player;
 238         players.sort_next = player;
 239         AuditLists();
 240         return true;
 241 }
 242
 243 void RemovePlayer(entity player)
 244 {
 245         entity pl, parent;
 246         AuditLists();
 247         parent = players;
 248         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
 249                 parent = pl;
 250
 251         if(!pl)
 252         {
 253                 error("Trying to remove a player which is not in the playerlist!");
 254                 return;
 255         }
 256         parent.sort_next = player.sort_next;
 257         if(player.sort_next)
 258                 player.sort_next.sort_prev = parent;
 259         AuditLists();
 260 }
 261
 262 void MoveToLast(entity e)
 263 {
 264         AuditLists();
 265         entity ent = e.sort_next;
 266         while(ent)
 267         {
 268                 SORT_SWAP(ent, e);
 269                 ent = e.sort_next;
 270         }
 271         AuditLists();
 272 }
 273
 274 float RegisterTeam(entity Team)
 275 {
 276         assert_once(Team.team, eprint(Team));
 277         entity tm;
 278         AuditLists();
 279         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 280                 if(tm == Team)
 281                         error("Team already registered!");
 282         Team.sort_next = teams.sort_next;
 283         Team.sort_prev = teams;
 284         if(teams.sort_next)
 285                 teams.sort_next.sort_prev = Team;
 286         teams.sort_next = Team;
 287         if(Team.team && Team.team != NUM_SPECTATOR)
 288                 ++team_count;
 289         AuditLists();
 290         return true;
 291 }
 292
 293 void RemoveTeam(entity Team)
 294 {
 295         entity tm, parent;
 296         AuditLists();
 297         parent = teams;
 298         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 299                 parent = tm;
 300
 301         if(!tm)
 302         {
 303                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
 304                 return;
 305         }
 306         parent.sort_next = Team.sort_next;
 307         if(Team.sort_next)
 308                 Team.sort_next.sort_prev = parent;
 309         if(Team.team && Team.team != NUM_SPECTATOR)
 310                 --team_count;
 311         AuditLists();
 312 }
 313
 314 entity GetTeam(int Team, bool add)
 315 {
 316         TC(int, Team); TC(bool, add);
 317         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
 318         if(teamslots[num])
 319                 return teamslots[num];
 320         if (!add)
 321                 return NULL;
 322         entity tm = new_pure(team);
 323         tm.team = Team;
 324         teamslots[num] = tm;
 325         RegisterTeam(tm);
 326         return tm;
 327 }
 328
 329 .float has_team;
 330 bool SetTeam(entity o, int Team)
 331 {
 332         TC(int, Team);
 333         //devassert_once(Team);
 334         entity tm;
 335         if(teamplay)
 336         {
 337                 switch(Team)
 338                 {
 339                         case -1:
 340                         case NUM_TEAM_1:
 341                         case NUM_TEAM_2:
 342                         case NUM_TEAM_3:
 343                         case NUM_TEAM_4:
 344                                 break;
 345                         default:
 346                                 if(GetTeam(Team, false) == NULL)
 347                                 {
 348                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 349                                         Team = NUM_SPECTATOR;
 350                                 }
 351                                 break;
 352                 }
 353         }
 354         else
 355         {
 356                 switch(Team)
 357                 {
 358                         case -1:
 359                         case 0:
 360                                 break;
 361                         default:
 362                                 if(GetTeam(Team, false) == NULL)
 363                                 {
 364                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 365                                         Team = NUM_SPECTATOR;
 366                                 }
 367                                 break;
 368                 }
 369         }
 370         if(Team == -1) // leave
 371         {
 372                 if(o.has_team)
 373                 {
 374                         tm = GetTeam(o.team, false);
 375                         tm.team_size -= 1;
 376                         o.has_team = 0;
 377                         return true;
 378                 }
 379         }
 380         else
 381         {
 382                 if (!o.has_team)
 383                 {
 384                         o.team = Team;
 385                         tm = GetTeam(Team, true);
 386                         tm.team_size += 1;
 387                         o.has_team = 1;
 388                         return true;
 389                 }
 390                 else if(Team != o.team)
 391                 {
 392                         tm = GetTeam(o.team, false);
 393                         tm.team_size -= 1;
 394                         o.team = Team;
 395                         tm = GetTeam(Team, true);
 396                         tm.team_size += 1;
 397                         return true;
 398                 }
 399         }
 400         return false;
 401 }
 402
 403 void Playerchecker_Think(entity this)
 404 {
 405         int i;
 406         entity e;
 407         for(i = 0; i < maxclients; ++i)
 408         {
 409                 e = playerslots[i];
 410                 if(entcs_GetName(i) == "")
 411                 {
 412                         if(e.sort_prev)
 413                         {
 414                                 // player disconnected
 415                                 SetTeam(e, -1);
 416                                 RemovePlayer(e);
 417                                 e.sort_prev = NULL;
 418                                 //e.gotscores = 0;
 419                         }
 420                 }
 421                 else
 422                 {
 423                         if (!e.sort_prev)
 424                         {
 425                                 // player connected
 426                                 if (!e)
 427                                 {
 428                                         playerslots[i] = e = new_pure(playerslot);
 429                                 }
 430                                 e.sv_entnum = i;
 431                                 e.ping = 0;
 432                                 e.ping_packetloss = 0;
 433                                 e.ping_movementloss = 0;
 434                                 //e.gotscores = 0; // we might already have the scores...
 435                                 int t = entcs_GetScoreTeam(i);
 436                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 437                                 RegisterPlayer(e);
 438                                 Scoreboard_UpdatePlayerPos(e);
 439                         }
 440                 }
 441         }
 442         this.nextthink = time + 0.2;
 443 }
 444
 445 void PostInit()
 446 {
 447         entity playerchecker = new_pure(playerchecker);
 448         setthink(playerchecker, Playerchecker_Think);
 449         playerchecker.nextthink = time + 0.2;
 450
 451         TrueAim_Init();
 452
 453         // this can't be called in CSQC_Init as it'd send cvars too early
 454         ReplicateVars_Start();
 455
 456         postinit = true;
 457 }
 458
 459 void Release_Common_Keys()
 460 {
 461         localcmd("-fire\n");
 462         localcmd("-fire2\n");
 463         localcmd("-use\n");
 464         localcmd("-hook\n");
 465         localcmd("-jump\n");
 466         localcmd("-forward\n");
 467         localcmd("-back\n");
 468         localcmd("-moveleft\n");
 469         localcmd("-moveright\n");
 470 }
 471
 472 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 473 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 474 // All keys are in ascii.
 475 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 476 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 477 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 478 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 479 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 480 {
 481         TC(int, bInputType);
 482         bool override = false;
 483
 484         override |= HUD_Scoreboard_InputEvent(bInputType, nPrimary, nSecondary);
 485         if (override)
 486                 return true;
 487
 488         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 489         if (override)
 490                 return true;
 491
 492         override |= HUD_Panel_Chat_InputEvent(bInputType, nPrimary, nSecondary);
 493
 494         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 495
 496         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 497
 498         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 499
 500         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 501
 502         if(override)
 503                 return true;
 504
 505         if(bInputType == 3 || bInputType == 2)
 506                 return false;
 507
 508         // at this point bInputType can only be 0 or 1 (key pressed or released)
 509         bool key_pressed = (bInputType == 0);
 510
 511         if(key_pressed) {
 512                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 513                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 514                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 515                 if(nPrimary == K_TAB) hudShiftState |= S_TAB;
 516         }
 517         else {
 518                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 519                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 520                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 521                 if(nPrimary == K_TAB) hudShiftState -= (hudShiftState & S_TAB);
 522         }
 523
 524         // NOTE: Shift-Escape must be filtered out because it's the hardcoded console shortcut
 525         if (nPrimary == K_ESCAPE && !(hudShiftState & S_SHIFT) && key_pressed)
 526         {
 527                 if (hudShiftState & S_TAB)
 528                 {
 529                         Scoreboard_UI_Enable(0);
 530                         return true;
 531                 }
 532                 if (autocvar_menu_gamemenu && !isdemo() && cvar("_menu_gamemenu_dialog_available"))
 533                 {
 534                         localcmd("\nmenu_showgamemenudialog\n");
 535                         return true;
 536                 }
 537         }
 538
 539         return false;
 540 }
 541
 542 // END REQUIRED CSQC FUNCTIONS
 543 // --------------------------------------------------------------------------
 544
 545 // --------------------------------------------------------------------------
 546 // BEGIN OPTIONAL CSQC FUNCTIONS
 547 .int survival_status;
 548 void Ent_RemovePlayerScore(entity this)
 549 {
 550         if(this.owner) {
 551                 SetTeam(this.owner, -1);
 552                 this.owner.gotscores = 0;
 553                 FOREACH(Scores, true, {
 554                         this.owner.(scores(it)) = 0; // clear all scores
 555                 });
 556                 this.owner.ready = 0;
 557                 this.owner.eliminated = 0;
 558                 this.owner.colormap = 0;
 559                 // TODO add a hook to reset this Survival field
 560                 this.owner.survival_status = 0;
 561         }
 562 }
 563
 564 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 565 {
 566         make_pure(this);
 567         entity o;
 568
 569         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 570         // (no I've never heard of M-x replace-string, sed, or anything like that)
 571         bool isNew = !this.owner; // workaround for DP bug
 572         int n = ReadByte()-1;
 573
 574 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 575         if(!isNew && n != this.sv_entnum)
 576         {
 577                 //print("A CSQC entity changed its owner!\n");
 578                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 579                 isNew = true;
 580                 Ent_Remove(this);
 581         }
 582 #endif
 583
 584         this.sv_entnum = n;
 585
 586         o = playerslots[this.sv_entnum];
 587         if (!o)
 588         {
 589                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 590         }
 591         this.owner = o;
 592         o.sv_entnum = this.sv_entnum;
 593         o.gotscores = 1;
 594
 595         //if (!o.sort_prev)
 596         //      RegisterPlayer(o);
 597         //playerchecker will do this for us later, if it has not already done so
 598
 599         int sf = ReadShort();
 600         int lf = ReadShort();
 601         FOREACH(Scores, true, {
 602                 int p = 1 << (i % 16);
 603                 if (sf & p)
 604                 {
 605                         if (lf & p)
 606                                 o.(scores(it)) = ReadInt24_t();
 607                         else
 608                                 o.(scores(it)) = ReadChar();
 609                 }
 610         });
 611
 612         return = true;
 613
 614         if(o.sort_prev)
 615                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 616
 617         this.entremove = Ent_RemovePlayerScore;
 618 }
 619
 620 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 621 {
 622         make_pure(this);
 623         int i;
 624
 625         this.team = ReadByte();
 626         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 627
 628 #if MAX_TEAMSCORE <= 8
 629         int sf = ReadByte();
 630         int lf = ReadByte();
 631 #else
 632         int sf = ReadShort();
 633         int lf = ReadShort();
 634 #endif
 635         for(i = 0; i < MAX_TEAMSCORE; ++i)
 636                 if(sf & BIT(i))
 637                 {
 638                         if(lf & BIT(i))
 639                                 o.(teamscores(i)) = ReadInt24_t();
 640                         else
 641                                 o.(teamscores(i)) = ReadChar();
 642                 }
 643
 644         return = true;
 645
 646         Scoreboard_UpdateTeamPos(o);
 647 }
 648
 649 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 650 {
 651         make_pure(this);
 652         float newspectatee_status;
 653
 654         int f = ReadByte();
 655
 656         scoreboard_showscores_force = (f & BIT(0));
 657
 658         if(f & BIT(1))
 659         {
 660                 newspectatee_status = ReadByte();
 661                 if(newspectatee_status == player_localnum + 1)
 662                         newspectatee_status = -1; // observing
 663         }
 664         else
 665                 newspectatee_status = 0;
 666
 667         spectatorbutton_zoom = (f & BIT(2));
 668         observe_blocked = (f & BIT(3));
 669
 670         if(f & BIT(4))
 671         {
 672                 num_spectators = ReadByte();
 673
 674                 float i, slot;
 675
 676                 for(i = 0; i < MAX_SPECTATORS; ++i)
 677                         spectatorlist[i] = 0; // reset list first
 678
 679                 int limit = min(num_spectators, MAX_SPECTATORS);
 680                 for(i = 0; i < limit; ++i)
 681                 {
 682                         slot = ReadByte();
 683                         spectatorlist[i] = slot - 1;
 684                 }
 685         }
 686         else
 687         {
 688                 for(int j = 0; j < MAX_SPECTATORS; ++j)
 689                         spectatorlist[j] = 0; // reset list if showspectators has been turned off
 690                 num_spectators = 0;
 691         }
 692
 693         return = true;
 694
 695         if(newspectatee_status != spectatee_status)
 696         {
 697                 // clear race stuff
 698                 race_laptime = 0;
 699                 race_checkpointtime = 0;
 700                 hud_dynamic_shake_factor = -1;
 701                 spectatee_status_changed_time = time;
 702         }
 703         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 704         {
 705                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 706                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 707                 )
 708                         prev_p_health = -1;
 709                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 710                         prev_health = -1;
 711         }
 712         spectatee_status = newspectatee_status;
 713
 714         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 715 }
 716
 717 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 718 {
 719         make_pure(this);
 720
 721         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 722
 723         if(!(nags & BIT(2)))
 724         {
 725                 strfree(vote_called_vote);
 726                 vote_active = 0;
 727         }
 728         else
 729         {
 730                 vote_active = 1;
 731         }
 732
 733         if(nags & BIT(6))
 734         {
 735                 vote_yescount = ReadByte();
 736                 vote_nocount = ReadByte();
 737                 vote_needed = ReadByte();
 738                 vote_highlighted = ReadChar();
 739         }
 740
 741         if(nags & BIT(7))
 742         {
 743                 strcpy(vote_called_vote, ReadString());
 744         }
 745
 746         if(nags & BIT(0))
 747                 for(int i = 0; i < maxclients;)
 748                         for(int f = ReadByte(), b = 0; b < 8 && i < maxclients; ++b, ++i)
 749                                 if(playerslots[i])
 750                                         playerslots[i].ready = (f & BIT(b));
 751
 752         return = true;
 753
 754         ready_waiting = (nags & BIT(0));
 755         ready_waiting_for_me = (nags & BIT(1));
 756         vote_waiting = (nags & BIT(2));
 757         vote_waiting_for_me = (nags & BIT(3));
 758         warmup_stage = (nags & BIT(4));
 759 }
 760
 761 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 762 {
 763         make_pure(this);
 764         int sf = 0;
 765         serialize(byte, 0, sf);
 766         if (sf & 1) {
 767                 for (int j = 0; j < maxclients; ++j) {
 768                         if (playerslots[j]) {
 769                                 playerslots[j].eliminated = true;
 770                         }
 771                 }
 772                 for (int i = 1; i <= maxclients; i += 8) {
 773                         int f = 0;
 774                         serialize(byte, 0, f);
 775                         for (int b = 0; b < 8; ++b) {
 776                                 if (f & BIT(b)) continue;
 777                                 int j = i - 1 + b;
 778                                 if (playerslots[j]) {
 779                                         playerslots[j].eliminated = false;
 780                                 }
 781                         }
 782                 }
 783         }
 784         return true;
 785 }
 786
 787 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 788 {
 789         make_pure(this);
 790         prandom_debug();
 791         float s = ReadShort();
 792         psrandom(s);
 793         return true;
 794 }
 795
 796 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 797 {
 798         make_pure(this);
 799         float entnum = ReadByte();
 800
 801         int sf = ReadInt24_t();
 802         if (sf == 0) {
 803                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 804                         weapon_accuracy[w] = -1;
 805                 return true;
 806         }
 807
 808         int f = 1;
 809         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 810                 if (sf & f) {
 811                         if(entnum > 0) {
 812                                 playerslots[entnum-1].accuracy_frags[w] = ReadByte();
 813                                 playerslots[entnum-1].accuracy_hit[w] = ReadShort();
 814                                 playerslots[entnum-1].accuracy_cnt_hit[w] = ReadShort();
 815                                 playerslots[entnum-1].accuracy_cnt_fired[w] = ReadShort();
 816
 817                                 //LOG_INFOF("Duel stats ?/%d", playerslots[entnum-1].accuracy_cnt_fired[w]);
 818                         } else {
 819                                 int b = ReadByte();
 820                                 if (b == 0)
 821                                         weapon_accuracy[w] = -1;
 822                                 else if (b == 255)
 823                                         weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 824                                 else
 825                                         weapon_accuracy[w] = (b - 1.0) / 100.0;
 826                         }
 827                 }
 828                 f = (f == 0x800000) ? 1 : f * 2;
 829         }
 830         return true;
 831 }
 832
 833 void Spawn_Draw(entity this)
 834 {
 835         bool dodraw = autocvar_cl_spawn_point_particles;
 836         if(dodraw && autocvar_cl_spawn_point_dist_max)
 837         {
 838                 vector org = getpropertyvec(VF_ORIGIN);
 839                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
 840         }
 841
 842         if(dodraw)
 843                 pointparticles(((!teamplay) ? EFFECT_SPAWNPOINT_NEUTRAL : EFFECT_SPAWNPOINT(this.team - 1)), this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 844 }
 845
 846 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 847 {
 848         float teamnum = (ReadByte() - 1);
 849         vector spn_origin = ReadVector();
 850
 851         this.team = (teamnum + 1);
 852
 853         //if(is_new)
 854         //{
 855                 this.origin = spn_origin;
 856                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 857                 //droptofloor();
 858
 859                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 860                 {
 861                         this.mdl = "models/spawnpoint.md3";
 862                         this.colormod = Team_ColorRGB(teamnum);
 863                         precache_model(this.mdl);
 864                         setmodel(this, this.mdl);
 865                         this.drawmask = MASK_NORMAL;
 866                         //this.move_movetype = MOVETYPE_NOCLIP;
 867                         //this.draw = Spawn_Draw;
 868                         IL_PUSH(g_drawables, this);
 869                 }*/
 870                 this.draw = Spawn_Draw;
 871                 if (is_new) IL_PUSH(g_drawables, this);
 872         //}
 873
 874         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 875         return true;
 876 }
 877
 878 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 879 {
 880         // If entnum is 0, ONLY do the local spawn actions
 881         // this way the server can disable the sending of
 882         // spawn origin or such to clients if wanted.
 883         float entnum = ReadByte();
 884
 885         if(entnum)
 886         {
 887                 this.origin = ReadVector();
 888
 889                 if(is_new)
 890                 {
 891                         float teamnum = entcs_GetTeam(entnum - 1);
 892
 893                         if(autocvar_cl_spawn_event_particles)
 894                         {
 895                                 switch(teamnum)
 896                                 {
 897                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 898                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 899                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 900                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 901                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 902                                 }
 903                         }
 904                         if(autocvar_cl_spawn_event_sound)
 905                         {
 906                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 907                         }
 908                 }
 909         }
 910         return = true;
 911
 912         // local spawn actions
 913         if(is_new && (!entnum || (entnum == player_localentnum)))
 914         {
 915                 if(autocvar_cl_spawnzoom && !autocvar_cl_lockview)
 916                 {
 917                         zoomin_effect = 1;
 918                         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 919                 }
 920
 921                 if(autocvar_cl_unpress_zoom_on_spawn)
 922                 {
 923                         localcmd("-zoom\n");
 924                         button_zoom = false;
 925                 }
 926                 HUD_Radar_Hide_Maximized();
 927         }
 928         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 929 }
 930
 931 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 932 // The parameter isnew reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 933 void CSQC_Ent_Update(entity this, bool isnew)
 934 {
 935         this.sourceLoc = __FILE__":"STR(__LINE__);
 936         int t = ReadByte();
 937
 938         // set up the "time" global for received entities to be correct for interpolation purposes
 939         float savetime = time;
 940         if(servertime)
 941         {
 942                 time = servertime;
 943         }
 944         else
 945         {
 946                 serverprevtime = time;
 947                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 948                 time = serverprevtime + serverdeltatime;
 949         }
 950
 951 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 952         if (this.enttype)
 953         {
 954                 if (t != this.enttype || isnew)
 955                 {
 956                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 957                         Ent_Remove(this);
 958                         ONREMOVE(this);
 959                         clearentity(this);
 960                         isnew = true;
 961                 }
 962         }
 963         else
 964         {
 965                 if (!isnew)
 966                 {
 967                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 968                         isnew = true;
 969                 }
 970         }
 971 #endif
 972         this.enttype = t;
 973         bool done = false;
 974         FOREACH(LinkedEntities, it.m_id == t, {
 975                 if (isnew) this.classname = it.netname;
 976                 if (autocvar_developer_csqcentities)
 977                         LOG_INFOF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 978                 done = it.m_read(this, NULL, isnew);
 979                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 980                 break;
 981         });
 982         time = savetime;
 983         if (!done)
 984         {
 985                 LOG_FATALF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 986         }
 987 }
 988
 989 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 990 // used when an entity changes its type. For an entity that someone interacts
 991 // with others, make sure it can no longer do so.
 992 void Ent_Remove(entity this)
 993 {
 994         if(this.entremove) this.entremove(this);
 995
 996         if(this.skeletonindex)
 997         {
 998                 skel_delete(this.skeletonindex);
 999                 this.skeletonindex = 0;
1000         }
1001
1002         if(this.snd_looping > 0)
1003         {
1004                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
1005                 this.snd_looping = 0;
1006         }
1007
1008         this.enttype = 0;
1009         this.classname = "";
1010         this.draw = func_null;
1011         this.entremove = func_null;
1012         // TODO possibly set more stuff to defaults
1013 }
1014 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
1015 void CSQC_Ent_Remove(entity this)
1016 {
1017         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
1018         if (wasfreed(this))
1019         {
1020                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
1021                 return;
1022         }
1023         if (this.enttype) Ent_Remove(this);
1024         delete(this);
1025 }
1026
1027 void Gamemode_Init()
1028 {
1029         if (!isdemo())
1030         {
1031                 if(!(calledhooks & HOOK_START))
1032                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
1033                 calledhooks |= HOOK_START;
1034         }
1035 }
1036 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1037 void CSQC_Parse_StuffCmd(string strMessage)
1038 {
1039         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
1040         localcmd(strMessage);
1041 }
1042 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1043 void CSQC_Parse_Print(string strMessage)
1044 {
1045         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
1046         print(ColorTranslateRGB(strMessage));
1047 }
1048
1049 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
1050 void CSQC_Parse_CenterPrint(string strMessage)
1051 {
1052         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
1053         centerprint_AddStandard(strMessage);
1054 }
1055
1056 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1057 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1058 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1059 bool CSQC_Parse_TempEntity()
1060 {
1061         // Acquire TE ID
1062         int nTEID = ReadByte();
1063
1064         FOREACH(TempEntities, it.m_id == nTEID, {
1065                 if (autocvar_developer_csqcentities)
1066                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
1067                 return it.m_read(NULL, NULL, true);
1068         });
1069
1070         if (autocvar_developer_csqcentities)
1071                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
1072
1073         // No special logic for this temporary entity; return 0 so the engine can handle it
1074         return false;
1075 }
1076
1077 string forcefog;
1078 void Fog_Force()
1079 {
1080         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1081                 localcmd("\nr_drawfog 0\n");
1082         else if (forcefog != "")
1083                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
1084 }
1085
1086 bool net_handle_ServerWelcome();
1087 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
1088 {
1089         make_pure(this);
1090         gametype = ReadRegistered(Gametypes);
1091         teamplay = _MapInfo_GetTeamPlayBool(gametype);
1092         HUD_ModIcons_SetFunc();
1093         FOREACH(Scores, true, {
1094                 strcpy(scores_label(it), ReadString());
1095                 scores_flags(it) = ReadByte();
1096         });
1097         for (int i = 0; i < MAX_TEAMSCORE; ++i)
1098         {
1099                 strcpy(teamscores_label(i), ReadString());
1100                 teamscores_flags(i) = ReadByte();
1101         }
1102         bool welcome_msg_too = ReadByte();
1103         if (welcome_msg_too)
1104                 net_handle_ServerWelcome();
1105         return = true;
1106         Scoreboard_InitScores();
1107         Gamemode_Init();
1108 }
1109
1110 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
1111 {
1112         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1113
1114         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1115         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1116         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1117         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1118         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1119         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1120         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1121         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1122
1123         strcpy(forcefog, ReadString());
1124
1125         armorblockpercent = ReadByte() / 255.0;
1126         damagepush_speedfactor = ReadByte() / 255.0;
1127
1128         serverflags = ReadByte();
1129
1130         g_trueaim_minrange = ReadCoord();
1131
1132         strcpy(hostname_full, ReadString());
1133         strcpy(motd_permanent, ReadString());
1134
1135         sv_timer_countdown = ReadByte();
1136
1137         return = true;
1138
1139         MUTATOR_CALLHOOK(Ent_Init);
1140
1141         if (!postinit) PostInit();
1142 }
1143
1144 NET_HANDLE(TE_CSQC_TEAMNAMES, bool isNew)
1145 {
1146         teamname_red = strzone(ReadString());
1147         teamname_blue = strzone(ReadString());
1148         teamname_yellow = strzone(ReadString());
1149         teamname_pink = strzone(ReadString());
1150
1151         return = true;
1152 }
1153
1154 NET_HANDLE(TE_CSQC_CHATSOUND, bool isNew)
1155 {
1156         string snd = ReadString();
1157         snd = strcat("chat/", snd, ".ogg");
1158
1159         precache_sound(snd);
1160         _sound(NULL, CH_INFO, snd, VOL_BASE, ATTN_NONE);
1161
1162         return = true;
1163 }
1164
1165 float GetSpeedUnitFactor(int speed_unit)
1166 {
1167         switch(speed_unit)
1168         {
1169                 default:
1170                 case 1: return 1.0;
1171                 case 2: return 0.0254;
1172                 case 3: return 0.0254 * 3.6;
1173                 case 4: return 0.0254 * 3.6 * 0.6213711922;
1174                 case 5: return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1175         }
1176 }
1177
1178 string GetSpeedUnit(int speed_unit)
1179 {
1180         switch(speed_unit)
1181         {
1182                 // translator-friendly strings without the initial space
1183                 default:
1184                 case 1: return strcat(" ", _("qu/s"));
1185                 case 2: return strcat(" ", _("m/s"));
1186                 case 3: return strcat(" ", _("km/h"));
1187                 case 4: return strcat(" ", _("mph"));
1188                 case 5: return strcat(" ", _("knots"));
1189         }
1190 }
1191
1192 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1193 {
1194         int b = ReadByte();
1195
1196         switch (b)
1197         {
1198                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1199                         race_checkpoint = ReadByte();
1200                         race_time = ReadInt24_t();
1201                         race_previousbesttime = ReadInt24_t();
1202                         race_mypreviousbesttime = ReadInt24_t();
1203                         string pbestname = ReadString();
1204                         if(autocvar_cl_race_cptimes_onlyself)
1205                         {
1206                                 race_previousbesttime = race_mypreviousbesttime;
1207                                 race_mypreviousbesttime = 0;
1208                                 strcpy(race_previousbestname, "");
1209                         }
1210                         else
1211                                 strcpy(race_previousbestname, pbestname);
1212
1213                         race_checkpointtime = time;
1214
1215                         if(race_checkpoint == 0 || race_checkpoint == 254)
1216                         {
1217                                 race_penaltyaccumulator = 0;
1218                                 race_laptime = time; // valid
1219                         }
1220                         break;
1221
1222                 case RACE_NET_CHECKPOINT_CLEAR:
1223                         race_laptime = 0;
1224                         race_checkpointtime = 0;
1225                         break;
1226
1227                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1228                         race_laptime = ReadCoord();
1229                         race_checkpointtime = -99999;
1230                         // fall through
1231                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1232                         race_nextcheckpoint = ReadByte();
1233
1234                         race_nextbesttime = ReadInt24_t();
1235                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1236                                 race_mybesttime = ReadInt24_t();
1237                         string newname = ReadString();
1238                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1239                         {
1240                                 race_nextbesttime = race_mybesttime;
1241                                 race_mybesttime = 0;
1242                                 strcpy(race_nextbestname, "");
1243                         }
1244                         else
1245                                 strcpy(race_nextbestname, newname);
1246                         break;
1247
1248                 case RACE_NET_CHECKPOINT_HIT_RACE:
1249                         race_mycheckpoint = ReadByte();
1250                         race_mycheckpointtime = time;
1251                         race_mycheckpointdelta = ReadInt24_t();
1252                         race_mycheckpointlapsdelta = ReadByte();
1253                         if(race_mycheckpointlapsdelta >= 128)
1254                                 race_mycheckpointlapsdelta -= 256;
1255                         int who = ReadByte();
1256                         if(who)
1257                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1258                         else
1259                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1260                         break;
1261
1262                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1263                         race_othercheckpoint = ReadByte();
1264                         race_othercheckpointtime = time;
1265                         race_othercheckpointdelta = ReadInt24_t();
1266                         race_othercheckpointlapsdelta = ReadByte();
1267                         if(race_othercheckpointlapsdelta >= 128)
1268                                 race_othercheckpointlapsdelta -= 256;
1269                         int what = ReadByte();
1270                         if(what)
1271                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1272                         else
1273                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1274                         break;
1275
1276                 case RACE_NET_PENALTY_RACE:
1277                 case RACE_NET_PENALTY_QUALIFYING:
1278                         race_penaltyeventtime = time;
1279                         race_penaltytime = ReadShort();
1280                         string reason = ReadString();
1281                         if (reason == "missing a checkpoint")
1282                                 reason = _("missing a checkpoint");
1283                         strcpy(race_penaltyreason, reason);
1284                         if (b == RACE_NET_PENALTY_QUALIFYING)
1285                                 race_penaltyaccumulator += race_penaltytime;
1286                         break;
1287
1288                 case RACE_NET_SERVER_RECORD:
1289                         race_server_record = ReadInt24_t();
1290                         break;
1291                 case RACE_NET_SPEED_AWARD:
1292                         race_speedaward = ReadInt24_t();
1293                         strcpy(race_speedaward_holder, ReadString());
1294                         break;
1295                 case RACE_NET_SPEED_AWARD_BEST:
1296                         race_speedaward_alltimebest = ReadInt24_t();
1297                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1298                         break;
1299                 case RACE_NET_RANKINGS_CNT:
1300                         RANKINGS_DISPLAY_CNT = ReadByte();
1301                         break;
1302                 case RACE_NET_SERVER_RANKINGS:
1303                         float prevpos, del;
1304                         int pos = ReadShort();
1305                         prevpos = ReadShort();
1306                         del = ReadShort();
1307
1308                         // move other rankings out of the way
1309                         int i;
1310                         if (prevpos) {
1311                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1312                                 for (i=m-1; i>pos-1; --i) {
1313                                         grecordtime[i] = grecordtime[i-1];
1314                                         strcpy(grecordholder[i], grecordholder[i-1]);
1315                                 }
1316                         } else if (del) { // a record has been deleted by the admin
1317                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1318                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1319                                                 grecordtime[i] = 0;
1320                                                 strfree(grecordholder[i]);
1321                                         }
1322                                         else {
1323                                                 grecordtime[i] = grecordtime[i+1];
1324                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1325                                         }
1326                                 }
1327                         } else { // player has no ranked record yet
1328                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1329                                         grecordtime[i] = grecordtime[i-1];
1330                                         strcpy(grecordholder[i], grecordholder[i-1]);
1331                                 }
1332                         }
1333
1334                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1335                                 // kick off the player who fell from the last displayed position
1336                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1337                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1338                         }
1339
1340                         // store new ranking
1341                         strcpy(grecordholder[pos-1], ReadString());
1342                         grecordtime[pos-1] = ReadInt24_t();
1343                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1344                                 race_myrank = pos;
1345                         break;
1346                 case RACE_NET_SERVER_STATUS:
1347                         race_status = ReadShort();
1348                         strcpy(race_status_name, ReadString());
1349         }
1350         return true;
1351 }
1352
1353 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1354 {
1355         teamnagger = 1;
1356         return true;
1357 }
1358
1359 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1360 {
1361         int i = ReadByte();
1362         int pi = ReadShort();
1363         int pl = ReadByte();
1364         int ml = ReadByte();
1365         return = true;
1366         entity e = playerslots[i];
1367         if (!e) return;
1368         e.ping = pi;
1369         e.ping_packetloss = pl / 255.0;
1370         e.ping_movementloss = ml / 255.0;
1371 }
1372
1373 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1374 {
1375         int weapon_id = ReadByte();
1376         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1377         complain_weapon_type = ReadByte();
1378         return = true;
1379
1380         complain_weapon_time = time;
1381         weapontime = time; // ping the weapon panel
1382
1383         switch(complain_weapon_type)
1384         {
1385                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1386                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1387                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1388         }
1389 }
1390
1391 string translate_modifications(string s)
1392 {
1393         return build_mutator_list(s);
1394 }
1395
1396 string translate_weaponarena(string s)
1397 {
1398         if (s == "") return s;
1399         if (s == "All Weapons Arena") return _("All Weapons Arena");
1400         if (s == "All Available Weapons Arena") return _("All Available Weapons Arena");
1401         if (s == "Most Weapons Arena") return _("Most Weapons Arena");
1402         if (s == "Most Available Weapons Arena") return _("Most Available Weapons Arena");
1403         if (s == "Dev All Weapons Arena") return s; // development option, do not translate
1404         if (s == "Dev All Available Weapons Arena") return s; // development option, do not translate
1405         if (s == "No Weapons Arena") return _("No Weapons Arena");
1406
1407         int n = tokenizebyseparator(s, " & ");
1408         string wpn_list = "";
1409         for (int i = 0; i < n; i++)
1410         {
1411                 Weapon wep = Weapon_from_name(argv(i));
1412                 if (wep == WEP_Null)
1413                         LOG_INFO("^3Warning: ^7server sent an invalid weapon name\n");
1414                 wpn_list = cons_mid(wpn_list, " & ", wep.m_name);
1415         }
1416         if (wpn_list != "")
1417                 return sprintf(_("%s Arena"), wpn_list);
1418         else
1419                 return _("No Weapons Arena");
1420 }
1421
1422 string GetVersionMessage(string hostversion, bool version_mismatch, bool version_check)
1423 {
1424         string xonotic_hostversion = strcat("Xonotic ", hostversion);
1425         if (version_mismatch)
1426         {
1427                 if(!version_check)
1428                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1429                                 _("Your client version is outdated."), "\n\n\n",
1430                                 _("### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###"), "\n\n\n",
1431                                 _("Please update!"));
1432                 else
1433                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1434                                 _("This server is using an outdated Xonotic version."), "\n\n\n",
1435                                 _("### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###"));
1436         }
1437         return sprintf(_("Welcome to %s"), xonotic_hostversion);
1438 }
1439
1440 bool net_handle_ServerWelcome()
1441 {
1442         campaign = ReadByte();
1443         if (campaign)
1444         {
1445                 int campaign_level = ReadByte();
1446                 // Menu can't build the whole campaign message because it lacks getcommandkey and CCR
1447                 // so we build part of the message here and let the menu insert the level description
1448                 // (that client doesn't know) by replacing the keyword _LEVEL_DESC
1449                 string key = getcommandkey(_("jump"), "+jump");
1450                 string msg = strcat(
1451                         CCR("^F1"), sprintf(_("Level %d:"), campaign_level),
1452                         sprintf(CCR(" ^BG%s\n\n"), "_LEVEL_DESC"),
1453                         sprintf(CCR(_("^BGPress ^F2%s^BG to enter the game")), key));
1454                 msg = MakeConsoleSafe(strreplace("\n", "\\n", msg));
1455                 string welcomedialog_args = strcat("CAMPAIGN ", itos(campaign_level), " \"", msg, "\"");
1456
1457                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1458                 return true;
1459         }
1460
1461         strcpy(hostname, ReadString());
1462         string hostversion = ReadString();
1463         bool version_mismatch = ReadByte();
1464         bool version_check = ReadByte();
1465         srv_minplayers = ReadByte();
1466         srv_maxplayers = ReadByte();
1467         string modifications = translate_modifications(ReadString());
1468         string weaponarena_list = translate_weaponarena(ReadString());
1469         string cache_mutatormsg = ReadString();
1470         string motd = ReadString();
1471
1472         string msg = GetVersionMessage(hostversion, version_mismatch, version_check);
1473
1474         msg = strcat(msg, "\n\n", _("Gametype:"), " ^1", MapInfo_Type_ToText(gametype), "\n");
1475
1476         msg = strcat(msg, "\n", _("Map:"), " ^2");
1477         if (world.message == "")
1478                 msg = strcat(msg, mi_shortname, "\n");
1479         else
1480         {
1481                 int i = strstrofs(world.message, " by ", 0); // matches _MapInfo_Generate()
1482                 string longname = i >= 0 ? substring(world.message, 0, i) : world.message;
1483                 msg = strcat(msg, (strcasecmp(longname, mi_shortname) ? strcat(mi_shortname, " ^7// ^2") : ""), longname, "\n");
1484         }
1485
1486         if (srv_minplayers || srv_maxplayers)
1487         {
1488                 msg = strcat(msg, "\n", _("This match supports"), " ^5");
1489                 if (srv_minplayers == srv_maxplayers)
1490                         msg = strcat(msg, sprintf(_("%d players"), srv_maxplayers), "\n");
1491                 else if (srv_minplayers && srv_maxplayers)
1492                         msg = strcat(msg, sprintf(_("%d to %d players"), srv_minplayers, srv_maxplayers), "\n");
1493                 else if (srv_maxplayers)
1494                         msg = strcat(msg, sprintf(_("%d players maximum"), srv_maxplayers), "\n");
1495                 else
1496                         msg = strcat(msg, sprintf(_("%d players minimum"), srv_minplayers), "\n");
1497         }
1498
1499         modifications = cons_mid(modifications, ", ", weaponarena_list);
1500         if(modifications != "")
1501                 msg = strcat(msg, "\n", _("Active modifications:"), " ^3", modifications, "\n");
1502
1503         if (cache_mutatormsg != "")
1504                 msg = strcat(msg, "\n", _("Special gameplay tips:"), " ^7", cache_mutatormsg, "\n");
1505         string mutator_msg = "";
1506         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1507         mutator_msg = M_ARGV(0, string);
1508         msg = strcat(msg, mutator_msg); // trust that the mutator will do proper formatting
1509
1510         if (motd != "")
1511                 msg = strcat(msg, "\n^9↓ ", _("Server's message"), " ↓\n", motd);
1512
1513         strcpy(welcome_msg, msg);
1514         welcome_msg_menu_check_maxtime = time + 1; // wait for menu to load before showing the welcome dialog
1515         return true;
1516 }
1517
1518 void Welcome_Message_Show_Try()
1519 {
1520         if (!welcome_msg_menu_check_maxtime)
1521                 return;
1522
1523         // if want dialog check if menu is initialized but for a short time
1524         if (cvar("_menu_initialized") == 2 || time > welcome_msg_menu_check_maxtime)
1525         {
1526                 if (cvar("_menu_welcome_dialog_available"))
1527                 {
1528                         string welcomedialog_args = strcat("HOSTNAME \"", hostname, "\"");
1529                         string msg = MakeConsoleSafe(strreplace("\n", "\\n", welcome_msg));
1530                         welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1531
1532                         if (intermission || isdemo() || !autocvar_cl_welcome)
1533                         {
1534                                 if (cvar("_menu_cmd_closemenu_available"))
1535                                 {
1536                                         // initialize the dialog without opening it
1537                                         localcmd("\nmenu_cmd closemenu Welcome ", welcomedialog_args, "\n");
1538                                 }
1539                                 else
1540                                 {
1541                                         // legacy code for clients with old menus
1542                                         // since togglemenu 0 doesn't close the dialog but only hides it,
1543                                         // playing back a demo the Welcome dialog will pop up on the first ESC press
1544                                         localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1545                                         // close it after it's been initialized so it can still be opened manually
1546                                         localcmd("\ntogglemenu 0\n");
1547                                 }
1548                         }
1549                         else
1550                                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1551                 }
1552
1553                 strfree(welcome_msg);
1554                 welcome_msg_menu_check_maxtime = 0;
1555         }
1556 }
1557
1558 NET_HANDLE(TE_CSQC_SERVERWELCOME, bool isNew)
1559 {
1560         return net_handle_ServerWelcome();
1561 }
1562
1563 string _getcommandkey(string cmd_name, string command, bool forcename)
1564 {
1565         string keys;
1566         float n, j, k, l = 0;
1567
1568         if (!autocvar_hud_showbinds)
1569                 return cmd_name;
1570
1571         keys = db_get(binddb, command);
1572         if (keys == "")
1573         {
1574                 bool joy_active = cvar("joy_active");
1575                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1576                 for(j = 0; j < n; ++j)
1577                 {
1578                         k = stof(argv(j));
1579                         if(k != -1)
1580                         {
1581                                 string key = keynumtostring(k);
1582                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1583                                         continue;
1584
1585                                 key = translate_key(key);
1586
1587                                 if (keys == "")
1588                                         keys = key;
1589                                 else
1590                                         keys = strcat(keys, ", ", key);
1591
1592                                 ++l;
1593                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1594                                         break;
1595                         }
1596
1597                 }
1598                 if (keys == "")
1599                         keys = "NO_KEY";
1600                 db_put(binddb, command, keys);
1601         }
1602
1603         if (keys == "NO_KEY") {
1604                 if (autocvar_hud_showbinds > 1)
1605                         return sprintf(_("%s (not bound)"), cmd_name);
1606                 else
1607                         return cmd_name;
1608         }
1609         else if (autocvar_hud_showbinds > 1 || forcename)
1610                 return sprintf("%s (%s)", cmd_name, keys);
1611         else
1612                 return keys;
1613 }
1614
1615 /** engine callback */
1616 void URI_Get_Callback(int id, int status, string data)
1617 {
1618         TC(int, id); TC(int, status);
1619         if(url_URI_Get_Callback(id, status, data))
1620         {
1621                 // handled
1622         }
1623         else if (id == URI_GET_DISCARD)
1624         {
1625                 // discard
1626         }
1627         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1628         {
1629                 // sv_cmd curl
1630                 Curl_URI_Get_Callback(id, status, data);
1631         }
1632         else
1633         {
1634                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
1635         }
1636 }