qcsrc/client/hud_config.qc

   1 #define HUD_Write(s) fputs(fh, s)
   2 // q: quoted, n: not quoted
   3 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
   4 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
   5 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel_name, cvar_suf))
   6 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel_name, cvar_suf))
   7 // Save the config
   8 void HUD_Panel_ExportCfg(string cfgname)
   9 {
  10         float fh;
  11         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  12         fh = fopen(filename, FILE_WRITE);
  13         if(fh >= 0)
  14         {
  15                 HUD_Write_Cvar_q("hud_skin");
  16                 HUD_Write_Cvar_q("hud_panel_bg");
  17                 HUD_Write_Cvar_q("hud_panel_bg_color");
  18                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
  19                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
  20                 HUD_Write_Cvar_q("hud_panel_bg_border");
  21                 HUD_Write_Cvar_q("hud_panel_bg_padding");
  22                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
  23                 HUD_Write("\n");
  24
  25                 HUD_Write_Cvar_q("hud_dock");
  26                 HUD_Write_Cvar_q("hud_dock_color");
  27                 HUD_Write_Cvar_q("hud_dock_color_team");
  28                 HUD_Write_Cvar_q("hud_dock_alpha");
  29                 HUD_Write("\n");
  30
  31                 HUD_Write_Cvar_q("hud_progressbar_alpha");
  32                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
  33                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
  34                 HUD_Write_Cvar_q("hud_progressbar_health_color");
  35                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
  36                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
  37                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
  38                 HUD_Write_Cvar_q("hud_progressbar_speed_color");
  39                 HUD_Write_Cvar_q("hud_progressbar_acceleration_color");
  40                 HUD_Write_Cvar_q("hud_progressbar_acceleration_neg_color");
  41                 HUD_Write("\n");
  42
  43                 HUD_Write_Cvar_q("_hud_panelorder");
  44                 HUD_Write("\n");
  45
  46                 HUD_Write_Cvar_q("hud_configure_grid");
  47                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
  48                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
  49                 HUD_Write("\n");
  50
  51                 // common cvars for all panels
  52                 float i;
  53                 for (i = 0; i < HUD_PANEL_NUM; ++i)
  54                 {
  55                         HUD_Panel_GetName(i);
  56
  57                         HUD_Write_PanelCvar_n("");
  58                         HUD_Write_PanelCvar_q("_pos");
  59                         HUD_Write_PanelCvar_q("_size");
  60                         HUD_Write_PanelCvar_q("_bg");
  61                         HUD_Write_PanelCvar_q("_bg_color");
  62                         HUD_Write_PanelCvar_q("_bg_color_team");
  63                         HUD_Write_PanelCvar_q("_bg_alpha");
  64                         HUD_Write_PanelCvar_q("_bg_border");
  65                         HUD_Write_PanelCvar_q("_bg_padding");
  66                         switch(i) {
  67                                 case HUD_PANEL_WEAPONS:
  68                                         HUD_Write_PanelCvar_q("_accuracy");
  69                                         HUD_Write_PanelCvar_q("_label");
  70                                         HUD_Write_PanelCvar_q("_complainbubble");
  71                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
  72                                         HUD_Write_PanelCvar_q("_complainbubble_time");
  73                                         HUD_Write_PanelCvar_q("_complainbubble_fadetime");
  74                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
  75                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
  76                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
  77                                         HUD_Write_PanelCvar_q("_ammo");
  78                                         HUD_Write_PanelCvar_q("_ammo_color");
  79                                         HUD_Write_PanelCvar_q("_ammo_alpha");
  80                                         HUD_Write_PanelCvar_q("_aspect");
  81                                         HUD_Write_PanelCvar_q("_timeout");
  82                                         HUD_Write_PanelCvar_q("_timeout_effect");
  83                                         HUD_Write_PanelCvar_q("_timeout_fadebgmin");
  84                                         HUD_Write_PanelCvar_q("_timeout_fadefgmin");
  85                                         HUD_Write_PanelCvar_q("_timeout_speed_in");
  86                                         HUD_Write_PanelCvar_q("_timeout_speed_out");
  87                                         HUD_Write_PanelCvar_q("_onlyowned");
  88                                         break;
  89                                 case HUD_PANEL_AMMO:
  90                                         HUD_Write_PanelCvar_q("_onlycurrent");
  91                                         HUD_Write_PanelCvar_q("_iconalign");
  92                                         HUD_Write_PanelCvar_q("_progressbar");
  93                                         HUD_Write_PanelCvar_q("_progressbar_name");
  94                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
  95                                         HUD_Write_PanelCvar_q("_text");
  96                                         break;
  97                                 case HUD_PANEL_POWERUPS:
  98                                         HUD_Write_PanelCvar_q("_flip");
  99                                         HUD_Write_PanelCvar_q("_iconalign");
 100                                         HUD_Write_PanelCvar_q("_baralign");
 101                                         HUD_Write_PanelCvar_q("_progressbar");
 102                                         HUD_Write_PanelCvar_q("_progressbar_strength");
 103                                         HUD_Write_PanelCvar_q("_progressbar_shield");
 104                                         HUD_Write_PanelCvar_q("_text");
 105                                         break;
 106                                 case HUD_PANEL_HEALTHARMOR:
 107                                         HUD_Write_PanelCvar_q("_flip");
 108                                         HUD_Write_PanelCvar_q("_iconalign");
 109                                         HUD_Write_PanelCvar_q("_baralign");
 110                                         HUD_Write_PanelCvar_q("_progressbar");
 111                                         HUD_Write_PanelCvar_q("_progressbar_health");
 112                                         HUD_Write_PanelCvar_q("_progressbar_armor");
 113                                         HUD_Write_PanelCvar_q("_progressbar_gfx");
 114                                         HUD_Write_PanelCvar_q("_progressbar_gfx_smooth");
 115                                         HUD_Write_PanelCvar_q("_text");
 116                                         break;
 117                                 case HUD_PANEL_NOTIFY:
 118                                         HUD_Write_PanelCvar_q("_flip");
 119                                         HUD_Write_PanelCvar_q("_fontsize");
 120                                         HUD_Write_PanelCvar_q("_time");
 121                                         HUD_Write_PanelCvar_q("_fadetime");
 122                                         break;
 123                                 case HUD_PANEL_TIMER:
 124                                         HUD_Write_PanelCvar_q("_increment");
 125                                         break;
 126                                 case HUD_PANEL_RADAR:
 127                                         HUD_Write_PanelCvar_q("_foreground_alpha");
 128                                         HUD_Write_PanelCvar_q("_rotation");
 129                                         HUD_Write_PanelCvar_q("_zoommode");
 130                                         HUD_Write_PanelCvar_q("_scale");
 131                                         HUD_Write_PanelCvar_q("_maximized_scale");
 132                                         HUD_Write_PanelCvar_q("_maximized_size");
 133                                         HUD_Write_PanelCvar_q("_maximized_rotation");
 134                                         HUD_Write_PanelCvar_q("_maximized_zoommode");
 135                                         break;
 136                                 case HUD_PANEL_SCORE:
 137                                         HUD_Write_PanelCvar_q("_rankings");
 138                                         break;
 139                                 case HUD_PANEL_VOTE:
 140                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
 141                                         break;
 142                                 case HUD_PANEL_MODICONS:
 143                                         HUD_Write_PanelCvar_q("_dom_layout");
 144                                         break;
 145                                 case HUD_PANEL_PRESSEDKEYS:
 146                                         HUD_Write_PanelCvar_q("_aspect");
 147                                         HUD_Write_PanelCvar_q("_attack");
 148                                         break;
 149                                 case HUD_PANEL_ENGINEINFO:
 150                                         HUD_Write_PanelCvar_q("_framecounter_time");
 151                                         HUD_Write_PanelCvar_q("_framecounter_decimals");
 152                                         break;
 153                                 case HUD_PANEL_INFOMESSAGES:
 154                                         HUD_Write_PanelCvar_q("_flip");
 155                                         break;
 156                                 case HUD_PANEL_PHYSICS:
 157                                         HUD_Write_PanelCvar_q("_speed_unit");
 158                                         HUD_Write_PanelCvar_q("_speed_unit_show");
 159                                         HUD_Write_PanelCvar_q("_speed_max");
 160                                         HUD_Write_PanelCvar_q("_speed_vertical");
 161                                         HUD_Write_PanelCvar_q("_topspeed");
 162                                         HUD_Write_PanelCvar_q("_topspeed_time");
 163                                         HUD_Write_PanelCvar_q("_acceleration_max");
 164                                         HUD_Write_PanelCvar_q("_acceleration_vertical");
 165                                         HUD_Write_PanelCvar_q("_flip");
 166                                         HUD_Write_PanelCvar_q("_baralign");
 167                                         HUD_Write_PanelCvar_q("_progressbar");
 168                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_mode");
 169                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_scale");
 170                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_nonlinear");
 171                                         HUD_Write_PanelCvar_q("_text");
 172                                         HUD_Write_PanelCvar_q("_text_scale");
 173                                         break;
 174                                 case HUD_PANEL_CENTERPRINT:
 175                                         HUD_Write_PanelCvar_q("_align");
 176                                         HUD_Write_PanelCvar_q("_flip");
 177                                         HUD_Write_PanelCvar_q("_fontscale");
 178                                         HUD_Write_PanelCvar_q("_time");
 179                                         HUD_Write_PanelCvar_q("_fade_in");
 180                                         HUD_Write_PanelCvar_q("_fade_out");
 181                                         HUD_Write_PanelCvar_q("_fade_subsequent");
 182                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone");
 183                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone_minalpha");
 184                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo");
 185                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo_minalpha");
 186                                         HUD_Write_PanelCvar_q("_fade_subsequent_minfontsize");
 187                                         HUD_Write_PanelCvar_q("_fade_minfontsize");
 188                                         break;
 189                                 case HUD_PANEL_QUICKMENU:
 190                                         HUD_Write_PanelCvar_q("_align");
 191                                         break;
 192                         }
 193                         HUD_Write("\n");
 194                 }
 195                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
 196
 197                 print(sprintf(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename));
 198                 fclose(fh);
 199         }
 200         else
 201                 print(sprintf(_("^1Couldn't write to %s\n"), filename));
 202 }
 203
 204 void HUD_Configure_Exit_Force()
 205 {
 206         if (menu_enabled)
 207         {
 208                 menu_enabled = 0;
 209                 localcmd("togglemenu\n");
 210         }
 211         cvar_set("_hud_configure", "0");
 212 }
 213
 214 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 215 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 216 {
 217         float i;
 218         float myCenter_x, myCenter_y, targCenter_x, targCenter_y;
 219         vector myTarget;
 220         myTarget = myPos;
 221
 222         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 223                 if(i == highlightedPanel || !panel_enabled)
 224                         continue;
 225
 226                 HUD_Panel_UpdatePosSizeForId(i);
 227
 228                 panel_pos -= '1 1 0' * panel_bg_border;
 229                 panel_size += '2 2 0' * panel_bg_border;
 230
 231                 if(myPos_y + mySize_y < panel_pos_y)
 232                         continue;
 233                 if(myPos_y > panel_pos_y + panel_size_y)
 234                         continue;
 235
 236                 if(myPos_x + mySize_x < panel_pos_x)
 237                         continue;
 238                 if(myPos_x > panel_pos_x + panel_size_x)
 239                         continue;
 240
 241                 // OK, there IS a collision.
 242
 243                 myCenter_x = myPos_x + 0.5 * mySize_x;
 244                 myCenter_y = myPos_y + 0.5 * mySize_y;
 245
 246                 targCenter_x = panel_pos_x + 0.5 * panel_size_x;
 247                 targCenter_y = panel_pos_y + 0.5 * panel_size_y;
 248
 249                 if(myCenter_x < targCenter_x && myCenter_y < targCenter_y) // top left (of the target panel)
 250                 {
 251                         if(myPos_x + mySize_x - panel_pos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 252                                 myTarget_x = panel_pos_x - mySize_x;
 253                         else // push it upwards
 254                                 myTarget_y = panel_pos_y - mySize_y;
 255                 }
 256                 else if(myCenter_x > targCenter_x && myCenter_y < targCenter_y) // top right
 257                 {
 258                         if(panel_pos_x + panel_size_x - myPos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 259                                 myTarget_x = panel_pos_x + panel_size_x;
 260                         else // push it upwards
 261                                 myTarget_y = panel_pos_y - mySize_y;
 262                 }
 263                 else if(myCenter_x < targCenter_x && myCenter_y > targCenter_y) // bottom left
 264                 {
 265                         if(myPos_x + mySize_x - panel_pos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 266                                 myTarget_x = panel_pos_x - mySize_x;
 267                         else // push it downwards
 268                                 myTarget_y = panel_pos_y + panel_size_y;
 269                 }
 270                 else if(myCenter_x > targCenter_x && myCenter_y > targCenter_y) // bottom right
 271                 {
 272                         if(panel_pos_x + panel_size_x - myPos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 273                                 myTarget_x = panel_pos_x + panel_size_x;
 274                         else // push it downwards
 275                                 myTarget_y = panel_pos_y + panel_size_y;
 276                 }
 277                 //if(cvar("hud_configure_checkcollisions_debug"))
 278                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 279         }
 280
 281         return myTarget;
 282 }
 283
 284 void HUD_Panel_SetPos(vector pos)
 285 {
 286         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 287         vector mySize;
 288         mySize = panel_size;
 289
 290         //if(cvar("hud_configure_checkcollisions_debug"))
 291                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 292
 293         if(autocvar_hud_configure_grid)
 294         {
 295                 pos_x = floor((pos_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 296                 pos_y = floor((pos_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 297         }
 298
 299         if(hud_configure_checkcollisions)
 300                 pos = HUD_Panel_CheckMove(pos, mySize);
 301
 302         pos_x = bound(0, pos_x, vid_conwidth - mySize_x);
 303         pos_y = bound(0, pos_y, vid_conheight - mySize_y);
 304
 305         string s;
 306         s = strcat(ftos(pos_x/vid_conwidth), " ", ftos(pos_y/vid_conheight));
 307
 308         HUD_Panel_GetName(highlightedPanel);
 309         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 310 }
 311
 312 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 313 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 314         float i;
 315
 316         vector targEndPos;
 317
 318         float dist_x, dist_y;
 319         float ratio;
 320         ratio = mySize_x/mySize_y;
 321
 322         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 323                 if(i == highlightedPanel || !panel_enabled)
 324                         continue;
 325
 326                 HUD_Panel_UpdatePosSizeForId(i);
 327
 328                 panel_pos -= '1 1 0' * panel_bg_border;
 329                 panel_size += '2 2 0' * panel_bg_border;
 330
 331                 targEndPos = panel_pos + panel_size;
 332
 333                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 334                 if(resizeorigin_x > panel_pos_x && resizeorigin_x < targEndPos_x && resizeorigin_y > panel_pos_y && resizeorigin_y < targEndPos_y)
 335                         continue;
 336
 337                 if (resizeCorner == 1)
 338                 {
 339                         // check if this panel is on our way
 340                         if (resizeorigin_x <= panel_pos_x)
 341                                 continue;
 342                         if (resizeorigin_y <= panel_pos_y)
 343                                 continue;
 344                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 345                                 continue;
 346                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 347                                 continue;
 348
 349                         // there is a collision:
 350                         // detect which side of the panel we are facing is actually limiting the resizing
 351                         // (which side the resize direction finds for first) and reduce the size up to there
 352                         //
 353                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 354                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 355                         dist_x = resizeorigin_x - targEndPos_x;
 356                         dist_y = resizeorigin_y - targEndPos_y;
 357                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 358                                 mySize_x = min(mySize_x, dist_x);
 359                         else
 360                                 mySize_y = min(mySize_y, dist_y);
 361                 }
 362                 else if (resizeCorner == 2)
 363                 {
 364                         if (resizeorigin_x >= targEndPos_x)
 365                                 continue;
 366                         if (resizeorigin_y <= panel_pos_y)
 367                                 continue;
 368                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 369                                 continue;
 370                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 371                                 continue;
 372
 373                         dist_x = panel_pos_x - resizeorigin_x;
 374                         dist_y = resizeorigin_y - targEndPos_y;
 375                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 376                                 mySize_x = min(mySize_x, dist_x);
 377                         else
 378                                 mySize_y = min(mySize_y, dist_y);
 379                 }
 380                 else if (resizeCorner == 3)
 381                 {
 382                         if (resizeorigin_x <= panel_pos_x)
 383                                 continue;
 384                         if (resizeorigin_y >= targEndPos_y)
 385                                 continue;
 386                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 387                                 continue;
 388                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 389                                 continue;
 390
 391                         dist_x = resizeorigin_x - targEndPos_x;
 392                         dist_y = panel_pos_y - resizeorigin_y;
 393                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 394                                 mySize_x = min(mySize_x, dist_x);
 395                         else
 396                                 mySize_y = min(mySize_y, dist_y);
 397                 }
 398                 else if (resizeCorner == 4)
 399                 {
 400                         if (resizeorigin_x >= targEndPos_x)
 401                                 continue;
 402                         if (resizeorigin_y >= targEndPos_y)
 403                                 continue;
 404                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 405                                 continue;
 406                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 407                                 continue;
 408
 409                         dist_x = panel_pos_x - resizeorigin_x;
 410                         dist_y = panel_pos_y - resizeorigin_y;
 411                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 412                                 mySize_x = min(mySize_x, dist_x);
 413                         else
 414                                 mySize_y = min(mySize_y, dist_y);
 415                 }
 416                 //if(cvar("hud_configure_checkcollisions_debug"))
 417                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 418         }
 419
 420         return mySize;
 421 }
 422
 423 void HUD_Panel_SetPosSize(vector mySize)
 424 {
 425         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 426         vector resizeorigin;
 427         resizeorigin = panel_click_resizeorigin;
 428         local noref vector myPos; // fteqcc sucks
 429
 430         // minimum panel size cap
 431         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 432         mySize_y = max(0.025 * vid_conheight, mySize_y);
 433
 434         if(highlightedPanel == HUD_PANEL_CHAT) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 435         {
 436                 mySize_x = max(17 * autocvar_con_chatsize, mySize_x);
 437                 mySize_y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize_y);
 438         }
 439
 440         // collision testing|
 441         // -----------------+
 442
 443         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 444         if(resizeCorner == 1) {
 445                 myPos_x = resizeorigin_x - mySize_x;
 446                 myPos_y = resizeorigin_y - mySize_y;
 447         } else if(resizeCorner == 2) {
 448                 myPos_x = resizeorigin_x;
 449                 myPos_y = resizeorigin_y - mySize_y;
 450         } else if(resizeCorner == 3) {
 451                 myPos_x = resizeorigin_x - mySize_x;
 452                 myPos_y = resizeorigin_y;
 453         } else { // resizeCorner == 4
 454                 myPos_x = resizeorigin_x;
 455                 myPos_y = resizeorigin_y;
 456         }
 457
 458         // left/top screen edges
 459         if(myPos_x < 0)
 460                 mySize_x = mySize_x + myPos_x;
 461         if(myPos_y < 0)
 462                 mySize_y = mySize_y + myPos_y;
 463
 464         // bottom/right screen edges
 465         if(myPos_x + mySize_x > vid_conwidth)
 466                 mySize_x = vid_conwidth - myPos_x;
 467         if(myPos_y + mySize_y > vid_conheight)
 468                 mySize_y = vid_conheight - myPos_y;
 469
 470         //if(cvar("hud_configure_checkcollisions_debug"))
 471                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 472
 473         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 474         if(autocvar_hud_configure_grid)
 475         {
 476                 mySize_x = floor((mySize_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 477                 mySize_y = floor((mySize_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 478         }
 479
 480         if(hud_configure_checkcollisions)
 481                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 482
 483         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 484         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 485         mySize_y = max(0.025 * vid_conheight, mySize_y);
 486
 487         // do another pos check, as size might have changed by now
 488         if(resizeCorner == 1) {
 489                 myPos_x = resizeorigin_x - mySize_x;
 490                 myPos_y = resizeorigin_y - mySize_y;
 491         } else if(resizeCorner == 2) {
 492                 myPos_x = resizeorigin_x;
 493                 myPos_y = resizeorigin_y - mySize_y;
 494         } else if(resizeCorner == 3) {
 495                 myPos_x = resizeorigin_x - mySize_x;
 496                 myPos_y = resizeorigin_y;
 497         } else { // resizeCorner == 4
 498                 myPos_x = resizeorigin_x;
 499                 myPos_y = resizeorigin_y;
 500         }
 501
 502         //if(cvar("hud_configure_checkcollisions_debug"))
 503                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 504
 505         HUD_Panel_GetName(highlightedPanel);
 506         string s;
 507         s = strcat(ftos(mySize_x/vid_conwidth), " ", ftos(mySize_y/vid_conheight));
 508         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 509
 510         s = strcat(ftos(myPos_x/vid_conwidth), " ", ftos(myPos_y/vid_conheight));
 511         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 512 }
 513
 514 float pressed_key_time;
 515 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 516 void HUD_Panel_Arrow_Action(float nPrimary)
 517 {
 518         if (highlightedPanel == -1)
 519                 return;
 520
 521         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 522
 523         float step;
 524         if(autocvar_hud_configure_grid)
 525         {
 526                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 527                 {
 528                         if (hudShiftState & S_SHIFT)
 529                                 step = hud_configure_realGridSize_y;
 530                         else
 531                                 step = 2 * hud_configure_realGridSize_y;
 532                 }
 533                 else
 534                 {
 535                         if (hudShiftState & S_SHIFT)
 536                                 step = hud_configure_realGridSize_x;
 537                         else
 538                                 step = 2 * hud_configure_realGridSize_x;
 539                 }
 540         }
 541         else
 542         {
 543                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 544                         step = vid_conheight;
 545                 else
 546                         step = vid_conwidth;
 547                 if (hudShiftState & S_SHIFT)
 548                         step = (step / 256); // more precision
 549                 else
 550                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 551         }
 552
 553         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 554
 555         highlightedPanel_initial_pos = panel_pos;
 556         highlightedPanel_initial_size = panel_size;
 557
 558         if (hudShiftState & S_ALT) // resize
 559         {
 560                 highlightedAction = 1;
 561                 if(nPrimary == K_UPARROW)
 562                         resizeCorner = 1;
 563                 else if(nPrimary == K_RIGHTARROW)
 564                         resizeCorner = 2;
 565                 else if(nPrimary == K_LEFTARROW)
 566                         resizeCorner = 3;
 567                 else // if(nPrimary == K_DOWNARROW)
 568                         resizeCorner = 4;
 569
 570                 // ctrl+arrow reduces the size, instead of increasing it
 571                 // Note that ctrl disables collisions check too, but it's fine
 572                 // since we don't collide with anything reducing the size
 573                 if (hudShiftState & S_CTRL) {
 574                         step = -step;
 575                         resizeCorner = 5 - resizeCorner;
 576                 }
 577
 578                 vector mySize;
 579                 mySize = panel_size;
 580                 panel_click_resizeorigin = panel_pos;
 581                 if(resizeCorner == 1) {
 582                         panel_click_resizeorigin += mySize;
 583                         mySize_y += step;
 584                 } else if(resizeCorner == 2) {
 585                         panel_click_resizeorigin_y += mySize_y;
 586                         mySize_x += step;
 587                 } else if(resizeCorner == 3) {
 588                         panel_click_resizeorigin_x += mySize_x;
 589                         mySize_x += step;
 590                 } else { // resizeCorner == 4
 591                         mySize_y += step;
 592                 }
 593                 HUD_Panel_SetPosSize(mySize);
 594         }
 595         else // move
 596         {
 597                 highlightedAction = 2;
 598                 vector pos;
 599                 pos = panel_pos;
 600                 if(nPrimary == K_UPARROW)
 601                         pos_y -= step;
 602                 else if(nPrimary == K_DOWNARROW)
 603                         pos_y += step;
 604                 else if(nPrimary == K_LEFTARROW)
 605                         pos_x -= step;
 606                 else // if(nPrimary == K_RIGHTARROW)
 607                         pos_x += step;
 608
 609                 HUD_Panel_SetPos(pos);
 610         }
 611
 612         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 613
 614         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 615         {
 616                 // backup!
 617                 panel_pos_backup = highlightedPanel_initial_pos;
 618                 panel_size_backup = highlightedPanel_initial_size;
 619                 highlightedPanel_backup = highlightedPanel;
 620         }
 621 }
 622
 623 const float S_MOUSE1 = 1;
 624 const float S_MOUSE2 = 2;
 625 const float S_MOUSE3 = 4;
 626 float mouseClicked;
 627 float prevMouseClicked; // previous state
 628 float prevMouseClickedTime; // time during previous left mouse click, to check for doubleclicks
 629 vector prevMouseClickedPos; // pos during previous left mouse click, to check for doubleclicks
 630
 631 void HUD_Panel_EnableMenu();
 632 float tab_panels[HUD_PANEL_NUM];
 633 float tab_panel, tab_backward;
 634 vector tab_panel_pos;
 635 void HUD_Panel_FirstInDrawQ(float id);
 636 void reset_tab_panels()
 637 {
 638         int i;
 639         for(i = 0; i < HUD_PANEL_NUM; ++i)
 640                 tab_panels[i] = -1;
 641 }
 642 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 643 {
 644         string s;
 645
 646         if(bInputType == 2)
 647                 return false;
 648
 649         if(!autocvar__hud_configure)
 650                 return false;
 651
 652         // block any input while a menu dialog is fading
 653         if(autocvar__menu_alpha)
 654                 return true;
 655
 656         if(bInputType == 3)
 657         {
 658                 mousepos_x = nPrimary;
 659                 mousepos_y = nSecondary;
 660                 return true;
 661         }
 662
 663         // allow console bind to work
 664         string con_keys;
 665         float keys;
 666         con_keys = findkeysforcommand("toggleconsole", 0);
 667         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 668
 669         float hit_con_bind = 0, i;
 670         for (i = 0; i < keys; ++i)
 671         {
 672                 if(nPrimary == stof(argv(i)))
 673                         hit_con_bind = 1;
 674         }
 675
 676         if(bInputType == 0) {
 677                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 678                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 679                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 680         }
 681         else if(bInputType == 1) {
 682                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 683                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 684                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 685         }
 686
 687         if(nPrimary == K_CTRL)
 688         {
 689                 if (bInputType == 1) //ctrl has been released
 690                 {
 691                         if (tab_panel != -1)
 692                         {
 693                                 //switch to selected panel
 694                                 highlightedPanel = tab_panel;
 695                                 highlightedAction = 0;
 696                                 HUD_Panel_FirstInDrawQ(highlightedPanel);
 697                         }
 698                         tab_panel = -1;
 699                         reset_tab_panels();
 700                 }
 701         }
 702
 703         if(nPrimary == K_MOUSE1)
 704         {
 705                 if(bInputType == 0) // key pressed
 706                         mouseClicked |= S_MOUSE1;
 707                 else if(bInputType == 1) // key released
 708                         mouseClicked -= (mouseClicked & S_MOUSE1);
 709         }
 710         else if(nPrimary == K_MOUSE2)
 711         {
 712                 if(bInputType == 0) // key pressed
 713                         mouseClicked |= S_MOUSE2;
 714                 else if(bInputType == 1) // key released
 715                         mouseClicked -= (mouseClicked & S_MOUSE2);
 716         }
 717         else if(nPrimary == K_ESCAPE)
 718         {
 719                 if (bInputType == 1)
 720                         return true;
 721                 menu_enabled = 1;
 722                 menu_enabled_time = time;
 723                 localcmd("menu_showhudexit\n");
 724         }
 725         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
 726         {
 727                 if (bInputType == 1)
 728                         return true;
 729                 if (!menu_enabled)
 730                         cvar_set("_hud_configure", "0");
 731         }
 732         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // select and highlight another panel
 733         {
 734                 if (bInputType == 1 || mouseClicked)
 735                         return true;
 736
 737                 //FIXME: if a panel is highlighted, has the same pos_x and lays in the same level
 738                 //of other panels then next consecutive ctrl-tab will select the highlighted panel too
 739                 //(it should only after every other panel of the hud)
 740                 //It's a minor bug anyway, we can live with it
 741
 742                 float starting_panel;
 743                 float old_tab_panel = tab_panel;
 744                 if (tab_panel == -1) //first press of TAB
 745                 {
 746                         if (highlightedPanel != -1)
 747                                 HUD_Panel_UpdatePosSizeForId(highlightedPanel)
 748                         else
 749                                 panel_pos = '0 0 0';
 750                         starting_panel = highlightedPanel; //can be -1, it means no starting panel
 751                         tab_panel_pos = panel_pos; //to compute level
 752                 }
 753                 else
 754                 {
 755                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 756                                 reset_tab_panels();
 757                         starting_panel = tab_panel;
 758                 }
 759                 tab_backward = (hudShiftState & S_SHIFT);
 760
 761                 float k, level = 0, start_pos_x;
 762                 vector candidate_pos = '0 0 0';
 763                 const float LEVELS_NUM = 4;
 764                 float level_height = vid_conheight / LEVELS_NUM;
 765 :find_tab_panel
 766                 level = floor(tab_panel_pos_y / level_height) * level_height; //starting level
 767                 candidate_pos_x = (!tab_backward) ? vid_conwidth : 0;
 768                 start_pos_x = tab_panel_pos_x;
 769                 tab_panel = -1;
 770                 k=0;
 771                 while(++k)
 772                 {
 773                         for(i = 0; i < HUD_PANEL_NUM; ++i)
 774                         {
 775                                 if (i == tab_panels[i] || i == starting_panel)
 776                                         continue;
 777                                 HUD_Panel_UpdatePosSizeForId(i)
 778                                 if (panel_pos_y >= level && (panel_pos_y - level) < level_height)
 779                                 if (  ( !tab_backward && panel_pos_x >= start_pos_x && (panel_pos_x < candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y <= candidate_pos_y)) )
 780                                         || ( tab_backward && panel_pos_x <= start_pos_x && (panel_pos_x > candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y >= candidate_pos_y)) )  )
 781                                 {
 782                                         tab_panel = i;
 783                                         tab_panel_pos = candidate_pos = panel_pos;
 784                                 }
 785                         }
 786                         if (tab_panel != -1)
 787                                 break;
 788                         if (k == LEVELS_NUM) //tab_panel not found
 789                         {
 790                                 reset_tab_panels();
 791                                 if (old_tab_panel == -2) //this prevents an infinite loop (should not happen normally)
 792                                 {
 793                                         tab_panel = -1;
 794                                         return true;
 795                                 }
 796                                 starting_panel = old_tab_panel;
 797                                 old_tab_panel = -2;
 798                                 goto find_tab_panel; //u must find tab_panel!
 799                         }
 800                         if (!tab_backward)
 801                         {
 802                                 level = mod(level + level_height, vid_conheight);
 803                                 start_pos_x = 0;
 804                                 candidate_pos_x = vid_conwidth;
 805                         }
 806                         else
 807                         {
 808                                 level = mod(level - level_height, vid_conheight);
 809                                 start_pos_x = vid_conwidth;
 810                                 candidate_pos_x = 0;
 811                         }
 812                 }
 813
 814                 tab_panels[tab_panel] = tab_panel;
 815         }
 816         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 817         {
 818                 if (bInputType == 1 || mouseClicked)
 819                         return true;
 820
 821                 if (highlightedPanel != -1)
 822                 {
 823                         HUD_Panel_GetName(highlightedPanel);
 824                         cvar_set(strcat("hud_panel_", panel_name), ftos(!(panel_enabled)));
 825                 }
 826                 else
 827                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 828         }
 829         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 830         {
 831                 if (bInputType == 1 || mouseClicked)
 832                         return true;
 833
 834                 if (highlightedPanel != -1)
 835                 {
 836                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 837                         panel_size_copied = panel_size;
 838                         highlightedPanel_copied = highlightedPanel;
 839                 }
 840         }
 841         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 842         {
 843                 if (bInputType == 1 || mouseClicked)
 844                         return true;
 845
 846                 if (highlightedPanel_copied == -1 || highlightedPanel == -1)
 847                         return true;
 848
 849                 HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 850
 851                 // reduce size if it'd go beyond screen boundaries
 852                 vector tmp_size = panel_size_copied;
 853                 if (panel_pos_x + panel_size_copied_x > vid_conwidth)
 854                         tmp_size_x = vid_conwidth - panel_pos_x;
 855                 if (panel_pos_y + panel_size_copied_y > vid_conheight)
 856                         tmp_size_y = vid_conheight - panel_pos_y;
 857
 858                 if (panel_size == tmp_size)
 859                         return true;
 860
 861                 // backup first!
 862                 panel_pos_backup = panel_pos;
 863                 panel_size_backup = panel_size;
 864                 highlightedPanel_backup = highlightedPanel;
 865
 866                 s = strcat(ftos(tmp_size_x/vid_conwidth), " ", ftos(tmp_size_y/vid_conheight));
 867                 HUD_Panel_GetName(highlightedPanel);
 868                 cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 869         }
 870         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 871         {
 872                 if (bInputType == 1 || mouseClicked)
 873                         return true;
 874                 //restore previous values
 875                 if (highlightedPanel_backup != -1)
 876                 {
 877                         HUD_Panel_GetName(highlightedPanel_backup);
 878                         s = strcat(ftos(panel_pos_backup_x/vid_conwidth), " ", ftos(panel_pos_backup_y/vid_conheight));
 879                         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 880                         s = strcat(ftos(panel_size_backup_x/vid_conwidth), " ", ftos(panel_size_backup_y/vid_conheight));
 881                         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 882                         highlightedPanel_backup = -1;
 883                 }
 884         }
 885         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 886         {
 887                 if (bInputType == 1)
 888                 {
 889                         pressed_key_time = 0;
 890                         return true;
 891                 }
 892                 else if (pressed_key_time == 0)
 893                         pressed_key_time = time;
 894
 895                 if (!mouseClicked)
 896                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 897         }
 898         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 899         {
 900                 if (bInputType == 1)
 901                         return true;
 902                 if (highlightedPanel != -1)
 903                         HUD_Panel_EnableMenu();
 904         }
 905         else if(hit_con_bind)
 906                 return false;
 907
 908         return true;
 909 }
 910
 911 float HUD_Panel_Check_Mouse_Pos(float allow_move)
 912 {
 913         float i, j = 0, border;
 914
 915         while(j < HUD_PANEL_NUM)
 916         {
 917                 i = panel_order[j];
 918                 j += 1;
 919
 920                 HUD_Panel_UpdatePosSizeForId(i);
 921
 922                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 923
 924                 // move
 925                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
 926                 {
 927                         return 1;
 928                 }
 929                 // resize from topleft border
 930                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 931                 {
 932                         return 2;
 933                 }
 934                 // resize from topright border
 935                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 936                 {
 937                         return 3;
 938                 }
 939                 // resize from bottomleft border
 940                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
 941                 {
 942                         return 3;
 943                 }
 944                 // resize from bottomright border
 945                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
 946                 {
 947                         return 2;
 948                 }
 949         }
 950         return 0;
 951 }
 952
 953 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 954 void HUD_Panel_FirstInDrawQ(float id)
 955 {
 956         float i;
 957         var float place = -1;
 958         // find out where in the array our current id is, save into place
 959         for(i = 0; i < HUD_PANEL_NUM; ++i)
 960         {
 961                 if(panel_order[i] == id)
 962                 {
 963                         place = i;
 964                         break;
 965                 }
 966         }
 967         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 968         if(place == -1)
 969                 place = HUD_PANEL_NUM - 1;
 970
 971         // move all ids up by one step in the array until "place"
 972         for(i = place; i > 0; --i)
 973         {
 974                 panel_order[i] = panel_order[i-1];
 975         }
 976         // now save the new top id
 977         panel_order[0] = id;
 978
 979         // let's save them into the cvar by some strcat trickery
 980         string s = "";
 981         for(i = 0; i < HUD_PANEL_NUM; ++i)
 982         {
 983                 s = strcat(s, ftos(panel_order[i]), " ");
 984         }
 985         cvar_set("_hud_panelorder", s);
 986         if(hud_panelorder_prev)
 987                 strunzone(hud_panelorder_prev);
 988         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
 989 }
 990
 991 void HUD_Panel_Highlight(float allow_move)
 992 {
 993         float i, j = 0, border;
 994
 995         while(j < HUD_PANEL_NUM)
 996         {
 997                 i = panel_order[j];
 998                 j += 1;
 999
1000                 HUD_Panel_UpdatePosSizeForId(i);
1001
1002                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
1003
1004                 // move
1005                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
1006                 {
1007                         highlightedPanel = i;
1008                         HUD_Panel_FirstInDrawQ(i);
1009                         highlightedAction = 1;
1010                         panel_click_distance = mousepos - panel_pos;
1011                         return;
1012                 }
1013                 // resize from topleft border
1014                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1015                 {
1016                         highlightedPanel = i;
1017                         HUD_Panel_FirstInDrawQ(i);
1018                         highlightedAction = 2;
1019                         resizeCorner = 1;
1020                         panel_click_distance = mousepos - panel_pos;
1021                         panel_click_resizeorigin = panel_pos + panel_size;
1022                         return;
1023                 }
1024                 // resize from topright border
1025                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1026                 {
1027                         highlightedPanel = i;
1028                         HUD_Panel_FirstInDrawQ(i);
1029                         highlightedAction = 2;
1030                         resizeCorner = 2;
1031                         panel_click_distance_x = panel_size_x - mousepos_x + panel_pos_x;
1032                         panel_click_distance_y = mousepos_y - panel_pos_y;
1033                         panel_click_resizeorigin = panel_pos + eY * panel_size_y;
1034                         return;
1035                 }
1036                 // resize from bottomleft border
1037                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
1038                 {
1039                         highlightedPanel = i;
1040                         HUD_Panel_FirstInDrawQ(i);
1041                         highlightedAction = 2;
1042                         resizeCorner = 3;
1043                         panel_click_distance_x = mousepos_x - panel_pos_x;
1044                         panel_click_distance_y = panel_size_y - mousepos_y + panel_pos_y;
1045                         panel_click_resizeorigin = panel_pos + eX * panel_size_x;
1046                         return;
1047                 }
1048                 // resize from bottomright border
1049                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
1050                 {
1051                         highlightedPanel = i;
1052                         HUD_Panel_FirstInDrawQ(i);
1053                         highlightedAction = 2;
1054                         resizeCorner = 4;
1055                         panel_click_distance = panel_size - mousepos + panel_pos;
1056                         panel_click_resizeorigin = panel_pos;
1057                         return;
1058                 }
1059         }
1060         highlightedPanel = -1;
1061         highlightedAction = 0;
1062 }
1063
1064 void HUD_Panel_EnableMenu()
1065 {
1066         menu_enabled = 2;
1067         menu_enabled_time = time;
1068         HUD_Panel_GetName(highlightedPanel);
1069         localcmd("menu_showhudoptions ", panel_name, "\n");
1070 }
1071 float mouse_over_panel;
1072 void HUD_Panel_Mouse()
1073 {
1074         // TODO: needs better check... is there any float that contains the current state of the menu? _menu_alpha isn't apparently updated the frame the menu gets enabled
1075         if (autocvar__menu_alpha == 0 && time - menu_enabled_time > 0.5)
1076                 menu_enabled = 0;
1077
1078         /*
1079         print("menu_enabled: ", ftos(menu_enabled), "\n");
1080         print("Highlighted: ", ftos(highlightedPanel), "\n");
1081         print("Menu theAlpha: ", ftos(autocvar__menu_alpha), "\n");
1082         */
1083
1084         if(autocvar__menu_alpha == 1)
1085                 return;
1086
1087         if not(autocvar_hud_cursormode)
1088         {
1089                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
1090
1091                 mousepos_x = bound(0, mousepos_x, vid_conwidth);
1092                 mousepos_y = bound(0, mousepos_y, vid_conheight);
1093         }
1094
1095         if(mouseClicked)
1096         {
1097                 if(prevMouseClicked == 0)
1098                 {
1099                         if (tab_panel != -1)
1100                         {
1101                                 //stop ctrl-tab selection
1102                                 tab_panel = -1;
1103                                 reset_tab_panels();
1104                         }
1105                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1106                                                                         // and calls HUD_Panel_UpdatePosSizeForId() for the highlighted panel
1107                         if (highlightedPanel != -1)
1108                         {
1109                                 highlightedPanel_initial_pos = panel_pos;
1110                                 highlightedPanel_initial_size = panel_size;
1111                         }
1112                         // doubleclick check
1113                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel != -1 && prevMouseClickedPos == mousepos)
1114                         {
1115                                 mouseClicked = 0; // to prevent spam, I guess.
1116                                 HUD_Panel_EnableMenu();
1117                         }
1118                         else
1119                         {
1120                                 if (mouseClicked & S_MOUSE1)
1121                                 {
1122                                         prevMouseClickedTime = time;
1123                                         prevMouseClickedPos = mousepos;
1124                                 }
1125                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1126                         }
1127                 }
1128                 else
1129                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
1130
1131                 if (highlightedPanel != -1)
1132                 {
1133                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1134                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1135                         {
1136                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1137                                 // backup!
1138                                 panel_pos_backup = highlightedPanel_initial_pos;
1139                                 panel_size_backup = highlightedPanel_initial_size;
1140                                 highlightedPanel_backup = highlightedPanel;
1141                         }
1142                         else
1143                                 // in case the clicked panel is inside another panel and we aren't
1144                                 // moving it, avoid the immediate "fix" of its position/size
1145                                 // (often unwanted and hateful) by disabling collisions check
1146                                 hud_configure_checkcollisions = false;
1147                 }
1148
1149                 if(highlightedAction == 1)
1150                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1151                 else if(highlightedAction == 2)
1152                 {
1153                         vector mySize = '0 0 0';
1154                         if(resizeCorner == 1) {
1155                                 mySize_x = panel_click_resizeorigin_x - (mousepos_x - panel_click_distance_x);
1156                                 mySize_y = panel_click_resizeorigin_y - (mousepos_y - panel_click_distance_y);
1157                         } else if(resizeCorner == 2) {
1158                                 mySize_x = mousepos_x + panel_click_distance_x - panel_click_resizeorigin_x;
1159                                 mySize_y = panel_click_distance_y + panel_click_resizeorigin_y - mousepos_y;
1160                         } else if(resizeCorner == 3) {
1161                                 mySize_x = panel_click_resizeorigin_x + panel_click_distance_x - mousepos_x;
1162                                 mySize_y = mousepos_y + panel_click_distance_y - panel_click_resizeorigin_y;
1163                         } else { // resizeCorner == 4
1164                                 mySize_x = mousepos_x - (panel_click_resizeorigin_x - panel_click_distance_x);
1165                                 mySize_y = mousepos_y - (panel_click_resizeorigin_y - panel_click_distance_y);
1166                         }
1167                         HUD_Panel_SetPosSize(mySize);
1168                 }
1169         }
1170         else
1171         {
1172                 if(menu_enabled == 2)
1173                         mouse_over_panel = 0;
1174                 else
1175                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(TRUE);
1176                 if (mouse_over_panel && tab_panel == -1)
1177                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1178         }
1179         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1180         const vector cursorsize = '32 32 0';
1181         float cursor_alpha = 1 - autocvar__menu_alpha;
1182
1183         if(!mouse_over_panel)
1184                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1185         else if(mouse_over_panel == 1)
1186                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1187         else if(mouse_over_panel == 2)
1188                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1189         else
1190                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1191
1192         prevMouseClicked = mouseClicked;
1193 }
1194
1195 const float hlBorderSize = 4;
1196 const string hlBorder = "gfx/hud/default/border_highlighted";
1197 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1198 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1199 {
1200         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1201         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1202         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size_y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1203         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1204         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size_x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1205 }