qcsrc/client/hud_config.qc

   1 #define HUD_Write(s) fputs(fh, s)
   2 // q: quoted, n: not quoted
   3 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
   4 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
   5 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel.panel_name, cvar_suf))
   6 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel.panel_name, cvar_suf))
   7 // Save the config
   8 void HUD_Panel_ExportCfg(string cfgname)
   9 {
  10         float fh;
  11         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  12         fh = fopen(filename, FILE_WRITE);
  13         if(fh >= 0)
  14         {
  15                 HUD_Write_Cvar_q("hud_skin");
  16                 HUD_Write_Cvar_q("hud_panel_bg");
  17                 HUD_Write_Cvar_q("hud_panel_bg_color");
  18                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
  19                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
  20                 HUD_Write_Cvar_q("hud_panel_bg_border");
  21                 HUD_Write_Cvar_q("hud_panel_bg_padding");
  22                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
  23                 HUD_Write("\n");
  24
  25                 HUD_Write_Cvar_q("hud_dock");
  26                 HUD_Write_Cvar_q("hud_dock_color");
  27                 HUD_Write_Cvar_q("hud_dock_color_team");
  28                 HUD_Write_Cvar_q("hud_dock_alpha");
  29                 HUD_Write("\n");
  30
  31                 HUD_Write_Cvar_q("hud_progressbar_alpha");
  32                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
  33                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
  34                 HUD_Write_Cvar_q("hud_progressbar_health_color");
  35                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
  36                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
  37                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
  38                 HUD_Write_Cvar_q("hud_progressbar_speed_color");
  39                 HUD_Write_Cvar_q("hud_progressbar_acceleration_color");
  40                 HUD_Write_Cvar_q("hud_progressbar_acceleration_neg_color");
  41                 HUD_Write("\n");
  42
  43                 HUD_Write_Cvar_q("_hud_panelorder");
  44                 HUD_Write("\n");
  45
  46                 HUD_Write_Cvar_q("hud_configure_grid");
  47                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
  48                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
  49                 HUD_Write("\n");
  50
  51                 // common cvars for all panels
  52                 float i;
  53                 for (i = 0; i < HUD_PANEL_NUM; ++i)
  54                 {
  55                         panel = hud_panel[i];
  56
  57                         HUD_Write_PanelCvar_n("");
  58                         HUD_Write_PanelCvar_q("_pos");
  59                         HUD_Write_PanelCvar_q("_size");
  60                         HUD_Write_PanelCvar_q("_bg");
  61                         HUD_Write_PanelCvar_q("_bg_color");
  62                         HUD_Write_PanelCvar_q("_bg_color_team");
  63                         HUD_Write_PanelCvar_q("_bg_alpha");
  64                         HUD_Write_PanelCvar_q("_bg_border");
  65                         HUD_Write_PanelCvar_q("_bg_padding");
  66                         switch(i) {
  67                                 case HUD_PANEL_WEAPONS:
  68                                         HUD_Write_PanelCvar_q("_accuracy");
  69                                         HUD_Write_PanelCvar_q("_label");
  70                                         HUD_Write_PanelCvar_q("_complainbubble");
  71                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
  72                                         HUD_Write_PanelCvar_q("_complainbubble_time");
  73                                         HUD_Write_PanelCvar_q("_complainbubble_fadetime");
  74                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
  75                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
  76                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
  77                                         HUD_Write_PanelCvar_q("_ammo");
  78                                         HUD_Write_PanelCvar_q("_ammo_color");
  79                                         HUD_Write_PanelCvar_q("_ammo_alpha");
  80                                         HUD_Write_PanelCvar_q("_aspect");
  81                                         HUD_Write_PanelCvar_q("_timeout");
  82                                         HUD_Write_PanelCvar_q("_timeout_effect");
  83                                         HUD_Write_PanelCvar_q("_timeout_fadebgmin");
  84                                         HUD_Write_PanelCvar_q("_timeout_fadefgmin");
  85                                         HUD_Write_PanelCvar_q("_timeout_speed_in");
  86                                         HUD_Write_PanelCvar_q("_timeout_speed_out");
  87                                         HUD_Write_PanelCvar_q("_onlyowned");
  88                                         break;
  89                                 case HUD_PANEL_AMMO:
  90                                         HUD_Write_PanelCvar_q("_onlycurrent");
  91                                         HUD_Write_PanelCvar_q("_iconalign");
  92                                         HUD_Write_PanelCvar_q("_progressbar");
  93                                         HUD_Write_PanelCvar_q("_progressbar_name");
  94                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
  95                                         HUD_Write_PanelCvar_q("_text");
  96                                         break;
  97                                 case HUD_PANEL_POWERUPS:
  98                                         HUD_Write_PanelCvar_q("_flip");
  99                                         HUD_Write_PanelCvar_q("_iconalign");
 100                                         HUD_Write_PanelCvar_q("_baralign");
 101                                         HUD_Write_PanelCvar_q("_progressbar");
 102                                         HUD_Write_PanelCvar_q("_progressbar_strength");
 103                                         HUD_Write_PanelCvar_q("_progressbar_shield");
 104                                         HUD_Write_PanelCvar_q("_text");
 105                                         break;
 106                                 case HUD_PANEL_HEALTHARMOR:
 107                                         HUD_Write_PanelCvar_q("_flip");
 108                                         HUD_Write_PanelCvar_q("_iconalign");
 109                                         HUD_Write_PanelCvar_q("_baralign");
 110                                         HUD_Write_PanelCvar_q("_progressbar");
 111                                         HUD_Write_PanelCvar_q("_progressbar_health");
 112                                         HUD_Write_PanelCvar_q("_progressbar_armor");
 113                                         HUD_Write_PanelCvar_q("_progressbar_gfx");
 114                                         HUD_Write_PanelCvar_q("_progressbar_gfx_smooth");
 115                                         HUD_Write_PanelCvar_q("_text");
 116                                         break;
 117                                 case HUD_PANEL_NOTIFY:
 118                                         HUD_Write_PanelCvar_q("_flip");
 119                                         HUD_Write_PanelCvar_q("_fontsize");
 120                                         HUD_Write_PanelCvar_q("_time");
 121                                         HUD_Write_PanelCvar_q("_fadetime");
 122                                         HUD_Write_PanelCvar_q("_icon_aspect");
 123                                         break;
 124                                 case HUD_PANEL_TIMER:
 125                                         HUD_Write_PanelCvar_q("_increment");
 126                                         break;
 127                                 case HUD_PANEL_RADAR:
 128                                         HUD_Write_PanelCvar_q("_foreground_alpha");
 129                                         HUD_Write_PanelCvar_q("_rotation");
 130                                         HUD_Write_PanelCvar_q("_zoommode");
 131                                         HUD_Write_PanelCvar_q("_scale");
 132                                         HUD_Write_PanelCvar_q("_maximized_scale");
 133                                         HUD_Write_PanelCvar_q("_maximized_size");
 134                                         HUD_Write_PanelCvar_q("_maximized_rotation");
 135                                         HUD_Write_PanelCvar_q("_maximized_zoommode");
 136                                         break;
 137                                 case HUD_PANEL_SCORE:
 138                                         HUD_Write_PanelCvar_q("_rankings");
 139                                         break;
 140                                 case HUD_PANEL_VOTE:
 141                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
 142                                         break;
 143                                 case HUD_PANEL_MODICONS:
 144                                         HUD_Write_PanelCvar_q("_ca_layout");
 145                                         HUD_Write_PanelCvar_q("_dom_layout");
 146                                         HUD_Write_PanelCvar_q("_freezetag_layout");
 147                                         break;
 148                                 case HUD_PANEL_PRESSEDKEYS:
 149                                         HUD_Write_PanelCvar_q("_aspect");
 150                                         HUD_Write_PanelCvar_q("_attack");
 151                                         break;
 152                                 case HUD_PANEL_ENGINEINFO:
 153                                         HUD_Write_PanelCvar_q("_framecounter_time");
 154                                         HUD_Write_PanelCvar_q("_framecounter_decimals");
 155                                         break;
 156                                 case HUD_PANEL_INFOMESSAGES:
 157                                         HUD_Write_PanelCvar_q("_flip");
 158                                         break;
 159                                 case HUD_PANEL_PHYSICS:
 160                                         HUD_Write_PanelCvar_q("_speed_unit");
 161                                         HUD_Write_PanelCvar_q("_speed_unit_show");
 162                                         HUD_Write_PanelCvar_q("_speed_max");
 163                                         HUD_Write_PanelCvar_q("_speed_vertical");
 164                                         HUD_Write_PanelCvar_q("_topspeed");
 165                                         HUD_Write_PanelCvar_q("_topspeed_time");
 166                                         HUD_Write_PanelCvar_q("_acceleration_max");
 167                                         HUD_Write_PanelCvar_q("_acceleration_vertical");
 168                                         HUD_Write_PanelCvar_q("_flip");
 169                                         HUD_Write_PanelCvar_q("_baralign");
 170                                         HUD_Write_PanelCvar_q("_progressbar");
 171                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_mode");
 172                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_scale");
 173                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_nonlinear");
 174                                         HUD_Write_PanelCvar_q("_text");
 175                                         HUD_Write_PanelCvar_q("_text_scale");
 176                                         break;
 177                                 case HUD_PANEL_CENTERPRINT:
 178                                         HUD_Write_PanelCvar_q("_align");
 179                                         HUD_Write_PanelCvar_q("_flip");
 180                                         HUD_Write_PanelCvar_q("_fontscale");
 181                                         HUD_Write_PanelCvar_q("_time");
 182                                         HUD_Write_PanelCvar_q("_fade_in");
 183                                         HUD_Write_PanelCvar_q("_fade_out");
 184                                         HUD_Write_PanelCvar_q("_fade_subsequent");
 185                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone");
 186                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone_minalpha");
 187                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo");
 188                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo_minalpha");
 189                                         HUD_Write_PanelCvar_q("_fade_subsequent_minfontsize");
 190                                         HUD_Write_PanelCvar_q("_fade_minfontsize");
 191                                         break;
 192                                 case HUD_PANEL_ITEMSTIME:
 193                                         HUD_Write_PanelCvar_q("_iconalign");
 194                                         HUD_Write_PanelCvar_q("_progressbar");
 195                                         HUD_Write_PanelCvar_q("_progressbar_name");
 196                                         HUD_Write_PanelCvar_q("_progressbar_reduced");
 197                                         HUD_Write_PanelCvar_q("_showspawned");
 198                                         HUD_Write_PanelCvar_q("_text");
 199                                         HUD_Write_PanelCvar_q("_ratio");
 200                                         HUD_Write_PanelCvar_q("_size_dinamic");
 201                                         break;
 202                         }
 203                         HUD_Write("\n");
 204                 }
 205                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
 206
 207                 printf(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename);
 208                 fclose(fh);
 209         }
 210         else
 211                 printf(_("^1Couldn't write to %s\n"), filename);
 212 }
 213
 214 void HUD_Configure_Exit_Force()
 215 {
 216         if (menu_enabled)
 217         {
 218                 menu_enabled = 0;
 219                 localcmd("togglemenu\n");
 220         }
 221         cvar_set("_hud_configure", "0");
 222 }
 223
 224 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 225 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 226 {
 227         float i;
 228         float myCenter_x, myCenter_y, targCenter_x, targCenter_y;
 229         vector myTarget;
 230         myTarget = myPos;
 231
 232         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 233                 panel = hud_panel[i];
 234                 if(panel == highlightedPanel) continue;
 235                 HUD_Panel_UpdatePosSize()
 236                 if(!panel_enabled) continue;
 237
 238                 panel_pos -= '1 1 0' * panel_bg_border;
 239                 panel_size += '2 2 0' * panel_bg_border;
 240
 241                 if(myPos_y + mySize_y < panel_pos_y)
 242                         continue;
 243                 if(myPos_y > panel_pos_y + panel_size_y)
 244                         continue;
 245
 246                 if(myPos_x + mySize_x < panel_pos_x)
 247                         continue;
 248                 if(myPos_x > panel_pos_x + panel_size_x)
 249                         continue;
 250
 251                 // OK, there IS a collision.
 252
 253                 myCenter_x = myPos_x + 0.5 * mySize_x;
 254                 myCenter_y = myPos_y + 0.5 * mySize_y;
 255
 256                 targCenter_x = panel_pos_x + 0.5 * panel_size_x;
 257                 targCenter_y = panel_pos_y + 0.5 * panel_size_y;
 258
 259                 if(myCenter_x < targCenter_x && myCenter_y < targCenter_y) // top left (of the target panel)
 260                 {
 261                         if(myPos_x + mySize_x - panel_pos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 262                                 myTarget_x = panel_pos_x - mySize_x;
 263                         else // push it upwards
 264                                 myTarget_y = panel_pos_y - mySize_y;
 265                 }
 266                 else if(myCenter_x > targCenter_x && myCenter_y < targCenter_y) // top right
 267                 {
 268                         if(panel_pos_x + panel_size_x - myPos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 269                                 myTarget_x = panel_pos_x + panel_size_x;
 270                         else // push it upwards
 271                                 myTarget_y = panel_pos_y - mySize_y;
 272                 }
 273                 else if(myCenter_x < targCenter_x && myCenter_y > targCenter_y) // bottom left
 274                 {
 275                         if(myPos_x + mySize_x - panel_pos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 276                                 myTarget_x = panel_pos_x - mySize_x;
 277                         else // push it downwards
 278                                 myTarget_y = panel_pos_y + panel_size_y;
 279                 }
 280                 else if(myCenter_x > targCenter_x && myCenter_y > targCenter_y) // bottom right
 281                 {
 282                         if(panel_pos_x + panel_size_x - myPos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 283                                 myTarget_x = panel_pos_x + panel_size_x;
 284                         else // push it downwards
 285                                 myTarget_y = panel_pos_y + panel_size_y;
 286                 }
 287                 //if(cvar("hud_configure_checkcollisions_debug"))
 288                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 289         }
 290
 291         return myTarget;
 292 }
 293
 294 void HUD_Panel_SetPos(vector pos)
 295 {
 296         panel = highlightedPanel;
 297         HUD_Panel_UpdatePosSize()
 298         vector mySize;
 299         mySize = panel_size;
 300
 301         //if(cvar("hud_configure_checkcollisions_debug"))
 302                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 303
 304         if(autocvar_hud_configure_grid)
 305         {
 306                 pos_x = floor((pos_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 307                 pos_y = floor((pos_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 308         }
 309
 310         if(hud_configure_checkcollisions)
 311                 pos = HUD_Panel_CheckMove(pos, mySize);
 312
 313         pos_x = bound(0, pos_x, vid_conwidth - mySize_x);
 314         pos_y = bound(0, pos_y, vid_conheight - mySize_y);
 315
 316         string s;
 317         s = strcat(ftos(pos_x/vid_conwidth), " ", ftos(pos_y/vid_conheight));
 318
 319         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_pos"), s);
 320 }
 321
 322 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 323 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 324         float i;
 325
 326         vector targEndPos;
 327
 328         float dist_x, dist_y;
 329         float ratio;
 330         ratio = mySize_x/mySize_y;
 331
 332         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 333                 panel = hud_panel[i];
 334                 if(panel == highlightedPanel) continue;
 335                 HUD_Panel_UpdatePosSize()
 336                 if(!panel_enabled) continue;
 337
 338                 panel_pos -= '1 1 0' * panel_bg_border;
 339                 panel_size += '2 2 0' * panel_bg_border;
 340
 341                 targEndPos = panel_pos + panel_size;
 342
 343                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 344                 if(resizeorigin_x > panel_pos_x && resizeorigin_x < targEndPos_x && resizeorigin_y > panel_pos_y && resizeorigin_y < targEndPos_y)
 345                         continue;
 346
 347                 if (resizeCorner == 1)
 348                 {
 349                         // check if this panel is on our way
 350                         if (resizeorigin_x <= panel_pos_x)
 351                                 continue;
 352                         if (resizeorigin_y <= panel_pos_y)
 353                                 continue;
 354                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 355                                 continue;
 356                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 357                                 continue;
 358
 359                         // there is a collision:
 360                         // detect which side of the panel we are facing is actually limiting the resizing
 361                         // (which side the resize direction finds for first) and reduce the size up to there
 362                         //
 363                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 364                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 365                         dist_x = resizeorigin_x - targEndPos_x;
 366                         dist_y = resizeorigin_y - targEndPos_y;
 367                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 368                                 mySize_x = min(mySize_x, dist_x);
 369                         else
 370                                 mySize_y = min(mySize_y, dist_y);
 371                 }
 372                 else if (resizeCorner == 2)
 373                 {
 374                         if (resizeorigin_x >= targEndPos_x)
 375                                 continue;
 376                         if (resizeorigin_y <= panel_pos_y)
 377                                 continue;
 378                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 379                                 continue;
 380                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 381                                 continue;
 382
 383                         dist_x = panel_pos_x - resizeorigin_x;
 384                         dist_y = resizeorigin_y - targEndPos_y;
 385                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 386                                 mySize_x = min(mySize_x, dist_x);
 387                         else
 388                                 mySize_y = min(mySize_y, dist_y);
 389                 }
 390                 else if (resizeCorner == 3)
 391                 {
 392                         if (resizeorigin_x <= panel_pos_x)
 393                                 continue;
 394                         if (resizeorigin_y >= targEndPos_y)
 395                                 continue;
 396                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 397                                 continue;
 398                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 399                                 continue;
 400
 401                         dist_x = resizeorigin_x - targEndPos_x;
 402                         dist_y = panel_pos_y - resizeorigin_y;
 403                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 404                                 mySize_x = min(mySize_x, dist_x);
 405                         else
 406                                 mySize_y = min(mySize_y, dist_y);
 407                 }
 408                 else if (resizeCorner == 4)
 409                 {
 410                         if (resizeorigin_x >= targEndPos_x)
 411                                 continue;
 412                         if (resizeorigin_y >= targEndPos_y)
 413                                 continue;
 414                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 415                                 continue;
 416                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 417                                 continue;
 418
 419                         dist_x = panel_pos_x - resizeorigin_x;
 420                         dist_y = panel_pos_y - resizeorigin_y;
 421                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 422                                 mySize_x = min(mySize_x, dist_x);
 423                         else
 424                                 mySize_y = min(mySize_y, dist_y);
 425                 }
 426                 //if(cvar("hud_configure_checkcollisions_debug"))
 427                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 428         }
 429
 430         return mySize;
 431 }
 432
 433 void HUD_Panel_SetPosSize(vector mySize)
 434 {
 435         panel = highlightedPanel;
 436         HUD_Panel_UpdatePosSize()
 437         vector resizeorigin;
 438         resizeorigin = panel_click_resizeorigin;
 439         local noref vector myPos; // fteqcc sucks
 440
 441         // minimum panel size cap
 442         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 443         mySize_y = max(0.025 * vid_conheight, mySize_y);
 444
 445         if(highlightedPanel == HUD_PANEL(CHAT)) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 446         {
 447                 mySize_x = max(17 * autocvar_con_chatsize, mySize_x);
 448                 mySize_y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize_y);
 449         }
 450
 451         // collision testing|
 452         // -----------------+
 453
 454         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 455         if(resizeCorner == 1) {
 456                 myPos_x = resizeorigin_x - mySize_x;
 457                 myPos_y = resizeorigin_y - mySize_y;
 458         } else if(resizeCorner == 2) {
 459                 myPos_x = resizeorigin_x;
 460                 myPos_y = resizeorigin_y - mySize_y;
 461         } else if(resizeCorner == 3) {
 462                 myPos_x = resizeorigin_x - mySize_x;
 463                 myPos_y = resizeorigin_y;
 464         } else { // resizeCorner == 4
 465                 myPos_x = resizeorigin_x;
 466                 myPos_y = resizeorigin_y;
 467         }
 468
 469         // left/top screen edges
 470         if(myPos_x < 0)
 471                 mySize_x = mySize_x + myPos_x;
 472         if(myPos_y < 0)
 473                 mySize_y = mySize_y + myPos_y;
 474
 475         // bottom/right screen edges
 476         if(myPos_x + mySize_x > vid_conwidth)
 477                 mySize_x = vid_conwidth - myPos_x;
 478         if(myPos_y + mySize_y > vid_conheight)
 479                 mySize_y = vid_conheight - myPos_y;
 480
 481         //if(cvar("hud_configure_checkcollisions_debug"))
 482                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 483
 484         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 485         if(autocvar_hud_configure_grid)
 486         {
 487                 mySize_x = floor((mySize_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 488                 mySize_y = floor((mySize_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 489         }
 490
 491         if(hud_configure_checkcollisions)
 492                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 493
 494         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 495         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 496         mySize_y = max(0.025 * vid_conheight, mySize_y);
 497
 498         // do another pos check, as size might have changed by now
 499         if(resizeCorner == 1) {
 500                 myPos_x = resizeorigin_x - mySize_x;
 501                 myPos_y = resizeorigin_y - mySize_y;
 502         } else if(resizeCorner == 2) {
 503                 myPos_x = resizeorigin_x;
 504                 myPos_y = resizeorigin_y - mySize_y;
 505         } else if(resizeCorner == 3) {
 506                 myPos_x = resizeorigin_x - mySize_x;
 507                 myPos_y = resizeorigin_y;
 508         } else { // resizeCorner == 4
 509                 myPos_x = resizeorigin_x;
 510                 myPos_y = resizeorigin_y;
 511         }
 512
 513         //if(cvar("hud_configure_checkcollisions_debug"))
 514                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 515
 516         string s;
 517         s = strcat(ftos(mySize_x/vid_conwidth), " ", ftos(mySize_y/vid_conheight));
 518         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_size"), s);
 519
 520         s = strcat(ftos(myPos_x/vid_conwidth), " ", ftos(myPos_y/vid_conheight));
 521         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_pos"), s);
 522 }
 523
 524 float pressed_key_time;
 525 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 526 void HUD_Panel_Arrow_Action(float nPrimary)
 527 {
 528         if(!highlightedPanel)
 529                 return;
 530
 531         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 532
 533         float step;
 534         if(autocvar_hud_configure_grid)
 535         {
 536                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 537                 {
 538                         if (hudShiftState & S_SHIFT)
 539                                 step = hud_configure_realGridSize_y;
 540                         else
 541                                 step = 2 * hud_configure_realGridSize_y;
 542                 }
 543                 else
 544                 {
 545                         if (hudShiftState & S_SHIFT)
 546                                 step = hud_configure_realGridSize_x;
 547                         else
 548                                 step = 2 * hud_configure_realGridSize_x;
 549                 }
 550         }
 551         else
 552         {
 553                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 554                         step = vid_conheight;
 555                 else
 556                         step = vid_conwidth;
 557                 if (hudShiftState & S_SHIFT)
 558                         step = (step / 256); // more precision
 559                 else
 560                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 561         }
 562
 563         panel = highlightedPanel;
 564         HUD_Panel_UpdatePosSize()
 565
 566         highlightedPanel_initial_pos = panel_pos;
 567         highlightedPanel_initial_size = panel_size;
 568
 569         if (hudShiftState & S_ALT) // resize
 570         {
 571                 highlightedAction = 1;
 572                 if(nPrimary == K_UPARROW)
 573                         resizeCorner = 1;
 574                 else if(nPrimary == K_RIGHTARROW)
 575                         resizeCorner = 2;
 576                 else if(nPrimary == K_LEFTARROW)
 577                         resizeCorner = 3;
 578                 else // if(nPrimary == K_DOWNARROW)
 579                         resizeCorner = 4;
 580
 581                 // ctrl+arrow reduces the size, instead of increasing it
 582                 // Note that ctrl disables collisions check too, but it's fine
 583                 // since we don't collide with anything reducing the size
 584                 if (hudShiftState & S_CTRL) {
 585                         step = -step;
 586                         resizeCorner = 5 - resizeCorner;
 587                 }
 588
 589                 vector mySize;
 590                 mySize = panel_size;
 591                 panel_click_resizeorigin = panel_pos;
 592                 if(resizeCorner == 1) {
 593                         panel_click_resizeorigin += mySize;
 594                         mySize_y += step;
 595                 } else if(resizeCorner == 2) {
 596                         panel_click_resizeorigin_y += mySize_y;
 597                         mySize_x += step;
 598                 } else if(resizeCorner == 3) {
 599                         panel_click_resizeorigin_x += mySize_x;
 600                         mySize_x += step;
 601                 } else { // resizeCorner == 4
 602                         mySize_y += step;
 603                 }
 604                 HUD_Panel_SetPosSize(mySize);
 605         }
 606         else // move
 607         {
 608                 highlightedAction = 2;
 609                 vector pos;
 610                 pos = panel_pos;
 611                 if(nPrimary == K_UPARROW)
 612                         pos_y -= step;
 613                 else if(nPrimary == K_DOWNARROW)
 614                         pos_y += step;
 615                 else if(nPrimary == K_LEFTARROW)
 616                         pos_x -= step;
 617                 else // if(nPrimary == K_RIGHTARROW)
 618                         pos_x += step;
 619
 620                 HUD_Panel_SetPos(pos);
 621         }
 622
 623         panel = highlightedPanel;
 624         HUD_Panel_UpdatePosSize()
 625
 626         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 627         {
 628                 // backup!
 629                 panel_pos_backup = highlightedPanel_initial_pos;
 630                 panel_size_backup = highlightedPanel_initial_size;
 631                 highlightedPanel_backup = highlightedPanel;
 632         }
 633 }
 634
 635 const float S_MOUSE1 = 1;
 636 const float S_MOUSE2 = 2;
 637 const float S_MOUSE3 = 4;
 638 float mouseClicked;
 639 float prevMouseClicked; // previous state
 640 float prevMouseClickedTime; // time during previous left mouse click, to check for doubleclicks
 641 vector prevMouseClickedPos; // pos during previous left mouse click, to check for doubleclicks
 642
 643 void HUD_Panel_EnableMenu();
 644 entity tab_panels[HUD_PANEL_MAX];
 645 entity tab_panel;
 646 vector tab_panel_pos;
 647 float tab_backward;
 648 void HUD_Panel_FirstInDrawQ(float id);
 649 void reset_tab_panels()
 650 {
 651         int i;
 652         for(i = 0; i < HUD_PANEL_NUM; ++i)
 653                 tab_panels[i] = world;
 654 }
 655 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 656 {
 657         string s;
 658
 659         if(bInputType == 2)
 660                 return false;
 661
 662         if(!autocvar__hud_configure)
 663                 return false;
 664
 665         if(bInputType == 3)
 666         {
 667                 mousepos_x = nPrimary;
 668                 mousepos_y = nSecondary;
 669                 return true;
 670         }
 671
 672         // block any input while a menu dialog is fading
 673         // don't block mousepos read as it leads to cursor jumps in the interaction with the menu
 674         if(autocvar__menu_alpha)
 675         {
 676                 hudShiftState = 0;
 677                 mouseClicked = 0;
 678                 return true;
 679         }
 680
 681         // allow console bind to work
 682         string con_keys;
 683         float keys;
 684         con_keys = findkeysforcommand("toggleconsole", 0);
 685         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 686
 687         float hit_con_bind = 0, i;
 688         for (i = 0; i < keys; ++i)
 689         {
 690                 if(nPrimary == stof(argv(i)))
 691                         hit_con_bind = 1;
 692         }
 693
 694         if(bInputType == 0) {
 695                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 696                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 697                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 698         }
 699         else if(bInputType == 1) {
 700                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 701                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 702                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 703         }
 704
 705         if(nPrimary == K_CTRL)
 706         {
 707                 if (bInputType == 1) //ctrl has been released
 708                 {
 709                         if (tab_panel)
 710                         {
 711                                 //switch to selected panel
 712                                 highlightedPanel = tab_panel;
 713                                 highlightedAction = 0;
 714                                 HUD_Panel_FirstInDrawQ(highlightedPanel.panel_id);
 715                         }
 716                         tab_panel = world;
 717                         reset_tab_panels();
 718                 }
 719         }
 720
 721         if(nPrimary == K_MOUSE1)
 722         {
 723                 if(bInputType == 0) // key pressed
 724                         mouseClicked |= S_MOUSE1;
 725                 else if(bInputType == 1) // key released
 726                         mouseClicked -= (mouseClicked & S_MOUSE1);
 727         }
 728         else if(nPrimary == K_MOUSE2)
 729         {
 730                 if(bInputType == 0) // key pressed
 731                         mouseClicked |= S_MOUSE2;
 732                 else if(bInputType == 1) // key released
 733                         mouseClicked -= (mouseClicked & S_MOUSE2);
 734         }
 735         else if(nPrimary == K_ESCAPE)
 736         {
 737                 if (bInputType == 1)
 738                         return true;
 739                 menu_enabled = 1;
 740                 localcmd("menu_showhudexit\n");
 741         }
 742         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
 743         {
 744                 if (bInputType == 1)
 745                         return true;
 746                 if (!menu_enabled)
 747                         cvar_set("_hud_configure", "0");
 748         }
 749         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // select and highlight another panel
 750         {
 751                 if (bInputType == 1 || mouseClicked)
 752                         return true;
 753
 754                 //FIXME: if a panel is highlighted, has the same pos_x and lays in the same level
 755                 //of other panels then next consecutive ctrl-tab will select the highlighted panel too
 756                 //(it should only after every other panel of the hud)
 757                 //It's a minor bug anyway, we can live with it
 758
 759                 entity starting_panel;
 760                 entity old_tab_panel = tab_panel;
 761                 if (!tab_panel) //first press of TAB
 762                 {
 763                         if (highlightedPanel)
 764                         {
 765                                 panel = highlightedPanel;
 766                                 HUD_Panel_UpdatePosSize()
 767                         }
 768                         else
 769                                 panel_pos = '0 0 0';
 770                         starting_panel = highlightedPanel;
 771                         tab_panel_pos = panel_pos; //to compute level
 772                 }
 773                 else
 774                 {
 775                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 776                                 reset_tab_panels();
 777                         starting_panel = tab_panel;
 778                 }
 779                 tab_backward = (hudShiftState & S_SHIFT);
 780
 781                 float k, level = 0, start_pos_x;
 782                 vector candidate_pos = '0 0 0';
 783                 const float LEVELS_NUM = 4;
 784                 float level_height = vid_conheight / LEVELS_NUM;
 785 :find_tab_panel
 786                 level = floor(tab_panel_pos_y / level_height) * level_height; //starting level
 787                 candidate_pos_x = (!tab_backward) ? vid_conwidth : 0;
 788                 start_pos_x = tab_panel_pos_x;
 789                 tab_panel = world;
 790                 k=0;
 791                 while(++k)
 792                 {
 793                         for(i = 0; i < HUD_PANEL_NUM; ++i)
 794                         {
 795                                 panel = hud_panel[i];
 796                                 if (panel == tab_panels[i] || panel == starting_panel)
 797                                         continue;
 798                                 HUD_Panel_UpdatePosSize()
 799                                 if (panel_pos_y >= level && (panel_pos_y - level) < level_height)
 800                                 if (  ( !tab_backward && panel_pos_x >= start_pos_x && (panel_pos_x < candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y <= candidate_pos_y)) )
 801                                         || ( tab_backward && panel_pos_x <= start_pos_x && (panel_pos_x > candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y >= candidate_pos_y)) )  )
 802                                 {
 803                                         tab_panel = panel;
 804                                         tab_panel_pos = candidate_pos = panel_pos;
 805                                 }
 806                         }
 807                         if (tab_panel)
 808                                 break;
 809                         if (k == LEVELS_NUM) //tab_panel not found
 810                         {
 811                                 reset_tab_panels();
 812                                 if (!old_tab_panel)
 813                                 {
 814                                         tab_panel = world;
 815                                         return true;
 816                                 }
 817                                 starting_panel = old_tab_panel;
 818                                 old_tab_panel = world;
 819                                 goto find_tab_panel; //u must find tab_panel!
 820                         }
 821                         if (!tab_backward)
 822                         {
 823                                 level = (level + level_height) % vid_conheight;
 824                                 start_pos_x = 0;
 825                                 candidate_pos_x = vid_conwidth;
 826                         }
 827                         else
 828                         {
 829                                 level = (level - level_height) % vid_conheight;
 830                                 start_pos_x = vid_conwidth;
 831                                 candidate_pos_x = 0;
 832                         }
 833                 }
 834
 835                 tab_panels[tab_panel.panel_id] = tab_panel;
 836         }
 837         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 838         {
 839                 if (bInputType == 1 || mouseClicked)
 840                         return true;
 841
 842                 if (highlightedPanel)
 843                         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name), ftos(!cvar(strcat("hud_panel_", highlightedPanel.panel_name))));
 844                 else
 845                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 846         }
 847         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 848         {
 849                 if (bInputType == 1 || mouseClicked)
 850                         return true;
 851
 852                 if (highlightedPanel)
 853                 {
 854                         panel = highlightedPanel;
 855                         HUD_Panel_UpdatePosSize()
 856                         panel_size_copied = panel_size;
 857                 }
 858         }
 859         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 860         {
 861                 if (bInputType == 1 || mouseClicked)
 862                         return true;
 863
 864                 if (panel_size_copied == '0 0 0' || !highlightedPanel)
 865                         return true;
 866
 867                 panel = highlightedPanel;
 868                 HUD_Panel_UpdatePosSize()
 869
 870                 // reduce size if it'd go beyond screen boundaries
 871                 vector tmp_size = panel_size_copied;
 872                 if (panel_pos_x + panel_size_copied_x > vid_conwidth)
 873                         tmp_size_x = vid_conwidth - panel_pos_x;
 874                 if (panel_pos_y + panel_size_copied_y > vid_conheight)
 875                         tmp_size_y = vid_conheight - panel_pos_y;
 876
 877                 if (panel_size == tmp_size)
 878                         return true;
 879
 880                 // backup first!
 881                 panel_pos_backup = panel_pos;
 882                 panel_size_backup = panel_size;
 883                 highlightedPanel_backup = highlightedPanel;
 884
 885                 s = strcat(ftos(tmp_size_x/vid_conwidth), " ", ftos(tmp_size_y/vid_conheight));
 886                 cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_size"), s);
 887         }
 888         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 889         {
 890                 if (bInputType == 1 || mouseClicked)
 891                         return true;
 892                 //restore previous values
 893                 if (highlightedPanel_backup)
 894                 {
 895                         s = strcat(ftos(panel_pos_backup_x/vid_conwidth), " ", ftos(panel_pos_backup_y/vid_conheight));
 896                         cvar_set(strcat("hud_panel_", highlightedPanel_backup.panel_name, "_pos"), s);
 897                         s = strcat(ftos(panel_size_backup_x/vid_conwidth), " ", ftos(panel_size_backup_y/vid_conheight));
 898                         cvar_set(strcat("hud_panel_", highlightedPanel_backup.panel_name, "_size"), s);
 899                         highlightedPanel_backup = world;
 900                 }
 901         }
 902         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 903         {
 904                 if (bInputType == 1)
 905                 {
 906                         pressed_key_time = 0;
 907                         return true;
 908                 }
 909                 else if (pressed_key_time == 0)
 910                         pressed_key_time = time;
 911
 912                 if (!mouseClicked)
 913                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 914         }
 915         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 916         {
 917                 if (bInputType == 1)
 918                         return true;
 919                 if (highlightedPanel)
 920                         HUD_Panel_EnableMenu();
 921         }
 922         else if(hit_con_bind)
 923                 return false;
 924
 925         return true;
 926 }
 927
 928 float HUD_Panel_Check_Mouse_Pos(float allow_move)
 929 {
 930         float i, j = 0, border;
 931
 932         while(j < HUD_PANEL_NUM)
 933         {
 934                 i = panel_order[j];
 935                 j += 1;
 936
 937                 panel = hud_panel[i];
 938                 HUD_Panel_UpdatePosSize()
 939
 940                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 941
 942                 // move
 943                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
 944                 {
 945                         return 1;
 946                 }
 947                 // resize from topleft border
 948                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 949                 {
 950                         return 2;
 951                 }
 952                 // resize from topright border
 953                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 954                 {
 955                         return 3;
 956                 }
 957                 // resize from bottomleft border
 958                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
 959                 {
 960                         return 3;
 961                 }
 962                 // resize from bottomright border
 963                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
 964                 {
 965                         return 2;
 966                 }
 967         }
 968         return 0;
 969 }
 970
 971 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 972 void HUD_Panel_FirstInDrawQ(float id)
 973 {
 974         float i;
 975         var float place = -1;
 976         // find out where in the array our current id is, save into place
 977         for(i = 0; i < HUD_PANEL_NUM; ++i)
 978         {
 979                 if(panel_order[i] == id)
 980                 {
 981                         place = i;
 982                         break;
 983                 }
 984         }
 985         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 986         if(place == -1)
 987                 place = HUD_PANEL_NUM - 1;
 988
 989         // move all ids up by one step in the array until "place"
 990         for(i = place; i > 0; --i)
 991         {
 992                 panel_order[i] = panel_order[i-1];
 993         }
 994         // now save the new top id
 995         panel_order[0] = id;
 996
 997         // let's save them into the cvar by some strcat trickery
 998         string s = "";
 999         for(i = 0; i < HUD_PANEL_NUM; ++i)
1000         {
1001                 s = strcat(s, ftos(panel_order[i]), " ");
1002         }
1003         cvar_set("_hud_panelorder", s);
1004         if(hud_panelorder_prev)
1005                 strunzone(hud_panelorder_prev);
1006         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
1007 }
1008
1009 void HUD_Panel_Highlight(float allow_move)
1010 {
1011         float i, j = 0, border;
1012
1013         while(j < HUD_PANEL_NUM)
1014         {
1015                 i = panel_order[j];
1016                 j += 1;
1017
1018                 panel = hud_panel[i];
1019                 HUD_Panel_UpdatePosSize()
1020
1021                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
1022
1023                 // move
1024                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
1025                 {
1026                         highlightedPanel = hud_panel[i];
1027                         HUD_Panel_FirstInDrawQ(i);
1028                         highlightedAction = 1;
1029                         panel_click_distance = mousepos - panel_pos;
1030                         return;
1031                 }
1032                 // resize from topleft border
1033                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1034                 {
1035                         highlightedPanel = hud_panel[i];
1036                         HUD_Panel_FirstInDrawQ(i);
1037                         highlightedAction = 2;
1038                         resizeCorner = 1;
1039                         panel_click_distance = mousepos - panel_pos;
1040                         panel_click_resizeorigin = panel_pos + panel_size;
1041                         return;
1042                 }
1043                 // resize from topright border
1044                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1045                 {
1046                         highlightedPanel = hud_panel[i];
1047                         HUD_Panel_FirstInDrawQ(i);
1048                         highlightedAction = 2;
1049                         resizeCorner = 2;
1050                         panel_click_distance_x = panel_size_x - mousepos_x + panel_pos_x;
1051                         panel_click_distance_y = mousepos_y - panel_pos_y;
1052                         panel_click_resizeorigin = panel_pos + eY * panel_size_y;
1053                         return;
1054                 }
1055                 // resize from bottomleft border
1056                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
1057                 {
1058                         highlightedPanel = hud_panel[i];
1059                         HUD_Panel_FirstInDrawQ(i);
1060                         highlightedAction = 2;
1061                         resizeCorner = 3;
1062                         panel_click_distance_x = mousepos_x - panel_pos_x;
1063                         panel_click_distance_y = panel_size_y - mousepos_y + panel_pos_y;
1064                         panel_click_resizeorigin = panel_pos + eX * panel_size_x;
1065                         return;
1066                 }
1067                 // resize from bottomright border
1068                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
1069                 {
1070                         highlightedPanel = hud_panel[i];
1071                         HUD_Panel_FirstInDrawQ(i);
1072                         highlightedAction = 2;
1073                         resizeCorner = 4;
1074                         panel_click_distance = panel_size - mousepos + panel_pos;
1075                         panel_click_resizeorigin = panel_pos;
1076                         return;
1077                 }
1078         }
1079         highlightedPanel = world;
1080         highlightedAction = 0;
1081 }
1082
1083 void HUD_Panel_EnableMenu()
1084 {
1085         menu_enabled = 2;
1086         localcmd("menu_showhudoptions ", highlightedPanel.panel_name, "\n");
1087 }
1088 float mouse_over_panel;
1089 void HUD_Panel_Mouse()
1090 {
1091         if(autocvar__menu_alpha == 1)
1092                 return;
1093
1094         if (!autocvar_hud_cursormode)
1095         {
1096                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
1097
1098                 mousepos_x = bound(0, mousepos_x, vid_conwidth);
1099                 mousepos_y = bound(0, mousepos_y, vid_conheight);
1100         }
1101
1102         if(mouseClicked)
1103         {
1104                 if(prevMouseClicked == 0)
1105                 {
1106                         if (tab_panel)
1107                         {
1108                                 //stop ctrl-tab selection
1109                                 tab_panel = world;
1110                                 reset_tab_panels();
1111                         }
1112                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1113                                                                         // and calls HUD_Panel_UpdatePosSize() for the highlighted panel
1114                         if (highlightedPanel)
1115                         {
1116                                 highlightedPanel_initial_pos = panel_pos;
1117                                 highlightedPanel_initial_size = panel_size;
1118                         }
1119                         // doubleclick check
1120                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel && prevMouseClickedPos == mousepos)
1121                         {
1122                                 mouseClicked = 0; // to prevent spam, I guess.
1123                                 HUD_Panel_EnableMenu();
1124                         }
1125                         else
1126                         {
1127                                 if (mouseClicked & S_MOUSE1)
1128                                 {
1129                                         prevMouseClickedTime = time;
1130                                         prevMouseClickedPos = mousepos;
1131                                 }
1132                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1133                         }
1134                 }
1135                 else
1136                 {
1137                         panel = highlightedPanel;
1138                         HUD_Panel_UpdatePosSize()
1139                 }
1140
1141                 if (highlightedPanel)
1142                 {
1143                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1144                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1145                         {
1146                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1147                                 // backup!
1148                                 panel_pos_backup = highlightedPanel_initial_pos;
1149                                 panel_size_backup = highlightedPanel_initial_size;
1150                                 highlightedPanel_backup = highlightedPanel;
1151                         }
1152                         else
1153                                 // in case the clicked panel is inside another panel and we aren't
1154                                 // moving it, avoid the immediate "fix" of its position/size
1155                                 // (often unwanted and hateful) by disabling collisions check
1156                                 hud_configure_checkcollisions = false;
1157                 }
1158
1159                 if(highlightedAction == 1)
1160                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1161                 else if(highlightedAction == 2)
1162                 {
1163                         vector mySize = '0 0 0';
1164                         if(resizeCorner == 1) {
1165                                 mySize_x = panel_click_resizeorigin_x - (mousepos_x - panel_click_distance_x);
1166                                 mySize_y = panel_click_resizeorigin_y - (mousepos_y - panel_click_distance_y);
1167                         } else if(resizeCorner == 2) {
1168                                 mySize_x = mousepos_x + panel_click_distance_x - panel_click_resizeorigin_x;
1169                                 mySize_y = panel_click_distance_y + panel_click_resizeorigin_y - mousepos_y;
1170                         } else if(resizeCorner == 3) {
1171                                 mySize_x = panel_click_resizeorigin_x + panel_click_distance_x - mousepos_x;
1172                                 mySize_y = mousepos_y + panel_click_distance_y - panel_click_resizeorigin_y;
1173                         } else { // resizeCorner == 4
1174                                 mySize_x = mousepos_x - (panel_click_resizeorigin_x - panel_click_distance_x);
1175                                 mySize_y = mousepos_y - (panel_click_resizeorigin_y - panel_click_distance_y);
1176                         }
1177                         HUD_Panel_SetPosSize(mySize);
1178                 }
1179         }
1180         else
1181         {
1182                 if(menu_enabled == 2)
1183                         mouse_over_panel = 0;
1184                 else
1185                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(TRUE);
1186                 if (mouse_over_panel && !tab_panel)
1187                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1188         }
1189         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1190         const vector cursorsize = '32 32 0';
1191         float cursor_alpha = 1 - autocvar__menu_alpha;
1192
1193         if(!mouse_over_panel)
1194                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1195         else if(mouse_over_panel == 1)
1196                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1197         else if(mouse_over_panel == 2)
1198                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1199         else
1200                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1201
1202         prevMouseClicked = mouseClicked;
1203 }
1204 void HUD_Configure_DrawGrid()
1205 {
1206         float i;
1207         if(autocvar_hud_configure_grid && autocvar_hud_configure_grid_alpha)
1208         {
1209                 hud_configure_gridSize_x = bound(0.005, cvar("hud_configure_grid_xsize"), 0.2);
1210                 hud_configure_gridSize_y = bound(0.005, cvar("hud_configure_grid_ysize"), 0.2);
1211                 hud_configure_realGridSize_x = hud_configure_gridSize_x * vid_conwidth;
1212                 hud_configure_realGridSize_y = hud_configure_gridSize_y * vid_conheight;
1213                 vector s;
1214                 // x-axis
1215                 s = eX + eY * vid_conheight;
1216                 for(i = 1; i < 1/hud_configure_gridSize_x; ++i)
1217                         drawfill(eX * i * hud_configure_realGridSize_x, s, '0.5 0.5 0.5', autocvar_hud_configure_grid_alpha, DRAWFLAG_NORMAL);
1218                 // y-axis
1219                 s = eY + eX * vid_conwidth;
1220                 for(i = 1; i < 1/hud_configure_gridSize_y; ++i)
1221                         drawfill(eY * i * hud_configure_realGridSize_y, s, '0.5 0.5 0.5', autocvar_hud_configure_grid_alpha, DRAWFLAG_NORMAL);
1222         }
1223 }
1224
1225 float _menu_alpha_prev;
1226 void HUD_Configure_Frame()
1227 {
1228         float i;
1229         if(autocvar__hud_configure)
1230         {
1231                 if(isdemo() || intermission == 2)
1232                 {
1233                         HUD_Configure_Exit_Force();
1234                         return;
1235                 }
1236
1237                 if(!hud_configure_prev || hud_configure_prev == -1)
1238                 {
1239                         if(autocvar_hud_cursormode)
1240                                 setcursormode(1);
1241                         hudShiftState = 0;
1242                         for(i = HUD_PANEL_NUM - 1; i >= 0; --i)
1243                                 hud_panel[panel_order[i]].update_time = time;
1244                 }
1245
1246                 // NOTE this check is necessary because _menu_alpha isn't updated the frame the menu gets enabled
1247                 if(autocvar__menu_alpha != _menu_alpha_prev)
1248                 {
1249                         if(autocvar__menu_alpha == 0)
1250                                 menu_enabled = 0;
1251                         _menu_alpha_prev = autocvar__menu_alpha;
1252                 }
1253
1254                 HUD_Configure_DrawGrid();
1255         }
1256         else if(hud_configure_prev)
1257         {
1258                 if(menu_enabled)
1259                         menu_enabled = 0;
1260                 if(autocvar_hud_cursormode)
1261                         setcursormode(0);
1262         }
1263 }
1264
1265 const float hlBorderSize = 4;
1266 const string hlBorder = "gfx/hud/default/border_highlighted";
1267 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1268 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1269 {
1270         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1271         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1272         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size_y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1273         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1274         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size_x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1275 }
1276
1277 void HUD_Configure_PostDraw()
1278 {
1279         if(autocvar__hud_configure)
1280         {
1281                 if(tab_panel)
1282                 {
1283                         panel = tab_panel;
1284                         HUD_Panel_UpdatePosSize()
1285                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .2, DRAWFLAG_NORMAL);
1286                 }
1287                 if(highlightedPanel)
1288                 {
1289                         panel = highlightedPanel;
1290                         HUD_Panel_UpdatePosSize()
1291                         HUD_Panel_HlBorder(panel_bg_border + 1.5 * hlBorderSize, '0 0.5 1', 0.25 * (1 - autocvar__menu_alpha));
1292                 }
1293         }
1294 }