qcsrc/client/hud_config.qc

   1 #if defined(CSQC)
   2         #include "../dpdefs/csprogsdefs.qh"
   3         #include "defs.qh"
   4         #include "../dpdefs/keycodes.qh"
   5         #include "../common/constants.qh"
   6         #include "autocvars.qh"
   7         #include "hud.qh"
   8 #elif defined(MENUQC)
   9 #elif defined(SVQC)
  10 #endif
  11
  12
  13 #define HUD_Write(s) fputs(fh, s)
  14 // q: quoted, n: not quoted
  15 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
  16 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
  17 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel.panel_name, cvar_suf))
  18 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel.panel_name, cvar_suf))
  19 // Save the config
  20 void HUD_Panel_ExportCfg(string cfgname)
  21 {
  22         float fh;
  23         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  24         fh = fopen(filename, FILE_WRITE);
  25         if(fh >= 0)
  26         {
  27                 HUD_Write_Cvar_q("hud_skin");
  28                 HUD_Write_Cvar_q("hud_panel_bg");
  29                 HUD_Write_Cvar_q("hud_panel_bg_color");
  30                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
  31                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
  32                 HUD_Write_Cvar_q("hud_panel_bg_border");
  33                 HUD_Write_Cvar_q("hud_panel_bg_padding");
  34                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
  35                 HUD_Write("\n");
  36
  37                 HUD_Write_Cvar_q("hud_dock");
  38                 HUD_Write_Cvar_q("hud_dock_color");
  39                 HUD_Write_Cvar_q("hud_dock_color_team");
  40                 HUD_Write_Cvar_q("hud_dock_alpha");
  41                 HUD_Write("\n");
  42
  43                 HUD_Write_Cvar_q("hud_progressbar_alpha");
  44                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
  45                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
  46                 HUD_Write_Cvar_q("hud_progressbar_health_color");
  47                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
  48                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
  49                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
  50                 HUD_Write_Cvar_q("hud_progressbar_speed_color");
  51                 HUD_Write_Cvar_q("hud_progressbar_acceleration_color");
  52                 HUD_Write_Cvar_q("hud_progressbar_acceleration_neg_color");
  53                 HUD_Write("\n");
  54
  55                 HUD_Write_Cvar_q("_hud_panelorder");
  56                 HUD_Write("\n");
  57
  58                 HUD_Write_Cvar_q("hud_configure_grid");
  59                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
  60                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
  61                 HUD_Write("\n");
  62
  63                 // common cvars for all panels
  64                 int i;
  65                 for (i = 0; i < HUD_PANEL_NUM; ++i)
  66                 {
  67                         panel = hud_panel[i];
  68
  69                         HUD_Write_PanelCvar_n("");
  70                         HUD_Write_PanelCvar_q("_pos");
  71                         HUD_Write_PanelCvar_q("_size");
  72                         HUD_Write_PanelCvar_q("_bg");
  73                         HUD_Write_PanelCvar_q("_bg_color");
  74                         HUD_Write_PanelCvar_q("_bg_color_team");
  75                         HUD_Write_PanelCvar_q("_bg_alpha");
  76                         HUD_Write_PanelCvar_q("_bg_border");
  77                         HUD_Write_PanelCvar_q("_bg_padding");
  78                         switch(i) {
  79                                 case HUD_PANEL_WEAPONS:
  80                                         HUD_Write_PanelCvar_q("_accuracy");
  81                                         HUD_Write_PanelCvar_q("_label");
  82                                         HUD_Write_PanelCvar_q("_label_scale");
  83                                         HUD_Write_PanelCvar_q("_complainbubble");
  84                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
  85                                         HUD_Write_PanelCvar_q("_complainbubble_time");
  86                                         HUD_Write_PanelCvar_q("_complainbubble_fadetime");
  87                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
  88                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
  89                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
  90                                         HUD_Write_PanelCvar_q("_ammo");
  91                                         HUD_Write_PanelCvar_q("_ammo_color");
  92                                         HUD_Write_PanelCvar_q("_ammo_alpha");
  93                                         HUD_Write_PanelCvar_q("_aspect");
  94                                         HUD_Write_PanelCvar_q("_timeout");
  95                                         HUD_Write_PanelCvar_q("_timeout_effect");
  96                                         HUD_Write_PanelCvar_q("_timeout_fadebgmin");
  97                                         HUD_Write_PanelCvar_q("_timeout_fadefgmin");
  98                                         HUD_Write_PanelCvar_q("_timeout_speed_in");
  99                                         HUD_Write_PanelCvar_q("_timeout_speed_out");
 100                                         HUD_Write_PanelCvar_q("_onlyowned");
 101                                         break;
 102                                 case HUD_PANEL_AMMO:
 103                                         HUD_Write_PanelCvar_q("_onlycurrent");
 104                                         HUD_Write_PanelCvar_q("_noncurrent_alpha");
 105                                         HUD_Write_PanelCvar_q("_noncurrent_scale");
 106                                         HUD_Write_PanelCvar_q("_iconalign");
 107                                         HUD_Write_PanelCvar_q("_progressbar");
 108                                         HUD_Write_PanelCvar_q("_progressbar_name");
 109                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
 110                                         HUD_Write_PanelCvar_q("_text");
 111                                         break;
 112                                 case HUD_PANEL_POWERUPS:
 113                                         HUD_Write_PanelCvar_q("_flip");
 114                                         HUD_Write_PanelCvar_q("_iconalign");
 115                                         HUD_Write_PanelCvar_q("_baralign");
 116                                         HUD_Write_PanelCvar_q("_progressbar");
 117                                         HUD_Write_PanelCvar_q("_progressbar_strength");
 118                                         HUD_Write_PanelCvar_q("_progressbar_shield");
 119                                         HUD_Write_PanelCvar_q("_text");
 120                                         break;
 121                                 case HUD_PANEL_HEALTHARMOR:
 122                                         HUD_Write_PanelCvar_q("_flip");
 123                                         HUD_Write_PanelCvar_q("_iconalign");
 124                                         HUD_Write_PanelCvar_q("_baralign");
 125                                         HUD_Write_PanelCvar_q("_progressbar");
 126                                         HUD_Write_PanelCvar_q("_progressbar_health");
 127                                         HUD_Write_PanelCvar_q("_progressbar_armor");
 128                                         HUD_Write_PanelCvar_q("_progressbar_gfx");
 129                                         HUD_Write_PanelCvar_q("_progressbar_gfx_smooth");
 130                                         HUD_Write_PanelCvar_q("_text");
 131                                         break;
 132                                 case HUD_PANEL_NOTIFY:
 133                                         HUD_Write_PanelCvar_q("_flip");
 134                                         HUD_Write_PanelCvar_q("_fontsize");
 135                                         HUD_Write_PanelCvar_q("_time");
 136                                         HUD_Write_PanelCvar_q("_fadetime");
 137                                         HUD_Write_PanelCvar_q("_icon_aspect");
 138                                         break;
 139                                 case HUD_PANEL_TIMER:
 140                                         HUD_Write_PanelCvar_q("_increment");
 141                                         break;
 142                                 case HUD_PANEL_RADAR:
 143                                         HUD_Write_PanelCvar_q("_foreground_alpha");
 144                                         HUD_Write_PanelCvar_q("_rotation");
 145                                         HUD_Write_PanelCvar_q("_zoommode");
 146                                         HUD_Write_PanelCvar_q("_scale");
 147                                         HUD_Write_PanelCvar_q("_maximized_scale");
 148                                         HUD_Write_PanelCvar_q("_maximized_size");
 149                                         HUD_Write_PanelCvar_q("_maximized_rotation");
 150                                         HUD_Write_PanelCvar_q("_maximized_zoommode");
 151                                         break;
 152                                 case HUD_PANEL_SCORE:
 153                                         HUD_Write_PanelCvar_q("_rankings");
 154                                         break;
 155                                 case HUD_PANEL_VOTE:
 156                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
 157                                         break;
 158                                 case HUD_PANEL_MODICONS:
 159                                         HUD_Write_PanelCvar_q("_ca_layout");
 160                                         HUD_Write_PanelCvar_q("_dom_layout");
 161                                         HUD_Write_PanelCvar_q("_freezetag_layout");
 162                                         break;
 163                                 case HUD_PANEL_PRESSEDKEYS:
 164                                         HUD_Write_PanelCvar_q("_aspect");
 165                                         HUD_Write_PanelCvar_q("_attack");
 166                                         break;
 167                                 case HUD_PANEL_ENGINEINFO:
 168                                         HUD_Write_PanelCvar_q("_framecounter_time");
 169                                         HUD_Write_PanelCvar_q("_framecounter_decimals");
 170                                         break;
 171                                 case HUD_PANEL_INFOMESSAGES:
 172                                         HUD_Write_PanelCvar_q("_flip");
 173                                         break;
 174                                 case HUD_PANEL_PHYSICS:
 175                                         HUD_Write_PanelCvar_q("_speed_unit");
 176                                         HUD_Write_PanelCvar_q("_speed_unit_show");
 177                                         HUD_Write_PanelCvar_q("_speed_max");
 178                                         HUD_Write_PanelCvar_q("_speed_vertical");
 179                                         HUD_Write_PanelCvar_q("_topspeed");
 180                                         HUD_Write_PanelCvar_q("_topspeed_time");
 181                                         HUD_Write_PanelCvar_q("_acceleration_max");
 182                                         HUD_Write_PanelCvar_q("_acceleration_vertical");
 183                                         HUD_Write_PanelCvar_q("_flip");
 184                                         HUD_Write_PanelCvar_q("_baralign");
 185                                         HUD_Write_PanelCvar_q("_progressbar");
 186                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_mode");
 187                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_scale");
 188                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_nonlinear");
 189                                         HUD_Write_PanelCvar_q("_text");
 190                                         HUD_Write_PanelCvar_q("_text_scale");
 191                                         break;
 192                                 case HUD_PANEL_CENTERPRINT:
 193                                         HUD_Write_PanelCvar_q("_align");
 194                                         HUD_Write_PanelCvar_q("_flip");
 195                                         HUD_Write_PanelCvar_q("_fontscale");
 196                                         HUD_Write_PanelCvar_q("_time");
 197                                         HUD_Write_PanelCvar_q("_fade_in");
 198                                         HUD_Write_PanelCvar_q("_fade_out");
 199                                         HUD_Write_PanelCvar_q("_fade_subsequent");
 200                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone");
 201                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone_minalpha");
 202                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo");
 203                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo_minalpha");
 204                                         HUD_Write_PanelCvar_q("_fade_subsequent_minfontsize");
 205                                         HUD_Write_PanelCvar_q("_fade_minfontsize");
 206                                         break;
 207                         }
 208                         HUD_Write("\n");
 209                 }
 210                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
 211
 212                 printf(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename);
 213                 fclose(fh);
 214         }
 215         else
 216                 printf(_("^1Couldn't write to %s\n"), filename);
 217 }
 218
 219 void HUD_Configure_Exit_Force()
 220 {
 221         if (menu_enabled)
 222         {
 223                 menu_enabled = 0;
 224                 localcmd("togglemenu\n");
 225         }
 226         cvar_set("_hud_configure", "0");
 227 }
 228
 229 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 230 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 231 {
 232         vector myCenter, targCenter;
 233         vector myTarget = myPos;
 234         int i;
 235         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 236                 panel = hud_panel[i];
 237                 if(panel == highlightedPanel) continue;
 238                 HUD_Panel_UpdatePosSize();
 239                 if(!panel_enabled) continue;
 240
 241                 panel_pos -= '1 1 0' * panel_bg_border;
 242                 panel_size += '2 2 0' * panel_bg_border;
 243
 244                 if(myPos.y + mySize.y < panel_pos.y)
 245                         continue;
 246                 if(myPos.y > panel_pos.y + panel_size.y)
 247                         continue;
 248
 249                 if(myPos.x + mySize.x < panel_pos.x)
 250                         continue;
 251                 if(myPos.x > panel_pos.x + panel_size.x)
 252                         continue;
 253
 254                 // OK, there IS a collision.
 255
 256                 myCenter.x = myPos.x + 0.5 * mySize.x;
 257                 myCenter.y = myPos.y + 0.5 * mySize.y;
 258
 259                 targCenter.x = panel_pos.x + 0.5 * panel_size.x;
 260                 targCenter.y = panel_pos.y + 0.5 * panel_size.y;
 261
 262                 if(myCenter.x < targCenter.x && myCenter.y < targCenter.y) // top left (of the target panel)
 263                 {
 264                         if(myPos.x + mySize.x - panel_pos.x < myPos.y + mySize.y - panel_pos.y) // push it to the side
 265                                 myTarget.x = panel_pos.x - mySize.x;
 266                         else // push it upwards
 267                                 myTarget.y = panel_pos.y - mySize.y;
 268                 }
 269                 else if(myCenter.x > targCenter.x && myCenter.y < targCenter.y) // top right
 270                 {
 271                         if(panel_pos.x + panel_size.x - myPos.x < myPos.y + mySize.y - panel_pos.y) // push it to the side
 272                                 myTarget.x = panel_pos.x + panel_size.x;
 273                         else // push it upwards
 274                                 myTarget.y = panel_pos.y - mySize.y;
 275                 }
 276                 else if(myCenter.x < targCenter.x && myCenter.y > targCenter.y) // bottom left
 277                 {
 278                         if(myPos.x + mySize.x - panel_pos.x < panel_pos.y + panel_size.y - myPos.y) // push it to the side
 279                                 myTarget.x = panel_pos.x - mySize.x;
 280                         else // push it downwards
 281                                 myTarget.y = panel_pos.y + panel_size.y;
 282                 }
 283                 else if(myCenter.x > targCenter.x && myCenter.y > targCenter.y) // bottom right
 284                 {
 285                         if(panel_pos.x + panel_size.x - myPos.x < panel_pos.y + panel_size.y - myPos.y) // push it to the side
 286                                 myTarget.x = panel_pos.x + panel_size.x;
 287                         else // push it downwards
 288                                 myTarget.y = panel_pos.y + panel_size.y;
 289                 }
 290                 //if(cvar("hud_configure_checkcollisions_debug"))
 291                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 292         }
 293
 294         return myTarget;
 295 }
 296
 297 void HUD_Panel_SetPos(vector pos)
 298 {
 299         panel = highlightedPanel;
 300         HUD_Panel_UpdatePosSize();
 301         vector mySize;
 302         mySize = panel_size;
 303
 304         //if(cvar("hud_configure_checkcollisions_debug"))
 305                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 306
 307         if(autocvar_hud_configure_grid)
 308         {
 309                 pos.x = floor((pos.x/vid_conwidth)/hud_configure_gridSize.x + 0.5) * hud_configure_realGridSize.x;
 310                 pos.y = floor((pos.y/vid_conheight)/hud_configure_gridSize.y + 0.5) * hud_configure_realGridSize.y;
 311         }
 312
 313         if(hud_configure_checkcollisions)
 314                 pos = HUD_Panel_CheckMove(pos, mySize);
 315
 316         pos.x = bound(0, pos.x, vid_conwidth - mySize.x);
 317         pos.y = bound(0, pos.y, vid_conheight - mySize.y);
 318
 319         string s;
 320         s = strcat(ftos(pos.x/vid_conwidth), " ", ftos(pos.y/vid_conheight));
 321
 322         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_pos"), s);
 323 }
 324
 325 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 326 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 327         vector targEndPos;
 328         vector dist;
 329         float ratio = mySize.x/mySize.y;
 330         int i;
 331         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 332                 panel = hud_panel[i];
 333                 if(panel == highlightedPanel) continue;
 334                 HUD_Panel_UpdatePosSize();
 335                 if(!panel_enabled) continue;
 336
 337                 panel_pos -= '1 1 0' * panel_bg_border;
 338                 panel_size += '2 2 0' * panel_bg_border;
 339
 340                 targEndPos = panel_pos + panel_size;
 341
 342                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 343                 if(resizeorigin.x > panel_pos.x && resizeorigin.x < targEndPos.x && resizeorigin.y > panel_pos.y && resizeorigin.y < targEndPos.y)
 344                         continue;
 345
 346                 if (resizeCorner == 1)
 347                 {
 348                         // check if this panel is on our way
 349                         if (resizeorigin.x <= panel_pos.x)
 350                                 continue;
 351                         if (resizeorigin.y <= panel_pos.y)
 352                                 continue;
 353                         if (targEndPos.x <= resizeorigin.x - mySize.x)
 354                                 continue;
 355                         if (targEndPos.y <= resizeorigin.y - mySize.y)
 356                                 continue;
 357
 358                         // there is a collision:
 359                         // detect which side of the panel we are facing is actually limiting the resizing
 360                         // (which side the resize direction finds for first) and reduce the size up to there
 361                         //
 362                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 363                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 364                         dist.x = resizeorigin.x - targEndPos.x;
 365                         dist.y = resizeorigin.y - targEndPos.y;
 366                         if (dist.y <= 0 || dist.x / dist.y > ratio)
 367                                 mySize.x = min(mySize.x, dist.x);
 368                         else
 369                                 mySize.y = min(mySize.y, dist.y);
 370                 }
 371                 else if (resizeCorner == 2)
 372                 {
 373                         if (resizeorigin.x >= targEndPos.x)
 374                                 continue;
 375                         if (resizeorigin.y <= panel_pos.y)
 376                                 continue;
 377                         if (panel_pos.x >= resizeorigin.x + mySize.x)
 378                                 continue;
 379                         if (targEndPos.y <= resizeorigin.y - mySize.y)
 380                                 continue;
 381
 382                         dist.x = panel_pos.x - resizeorigin.x;
 383                         dist.y = resizeorigin.y - targEndPos.y;
 384                         if (dist.y <= 0 || dist.x / dist.y > ratio)
 385                                 mySize.x = min(mySize.x, dist.x);
 386                         else
 387                                 mySize.y = min(mySize.y, dist.y);
 388                 }
 389                 else if (resizeCorner == 3)
 390                 {
 391                         if (resizeorigin.x <= panel_pos.x)
 392                                 continue;
 393                         if (resizeorigin.y >= targEndPos.y)
 394                                 continue;
 395                         if (targEndPos.x <= resizeorigin.x - mySize.x)
 396                                 continue;
 397                         if (panel_pos.y >= resizeorigin.y + mySize.y)
 398                                 continue;
 399
 400                         dist.x = resizeorigin.x - targEndPos.x;
 401                         dist.y = panel_pos.y - resizeorigin.y;
 402                         if (dist.y <= 0 || dist.x / dist.y > ratio)
 403                                 mySize.x = min(mySize.x, dist.x);
 404                         else
 405                                 mySize.y = min(mySize.y, dist.y);
 406                 }
 407                 else if (resizeCorner == 4)
 408                 {
 409                         if (resizeorigin.x >= targEndPos.x)
 410                                 continue;
 411                         if (resizeorigin.y >= targEndPos.y)
 412                                 continue;
 413                         if (panel_pos.x >= resizeorigin.x + mySize.x)
 414                                 continue;
 415                         if (panel_pos.y >= resizeorigin.y + mySize.y)
 416                                 continue;
 417
 418                         dist.x = panel_pos.x - resizeorigin.x;
 419                         dist.y = panel_pos.y - resizeorigin.y;
 420                         if (dist.y <= 0 || dist.x / dist.y > ratio)
 421                                 mySize.x = min(mySize.x, dist.x);
 422                         else
 423                                 mySize.y = min(mySize.y, dist.y);
 424                 }
 425                 //if(cvar("hud_configure_checkcollisions_debug"))
 426                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 427         }
 428
 429         return mySize;
 430 }
 431
 432 void HUD_Panel_SetPosSize(vector mySize)
 433 {
 434         panel = highlightedPanel;
 435         HUD_Panel_UpdatePosSize();
 436         vector resizeorigin = panel_click_resizeorigin;
 437         vector myPos;
 438
 439         // minimum panel size cap
 440         mySize.x = max(0.025 * vid_conwidth, mySize.x);
 441         mySize.y = max(0.025 * vid_conheight, mySize.y);
 442
 443         if(highlightedPanel == HUD_PANEL(CHAT)) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 444         {
 445                 mySize.x = max(17 * autocvar_con_chatsize, mySize.x);
 446                 mySize.y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize.y);
 447         }
 448
 449         // collision testing|
 450         // -----------------+
 451
 452         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 453         if(resizeCorner == 1) {
 454                 myPos.x = resizeorigin.x - mySize.x;
 455                 myPos.y = resizeorigin.y - mySize.y;
 456         } else if(resizeCorner == 2) {
 457                 myPos.x = resizeorigin.x;
 458                 myPos.y = resizeorigin.y - mySize.y;
 459         } else if(resizeCorner == 3) {
 460                 myPos.x = resizeorigin.x - mySize.x;
 461                 myPos.y = resizeorigin.y;
 462         } else { // resizeCorner == 4
 463                 myPos.x = resizeorigin.x;
 464                 myPos.y = resizeorigin.y;
 465         }
 466
 467         // left/top screen edges
 468         if(myPos.x < 0)
 469                 mySize.x = mySize.x + myPos.x;
 470         if(myPos.y < 0)
 471                 mySize.y = mySize.y + myPos.y;
 472
 473         // bottom/right screen edges
 474         if(myPos.x + mySize.x > vid_conwidth)
 475                 mySize.x = vid_conwidth - myPos.x;
 476         if(myPos.y + mySize.y > vid_conheight)
 477                 mySize.y = vid_conheight - myPos.y;
 478
 479         //if(cvar("hud_configure_checkcollisions_debug"))
 480                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 481
 482         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 483         if(autocvar_hud_configure_grid)
 484         {
 485                 mySize.x = floor((mySize.x/vid_conwidth)/hud_configure_gridSize.x + 0.5) * hud_configure_realGridSize.x;
 486                 mySize.y = floor((mySize.y/vid_conheight)/hud_configure_gridSize.y + 0.5) * hud_configure_realGridSize.y;
 487         }
 488
 489         if(hud_configure_checkcollisions)
 490                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 491
 492         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 493         mySize.x = max(0.025 * vid_conwidth, mySize.x);
 494         mySize.y = max(0.025 * vid_conheight, mySize.y);
 495
 496         // do another pos check, as size might have changed by now
 497         if(resizeCorner == 1) {
 498                 myPos.x = resizeorigin.x - mySize.x;
 499                 myPos.y = resizeorigin.y - mySize.y;
 500         } else if(resizeCorner == 2) {
 501                 myPos.x = resizeorigin.x;
 502                 myPos.y = resizeorigin.y - mySize.y;
 503         } else if(resizeCorner == 3) {
 504                 myPos.x = resizeorigin.x - mySize.x;
 505                 myPos.y = resizeorigin.y;
 506         } else { // resizeCorner == 4
 507                 myPos.x = resizeorigin.x;
 508                 myPos.y = resizeorigin.y;
 509         }
 510
 511         //if(cvar("hud_configure_checkcollisions_debug"))
 512                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 513
 514         string s;
 515         s = strcat(ftos(mySize.x/vid_conwidth), " ", ftos(mySize.y/vid_conheight));
 516         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_size"), s);
 517
 518         s = strcat(ftos(myPos.x/vid_conwidth), " ", ftos(myPos.y/vid_conheight));
 519         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_pos"), s);
 520 }
 521
 522 float pressed_key_time;
 523 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 524 void HUD_Panel_Arrow_Action(float nPrimary)
 525 {
 526         if(!highlightedPanel)
 527                 return;
 528
 529         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 530
 531         float step;
 532         if(autocvar_hud_configure_grid)
 533         {
 534                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 535                 {
 536                         if (hudShiftState & S_SHIFT)
 537                                 step = hud_configure_realGridSize.y;
 538                         else
 539                                 step = 2 * hud_configure_realGridSize.y;
 540                 }
 541                 else
 542                 {
 543                         if (hudShiftState & S_SHIFT)
 544                                 step = hud_configure_realGridSize.x;
 545                         else
 546                                 step = 2 * hud_configure_realGridSize.x;
 547                 }
 548         }
 549         else
 550         {
 551                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 552                         step = vid_conheight;
 553                 else
 554                         step = vid_conwidth;
 555                 if (hudShiftState & S_SHIFT)
 556                         step = (step / 256); // more precision
 557                 else
 558                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 559         }
 560
 561         panel = highlightedPanel;
 562         HUD_Panel_UpdatePosSize();
 563
 564         highlightedPanel_initial_pos = panel_pos;
 565         highlightedPanel_initial_size = panel_size;
 566
 567         if (hudShiftState & S_ALT) // resize
 568         {
 569                 if(nPrimary == K_UPARROW)
 570                         resizeCorner = 1;
 571                 else if(nPrimary == K_RIGHTARROW)
 572                         resizeCorner = 2;
 573                 else if(nPrimary == K_LEFTARROW)
 574                         resizeCorner = 3;
 575                 else // if(nPrimary == K_DOWNARROW)
 576                         resizeCorner = 4;
 577
 578                 // ctrl+arrow reduces the size, instead of increasing it
 579                 // Note that ctrl disables collisions check too, but it's fine
 580                 // since we don't collide with anything reducing the size
 581                 if (hudShiftState & S_CTRL) {
 582                         step = -step;
 583                         resizeCorner = 5 - resizeCorner;
 584                 }
 585
 586                 vector mySize;
 587                 mySize = panel_size;
 588                 panel_click_resizeorigin = panel_pos;
 589                 if(resizeCorner == 1) {
 590                         panel_click_resizeorigin += mySize;
 591                         mySize.y += step;
 592                 } else if(resizeCorner == 2) {
 593                         panel_click_resizeorigin.y += mySize.y;
 594                         mySize.x += step;
 595                 } else if(resizeCorner == 3) {
 596                         panel_click_resizeorigin.x += mySize.x;
 597                         mySize.x += step;
 598                 } else { // resizeCorner == 4
 599                         mySize.y += step;
 600                 }
 601                 HUD_Panel_SetPosSize(mySize);
 602         }
 603         else // move
 604         {
 605                 vector pos;
 606                 pos = panel_pos;
 607                 if(nPrimary == K_UPARROW)
 608                         pos.y -= step;
 609                 else if(nPrimary == K_DOWNARROW)
 610                         pos.y += step;
 611                 else if(nPrimary == K_LEFTARROW)
 612                         pos.x -= step;
 613                 else // if(nPrimary == K_RIGHTARROW)
 614                         pos.x += step;
 615
 616                 HUD_Panel_SetPos(pos);
 617         }
 618
 619         panel = highlightedPanel;
 620         HUD_Panel_UpdatePosSize();
 621
 622         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 623         {
 624                 // backup!
 625                 panel_pos_backup = highlightedPanel_initial_pos;
 626                 panel_size_backup = highlightedPanel_initial_size;
 627                 highlightedPanel_backup = highlightedPanel;
 628         }
 629 }
 630
 631 const int S_MOUSE1 = 1;
 632 const int S_MOUSE2 = 2;
 633 const int S_MOUSE3 = 4;
 634 int mouseClicked;
 635 int prevMouseClicked; // previous state
 636 float prevMouseClickedTime; // time during previous left mouse click, to check for doubleclicks
 637 vector prevMouseClickedPos; // pos during previous left mouse click, to check for doubleclicks
 638
 639 void HUD_Panel_EnableMenu();
 640 entity tab_panels[HUD_PANEL_MAX];
 641 entity tab_panel;
 642 vector tab_panel_pos;
 643 float tab_backward;
 644 void HUD_Panel_FirstInDrawQ(float id);
 645 void reset_tab_panels()
 646 {
 647         int i;
 648         for(i = 0; i < HUD_PANEL_NUM; ++i)
 649                 tab_panels[i] = world;
 650 }
 651 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 652 {
 653         string s;
 654
 655         if(bInputType == 2)
 656                 return false;
 657
 658         if(!autocvar__hud_configure)
 659                 return false;
 660
 661         if(bInputType == 3)
 662         {
 663                 mousepos.x = nPrimary;
 664                 mousepos.y = nSecondary;
 665                 return true;
 666         }
 667
 668         // block any input while a menu dialog is fading
 669         // don't block mousepos read as it leads to cursor jumps in the interaction with the menu
 670         if(autocvar__menu_alpha)
 671         {
 672                 hudShiftState = 0;
 673                 mouseClicked = 0;
 674                 return true;
 675         }
 676
 677         // allow console bind to work
 678         string con_keys;
 679         float keys;
 680         con_keys = findkeysforcommand("toggleconsole", 0);
 681         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 682
 683         bool hit_con_bind = false;
 684         int i;
 685         for (i = 0; i < keys; ++i)
 686         {
 687                 if(nPrimary == stof(argv(i)))
 688                         hit_con_bind = true;
 689         }
 690
 691         if(bInputType == 0) {
 692                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 693                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 694                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 695         }
 696         else if(bInputType == 1) {
 697                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 698                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 699                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 700         }
 701
 702         if(nPrimary == K_CTRL)
 703         {
 704                 if (bInputType == 1) //ctrl has been released
 705                 {
 706                         if (tab_panel)
 707                         {
 708                                 //switch to selected panel
 709                                 highlightedPanel = tab_panel;
 710                                 highlightedAction = 0;
 711                                 HUD_Panel_FirstInDrawQ(highlightedPanel.panel_id);
 712                         }
 713                         tab_panel = world;
 714                         reset_tab_panels();
 715                 }
 716         }
 717
 718         if(nPrimary == K_MOUSE1)
 719         {
 720                 if(bInputType == 0) // key pressed
 721                         mouseClicked |= S_MOUSE1;
 722                 else if(bInputType == 1) // key released
 723                         mouseClicked -= (mouseClicked & S_MOUSE1);
 724         }
 725         else if(nPrimary == K_MOUSE2)
 726         {
 727                 if(bInputType == 0) // key pressed
 728                         mouseClicked |= S_MOUSE2;
 729                 else if(bInputType == 1) // key released
 730                         mouseClicked -= (mouseClicked & S_MOUSE2);
 731         }
 732         else if(nPrimary == K_ESCAPE)
 733         {
 734                 if (bInputType == 1)
 735                         return true;
 736                 menu_enabled = 1;
 737                 localcmd("menu_showhudexit\n");
 738         }
 739         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
 740         {
 741                 if (bInputType == 1)
 742                         return true;
 743                 if (!menu_enabled)
 744                         cvar_set("_hud_configure", "0");
 745         }
 746         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // select and highlight another panel
 747         {
 748                 if (bInputType == 1 || mouseClicked)
 749                         return true;
 750
 751                 //FIXME: if a panel is highlighted, has the same pos_x and lays in the same level
 752                 //of other panels then next consecutive ctrl-tab will select the highlighted panel too
 753                 //(it should only after every other panel of the hud)
 754                 //It's a minor bug anyway, we can live with it
 755
 756                 entity starting_panel;
 757                 entity old_tab_panel = tab_panel;
 758                 if (!tab_panel) //first press of TAB
 759                 {
 760                         if (highlightedPanel)
 761                         {
 762                                 panel = highlightedPanel;
 763                                 HUD_Panel_UpdatePosSize();
 764                         }
 765                         else
 766                                 panel_pos = '0 0 0';
 767                         starting_panel = highlightedPanel;
 768                         tab_panel_pos = panel_pos; //to compute level
 769                 }
 770                 else
 771                 {
 772                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 773                                 reset_tab_panels();
 774                         starting_panel = tab_panel;
 775                 }
 776                 tab_backward = (hudShiftState & S_SHIFT);
 777
 778                 float k, level = 0, start_posX;
 779                 vector candidate_pos = '0 0 0';
 780                 const float LEVELS_NUM = 4;
 781                 float level_height = vid_conheight / LEVELS_NUM;
 782 :find_tab_panel
 783                 level = floor(tab_panel_pos.y / level_height) * level_height; //starting level
 784                 candidate_pos.x = (!tab_backward) ? vid_conwidth : 0;
 785                 start_posX = tab_panel_pos.x;
 786                 tab_panel = world;
 787                 k=0;
 788                 while(++k)
 789                 {
 790                         for(i = 0; i < HUD_PANEL_NUM; ++i)
 791                         {
 792                                 panel = hud_panel[i];
 793                                 if (panel == tab_panels[i] || panel == starting_panel)
 794                                         continue;
 795                                 HUD_Panel_UpdatePosSize();
 796                                 if (panel_pos.y >= level && (panel_pos.y - level) < level_height)
 797                                 if (  ( !tab_backward && panel_pos.x >= start_posX && (panel_pos.x < candidate_pos.x || (panel_pos.x == candidate_pos.x && panel_pos.y <= candidate_pos.y)) )
 798                                         || ( tab_backward && panel_pos.x <= start_posX && (panel_pos.x > candidate_pos.x || (panel_pos.x == candidate_pos.x && panel_pos.y >= candidate_pos.y)) )  )
 799                                 {
 800                                         tab_panel = panel;
 801                                         tab_panel_pos = candidate_pos = panel_pos;
 802                                 }
 803                         }
 804                         if (tab_panel)
 805                                 break;
 806                         if (k == LEVELS_NUM) //tab_panel not found
 807                         {
 808                                 reset_tab_panels();
 809                                 if (!old_tab_panel)
 810                                 {
 811                                         tab_panel = world;
 812                                         return true;
 813                                 }
 814                                 starting_panel = old_tab_panel;
 815                                 old_tab_panel = world;
 816                                 goto find_tab_panel; //u must find tab_panel!
 817                         }
 818                         if (!tab_backward)
 819                         {
 820                                 level = (level + level_height) % vid_conheight;
 821                                 start_posX = 0;
 822                                 candidate_pos.x = vid_conwidth;
 823                         }
 824                         else
 825                         {
 826                                 level = (level - level_height) % vid_conheight;
 827                                 start_posX = vid_conwidth;
 828                                 candidate_pos.x = 0;
 829                         }
 830                 }
 831
 832                 tab_panels[tab_panel.panel_id] = tab_panel;
 833         }
 834         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 835         {
 836                 if (bInputType == 1 || mouseClicked)
 837                         return true;
 838
 839                 if (highlightedPanel)
 840                         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name), ftos(!cvar(strcat("hud_panel_", highlightedPanel.panel_name))));
 841                 else
 842                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 843         }
 844         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 845         {
 846                 if (bInputType == 1 || mouseClicked)
 847                         return true;
 848
 849                 if (highlightedPanel)
 850                 {
 851                         panel = highlightedPanel;
 852                         HUD_Panel_UpdatePosSize();
 853                         panel_size_copied = panel_size;
 854                 }
 855         }
 856         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 857         {
 858                 if (bInputType == 1 || mouseClicked)
 859                         return true;
 860
 861                 if (panel_size_copied == '0 0 0' || !highlightedPanel)
 862                         return true;
 863
 864                 panel = highlightedPanel;
 865                 HUD_Panel_UpdatePosSize();
 866
 867                 // reduce size if it'd go beyond screen boundaries
 868                 vector tmp_size = panel_size_copied;
 869                 if (panel_pos.x + panel_size_copied.x > vid_conwidth)
 870                         tmp_size.x = vid_conwidth - panel_pos.x;
 871                 if (panel_pos.y + panel_size_copied.y > vid_conheight)
 872                         tmp_size.y = vid_conheight - panel_pos.y;
 873
 874                 if (panel_size == tmp_size)
 875                         return true;
 876
 877                 // backup first!
 878                 panel_pos_backup = panel_pos;
 879                 panel_size_backup = panel_size;
 880                 highlightedPanel_backup = highlightedPanel;
 881
 882                 s = strcat(ftos(tmp_size.x/vid_conwidth), " ", ftos(tmp_size.y/vid_conheight));
 883                 cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_size"), s);
 884         }
 885         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 886         {
 887                 if (bInputType == 1 || mouseClicked)
 888                         return true;
 889                 //restore previous values
 890                 if (highlightedPanel_backup)
 891                 {
 892                         s = strcat(ftos(panel_pos_backup.x/vid_conwidth), " ", ftos(panel_pos_backup.y/vid_conheight));
 893                         cvar_set(strcat("hud_panel_", highlightedPanel_backup.panel_name, "_pos"), s);
 894                         s = strcat(ftos(panel_size_backup.x/vid_conwidth), " ", ftos(panel_size_backup.y/vid_conheight));
 895                         cvar_set(strcat("hud_panel_", highlightedPanel_backup.panel_name, "_size"), s);
 896                         highlightedPanel_backup = world;
 897                 }
 898         }
 899         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 900         {
 901                 if (bInputType == 1)
 902                 {
 903                         pressed_key_time = 0;
 904                         return true;
 905                 }
 906                 else if (pressed_key_time == 0)
 907                         pressed_key_time = time;
 908
 909                 if (!mouseClicked)
 910                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 911         }
 912         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 913         {
 914                 if (bInputType == 1)
 915                         return true;
 916                 if (highlightedPanel)
 917                         HUD_Panel_EnableMenu();
 918         }
 919         else if(hit_con_bind)
 920                 return false;
 921
 922         return true;
 923 }
 924
 925 float HUD_Panel_Check_Mouse_Pos(float allow_move)
 926 {
 927         int i, j = 0;
 928         while(j < HUD_PANEL_NUM)
 929         {
 930                 i = panel_order[j];
 931                 j += 1;
 932
 933                 panel = hud_panel[i];
 934                 HUD_Panel_UpdatePosSize();
 935
 936                 float border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 937
 938                 // move
 939                 if(allow_move && mousepos.x > panel_pos.x && mousepos.y > panel_pos.y && mousepos.x < panel_pos.x + panel_size.x && mousepos.y < panel_pos.y + panel_size.y)
 940                 {
 941                         return 1;
 942                 }
 943                 // resize from topleft border
 944                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
 945                 {
 946                         return 2;
 947                 }
 948                 // resize from topright border
 949                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
 950                 {
 951                         return 3;
 952                 }
 953                 // resize from bottomleft border
 954                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + panel_size.y + border)
 955                 {
 956                         return 3;
 957                 }
 958                 // resize from bottomright border
 959                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + panel_size.y + border)
 960                 {
 961                         return 2;
 962                 }
 963         }
 964         return 0;
 965 }
 966
 967 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 968 void HUD_Panel_FirstInDrawQ(float id)
 969 {
 970         int i;
 971         int place = -1;
 972         // find out where in the array our current id is, save into place
 973         for(i = 0; i < HUD_PANEL_NUM; ++i)
 974         {
 975                 if(panel_order[i] == id)
 976                 {
 977                         place = i;
 978                         break;
 979                 }
 980         }
 981         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 982         if(place == -1)
 983                 place = HUD_PANEL_NUM - 1;
 984
 985         // move all ids up by one step in the array until "place"
 986         for(i = place; i > 0; --i)
 987         {
 988                 panel_order[i] = panel_order[i-1];
 989         }
 990         // now save the new top id
 991         panel_order[0] = id;
 992
 993         // let's save them into the cvar by some strcat trickery
 994         string s = "";
 995         for(i = 0; i < HUD_PANEL_NUM; ++i)
 996         {
 997                 s = strcat(s, ftos(panel_order[i]), " ");
 998         }
 999         cvar_set("_hud_panelorder", s);
1000         if(hud_panelorder_prev)
1001                 strunzone(hud_panelorder_prev);
1002         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
1003 }
1004
1005 void HUD_Panel_Highlight(float allow_move)
1006 {
1007         int i, j = 0;
1008
1009         while(j < HUD_PANEL_NUM)
1010         {
1011                 i = panel_order[j];
1012                 j += 1;
1013
1014                 panel = hud_panel[i];
1015                 HUD_Panel_UpdatePosSize();
1016
1017                 float border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
1018
1019                 // move
1020                 if(allow_move && mousepos.x > panel_pos.x && mousepos.y > panel_pos.y && mousepos.x < panel_pos.x + panel_size.x && mousepos.y < panel_pos.y + panel_size.y)
1021                 {
1022                         highlightedPanel = hud_panel[i];
1023                         HUD_Panel_FirstInDrawQ(i);
1024                         highlightedAction = 1;
1025                         panel_click_distance = mousepos - panel_pos;
1026                         return;
1027                 }
1028                 // resize from topleft border
1029                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
1030                 {
1031                         highlightedPanel = hud_panel[i];
1032                         HUD_Panel_FirstInDrawQ(i);
1033                         highlightedAction = 2;
1034                         resizeCorner = 1;
1035                         panel_click_distance = mousepos - panel_pos;
1036                         panel_click_resizeorigin = panel_pos + panel_size;
1037                         return;
1038                 }
1039                 // resize from topright border
1040                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
1041                 {
1042                         highlightedPanel = hud_panel[i];
1043                         HUD_Panel_FirstInDrawQ(i);
1044                         highlightedAction = 2;
1045                         resizeCorner = 2;
1046                         panel_click_distance.x = panel_size.x - mousepos.x + panel_pos.x;
1047                         panel_click_distance.y = mousepos.y - panel_pos.y;
1048                         panel_click_resizeorigin = panel_pos + eY * panel_size.y;
1049                         return;
1050                 }
1051                 // resize from bottomleft border
1052                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + panel_size.y + border)
1053                 {
1054                         highlightedPanel = hud_panel[i];
1055                         HUD_Panel_FirstInDrawQ(i);
1056                         highlightedAction = 2;
1057                         resizeCorner = 3;
1058                         panel_click_distance.x = mousepos.x - panel_pos.x;
1059                         panel_click_distance.y = panel_size.y - mousepos.y + panel_pos.y;
1060                         panel_click_resizeorigin = panel_pos + eX * panel_size.x;
1061                         return;
1062                 }
1063                 // resize from bottomright border
1064                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + panel_size.y + border)
1065                 {
1066                         highlightedPanel = hud_panel[i];
1067                         HUD_Panel_FirstInDrawQ(i);
1068                         highlightedAction = 2;
1069                         resizeCorner = 4;
1070                         panel_click_distance = panel_size - mousepos + panel_pos;
1071                         panel_click_resizeorigin = panel_pos;
1072                         return;
1073                 }
1074         }
1075         highlightedPanel = world;
1076         highlightedAction = 0;
1077 }
1078
1079 void HUD_Panel_EnableMenu()
1080 {
1081         menu_enabled = 2;
1082         localcmd("menu_showhudoptions ", highlightedPanel.panel_name, "\n");
1083 }
1084 float mouse_over_panel;
1085 void HUD_Panel_Mouse()
1086 {
1087         if(autocvar__menu_alpha == 1)
1088                 return;
1089
1090         if (!autocvar_hud_cursormode)
1091         {
1092                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
1093
1094                 mousepos.x = bound(0, mousepos.x, vid_conwidth);
1095                 mousepos.y = bound(0, mousepos.y, vid_conheight);
1096         }
1097
1098         if(mouseClicked)
1099         {
1100                 if(prevMouseClicked == 0)
1101                 {
1102                         if (tab_panel)
1103                         {
1104                                 //stop ctrl-tab selection
1105                                 tab_panel = world;
1106                                 reset_tab_panels();
1107                         }
1108                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1109                                                                         // and calls HUD_Panel_UpdatePosSize() for the highlighted panel
1110                         if (highlightedPanel)
1111                         {
1112                                 highlightedPanel_initial_pos = panel_pos;
1113                                 highlightedPanel_initial_size = panel_size;
1114                         }
1115                         // doubleclick check
1116                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel && prevMouseClickedPos == mousepos)
1117                         {
1118                                 mouseClicked = 0; // to prevent spam, I guess.
1119                                 HUD_Panel_EnableMenu();
1120                         }
1121                         else
1122                         {
1123                                 if (mouseClicked & S_MOUSE1)
1124                                 {
1125                                         prevMouseClickedTime = time;
1126                                         prevMouseClickedPos = mousepos;
1127                                 }
1128                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1129                         }
1130                 }
1131                 else
1132                 {
1133                         panel = highlightedPanel;
1134                         HUD_Panel_UpdatePosSize();
1135                 }
1136
1137                 if (highlightedPanel)
1138                 {
1139                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1140                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1141                         {
1142                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1143                                 // backup!
1144                                 panel_pos_backup = highlightedPanel_initial_pos;
1145                                 panel_size_backup = highlightedPanel_initial_size;
1146                                 highlightedPanel_backup = highlightedPanel;
1147                         }
1148                         else
1149                                 // in case the clicked panel is inside another panel and we aren't
1150                                 // moving it, avoid the immediate "fix" of its position/size
1151                                 // (often unwanted and hateful) by disabling collisions check
1152                                 hud_configure_checkcollisions = false;
1153                 }
1154
1155                 if(highlightedAction == 1)
1156                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1157                 else if(highlightedAction == 2)
1158                 {
1159                         vector mySize = '0 0 0';
1160                         if(resizeCorner == 1) {
1161                                 mySize.x = panel_click_resizeorigin.x - (mousepos.x - panel_click_distance.x);
1162                                 mySize.y = panel_click_resizeorigin.y - (mousepos.y - panel_click_distance.y);
1163                         } else if(resizeCorner == 2) {
1164                                 mySize.x = mousepos.x + panel_click_distance.x - panel_click_resizeorigin.x;
1165                                 mySize.y = panel_click_distance.y + panel_click_resizeorigin.y - mousepos.y;
1166                         } else if(resizeCorner == 3) {
1167                                 mySize.x = panel_click_resizeorigin.x + panel_click_distance.x - mousepos.x;
1168                                 mySize.y = mousepos.y + panel_click_distance.y - panel_click_resizeorigin.y;
1169                         } else { // resizeCorner == 4
1170                                 mySize.x = mousepos.x - (panel_click_resizeorigin.x - panel_click_distance.x);
1171                                 mySize.y = mousepos.y - (panel_click_resizeorigin.y - panel_click_distance.y);
1172                         }
1173                         HUD_Panel_SetPosSize(mySize);
1174                 }
1175         }
1176         else
1177         {
1178                 if(prevMouseClicked)
1179                         highlightedAction = 0;
1180                 if(menu_enabled == 2)
1181                         mouse_over_panel = 0;
1182                 else
1183                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(true);
1184                 if (mouse_over_panel && !tab_panel)
1185                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1186         }
1187         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1188         const vector cursorsize = '32 32 0';
1189         float cursor_alpha = 1 - autocvar__menu_alpha;
1190
1191         if(!mouse_over_panel)
1192                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1193         else if(mouse_over_panel == 1)
1194                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1195         else if(mouse_over_panel == 2)
1196                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1197         else
1198                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1199
1200         prevMouseClicked = mouseClicked;
1201 }
1202 void HUD_Configure_DrawGrid()
1203 {
1204         float i;
1205         if(autocvar_hud_configure_grid && autocvar_hud_configure_grid_alpha)
1206         {
1207                 hud_configure_gridSize.x = bound(0.005, cvar("hud_configure_grid_xsize"), 0.2);
1208                 hud_configure_gridSize.y = bound(0.005, cvar("hud_configure_grid_ysize"), 0.2);
1209                 hud_configure_realGridSize.x = hud_configure_gridSize.x * vid_conwidth;
1210                 hud_configure_realGridSize.y = hud_configure_gridSize.y * vid_conheight;
1211                 vector s;
1212                 // x-axis
1213                 s = eX + eY * vid_conheight;
1214                 for(i = 1; i < 1/hud_configure_gridSize.x; ++i)
1215                         drawfill(eX * i * hud_configure_realGridSize.x, s, '0.5 0.5 0.5', autocvar_hud_configure_grid_alpha, DRAWFLAG_NORMAL);
1216                 // y-axis
1217                 s = eY + eX * vid_conwidth;
1218                 for(i = 1; i < 1/hud_configure_gridSize.y; ++i)
1219                         drawfill(eY * i * hud_configure_realGridSize.y, s, '0.5 0.5 0.5', autocvar_hud_configure_grid_alpha, DRAWFLAG_NORMAL);
1220         }
1221 }
1222
1223 float _menu_alpha_prev;
1224 void HUD_Configure_Frame()
1225 {
1226         int i;
1227         if(autocvar__hud_configure)
1228         {
1229                 if(isdemo() || intermission == 2)
1230                 {
1231                         HUD_Configure_Exit_Force();
1232                         return;
1233                 }
1234
1235                 if(!hud_configure_prev || hud_configure_prev == -1)
1236                 {
1237                         if(autocvar_hud_cursormode)
1238                                 setcursormode(1);
1239                         hudShiftState = 0;
1240                         for(i = HUD_PANEL_NUM - 1; i >= 0; --i)
1241                                 hud_panel[panel_order[i]].update_time = time;
1242                 }
1243
1244                 // NOTE this check is necessary because _menu_alpha isn't updated the frame the menu gets enabled
1245                 if(autocvar__menu_alpha != _menu_alpha_prev)
1246                 {
1247                         if(autocvar__menu_alpha == 0)
1248                                 menu_enabled = 0;
1249                         _menu_alpha_prev = autocvar__menu_alpha;
1250                 }
1251
1252                 HUD_Configure_DrawGrid();
1253         }
1254         else if(hud_configure_prev)
1255         {
1256                 if(menu_enabled)
1257                         menu_enabled = 0;
1258                 if(autocvar_hud_cursormode)
1259                         setcursormode(0);
1260         }
1261 }
1262
1263 const float hlBorderSize = 2;
1264 const string hlBorder = "gfx/hud/default/border_highlighted";
1265 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1266 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1267 {
1268         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1269         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size.x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1270         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size.y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size.x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1271         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size.y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1272         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size.x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size.y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1273 }
1274
1275 void HUD_Configure_PostDraw()
1276 {
1277         if(autocvar__hud_configure)
1278         {
1279                 if(tab_panel)
1280                 {
1281                         panel = tab_panel;
1282                         HUD_Panel_UpdatePosSize();
1283                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .2, DRAWFLAG_NORMAL);
1284                 }
1285                 if(highlightedPanel)
1286                 {
1287                         panel = highlightedPanel;
1288                         HUD_Panel_UpdatePosSize();
1289                         HUD_Panel_HlBorder(panel_bg_border * hlBorderSize, '0 0.5 1', 0.4 * (1 - autocvar__menu_alpha));
1290                 }
1291         }
1292 }