qcsrc/client/hud.qc

   1 /*
   2 ==================
   3 Misc HUD functions
   4 ==================
   5 */
   6
   7 // a border picture is a texture containing nine parts:
   8 //   1/4 width: left part
   9 //   1/2 width: middle part (stretched)
  10 //   1/4 width: right part
  11 // divided into
  12 //   1/4 height: top part
  13 //   1/2 height: middle part (stretched)
  14 //   1/4 height: bottom part
  15 void draw_BorderPicture(vector theOrigin, string pic, vector theSize, vector theColor, float theAlpha, vector theBorderSize)
  16 {
  17     if (theBorderSize_x < 0 && theBorderSize_y < 0) // draw whole image as it is
  18     {
  19                 drawpic(theOrigin, pic, theSize, theColor, theAlpha, 0);
  20                 return;
  21     }
  22         if (theBorderSize_x == 0 && theBorderSize_y == 0) // no border
  23         {
  24                 // draw only the central part
  25                 drawsubpic(theOrigin, theSize, pic, '0.25 0.25 0', '0.5 0.5 0', theColor, theAlpha, 0);
  26                 return;
  27         }
  28
  29         vector dX, dY;
  30         vector width, height;
  31         vector bW, bH;
  32         //pic = draw_UseSkinFor(pic);
  33         width = eX * theSize_x;
  34         height = eY * theSize_y;
  35         if(theSize_x <= theBorderSize_x * 2)
  36         {
  37                 // not wide enough... draw just left and right then
  38                 bW = eX * (0.25 * theSize_x / (theBorderSize_x * 2));
  39                 if(theSize_y <= theBorderSize_y * 2)
  40                 {
  41                         // not high enough... draw just corners
  42                         bH = eY * (0.25 * theSize_y / (theBorderSize_y * 2));
  43                         drawsubpic(theOrigin,                 width * 0.5 + height * 0.5, pic, '0 0 0',           bW + bH, theColor, theAlpha, 0);
  44                         drawsubpic(theOrigin + width   * 0.5, width * 0.5 + height * 0.5, pic, eX - bW,           bW + bH, theColor, theAlpha, 0);
  45                         drawsubpic(theOrigin + height  * 0.5, width * 0.5 + height * 0.5, pic, eY - bH,           bW + bH, theColor, theAlpha, 0);
  46                         drawsubpic(theOrigin + theSize * 0.5, width * 0.5 + height * 0.5, pic, eX + eY - bW - bH, bW + bH, theColor, theAlpha, 0);
  47                 }
  48                 else
  49                 {
  50                         dY = theBorderSize_x * eY;
  51                         drawsubpic(theOrigin,                             width * 0.5          +     dY, pic, '0 0    0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  52                         drawsubpic(theOrigin + width * 0.5,               width * 0.5          +     dY, pic, '0 0    0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  53                         drawsubpic(theOrigin                        + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0',           '0 0.5  0' + bW, theColor, theAlpha, 0);
  54                         drawsubpic(theOrigin + width * 0.5          + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0' + eX - bW, '0 0.5  0' + bW, theColor, theAlpha, 0);
  55                         drawsubpic(theOrigin               + height - dY, width * 0.5          +     dY, pic, '0 0.75 0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  56                         drawsubpic(theOrigin + width * 0.5 + height - dY, width * 0.5          +     dY, pic, '0 0.75 0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  57                 }
  58         }
  59         else
  60         {
  61                 if(theSize_y <= theBorderSize_y * 2)
  62                 {
  63                         // not high enough... draw just top and bottom then
  64                         bH = eY * (0.25 * theSize_y / (theBorderSize_y * 2));
  65                         dX = theBorderSize_x * eX;
  66                         drawsubpic(theOrigin,                                         dX + height * 0.5, pic, '0    0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  67                         drawsubpic(theOrigin + dX,                        width - 2 * dX + height * 0.5, pic, '0.25 0 0',           '0.5  0 0' + bH, theColor, theAlpha, 0);
  68                         drawsubpic(theOrigin + width - dX,                            dX + height * 0.5, pic, '0.75 0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  69                         drawsubpic(theOrigin              + height * 0.5,             dX + height * 0.5, pic, '0    0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  70                         drawsubpic(theOrigin + dX         + height * 0.5, width - 2 * dX + height * 0.5, pic, '0.25 0 0' + eY - bH, '0.5  0 0' + bH, theColor, theAlpha, 0);
  71                         drawsubpic(theOrigin + width - dX + height * 0.5,             dX + height * 0.5, pic, '0.75 0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  72                 }
  73                 else
  74                 {
  75                         dX = theBorderSize_x * eX;
  76                         dY = theBorderSize_x * eY;
  77                         drawsubpic(theOrigin,                                        dX          +     dY, pic, '0    0    0', '0.25 0.25 0', theColor, theAlpha, 0);
  78                         drawsubpic(theOrigin                  + dX,      width - 2 * dX          +     dY, pic, '0.25 0    0', '0.5  0.25 0', theColor, theAlpha, 0);
  79                         drawsubpic(theOrigin          + width - dX,                  dX          +     dY, pic, '0.75 0    0', '0.25 0.25 0', theColor, theAlpha, 0);
  80                         drawsubpic(theOrigin          + dY,                          dX + height - 2 * dY, pic, '0    0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
  81                         drawsubpic(theOrigin          + dY         + dX, width - 2 * dX + height - 2 * dY, pic, '0.25 0.25 0', '0.5  0.5  0', theColor, theAlpha, 0);
  82                         drawsubpic(theOrigin          + dY + width - dX,             dX + height - 2 * dY, pic, '0.75 0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
  83                         drawsubpic(theOrigin + height - dY,                          dX          +     dY, pic, '0    0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
  84                         drawsubpic(theOrigin + height - dY         + dX, width - 2 * dX          +     dY, pic, '0.25 0.75 0', '0.5  0.25 0', theColor, theAlpha, 0);
  85                         drawsubpic(theOrigin + height - dY + width - dX,             dX          +     dY, pic, '0.75 0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
  86                 }
  87         }
  88 }
  89
  90 vector HUD_Get_Num_Color (float x, float maxvalue)
  91 {
  92         float blinkingamt;
  93         vector color;
  94         if(x >= maxvalue) {
  95                 color_x = sin(2*M_PI*time);
  96                 color_y = 1;
  97                 color_z = sin(2*M_PI*time);
  98         }
  99         else if(x > maxvalue * 0.75) {
 100                 color_x = 0.4 - (x-150)*0.02 * 0.4; //red value between 0.4 -> 0
 101                 color_y = 0.9 + (x-150)*0.02 * 0.1; // green value between 0.9 -> 1
 102                 color_z = 0;
 103         }
 104         else if(x > maxvalue * 0.5) {
 105                 color_x = 1 - (x-100)*0.02 * 0.6; //red value between 1 -> 0.4
 106                 color_y = 1 - (x-100)*0.02 * 0.1; // green value between 1 -> 0.9
 107                 color_z = 1 - (x-100)*0.02; // blue value between 1 -> 0
 108         }
 109         else if(x > maxvalue * 0.25) {
 110                 color_x = 1;
 111                 color_y = 1;
 112                 color_z = 0.2 + (x-50)*0.02 * 0.8; // blue value between 0.2 -> 1
 113         }
 114         else if(x > maxvalue * 0.1) {
 115                 color_x = 1;
 116                 color_y = (x-20)*90/27/100; // green value between 0 -> 1
 117                 color_z = (x-20)*90/27/100 * 0.2; // blue value between 0 -> 0.2
 118         }
 119         else {
 120                 color_x = 1;
 121                 color_y = 0;
 122                 color_z = 0;
 123         }
 124
 125         blinkingamt = (1 - x/maxvalue/0.25);
 126         if(blinkingamt > 0)
 127         {
 128                 color_x = color_x - color_x * blinkingamt * sin(2*M_PI*time);
 129                 color_y = color_y - color_y * blinkingamt * sin(2*M_PI*time);
 130                 color_z = color_z - color_z * blinkingamt * sin(2*M_PI*time);
 131         }
 132         return color;
 133 }
 134
 135 float stringwidth_colors(string s, vector theSize)
 136 {
 137         return stringwidth(s, TRUE, theSize);
 138 }
 139
 140 float stringwidth_nocolors(string s, vector theSize)
 141 {
 142         return stringwidth(s, FALSE, theSize);
 143 }
 144
 145 void drawstringright(vector position, string text, vector theScale, vector rgb, float theAlpha, float flag)
 146 {
 147         position_x -= 2 / 3 * strlen(text) * theScale_x;
 148         drawstring(position, text, theScale, rgb, theAlpha, flag);
 149 }
 150
 151 void drawstringcenter(vector position, string text, vector theScale, vector rgb, float theAlpha, float flag)
 152 {
 153         position_x = 0.5 * (vid_conwidth - 0.6025 * strlen(text) * theScale_x);
 154         drawstring(position, text, theScale, rgb, theAlpha, flag);
 155 }
 156
 157 // return the string of the onscreen race timer
 158 string MakeRaceString(float cp, float mytime, float histime, float lapdelta, string hisname)
 159 {
 160         string col;
 161         string timestr;
 162         string cpname;
 163         string lapstr;
 164         lapstr = "";
 165
 166         if(histime == 0) // goal hit
 167         {
 168                 if(mytime > 0)
 169                 {
 170                         timestr = strcat("+", ftos_decimals(+mytime, TIME_DECIMALS));
 171                         col = "^1";
 172                 }
 173                 else if(mytime == 0)
 174                 {
 175                         timestr = "+0.0";
 176                         col = "^3";
 177                 }
 178                 else
 179                 {
 180                         timestr = strcat("-", ftos_decimals(-mytime, TIME_DECIMALS));
 181                         col = "^2";
 182                 }
 183
 184                 if(lapdelta > 0)
 185                 {
 186                         lapstr = sprintf(_(" (-%dL)"), lapdelta);
 187                         col = "^2";
 188                 }
 189                 else if(lapdelta < 0)
 190                 {
 191                         lapstr = sprintf(_(" (+%dL)"), -lapdelta);
 192                         col = "^1";
 193                 }
 194         }
 195         else if(histime > 0) // anticipation
 196         {
 197                 if(mytime >= histime)
 198                         timestr = strcat("+", ftos_decimals(mytime - histime, TIME_DECIMALS));
 199                 else
 200                         timestr = TIME_ENCODED_TOSTRING(TIME_ENCODE(histime));
 201                 col = "^3";
 202         }
 203         else
 204         {
 205                 col = "^7";
 206                 timestr = "";
 207         }
 208
 209         if(cp == 254)
 210                 cpname = _("Start line");
 211         else if(cp == 255)
 212                 cpname = _("Finish line");
 213         else if(cp)
 214                 cpname = sprintf(_("Intermediate %d"), cp);
 215         else
 216                 cpname = _("Finish line");
 217
 218         if(histime < 0)
 219                 return strcat(col, cpname);
 220         else if(hisname == "")
 221                 return strcat(col, sprintf(_("%s (%s)"), cpname, timestr));
 222         else
 223                 return strcat(col, sprintf(_("%s (%s %s)"), cpname, timestr, strcat(hisname, col, lapstr)));
 224 }
 225
 226 // Check if the given name already exist in race rankings? In that case, where? (otherwise return 0)
 227 float race_CheckName(string net_name) {
 228         float i;
 229         for (i=RANKINGS_CNT-1;i>=0;--i)
 230                 if(grecordholder[i] == net_name)
 231                         return i+1;
 232         return 0;
 233 }
 234
 235 float GetPlayerColorForce(float i)
 236 {
 237         if(!teamplay)
 238                 return 0;
 239         else
 240                 return stof(getplayerkeyvalue(i, "colors")) & 15;
 241 }
 242
 243 float GetPlayerColor(float i)
 244 {
 245         if(!playerslots[i].gotscores) // unconnected
 246                 return NUM_SPECTATOR;
 247         else if(stof(getplayerkeyvalue(i, "frags")) == FRAGS_SPECTATOR)
 248                 return NUM_SPECTATOR;
 249         else
 250                 return GetPlayerColorForce(i);
 251 }
 252
 253 string GetPlayerName(float i)
 254 {
 255         return ColorTranslateRGB(getplayerkeyvalue(i, "name"));
 256 }
 257
 258
 259 /*
 260 ==================
 261 HUD panels
 262 ==================
 263 */
 264
 265 // draw the background/borders
 266 #define HUD_Panel_DrawBg(theAlpha)\
 267 if(panel.current_panel_bg != "0" && panel.current_panel_bg != "")\
 268         draw_BorderPicture(panel_pos - '1 1 0' * panel_bg_border, panel.current_panel_bg, panel_size + '1 1 0' * 2 * panel_bg_border, panel_bg_color, panel_bg_alpha * theAlpha, '1 1 0' * (panel_bg_border/BORDER_MULTIPLIER))
 269
 270 //basically the same code of draw_ButtonPicture and draw_VertButtonPicture for the menu
 271 void HUD_Panel_DrawProgressBar(vector theOrigin, vector theSize, string pic, float length_ratio, float vertical, float baralign, vector theColor, float theAlpha, float drawflag)
 272 {
 273         if(!length_ratio || !theAlpha)
 274                 return;
 275         if(length_ratio > 1)
 276                 length_ratio = 1;
 277         if (baralign == 3)
 278         {
 279                 if(length_ratio < -1)
 280                         length_ratio = -1;
 281         }
 282         else if(length_ratio < 0)
 283                 return;
 284
 285         vector square;
 286         vector width, height;
 287         if(vertical) {
 288                 pic = strcat(hud_skin_path, "/", pic, "_vertical");
 289                 if(precache_pic(pic) == "") {
 290                         pic = "gfx/hud/default/progressbar_vertical";
 291                 }
 292
 293         if (baralign == 1) // bottom align
 294                         theOrigin_y += (1 - length_ratio) * theSize_y;
 295         else if (baralign == 2) // center align
 296             theOrigin_y += 0.5 * (1 - length_ratio) * theSize_y;
 297         else if (baralign == 3) // center align, positive values down, negative up
 298                 {
 299                         theSize_y *= 0.5;
 300                         if (length_ratio > 0)
 301                                 theOrigin_y += theSize_y;
 302                         else
 303                         {
 304                                 theOrigin_y += (1 + length_ratio) * theSize_y;
 305                                 length_ratio = -length_ratio;
 306                         }
 307                 }
 308                 theSize_y *= length_ratio;
 309
 310                 vector bH;
 311                 width = eX * theSize_x;
 312                 height = eY * theSize_y;
 313                 if(theSize_y <= theSize_x * 2)
 314                 {
 315                         // button not high enough
 316                         // draw just upper and lower part then
 317                         square = eY * theSize_y * 0.5;
 318                         bH = eY * (0.25 * theSize_y / (theSize_x * 2));
 319                         drawsubpic(theOrigin,          square + width, pic, '0 0 0', eX + bH, theColor, theAlpha, drawflag);
 320                         drawsubpic(theOrigin + square, square + width, pic, eY - bH, eX + bH, theColor, theAlpha, drawflag);
 321                 }
 322                 else
 323                 {
 324                         square = eY * theSize_x;
 325                         drawsubpic(theOrigin,                   width   +     square, pic, '0 0    0', '1 0.25 0', theColor, theAlpha, drawflag);
 326                         drawsubpic(theOrigin +          square, theSize - 2 * square, pic, '0 0.25 0', '1 0.5  0', theColor, theAlpha, drawflag);
 327                         drawsubpic(theOrigin + height - square, width   +     square, pic, '0 0.75 0', '1 0.25 0', theColor, theAlpha, drawflag);
 328                 }
 329         } else {
 330                 pic = strcat(hud_skin_path, "/", pic);
 331                 if(precache_pic(pic) == "") {
 332                         pic = "gfx/hud/default/progressbar";
 333                 }
 334
 335                 if (baralign == 1) // right align
 336                         theOrigin_x += (1 - length_ratio) * theSize_x;
 337         else if (baralign == 2) // center align
 338             theOrigin_x += 0.5 * (1 - length_ratio) * theSize_x;
 339         else if (baralign == 3) // center align, positive values on the right, negative on the left
 340                 {
 341                         theSize_x *= 0.5;
 342                         if (length_ratio > 0)
 343                                 theOrigin_x += theSize_x;
 344                         else
 345                         {
 346                                 theOrigin_x += (1 + length_ratio) * theSize_x;
 347                                 length_ratio = -length_ratio;
 348                         }
 349                 }
 350                 theSize_x *= length_ratio;
 351
 352                 vector bW;
 353                 width = eX * theSize_x;
 354                 height = eY * theSize_y;
 355                 if(theSize_x <= theSize_y * 2)
 356                 {
 357                         // button not wide enough
 358                         // draw just left and right part then
 359                         square = eX * theSize_x * 0.5;
 360                         bW = eX * (0.25 * theSize_x / (theSize_y * 2));
 361                         drawsubpic(theOrigin,          square + height, pic, '0 0 0', eY + bW, theColor, theAlpha, drawflag);
 362                         drawsubpic(theOrigin + square, square + height, pic, eX - bW, eY + bW, theColor, theAlpha, drawflag);
 363                 }
 364                 else
 365                 {
 366                         square = eX * theSize_y;
 367                         drawsubpic(theOrigin,                  height  +     square, pic, '0    0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 368                         drawsubpic(theOrigin +         square, theSize - 2 * square, pic, '0.25 0 0', '0.5  1 0', theColor, theAlpha, drawflag);
 369                         drawsubpic(theOrigin + width - square, height  +     square, pic, '0.75 0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 370                 }
 371         }
 372 }
 373
 374 void HUD_Panel_DrawHighlight(vector pos, vector mySize, vector color, float theAlpha, float drawflag)
 375 {
 376         if(!theAlpha)
 377                 return;
 378
 379         string pic;
 380         pic = strcat(hud_skin_path, "/num_leading");
 381         if(precache_pic(pic) == "") {
 382                 pic = "gfx/hud/default/num_leading";
 383         }
 384
 385         drawsubpic(pos, eX * min(mySize_x * 0.5, mySize_y) + eY * mySize_y, pic, '0 0 0', '0.25 1 0', color, theAlpha, drawflag);
 386         if(mySize_x/mySize_y > 2)
 387                 drawsubpic(pos + eX * mySize_y, eX * (mySize_x - 2 * mySize_y) + eY * mySize_y, pic, '0.25 0 0', '0.5 1 0', color, theAlpha, drawflag);
 388         drawsubpic(pos + eX * mySize_x - eX * min(mySize_x * 0.5, mySize_y), eX * min(mySize_x * 0.5, mySize_y) + eY * mySize_y, pic, '0.75 0 0', '0.25 1 0', color, theAlpha, drawflag);
 389 }
 390
 391 // Weapon icons (#0)
 392 //
 393 entity weaponorder[WEP_MAXCOUNT];
 394 void weaponorder_swap(float i, float j, entity pass)
 395 {
 396         entity h;
 397         h = weaponorder[i];
 398         weaponorder[i] = weaponorder[j];
 399         weaponorder[j] = h;
 400 }
 401
 402 string weaponorder_cmp_str;
 403 float weaponorder_cmp(float i, float j, entity pass)
 404 {
 405         float ai, aj;
 406         ai = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[i].weapon), 0);
 407         aj = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[j].weapon), 0);
 408         return aj - ai; // the string is in REVERSE order (higher prio at the right is what we want, but higher prio first is the string)
 409 }
 410
 411 float GetAmmoStat(float i)
 412 {
 413         switch(i)
 414         {
 415                 case 0: return STAT_SHELLS;
 416                 case 1: return STAT_NAILS;
 417                 case 2: return STAT_ROCKETS;
 418                 case 3: return STAT_CELLS;
 419                 case 4: return STAT_FUEL;
 420                 default: return -1;
 421         }
 422 }
 423
 424 float GetAmmoTypeForWep(float i)
 425 {
 426         switch(i)
 427         {
 428                 case WEP_SHOTGUN: return 0;
 429                 case WEP_UZI: return 1;
 430                 case WEP_GRENADE_LAUNCHER: return 2;
 431                 case WEP_MINE_LAYER: return 2;
 432                 case WEP_ELECTRO: return 3;
 433                 case WEP_CRYLINK: return 3;
 434                 case WEP_HLAC: return 3;
 435                 case WEP_MINSTANEX: return 3;
 436                 case WEP_NEX: return 3;
 437                 case WEP_RIFLE: return 1;
 438                 case WEP_HAGAR: return 2;
 439                 case WEP_ROCKET_LAUNCHER: return 2;
 440                 case WEP_SEEKER: return 2;
 441                 case WEP_FIREBALL: return 4;
 442                 case WEP_HOOK: return 3;
 443                 default: return -1;
 444         }
 445 }
 446
 447 void HUD_Weapons(void)
 448 {
 449         // declarations
 450         WepSet weapons_stat = WepSet_GetFromStat();
 451         float i, f, a;
 452         float screen_ar, center_x = 0, center_y;
 453         float weapon_count, weapon_id;
 454         float row, column, rows = 0, columns;
 455         float aspect = autocvar_hud_panel_weapons_aspect;
 456
 457         float panel_weapon_accuracy;
 458
 459         float timeout = autocvar_hud_panel_weapons_timeout;
 460         float timein_effect_length = autocvar_hud_panel_weapons_timeout_speed_in; //? 0.375 : 0);
 461         float timeout_effect_length = autocvar_hud_panel_weapons_timeout_speed_out; //? 0.75 : 0);
 462
 463         float ammo_type, ammo_full;
 464         float barsize_x = 0, barsize_y = 0, baroffset_x = 0, baroffset_y = 0;
 465         vector ammo_color = '1 0 1';
 466         float ammo_alpha = 1;
 467
 468         float when = max(1, autocvar_hud_panel_weapons_complainbubble_time);
 469         float fadetime = max(0, autocvar_hud_panel_weapons_complainbubble_fadetime);
 470
 471         vector weapon_pos, weapon_size = '0 0 0';
 472         local noref vector old_panel_size; // fteqcc sucks
 473         vector color;
 474
 475         // check to see if we want to continue
 476         if(hud != HUD_NORMAL) { return; }
 477
 478         if(!autocvar__hud_configure)
 479         {
 480                 if((!autocvar_hud_panel_weapons) || (spectatee_status == -1))
 481                         return;
 482                 if(timeout && time >= weapontime + timeout + timeout_effect_length)
 483                 if(autocvar_hud_panel_weapons_timeout_effect == 3 || (autocvar_hud_panel_weapons_timeout_effect == 1 && !(autocvar_hud_panel_weapons_timeout_fadebgmin + autocvar_hud_panel_weapons_timeout_fadefgmin)))
 484                 {
 485                         weaponprevtime = time;
 486                         return;
 487                 }
 488         }
 489
 490         // update generic hud functions
 491         HUD_Panel_UpdateCvars();
 492
 493         draw_beginBoldFont();
 494
 495         // figure out weapon order (how the weapons are sorted) // TODO make this configurable
 496         if(weaponorder_bypriority != autocvar_cl_weaponpriority || !weaponorder[0])
 497         {
 498                 float weapon_cnt;
 499                 if(weaponorder_bypriority)
 500                         strunzone(weaponorder_bypriority);
 501                 if(weaponorder_byimpulse)
 502                         strunzone(weaponorder_byimpulse);
 503
 504                 weaponorder_bypriority = strzone(autocvar_cl_weaponpriority);
 505                 weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(W_FixWeaponOrder_ForceComplete(W_NumberWeaponOrder(weaponorder_bypriority))));
 506                 weaponorder_cmp_str = strcat(" ", weaponorder_byimpulse, " ");
 507
 508                 weapon_cnt = 0;
 509                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 510                 {
 511                         self = get_weaponinfo(i);
 512                         if(self.impulse >= 0)
 513                         {
 514                                 weaponorder[weapon_cnt] = self;
 515                                 ++weapon_cnt;
 516                         }
 517                 }
 518                 for(i = weapon_cnt; i < WEP_MAXCOUNT; ++i)
 519                         weaponorder[i] = world;
 520                 heapsort(weapon_cnt, weaponorder_swap, weaponorder_cmp, world);
 521
 522                 weaponorder_cmp_str = string_null;
 523         }
 524
 525         if(!autocvar_hud_panel_weapons_complainbubble || autocvar__hud_configure || time - complain_weapon_time >= when + fadetime)
 526                 complain_weapon = 0;
 527
 528         // determine which weapons are going to be shown
 529         if (autocvar_hud_panel_weapons_onlyowned)
 530         {
 531                 if(autocvar__hud_configure)
 532                 {
 533                         if (!weapons_stat)
 534                                 for(i = WEP_FIRST; i <= WEP_LAST; i += floor((WEP_LAST-WEP_FIRST)/5))
 535                                         weapons_stat |= WepSet_FromWeapon(i);
 536
 537                         if(menu_enabled != 2)
 538                                 HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
 539                 }
 540
 541                 // do we own this weapon?
 542                 weapon_count = 0;
 543                 for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 544                         if(weapons_stat & WepSet_FromWeapon(weaponorder[i].weapon))
 545                                 ++weapon_count;
 546
 547                 // add it anyway if weaponcomplain is shown
 548                 if(complain_weapon)
 549                         ++weapon_count;
 550
 551                 // might as well commit suicide now, no reason to live ;)
 552                 if (weapon_count == 0)
 553                 {
 554                         draw_endBoldFont();
 555                         return;
 556                 }
 557
 558                 old_panel_size = panel_size;
 559                 if(panel_bg_padding)
 560                         old_panel_size -= '2 2 0' * panel_bg_padding;
 561
 562                 // first find values for the standard table (with all the weapons)
 563                 rows = old_panel_size_y/old_panel_size_x;
 564                 rows = bound(1, floor((sqrt(4 * aspect * rows * WEP_COUNT + rows * rows) + rows + 0.5) / 2), WEP_COUNT);
 565                 columns = ceil(WEP_COUNT/rows);
 566                 weapon_size_x = old_panel_size_x / columns;
 567                 weapon_size_y = old_panel_size_y / rows;
 568
 569                 // change table values to include only the owned weapons
 570                 // weapon_size won't be changed
 571                 if(weapon_count <= rows)
 572                 {
 573                         rows = weapon_count;
 574                         columns = 1;
 575                 }
 576                 else
 577                         columns = ceil(weapon_count / rows);
 578
 579                 // reduce size of the panel
 580                 panel_size_x = columns * weapon_size_x;
 581                 panel_size_y = rows * weapon_size_y;
 582                 panel_pos_x += (old_panel_size_x - panel_size_x) / 2;
 583                 panel_pos_y += (old_panel_size_y - panel_size_y) / 2;
 584                 if(panel_bg_padding)
 585                         panel_size += '2 2 0' * panel_bg_padding;
 586         }
 587         else
 588                 weapon_count = WEP_COUNT;
 589
 590         // animation for fading in/out the panel respectively when not in use
 591         if(!autocvar__hud_configure)
 592         {
 593                 if (timeout && time >= weapontime + timeout) // apply timeout effect if needed
 594                 {
 595                         f = bound(0, (time - (weapontime + timeout)) / timeout_effect_length, 1);
 596
 597                         // fade the panel alpha
 598                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 599                         {
 600                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * f + (1 - f));
 601                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * f + (1 - f));
 602                         }
 603                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 604                         {
 605                                 panel_bg_alpha *= (1 - f);
 606                                 panel_fg_alpha *= (1 - f);
 607                         }
 608
 609                         // move the panel off the screen
 610                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 611                         {
 612                                 f *= f; // for a cooler movement
 613                                 center_x = panel_pos_x + panel_size_x/2;
 614                                 center_y = panel_pos_y + panel_size_y/2;
 615                                 screen_ar = vid_conwidth/vid_conheight;
 616                                 if (center_x/center_y < screen_ar) //bottom left
 617                                 {
 618                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //bottom
 619                                                 panel_pos_y += f * (vid_conheight - panel_pos_y);
 620                                         else //left
 621                                                 panel_pos_x -= f * (panel_pos_x + panel_size_x);
 622                                 }
 623                                 else //top right
 624                                 {
 625                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //right
 626                                                 panel_pos_x += f * (vid_conwidth - panel_pos_x);
 627                                         else //top
 628                                                 panel_pos_y -= f * (panel_pos_y + panel_size_y);
 629                                 }
 630                                 if(f == 1)
 631                                         center_x = -1; // mark the panel as off screen
 632                         }
 633                         weaponprevtime = time - (1 - f) * timein_effect_length;
 634                 }
 635                 else if (timeout && time < weaponprevtime + timein_effect_length) // apply timein effect if needed
 636                 {
 637                         f = bound(0, (time - weaponprevtime) / timein_effect_length, 1);
 638
 639                         // fade the panel alpha
 640                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 641                         {
 642                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * (1 - f) + f);
 643                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * (1 - f) + f);
 644                         }
 645                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 646                         {
 647                                 panel_bg_alpha *= (f);
 648                                 panel_fg_alpha *= (f);
 649                         }
 650
 651                         // move the panel back on screen
 652                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 653                         {
 654                                 f *= f; // for a cooler movement
 655                                 f = 1 - f;
 656                                 center_x = panel_pos_x + panel_size_x/2;
 657                                 center_y = panel_pos_y + panel_size_y/2;
 658                                 screen_ar = vid_conwidth/vid_conheight;
 659                                 if (center_x/center_y < screen_ar) //bottom left
 660                                 {
 661                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //bottom
 662                                                 panel_pos_y += f * (vid_conheight - panel_pos_y);
 663                                         else //left
 664                                                 panel_pos_x -= f * (panel_pos_x + panel_size_x);
 665                                 }
 666                                 else //top right
 667                                 {
 668                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //right
 669                                                 panel_pos_x += f * (vid_conwidth - panel_pos_x);
 670                                         else //top
 671                                                 panel_pos_y -= f * (panel_pos_y + panel_size_y);
 672                                 }
 673                         }
 674                 }
 675         }
 676
 677         // draw the background, then change the virtual size of it to better fit other items inside
 678         HUD_Panel_DrawBg(1);
 679
 680         if(center_x == -1)
 681         {
 682                 draw_endBoldFont();
 683                 return;
 684         }
 685
 686         if(panel_bg_padding)
 687         {
 688                 panel_pos += '1 1 0' * panel_bg_padding;
 689                 panel_size -= '2 2 0' * panel_bg_padding;
 690         }
 691
 692         // after the sizing and animations are done, update the other values
 693
 694         if(!rows) // if rows is > 0 onlyowned code has already updated these vars
 695         {
 696                 rows = panel_size_y/panel_size_x;
 697                 rows = bound(1, floor((sqrt(4 * aspect * rows * weapon_count + rows * rows) + rows + 0.5) / 2), weapon_count);
 698                 columns = ceil(weapon_count/rows);
 699                 weapon_size = eX * panel_size_x*(1/columns) + eY * panel_size_y*(1/rows);
 700         }
 701
 702         // calculate position/size for visual bar displaying ammount of ammo status
 703         if (autocvar_hud_panel_weapons_ammo)
 704         {
 705                 ammo_color = stov(autocvar_hud_panel_weapons_ammo_color);
 706                 ammo_alpha = panel_fg_alpha * autocvar_hud_panel_weapons_ammo_alpha;
 707
 708                 if(weapon_size_x/weapon_size_y > aspect)
 709                 {
 710                         barsize_x = aspect * weapon_size_y;
 711                         barsize_y = weapon_size_y;
 712                         baroffset_x = (weapon_size_x - barsize_x) / 2;
 713                 }
 714                 else
 715                 {
 716                         barsize_y = 1/aspect * weapon_size_x;
 717                         barsize_x = weapon_size_x;
 718                         baroffset_y = (weapon_size_y - barsize_y) / 2;
 719                 }
 720         }
 721         if(autocvar_hud_panel_weapons_accuracy)
 722                 Accuracy_LoadColors();
 723
 724         row = column = 0;
 725         for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 726         {
 727                 // retrieve information about the current weapon to be drawn
 728                 self = weaponorder[i];
 729                 weapon_id = self.impulse;
 730
 731                 // skip if this weapon doesn't exist
 732                 if(!self || weapon_id < 0) { continue; }
 733
 734                 // skip this weapon if we don't own it (and onlyowned is enabled)-- or if weapons_complainbubble is showing for this weapon
 735                 if(autocvar_hud_panel_weapons_onlyowned)
 736                 if (!((weapons_stat & WepSet_FromWeapon(self.weapon)) || (self.weapon == complain_weapon)))
 737                         continue;
 738
 739                 // figure out the drawing position of weapon
 740                 weapon_pos = (panel_pos
 741                         + eX * column * weapon_size_x
 742                         + eY * row * weapon_size_y);
 743
 744                 // draw background behind currently selected weapon
 745                 if(self.weapon == switchweapon)
 746                         drawpic_aspect_skin(weapon_pos, "weapon_current_bg", weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 747
 748                 // draw the weapon accuracy
 749                 if(autocvar_hud_panel_weapons_accuracy)
 750                 {
 751                         panel_weapon_accuracy = weapon_accuracy[self.weapon-WEP_FIRST];
 752                         if(panel_weapon_accuracy >= 0)
 753                         {
 754                                 color = Accuracy_GetColor(panel_weapon_accuracy);
 755                                 drawpic_aspect_skin(weapon_pos, "weapon_accuracy", weapon_size, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 756                         }
 757                 }
 758
 759                 // drawing all the weapon items
 760                 if(weapons_stat & WepSet_FromWeapon(self.weapon))
 761                 {
 762                         // draw the weapon image
 763                         drawpic_aspect_skin(weapon_pos, strcat("weapon", self.netname), weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 764
 765                         // draw weapon label string
 766                         switch(autocvar_hud_panel_weapons_label)
 767                         {
 768                                 case 1: // weapon number
 769                                         drawstring(weapon_pos, ftos(weapon_id), '1 1 0' * 0.5 * weapon_size_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 770                                         break;
 771
 772                                 case 2: // bind
 773                                         drawstring(weapon_pos, getcommandkey(ftos(weapon_id), strcat("weapon_group_", ftos(weapon_id))), '1 1 0' * 0.5 * weapon_size_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 774                                         break;
 775
 776                                 case 3: // weapon name
 777                                         drawstring(weapon_pos, self.netname, '1 1 0' * 0.5 * weapon_size_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 778                                         break;
 779
 780                                 default: // nothing
 781                                         break;
 782                         }
 783
 784                         // draw ammo status bar
 785                         if(autocvar_hud_panel_weapons_ammo && self.weapon != WEP_TUBA && self.weapon != WEP_LASER && self.weapon != WEP_PORTO)
 786                         {
 787                                 a = 0;
 788                                 ammo_type = GetAmmoTypeForWep(self.weapon);
 789                                 if(ammo_type != -1)
 790                                         a = getstati(GetAmmoStat(ammo_type)); // how much ammo do we have?
 791
 792                                 if(a > 0)
 793                                 {
 794                                         switch(ammo_type) {
 795                                                 case 0: ammo_full = autocvar_hud_panel_weapons_ammo_full_shells; break;
 796                                                 case 1: ammo_full = autocvar_hud_panel_weapons_ammo_full_nails; break;
 797                                                 case 2: ammo_full = autocvar_hud_panel_weapons_ammo_full_rockets; break;
 798                                                 case 3: ammo_full = autocvar_hud_panel_weapons_ammo_full_cells; break;
 799                                                 case 4: ammo_full = autocvar_hud_panel_weapons_ammo_full_fuel; break;
 800                                                 default: ammo_full = 60;
 801                                         }
 802
 803                                         drawsetcliparea(
 804                                                 weapon_pos_x + baroffset_x,
 805                                                 weapon_pos_y + baroffset_y,
 806                                                 barsize_x * bound(0, a/ammo_full, 1),
 807                                                 barsize_y);
 808                                         drawpic_aspect_skin(weapon_pos, "weapon_ammo", weapon_size, ammo_color, ammo_alpha, DRAWFLAG_NORMAL);
 809                                         drawresetcliparea();
 810                                 }
 811                         }
 812                 }
 813                 else // draw a "ghost weapon icon" if you don't have the weapon
 814                 {
 815                         drawpic_aspect_skin(weapon_pos, strcat("weapon", self.netname), weapon_size, '0 0 0', panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
 816                 }
 817
 818                 // draw the complain message
 819                 if(self.weapon == complain_weapon)
 820                 {
 821                         if(fadetime)
 822                                 a = ((complain_weapon_time + when > time) ? 1 : bound(0, (complain_weapon_time + when + fadetime - time) / fadetime, 1));
 823                         else
 824                                 a = ((complain_weapon_time + when > time) ? 1 : 0);
 825
 826                         string s;
 827                         if(complain_weapon_type == 0) {
 828                                 s = _("Out of ammo");
 829                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_outofammo);
 830                         }
 831                         else if(complain_weapon_type == 1) {
 832                                 s = _("Don't have");
 833                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_donthave);
 834                         }
 835                         else {
 836                                 s = _("Unavailable");
 837                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_unavailable);
 838                         }
 839                         float padding = autocvar_hud_panel_weapons_complainbubble_padding;
 840                         drawpic_aspect_skin(weapon_pos + '1 1 0' * padding, "weapon_complainbubble", weapon_size - '2 2 0' * padding, color, a * panel_fg_alpha, DRAWFLAG_NORMAL);
 841                         drawstring_aspect(weapon_pos + '1 1 0' * padding, s, weapon_size - '2 2 0' * padding, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 842                 }
 843
 844                 // continue with new position for the next weapon
 845                 ++row;
 846                 if(row >= rows)
 847                 {
 848                         row = 0;
 849                         ++column;
 850                 }
 851         }
 852
 853         draw_endBoldFont();
 854 }
 855
 856 // Ammo (#1)
 857 //
 858 // TODO: macro
 859 float GetAmmoItemCode(float i)
 860 {
 861         switch(i)
 862         {
 863                 case 0: return IT_SHELLS;
 864                 case 1: return IT_NAILS;
 865                 case 2: return IT_ROCKETS;
 866                 case 3: return IT_CELLS;
 867                 case 4: return IT_FUEL;
 868                 default: return -1;
 869         }
 870 }
 871
 872 string GetAmmoPicture(float i)
 873 {
 874         switch(i)
 875         {
 876                 case 0: return "ammo_shells";
 877                 case 1: return "ammo_bullets";
 878                 case 2: return "ammo_rockets";
 879                 case 3: return "ammo_cells";
 880                 case 4: return "ammo_fuel";
 881                 default: return "";
 882         }
 883 }
 884
 885 void DrawAmmoItem(vector myPos, vector mySize, float itemcode, float currently_selected, float infinite_ammo)
 886 {
 887         float a;
 888         if(autocvar__hud_configure)
 889         {
 890                 currently_selected = (itemcode == 2); //rockets always selected
 891                 a = 31 + mod(itemcode*93, 128);
 892         }
 893         else
 894                 a = getstati(GetAmmoStat(itemcode)); // how much ammo do we have of type itemcode?
 895
 896         vector color;
 897         if(infinite_ammo)
 898                 color = '0 0.5 0.75';
 899         else if(a < 10)
 900                 color = '0.7 0 0';
 901         else
 902                 color = '1 1 1';
 903
 904         float theAlpha;
 905         if(currently_selected)
 906                 theAlpha = 1;
 907         else
 908                 theAlpha = 0.7;
 909
 910         vector picpos, numpos;
 911         if(autocvar_hud_panel_ammo_iconalign)
 912         {
 913                 numpos = myPos;
 914                 picpos = myPos + eX * 2 * mySize_y;
 915         }
 916         else
 917         {
 918                 numpos = myPos + eX * mySize_y;
 919                 picpos = myPos;
 920         }
 921
 922         if (currently_selected)
 923                 drawpic_aspect_skin(myPos, "ammo_current_bg", mySize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 924
 925     if(a > 0 && autocvar_hud_panel_ammo_progressbar)
 926         HUD_Panel_DrawProgressBar(myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize_x, mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize_x, autocvar_hud_panel_ammo_progressbar_name, a/autocvar_hud_panel_ammo_maxammo, 0, 0, color, autocvar_hud_progressbar_alpha * panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 927
 928     if(autocvar_hud_panel_ammo_text)
 929     {
 930         if(a > 0 || infinite_ammo)
 931             drawstring_aspect(numpos, ftos(a), eX * (2/3) * mySize_x + eY * mySize_y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 932         else // "ghost" ammo count
 933             drawstring_aspect(numpos, ftos(a), eX * (2/3) * mySize_x + eY * mySize_y, '0 0 0', panel_fg_alpha * theAlpha * 0.5, DRAWFLAG_NORMAL);
 934     }
 935         if(a > 0 || infinite_ammo)
 936                 drawpic_aspect_skin(picpos, GetAmmoPicture(itemcode), '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 937         else // "ghost" ammo icon
 938                 drawpic_aspect_skin(picpos, GetAmmoPicture(itemcode), '1 1 0' * mySize_y, '0 0 0', panel_fg_alpha * theAlpha * 0.5, DRAWFLAG_NORMAL);
 939 }
 940
 941 void HUD_Ammo(void)
 942 {
 943         if(hud != HUD_NORMAL) return;
 944         if(!autocvar__hud_configure)
 945         {
 946                 if(!autocvar_hud_panel_ammo) return;
 947                 if(spectatee_status == -1) return;
 948         }
 949
 950         HUD_Panel_UpdateCvars();
 951
 952         draw_beginBoldFont();
 953
 954         vector pos, mySize;
 955         pos = panel_pos;
 956         mySize = panel_size;
 957
 958         HUD_Panel_DrawBg(1);
 959         if(panel_bg_padding)
 960         {
 961                 pos += '1 1 0' * panel_bg_padding;
 962                 mySize -= '2 2 0' * panel_bg_padding;
 963         }
 964
 965         const float AMMO_COUNT = 4;
 966         float rows = 0, columns, row, column;
 967         vector ammo_size;
 968         if (autocvar_hud_panel_ammo_onlycurrent)
 969                 ammo_size = mySize;
 970         else
 971         {
 972                 rows = mySize_y/mySize_x;
 973                 rows = bound(1, floor((sqrt(4 * (3/1) * rows * AMMO_COUNT + rows * rows) + rows + 0.5) / 2), AMMO_COUNT);
 974                 //                               ^^^ ammo item aspect goes here
 975
 976                 columns = ceil(AMMO_COUNT/rows);
 977
 978                 ammo_size = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
 979         }
 980
 981         local vector offset = '0 0 0'; // fteqcc sucks
 982         float newSize;
 983         if(ammo_size_x/ammo_size_y > 3)
 984         {
 985                 newSize = 3 * ammo_size_y;
 986                 offset_x = ammo_size_x - newSize;
 987                 pos_x += offset_x/2;
 988                 ammo_size_x = newSize;
 989         }
 990         else
 991         {
 992                 newSize = 1/3 * ammo_size_x;
 993                 offset_y = ammo_size_y - newSize;
 994                 pos_y += offset_y/2;
 995                 ammo_size_y = newSize;
 996         }
 997
 998         float i, stat_items, currently_selected, infinite_ammo;
 999         infinite_ammo = FALSE;
1000         if (autocvar_hud_panel_ammo_onlycurrent)
1001         {
1002                 if(autocvar__hud_configure)
1003                 {
1004                         DrawAmmoItem(pos, ammo_size, 2, true, FALSE); //show rockets
1005                 }
1006                 else
1007                 {
1008                         stat_items = getstati(STAT_ITEMS, 0, 24);
1009                         if (stat_items & IT_UNLIMITED_WEAPON_AMMO)
1010                                 infinite_ammo = TRUE;
1011                         for (i = 0; i < AMMO_COUNT; ++i) {
1012                                 currently_selected = stat_items & GetAmmoItemCode(i);
1013                                 if (currently_selected)
1014                                 {
1015                                         DrawAmmoItem(pos, ammo_size, i, true, infinite_ammo);
1016                                         break;
1017                                 }
1018                         }
1019                 }
1020         }
1021         else
1022         {
1023                 stat_items = getstati(STAT_ITEMS, 0, 24);
1024                 if (stat_items & IT_UNLIMITED_WEAPON_AMMO)
1025                         infinite_ammo = TRUE;
1026                 row = column = 0;
1027                 for (i = 0; i < AMMO_COUNT; ++i) {
1028                         currently_selected = stat_items & GetAmmoItemCode(i);
1029                         DrawAmmoItem(pos + eX * column * (ammo_size_x + offset_x) + eY * row * (ammo_size_y + offset_y), ammo_size, i, currently_selected, infinite_ammo);
1030                         ++row;
1031                         if(row >= rows)
1032                         {
1033                                 row = 0;
1034                                 column = column + 1;
1035                         }
1036                 }
1037         }
1038
1039         draw_endBoldFont();
1040 }
1041
1042 void DrawNumIcon_expanding(vector myPos, vector mySize, float x, string icon, float vertical, float icon_right_align, vector color, float theAlpha, float fadelerp)
1043 {
1044         vector newPos = '0 0 0', newSize = '0 0 0';
1045         vector picpos, numpos;
1046
1047         if (vertical)
1048         {
1049                 if(mySize_y/mySize_x > 2)
1050                 {
1051                         newSize_y = 2 * mySize_x;
1052                         newSize_x = mySize_x;
1053
1054                         newPos_y = myPos_y + (mySize_y - newSize_y) / 2;
1055                         newPos_x = myPos_x;
1056                 }
1057                 else
1058                 {
1059                         newSize_x = 1/2 * mySize_y;
1060                         newSize_y = mySize_y;
1061
1062                         newPos_x = myPos_x + (mySize_x - newSize_x) / 2;
1063                         newPos_y = myPos_y;
1064                 }
1065
1066                 if(icon_right_align)
1067                 {
1068                         numpos = newPos;
1069                         picpos = newPos + eY * newSize_x;
1070                 }
1071                 else
1072                 {
1073                         picpos = newPos;
1074                         numpos = newPos + eY * newSize_x;
1075                 }
1076
1077                 newSize_y /= 2;
1078                 drawpic_aspect_skin(picpos, icon, newSize, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1079                 // make number smaller than icon, it looks better
1080                 // reduce only y to draw numbers with different number of digits with the same y size
1081                 numpos_y += newSize_y * ((1 - 0.7) / 2);
1082                 newSize_y *= 0.7;
1083                 drawstring_aspect(numpos, ftos(x), newSize, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1084                 return;
1085         }
1086
1087         if(mySize_x/mySize_y > 3)
1088         {
1089                 newSize_x = 3 * mySize_y;
1090                 newSize_y = mySize_y;
1091
1092                 newPos_x = myPos_x + (mySize_x - newSize_x) / 2;
1093                 newPos_y = myPos_y;
1094         }
1095         else
1096         {
1097                 newSize_y = 1/3 * mySize_x;
1098                 newSize_x = mySize_x;
1099
1100                 newPos_y = myPos_y + (mySize_y - newSize_y) / 2;
1101                 newPos_x = myPos_x;
1102         }
1103
1104         if(icon_right_align) // right align
1105         {
1106                 numpos = newPos;
1107                 picpos = newPos + eX * 2 * newSize_y;
1108         }
1109         else // left align
1110         {
1111                 numpos = newPos + eX * newSize_y;
1112                 picpos = newPos;
1113         }
1114
1115         // NOTE: newSize_x is always equal to 3 * mySize_y so we can use
1116         // '2 1 0' * newSize_y instead of eX * (2/3) * newSize_x + eY * newSize_y
1117         drawstring_aspect_expanding(numpos, ftos(x), '2 1 0' * newSize_y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1118         drawpic_aspect_skin_expanding(picpos, icon, '1 1 0' * newSize_y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1119 }
1120
1121 void DrawNumIcon(vector myPos, vector mySize, float x, string icon, float vertical, float icon_right_align, vector color, float theAlpha)
1122 {
1123         DrawNumIcon_expanding(myPos, mySize, x, icon, vertical, icon_right_align, color, theAlpha, 0);
1124 }
1125
1126 // Powerups (#2)
1127 //
1128 void HUD_Powerups(void)
1129 {
1130         float strength_time, shield_time, superweapons_time;
1131         if(!autocvar__hud_configure)
1132         {
1133                 if(!autocvar_hud_panel_powerups) return;
1134                 if(spectatee_status == -1) return;
1135                 if(!(getstati(STAT_ITEMS, 0, 24) & (IT_STRENGTH | IT_INVINCIBLE | IT_SUPERWEAPON))) return;
1136                 if (getstati(STAT_HEALTH) <= 0) return;
1137
1138                 strength_time = bound(0, getstatf(STAT_STRENGTH_FINISHED) - time, 99);
1139                 shield_time = bound(0, getstatf(STAT_INVINCIBLE_FINISHED) - time, 99);
1140                 superweapons_time = bound(0, getstatf(STAT_SUPERWEAPONS_FINISHED) - time, 99);
1141
1142                 if (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_SUPERWEAPONS)
1143                         superweapons_time = 99; // force max
1144
1145                 // prevent stuff to show up on mismatch that will be fixed next frame
1146                 if (!(getstati(STAT_ITEMS, 0, 24) & IT_SUPERWEAPON))
1147                         superweapons_time = 0;
1148         }
1149         else
1150         {
1151                 strength_time = 15;
1152                 shield_time = 27;
1153                 superweapons_time = 13;
1154         }
1155
1156         HUD_Panel_UpdateCvars();
1157
1158         draw_beginBoldFont();
1159
1160         vector pos, mySize;
1161         pos = panel_pos;
1162         mySize = panel_size;
1163
1164         HUD_Panel_DrawBg(bound(0, max(strength_time, shield_time, superweapons_time), 1));
1165         if(panel_bg_padding)
1166         {
1167                 pos += '1 1 0' * panel_bg_padding;
1168                 mySize -= '2 2 0' * panel_bg_padding;
1169         }
1170
1171         float panel_ar = mySize_x/mySize_y;
1172         float is_vertical = (panel_ar < 1);
1173         vector shield_offset = '0 0 0', strength_offset = '0 0 0', superweapons_offset = '0 0 0';
1174
1175         float superweapons_is = -1;
1176
1177         if(superweapons_time)
1178         {
1179                 if(strength_time)
1180                 {
1181                         if(shield_time)
1182                                 superweapons_is = 0;
1183                         else
1184                                 superweapons_is = 2;
1185                 }
1186                 else
1187                 {
1188                         if(shield_time)
1189                                 superweapons_is = 1;
1190                         else
1191                                 superweapons_is = 2;
1192                 }
1193         }
1194
1195         // FIXME handle superweapons here
1196         if(superweapons_is == 0)
1197         {
1198                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1199                 {
1200                         mySize_x *= (1.0 / 3.0);
1201                         superweapons_offset_x = mySize_x;
1202                         if (autocvar_hud_panel_powerups_flip)
1203                                 shield_offset_x = 2*mySize_x;
1204                         else
1205                                 strength_offset_x = 2*mySize_x;
1206                 }
1207                 else
1208                 {
1209                         mySize_y *= (1.0 / 3.0);
1210                         superweapons_offset_y = mySize_y;
1211                         if (autocvar_hud_panel_powerups_flip)
1212                                 shield_offset_y = 2*mySize_y;
1213                         else
1214                                 strength_offset_y = 2*mySize_y;
1215                 }
1216         }
1217         else
1218         {
1219                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1220                 {
1221                         mySize_x *= 0.5;
1222                         if (autocvar_hud_panel_powerups_flip)
1223                                 shield_offset_x = mySize_x;
1224                         else
1225                                 strength_offset_x = mySize_x;
1226                 }
1227                 else
1228                 {
1229                         mySize_y *= 0.5;
1230                         if (autocvar_hud_panel_powerups_flip)
1231                                 shield_offset_y = mySize_y;
1232                         else
1233                                 strength_offset_y = mySize_y;
1234                 }
1235         }
1236
1237         float shield_baralign, strength_baralign, superweapons_baralign;
1238         float shield_iconalign, strength_iconalign, superweapons_iconalign;
1239
1240         if (autocvar_hud_panel_powerups_flip)
1241         {
1242                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1243                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1244                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1245                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1246         }
1247         else
1248         {
1249                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1250                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1251                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1252                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1253         }
1254
1255         if(superweapons_is == 0)
1256         {
1257                 superweapons_iconalign = strength_iconalign;
1258                 superweapons_baralign = 2;
1259         }
1260         else if(superweapons_is == 1)
1261         {
1262                 superweapons_offset = strength_offset;
1263                 superweapons_iconalign = strength_iconalign;
1264                 superweapons_baralign = strength_baralign;
1265         }
1266         else // if(superweapons_is == 2)
1267         {
1268                 superweapons_offset = shield_offset;
1269                 superweapons_iconalign = shield_iconalign;
1270                 superweapons_baralign = shield_baralign;
1271         }
1272
1273         if(shield_time)
1274         {
1275                 const float maxshield = 30;
1276                 float shield = ceil(shield_time);
1277                 if(autocvar_hud_panel_powerups_progressbar)
1278                         HUD_Panel_DrawProgressBar(pos + shield_offset, mySize, autocvar_hud_panel_powerups_progressbar_shield, shield/maxshield, is_vertical, shield_baralign, autocvar_hud_progressbar_shield_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1279                 if(autocvar_hud_panel_powerups_text)
1280                 {
1281                         if(shield > 1)
1282                                 DrawNumIcon(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1);
1283                         if(shield <= 5)
1284                                 DrawNumIcon_expanding(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1, bound(0, (shield - shield_time) / 0.5, 1));
1285                 }
1286         }
1287
1288         if(strength_time)
1289         {
1290                 const float maxstrength = 30;
1291                 float strength = ceil(strength_time);
1292                 if(autocvar_hud_panel_powerups_progressbar)
1293                         HUD_Panel_DrawProgressBar(pos + strength_offset, mySize, autocvar_hud_panel_powerups_progressbar_strength, strength/maxstrength, is_vertical, strength_baralign, autocvar_hud_progressbar_strength_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1294                 if(autocvar_hud_panel_powerups_text)
1295                 {
1296                         if(strength > 1)
1297                                 DrawNumIcon(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1);
1298                         if(strength <= 5)
1299                                 DrawNumIcon_expanding(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1, bound(0, (strength - strength_time) / 0.5, 1));
1300                 }
1301         }
1302
1303         if(superweapons_time)
1304         {
1305                 const float maxsuperweapons = 30;
1306                 float superweapons = ceil(superweapons_time);
1307                 if(autocvar_hud_panel_powerups_progressbar)
1308                         HUD_Panel_DrawProgressBar(pos + superweapons_offset, mySize, autocvar_hud_panel_powerups_progressbar_superweapons, superweapons/maxsuperweapons, is_vertical, superweapons_baralign, autocvar_hud_progressbar_superweapons_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1309                 if(autocvar_hud_panel_powerups_text)
1310                 {
1311                         if(superweapons > 1)
1312                                 DrawNumIcon(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1);
1313                         if(superweapons <= 5)
1314                                 DrawNumIcon_expanding(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1, bound(0, (superweapons - superweapons_time) / 0.5, 1));
1315                 }
1316         }
1317
1318         draw_endBoldFont();
1319 }
1320
1321 // Health/armor (#3)
1322 //
1323
1324 // prev_* vars contain the health/armor at the previous FRAME
1325 // set to -1 when player is dead or was not playing
1326 float prev_health, prev_armor;
1327 float health_damagetime, armor_damagetime;
1328 float health_beforedamage, armor_beforedamage;
1329 // old_p_* vars keep track of previous values when smoothing value changes of the progressbar
1330 float old_p_health, old_p_armor;
1331 float old_p_healthtime, old_p_armortime;
1332 // prev_p_* vars contain the health/armor progressbar value at the previous FRAME
1333 // set to -1 to forcedly stop effects when we switch spectated player (e.g. from playerX: 70h to playerY: 50h)
1334 float prev_p_health, prev_p_armor;
1335
1336 void HUD_HealthArmor(void)
1337 {
1338         float armor, health, fuel;
1339         if(!autocvar__hud_configure)
1340         {
1341                 if(!autocvar_hud_panel_healtharmor) return;
1342                 if(hud != HUD_NORMAL) return;
1343                 if(spectatee_status == -1) return;
1344
1345                 health = getstati(STAT_HEALTH);
1346                 if(health <= 0)
1347                 {
1348                         prev_health = -1;
1349                         return;
1350                 }
1351                 armor = getstati(STAT_ARMOR);
1352
1353                 // code to check for spectatee_status changes is in Ent_ClientData()
1354                 // prev_p_health and prev_health can be set to -1 there
1355
1356                 if (prev_p_health == -1)
1357                 {
1358                         // no effect
1359                         health_beforedamage = 0;
1360                         armor_beforedamage = 0;
1361                         health_damagetime = 0;
1362                         armor_damagetime = 0;
1363                         prev_health = health;
1364                         prev_armor = armor;
1365                         old_p_health = health;
1366                         old_p_armor = armor;
1367                         prev_p_health = health;
1368                         prev_p_armor = armor;
1369                 }
1370                 else if (prev_health == -1)
1371                 {
1372                         //start the load effect
1373                         health_damagetime = 0;
1374                         armor_damagetime = 0;
1375                         prev_health = 0;
1376                         prev_armor = 0;
1377                 }
1378                 fuel = getstati(STAT_FUEL);
1379         }
1380         else
1381         {
1382                 health = 150;
1383                 armor = 75;
1384                 fuel = 20;
1385         }
1386
1387         HUD_Panel_UpdateCvars();
1388         vector pos, mySize;
1389         pos = panel_pos;
1390         mySize = panel_size;
1391
1392         HUD_Panel_DrawBg(1);
1393         if(panel_bg_padding)
1394         {
1395                 pos += '1 1 0' * panel_bg_padding;
1396                 mySize -= '2 2 0' * panel_bg_padding;
1397         }
1398
1399         float baralign = autocvar_hud_panel_healtharmor_baralign;
1400         float iconalign = autocvar_hud_panel_healtharmor_iconalign;
1401
1402     float maxhealth = autocvar_hud_panel_healtharmor_maxhealth;
1403     float maxarmor = autocvar_hud_panel_healtharmor_maxarmor;
1404         if(autocvar_hud_panel_healtharmor == 2) // combined health and armor display
1405         {
1406                 vector v;
1407                 v = healtharmor_maxdamage(health, armor, armorblockpercent, DEATH_WEAPON);
1408
1409                 float x;
1410                 x = floor(v_x + 1);
1411
1412         float maxtotal = maxhealth + maxarmor;
1413                 string biggercount;
1414                 if(v_z) // NOT fully armored
1415                 {
1416                         biggercount = "health";
1417                         if(autocvar_hud_panel_healtharmor_progressbar)
1418                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_health, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1419                         if(armor)
1420             if(autocvar_hud_panel_healtharmor_text)
1421                                 drawpic_aspect_skin(pos + eX * mySize_x - eX * 0.5 * mySize_y, "armor", '0.5 0.5 0' * mySize_y, '1 1 1', panel_fg_alpha * armor / health, DRAWFLAG_NORMAL);
1422                 }
1423                 else
1424                 {
1425                         biggercount = "armor";
1426                         if(autocvar_hud_panel_healtharmor_progressbar)
1427                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1428                         if(health)
1429             if(autocvar_hud_panel_healtharmor_text)
1430                                 drawpic_aspect_skin(pos + eX * mySize_x - eX * 0.5 * mySize_y, "health", '0.5 0.5 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1431                 }
1432         if(autocvar_hud_panel_healtharmor_text)
1433                         DrawNumIcon(pos, mySize, x, biggercount, 0, iconalign, HUD_Get_Num_Color(x, maxtotal), 1);
1434
1435                 if(fuel)
1436                         HUD_Panel_DrawProgressBar(pos, eX * mySize_x + eY * 0.2 * mySize_y, "progressbar", fuel/100, 0, (baralign == 1 || baralign == 3), autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1437         }
1438         else
1439         {
1440                 float panel_ar = mySize_x/mySize_y;
1441                 float is_vertical = (panel_ar < 1);
1442                 vector health_offset = '0 0 0', armor_offset = '0 0 0';
1443                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1444                 {
1445                         mySize_x *= 0.5;
1446                         if (autocvar_hud_panel_healtharmor_flip)
1447                                 health_offset_x = mySize_x;
1448                         else
1449                                 armor_offset_x = mySize_x;
1450                 }
1451                 else
1452                 {
1453                         mySize_y *= 0.5;
1454                         if (autocvar_hud_panel_healtharmor_flip)
1455                                 health_offset_y = mySize_y;
1456                         else
1457                                 armor_offset_y = mySize_y;
1458                 }
1459
1460                 float health_baralign, armor_baralign, fuel_baralign;
1461                 float health_iconalign, armor_iconalign;
1462                 if (autocvar_hud_panel_healtharmor_flip)
1463                 {
1464                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1465                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1466                         fuel_baralign = health_baralign;
1467                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1468                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1469                 }
1470                 else
1471                 {
1472                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1473                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1474                         fuel_baralign = armor_baralign;
1475                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1476                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1477                 }
1478
1479                 //if(health)
1480                 {
1481                         if(autocvar_hud_panel_healtharmor_progressbar)
1482                         {
1483                                 float p_health, pain_health_alpha;
1484                                 p_health = health;
1485                                 pain_health_alpha = 1;
1486                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1487                                 {
1488                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1489                                         {
1490                                                 if (fabs(prev_health - health) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1491                                                 {
1492                                                         if (time - old_p_healthtime < 1)
1493                                                                 old_p_health = prev_p_health;
1494                                                         else
1495                                                                 old_p_health = prev_health;
1496                                                         old_p_healthtime = time;
1497                                                 }
1498                                                 if (time - old_p_healthtime < 1)
1499                                                 {
1500                                                         p_health += (old_p_health - health) * (1 - (time - old_p_healthtime));
1501                                                         prev_p_health = p_health;
1502                                                 }
1503                                         }
1504                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1505                                         {
1506                                                 if (prev_health - health >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1507                                                 {
1508                                                         if (time - health_damagetime >= 1)
1509                                                                 health_beforedamage = prev_health;
1510                                                         health_damagetime = time;
1511                                                 }
1512                                                 if (time - health_damagetime < 1)
1513                                                 {
1514                                                         float health_damagealpha = 1 - (time - health_damagetime)*(time - health_damagetime);
1515                                                         HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, health_beforedamage/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * health_damagealpha, DRAWFLAG_NORMAL);
1516                                                 }
1517                                         }
1518                                         prev_health = health;
1519
1520                                         if (health <= autocvar_hud_panel_healtharmor_progressbar_gfx_lowhealth)
1521                                         {
1522                                                 float BLINK_FACTOR = 0.15;
1523                                                 float BLINK_BASE = 0.85;
1524                                                 float BLINK_FREQ = 9;
1525                                                 pain_health_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
1526                                         }
1527                                 }
1528                                 HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, p_health/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * pain_health_alpha, DRAWFLAG_NORMAL);
1529                         }
1530                         if(autocvar_hud_panel_healtharmor_text)
1531                                 DrawNumIcon(pos + health_offset, mySize, health, "health", is_vertical, health_iconalign, HUD_Get_Num_Color(health, maxhealth), 1);
1532                 }
1533
1534                 if(armor)
1535                 {
1536                         if(autocvar_hud_panel_healtharmor_progressbar)
1537                         {
1538                                 float p_armor;
1539                                 p_armor = armor;
1540                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1541                                 {
1542                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1543                                         {
1544                                                 if (fabs(prev_armor - armor) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1545                                                 {
1546                                                         if (time - old_p_armortime < 1)
1547                                                                 old_p_armor = prev_p_armor;
1548                                                         else
1549                                                                 old_p_armor = prev_armor;
1550                                                         old_p_armortime = time;
1551                                                 }
1552                                                 if (time - old_p_armortime < 1)
1553                                                 {
1554                                                         p_armor += (old_p_armor - armor) * (1 - (time - old_p_armortime));
1555                                                         prev_p_armor = p_armor;
1556                                                 }
1557                                         }
1558                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1559                                         {
1560                                                 if (prev_armor - armor >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1561                                                 {
1562                                                         if (time - armor_damagetime >= 1)
1563                                                                 armor_beforedamage = prev_armor;
1564                                                         armor_damagetime = time;
1565                                                 }
1566                                                 if (time - armor_damagetime < 1)
1567                                                 {
1568                                                         float armor_damagealpha = 1 - (time - armor_damagetime)*(time - armor_damagetime);
1569                                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, armor_beforedamage/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * armor_damagealpha, DRAWFLAG_NORMAL);
1570                                                 }
1571                                         }
1572                                         prev_armor = armor;
1573                                 }
1574                                 HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, p_armor/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1575                         }
1576                         if(autocvar_hud_panel_healtharmor_text)
1577                                 DrawNumIcon(pos + armor_offset, mySize, armor, "armor", is_vertical, armor_iconalign, HUD_Get_Num_Color(armor, maxarmor), 1);
1578                 }
1579
1580                 if(fuel)
1581                 {
1582                         if (is_vertical)
1583                                 mySize_x *= 0.2 / 2; //if vertical always halve x to not cover too much numbers with 3 digits
1584                         else
1585                                 mySize_y *= 0.2;
1586                         if (panel_ar >= 4)
1587                                 mySize_x *= 2; //restore full panel size
1588                         else if (panel_ar < 1/4)
1589                                 mySize_y *= 2; //restore full panel size
1590                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", fuel/100, is_vertical, fuel_baralign, autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1591                 }
1592         }
1593 }
1594
1595 // Notification area (#4)
1596 //
1597
1598 void HUD_Notify_Push(string icon, string attacker, string victim)
1599 {
1600         if(icon != "")
1601         {
1602                 --kn_index;
1603                 if (kn_index == -1) { kn_index = KN_MAX_ENTRIES-1; }
1604                 notify_times[kn_index] = time;
1605
1606                 // icon
1607                 if(notify_icon[kn_index]) { strunzone(notify_icon[kn_index]); }
1608                 notify_icon[kn_index] = strzone(icon);
1609
1610                 // attacker
1611                 if(notify_attackers[kn_index]) { strunzone(notify_attackers[kn_index]); }
1612                 notify_attackers[kn_index] = strzone(attacker);
1613
1614                 // victim
1615                 if(notify_victims[kn_index]) { strunzone(notify_victims[kn_index]); }
1616                 notify_victims[kn_index] = strzone(victim);
1617         }
1618 }
1619
1620 void HUD_Notify(void)
1621 {
1622         if(!autocvar__hud_configure)
1623         {
1624                 if(!autocvar_hud_panel_notify) return;
1625         }
1626
1627         HUD_Panel_UpdateCvars();
1628         vector pos, mySize;
1629         pos = panel_pos;
1630         mySize = panel_size;
1631
1632         HUD_Panel_DrawBg(1);
1633         if(panel_bg_padding)
1634         {
1635                 pos += '1 1 0' * panel_bg_padding;
1636                 mySize -= '2 2 0' * panel_bg_padding;
1637         }
1638
1639         float entries, height;
1640         entries = bound(1, floor(KN_MAX_ENTRIES * mySize_y/mySize_x), KN_MAX_ENTRIES);
1641         height = mySize_y/entries;
1642
1643         vector fontsize;
1644         float fontheight = height * autocvar_hud_panel_notify_fontsize;
1645         fontsize = '0.5 0.5 0' * fontheight;
1646
1647         float a;
1648         float when;
1649         when = autocvar_hud_panel_notify_time;
1650         float fadetime;
1651         fadetime = autocvar_hud_panel_notify_fadetime;
1652
1653         vector pos_attacker, pos_victim, pos_icon;
1654         float width_attacker;
1655         string attacker, victim, icon;
1656
1657         float i, j, step, limit;
1658         if(autocvar_hud_panel_notify_flip) //order items from the top down
1659         {
1660                 i = 0;
1661                 step = +1;
1662                 limit = entries;
1663         }
1664         else //order items from the bottom up
1665         {
1666                 i = entries - 1;
1667                 step = -1;
1668                 limit = -1;
1669         }
1670
1671         for(j = kn_index;  i != limit;  i += step, ++j)
1672         {
1673                 if(autocvar__hud_configure)
1674                 {
1675                         if (step == +1)
1676                                 a = i;
1677                         else // inverse order
1678                                 a = entries - 1 - i;
1679                         attacker = textShortenToWidth(sprintf(_("Player %d"), a+1), 0.48 * mySize_x - height, fontsize, stringwidth_colors);
1680                         victim = textShortenToWidth(sprintf(_("Player %d"), a+2), 0.48 * mySize_x - height, fontsize, stringwidth_colors);
1681                         icon = strcat("weapon", get_weaponinfo(WEP_FIRST + mod(floor(a*2.4), WEP_LAST)).netname);
1682                         a = bound(0, (when - a) / 4, 1);
1683                         goto hud_config_notifyprint;
1684                 }
1685                 else
1686                 {
1687                         if (j == KN_MAX_ENTRIES)
1688                                 j = 0;
1689
1690                         if(notify_times[j] + when > time)
1691                                 a = 1;
1692                         else if(fadetime)
1693                         {
1694                                 a = bound(0, (notify_times[j] + when + fadetime - time) / fadetime, 1);
1695                                 if(!a)
1696                                 {
1697                                         break;
1698                                 }
1699                         }
1700                         else
1701                         {
1702                                 break;
1703                         }
1704
1705                         attacker = notify_attackers[j];
1706                         victim = notify_victims[j];
1707                         icon = notify_icon[j];
1708                 }
1709
1710                 //type = notify_deathtype[j];
1711                 //w = DEATH_WEAPONOF(type);
1712
1713                 if(icon != "")
1714                 {
1715                         if((attacker != "") && (victim == ""))
1716                         {
1717                                 // Y [used by] X
1718                                 attacker = textShortenToWidth(attacker, 0.73 * mySize_x - height, fontsize, stringwidth_colors);
1719                                 pos_attacker = pos + eX * (0.27 * mySize_x + height) + eY * ((0.5 * fontsize_y + i * height) + (0.5 * (height - fontheight)));
1720                                 pos_icon = pos + eX * 0.25 * mySize_x - eX * height + eY * i * height;
1721
1722                                 drawpic_aspect_skin(pos_icon, icon, '2 1 0' * height, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
1723                                 drawcolorcodedstring(pos_attacker, attacker, fontsize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
1724                         }
1725                         else if((attacker != "") && (victim != ""))
1726                         {
1727                                 // X [did action to] Y
1728                                 attacker = textShortenToWidth(attacker, 0.48 * mySize_x - height, fontsize, stringwidth_colors);
1729                                 victim = textShortenToWidth(victim, 0.48 * mySize_x - height, fontsize, stringwidth_colors);
1730 :hud_config_notifyprint
1731                                 width_attacker = stringwidth(attacker, TRUE, fontsize);
1732                                 pos_attacker = pos + eX * (0.48 * mySize_x - height - width_attacker) + eY * ((0.5 * fontsize_y + i * height) + (0.5 * (height - fontheight)));
1733                                 pos_victim = pos + eX * (0.52 * mySize_x + height) + eY * ((0.5 * fontsize_y + i * height) + (0.5 * (height - fontheight)));
1734                                 pos_icon = pos + eX * 0.5 * mySize_x - eX * height + eY * i * height;
1735
1736                                 drawpic_aspect_skin(pos_icon, icon, '2 1 0' * height, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
1737                                 drawcolorcodedstring(pos_attacker, attacker, fontsize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
1738                                 drawcolorcodedstring(pos_victim, victim, fontsize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
1739                         }
1740                 }
1741         }
1742 }
1743
1744 // Timer (#5)
1745 //
1746 // TODO: macro
1747 string seconds_tostring(float sec)
1748 {
1749         float minutes;
1750         minutes = floor(sec / 60);
1751
1752         sec -= minutes * 60;
1753         return sprintf("%d:%02d", minutes, sec);
1754 }
1755
1756 void HUD_Timer(void)
1757 {
1758         if(!autocvar__hud_configure)
1759         {
1760                 if(!autocvar_hud_panel_timer) return;
1761         }
1762
1763         HUD_Panel_UpdateCvars();
1764
1765         draw_beginBoldFont();
1766
1767         vector pos, mySize;
1768         pos = panel_pos;
1769         mySize = panel_size;
1770
1771         HUD_Panel_DrawBg(1);
1772         if(panel_bg_padding)
1773         {
1774                 pos += '1 1 0' * panel_bg_padding;
1775                 mySize -= '2 2 0' * panel_bg_padding;
1776         }
1777
1778         string timer;
1779         float timelimit, elapsedTime, timeleft, minutesLeft;
1780
1781         timelimit = getstatf(STAT_TIMELIMIT);
1782
1783         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
1784         timeleft = ceil(timeleft);
1785
1786         minutesLeft = floor(timeleft / 60);
1787
1788         vector timer_color;
1789         if(minutesLeft >= 5 || warmup_stage || timelimit == 0) //don't use red or yellow in warmup or when there is no timelimit
1790                 timer_color = '1 1 1'; //white
1791         else if(minutesLeft >= 1)
1792                 timer_color = '1 1 0'; //yellow
1793         else
1794                 timer_color = '1 0 0'; //red
1795
1796         if (autocvar_hud_panel_timer_increment || timelimit == 0 || warmup_stage) {
1797                 if (time < getstatf(STAT_GAMESTARTTIME)) {
1798                         //while restart is still active, show 00:00
1799                         timer = seconds_tostring(0);
1800                 } else {
1801                         elapsedTime = floor(time - getstatf(STAT_GAMESTARTTIME)); //127
1802                         timer = seconds_tostring(elapsedTime);
1803                 }
1804         } else {
1805                 timer = seconds_tostring(timeleft);
1806         }
1807
1808         drawstring_aspect(pos, timer, mySize, timer_color, panel_fg_alpha, DRAWFLAG_NORMAL);
1809
1810         draw_endBoldFont();
1811 }
1812
1813 // Radar (#6)
1814 //
1815 void HUD_Radar(void)
1816 {
1817         if (!autocvar__hud_configure)
1818         {
1819                 if (hud_panel_radar_maximized)
1820                 {
1821                         if (!hud_draw_maximized) return;
1822                 }
1823                 else
1824                 {
1825                         if (autocvar_hud_panel_radar == 0) return;
1826                         if (autocvar_hud_panel_radar != 2 && !teamplay) return;
1827                         if(radar_panel_modified)
1828                         {
1829                                 panel.update_time = time; // forces reload of panel attributes
1830                                 radar_panel_modified = false;
1831                         }
1832                 }
1833         }
1834
1835         HUD_Panel_UpdateCvars();
1836
1837         float f = 0;
1838
1839         if (hud_panel_radar_maximized && !autocvar__hud_configure)
1840         {
1841                 panel_size = autocvar_hud_panel_radar_maximized_size;
1842                 panel_size_x = bound(0.2, panel_size_x, 1) * vid_conwidth;
1843                 panel_size_y = bound(0.2, panel_size_y, 1) * vid_conheight;
1844                 panel_pos_x = (vid_conwidth - panel_size_x) / 2;
1845                 panel_pos_y = (vid_conheight - panel_size_y) / 2;
1846
1847                 string panel_bg;
1848                 panel_bg = strcat(hud_skin_path, "/border_default"); // always use the default border when maximized
1849                 if(precache_pic(panel_bg) == "")
1850                         panel_bg = "gfx/hud/default/border_default"; // fallback
1851                 if(!radar_panel_modified && panel_bg != panel.current_panel_bg)
1852                         radar_panel_modified = true;
1853                 if(panel.current_panel_bg)
1854                         strunzone(panel.current_panel_bg);
1855                 panel.current_panel_bg = strzone(panel_bg);
1856
1857                 switch(hud_panel_radar_maximized_zoommode)
1858                 {
1859                         default:
1860                         case 0:
1861                                 f = current_zoomfraction;
1862                                 break;
1863                         case 1:
1864                                 f = 1 - current_zoomfraction;
1865                                 break;
1866                         case 2:
1867                                 f = 0;
1868                                 break;
1869                         case 3:
1870                                 f = 1;
1871                                 break;
1872                 }
1873
1874                 switch(hud_panel_radar_maximized_rotation)
1875                 {
1876                         case 0:
1877                                 teamradar_angle = view_angles_y - 90;
1878                                 break;
1879                         default:
1880                                 teamradar_angle = 90 * hud_panel_radar_maximized_rotation;
1881                                 break;
1882                 }
1883         }
1884         if (!hud_panel_radar_maximized && !autocvar__hud_configure)
1885         {
1886                 switch(hud_panel_radar_zoommode)
1887                 {
1888                         default:
1889                         case 0:
1890                                 f = current_zoomfraction;
1891                                 break;
1892                         case 1:
1893                                 f = 1 - current_zoomfraction;
1894                                 break;
1895                         case 2:
1896                                 f = 0;
1897                                 break;
1898                         case 3:
1899                                 f = 1;
1900                                 break;
1901                 }
1902
1903                 switch(hud_panel_radar_rotation)
1904                 {
1905                         case 0:
1906                                 teamradar_angle = view_angles_y - 90;
1907                                 break;
1908                         default:
1909                                 teamradar_angle = 90 * hud_panel_radar_rotation;
1910                                 break;
1911                 }
1912         }
1913
1914         vector pos, mySize;
1915         pos = panel_pos;
1916         mySize = panel_size;
1917
1918         HUD_Panel_DrawBg(1);
1919         if(panel_bg_padding)
1920         {
1921                 pos += '1 1 0' * panel_bg_padding;
1922                 mySize -= '2 2 0' * panel_bg_padding;
1923         }
1924
1925         float color2;
1926         entity tm;
1927         float scale2d, normalsize, bigsize;
1928
1929         teamradar_origin2d = pos + 0.5 * mySize;
1930         teamradar_size2d = mySize;
1931
1932         if(minimapname == "")
1933                 return;
1934
1935         teamradar_loadcvars();
1936
1937         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
1938         teamradar_size2d = mySize;
1939
1940         teamradar_extraclip_mins = teamradar_extraclip_maxs = '0 0 0'; // we always center
1941
1942         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
1943         if((hud_panel_radar_rotation == 0 && !hud_panel_radar_maximized) || (hud_panel_radar_maximized_rotation == 0 && hud_panel_radar_maximized))
1944         {
1945                 // max-min distance must fit the radar in any rotation
1946                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen2d(mi_scale));
1947         }
1948         else
1949         {
1950                 vector c0, c1, c2, c3, span;
1951                 c0 = rotate(mi_min, teamradar_angle * DEG2RAD);
1952                 c1 = rotate(mi_max, teamradar_angle * DEG2RAD);
1953                 c2 = rotate('1 0 0' * mi_min_x + '0 1 0' * mi_max_y, teamradar_angle * DEG2RAD);
1954                 c3 = rotate('1 0 0' * mi_max_x + '0 1 0' * mi_min_y, teamradar_angle * DEG2RAD);
1955                 span = '0 0 0';
1956                 span_x = max(c0_x, c1_x, c2_x, c3_x) - min(c0_x, c1_x, c2_x, c3_x);
1957                 span_y = max(c0_y, c1_y, c2_y, c3_y) - min(c0_y, c1_y, c2_y, c3_y);
1958
1959                 // max-min distance must fit the radar in x=x, y=y
1960                 bigsize = min(
1961                         teamradar_size2d_x * scale2d / (1.05 * span_x),
1962                         teamradar_size2d_y * scale2d / (1.05 * span_y)
1963                 );
1964         }
1965
1966         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / hud_panel_radar_scale;
1967         if(bigsize > normalsize)
1968                 normalsize = bigsize;
1969
1970         teamradar_size =
1971                   f * bigsize
1972                 + (1 - f) * normalsize;
1973         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
1974                   f * mi_center
1975                 + (1 - f) * view_origin);
1976
1977         drawsetcliparea(
1978                 pos_x,
1979                 pos_y,
1980                 mySize_x,
1981                 mySize_y
1982         );
1983
1984         draw_teamradar_background(hud_panel_radar_foreground_alpha);
1985
1986         for(tm = world; (tm = find(tm, classname, "radarlink")); )
1987                 draw_teamradar_link(tm.origin, tm.velocity, tm.team);
1988         for(tm = world; (tm = findflags(tm, teamradar_icon, 0xFFFFFF)); )
1989                 draw_teamradar_icon(tm.origin, tm.teamradar_icon, tm, tm.teamradar_color, panel_fg_alpha);
1990         for(tm = world; (tm = find(tm, classname, "entcs_receiver")); )
1991         {
1992                 color2 = GetPlayerColor(tm.sv_entnum);
1993                 //if(color == NUM_SPECTATOR || color == color2)
1994                         draw_teamradar_player(tm.origin, tm.angles, Team_ColorRGB(color2));
1995         }
1996         draw_teamradar_player(view_origin, view_angles, '1 1 1');
1997
1998         drawresetcliparea();
1999 }
2000
2001 // Score (#7)
2002 //
2003 void HUD_UpdatePlayerTeams();
2004 void HUD_Score_Rankings(vector pos, vector mySize, entity me)
2005 {
2006         float score;
2007         entity tm = world, pl;
2008 #define SCOREPANEL_MAX_ENTRIES 6
2009 #define SCOREPANEL_ASPECTRATIO 2
2010         float entries = bound(1, floor(SCOREPANEL_MAX_ENTRIES * mySize_y/mySize_x * SCOREPANEL_ASPECTRATIO), SCOREPANEL_MAX_ENTRIES);
2011         vector fontsize = '1 1 0' * (mySize_y/entries);
2012
2013         vector rgb, score_color;
2014         rgb = '1 1 1';
2015         score_color = '1 1 1';
2016
2017         float name_size = mySize_x*0.75;
2018         float spacing_size = mySize_x*0.04;
2019         const float highlight_alpha = 0.2;
2020         float i = 0, me_printed = 0, first_pl = 0;
2021         string s;
2022         if (autocvar__hud_configure)
2023         {
2024                 float players_per_team = 0;
2025                 if (team_count)
2026                 {
2027                         // show team scores in the first line
2028                         float score_size = mySize_x / team_count;
2029                         players_per_team = max(2, ceil((entries - 1) / team_count));
2030                         for(i=0; i<team_count; ++i) {
2031                                 if (i == floor((entries - 2) / players_per_team) || (entries == 1 && i == 0))
2032                                         HUD_Panel_DrawHighlight(pos + eX * score_size * i, eX * score_size + eY * fontsize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2033                                 drawstring_aspect(pos + eX * score_size * i, ftos(175 - 23*i), eX * score_size + eY * fontsize_y, Team_ColorRGB(ColorByTeam(i)) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2034                         }
2035                         first_pl = 1;
2036                         pos_y += fontsize_y;
2037                 }
2038                 score = 10 + SCOREPANEL_MAX_ENTRIES * 3;
2039                 for (i=first_pl; i<entries; ++i)
2040                 {
2041                         //simulate my score is lower than all displayed players,
2042                         //so that I don't appear at all showing pure rankings.
2043                         //This is to better show the difference between the 2 ranking views
2044                         if (i == entries-1 && autocvar_hud_panel_score_rankings == 1)
2045                         {
2046                                 rgb = '1 1 0';
2047                                 drawfill(pos, eX * mySize_x + eY * fontsize_y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2048                                 s = GetPlayerName(player_localnum);
2049                                 score = 7;
2050                         }
2051                         else
2052                         {
2053                                 s = sprintf(_("Player %d"), i + 1 - first_pl);
2054                                 score -= 3;
2055                         }
2056
2057                         if (team_count)
2058                                 score_color = Team_ColorRGB(ColorByTeam(floor((i - first_pl) / players_per_team))) * 0.8;
2059                         s = textShortenToWidth(s, name_size, fontsize, stringwidth_colors);
2060                         drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, TRUE, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2061                         drawstring(pos + eX * (name_size + spacing_size), ftos(score), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2062                         pos_y += fontsize_y;
2063                 }
2064                 return;
2065         }
2066
2067         if (!scoreboard_fade_alpha) // the scoreboard too calls HUD_UpdatePlayerTeams
2068                 HUD_UpdatePlayerTeams();
2069         if (team_count)
2070         {
2071                 // show team scores in the first line
2072                 float score_size = mySize_x / team_count;
2073                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2074                         if(tm.team == NUM_SPECTATOR)
2075                                 continue;
2076                         if (tm.team == myteam)
2077                                 drawfill(pos + eX * score_size * i, eX * score_size + eY * fontsize_y, '1 1 1', highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2078                         drawstring_aspect(pos + eX * score_size * i, ftos(tm.(teamscores[ts_primary])), eX * score_size + eY * fontsize_y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2079                         ++i;
2080                 }
2081                 first_pl = 1;
2082                 pos_y += fontsize_y;
2083                 tm = teams.sort_next;
2084         }
2085         i = first_pl;
2086
2087         do
2088         for (pl = players.sort_next; pl && i<entries; pl = pl.sort_next)
2089         {
2090                 if ((team_count && pl.team != tm.team) || pl.team == NUM_SPECTATOR)
2091                         continue;
2092
2093                 if (i == entries-1 && !me_printed && pl != me)
2094                 if (autocvar_hud_panel_score_rankings == 1 && spectatee_status != -1)
2095                 {
2096                         for (pl = me.sort_next; pl; pl = pl.sort_next)
2097                                 if (pl.team != NUM_SPECTATOR)
2098                                         break;
2099
2100                         if (pl)
2101                                 rgb = '1 1 0'; //not last but not among the leading players: yellow
2102                         else
2103                                 rgb = '1 0 0'; //last: red
2104                         pl = me;
2105                 }
2106
2107                 if (pl == me)
2108                 {
2109                         if (i == first_pl)
2110                                 rgb = '0 1 0'; //first: green
2111                         me_printed = 1;
2112                         drawfill(pos, eX * mySize_x + eY * fontsize_y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2113                 }
2114                 if (team_count)
2115                         score_color = Team_ColorRGB(pl.team) * 0.8;
2116                 s = textShortenToWidth(GetPlayerName(pl.sv_entnum), name_size, fontsize, stringwidth_colors);
2117                 drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, TRUE, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2118                 drawstring(pos + eX * (name_size + spacing_size), ftos(pl.(scores[ps_primary])), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2119                 pos_y += fontsize_y;
2120                 ++i;
2121         }
2122         while (i<entries && team_count && (tm = tm.sort_next) && (tm.team != NUM_SPECTATOR || (tm = tm.sort_next)));
2123 }
2124
2125 void HUD_Score(void)
2126 {
2127         if(!autocvar__hud_configure)
2128         {
2129                 if(!autocvar_hud_panel_score) return;
2130                 if(spectatee_status == -1 && (gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2131         }
2132
2133         HUD_Panel_UpdateCvars();
2134         vector pos, mySize;
2135         pos = panel_pos;
2136         mySize = panel_size;
2137
2138         HUD_Panel_DrawBg(1);
2139         if(panel_bg_padding)
2140         {
2141                 pos += '1 1 0' * panel_bg_padding;
2142                 mySize -= '2 2 0' * panel_bg_padding;
2143         }
2144
2145         float score, distribution = 0;
2146         string sign;
2147         vector distribution_color;
2148         entity tm, pl, me;
2149
2150 #ifdef COMPAT_XON050_ENGINE
2151         me = (spectatee_status > 0) ? playerslots[spectatee_status - 1] : playerslots[player_localentnum - 1];
2152 #else
2153         me = playerslots[player_localentnum - 1];
2154 #endif
2155
2156         if((scores_flags[ps_primary] & SFL_TIME) && !teamplay) { // race/cts record display on HUD
2157                 string timer, distrtimer;
2158
2159                 pl = players.sort_next;
2160                 if(pl == me)
2161                         pl = pl.sort_next;
2162                 if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
2163                         if(pl.scores[ps_primary] == 0)
2164                                 pl = world;
2165
2166                 score = me.(scores[ps_primary]);
2167                 timer = TIME_ENCODED_TOSTRING(score);
2168
2169                 draw_beginBoldFont();
2170                 if (pl && ((!(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)) || score)) {
2171                         // distribution display
2172                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2173
2174                         distrtimer = ftos_decimals(fabs(distribution/pow(10, TIME_DECIMALS)), TIME_DECIMALS);
2175
2176                         if (distribution <= 0) {
2177                                 distribution_color = '0 1 0';
2178                                 sign = "-";
2179                         }
2180                         else {
2181                                 distribution_color = '1 0 0';
2182                                 sign = "+";
2183                         }
2184                         drawstring_aspect(pos + eX * 0.75 * mySize_x, strcat(sign, distrtimer), eX * 0.25 * mySize_x + eY * (1/3) * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2185                 }
2186                 // race record display
2187                 if (distribution <= 0)
2188                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2189                 drawstring_aspect(pos, timer, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2190                 draw_endBoldFont();
2191         } else if (!teamplay) { // non-teamgames
2192                 if ((spectatee_status == -1 && !autocvar__hud_configure) || autocvar_hud_panel_score_rankings)
2193                 {
2194                         HUD_Score_Rankings(pos, mySize, me);
2195                         return;
2196                 }
2197                 // me vector := [team/connected frags id]
2198                 pl = players.sort_next;
2199                 if(pl == me)
2200                         pl = pl.sort_next;
2201
2202                 if(autocvar__hud_configure)
2203                         distribution = 42;
2204                 else if(pl)
2205                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2206                 else
2207                         distribution = 0;
2208
2209                 score = me.(scores[ps_primary]);
2210                 if(autocvar__hud_configure)
2211                         score = 123;
2212
2213                 if(distribution >= 5)
2214                         distribution_color = eY;
2215                 else if(distribution >= 0)
2216                         distribution_color = '1 1 1';
2217                 else if(distribution >= -5)
2218                         distribution_color = '1 1 0';
2219                 else
2220                         distribution_color = eX;
2221
2222                 string distribution_str;
2223                 distribution_str = ftos(distribution);
2224                 draw_beginBoldFont();
2225                 if (distribution >= 0)
2226                 {
2227                         if (distribution > 0)
2228                                 distribution_str = strcat("+", distribution_str);
2229                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2230                 }
2231                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize_x + eY * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2232                 drawstring_aspect(pos + eX * 0.75 * mySize_x, distribution_str, eX * 0.25 * mySize_x + eY * (1/3) * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2233                 draw_endBoldFont();
2234         } else { // teamgames
2235                 float row, column, rows = 0, columns = 0;
2236                 local noref vector offset = '0 0 0';
2237                 vector score_pos, score_size; //for scores other than myteam
2238                 if(autocvar_hud_panel_score_rankings)
2239                 {
2240                         HUD_Score_Rankings(pos, mySize, me);
2241                         return;
2242                 }
2243                 if(spectatee_status == -1)
2244                 {
2245                         rows = mySize_y/mySize_x;
2246                         rows = bound(1, floor((sqrt(4 * (3/1) * rows * team_count + rows * rows) + rows + 0.5) / 2), team_count);
2247                         //                               ^^^ ammo item aspect goes here
2248
2249                         columns = ceil(team_count/rows);
2250
2251                         score_size = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
2252
2253                         float newSize;
2254                         if(score_size_x/score_size_y > 3)
2255                         {
2256                                 newSize = 3 * score_size_y;
2257                                 offset_x = score_size_x - newSize;
2258                                 pos_x += offset_x/2;
2259                                 score_size_x = newSize;
2260                         }
2261                         else
2262                         {
2263                                 newSize = 1/3 * score_size_x;
2264                                 offset_y = score_size_y - newSize;
2265                                 pos_y += offset_y/2;
2266                                 score_size_y = newSize;
2267                         }
2268                 }
2269                 else
2270                         score_size = eX * mySize_x*(1/4) + eY * mySize_y*(1/3);
2271
2272                 float max_fragcount;
2273                 max_fragcount = -99;
2274                 draw_beginBoldFont();
2275                 row = column = 0;
2276                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2277                         if(tm.team == NUM_SPECTATOR)
2278                                 continue;
2279                         score = tm.(teamscores[ts_primary]);
2280                         if(autocvar__hud_configure)
2281                                 score = 123;
2282
2283                         if (score > max_fragcount)
2284                                 max_fragcount = score;
2285
2286                         if (spectatee_status == -1)
2287                         {
2288                                 score_pos = pos + eX * column * (score_size_x + offset_x) + eY * row * (score_size_y + offset_y);
2289                                 if (max_fragcount == score)
2290                                         HUD_Panel_DrawHighlight(score_pos, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2291                                 drawstring_aspect(score_pos, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2292                                 ++row;
2293                                 if(row >= rows)
2294                                 {
2295                                         row = 0;
2296                                         ++column;
2297                                 }
2298                         }
2299                         else if(tm.team == myteam) {
2300                                 if (max_fragcount == score)
2301                                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2302                                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize_x + eY * mySize_y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2303                         } else {
2304                                 if (max_fragcount == score)
2305                                         HUD_Panel_DrawHighlight(pos + eX * 0.75 * mySize_x + eY * (1/3) * rows * mySize_y, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2306                                 drawstring_aspect(pos + eX * 0.75 * mySize_x + eY * (1/3) * rows * mySize_y, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2307                                 ++rows;
2308                         }
2309                 }
2310                 draw_endBoldFont();
2311         }
2312 }
2313
2314 // Race timer (#8)
2315 //
2316 void HUD_RaceTimer (void)
2317 {
2318         if(!autocvar__hud_configure)
2319         {
2320                 if(!autocvar_hud_panel_racetimer) return;
2321                 if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2322                 if(spectatee_status == -1) return;
2323         }
2324
2325         HUD_Panel_UpdateCvars();
2326
2327         draw_beginBoldFont();
2328
2329         vector pos, mySize;
2330         pos = panel_pos;
2331         mySize = panel_size;
2332
2333         HUD_Panel_DrawBg(1);
2334         if(panel_bg_padding)
2335         {
2336                 pos += '1 1 0' * panel_bg_padding;
2337                 mySize -= '2 2 0' * panel_bg_padding;
2338         }
2339
2340         // always force 4:1 aspect
2341         vector newSize = '0 0 0';
2342         if(mySize_x/mySize_y > 4)
2343         {
2344                 newSize_x = 4 * mySize_y;
2345                 newSize_y = mySize_y;
2346
2347                 pos_x = pos_x + (mySize_x - newSize_x) / 2;
2348         }
2349         else
2350         {
2351                 newSize_y = 1/4 * mySize_x;
2352                 newSize_x = mySize_x;
2353
2354                 pos_y = pos_y + (mySize_y - newSize_y) / 2;
2355         }
2356         mySize = newSize;
2357
2358         float a, t;
2359         string s, forcetime;
2360
2361         if(autocvar__hud_configure)
2362         {
2363                 s = "0:13:37";
2364                 drawstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, FALSE, '0.60 0.60 0' * mySize_y), s, '0.60 0.60 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2365                 s = _("^1Intermediate 1 (+15.42)");
2366                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.20 * mySize_y) + eY * 0.60 * mySize_y, s, '1 1 0' * 0.20 * mySize_y, panel_fg_alpha, DRAWFLAG_NORMAL);
2367                 s = sprintf(_("^1PENALTY: %.1f (%s)"), 2, "missing a checkpoint");
2368                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.20 * mySize_y) + eY * 0.80 * mySize_y, s, '1 1 0' * 0.20 * mySize_y, panel_fg_alpha, DRAWFLAG_NORMAL);
2369         }
2370         else if(race_checkpointtime)
2371         {
2372                 a = bound(0, 2 - (time - race_checkpointtime), 1);
2373                 s = "";
2374                 forcetime = "";
2375                 if(a > 0) // just hit a checkpoint?
2376                 {
2377                         if(race_checkpoint != 254)
2378                         {
2379                                 if(race_time && race_previousbesttime)
2380                                         s = MakeRaceString(race_checkpoint, TIME_DECODE(race_time) - TIME_DECODE(race_previousbesttime), 0, 0, race_previousbestname);
2381                                 else
2382                                         s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
2383                                 if(race_time)
2384                                         forcetime = TIME_ENCODED_TOSTRING(race_time);
2385                         }
2386                 }
2387                 else
2388                 {
2389                         if(race_laptime && race_nextbesttime && race_nextcheckpoint != 254)
2390                         {
2391                                 a = bound(0, 2 - ((race_laptime + TIME_DECODE(race_nextbesttime)) - (time + TIME_DECODE(race_penaltyaccumulator))), 1);
2392                                 if(a > 0) // next one?
2393                                 {
2394                                         s = MakeRaceString(race_nextcheckpoint, (time + TIME_DECODE(race_penaltyaccumulator)) - race_laptime, TIME_DECODE(race_nextbesttime), 0, race_nextbestname);
2395                                 }
2396                         }
2397                 }
2398
2399                 if(s != "" && a > 0)
2400                 {
2401                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2402                 }
2403
2404                 if(race_penaltytime)
2405                 {
2406                         a = bound(0, 2 - (time - race_penaltyeventtime), 1);
2407                         if(a > 0)
2408                         {
2409                                 s = sprintf(_("^1PENALTY: %.1f (%s)"), race_penaltytime * 0.1, race_penaltyreason);
2410                                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.8 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2411                         }
2412                 }
2413
2414                 if(forcetime != "")
2415                 {
2416                         a = bound(0, (time - race_checkpointtime) / 0.5, 1);
2417                         drawstring_expanding(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(forcetime, FALSE, '1 1 0' * 0.6 * mySize_y), forcetime, '1 1 0' * 0.6 * mySize_y, '1 1 1', panel_fg_alpha, 0, a);
2418                 }
2419                 else
2420                         a = 1;
2421
2422                 if(race_laptime && race_checkpoint != 255)
2423                 {
2424                         s = TIME_ENCODED_TOSTRING(TIME_ENCODE(time + TIME_DECODE(race_penaltyaccumulator) - race_laptime));
2425                         drawstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, FALSE, '0.6 0.6 0' * mySize_y), s, '0.6 0.6 0' * mySize_y, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
2426                 }
2427         }
2428         else
2429         {
2430                 if(race_mycheckpointtime)
2431                 {
2432                         a = bound(0, 2 - (time - race_mycheckpointtime), 1);
2433                         s = MakeRaceString(race_mycheckpoint, TIME_DECODE(race_mycheckpointdelta), -(race_mycheckpointenemy == ""), race_mycheckpointlapsdelta, race_mycheckpointenemy);
2434                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2435                 }
2436                 if(race_othercheckpointtime && race_othercheckpointenemy != "")
2437                 {
2438                         a = bound(0, 2 - (time - race_othercheckpointtime), 1);
2439                         s = MakeRaceString(race_othercheckpoint, -TIME_DECODE(race_othercheckpointdelta), -(race_othercheckpointenemy == ""), race_othercheckpointlapsdelta, race_othercheckpointenemy);
2440                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2441                 }
2442
2443                 if(race_penaltytime && !race_penaltyaccumulator)
2444                 {
2445                         t = race_penaltytime * 0.1 + race_penaltyeventtime;
2446                         a = bound(0, (1 + t - time), 1);
2447                         if(a > 0)
2448                         {
2449                                 if(time < t)
2450                                         s = sprintf(_("^1PENALTY: %.1f (%s)"), (t - time) * 0.1, race_penaltyreason);
2451                                 else
2452                                         s = sprintf(_("^2PENALTY: %.1f (%s)"), 0, race_penaltyreason);
2453                                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2454                         }
2455                 }
2456         }
2457
2458         draw_endBoldFont();
2459 }
2460
2461 // Vote window (#9)
2462 //
2463 float vote_yescount;
2464 float vote_nocount;
2465 float vote_needed;
2466 float vote_highlighted; // currently selected vote
2467
2468 float vote_active; // is there an active vote?
2469 float vote_prev; // previous state of vote_active to check for a change
2470 float vote_alpha;
2471 float vote_change; // "time" when vote_active changed
2472
2473 void HUD_Vote(void)
2474 {
2475         if(autocvar_cl_allow_uid2name == -1 && (gametype == MAPINFO_TYPE_CTS || gametype == MAPINFO_TYPE_RACE || (serverflags & SERVERFLAG_PLAYERSTATS)))
2476         {
2477                 vote_active = 1;
2478                 if (autocvar__hud_configure)
2479                 {
2480                         vote_yescount = 0;
2481                         vote_nocount = 0;
2482                         print(_("^1You must answer before entering hud configure mode\n"));
2483                         cvar_set("_hud_configure", "0");
2484                 }
2485                 if(vote_called_vote)
2486                         strunzone(vote_called_vote);
2487                 vote_called_vote = strzone(_("^2Name ^7instead of \"^1Anonymous player^7\" in stats"));
2488                 uid2name_dialog = 1;
2489         }
2490
2491         if(!autocvar__hud_configure)
2492         {
2493                 if(!autocvar_hud_panel_vote) return;
2494
2495                 panel_fg_alpha = autocvar_hud_panel_fg_alpha;
2496                 panel_bg_alpha_str = autocvar_hud_panel_vote_bg_alpha;
2497
2498                 if(panel_bg_alpha_str == "") {
2499                         panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);
2500                 }
2501                 panel_bg_alpha = stof(panel_bg_alpha_str);
2502         }
2503         else
2504         {
2505                 vote_yescount = 3;
2506                 vote_nocount = 2;
2507                 vote_needed = 4;
2508         }
2509
2510         string s;
2511         float a;
2512         if(vote_active != vote_prev) {
2513                 vote_change = time;
2514                 vote_prev = vote_active;
2515         }
2516
2517         if(vote_active || autocvar__hud_configure)
2518                 vote_alpha = bound(0, (time - vote_change) * 2, 1);
2519         else
2520                 vote_alpha = bound(0, 1 - (time - vote_change) * 2, 1);
2521
2522         if(!vote_alpha)
2523                 return;
2524
2525         HUD_Panel_UpdateCvars();
2526
2527         if(uid2name_dialog)
2528         {
2529                 panel_pos = eX * 0.3 * vid_conwidth + eY * 0.1 * vid_conheight;
2530                 panel_size = eX * 0.4 * vid_conwidth + eY * 0.3 * vid_conheight;
2531         }
2532
2533     // these must be below above block
2534         vector pos, mySize;
2535         pos = panel_pos;
2536         mySize = panel_size;
2537
2538         a = vote_alpha * (vote_highlighted ? autocvar_hud_panel_vote_alreadyvoted_alpha : 1);
2539         HUD_Panel_DrawBg(a);
2540         a = panel_fg_alpha * a;
2541
2542         if(panel_bg_padding)
2543         {
2544                 pos += '1 1 0' * panel_bg_padding;
2545                 mySize -= '2 2 0' * panel_bg_padding;
2546         }
2547
2548         // always force 3:1 aspect
2549         vector newSize = '0 0 0';
2550         if(mySize_x/mySize_y > 3)
2551         {
2552                 newSize_x = 3 * mySize_y;
2553                 newSize_y = mySize_y;
2554
2555                 pos_x = pos_x + (mySize_x - newSize_x) / 2;
2556         }
2557         else
2558         {
2559                 newSize_y = 1/3 * mySize_x;
2560                 newSize_x = mySize_x;
2561
2562                 pos_y = pos_y + (mySize_y - newSize_y) / 2;
2563         }
2564         mySize = newSize;
2565
2566         s = _("A vote has been called for:");
2567         if(uid2name_dialog)
2568                 s = _("Allow servers to store and display your name?");
2569         drawstring_aspect(pos, s, eX * mySize_x + eY * (2/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2570         s = textShortenToWidth(vote_called_vote, mySize_x, '1 1 0' * mySize_y * (1/8), stringwidth_colors);
2571         if(autocvar__hud_configure)
2572                 s = _("^1Configure the HUD");
2573         drawcolorcodedstring_aspect(pos + eY * (2/8) * mySize_y, s, eX * mySize_x + eY * (1.75/8) * mySize_y, a, DRAWFLAG_NORMAL);
2574
2575         // print the yes/no counts
2576     s = sprintf(_("Yes (%s): %d"), getcommandkey("vyes", "vyes"), vote_yescount);
2577         drawstring_aspect(pos + eY * (4/8) * mySize_y, s, eX * 0.5 * mySize_x + eY * (1.5/8) * mySize_y, '0 1 0', a, DRAWFLAG_NORMAL);
2578     s = sprintf(_("No (%s): %d"), getcommandkey("vno", "vno"), vote_nocount);
2579         drawstring_aspect(pos + eX * 0.5 * mySize_x + eY * (4/8) * mySize_y, s, eX * 0.5 * mySize_x + eY * (1.5/8) * mySize_y, '1 0 0', a, DRAWFLAG_NORMAL);
2580
2581         // draw the progress bar backgrounds
2582         drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_back", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2583
2584         // draw the highlights
2585         if(vote_highlighted == 1) {
2586                 drawsetcliparea(pos_x, pos_y, mySize_x * 0.5, mySize_y);
2587                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_voted", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2588         }
2589         else if(vote_highlighted == -1) {
2590                 drawsetcliparea(pos_x + 0.5 * mySize_x, pos_y, mySize_x * 0.5, mySize_y);
2591                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_voted", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2592         }
2593
2594         // draw the progress bars
2595         if(vote_yescount && vote_needed)
2596         {
2597                 drawsetcliparea(pos_x, pos_y, mySize_x * 0.5 * (vote_yescount/vote_needed), mySize_y);
2598                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_prog", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2599         }
2600
2601         if(vote_nocount && vote_needed)
2602         {
2603                 drawsetcliparea(pos_x + mySize_x - mySize_x * 0.5 * (vote_nocount/vote_needed), pos_y, mySize_x * 0.5, mySize_y);
2604                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_prog", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2605         }
2606
2607         drawresetcliparea();
2608 }
2609
2610 // Mod icons panel (#10)
2611 //
2612
2613 float mod_active; // is there any active mod icon?
2614
2615 void DrawCAItem(vector myPos, vector mySize, float aspect_ratio, float layout, float i)
2616 {
2617         float stat;
2618         string pic;
2619         vector color;
2620 #ifdef GMQCC
2621         stat = -1;
2622         pic = "";
2623         color = '0 0 0';
2624 #endif
2625         switch(i)
2626         {
2627                 case 0:
2628                         stat = getstati(STAT_REDALIVE);
2629                         pic = "player_red.tga";
2630                         color = '1 0 0';
2631                         break;
2632                 case 1:
2633                         stat = getstati(STAT_BLUEALIVE);
2634                         pic = "player_blue.tga";
2635                         color = '0 0 1';
2636                         break;
2637                 case 2:
2638                         stat = getstati(STAT_YELLOWALIVE);
2639                         pic = "player_yellow.tga";
2640                         color = '1 1 0';
2641                         break;
2642                 default:
2643                 case 3:
2644                         stat = getstati(STAT_PINKALIVE);
2645                         pic = "player_pink.tga";
2646                         color = '1 0 1';
2647                         break;
2648         }
2649
2650         if(mySize_x/mySize_y > aspect_ratio)
2651         {
2652                 i = aspect_ratio * mySize_y;
2653                 myPos_x = myPos_x + (mySize_x - i) / 2;
2654                 mySize_x = i;
2655         }
2656         else
2657         {
2658                 i = 1/aspect_ratio * mySize_x;
2659                 myPos_y = myPos_y + (mySize_y - i) / 2;
2660                 mySize_y = i;
2661         }
2662
2663         if(layout)
2664         {
2665                 drawpic_aspect_skin(myPos, pic, eX * 0.7 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2666                 drawstring_aspect(myPos + eX * 0.7 * mySize_x, ftos(stat), eX * 0.3 * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2667         }
2668         else
2669                 drawstring_aspect(myPos, ftos(stat), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2670 }
2671
2672 // Clan Arena and Freeze Tag HUD modicons
2673 void HUD_Mod_CA(vector myPos, vector mySize)
2674 {
2675         mod_active = 1; // required in each mod function that always shows something
2676
2677         float layout;
2678         if(gametype == MAPINFO_TYPE_CA)
2679                 layout = autocvar_hud_panel_modicons_ca_layout;
2680         else //if(gametype == MAPINFO_TYPE_FREEZETAG)
2681                 layout = autocvar_hud_panel_modicons_freezetag_layout;
2682         float rows, columns, aspect_ratio;
2683         rows = mySize_y/mySize_x;
2684         aspect_ratio = (layout) ? 2 : 1;
2685         rows = bound(1, floor((sqrt((4 * aspect_ratio * team_count + rows) * rows) + rows + 0.5) / 2), team_count);
2686         columns = ceil(team_count/rows);
2687
2688         int i;
2689         float row = 0, column = 0;
2690         vector pos, itemSize;
2691         itemSize = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
2692         for(i=0; i<team_count; ++i)
2693         {
2694                 pos = myPos + eX * column * itemSize_x + eY * row * itemSize_y;
2695
2696                 DrawCAItem(pos, itemSize, aspect_ratio, layout, i);
2697
2698                 ++row;
2699                 if(row >= rows)
2700                 {
2701                         row = 0;
2702                         ++column;
2703                 }
2704         }
2705 }
2706
2707 // CTF HUD modicon section
2708 float redflag_prevframe, blueflag_prevframe; // status during previous frame
2709 float redflag_prevstatus, blueflag_prevstatus; // last remembered status
2710 float redflag_statuschange_time, blueflag_statuschange_time; // time when the status changed
2711
2712 void HUD_Mod_CTF_Reset(void)
2713 {
2714         redflag_prevstatus = blueflag_prevstatus = redflag_prevframe = blueflag_prevframe = redflag_statuschange_time = blueflag_statuschange_time = 0;
2715 }
2716
2717 void HUD_Mod_CTF(vector pos, vector mySize)
2718 {
2719         vector redflag_pos, blueflag_pos;
2720         vector flag_size;
2721         float f; // every function should have that
2722
2723         float redflag, blueflag; // current status
2724         float redflag_statuschange_elapsedtime, blueflag_statuschange_elapsedtime; // time since the status changed
2725         float stat_items;
2726
2727         stat_items = getstati(STAT_ITEMS, 0, 24);
2728         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
2729         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
2730
2731         if(redflag || blueflag)
2732                 mod_active = 1;
2733         else
2734                 mod_active = 0;
2735
2736         if(autocvar__hud_configure)
2737         {
2738                 redflag = 1;
2739                 blueflag = 2;
2740         }
2741
2742         // when status CHANGES, set old status into prevstatus and current status into status
2743         if (redflag != redflag_prevframe)
2744         {
2745                 redflag_statuschange_time = time;
2746                 redflag_prevstatus = redflag_prevframe;
2747                 redflag_prevframe = redflag;
2748         }
2749
2750         if (blueflag != blueflag_prevframe)
2751         {
2752                 blueflag_statuschange_time = time;
2753                 blueflag_prevstatus = blueflag_prevframe;
2754                 blueflag_prevframe = blueflag;
2755         }
2756
2757         redflag_statuschange_elapsedtime = time - redflag_statuschange_time;
2758         blueflag_statuschange_elapsedtime = time - blueflag_statuschange_time;
2759
2760         float BLINK_FACTOR = 0.15;
2761         float BLINK_BASE = 0.85;
2762         // note:
2763         //   RMS = sqrt(BLINK_BASE^2 + 0.5 * BLINK_FACTOR^2)
2764         // thus
2765         //   BLINK_BASE = sqrt(RMS^2 - 0.5 * BLINK_FACTOR^2)
2766         // ensure RMS == 1
2767         float BLINK_FREQ = 5; // circle frequency, = 2*pi*frequency in hertz
2768
2769         string red_icon, red_icon_prevstatus;
2770         float red_alpha, red_alpha_prevstatus;
2771         red_alpha = red_alpha_prevstatus = 1;
2772         switch(redflag) {
2773                 case 1: red_icon = "flag_red_taken"; break;
2774                 case 2: red_icon = "flag_red_lost"; break;
2775                 case 3: red_icon = "flag_red_carrying"; red_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2776                 default:
2777                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2778                                 red_icon = "flag_red_shielded";
2779                         else
2780                                 red_icon = string_null;
2781                         break;
2782         }
2783         switch(redflag_prevstatus) {
2784                 case 1: red_icon_prevstatus = "flag_red_taken"; break;
2785                 case 2: red_icon_prevstatus = "flag_red_lost"; break;
2786                 case 3: red_icon_prevstatus = "flag_red_carrying"; red_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2787                 default:
2788                         if(redflag == 3)
2789                                 red_icon_prevstatus = "flag_red_carrying"; // make it more visible
2790                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2791                                 red_icon_prevstatus = "flag_red_shielded";
2792                         else
2793                                 red_icon_prevstatus = string_null;
2794                         break;
2795         }
2796
2797         string blue_icon, blue_icon_prevstatus;
2798         float blue_alpha, blue_alpha_prevstatus;
2799         blue_alpha = blue_alpha_prevstatus = 1;
2800         switch(blueflag) {
2801                 case 1: blue_icon = "flag_blue_taken"; break;
2802                 case 2: blue_icon = "flag_blue_lost"; break;
2803                 case 3: blue_icon = "flag_blue_carrying"; blue_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2804                 default:
2805                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2806                                 blue_icon = "flag_blue_shielded";
2807                         else
2808                                 blue_icon = string_null;
2809                         break;
2810         }
2811         switch(blueflag_prevstatus) {
2812                 case 1: blue_icon_prevstatus = "flag_blue_taken"; break;
2813                 case 2: blue_icon_prevstatus = "flag_blue_lost"; break;
2814                 case 3: blue_icon_prevstatus = "flag_blue_carrying"; blue_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2815                 default:
2816                         if(blueflag == 3)
2817                                 blue_icon_prevstatus = "flag_blue_carrying"; // make it more visible
2818                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2819                                 blue_icon_prevstatus = "flag_blue_shielded";
2820                         else
2821                                 blue_icon_prevstatus = string_null;
2822                         break;
2823         }
2824
2825         if(mySize_x > mySize_y) {
2826                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2827                         redflag_pos = pos;
2828                         blueflag_pos = pos + eX * 0.5 * mySize_x;
2829                 } else {
2830                         blueflag_pos = pos;
2831                         redflag_pos = pos + eX * 0.5 * mySize_x;
2832                 }
2833                 flag_size = eX * 0.5 * mySize_x + eY * mySize_y;
2834         } else {
2835                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2836                         redflag_pos = pos;
2837                         blueflag_pos = pos + eY * 0.5 * mySize_y;
2838                 } else {
2839                         blueflag_pos = pos;
2840                         redflag_pos = pos + eY * 0.5 * mySize_y;
2841                 }
2842                 flag_size = eY * 0.5 * mySize_y + eX * mySize_x;
2843         }
2844
2845         f = bound(0, redflag_statuschange_elapsedtime*2, 1);
2846         if(red_icon_prevstatus && f < 1)
2847                 drawpic_aspect_skin_expanding(redflag_pos, red_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * red_alpha_prevstatus, DRAWFLAG_NORMAL, f);
2848         if(red_icon)
2849                 drawpic_aspect_skin(redflag_pos, red_icon, flag_size, '1 1 1', panel_fg_alpha * red_alpha * f, DRAWFLAG_NORMAL);
2850
2851         f = bound(0, blueflag_statuschange_elapsedtime*2, 1);
2852         if(blue_icon_prevstatus && f < 1)
2853                 drawpic_aspect_skin_expanding(blueflag_pos, blue_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * blue_alpha_prevstatus, DRAWFLAG_NORMAL, f);
2854         if(blue_icon)
2855                 drawpic_aspect_skin(blueflag_pos, blue_icon, flag_size, '1 1 1', panel_fg_alpha * blue_alpha * f, DRAWFLAG_NORMAL);
2856 }
2857
2858 // Keyhunt HUD modicon section
2859 float kh_runheretime;
2860
2861 void HUD_Mod_KH_Reset(void)
2862 {
2863         kh_runheretime = 0;
2864 }
2865
2866 void HUD_Mod_KH(vector pos, vector mySize)
2867 {
2868         mod_active = 1; // keyhunt should never hide the mod icons panel
2869         float kh_keys;
2870         float keyteam;
2871         float a, aa;
2872         vector p = '0 0 0', pa, kh_size = '0 0 0', kh_asize = '0 0 0';
2873
2874         kh_keys = getstati(STAT_KH_KEYS);
2875
2876         p_x = pos_x;
2877         if(mySize_x > mySize_y)
2878         {
2879                 p_y = pos_y + 0.25 * mySize_y;
2880                 pa = p - eY * 0.25 * mySize_y;
2881
2882                 kh_size_x = mySize_x * 0.25;
2883                 kh_size_y = 0.75 * mySize_y;
2884                 kh_asize_x = mySize_x * 0.25;
2885                 kh_asize_y = mySize_y * 0.25;
2886         }
2887         else
2888         {
2889                 p_y = pos_y + 0.125 * mySize_y;
2890                 pa = p - eY * 0.125 * mySize_y;
2891
2892                 kh_size_x = mySize_x * 0.5;
2893                 kh_size_y = 0.375 * mySize_y;
2894                 kh_asize_x = mySize_x * 0.5;
2895                 kh_asize_y = mySize_y * 0.125;
2896         }
2897
2898         float i, key;
2899
2900         float keycount;
2901         keycount = 0;
2902         for(i = 0; i < 4; ++i)
2903         {
2904                 key = floor(kh_keys / pow(32, i)) & 31;
2905                 keyteam = key - 1;
2906                 if(keyteam == 30 && keycount <= 4)
2907                         keycount += 4;
2908                 if(keyteam == myteam || keyteam == -1 || keyteam == 30)
2909                         keycount += 1;
2910         }
2911
2912         // this yields 8 exactly if "RUN HERE" shows
2913
2914         if(keycount == 8)
2915         {
2916                 if(!kh_runheretime)
2917                         kh_runheretime = time;
2918                 pa_y -= fabs(sin((time - kh_runheretime) * 3.5)) * 6; // make the arrows jump in case of RUN HERE
2919         }
2920         else
2921                 kh_runheretime = 0;
2922
2923         for(i = 0; i < 4; ++i)
2924         {
2925                 key = floor(kh_keys / pow(32, i)) & 31;
2926                 keyteam = key - 1;
2927                 switch(keyteam)
2928                 {
2929                         case 30: // my key
2930                                 keyteam = myteam;
2931                                 a = 1;
2932                                 aa = 1;
2933                                 break;
2934                         case -1: // no key
2935                                 a = 0;
2936                                 aa = 0;
2937                                 break;
2938                         default: // owned or dropped
2939                                 a = 0.2;
2940                                 aa = 0.5;
2941                                 break;
2942                 }
2943                 a = a * panel_fg_alpha;
2944                 aa = aa * panel_fg_alpha;
2945                 if(a > 0)
2946                 {
2947                         switch(keyteam)
2948                         {
2949                                 case NUM_TEAM_1:
2950                                         drawpic_aspect_skin(pa, "kh_redarrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2951                                         break;
2952                                 case NUM_TEAM_2:
2953                                         drawpic_aspect_skin(pa, "kh_bluearrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2954                                         break;
2955                                 case NUM_TEAM_3:
2956                                         drawpic_aspect_skin(pa, "kh_yellowarrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2957                                         break;
2958                                 case NUM_TEAM_4:
2959                                         drawpic_aspect_skin(pa, "kh_pinkarrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2960                                         break;
2961                                 default:
2962                                         break;
2963                         }
2964                         switch(i) // YAY! switch(i) inside a for loop for i. DailyWTF, here we come!
2965                         {
2966                                 case 0:
2967                                         drawpic_aspect_skin(p, "kh_red", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2968                                         break;
2969                                 case 1:
2970                                         drawpic_aspect_skin(p, "kh_blue", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2971                                         break;
2972                                 case 2:
2973                                         drawpic_aspect_skin(p, "kh_yellow", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2974                                         break;
2975                                 case 3:
2976                                         drawpic_aspect_skin(p, "kh_pink", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2977                                         break;
2978                         }
2979                 }
2980                 if(mySize_x > mySize_y)
2981                 {
2982                         p_x += 0.25 * mySize_x;
2983                         pa_x += 0.25 * mySize_x;
2984                 }
2985                 else
2986                 {
2987                         if(i == 1)
2988                         {
2989                                 p_y = pos_y + 0.625 * mySize_y;
2990                                 pa_y = pos_y + 0.5 * mySize_y;
2991                                 p_x = pos_x;
2992                                 pa_x = pos_x;
2993                         }
2994                         else
2995                         {
2996                                 p_x += 0.5 * mySize_x;
2997                                 pa_x += 0.5 * mySize_x;
2998                         }
2999                 }
3000         }
3001 }
3002
3003 // Keepaway HUD mod icon
3004 float kaball_prevstatus; // last remembered status
3005 float kaball_statuschange_time; // time when the status changed
3006
3007 // we don't need to reset for keepaway since it immediately
3008 // autocorrects prevstatus as to if the player has the ball or not
3009
3010 void HUD_Mod_Keepaway(vector pos, vector mySize)
3011 {
3012         mod_active = 1; // keepaway should always show the mod HUD
3013
3014         float BLINK_FACTOR = 0.15;
3015         float BLINK_BASE = 0.85;
3016         float BLINK_FREQ = 5;
3017         float kaball_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
3018
3019         float stat_items = getstati(STAT_ITEMS, 0, 24);
3020         float kaball = (stat_items/IT_KEY1) & 1;
3021
3022         if(kaball != kaball_prevstatus)
3023         {
3024                 kaball_statuschange_time = time;
3025                 kaball_prevstatus = kaball;
3026         }
3027
3028         vector kaball_pos, kaball_size;
3029
3030         if(mySize_x > mySize_y) {
3031                 kaball_pos = pos + eX * 0.25 * mySize_x;
3032                 kaball_size = eX * 0.5 * mySize_x + eY * mySize_y;
3033         } else {
3034                 kaball_pos = pos + eY * 0.25 * mySize_y;
3035                 kaball_size = eY * 0.5 * mySize_y + eX * mySize_x;
3036         }
3037
3038         float kaball_statuschange_elapsedtime = time - kaball_statuschange_time;
3039         float f = bound(0, kaball_statuschange_elapsedtime*2, 1);
3040
3041         if(kaball_prevstatus && f < 1)
3042                 drawpic_aspect_skin_expanding(kaball_pos, "keepawayball_carrying", kaball_size, '1 1 1', panel_fg_alpha * kaball_alpha, DRAWFLAG_NORMAL, f);
3043
3044         if(kaball)
3045                 drawpic_aspect_skin(pos, "keepawayball_carrying", eX * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha * kaball_alpha * f, DRAWFLAG_NORMAL);
3046 }
3047
3048
3049 // Nexball HUD mod icon
3050 void HUD_Mod_NexBall(vector pos, vector mySize)
3051 {
3052         float stat_items, nb_pb_starttime, dt, p;
3053
3054         stat_items = getstati(STAT_ITEMS, 0, 24);
3055         nb_pb_starttime = getstatf(STAT_NB_METERSTART);
3056
3057         if (stat_items & IT_KEY1)
3058                 mod_active = 1;
3059         else
3060                 mod_active = 0;
3061
3062         //Manage the progress bar if any
3063         if (nb_pb_starttime > 0)
3064         {
3065                 dt = mod(time - nb_pb_starttime, nb_pb_period);
3066                 // one period of positive triangle
3067                 p = 2 * dt / nb_pb_period;
3068                 if (p > 1)
3069                         p = 2 - p;
3070
3071                 HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", p, (mySize_x <= mySize_y), 0, autocvar_hud_progressbar_nexball_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3072         }
3073
3074         if (stat_items & IT_KEY1)
3075                 drawpic_aspect_skin(pos, "nexball_carrying", eX * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3076 }
3077
3078 // Race/CTS HUD mod icons
3079 float crecordtime_prev; // last remembered crecordtime
3080 float crecordtime_change_time; // time when crecordtime last changed
3081 float srecordtime_prev; // last remembered srecordtime
3082 float srecordtime_change_time; // time when srecordtime last changed
3083
3084 float race_status_time;
3085 float race_status_prev;
3086 string race_status_name_prev;
3087 void HUD_Mod_Race(vector pos, vector mySize)
3088 {
3089         mod_active = 1; // race should never hide the mod icons panel
3090         entity me;
3091         me = playerslots[player_localnum];
3092         float t, score;
3093         float f; // yet another function has this
3094         score = me.(scores[ps_primary]);
3095
3096         if(!(scores_flags[ps_primary] & SFL_TIME) || teamplay) // race/cts record display on HUD
3097                 return; // no records in the actual race
3098
3099         // clientside personal record
3100         string rr;
3101         if(gametype == MAPINFO_TYPE_CTS)
3102                 rr = CTS_RECORD;
3103         else
3104                 rr = RACE_RECORD;
3105         t = stof(db_get(ClientProgsDB, strcat(shortmapname, rr, "time")));
3106
3107         if(score && (score < t || !t)) {
3108                 db_put(ClientProgsDB, strcat(shortmapname, rr, "time"), ftos(score));
3109                 if(autocvar_cl_autodemo_delete_keeprecords)
3110                 {
3111                         f = autocvar_cl_autodemo_delete;
3112                         f &= ~1;
3113                         cvar_set("cl_autodemo_delete", ftos(f)); // don't delete demo with new record!
3114                 }
3115         }
3116
3117         if(t != crecordtime_prev) {
3118                 crecordtime_prev = t;
3119                 crecordtime_change_time = time;
3120         }
3121
3122         vector textPos, medalPos;
3123         float squareSize;
3124         if(mySize_x > mySize_y) {
3125                 // text on left side
3126                 squareSize = min(mySize_y, mySize_x/2);
3127                 textPos = pos + eX * 0.5 * max(0, mySize_x/2 - squareSize) + eY * 0.5 * (mySize_y - squareSize);
3128                 medalPos = pos + eX * 0.5 * max(0, mySize_x/2 - squareSize) + eX * 0.5 * mySize_x + eY * 0.5 * (mySize_y - squareSize);
3129         } else {
3130                 // text on top
3131                 squareSize = min(mySize_x, mySize_y/2);
3132                 textPos = pos + eY * 0.5 * max(0, mySize_y/2 - squareSize) + eX * 0.5 * (mySize_x - squareSize);
3133                 medalPos = pos + eY * 0.5 * max(0, mySize_y/2 - squareSize) + eY * 0.5 * mySize_y + eX * 0.5 * (mySize_x - squareSize);
3134         }
3135
3136         f = time - crecordtime_change_time;
3137
3138         if (f > 1) {
3139                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3140                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3141         } else {
3142                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3143                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3144                 drawstring_aspect_expanding(pos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3145                 drawstring_aspect_expanding(pos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3146         }
3147
3148         // server record
3149         t = race_server_record;
3150         if(t != srecordtime_prev) {
3151                 srecordtime_prev = t;
3152                 srecordtime_change_time = time;
3153         }
3154         f = time - srecordtime_change_time;
3155
3156         if (f > 1) {
3157                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3158                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3159         } else {
3160                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3161                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3162                 drawstring_aspect_expanding(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3163                 drawstring_aspect_expanding(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3164         }
3165
3166         if (race_status != race_status_prev || race_status_name != race_status_name_prev) {
3167                 race_status_time = time + 5;
3168                 race_status_prev = race_status;
3169                 if (race_status_name_prev)
3170                         strunzone(race_status_name_prev);
3171                 race_status_name_prev = strzone(race_status_name);
3172         }
3173
3174         // race "awards"
3175         float a;
3176         a = bound(0, race_status_time - time, 1);
3177
3178         string s;
3179         s = textShortenToWidth(race_status_name, squareSize, '1 1 0' * 0.1 * squareSize, stringwidth_colors);
3180
3181         float rank;
3182         if(race_status > 0)
3183                 rank = race_CheckName(race_status_name);
3184         else
3185                 rank = 0;
3186         string rankname;
3187         rankname = count_ordinal(rank);
3188
3189         vector namepos;
3190         namepos = medalPos + '0 0.8 0' * squareSize;
3191         vector rankpos;
3192         rankpos = medalPos + '0 0.15 0' * squareSize;
3193
3194         if(race_status == 0)
3195                 drawpic_aspect_skin(medalPos, "race_newfail", '1 1 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3196         else if(race_status == 1) {
3197                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newtime", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3198                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3199                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3200         } else if(race_status == 2) {
3201                 if(race_status_name == GetPlayerName(player_localnum) || !race_myrank || race_myrank < rank)
3202                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankgreen", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3203                 else
3204                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankyellow", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3205                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3206                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3207         } else if(race_status == 3) {
3208                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrecordserver", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3209                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3210                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3211         }
3212
3213         if (race_status_time - time <= 0) {
3214                 race_status_prev = -1;
3215                 race_status = -1;
3216                 if(race_status_name)
3217                         strunzone(race_status_name);
3218                 race_status_name = string_null;
3219                 if(race_status_name_prev)
3220                         strunzone(race_status_name_prev);
3221                 race_status_name_prev = string_null;
3222         }
3223 }
3224
3225 void DrawDomItem(vector myPos, vector mySize, float aspect_ratio, float layout, float i)
3226 {
3227         float stat, pps_ratio;
3228         string pic;
3229         vector color;
3230 #ifdef GMQCC
3231         stat = -1;
3232         pic = "";
3233         color = '0 0 0';
3234 #endif
3235         switch(i)
3236         {
3237                 case 0:
3238                         stat = getstatf(STAT_DOM_PPS_RED);
3239                         pic = "dom_icon_red";
3240                         color = '1 0 0';
3241                         break;
3242                 case 1:
3243                         stat = getstatf(STAT_DOM_PPS_BLUE);
3244                         pic = "dom_icon_blue";
3245                         color = '0 0 1';
3246                         break;
3247                 case 2:
3248                         stat = getstatf(STAT_DOM_PPS_YELLOW);
3249                         pic = "dom_icon_yellow";
3250                         color = '1 1 0';
3251                         break;
3252                 default:
3253                 case 3:
3254                         stat = getstatf(STAT_DOM_PPS_PINK);
3255                         pic = "dom_icon_pink";
3256                         color = '1 0 1';
3257                         break;
3258         }
3259         pps_ratio = stat / getstatf(STAT_DOM_TOTAL_PPS);
3260
3261         if(mySize_x/mySize_y > aspect_ratio)
3262         {
3263                 i = aspect_ratio * mySize_y;
3264                 myPos_x = myPos_x + (mySize_x - i) / 2;
3265                 mySize_x = i;
3266         }
3267         else
3268         {
3269                 i = 1/aspect_ratio * mySize_x;
3270                 myPos_y = myPos_y + (mySize_y - i) / 2;
3271                 mySize_y = i;
3272         }
3273
3274         if (layout) // show text too
3275         {
3276                 //draw the text
3277                 color *= 0.5 + pps_ratio * (1 - 0.5); // half saturated color at min, full saturated at max
3278                 if (layout == 2) // average pps
3279                         drawstring_aspect(myPos + eX * mySize_y, ftos_decimals(stat, 2), eX * (2/3) * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3280                 else // percentage of average pps
3281                         drawstring_aspect(myPos + eX * mySize_y, strcat( ftos(floor(pps_ratio*100 + 0.5)), "%" ), eX * (2/3) * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3282         }
3283
3284         //draw the icon
3285         drawpic_aspect_skin(myPos, pic, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3286         if (stat > 0)
3287         {
3288                 drawsetcliparea(myPos_x, myPos_y + mySize_y * (1 - pps_ratio), mySize_y, mySize_y * pps_ratio);
3289                 drawpic_aspect_skin(myPos, strcat(pic, "-highlighted"), '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3290                 drawresetcliparea();
3291         }
3292 }
3293
3294 void HUD_Mod_Dom(vector myPos, vector mySize)
3295 {
3296         mod_active = 1; // required in each mod function that always shows something
3297
3298         float layout = autocvar_hud_panel_modicons_dom_layout;
3299         float rows, columns, aspect_ratio;
3300         rows = mySize_y/mySize_x;
3301         aspect_ratio = (layout) ? 3 : 1;
3302         rows = bound(1, floor((sqrt((4 * aspect_ratio * team_count + rows) * rows) + rows + 0.5) / 2), team_count);
3303         columns = ceil(team_count/rows);
3304
3305         int i;
3306         float row = 0, column = 0;
3307         vector pos, itemSize;
3308         itemSize = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
3309         for(i=0; i<team_count; ++i)
3310         {
3311                 pos = myPos + eX * column * itemSize_x + eY * row * itemSize_y;
3312
3313                 DrawDomItem(pos, itemSize, aspect_ratio, layout, i);
3314
3315                 ++row;
3316                 if(row >= rows)
3317                 {
3318                         row = 0;
3319                         ++column;
3320                 }
3321         }
3322 }
3323
3324 void HUD_ModIcons_SetFunc()
3325 {
3326         switch(gametype)
3327         {
3328                 case MAPINFO_TYPE_KEYHUNT:              HUD_ModIcons_GameType = HUD_Mod_KH; break;
3329                 case MAPINFO_TYPE_CTF:                  HUD_ModIcons_GameType = HUD_Mod_CTF; break;
3330                 case MAPINFO_TYPE_NEXBALL:              HUD_ModIcons_GameType = HUD_Mod_NexBall; break;
3331                 case MAPINFO_TYPE_CTS:
3332                 case MAPINFO_TYPE_RACE:         HUD_ModIcons_GameType = HUD_Mod_Race; break;
3333                 case MAPINFO_TYPE_CA:
3334                 case MAPINFO_TYPE_FREEZETAG:    HUD_ModIcons_GameType = HUD_Mod_CA; break;
3335                 case MAPINFO_TYPE_DOMINATION:   HUD_ModIcons_GameType = HUD_Mod_Dom; break;
3336                 case MAPINFO_TYPE_KEEPAWAY:     HUD_ModIcons_GameType = HUD_Mod_Keepaway; break;
3337         }
3338 }
3339
3340 float mod_prev; // previous state of mod_active to check for a change
3341 float mod_alpha;
3342 float mod_change; // "time" when mod_active changed
3343
3344 void HUD_ModIcons(void)
3345 {
3346         if(!autocvar__hud_configure)
3347         {
3348                 if(!autocvar_hud_panel_modicons) return;
3349                 if(!HUD_ModIcons_GameType) return;
3350         }
3351
3352         HUD_Panel_UpdateCvars();
3353
3354         draw_beginBoldFont();
3355
3356         if(mod_active != mod_prev) {
3357                 mod_change = time;
3358                 mod_prev = mod_active;
3359         }
3360
3361         if(mod_active || autocvar__hud_configure)
3362                 mod_alpha = bound(0, (time - mod_change) * 2, 1);
3363         else
3364                 mod_alpha = bound(0, 1 - (time - mod_change) * 2, 1);
3365
3366         if(mod_alpha)
3367                 HUD_Panel_DrawBg(mod_alpha);
3368
3369         if(panel_bg_padding)
3370         {
3371                 panel_pos += '1 1 0' * panel_bg_padding;
3372                 panel_size -= '2 2 0' * panel_bg_padding;
3373         }
3374
3375         if(autocvar__hud_configure)
3376                 HUD_Mod_CTF(panel_pos, panel_size);
3377         else
3378                 HUD_ModIcons_GameType(panel_pos, panel_size);
3379
3380         draw_endBoldFont();
3381 }
3382
3383 // Draw pressed keys (#11)
3384 //
3385 void HUD_PressedKeys(void)
3386 {
3387         if(!autocvar__hud_configure)
3388         {
3389                 if(!autocvar_hud_panel_pressedkeys) return;
3390                 if(spectatee_status <= 0 && autocvar_hud_panel_pressedkeys < 2) return;
3391         }
3392
3393         HUD_Panel_UpdateCvars();
3394         vector pos, mySize;
3395         pos = panel_pos;
3396         mySize = panel_size;
3397
3398         HUD_Panel_DrawBg(1);
3399         if(panel_bg_padding)
3400         {
3401                 pos += '1 1 0' * panel_bg_padding;
3402                 mySize -= '2 2 0' * panel_bg_padding;
3403         }
3404
3405         // force custom aspect
3406         float aspect = autocvar_hud_panel_pressedkeys_aspect;
3407         if(aspect)
3408         {
3409                 vector newSize = '0 0 0';
3410                 if(mySize_x/mySize_y > aspect)
3411                 {
3412                         newSize_x = aspect * mySize_y;
3413                         newSize_y = mySize_y;
3414
3415                         pos_x = pos_x + (mySize_x - newSize_x) / 2;
3416                 }
3417                 else
3418                 {
3419                         newSize_y = 1/aspect * mySize_x;
3420                         newSize_x = mySize_x;
3421
3422                         pos_y = pos_y + (mySize_y - newSize_y) / 2;
3423                 }
3424                 mySize = newSize;
3425         }
3426
3427         vector keysize;
3428         keysize = eX * mySize_x * (1/3.0) + eY * mySize_y * (1/(3.0 - !autocvar_hud_panel_pressedkeys_attack));
3429         float pressedkeys;
3430         pressedkeys = getstatf(STAT_PRESSED_KEYS);
3431
3432         if(autocvar_hud_panel_pressedkeys_attack)
3433         {
3434                 drawpic_aspect_skin(pos + eX * keysize_x * 0.5, ((pressedkeys & KEY_ATCK) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3435                 drawpic_aspect_skin(pos + eX * keysize_x * 1.5, ((pressedkeys & KEY_ATCK2) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3436                 pos_y += keysize_y;
3437         }
3438
3439         drawpic_aspect_skin(pos, ((pressedkeys & KEY_CROUCH) ? "key_crouch_inv.tga" : "key_crouch.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3440         drawpic_aspect_skin(pos + eX * keysize_x, ((pressedkeys & KEY_FORWARD) ? "key_forward_inv.tga" : "key_forward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3441         drawpic_aspect_skin(pos + eX * keysize_x * 2, ((pressedkeys & KEY_JUMP) ? "key_jump_inv.tga" : "key_jump.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3442         pos_y += keysize_y;
3443         drawpic_aspect_skin(pos, ((pressedkeys & KEY_LEFT) ? "key_left_inv.tga" : "key_left.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3444         drawpic_aspect_skin(pos + eX * keysize_x, ((pressedkeys & KEY_BACKWARD) ? "key_backward_inv.tga" : "key_backward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3445         drawpic_aspect_skin(pos + eX * keysize_x * 2, ((pressedkeys & KEY_RIGHT) ? "key_right_inv.tga" : "key_right.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3446 }
3447
3448 // Handle chat as a panel (#12)
3449 //
3450 void HUD_Chat(void)
3451 {
3452         if(!autocvar__hud_configure)
3453         {
3454                 if (!autocvar_hud_panel_chat)
3455                 {
3456                         if (!autocvar_con_chatrect)
3457                                 cvar_set("con_chatrect", "0");
3458                         return;
3459                 }
3460                 if(autocvar__con_chat_maximized)
3461                 {
3462                         if(!hud_draw_maximized) return;
3463                 }
3464                 else if(chat_panel_modified)
3465                 {
3466                         panel.update_time = time; // forces reload of panel attributes
3467                         chat_panel_modified = false;
3468                 }
3469         }
3470
3471         HUD_Panel_UpdateCvars();
3472
3473         if(autocvar__con_chat_maximized && !autocvar__hud_configure) // draw at full screen height if maximized
3474         {
3475                 panel_pos_y = panel_bg_border;
3476                 panel_size_y = vid_conheight - panel_bg_border * 2;
3477                 if(panel.current_panel_bg == "0") // force a border when maximized
3478                 {
3479                         string panel_bg;
3480                         panel_bg = strcat(hud_skin_path, "/border_default");
3481                         if(precache_pic(panel_bg) == "")
3482                                 panel_bg = "gfx/hud/default/border_default";
3483                         if(panel.current_panel_bg)
3484                                 strunzone(panel.current_panel_bg);
3485                         panel.current_panel_bg = strzone(panel_bg);
3486                         chat_panel_modified = true;
3487                 }
3488                 panel_bg_alpha = max(0.75, panel_bg_alpha); // force an theAlpha of at least 0.75
3489         }
3490
3491         vector pos, mySize;
3492         pos = panel_pos;
3493         mySize = panel_size;
3494
3495         HUD_Panel_DrawBg(1);
3496
3497         if(panel_bg_padding)
3498         {
3499                 pos += '1 1 0' * panel_bg_padding;
3500                 mySize -= '2 2 0' * panel_bg_padding;
3501         }
3502
3503         if (!autocvar_con_chatrect)
3504                 cvar_set("con_chatrect", "1");
3505
3506         cvar_set("con_chatrect_x", ftos(pos_x/vid_conwidth));
3507         cvar_set("con_chatrect_y", ftos(pos_y/vid_conheight));
3508
3509         cvar_set("con_chatwidth", ftos(mySize_x/vid_conwidth));
3510         cvar_set("con_chat", ftos(floor(mySize_y/autocvar_con_chatsize - 0.5)));
3511
3512         if(autocvar__hud_configure)
3513         {
3514                 vector chatsize;
3515                 chatsize = '1 1 0' * autocvar_con_chatsize;
3516                 cvar_set("con_chatrect_x", "9001"); // over 9000, we'll fake it instead for more control over theAlpha and such
3517                 float i, a;
3518                 for(i = 0; i < autocvar_con_chat; ++i)
3519                 {
3520                         if(i == autocvar_con_chat - 1)
3521                                 a = panel_fg_alpha;
3522                         else
3523                                 a = panel_fg_alpha * floor(((i + 1) * 7 + autocvar_con_chattime)/45);
3524                         drawcolorcodedstring(pos, textShortenToWidth(_("^3Player^7: This is the chat area."), mySize_x, chatsize, stringwidth_colors), chatsize, a, DRAWFLAG_NORMAL);
3525                         pos_y += chatsize_y;
3526                 }
3527         }
3528 }
3529
3530 // Engine info panel (#13)
3531 //
3532 float prevfps;
3533 float prevfps_time;
3534 float framecounter;
3535
3536 float frametimeavg;
3537 float frametimeavg1; // 1 frame ago
3538 float frametimeavg2; // 2 frames ago
3539 void HUD_EngineInfo(void)
3540 {
3541         if(!autocvar__hud_configure)
3542         {
3543                 if(!autocvar_hud_panel_engineinfo) return;
3544         }
3545
3546         HUD_Panel_UpdateCvars();
3547         vector pos, mySize;
3548         pos = panel_pos;
3549         mySize = panel_size;
3550
3551         HUD_Panel_DrawBg(1);
3552         if(panel_bg_padding)
3553         {
3554                 pos += '1 1 0' * panel_bg_padding;
3555                 mySize -= '2 2 0' * panel_bg_padding;
3556         }
3557
3558         float currentTime = gettime(GETTIME_REALTIME);
3559         if(cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage"))
3560         {
3561                 float currentframetime = currentTime - prevfps_time;
3562                 frametimeavg = (frametimeavg + frametimeavg1 + frametimeavg2 + currentframetime)/4; // average three frametimes into framecounter for slightly more stable fps readings :P
3563                 frametimeavg2 = frametimeavg1;
3564                 frametimeavg1 = frametimeavg;
3565
3566                 float weight;
3567                 weight = cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_new_weight");
3568                 if(currentframetime > 0.0001) // filter out insane values which sometimes seem to occur and throw off the average? If you are getting 10,000 fps or more, then you don't need a framerate counter.
3569                 {
3570                         if(fabs(prevfps - (1/frametimeavg)) > prevfps * cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_instantupdate_change_threshold")) // if there was a big jump in fps, just force prevfps at current (1/currentframetime) to make big updates instant
3571                                 prevfps = (1/currentframetime);
3572                         prevfps = (1 - weight) * prevfps + weight * (1/frametimeavg); // framecounter just used so there's no need for a new variable, think of it as "frametime average"
3573                 }
3574                 prevfps_time = currentTime;
3575         }
3576         else
3577         {
3578                 framecounter += 1;
3579                 if(currentTime - prevfps_time > autocvar_hud_panel_engineinfo_framecounter_time)
3580                 {
3581                         prevfps = framecounter/(currentTime - prevfps_time);
3582                         framecounter = 0;
3583                         prevfps_time = currentTime;
3584                 }
3585         }
3586
3587         vector color;
3588         color = HUD_Get_Num_Color (prevfps, 100);
3589         drawstring_aspect(pos, sprintf(_("FPS: %.*f"), autocvar_hud_panel_engineinfo_framecounter_decimals, prevfps), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3590 }
3591
3592 // Info messages panel (#14)
3593 //
3594 #define drawInfoMessage(s)\
3595         if(autocvar_hud_panel_infomessages_flip)\
3596                 o_x = pos_x + mySize_x - stringwidth(s, TRUE, fontsize);\
3597         drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);\
3598         o_y += fontsize_y;
3599 void HUD_InfoMessages(void)
3600 {
3601         if(!autocvar__hud_configure)
3602         {
3603                 if(!autocvar_hud_panel_infomessages) return;
3604         }
3605
3606         HUD_Panel_UpdateCvars();
3607         vector pos, mySize;
3608         pos = panel_pos;
3609         mySize = panel_size;
3610
3611         HUD_Panel_DrawBg(1);
3612         if(panel_bg_padding)
3613         {
3614                 pos += '1 1 0' * panel_bg_padding;
3615                 mySize -= '2 2 0' * panel_bg_padding;
3616         }
3617
3618         // always force 5:1 aspect
3619         vector newSize = '0 0 0';
3620         if(mySize_x/mySize_y > 5)
3621         {
3622                 newSize_x = 5 * mySize_y;
3623                 newSize_y = mySize_y;
3624
3625                 pos_x = pos_x + (mySize_x - newSize_x) / 2;
3626         }
3627         else
3628         {
3629                 newSize_y = 1/5 * mySize_x;
3630                 newSize_x = mySize_x;
3631
3632                 pos_y = pos_y + (mySize_y - newSize_y) / 2;
3633         }
3634
3635         mySize = newSize;
3636         entity tm;
3637         vector o;
3638         o = pos;
3639
3640         vector fontsize;
3641         fontsize = '0.20 0.20 0' * mySize_y;
3642
3643         float a;
3644         a = panel_fg_alpha;
3645
3646         string s;
3647         if(!autocvar__hud_configure)
3648         {
3649                 if(spectatee_status && !intermission)
3650                 {
3651                         a = 1;
3652                         if(spectatee_status == -1)
3653                                 s = _("^1Observing");
3654                         else
3655 #ifdef COMPAT_XON050_ENGINE
3656                                 s = sprintf(_("^1Spectating: ^7%s"), GetPlayerName(spectatee_status - 1));
3657 #else
3658                                 s = sprintf(_("^1Spectating: ^7%s"), GetPlayerName(player_localentnum - 1));
3659 #endif
3660                         drawInfoMessage(s)
3661
3662                         if(spectatee_status == -1)
3663                                 s = sprintf(_("^1Press ^3%s^1 to spectate"), getcommandkey("primary fire", "+fire"));
3664                         else
3665                                 s = sprintf(_("^1Press ^3%s^1 or ^3%s^1 for next or previous player"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3666                         drawInfoMessage(s)
3667
3668                         if(spectatee_status == -1)
3669                                 s = sprintf(_("^1Use ^3%s^1 or ^3%s^1 to change the speed"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3670                         else
3671                                 s = sprintf(_("^1Press ^3%s^1 to observe"), getcommandkey("secondary fire", "+fire2"));
3672                         drawInfoMessage(s)
3673
3674                         s = sprintf(_("^1Press ^3%s^1 for gamemode info"), getcommandkey("server info", "+show_info"));
3675                         drawInfoMessage(s)
3676
3677                         if(gametype == MAPINFO_TYPE_LMS)
3678                         {
3679                                 entity sk;
3680                                 sk = playerslots[player_localnum];
3681                                 if(sk.(scores[ps_primary]) >= 666)
3682                                         s = _("^1Match has already begun");
3683                                 else if(sk.(scores[ps_primary]) > 0)
3684                                         s = _("^1You have no more lives left");
3685                                 else
3686                                         s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3687                         }
3688                         else
3689                                 s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3690                         drawInfoMessage(s)
3691
3692                         //show restart countdown:
3693                         if (time < getstatf(STAT_GAMESTARTTIME)) {
3694                                 float countdown;
3695                                 //we need to ceil, otherwise the countdown would be off by .5 when using round()
3696                                 countdown = ceil(getstatf(STAT_GAMESTARTTIME) - time);
3697                                 s = sprintf(_("^1Game starts in ^3%d^1 seconds"), countdown);
3698                                 drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);
3699                                 o_y += fontsize_y;
3700                         }
3701                 }
3702                 if(warmup_stage && !intermission)
3703                 {
3704                         s = _("^2Currently in ^1warmup^2 stage!");
3705                         drawInfoMessage(s)
3706                 }
3707
3708                 string blinkcolor;
3709                 if(mod(time, 1) >= 0.5)
3710                         blinkcolor = "^1";
3711                 else
3712                         blinkcolor = "^3";
3713
3714                 if(ready_waiting && !intermission && !spectatee_status)
3715                 {
3716                         if(ready_waiting_for_me)
3717                         {
3718                                 if(warmup_stage)
3719                                         s = sprintf(_("%sPress ^3%s%s to end warmup"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3720                                 else
3721                                         s = sprintf(_("%sPress ^3%s%s once you are ready"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3722                         }
3723                         else
3724                         {
3725                                 if(warmup_stage)
3726                                         s = _("^2Waiting for others to ready up to end warmup...");
3727                                 else
3728                                         s = _("^2Waiting for others to ready up...");
3729                         }
3730                         drawInfoMessage(s)
3731                 }
3732                 else if(warmup_stage && !intermission && !spectatee_status)
3733                 {
3734                         s = sprintf(_("^2Press ^3%s^2 to end warmup"), getcommandkey("ready", "ready"));
3735                         drawInfoMessage(s)
3736                 }
3737
3738                 if(teamplay && !intermission && !spectatee_status && gametype != MAPINFO_TYPE_CA && teamnagger)
3739                 {
3740                         float ts_min = 0, ts_max = 0;
3741                         tm = teams.sort_next;
3742                         if (tm)
3743                         {
3744                                 for(; tm.sort_next; tm = tm.sort_next)
3745                                 {
3746                                         if(!tm.team_size || tm.team == NUM_SPECTATOR)
3747                                                 continue;
3748                                         if(!ts_min) ts_min = tm.team_size;
3749                                         else ts_min = min(ts_min, tm.team_size);
3750                                         if(!ts_max) ts_max = tm.team_size;
3751                                         else ts_max = max(ts_max, tm.team_size);
3752                                 }
3753                                 if ((ts_max - ts_min) > 1)
3754                                 {
3755                                         s = strcat(blinkcolor, _("Teamnumbers are unbalanced!"));
3756                                         tm = GetTeam(myteam, false);
3757                                         if (tm)
3758                                         if (tm.team != NUM_SPECTATOR)
3759                                         if (tm.team_size == ts_max)
3760                                                 s = strcat(s, sprintf(_(" Press ^3%s%s to adjust"), getcommandkey("team menu", "menu_showteamselect"), blinkcolor));
3761                                         drawInfoMessage(s)
3762                                 }
3763                         }
3764                 }
3765         }
3766         else
3767         {
3768                 s = _("^7Press ^3ESC ^7to show HUD options.");
3769                 drawInfoMessage(s)
3770                 s = _("^3Doubleclick ^7a panel for panel-specific options.");
3771                 drawInfoMessage(s)
3772                 s = _("^3CTRL ^7to disable collision testing, ^3SHIFT ^7and");
3773                 drawInfoMessage(s)
3774                 s = _("^3ALT ^7+ ^3ARROW KEYS ^7for fine adjustments.");
3775                 drawInfoMessage(s)
3776         }
3777 }
3778
3779 // Physics panel (#15)
3780 //
3781 vector acc_prevspeed;
3782 float acc_prevtime, acc_avg, top_speed, top_speed_time;
3783 void HUD_Physics(void)
3784 {
3785         if(!autocvar__hud_configure)
3786         {
3787                 if(!autocvar_hud_panel_physics) return;
3788                 if(spectatee_status == -1 && (autocvar_hud_panel_physics == 1 || autocvar_hud_panel_physics == 3)) return;
3789                 if(autocvar_hud_panel_physics == 3 && !(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
3790         }
3791
3792         HUD_Panel_UpdateCvars();
3793
3794         draw_beginBoldFont();
3795
3796         HUD_Panel_DrawBg(1);
3797         if(panel_bg_padding)
3798         {
3799                 panel_pos += '1 1 0' * panel_bg_padding;
3800                 panel_size -= '2 2 0' * panel_bg_padding;
3801         }
3802
3803         float acceleration_progressbar_scale = 0;
3804         if(autocvar_hud_panel_physics_progressbar && autocvar_hud_panel_physics_acceleration_progressbar_scale > 1)
3805                 acceleration_progressbar_scale = autocvar_hud_panel_physics_acceleration_progressbar_scale;
3806
3807         float text_scale;
3808         if (autocvar_hud_panel_physics_text_scale <= 0)
3809                 text_scale = 1;
3810         else
3811                 text_scale = min(autocvar_hud_panel_physics_text_scale, 1);
3812
3813         //compute speed
3814         float speed, conversion_factor;
3815         string unit;
3816
3817         switch(autocvar_hud_panel_physics_speed_unit)
3818         {
3819                 default:
3820                 case 1:
3821                         unit = _(" qu/s");
3822                         conversion_factor = 1.0;
3823                         break;
3824                 case 2:
3825                         unit = _(" m/s");
3826                         conversion_factor = 0.0254;
3827                         break;
3828                 case 3:
3829                         unit = _(" km/h");
3830                         conversion_factor = 0.0254 * 3.6;
3831                         break;
3832                 case 4:
3833                         unit = _(" mph");
3834                         conversion_factor = 0.0254 * 3.6 * 0.6213711922;
3835                         break;
3836                 case 5:
3837                         unit = _(" knots");
3838                         conversion_factor = 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
3839                         break;
3840         }
3841
3842         vector vel = (csqcplayer ? csqcplayer.velocity : pmove_vel);
3843
3844         float max_speed = floor( autocvar_hud_panel_physics_speed_max * conversion_factor + 0.5 );
3845         if (autocvar__hud_configure)
3846                 speed = floor( max_speed * 0.65 + 0.5 );
3847         else if(autocvar_hud_panel_physics_speed_vertical)
3848                 speed = floor( vlen(vel) * conversion_factor + 0.5 );
3849         else
3850                 speed = floor( vlen(vel - vel_z * '0 0 1') * conversion_factor + 0.5 );
3851
3852         //compute acceleration
3853         float acceleration, f;
3854         if (autocvar__hud_configure)
3855                 acceleration = autocvar_hud_panel_physics_acceleration_max * 0.3;
3856         else
3857         {
3858                 // 1 m/s = 0.0254 qu/s; 1 g = 9.80665 m/s^2
3859                 f = time - acc_prevtime;
3860                 if(autocvar_hud_panel_physics_acceleration_vertical)
3861                         acceleration = (vlen(vel) - vlen(acc_prevspeed));
3862                 else
3863                         acceleration = (vlen(vel - '0 0 1' * vel_z) - vlen(acc_prevspeed - '0 0 1' * acc_prevspeed_z));
3864
3865                 acceleration = acceleration * (1 / max(0.0001, f)) * (0.0254 / 9.80665);
3866
3867                 acc_prevspeed = vel;
3868                 acc_prevtime = time;
3869
3870                 f = bound(0, f * 10, 1);
3871                 acc_avg = acc_avg * (1 - f) + acceleration * f;
3872         }
3873
3874         //compute layout
3875         float panel_ar = panel_size_x/panel_size_y;
3876         vector speed_offset = '0 0 0', acceleration_offset = '0 0 0';
3877         if (panel_ar >= 5 && !acceleration_progressbar_scale)
3878         {
3879                 panel_size_x *= 0.5;
3880                 if (autocvar_hud_panel_physics_flip)
3881                         speed_offset_x = panel_size_x;
3882                 else
3883                         acceleration_offset_x = panel_size_x;
3884         }
3885         else
3886         {
3887                 panel_size_y *= 0.5;
3888                 if (autocvar_hud_panel_physics_flip)
3889                         speed_offset_y = panel_size_y;
3890                 else
3891                         acceleration_offset_y = panel_size_y;
3892         }
3893         float speed_baralign, acceleration_baralign;
3894         if (autocvar_hud_panel_physics_baralign == 1)
3895                 acceleration_baralign = speed_baralign = 1;
3896     else if(autocvar_hud_panel_physics_baralign == 4)
3897                 acceleration_baralign = speed_baralign = 2;
3898         else if (autocvar_hud_panel_physics_flip)
3899         {
3900                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 2);
3901                 speed_baralign = (autocvar_hud_panel_physics_baralign == 3);
3902         }
3903         else
3904         {
3905                 speed_baralign = (autocvar_hud_panel_physics_baralign == 2);
3906                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 3);
3907         }
3908         if (autocvar_hud_panel_physics_acceleration_progressbar_mode == 0)
3909                 acceleration_baralign = 3; //override hud_panel_physics_baralign value for acceleration
3910
3911         //draw speed
3912         if(speed)
3913         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
3914                 HUD_Panel_DrawProgressBar(panel_pos + speed_offset, panel_size, "progressbar", speed/max_speed, 0, speed_baralign, autocvar_hud_progressbar_speed_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3915         vector tmp_offset = '0 0 0', tmp_size = '0 0 0';
3916         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
3917         {
3918                 tmp_size_x = panel_size_x * 0.75;
3919                 tmp_size_y = panel_size_y * text_scale;
3920                 if (speed_baralign)
3921                         tmp_offset_x = panel_size_x - tmp_size_x;
3922                 //else
3923                         //tmp_offset_x = 0;
3924                 tmp_offset_y = (panel_size_y - tmp_size_y) / 2;
3925                 drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(speed), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3926
3927                 //draw speed unit
3928                 if (speed_baralign)
3929                         tmp_offset_x = 0;
3930                 else
3931                         tmp_offset_x = tmp_size_x;
3932                 if (autocvar_hud_panel_physics_speed_unit_show)
3933                 {
3934                         //tmp_offset_y = 0;
3935                         tmp_size_x = panel_size_x * (1 - 0.75);
3936                         tmp_size_y = panel_size_y * 0.4 * text_scale;
3937                         tmp_offset_y = (panel_size_y * 0.4 - tmp_size_y) / 2;
3938                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, unit, tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3939                 }
3940         }
3941
3942         //compute and draw top speed
3943         if (autocvar_hud_panel_physics_topspeed)
3944         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
3945         {
3946                 if (autocvar__hud_configure)
3947                 {
3948                         top_speed = floor( max_speed * 0.75 + 0.5 );
3949                         f = 1;
3950                 }
3951                 else
3952                 {
3953                         if (speed >= top_speed)
3954                         {
3955                                 top_speed = speed;
3956                                 top_speed_time = time;
3957                         }
3958                         if (top_speed != 0)
3959                         {
3960                                 f = max(1, autocvar_hud_panel_physics_topspeed_time);
3961                                 // divide by f to make it start from 1
3962                                 f = cos( ((time - top_speed_time) / f) * PI/2 );
3963                         }
3964             else //hide top speed 0, it would be stupid
3965                                 f = 0;
3966                 }
3967                 if (f > 0)
3968                 {
3969                         //top speed progressbar peak
3970                         if(speed < top_speed)
3971                         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
3972                         {
3973                                 float peak_offset_x;
3974                                 vector peak_size = '0 0 0';
3975                                 if (speed_baralign == 0)
3976                                         peak_offset_x = min(top_speed, max_speed)/max_speed * panel_size_x;
3977                 else if (speed_baralign == 1)
3978                                         peak_offset_x = (1 - min(top_speed, max_speed)/max_speed) * panel_size_x;
3979                 else // if (speed_baralign == 2)
3980                     peak_offset_x = min(top_speed, max_speed)/max_speed * panel_size_x * 0.5;
3981                                 peak_size_x = floor(panel_size_x * 0.01 + 1.5);
3982                 peak_size_y = panel_size_y;
3983                 if (speed_baralign == 2) // draw two peaks, on both sides
3984                 {
3985                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size_x + peak_offset_x - peak_size_x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3986                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size_x - peak_offset_x + peak_size_x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3987                 }
3988                 else
3989                     drawfill(panel_pos + speed_offset + eX * (peak_offset_x - peak_size_x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3990                         }
3991
3992                         //top speed
3993                         tmp_offset_y = panel_size_y * 0.4;
3994                         tmp_size_x = panel_size_x * (1 - 0.75);
3995                         tmp_size_y = (panel_size_y - tmp_offset_y) * text_scale;
3996                         tmp_offset_y += (panel_size_y - tmp_offset_y - tmp_size_y) / 2;
3997                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(top_speed), tmp_size, '1 0 0', f * panel_fg_alpha, DRAWFLAG_NORMAL);
3998                 }
3999                 else
4000                         top_speed = 0;
4001         }
4002
4003         //draw acceleration
4004         if(acceleration)
4005         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 3)
4006         {
4007                 vector progressbar_color;
4008                 if(acceleration < 0)
4009                         progressbar_color = autocvar_hud_progressbar_acceleration_neg_color;
4010                 else
4011                         progressbar_color = autocvar_hud_progressbar_acceleration_color;
4012
4013                 f = acceleration/autocvar_hud_panel_physics_acceleration_max;
4014                 if (autocvar_hud_panel_physics_acceleration_progressbar_nonlinear)
4015                         f = sqrt(f);
4016
4017                 if (acceleration_progressbar_scale) // allow progressbar to go out of panel bounds
4018                 {
4019                         tmp_size = acceleration_progressbar_scale * panel_size_x * eX + panel_size_y * eY;
4020
4021                         if (acceleration_baralign == 1)
4022                                 tmp_offset_x = panel_size_x - tmp_size_x;
4023                         else if (acceleration_baralign == 2 || acceleration_baralign == 3)
4024                                 tmp_offset_x = (panel_size_x - tmp_size_x) / 2;
4025                         else
4026                                 tmp_offset_x = 0;
4027                         tmp_offset_y = 0;
4028                 }
4029                 else
4030                 {
4031                         tmp_size = panel_size;
4032                         tmp_offset = '0 0 0';
4033                 }
4034
4035                 HUD_Panel_DrawProgressBar(panel_pos + acceleration_offset + tmp_offset, tmp_size, "accelbar", f, 0, acceleration_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4036         }
4037         tmp_size_x = panel_size_x;
4038         tmp_size_y = panel_size_y * text_scale;
4039         tmp_offset_x = 0;
4040         tmp_offset_y = (panel_size_y - tmp_size_y) / 2;
4041         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 3)
4042                 drawstring_aspect(panel_pos + acceleration_offset + tmp_offset, strcat(ftos_decimals(acceleration, 2), "g"), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4043
4044         draw_endBoldFont();
4045 }
4046
4047 // CenterPrint (#16)
4048 //
4049 #define CENTERPRINT_MAX_MSGS 10
4050 #define CENTERPRINT_MAX_ENTRIES 50
4051 #define CENTERPRINT_SPACING 0.7
4052 float cpm_index;
4053 string centerprint_messages[CENTERPRINT_MAX_MSGS];
4054 float centerprint_msgID[CENTERPRINT_MAX_MSGS];
4055 float centerprint_time[CENTERPRINT_MAX_MSGS];
4056 float centerprint_expire_time[CENTERPRINT_MAX_MSGS];
4057 float centerprint_countdown_num[CENTERPRINT_MAX_MSGS];
4058 float centerprint_showing;
4059
4060 void centerprint_generic(float new_id, string strMessage, float duration, float countdown_num)
4061 {
4062         //printf("centerprint_generic(%d, '%s^7', %d, %d);\n", new_id, strMessage, duration, countdown_num);
4063         float i, j;
4064
4065         if(strMessage == "" && new_id == 0)
4066                 return;
4067
4068         // strip trailing newlines
4069         j = strlen(strMessage) - 1;
4070         while(substring(strMessage, j, 1) == "\n" && j >= 0)
4071                 --j;
4072         if (j < strlen(strMessage) - 1)
4073                 strMessage = substring(strMessage, 0, j + 1);
4074
4075         if(strMessage == "" && new_id == 0)
4076                 return;
4077
4078         // strip leading newlines
4079         j = 0;
4080         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
4081                 ++j;
4082         if (j > 0)
4083                 strMessage = substring(strMessage, j, strlen(strMessage) - j);
4084
4085         if(strMessage == "" && new_id == 0)
4086                 return;
4087
4088         if (!centerprint_showing)
4089                 centerprint_showing = TRUE;
4090
4091         for (i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4092         {
4093                 if (j == CENTERPRINT_MAX_MSGS)
4094                         j = 0;
4095                 if (new_id && new_id == centerprint_msgID[j])
4096                 {
4097                         if (strMessage == "" && centerprint_messages[j] != "" && centerprint_countdown_num[j] == 0)
4098                         {
4099                                 // fade out the current msg (duration and countdown_num are ignored)
4100                                 centerprint_time[j] = min(5, autocvar_hud_panel_centerprint_fade_out);
4101                                 if (centerprint_expire_time[j] > time + min(5, autocvar_hud_panel_centerprint_fade_out) || centerprint_expire_time[j] < time)
4102                                         centerprint_expire_time[j] = time + min(5, autocvar_hud_panel_centerprint_fade_out);
4103                                 return;
4104                         }
4105                         break; // found a msg with the same id, at position j
4106                 }
4107         }
4108
4109         if (i == CENTERPRINT_MAX_MSGS)
4110         {
4111                 // a msg with the same id was not found, add the msg at the next position
4112                 --cpm_index;
4113                 if (cpm_index == -1)
4114                         cpm_index = CENTERPRINT_MAX_MSGS - 1;
4115                 j = cpm_index;
4116         }
4117         if(centerprint_messages[j])
4118                 strunzone(centerprint_messages[j]);
4119         centerprint_messages[j] = strzone(strMessage);
4120         centerprint_msgID[j] = new_id;
4121         if (duration < 0)
4122         {
4123                 centerprint_time[j] = -1;
4124                 centerprint_expire_time[j] = time;
4125         }
4126         else
4127         {
4128                 if(duration == 0)
4129                         duration = max(1, autocvar_hud_panel_centerprint_time);
4130                 centerprint_time[j] = duration;
4131                 centerprint_expire_time[j] = time + duration;
4132         }
4133         centerprint_countdown_num[j] = countdown_num;
4134 }
4135
4136 void centerprint_hud(string strMessage)
4137 {
4138         centerprint_generic(0, strMessage, autocvar_hud_panel_centerprint_time, 0);
4139 }
4140
4141 void reset_centerprint_messages(void)
4142 {
4143         float i;
4144         for (i=0; i<CENTERPRINT_MAX_MSGS; ++i)
4145         {
4146                 centerprint_expire_time[i] = 0;
4147                 centerprint_time[i] = 1;
4148                 centerprint_msgID[i] = 0;
4149                 if(centerprint_messages[i])
4150                         strunzone(centerprint_messages[i]);
4151                 centerprint_messages[i] = string_null;
4152         }
4153 }
4154 float hud_configure_cp_generation_time;
4155 void HUD_CenterPrint (void)
4156 {
4157         if(!autocvar__hud_configure)
4158         {
4159                 if(!autocvar_hud_panel_centerprint) return;
4160
4161                 if (hud_configure_prev && hud_configure_prev != -1)
4162                         reset_centerprint_messages();
4163         }
4164         else
4165         {
4166                 if (!hud_configure_prev)
4167                         reset_centerprint_messages();
4168                 if (time > hud_configure_cp_generation_time)
4169                 {
4170                         float r;
4171                         r = random();
4172                         if (r > 0.9)
4173                                 centerprint_generic(floor(r*1000), strcat(sprintf("^3Countdown message at time %s", seconds_tostring(time)), ", seconds left: ^COUNT"), 1, 10);
4174                         else if (r > 0.8)
4175                                 centerprint_generic(0, sprintf("^1Multiline message at time %s that\n^1lasts longer than normal", seconds_tostring(time)), 20, 0);
4176                         else
4177                                 centerprint_hud(sprintf("Message at time %s", seconds_tostring(time)));
4178                         hud_configure_cp_generation_time = time + 1 + random()*4;
4179                 }
4180         }
4181
4182         // this panel fades only when the menu does
4183         float hud_fade_alpha_save = 0;
4184         if(scoreboard_fade_alpha)
4185         {
4186                 hud_fade_alpha_save = hud_fade_alpha;
4187                 hud_fade_alpha = 1 - autocvar__menu_alpha;
4188         }
4189         HUD_Panel_UpdateCvars();
4190
4191         if(scoreboard_fade_alpha)
4192         {
4193                 hud_fade_alpha = hud_fade_alpha_save;
4194
4195                 // move the panel below the scoreboard
4196                 if (scoreboard_bottom >= 0.96 * vid_conheight)
4197                         return;
4198                 vector target_pos;
4199
4200                 target_pos = eY * scoreboard_bottom + eX * 0.5 * (vid_conwidth - panel_size_x);
4201
4202                 if(target_pos_y > panel_pos_y)
4203                 {
4204                         panel_pos = panel_pos + (target_pos - panel_pos) * sqrt(scoreboard_fade_alpha);
4205                         panel_size_y = min(panel_size_y, vid_conheight - scoreboard_bottom);
4206                 }
4207         }
4208
4209         HUD_Panel_DrawBg(1);
4210
4211         if (!centerprint_showing)
4212                 return;
4213
4214         if(panel_bg_padding)
4215         {
4216                 panel_pos += '1 1 0' * panel_bg_padding;
4217                 panel_size -= '2 2 0' * panel_bg_padding;
4218         }
4219
4220         float entries, height;
4221         vector fontsize;
4222         // entries = bound(1, floor(CENTERPRINT_MAX_ENTRIES * 4 * panel_size_y/panel_size_x), CENTERPRINT_MAX_ENTRIES);
4223         // height = panel_size_y/entries;
4224         // fontsize = '1 1 0' * height;
4225         height = vid_conheight/50 * autocvar_hud_panel_centerprint_fontscale;
4226         fontsize = '1 1 0' * height;
4227         entries = bound(1, floor(panel_size_y/height), CENTERPRINT_MAX_ENTRIES);
4228
4229         float i, j, k, n, g;
4230         float a, sz, align, current_msg_pos_y = 0, msg_size;
4231         vector pos;
4232         string ts;
4233         float all_messages_expired = TRUE;
4234
4235         pos = panel_pos;
4236         if (autocvar_hud_panel_centerprint_flip)
4237                 pos_y += panel_size_y;
4238         align = bound(0, autocvar_hud_panel_centerprint_align, 1);
4239         for (g=0, i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4240         {
4241                 if (j == CENTERPRINT_MAX_MSGS)
4242                         j = 0;
4243                 if (centerprint_expire_time[j] <= time)
4244                 {
4245                         if (centerprint_countdown_num[j] && centerprint_time[j] > 0)
4246                         {
4247                                 centerprint_countdown_num[j] = centerprint_countdown_num[j] - 1;
4248                                 if (centerprint_countdown_num[j] == 0)
4249                                         continue;
4250                                 centerprint_expire_time[j] = centerprint_expire_time[j] + centerprint_time[j];
4251                         }
4252                         else if(centerprint_time[j] != -1)
4253                                 continue;
4254                 }
4255
4256                 all_messages_expired = FALSE;
4257
4258                 // fade the centerprint_hud in/out
4259                 if(centerprint_time[j] < 0)  // Expired but forced. Expire time is the fade-in time.
4260                         a = (time - centerprint_expire_time[j]) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4261                 else if(centerprint_expire_time[j] - autocvar_hud_panel_centerprint_fade_out > time)  // Regularily printed. Not fading out yet.
4262                         a = (time - (centerprint_expire_time[j] - centerprint_time[j])) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4263                 else // Expiring soon, so fade it out.
4264                         a = (centerprint_expire_time[j] - time) / max(0.0001, autocvar_hud_panel_centerprint_fade_out);
4265
4266                 if (a <= 0.5/255.0)  // Guaranteed invisible - don't show.
4267                         continue;
4268                 if (a > 1)
4269                         a = 1;
4270
4271                 // set the size from fading in/out before subsequent fading
4272                 sz = autocvar_hud_panel_centerprint_fade_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_minfontsize);
4273
4274                 // also fade it based on positioning
4275                 if(autocvar_hud_panel_centerprint_fade_subsequent)
4276                 {
4277                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passone_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passone))), 1); // pass one: all messages after the first have half theAlpha
4278                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passtwo_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passtwo))), 1); // pass two: after that, gradually lower theAlpha even more for each message
4279                 }
4280                 a *= panel_fg_alpha;
4281
4282                 // finally set the size based on the new theAlpha from subsequent fading
4283                 sz = sz * (autocvar_hud_panel_centerprint_fade_subsequent_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_subsequent_minfontsize));
4284                 drawfontscale = sz * '1 1 0';
4285
4286                 if (centerprint_countdown_num[j])
4287                         n = tokenizebyseparator(strreplace("^COUNT", count_seconds(centerprint_countdown_num[j]), centerprint_messages[j]), "\n");
4288                 else
4289                         n = tokenizebyseparator(centerprint_messages[j], "\n");
4290
4291                 if (autocvar_hud_panel_centerprint_flip)
4292                 {
4293                         // check if the message can be entirely shown
4294                         for(k = 0; k < n; ++k)
4295                         {
4296                                 getWrappedLine_remaining = argv(k);
4297                                 while(getWrappedLine_remaining)
4298                                 {
4299                                         ts = getWrappedLine(panel_size_x * sz, fontsize, stringwidth_colors);
4300                                         if (ts != "")
4301                                                 pos_y -= fontsize_y;
4302                                         else
4303                                                 pos_y -= fontsize_y * CENTERPRINT_SPACING/2;
4304                                 }
4305                         }
4306                         current_msg_pos_y = pos_y; // save starting pos (first line) of the current message
4307                 }
4308
4309                 msg_size = pos_y;
4310                 for(k = 0; k < n; ++k)
4311                 {
4312                         getWrappedLine_remaining = argv(k);
4313                         while(getWrappedLine_remaining)
4314                         {
4315                                 ts = getWrappedLine(panel_size_x * sz, fontsize, stringwidth_colors);
4316                                 if (ts != "")
4317                                 {
4318                                         if (align)
4319                                                 pos_x = panel_pos_x + (panel_size_x - stringwidth(ts, TRUE, fontsize)) * align;
4320                                         if (a > 0.5/255.0)  // Otherwise guaranteed invisible - don't show. This is checked a second time after some multiplications with other factors were done so temporary changes of these cannot cause flicker.
4321                                                 drawcolorcodedstring(pos + eY * 0.5 * (1 - sz) * fontsize_y, ts, fontsize, a, DRAWFLAG_NORMAL);
4322                                         pos_y += fontsize_y;
4323                                 }
4324                                 else
4325                                         pos_y += fontsize_y * CENTERPRINT_SPACING/2;
4326                         }
4327                 }
4328
4329                 ++g; // move next position number up
4330
4331                 msg_size = pos_y - msg_size;
4332                 if (autocvar_hud_panel_centerprint_flip)
4333                 {
4334                         pos_y = current_msg_pos_y - CENTERPRINT_SPACING * fontsize_y;
4335                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4336                                 pos_y += (msg_size + CENTERPRINT_SPACING * fontsize_y) * (1 - sqrt(sz));
4337
4338                         if (pos_y < panel_pos_y) // check if the next message can be shown
4339                         {
4340                                 drawfontscale = '1 1 0';
4341                                 return;
4342                         }
4343                 }
4344                 else
4345                 {
4346                         pos_y += CENTERPRINT_SPACING * fontsize_y;
4347                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4348                                 pos_y -= (msg_size + CENTERPRINT_SPACING * fontsize_y) * (1 - sqrt(sz));
4349
4350                         if(pos_y > panel_pos_y + panel_size_y - fontsize_y) // check if the next message can be shown
4351                         {
4352                                 drawfontscale = '1 1 0';
4353                                 return;
4354                         }
4355                 }
4356         }
4357         drawfontscale = '1 1 0';
4358         if (all_messages_expired)
4359         {
4360                 centerprint_showing = FALSE;
4361                 reset_centerprint_messages();
4362         }
4363 }
4364
4365 /*
4366 ==================
4367 Main HUD system
4368 ==================
4369 */
4370
4371 void HUD_Reset (void)
4372 {
4373         // reset gametype specific icons
4374         if(gametype == MAPINFO_TYPE_KEYHUNT)
4375                 HUD_Mod_KH_Reset();
4376         else if(gametype == MAPINFO_TYPE_CTF)
4377                 HUD_Mod_CTF_Reset();
4378 }
4379
4380 void HUD_Main (void)
4381 {
4382         float i;
4383         // global hud theAlpha fade
4384         if(menu_enabled == 1)
4385                 hud_fade_alpha = 1;
4386         else
4387                 hud_fade_alpha = (1 - autocvar__menu_alpha);
4388
4389         if(scoreboard_fade_alpha)
4390                 hud_fade_alpha = (1 - scoreboard_fade_alpha);
4391
4392         HUD_Configure_Frame();
4393
4394         if(intermission == 2) // no hud during mapvote
4395                 hud_fade_alpha = 0;
4396
4397         // panels that we want to be active together with the scoreboard
4398         // they must fade only when the menu does
4399         if(scoreboard_fade_alpha == 1)
4400         {
4401                 (panel = HUD_PANEL(CENTERPRINT)).panel_draw();
4402                 return;
4403         }
4404
4405         if(!autocvar__hud_configure && !hud_fade_alpha)
4406                 return;
4407
4408         // Drawing stuff
4409         if (hud_skin_prev != autocvar_hud_skin)
4410         {
4411                 if (hud_skin_path)
4412                         strunzone(hud_skin_path);
4413                 hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
4414                 if (hud_skin_prev)
4415                         strunzone(hud_skin_prev);
4416                 hud_skin_prev = strzone(autocvar_hud_skin);
4417         }
4418
4419 #ifdef COMPAT_XON050_ENGINE
4420     current_player = (spectatee_status > 0) ? spectatee_status : player_localentnum;
4421 #else
4422     current_player = player_localentnum;
4423 #endif
4424
4425         // draw the dock
4426         if(autocvar_hud_dock != "" && autocvar_hud_dock != "0")
4427         {
4428                 float f;
4429                 vector color;
4430                 float hud_dock_color_team = autocvar_hud_dock_color_team;
4431                 if((teamplay) && hud_dock_color_team) {
4432                         if(autocvar__hud_configure && myteam == NUM_SPECTATOR)
4433                                 color = '1 0 0' * hud_dock_color_team;
4434                         else
4435                                 color = myteamcolors * hud_dock_color_team;
4436                 }
4437                 else if(autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && hud_dock_color_team) {
4438                         color = '1 0 0' * hud_dock_color_team;
4439                 }
4440                 else
4441                 {
4442                         string hud_dock_color = autocvar_hud_dock_color;
4443                         if(hud_dock_color == "shirt") {
4444                                 f = stof(getplayerkeyvalue(current_player - 1, "colors"));
4445                                 color = colormapPaletteColor(floor(f / 16), 0);
4446                         }
4447                         else if(hud_dock_color == "pants") {
4448                                 f = stof(getplayerkeyvalue(current_player - 1, "colors"));
4449                                 color = colormapPaletteColor(mod(f, 16), 1);
4450                         }
4451                         else
4452                                 color = stov(hud_dock_color);
4453                 }
4454
4455                 string pic;
4456                 pic = strcat(hud_skin_path, "/", autocvar_hud_dock);
4457                 if(precache_pic(pic) == "") {
4458                         pic = strcat(hud_skin_path, "/dock_medium");
4459                         if(precache_pic(pic) == "") {
4460                                 pic = "gfx/hud/default/dock_medium";
4461                         }
4462                 }
4463                 drawpic('0 0 0', pic, eX * vid_conwidth + eY * vid_conheight, color, autocvar_hud_dock_alpha * hud_fade_alpha, DRAWFLAG_NORMAL); // no aspect ratio forcing on dock...
4464         }
4465
4466         // cache the panel order into the panel_order array
4467         if(autocvar__hud_panelorder != hud_panelorder_prev) {
4468                 for(i = 0; i < HUD_PANEL_NUM; ++i)
4469                         panel_order[i] = -1;
4470                 string s = "";
4471                 float p_num, warning = false;
4472                 float argc = tokenize_console(autocvar__hud_panelorder);
4473                 if (argc > HUD_PANEL_NUM)
4474                         warning = true;
4475                 //first detect wrong/missing panel numbers
4476                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4477                         p_num = stof(argv(i));
4478                         if (p_num >= 0 && p_num < HUD_PANEL_NUM) { //correct panel number?
4479                                 if (panel_order[p_num] == -1) //found for the first time?
4480                                         s = strcat(s, ftos(p_num), " ");
4481                                 panel_order[p_num] = 1; //mark as found
4482                         }
4483                         else
4484                                 warning = true;
4485                 }
4486                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4487                         if (panel_order[i] == -1) {
4488                                 warning = true;
4489                                 s = strcat(s, ftos(i), " "); //add missing panel number
4490                         }
4491                 }
4492                 if (warning)
4493                         print(_("Automatically fixed wrong/missing panel numbers in _hud_panelorder\n"));
4494
4495                 cvar_set("_hud_panelorder", s);
4496                 if(hud_panelorder_prev)
4497                         strunzone(hud_panelorder_prev);
4498                 hud_panelorder_prev = strzone(s);
4499
4500                 //now properly set panel_order
4501                 tokenize_console(s);
4502                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4503                         panel_order[i] = stof(argv(i));
4504                 }
4505         }
4506
4507         hud_draw_maximized = 0;
4508         // draw panels in order specified by panel_order array
4509         for(i = HUD_PANEL_NUM - 1; i >= 0; --i)
4510                 (panel = hud_panel[panel_order[i]]).panel_draw();
4511
4512         hud_draw_maximized = 1; // panels that may be maximized must check this var
4513         // draw maximized panels on top
4514         if(hud_panel_radar_maximized)
4515                 (panel = HUD_PANEL(RADAR)).panel_draw();
4516         if(autocvar__con_chat_maximized)
4517                 (panel = HUD_PANEL(CHAT)).panel_draw();
4518
4519         HUD_Configure_PostDraw();
4520
4521         hud_configure_prev = autocvar__hud_configure;
4522 }