qcsrc/client/hud_config.qc

   1 #define HUD_Write(s) fputs(fh, s)
   2 // q: quoted, n: not quoted
   3 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
   4 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
   5 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel_name, cvar_suf))
   6 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel_name, cvar_suf))
   7 // Save the config
   8 void HUD_Panel_ExportCfg(string cfgname)
   9 {
  10         float fh;
  11         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  12         fh = fopen(filename, FILE_WRITE);
  13         if(fh >= 0)
  14         {
  15                 HUD_Write_Cvar_q("hud_skin");
  16                 HUD_Write_Cvar_q("hud_panel_bg");
  17                 HUD_Write_Cvar_q("hud_panel_bg_color");
  18                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
  19                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
  20                 HUD_Write_Cvar_q("hud_panel_bg_border");
  21                 HUD_Write_Cvar_q("hud_panel_bg_padding");
  22                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
  23                 HUD_Write("\n");
  24
  25                 HUD_Write_Cvar_q("hud_dock");
  26                 HUD_Write_Cvar_q("hud_dock_color");
  27                 HUD_Write_Cvar_q("hud_dock_color_team");
  28                 HUD_Write_Cvar_q("hud_dock_alpha");
  29                 HUD_Write("\n");
  30
  31                 HUD_Write_Cvar_q("hud_progressbar_alpha");
  32                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
  33                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
  34                 HUD_Write_Cvar_q("hud_progressbar_health_color");
  35                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
  36                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
  37                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
  38                 HUD_Write_Cvar_q("hud_progressbar_speed_color");
  39                 HUD_Write_Cvar_q("hud_progressbar_acceleration_color");
  40                 HUD_Write_Cvar_q("hud_progressbar_acceleration_neg_color");
  41                 HUD_Write("\n");
  42
  43                 HUD_Write_Cvar_q("_hud_panelorder");
  44                 HUD_Write("\n");
  45
  46                 HUD_Write_Cvar_q("hud_configure_grid");
  47                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
  48                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
  49                 HUD_Write("\n");
  50
  51                 // common cvars for all panels
  52                 float i;
  53                 for (i = 0; i < HUD_PANEL_NUM; ++i)
  54                 {
  55                         HUD_Panel_GetName(i);
  56
  57                         HUD_Write_PanelCvar_n("");
  58                         HUD_Write_PanelCvar_q("_pos");
  59                         HUD_Write_PanelCvar_q("_size");
  60                         HUD_Write_PanelCvar_q("_bg");
  61                         HUD_Write_PanelCvar_q("_bg_color");
  62                         HUD_Write_PanelCvar_q("_bg_color_team");
  63                         HUD_Write_PanelCvar_q("_bg_alpha");
  64                         HUD_Write_PanelCvar_q("_bg_border");
  65                         HUD_Write_PanelCvar_q("_bg_padding");
  66                         switch(i) {
  67                                 case HUD_PANEL_WEAPONS:
  68                                         HUD_Write_PanelCvar_q("_accuracy");
  69                                         HUD_Write_PanelCvar_q("_label");
  70                                         HUD_Write_PanelCvar_q("_complainbubble");
  71                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
  72                                         HUD_Write_PanelCvar_q("_complainbubble_time");
  73                                         HUD_Write_PanelCvar_q("_complainbubble_fadetime");
  74                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
  75                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
  76                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
  77                                         HUD_Write_PanelCvar_q("_ammo");
  78                                         HUD_Write_PanelCvar_q("_ammo_color");
  79                                         HUD_Write_PanelCvar_q("_ammo_alpha");
  80                                         HUD_Write_PanelCvar_q("_aspect");
  81                                         HUD_Write_PanelCvar_q("_timeout");
  82                                         HUD_Write_PanelCvar_q("_timeout_effect");
  83                                         HUD_Write_PanelCvar_q("_onlyowned");
  84                                         break;
  85                                 case HUD_PANEL_AMMO:
  86                                         HUD_Write_PanelCvar_q("_onlycurrent");
  87                                         HUD_Write_PanelCvar_q("_iconalign");
  88                                         HUD_Write_PanelCvar_q("_progressbar");
  89                                         HUD_Write_PanelCvar_q("_progressbar_name");
  90                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
  91                                         HUD_Write_PanelCvar_q("_text");
  92                                         break;
  93                                 case HUD_PANEL_POWERUPS:
  94                                         HUD_Write_PanelCvar_q("_flip");
  95                                         HUD_Write_PanelCvar_q("_iconalign");
  96                                         HUD_Write_PanelCvar_q("_baralign");
  97                                         HUD_Write_PanelCvar_q("_progressbar");
  98                                         HUD_Write_PanelCvar_q("_progressbar_strength");
  99                                         HUD_Write_PanelCvar_q("_progressbar_shield");
 100                                         HUD_Write_PanelCvar_q("_text");
 101                                         break;
 102                                 case HUD_PANEL_HEALTHARMOR:
 103                                         HUD_Write_PanelCvar_q("_flip");
 104                                         HUD_Write_PanelCvar_q("_iconalign");
 105                                         HUD_Write_PanelCvar_q("_baralign");
 106                                         HUD_Write_PanelCvar_q("_progressbar");
 107                                         HUD_Write_PanelCvar_q("_progressbar_health");
 108                                         HUD_Write_PanelCvar_q("_progressbar_armor");
 109                                         HUD_Write_PanelCvar_q("_progressbar_gfx");
 110                                         HUD_Write_PanelCvar_q("_progressbar_gfx_smooth");
 111                                         HUD_Write_PanelCvar_q("_text");
 112                                         break;
 113                                 case HUD_PANEL_NOTIFY:
 114                                         HUD_Write_PanelCvar_q("_flip");
 115                                         HUD_Write_PanelCvar_q("_fontsize");
 116                                         HUD_Write_PanelCvar_q("_print");
 117                                         HUD_Write_PanelCvar_q("_time");
 118                                         HUD_Write_PanelCvar_q("_fadetime");
 119                                         break;
 120                                 case HUD_PANEL_TIMER:
 121                                         HUD_Write_PanelCvar_q("_increment");
 122                                         break;
 123                                 case HUD_PANEL_RADAR:
 124                                         HUD_Write_PanelCvar_q("_foreground_alpha");
 125                                         HUD_Write_PanelCvar_q("_rotation");
 126                                         HUD_Write_PanelCvar_q("_zoommode");
 127                                         HUD_Write_PanelCvar_q("_scale");
 128                                         HUD_Write_PanelCvar_q("_maximized_scale");
 129                                         HUD_Write_PanelCvar_q("_maximized_size");
 130                                         break;
 131                                 case HUD_PANEL_SCORE:
 132                                         HUD_Write_PanelCvar_q("_rankings");
 133                                         break;
 134                                 case HUD_PANEL_VOTE:
 135                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
 136                                         break;
 137                                 case HUD_PANEL_MODICONS:
 138                                         HUD_Write_PanelCvar_q("_dom_layout");
 139                                         break;
 140                                 case HUD_PANEL_PRESSEDKEYS:
 141                                         HUD_Write_PanelCvar_q("_aspect");
 142                                         break;
 143                                 case HUD_PANEL_ENGINEINFO:
 144                                         HUD_Write_PanelCvar_q("_framecounter_time");
 145                                         HUD_Write_PanelCvar_q("_framecounter_decimals");
 146                                         break;
 147                                 case HUD_PANEL_INFOMESSAGES:
 148                                         HUD_Write_PanelCvar_q("_flip");
 149                                         break;
 150                                 case HUD_PANEL_PHYSICS:
 151                                         HUD_Write_PanelCvar_q("_speed_unit");
 152                                         HUD_Write_PanelCvar_q("_speed_unit_show");
 153                                         HUD_Write_PanelCvar_q("_speed_max");
 154                                         HUD_Write_PanelCvar_q("_speed_vertical");
 155                                         HUD_Write_PanelCvar_q("_topspeed");
 156                                         HUD_Write_PanelCvar_q("_topspeed_time");
 157                                         HUD_Write_PanelCvar_q("_acceleration_max");
 158                                         HUD_Write_PanelCvar_q("_acceleration_vertical");
 159                                         HUD_Write_PanelCvar_q("_flip");
 160                                         HUD_Write_PanelCvar_q("_baralign");
 161                                         HUD_Write_PanelCvar_q("_progressbar");
 162                                         HUD_Write_PanelCvar_q("_acceleration_mode");
 163                                         HUD_Write_PanelCvar_q("_text");
 164                                         break;
 165                                 case HUD_PANEL_CENTERPRINT:
 166                                         HUD_Write_PanelCvar_q("_align");
 167                                         HUD_Write_PanelCvar_q("_flip");
 168                                         HUD_Write_PanelCvar_q("_fontscale");
 169                                         HUD_Write_PanelCvar_q("_time");
 170                                         HUD_Write_PanelCvar_q("_fade_in");
 171                                         HUD_Write_PanelCvar_q("_fade_out");
 172                                         HUD_Write_PanelCvar_q("_fade_subsequent");
 173                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone");
 174                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone_minalpha");
 175                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo");
 176                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo_minalpha");
 177                                         HUD_Write_PanelCvar_q("_fade_subsequent_minfontsize");
 178                                         HUD_Write_PanelCvar_q("_fade_minfontsize");
 179                                         break;
 180                                 case HUD_PANEL_ITEMSTIME:
 181                                         HUD_Write_PanelCvar_q("_iconalign");
 182                                         HUD_Write_PanelCvar_q("_progressbar");
 183                                         HUD_Write_PanelCvar_q("_progressbar_name");
 184                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
 185                                         HUD_Write_PanelCvar_q("_showspawned");
 186                                         HUD_Write_PanelCvar_q("_text");
 187                                         HUD_Write_PanelCvar_q("_ratio");
 188                                         break;
 189                         }
 190                         HUD_Write("\n");
 191                 }
 192                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
 193
 194                 print(sprintf(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename));
 195                 fclose(fh);
 196         }
 197         else
 198                 print(sprintf(_("^1Couldn't write to %s\n"), filename));
 199 }
 200
 201 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 202 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 203 {
 204         float i;
 205         float myCenter_x, myCenter_y, targCenter_x, targCenter_y;
 206         vector myTarget;
 207         myTarget = myPos;
 208
 209         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 210                 if(i == highlightedPanel || !panel_enabled)
 211                         continue;
 212
 213                 HUD_Panel_UpdatePosSizeForId(i);
 214
 215                 panel_pos -= '1 1 0' * panel_bg_border;
 216                 panel_size += '2 2 0' * panel_bg_border;
 217
 218                 if(myPos_y + mySize_y < panel_pos_y)
 219                         continue;
 220                 if(myPos_y > panel_pos_y + panel_size_y)
 221                         continue;
 222
 223                 if(myPos_x + mySize_x < panel_pos_x)
 224                         continue;
 225                 if(myPos_x > panel_pos_x + panel_size_x)
 226                         continue;
 227
 228                 // OK, there IS a collision.
 229
 230                 myCenter_x = myPos_x + 0.5 * mySize_x;
 231                 myCenter_y = myPos_y + 0.5 * mySize_y;
 232
 233                 targCenter_x = panel_pos_x + 0.5 * panel_size_x;
 234                 targCenter_y = panel_pos_y + 0.5 * panel_size_y;
 235
 236                 if(myCenter_x < targCenter_x && myCenter_y < targCenter_y) // top left (of the target panel)
 237                 {
 238                         if(myPos_x + mySize_x - panel_pos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 239                                 myTarget_x = panel_pos_x - mySize_x;
 240                         else // push it upwards
 241                                 myTarget_y = panel_pos_y - mySize_y;
 242                 }
 243                 else if(myCenter_x > targCenter_x && myCenter_y < targCenter_y) // top right
 244                 {
 245                         if(panel_pos_x + panel_size_x - myPos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 246                                 myTarget_x = panel_pos_x + panel_size_x;
 247                         else // push it upwards
 248                                 myTarget_y = panel_pos_y - mySize_y;
 249                 }
 250                 else if(myCenter_x < targCenter_x && myCenter_y > targCenter_y) // bottom left
 251                 {
 252                         if(myPos_x + mySize_x - panel_pos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 253                                 myTarget_x = panel_pos_x - mySize_x;
 254                         else // push it downwards
 255                                 myTarget_y = panel_pos_y + panel_size_y;
 256                 }
 257                 else if(myCenter_x > targCenter_x && myCenter_y > targCenter_y) // bottom right
 258                 {
 259                         if(panel_pos_x + panel_size_x - myPos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 260                                 myTarget_x = panel_pos_x + panel_size_x;
 261                         else // push it downwards
 262                                 myTarget_y = panel_pos_y + panel_size_y;
 263                 }
 264                 //if(cvar("hud_configure_checkcollisions_debug"))
 265                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 266         }
 267
 268         return myTarget;
 269 }
 270
 271 void HUD_Panel_SetPos(vector pos)
 272 {
 273         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 274         vector mySize;
 275         mySize = panel_size;
 276
 277         //if(cvar("hud_configure_checkcollisions_debug"))
 278                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 279
 280         if(autocvar_hud_configure_grid)
 281         {
 282                 pos_x = floor((pos_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 283                 pos_y = floor((pos_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 284         }
 285
 286         if(hud_configure_checkcollisions)
 287                 pos = HUD_Panel_CheckMove(pos, mySize);
 288
 289         pos_x = bound(0, pos_x, vid_conwidth - mySize_x);
 290         pos_y = bound(0, pos_y, vid_conheight - mySize_y);
 291
 292         string s;
 293         s = strcat(ftos(pos_x/vid_conwidth), " ", ftos(pos_y/vid_conheight));
 294
 295         HUD_Panel_GetName(highlightedPanel);
 296         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 297 }
 298
 299 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 300 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 301         float i;
 302
 303         vector targEndPos;
 304
 305         float dist_x, dist_y;
 306         float ratio;
 307         ratio = mySize_x/mySize_y;
 308
 309         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 310                 if(i == highlightedPanel || !panel_enabled)
 311                         continue;
 312
 313                 HUD_Panel_UpdatePosSizeForId(i);
 314
 315                 panel_pos -= '1 1 0' * panel_bg_border;
 316                 panel_size += '2 2 0' * panel_bg_border;
 317
 318                 targEndPos = panel_pos + panel_size;
 319
 320                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 321                 if(resizeorigin_x > panel_pos_x && resizeorigin_x < targEndPos_x && resizeorigin_y > panel_pos_y && resizeorigin_y < targEndPos_y)
 322                         continue;
 323
 324                 if (resizeCorner == 1)
 325                 {
 326                         // check if this panel is on our way
 327                         if (resizeorigin_x <= panel_pos_x)
 328                                 continue;
 329                         if (resizeorigin_y <= panel_pos_y)
 330                                 continue;
 331                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 332                                 continue;
 333                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 334                                 continue;
 335
 336                         // there is a collision:
 337                         // detect which side of the panel we are facing is actually limiting the resizing
 338                         // (which side the resize direction finds for first) and reduce the size up to there
 339                         //
 340                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 341                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 342                         dist_x = resizeorigin_x - targEndPos_x;
 343                         dist_y = resizeorigin_y - targEndPos_y;
 344                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 345                                 mySize_x = min(mySize_x, dist_x);
 346                         else
 347                                 mySize_y = min(mySize_y, dist_y);
 348                 }
 349                 else if (resizeCorner == 2)
 350                 {
 351                         if (resizeorigin_x >= targEndPos_x)
 352                                 continue;
 353                         if (resizeorigin_y <= panel_pos_y)
 354                                 continue;
 355                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 356                                 continue;
 357                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 358                                 continue;
 359
 360                         dist_x = panel_pos_x - resizeorigin_x;
 361                         dist_y = resizeorigin_y - targEndPos_y;
 362                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 363                                 mySize_x = min(mySize_x, dist_x);
 364                         else
 365                                 mySize_y = min(mySize_y, dist_y);
 366                 }
 367                 else if (resizeCorner == 3)
 368                 {
 369                         if (resizeorigin_x <= panel_pos_x)
 370                                 continue;
 371                         if (resizeorigin_y >= targEndPos_y)
 372                                 continue;
 373                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 374                                 continue;
 375                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 376                                 continue;
 377
 378                         dist_x = resizeorigin_x - targEndPos_x;
 379                         dist_y = panel_pos_y - resizeorigin_y;
 380                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 381                                 mySize_x = min(mySize_x, dist_x);
 382                         else
 383                                 mySize_y = min(mySize_y, dist_y);
 384                 }
 385                 else if (resizeCorner == 4)
 386                 {
 387                         if (resizeorigin_x >= targEndPos_x)
 388                                 continue;
 389                         if (resizeorigin_y >= targEndPos_y)
 390                                 continue;
 391                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 392                                 continue;
 393                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 394                                 continue;
 395
 396                         dist_x = panel_pos_x - resizeorigin_x;
 397                         dist_y = panel_pos_y - resizeorigin_y;
 398                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 399                                 mySize_x = min(mySize_x, dist_x);
 400                         else
 401                                 mySize_y = min(mySize_y, dist_y);
 402                 }
 403                 //if(cvar("hud_configure_checkcollisions_debug"))
 404                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 405         }
 406
 407         return mySize;
 408 }
 409
 410 void HUD_Panel_SetPosSize(vector mySize)
 411 {
 412         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 413         vector resizeorigin;
 414         resizeorigin = panel_click_resizeorigin;
 415         local noref vector myPos; // fteqcc sucks
 416
 417         // minimum panel size cap
 418         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 419         mySize_y = max(0.025 * vid_conheight, mySize_y);
 420
 421         if(highlightedPanel == HUD_PANEL_CHAT) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 422         {
 423                 mySize_x = max(17 * autocvar_con_chatsize, mySize_x);
 424                 mySize_y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize_y);
 425         }
 426
 427         // collision testing|
 428         // -----------------+
 429
 430         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 431         if(resizeCorner == 1) {
 432                 myPos_x = resizeorigin_x - mySize_x;
 433                 myPos_y = resizeorigin_y - mySize_y;
 434         } else if(resizeCorner == 2) {
 435                 myPos_x = resizeorigin_x;
 436                 myPos_y = resizeorigin_y - mySize_y;
 437         } else if(resizeCorner == 3) {
 438                 myPos_x = resizeorigin_x - mySize_x;
 439                 myPos_y = resizeorigin_y;
 440         } else { // resizeCorner == 4
 441                 myPos_x = resizeorigin_x;
 442                 myPos_y = resizeorigin_y;
 443         }
 444
 445         // left/top screen edges
 446         if(myPos_x < 0)
 447                 mySize_x = mySize_x + myPos_x;
 448         if(myPos_y < 0)
 449                 mySize_y = mySize_y + myPos_y;
 450
 451         // bottom/right screen edges
 452         if(myPos_x + mySize_x > vid_conwidth)
 453                 mySize_x = vid_conwidth - myPos_x;
 454         if(myPos_y + mySize_y > vid_conheight)
 455                 mySize_y = vid_conheight - myPos_y;
 456
 457         //if(cvar("hud_configure_checkcollisions_debug"))
 458                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 459
 460         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 461         if(autocvar_hud_configure_grid)
 462         {
 463                 mySize_x = floor((mySize_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 464                 mySize_y = floor((mySize_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 465         }
 466
 467         if(hud_configure_checkcollisions)
 468                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 469
 470         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 471         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 472         mySize_y = max(0.025 * vid_conheight, mySize_y);
 473
 474         // do another pos check, as size might have changed by now
 475         if(resizeCorner == 1) {
 476                 myPos_x = resizeorigin_x - mySize_x;
 477                 myPos_y = resizeorigin_y - mySize_y;
 478         } else if(resizeCorner == 2) {
 479                 myPos_x = resizeorigin_x;
 480                 myPos_y = resizeorigin_y - mySize_y;
 481         } else if(resizeCorner == 3) {
 482                 myPos_x = resizeorigin_x - mySize_x;
 483                 myPos_y = resizeorigin_y;
 484         } else { // resizeCorner == 4
 485                 myPos_x = resizeorigin_x;
 486                 myPos_y = resizeorigin_y;
 487         }
 488
 489         //if(cvar("hud_configure_checkcollisions_debug"))
 490                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 491
 492         HUD_Panel_GetName(highlightedPanel);
 493         string s;
 494         s = strcat(ftos(mySize_x/vid_conwidth), " ", ftos(mySize_y/vid_conheight));
 495         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 496
 497         s = strcat(ftos(myPos_x/vid_conwidth), " ", ftos(myPos_y/vid_conheight));
 498         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 499 }
 500
 501 float pressed_key_time;
 502 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 503 void HUD_Panel_Arrow_Action(float nPrimary)
 504 {
 505         if (highlightedPanel == -1)
 506                 return;
 507
 508         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 509
 510         float step;
 511         if(autocvar_hud_configure_grid)
 512         {
 513                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 514                 {
 515                         if (hudShiftState & S_SHIFT)
 516                                 step = hud_configure_realGridSize_y;
 517                         else
 518                                 step = 2 * hud_configure_realGridSize_y;
 519                 }
 520                 else
 521                 {
 522                         if (hudShiftState & S_SHIFT)
 523                                 step = hud_configure_realGridSize_x;
 524                         else
 525                                 step = 2 * hud_configure_realGridSize_x;
 526                 }
 527         }
 528         else
 529         {
 530                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 531                         step = vid_conheight;
 532                 else
 533                         step = vid_conwidth;
 534                 if (hudShiftState & S_SHIFT)
 535                         step = (step / 256); // more precision
 536                 else
 537                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 538         }
 539
 540         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 541
 542         highlightedPanel_initial_pos = panel_pos;
 543         highlightedPanel_initial_size = panel_size;
 544
 545         if (hudShiftState & S_ALT) // resize
 546         {
 547                 highlightedAction = 1;
 548                 if(nPrimary == K_UPARROW)
 549                         resizeCorner = 1;
 550                 else if(nPrimary == K_RIGHTARROW)
 551                         resizeCorner = 2;
 552                 else if(nPrimary == K_LEFTARROW)
 553                         resizeCorner = 3;
 554                 else // if(nPrimary == K_DOWNARROW)
 555                         resizeCorner = 4;
 556
 557                 // ctrl+arrow reduces the size, instead of increasing it
 558                 // Note that ctrl disables collisions check too, but it's fine
 559                 // since we don't collide with anything reducing the size
 560                 if (hudShiftState & S_CTRL) {
 561                         step = -step;
 562                         resizeCorner = 5 - resizeCorner;
 563                 }
 564
 565                 vector mySize;
 566                 mySize = panel_size;
 567                 panel_click_resizeorigin = panel_pos;
 568                 if(resizeCorner == 1) {
 569                         panel_click_resizeorigin += mySize;
 570                         mySize_y += step;
 571                 } else if(resizeCorner == 2) {
 572                         panel_click_resizeorigin_y += mySize_y;
 573                         mySize_x += step;
 574                 } else if(resizeCorner == 3) {
 575                         panel_click_resizeorigin_x += mySize_x;
 576                         mySize_x += step;
 577                 } else { // resizeCorner == 4
 578                         mySize_y += step;
 579                 }
 580                 HUD_Panel_SetPosSize(mySize);
 581         }
 582         else // move
 583         {
 584                 highlightedAction = 2;
 585                 vector pos;
 586                 pos = panel_pos;
 587                 if(nPrimary == K_UPARROW)
 588                         pos_y -= step;
 589                 else if(nPrimary == K_DOWNARROW)
 590                         pos_y += step;
 591                 else if(nPrimary == K_LEFTARROW)
 592                         pos_x -= step;
 593                 else // if(nPrimary == K_RIGHTARROW)
 594                         pos_x += step;
 595
 596                 HUD_Panel_SetPos(pos);
 597         }
 598
 599         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 600
 601         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 602         {
 603                 // backup!
 604                 panel_pos_backup = highlightedPanel_initial_pos;
 605                 panel_size_backup = highlightedPanel_initial_size;
 606                 highlightedPanel_backup = highlightedPanel;
 607         }
 608 }
 609
 610 const float S_MOUSE1 = 1;
 611 const float S_MOUSE2 = 2;
 612 const float S_MOUSE3 = 4;
 613 float mouseClicked;
 614 float prevMouseClicked; // previous state
 615 float prevMouseClickedTime; // time during previous left mouse click, to check for doubleclicks
 616 vector prevMouseClickedPos; // pos during previous left mouse click, to check for doubleclicks
 617
 618 void HUD_Panel_EnableMenu();
 619 float tab_panels[HUD_PANEL_NUM];
 620 float tab_panel, tab_backward;
 621 vector tab_panel_pos;
 622 void HUD_Panel_FirstInDrawQ(float id);
 623 void reset_tab_panels()
 624 {
 625         int i;
 626         for(i = 0; i < HUD_PANEL_NUM; ++i)
 627                 tab_panels[i] = -1;
 628 }
 629 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 630 {
 631         string s;
 632
 633         // we only care for keyboard events
 634         if(bInputType != 0 && bInputType != 1)
 635                 return false;
 636
 637         if(!autocvar__hud_configure)
 638                 return false;
 639
 640         // allow console bind to work
 641         string con_keys;
 642         float keys;
 643         con_keys = findkeysforcommand("toggleconsole", 0);
 644         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 645
 646         float hit_con_bind, i;
 647         for (i = 0; i < keys; ++i)
 648         {
 649                 if(nPrimary == stof(argv(i)))
 650                         hit_con_bind = 1;
 651         }
 652
 653         if(bInputType == 0) {
 654                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 655                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 656                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 657         }
 658         else if(bInputType == 1) {
 659                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 660                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 661                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 662         }
 663
 664         if(nPrimary == K_CTRL)
 665         {
 666                 if (bInputType == 1) //ctrl has been released
 667                 {
 668                         if (tab_panel != -1)
 669                         {
 670                                 //switch to selected panel
 671                                 highlightedPanel = tab_panel;
 672                                 highlightedAction = 0;
 673                                 HUD_Panel_FirstInDrawQ(highlightedPanel);
 674                         }
 675                         tab_panel = -1;
 676                         reset_tab_panels();
 677                 }
 678         }
 679
 680         if(nPrimary == K_MOUSE1)
 681         {
 682                 if(bInputType == 0) // key pressed
 683                         mouseClicked |= S_MOUSE1;
 684                 else if(bInputType == 1) // key released
 685                         mouseClicked -= (mouseClicked & S_MOUSE1);
 686         }
 687         else if(nPrimary == K_MOUSE2)
 688         {
 689                 if(bInputType == 0) // key pressed
 690                         mouseClicked |= S_MOUSE2;
 691                 else if(bInputType == 1) // key released
 692                         mouseClicked -= (mouseClicked & S_MOUSE2);
 693         }
 694         else if(nPrimary == K_ESCAPE)
 695         {
 696                 if (bInputType == 1)
 697                         return true;
 698                 menu_enabled = 1;
 699                 menu_enabled_time = time;
 700                 localcmd("menu_showhudexit\n");
 701         }
 702         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
 703         {
 704                 if (bInputType == 1)
 705                         return true;
 706                 if (!menu_enabled)
 707                         cvar_set("_hud_configure", "0");
 708         }
 709         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // select and highlight another panel
 710         {
 711                 if (bInputType == 1 || mouseClicked)
 712                         return true;
 713
 714                 //FIXME: if a panel is highlighted, has the same pos_x and lays in the same level
 715                 //of other panels then next consecutive ctrl-tab will select the highlighted panel too
 716                 //(it should only after every other panel of the hud)
 717                 //It's a minor bug anyway, we can live with it
 718
 719                 float starting_panel;
 720                 float old_tab_panel = tab_panel;
 721                 if (tab_panel == -1) //first press of TAB
 722                 {
 723                         if (highlightedPanel != -1)
 724                                 HUD_Panel_UpdatePosSizeForId(highlightedPanel)
 725                         else
 726                                 panel_pos = '0 0 0';
 727                         starting_panel = highlightedPanel; //can be -1, it means no starting panel
 728                         tab_panel_pos = panel_pos; //to compute level
 729                 }
 730                 else
 731                 {
 732                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 733                                 reset_tab_panels();
 734                         starting_panel = tab_panel;
 735                 }
 736                 tab_backward = (hudShiftState & S_SHIFT);
 737
 738                 float k, level, start_pos_x;
 739                 vector candidate_pos;
 740                 const float LEVELS_NUM = 4;
 741                 float level_height = vid_conheight / LEVELS_NUM;
 742 :find_tab_panel
 743                 level = floor(tab_panel_pos_y / level_height) * level_height; //starting level
 744                 candidate_pos_x = (!tab_backward) ? vid_conwidth : 0;
 745                 start_pos_x = tab_panel_pos_x;
 746                 tab_panel = -1;
 747                 k=0;
 748                 while(++k)
 749                 {
 750                         for(i = 0; i < HUD_PANEL_NUM; ++i)
 751                         {
 752                                 if (i == tab_panels[i] || i == starting_panel)
 753                                         continue;
 754                                 HUD_Panel_UpdatePosSizeForId(i)
 755                                 if (panel_pos_y >= level && (panel_pos_y - level) < level_height)
 756                                 if (  ( !tab_backward && panel_pos_x >= start_pos_x && (panel_pos_x < candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y <= candidate_pos_y)) )
 757                                         || ( tab_backward && panel_pos_x <= start_pos_x && (panel_pos_x > candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y >= candidate_pos_y)) )  )
 758                                 {
 759                                         tab_panel = i;
 760                                         tab_panel_pos = candidate_pos = panel_pos;
 761                                 }
 762                         }
 763                         if (tab_panel != -1)
 764                                 break;
 765                         if (k == LEVELS_NUM) //tab_panel not found
 766                         {
 767                                 reset_tab_panels();
 768                                 if (old_tab_panel == -2) //this prevents an infinite loop (should not happen normally)
 769                                 {
 770                                         tab_panel = -1;
 771                                         return true;
 772                                 }
 773                                 starting_panel = old_tab_panel;
 774                                 old_tab_panel = -2;
 775                                 goto find_tab_panel; //u must find tab_panel!
 776                         }
 777                         if (!tab_backward)
 778                         {
 779                                 level = mod(level + level_height, vid_conheight);
 780                                 start_pos_x = 0;
 781                                 candidate_pos_x = vid_conwidth;
 782                         }
 783                         else
 784                         {
 785                                 level = mod(level - level_height, vid_conheight);
 786                                 start_pos_x = vid_conwidth;
 787                                 candidate_pos_x = 0;
 788                         }
 789                 }
 790
 791                 tab_panels[tab_panel] = tab_panel;
 792         }
 793         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 794         {
 795                 if (bInputType == 1 || mouseClicked)
 796                         return true;
 797
 798                 if (highlightedPanel != -1)
 799                 {
 800                         HUD_Panel_GetName(highlightedPanel);
 801                         cvar_set(strcat("hud_panel_", panel_name), ftos(!(panel_enabled)));
 802                 }
 803                 else
 804                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 805         }
 806         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 807         {
 808                 if (bInputType == 1 || mouseClicked)
 809                         return true;
 810
 811                 if (highlightedPanel != -1)
 812                 {
 813                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 814                         panel_size_copied = panel_size;
 815                         highlightedPanel_copied = highlightedPanel;
 816                 }
 817         }
 818         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 819         {
 820                 if (bInputType == 1 || mouseClicked)
 821                         return true;
 822
 823                 if (highlightedPanel_copied == -1 || highlightedPanel == -1)
 824                         return true;
 825
 826                 HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 827
 828                 // reduce size if it'd go beyond screen boundaries
 829                 vector tmp_size = panel_size_copied;
 830                 if (panel_pos_x + panel_size_copied_x > vid_conwidth)
 831                         tmp_size_x = vid_conwidth - panel_pos_x;
 832                 if (panel_pos_y + panel_size_copied_y > vid_conheight)
 833                         tmp_size_y = vid_conheight - panel_pos_y;
 834
 835                 if (panel_size == tmp_size)
 836                         return true;
 837
 838                 // backup first!
 839                 panel_pos_backup = panel_pos;
 840                 panel_size_backup = panel_size;
 841                 highlightedPanel_backup = highlightedPanel;
 842
 843                 s = strcat(ftos(tmp_size_x/vid_conwidth), " ", ftos(tmp_size_y/vid_conheight));
 844                 HUD_Panel_GetName(highlightedPanel);
 845                 cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 846         }
 847         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 848         {
 849                 if (bInputType == 1 || mouseClicked)
 850                         return true;
 851                 //restore previous values
 852                 if (highlightedPanel_backup != -1)
 853                 {
 854                         HUD_Panel_GetName(highlightedPanel_backup);
 855                         s = strcat(ftos(panel_pos_backup_x/vid_conwidth), " ", ftos(panel_pos_backup_y/vid_conheight));
 856                         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 857                         s = strcat(ftos(panel_size_backup_x/vid_conwidth), " ", ftos(panel_size_backup_y/vid_conheight));
 858                         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 859                         highlightedPanel_backup = -1;
 860                 }
 861         }
 862         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 863         {
 864                 if (bInputType == 1)
 865                 {
 866                         pressed_key_time = 0;
 867                         return true;
 868                 }
 869                 else if (pressed_key_time == 0)
 870                         pressed_key_time = time;
 871
 872                 if (!mouseClicked)
 873                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 874         }
 875         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 876         {
 877                 if (bInputType == 1)
 878                         return true;
 879                 if (highlightedPanel != -1)
 880                         HUD_Panel_EnableMenu();
 881         }
 882         else if(hit_con_bind)
 883                 return false;
 884
 885         return true;
 886 }
 887
 888 float HUD_Panel_Check_Mouse_Pos(float allow_move)
 889 {
 890         float i, j, border;
 891
 892         while(j < HUD_PANEL_NUM)
 893         {
 894                 i = panel_order[j];
 895                 j += 1;
 896
 897                 HUD_Panel_UpdatePosSizeForId(i);
 898
 899                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 900
 901                 // move
 902                 if(allow_move && mousepos_x >= panel_pos_x && mousepos_y >= panel_pos_y && mousepos_x <= panel_pos_x + panel_size_x && mousepos_y <= panel_pos_y + panel_size_y)
 903                 {
 904                         return 1;
 905                 }
 906                 // resize from topleft border
 907                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 908                 {
 909                         return 2;
 910                 }
 911                 // resize from topright border
 912                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 913                 {
 914                         return 3;
 915                 }
 916                 // resize from bottomleft border
 917                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
 918                 {
 919                         return 3;
 920                 }
 921                 // resize from bottomright border
 922                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
 923                 {
 924                         return 2;
 925                 }
 926         }
 927         return 0;
 928 }
 929
 930 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 931 void HUD_Panel_FirstInDrawQ(float id)
 932 {
 933         float i;
 934         var float place = -1;
 935         // find out where in the array our current id is, save into place
 936         for(i = 0; i < HUD_PANEL_NUM; ++i)
 937         {
 938                 if(panel_order[i] == id)
 939                 {
 940                         place = i;
 941                         break;
 942                 }
 943         }
 944         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 945         if(place == -1)
 946                 place = HUD_PANEL_NUM - 1;
 947
 948         // move all ids up by one step in the array until "place"
 949         for(i = place; i > 0; --i)
 950         {
 951                 panel_order[i] = panel_order[i-1];
 952         }
 953         // now save the new top id
 954         panel_order[0] = id;
 955
 956         // let's save them into the cvar by some strcat trickery
 957         string s;
 958         for(i = 0; i < HUD_PANEL_NUM; ++i)
 959         {
 960                 s = strcat(s, ftos(panel_order[i]), " ");
 961         }
 962         cvar_set("_hud_panelorder", s);
 963         if(hud_panelorder_prev)
 964                 strunzone(hud_panelorder_prev);
 965         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
 966 }
 967
 968 void HUD_Panel_Highlight(float allow_move)
 969 {
 970         float i, j, border;
 971
 972         while(j < HUD_PANEL_NUM)
 973         {
 974                 i = panel_order[j];
 975                 j += 1;
 976
 977                 HUD_Panel_UpdatePosSizeForId(i);
 978
 979                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 980
 981                 // move
 982                 if(allow_move && mousepos_x >= panel_pos_x && mousepos_y >= panel_pos_y && mousepos_x <= panel_pos_x + panel_size_x && mousepos_y <= panel_pos_y + panel_size_y)
 983                 {
 984                         highlightedPanel = i;
 985                         HUD_Panel_FirstInDrawQ(i);
 986                         highlightedAction = 1;
 987                         panel_click_distance = mousepos - panel_pos;
 988                         return;
 989                 }
 990                 // resize from topleft border
 991                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 992                 {
 993                         highlightedPanel = i;
 994                         HUD_Panel_FirstInDrawQ(i);
 995                         highlightedAction = 2;
 996                         resizeCorner = 1;
 997                         panel_click_distance = mousepos - panel_pos;
 998                         panel_click_resizeorigin = panel_pos + panel_size;
 999                         return;
1000                 }
1001                 // resize from topright border
1002                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1003                 {
1004                         highlightedPanel = i;
1005                         HUD_Panel_FirstInDrawQ(i);
1006                         highlightedAction = 2;
1007                         resizeCorner = 2;
1008                         panel_click_distance_x = panel_size_x - mousepos_x + panel_pos_x;
1009                         panel_click_distance_y = mousepos_y - panel_pos_y;
1010                         panel_click_resizeorigin = panel_pos + eY * panel_size_y;
1011                         return;
1012                 }
1013                 // resize from bottomleft border
1014                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
1015                 {
1016                         highlightedPanel = i;
1017                         HUD_Panel_FirstInDrawQ(i);
1018                         highlightedAction = 2;
1019                         resizeCorner = 3;
1020                         panel_click_distance_x = mousepos_x - panel_pos_x;
1021                         panel_click_distance_y = panel_size_y - mousepos_y + panel_pos_y;
1022                         panel_click_resizeorigin = panel_pos + eX * panel_size_x;
1023                         return;
1024                 }
1025                 // resize from bottomright border
1026                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
1027                 {
1028                         highlightedPanel = i;
1029                         HUD_Panel_FirstInDrawQ(i);
1030                         highlightedAction = 2;
1031                         resizeCorner = 4;
1032                         panel_click_distance = panel_size - mousepos + panel_pos;
1033                         panel_click_resizeorigin = panel_pos;
1034                         return;
1035                 }
1036         }
1037         highlightedPanel = -1;
1038         highlightedAction = 0;
1039 }
1040
1041 void HUD_Panel_EnableMenu()
1042 {
1043         menu_enabled = 2;
1044         menu_enabled_time = time;
1045         HUD_Panel_GetName(highlightedPanel);
1046         localcmd("menu_showhudoptions ", panel_name, "\n");
1047 }
1048 float mouse_over_panel;
1049 void HUD_Panel_Mouse()
1050 {
1051         // TODO: needs better check... is there any float that contains the current state of the menu? _menu_alpha isn't apparently updated the frame the menu gets enabled
1052         if (autocvar__menu_alpha == 0 && time - menu_enabled_time > 0.5)
1053                 menu_enabled = 0;
1054
1055         /*
1056         print("menu_enabled: ", ftos(menu_enabled), "\n");
1057         print("Highlighted: ", ftos(highlightedPanel), "\n");
1058         print("Menu theAlpha: ", ftos(autocvar__menu_alpha), "\n");
1059         */
1060
1061         // instantly hide the editor cursor if we open the HUDExit dialog
1062         // as hud_fade_alpha doesn't decrease to 0 in this case
1063         // TODO: find a way to fade the cursor out even in this case
1064         if(menu_enabled == 1 || (menu_enabled == 2 && !hud_fade_alpha))
1065                 return;
1066
1067         mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
1068
1069         mousepos_x = bound(0, mousepos_x, vid_conwidth);
1070         mousepos_y = bound(0, mousepos_y, vid_conheight);
1071
1072         if(mouseClicked)
1073         {
1074                 if(prevMouseClicked == 0)
1075                 {
1076                         if (tab_panel != -1)
1077                         {
1078                                 //stop ctrl-tab selection
1079                                 tab_panel = -1;
1080                                 reset_tab_panels();
1081                         }
1082                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1083                                                                         // and calls HUD_Panel_UpdatePosSizeForId() for the highlighted panel
1084                         if (highlightedPanel != -1)
1085                         {
1086                                 highlightedPanel_initial_pos = panel_pos;
1087                                 highlightedPanel_initial_size = panel_size;
1088                         }
1089                         // doubleclick check
1090                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel != -1 && prevMouseClickedPos == mousepos)
1091                         {
1092                                 mouseClicked = 0; // to prevent spam, I guess.
1093                                 HUD_Panel_EnableMenu();
1094                         }
1095                         else
1096                         {
1097                                 if (mouseClicked & S_MOUSE1)
1098                                 {
1099                                         prevMouseClickedTime = time;
1100                                         prevMouseClickedPos = mousepos;
1101                                 }
1102                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1103                         }
1104                 }
1105                 else
1106                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
1107
1108                 if (highlightedPanel != -1)
1109                 {
1110                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1111                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1112                         {
1113                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1114                                 // backup!
1115                                 panel_pos_backup = highlightedPanel_initial_pos;
1116                                 panel_size_backup = highlightedPanel_initial_size;
1117                                 highlightedPanel_backup = highlightedPanel;
1118                         }
1119                         else
1120                                 // in case the clicked panel is inside another panel and we aren't
1121                                 // moving it, avoid the immediate "fix" of its position/size
1122                                 // (often unwanted and hateful) by disabling collisions check
1123                                 hud_configure_checkcollisions = false;
1124                 }
1125
1126                 if(highlightedAction == 1)
1127                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1128                 else if(highlightedAction == 2)
1129                 {
1130                         vector mySize;
1131                         if(resizeCorner == 1) {
1132                                 mySize_x = panel_click_resizeorigin_x - (mousepos_x - panel_click_distance_x);
1133                                 mySize_y = panel_click_resizeorigin_y - (mousepos_y - panel_click_distance_y);
1134                         } else if(resizeCorner == 2) {
1135                                 mySize_x = mousepos_x + panel_click_distance_x - panel_click_resizeorigin_x;
1136                                 mySize_y = panel_click_distance_y + panel_click_resizeorigin_y - mousepos_y;
1137                         } else if(resizeCorner == 3) {
1138                                 mySize_x = panel_click_resizeorigin_x + panel_click_distance_x - mousepos_x;
1139                                 mySize_y = mousepos_y + panel_click_distance_y - panel_click_resizeorigin_y;
1140                         } else { // resizeCorner == 4
1141                                 mySize_x = mousepos_x - (panel_click_resizeorigin_x - panel_click_distance_x);
1142                                 mySize_y = mousepos_y - (panel_click_resizeorigin_y - panel_click_distance_y);
1143                         }
1144                         HUD_Panel_SetPosSize(mySize);
1145                 }
1146         }
1147         else
1148         {
1149                 if(menu_enabled == 2)
1150                         mouse_over_panel = 0;
1151                 else
1152                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(TRUE);
1153                 if (mouse_over_panel && tab_panel == -1)
1154                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1155         }
1156         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1157         const vector cursorsize = '32 32 0';
1158
1159         if(!mouse_over_panel)
1160                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', hud_fade_alpha, DRAWFLAG_NORMAL);
1161         else if(mouse_over_panel == 1)
1162                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', hud_fade_alpha, DRAWFLAG_NORMAL);
1163         else if(mouse_over_panel == 2)
1164                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', hud_fade_alpha, DRAWFLAG_NORMAL);
1165         else
1166                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', hud_fade_alpha, DRAWFLAG_NORMAL);
1167
1168         prevMouseClicked = mouseClicked;
1169 }
1170
1171 const float hlBorderSize = 4;
1172 const string hlBorder = "gfx/hud/default/border_highlighted";
1173 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1174 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1175 {
1176         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1177         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1178         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size_y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1179         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1180         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size_x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1181 }