qcsrc/client/hud/panel/strafehud.qc

   1 // Author: Juhu
   2
   3 #include "strafehud.qh"
   4
   5 #include <client/autocvars.qh>
   6 #include <client/miscfunctions.qh>
   7 #include <common/animdecide.qh>
   8 #include <common/ent_cs.qh>
   9 #include <common/mapinfo.qh>
  10 #include <common/physics/movetypes/movetypes.qh>
  11 #include <common/physics/player.qh>
  12 #include <lib/csqcmodel/cl_player.qh>
  13
  14 // StrafeHUD (#25)
  15
  16 void HUD_StrafeHUD_Export(int fh)
  17 {
  18     // allow saving cvars that aesthetically change the panel into hud skin files
  19 }
  20
  21 bool fwd = true;
  22 bool state_fwd = true;
  23 bool state_fwd_prev = true;
  24 float demo_angle = -37;
  25 float demo_direction = 1;
  26 float demo_time = 0;
  27 float state_onground_time = 0;
  28 float state_strafekeys_time = 0;
  29 float state_direction_time = 0;
  30 bool state_onground = false;
  31 bool state_strafekeys = false;
  32 bool turn = false;
  33 float turnangle;
  34
  35 // provide basic panel cvars to old clients
  36 // TODO remove them after a future release (0.8.2+)
  37 noref string autocvar_hud_panel_strafehud_pos = "0.320000 0.570000";
  38 noref string autocvar_hud_panel_strafehud_size = "0.360000 0.020000";
  39 noref string autocvar_hud_panel_strafehud_bg = "0";
  40 noref string autocvar_hud_panel_strafehud_bg_color = "";
  41 noref string autocvar_hud_panel_strafehud_bg_color_team = "";
  42 noref string autocvar_hud_panel_strafehud_bg_alpha = "0.7";
  43 noref string autocvar_hud_panel_strafehud_bg_border = "";
  44 noref string autocvar_hud_panel_strafehud_bg_padding = "";
  45
  46 void HUD_StrafeHUD()
  47 {
  48     entity strafeplayer;
  49     bool islocal;
  50
  51     if(!autocvar__hud_configure)
  52     {
  53         if(!autocvar_hud_panel_strafehud) return;
  54         if(spectatee_status == -1 && (autocvar_hud_panel_strafehud == 1 || autocvar_hud_panel_strafehud == 3)) return;
  55         if(autocvar_hud_panel_strafehud == 3 && !(ISGAMETYPE(RACE) || ISGAMETYPE(CTS))) return;
  56     }
  57
  58     HUD_Panel_LoadCvars();
  59
  60     if(autocvar_hud_panel_strafehud_dynamichud)
  61         HUD_Scale_Enable();
  62     else
  63         HUD_Scale_Disable();
  64     HUD_Panel_DrawBg();
  65     if(panel_bg_padding)
  66     {
  67         panel_pos  += '1 1 0' * panel_bg_padding;
  68         panel_size -= '2 2 0' * panel_bg_padding;
  69     }
  70
  71     if(spectatee_status > 0 || isdemo())
  72     {
  73         islocal = false;
  74         strafeplayer = CSQCModel_server2csqc(player_localentnum - 1);
  75     }
  76     else
  77     {
  78         islocal = true;
  79         strafeplayer = csqcplayer;
  80     }
  81
  82     // draw strafehud
  83     if(csqcplayer && strafeplayer)
  84     {
  85         // physics
  86         bool   onground                      = islocal ? IS_ONGROUND(strafeplayer) : !(strafeplayer.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
  87         bool   strafekeys;
  88         bool   is_swimming                   = strafeplayer.waterlevel >= WATERLEVEL_SWIMMING;
  89         float  speed                         = !autocvar__hud_configure ? vlen(vec2(csqcplayer.velocity)) : 1337; // use local csqcmodel entity for this even when spectating, flickers too much otherwise
  90         float  maxspeed_crouch_mod           = IS_DUCKED(strafeplayer) && (!is_swimming || IS_ONGROUND(strafeplayer)) ? .5 : 1;
  91         float  maxspeed_water_mod            = is_swimming ? .7 : 1; // very simplified water physics, the hud will not work well (and is not supposed to) while swimming
  92         float  maxspeed_phys                 = onground ? PHYS_MAXSPEED(strafeplayer) : PHYS_MAXAIRSPEED(strafeplayer);
  93         float  maxspeed                      = !autocvar__hud_configure ? maxspeed_phys * maxspeed_crouch_mod * maxspeed_water_mod : 320;
  94         float  vel_angle                     = vectoangles(strafeplayer.velocity).y;
  95         float  view_angle                    = view_angles.y + 180;
  96         float  angle;
  97         float  direction;
  98         vector movement                      = PHYS_INPUT_MOVEVALUES(strafeplayer);
  99         int    keys                          = STAT(PRESSED_KEYS);
 100         int    keys_fwd;
 101         float  wishangle                     = 0;
 102         float  moveangle;
 103
 104         // HUD
 105         int    mode                          = autocvar_hud_panel_strafehud_mode >= 0 && autocvar_hud_panel_strafehud_mode <= 1 ? autocvar_hud_panel_strafehud_mode : 0;
 106         float  minspeed;
 107         float  hudangle;
 108         float  bar_offset;
 109         float  bar_width;
 110         vector currentangle_color            = autocvar_hud_panel_strafehud_warning_color;
 111         float  currentangle_offset;
 112         vector currentangle_size             = '0 0 0';
 113         bool   show_indicators;
 114         float  bestangle;
 115         bool   bestangle_anywhere            = false;
 116         float  bestangle_offset;
 117         float  bestangle_width;
 118         float  switch_bestangle_offset;
 119         float  accelzone_offset;
 120         float  accelzone_width;
 121         float  odd_accelzone_offset;
 122         float  odd_accelzone_width;
 123         float  overturn_offset;
 124         float  overturn_width;
 125         float  overturn_width_visible;
 126         float  hidden_angle;
 127         float  hidden_size;
 128         vector direction_size_vertical       = '0 0 0';
 129         vector direction_size_horizontal     = '0 0 0';
 130         float  maxangle;
 131         float  range_minangle;
 132
 133         // determine whether the player is pressing forwards or backwards keys
 134         if(islocal) // if entity is local player
 135         {
 136             if(movement_x > 0)
 137             {
 138                 keys_fwd = 1;
 139             }
 140             else if(movement_x < 0)
 141             {
 142                 keys_fwd = -1;
 143             }
 144             else
 145             {
 146                 keys_fwd = 0;
 147             }
 148         }
 149         else // alternatively determine direction by querying pressed keys
 150         {
 151             if((keys & KEY_FORWARD) && !(keys & KEY_BACKWARD))
 152             {
 153                 keys_fwd = 1;
 154             }
 155             else if(!(keys & KEY_FORWARD) && (keys & KEY_BACKWARD))
 156             {
 157                 keys_fwd = -1;
 158             }
 159             else
 160             {
 161                 keys_fwd = 0;
 162             }
 163         }
 164
 165         // determine player wishdir
 166         if(islocal) // if entity is local player
 167         {
 168             if(movement_x == 0)
 169             {
 170                 if(movement_y < 0)
 171                 {
 172                     wishangle = -90;
 173                 }
 174                 else if(movement_y > 0)
 175                 {
 176                     wishangle = 90;
 177                 }
 178                 else
 179                 {
 180                     wishangle = 0;
 181                 }
 182             }
 183             else
 184             {
 185                 if(movement_y == 0)
 186                 {
 187                     wishangle = 0;
 188                 }
 189                 else
 190                 {
 191                     wishangle = RAD2DEG * atan2(movement_y, movement_x);
 192                     // wrap the wish angle if it exceeds ±90°
 193                     if(fabs(wishangle) > 90)
 194                     {
 195                         if(wishangle < 0) wishangle += 180;
 196                         else wishangle -= 180;
 197                         wishangle = -wishangle;
 198                     }
 199                 }
 200             }
 201         }
 202         else // alternatively calculate wishdir by querying pressed keys
 203         {
 204             if(keys & KEY_FORWARD || keys & KEY_BACKWARD)
 205             {
 206                 wishangle = 45;
 207             }
 208             else
 209             {
 210                 wishangle = 90;
 211             }
 212             if(keys & KEY_LEFT)
 213             {
 214                 wishangle *= -1;
 215             }
 216             else if(!(keys & KEY_RIGHT))
 217             {
 218                 wishangle = 0; // wraps at 180°
 219             }
 220         }
 221
 222         strafekeys = fabs(wishangle) == 90;
 223
 224         // determine minimum required angle to display full strafe range
 225         range_minangle = fabs(wishangle) % 90; // maximum range is 90 degree
 226         if(range_minangle > 45) // minimum angle range is 45
 227         {
 228             range_minangle = 45 - fabs(wishangle) % 45;
 229         }
 230         range_minangle = 90 - range_minangle; // calculate value which is never >90 or <45
 231         range_minangle *= 2; // multiply to accommodate for both sides of the hud
 232
 233         if(autocvar_hud_panel_strafehud_angle == 0)
 234         {
 235             if(autocvar__hud_configure)
 236             {
 237                 hudangle = 90;
 238             }
 239             else
 240             {
 241                 hudangle = range_minangle; // use minimum angle required if dynamically setting hud angle
 242             }
 243         }
 244         else
 245         {
 246             hudangle = bound(0, fabs(autocvar_hud_panel_strafehud_angle), 360); // limit HUD range to 360 degrees, higher values don't make sense
 247         }
 248
 249         // detect air strafe turning
 250         if(onground != state_onground)
 251         {
 252             state_onground_time = time;
 253         }
 254         state_onground = onground;
 255         if(strafekeys != state_strafekeys)
 256         {
 257             state_strafekeys_time = time;
 258         }
 259         state_strafekeys = strafekeys;
 260         if((keys & KEY_FORWARD) || (keys & KEY_BACKWARD) || is_swimming || autocvar__hud_configure)
 261         {
 262             turn = false;
 263         }
 264         else if(onground)
 265         {
 266             if((time - state_onground_time) >= autocvar_hud_panel_strafehud_timeout_ground) // timeout for strafe jumping in general
 267             {
 268                 turn = false;
 269             }
 270         }
 271         else // air strafe only
 272         {
 273             if(strafekeys)
 274             {
 275                 if(((time - state_onground_time) >= autocvar_hud_panel_strafehud_timeout_air) || (keys & KEY_JUMP)) // timeout for slick ramps
 276                 {
 277                     turn = true; // CPMA turning
 278                     turnangle = wishangle;
 279                 }
 280             }
 281             else if((time - state_strafekeys_time) >= autocvar_hud_panel_strafehud_timeout_strafe) // timeout for jumping with strafe keys only
 282             {
 283                 turn = false;
 284             }
 285         }
 286         if(turn)
 287         {
 288             maxspeed = PHYS_MAXAIRSTRAFESPEED(strafeplayer); // no crouching here because it doesn't affect air strafing
 289             wishangle = turnangle;
 290         }
 291
 292         minspeed = autocvar_hud_panel_strafehud_indicator_minspeed < 0 ? maxspeed + .1 : autocvar_hud_panel_strafehud_indicator_minspeed;
 293         show_indicators = (autocvar_hud_panel_strafehud_indicators && (speed >= minspeed));
 294
 295         // get current strafing angle ranging from -180° to +180°
 296         if(!autocvar__hud_configure)
 297         {
 298             if(speed > 0)
 299             {
 300                 // calculate view angle relative to the players current velocity direction
 301                 angle = vel_angle - view_angle;
 302
 303                 // if the angle goes above 180° or below -180° wrap it to the opposite side
 304                 if (angle > 180) angle -= 360;
 305                 else if(angle < -180) angle += 360;
 306
 307                 // shift the strafe angle by 180° for hud calculations
 308                 if(angle < 0) angle += 180;
 309                 else angle -= 180;
 310
 311                 // determine whether the player is strafing forwards or backwards
 312                 // if the player isn't strafe turning use forwards/backwards keys to determine direction
 313                 if(!strafekeys)
 314                 {
 315                     if(keys_fwd > 0)
 316                     {
 317                     state_fwd = true;
 318                     }
 319                     else if(keys_fwd < 0)
 320                     {
 321                         state_fwd = false;
 322                     }
 323                     else
 324                     {
 325                         state_fwd = fabs(angle) <= 90;
 326                     }
 327                 }
 328                 // otherwise determine by examining the strafe angle
 329                 else
 330                 {
 331                     if(wishangle < 0) // detect direction since the direction is not yet set
 332                     {
 333                         state_fwd = angle <= -wishangle;
 334                     }
 335                     else
 336                     {
 337                         state_fwd = angle >= -wishangle;
 338                     }
 339                 }
 340
 341                 if(state_fwd_prev != state_fwd)
 342                 {
 343                     state_direction_time = time;
 344                 }
 345                 state_fwd_prev = state_fwd;
 346
 347                 if((time - state_direction_time) >= autocvar_hud_panel_strafehud_timeout_direction) // timeout when changing between forwards and backwards strafe
 348                 {
 349                     fwd = state_fwd;
 350                 }
 351
 352                 // shift the strafe angle by 180° when strafing backwards
 353                 if(!fwd)
 354                 {
 355                     if(angle < 0) angle += 180;
 356                     else angle -= 180;
 357                 }
 358
 359                 // making the hud less flickery in case of rounding errors
 360                 if(angle > 179.9 || angle < -179.9)
 361                 {
 362                     currentangle_color = autocvar_hud_panel_strafehud_alert_color;
 363                     angle = 0;
 364                 }
 365                 if(angle < .1 && angle > -.1)
 366                 {
 367                     angle = 0;
 368                 }
 369             }
 370             else
 371             {
 372                 angle = 0;
 373             }
 374         }
 375         else // simulate turning for HUD setup
 376         {
 377             if(autocvar__hud_panel_strafehud_center)
 378             {
 379                 angle = demo_angle = 0;
 380                 demo_time = 0;
 381                 wishangle = 0;
 382             }
 383             else
 384             {
 385                 if(autocvar__hud_panel_strafehud_demo && ((time - demo_time) >= .025))
 386                 {
 387                     demo_time = time;
 388                     demo_angle += demo_direction;
 389                     if(fabs(demo_angle) >= 55)
 390                     {
 391                         demo_direction = -demo_direction;
 392                     }
 393                 }
 394                 angle = demo_angle;
 395                 wishangle = 45 * (demo_angle > 0 ? 1 : -1);
 396             }
 397         }
 398
 399         // invert the wish angle when strafing backwards
 400         if(!fwd)
 401         {
 402             wishangle = -wishangle;
 403         }
 404
 405         // flip angles if v_flipped is enabled
 406         if(autocvar_v_flipped)
 407         {
 408             angle = -angle;
 409             wishangle = -wishangle;
 410         }
 411
 412         moveangle = angle + wishangle;
 413
 414         if(wishangle != 0)
 415         {
 416             direction = wishangle > 0 ? 1 : -1;
 417         }
 418         else
 419         {
 420             direction = moveangle > 0 ? 1 : moveangle < 0 ? -1 : 0;
 421         }
 422
 423         // how much is hidden by the current hud angle
 424         hidden_angle = 360 - hudangle;
 425         hidden_size = hidden_angle / hudangle * panel_size.x;
 426         // decelerating at this angle
 427         maxangle = 90 - fabs(wishangle);
 428         // best angle to strafe at
 429         bestangle = (speed > maxspeed ? acos(maxspeed / speed) : 0) * RAD2DEG * (direction < 0 ? -1 : 1) - wishangle;
 430         // various offsets and size calculations of hud indicator elements
 431         // current angle
 432         currentangle_size.x = panel_size.x * .005;
 433         if(currentangle_size.x < 1) currentangle_size.x = 1;
 434         if(mode == 0)
 435         {
 436             currentangle_offset = angle/hudangle * panel_size.x;
 437         }
 438         else
 439         {
 440             currentangle_offset = bound(-hudangle/2, angle, hudangle/2)/hudangle * panel_size.x + panel_size.x/2;
 441         }
 442         currentangle_size.y = panel_size.y * 1.5;
 443         // best strafe acceleration angle
 444         bestangle_offset        =  bestangle/hudangle * panel_size.x + panel_size.x/2;
 445         switch_bestangle_offset = -bestangle/hudangle * panel_size.x + panel_size.x/2;
 446         if(show_indicators)
 447         {
 448             bestangle_width = panel_size.x * .01;
 449             if(bestangle_width < 1) bestangle_width = 1;
 450         }
 451         else
 452         {
 453             bestangle_width = 0;
 454         }
 455         // remove indicator width from offset
 456         if(direction < 0)
 457         {
 458             bestangle_offset -= bestangle_width;
 459         }
 460         else
 461         {
 462             switch_bestangle_offset -= bestangle_width;
 463         }
 464         // direction indicator
 465         direction_size_vertical.x = panel_size.x * .0075;
 466         if(direction_size_vertical.x < 1) direction_size_vertical.x = 1;
 467         direction_size_vertical.y = panel_size.y;
 468         direction_size_horizontal.x = direction_size_vertical.x * 3;
 469         direction_size_horizontal.y = direction_size_vertical.x;
 470         // overturn
 471         overturn_width = 180/hudangle * panel_size.x;
 472         overturn_width_visible = (hudangle/2 - maxangle) / hudangle * panel_size.x;
 473
 474         // mark the ideal strafe angle
 475         if(direction < 0) // turning left
 476         {
 477             // calculate zone in which strafe acceleration happens
 478             accelzone_width = bestangle_offset;
 479             // calculate offset of overturn area
 480             overturn_offset = overturn_width_visible - overturn_width;
 481             // move/adjust acceleration zone
 482             accelzone_offset = overturn_width_visible;
 483             accelzone_width -= overturn_width_visible;
 484             // calculate zone in which strafe acceleration could also happen without changing wishdir
 485             odd_accelzone_width = accelzone_width + bestangle_width;
 486             odd_accelzone_offset = overturn_offset - odd_accelzone_width;
 487             // calculate the background of the strafe-o-meter
 488             bar_offset = bestangle_offset + bestangle_width;
 489             bar_width = 360/hudangle * panel_size.x - bestangle_width - accelzone_width - odd_accelzone_width - overturn_width;
 490         }
 491         else // turning right or moving forward
 492         {
 493             // calculate zone in which strafe acceleration happens
 494             accelzone_offset = bestangle_offset + bestangle_width;
 495             accelzone_width = panel_size.x - accelzone_offset;
 496             // calculate offset of overturn area
 497             overturn_offset = panel_size.x - overturn_width_visible;
 498             // adjust acceleration zone
 499             accelzone_width -= overturn_width_visible;
 500             // calculate zone in which strafe acceleration could also happen without changing wishdir
 501             odd_accelzone_width = accelzone_width + bestangle_width;
 502             odd_accelzone_offset = overturn_offset + overturn_width;
 503             // calculate the background of the strafe-o-meter
 504             bar_offset = odd_accelzone_offset + odd_accelzone_width;
 505             bar_width = 360/hudangle * panel_size.x - bestangle_width - accelzone_width - odd_accelzone_width - overturn_width;
 506         }
 507
 508         if(mode == 0)
 509         {
 510             bar_offset -= currentangle_offset;
 511             accelzone_offset -= currentangle_offset;
 512             odd_accelzone_offset -= currentangle_offset;
 513             overturn_offset -= currentangle_offset;
 514             bestangle_offset -= currentangle_offset;
 515             switch_bestangle_offset -= currentangle_offset;
 516         }
 517
 518         if(!autocvar_hud_panel_strafehud_unstyled)
 519         {
 520             // draw acceleration zone
 521             HUD_Panel_DrawStrafeHUD_ProgressBar(accelzone_offset, accelzone_width, autocvar_hud_panel_strafehud_indicator_color, autocvar_hud_panel_strafehud_bar_alpha, hidden_size);
 522
 523             // draw odd acceleration zone
 524             HUD_Panel_DrawStrafeHUD_ProgressBar(odd_accelzone_offset, odd_accelzone_width, autocvar_hud_panel_strafehud_indicator_color, autocvar_hud_panel_strafehud_bar_alpha, hidden_size);
 525
 526             // draw overturn area
 527             HUD_Panel_DrawStrafeHUD_ProgressBar(overturn_offset, overturn_width, autocvar_hud_panel_strafehud_alert_color, autocvar_hud_panel_strafehud_bar_alpha, hidden_size);
 528
 529             // draw the strafe bar background
 530             HUD_Panel_DrawStrafeHUD_ProgressBar(bar_offset, bar_width, autocvar_hud_panel_strafehud_bar_color, autocvar_hud_panel_strafehud_bar_alpha, hidden_size);
 531         }
 532         else
 533         {
 534             // draw acceleration zone
 535             HUD_Panel_DrawStrafeHUD_drawfill(accelzone_offset, accelzone_width, autocvar_hud_panel_strafehud_indicator_color, autocvar_hud_panel_strafehud_bar_alpha, hidden_size);
 536
 537             // draw odd acceleration zone
 538             HUD_Panel_DrawStrafeHUD_drawfill(odd_accelzone_offset, odd_accelzone_width, autocvar_hud_panel_strafehud_indicator_color, autocvar_hud_panel_strafehud_bar_alpha, hidden_size);
 539
 540             // draw overturn area
 541             HUD_Panel_DrawStrafeHUD_drawfill(overturn_offset, overturn_width, autocvar_hud_panel_strafehud_alert_color, autocvar_hud_panel_strafehud_bar_alpha, hidden_size);
 542
 543             // draw the strafe bar background
 544             HUD_Panel_DrawStrafeHUD_drawfill(bar_offset, bar_width, autocvar_hud_panel_strafehud_bar_color, autocvar_hud_panel_strafehud_bar_alpha, hidden_size);
 545         }
 546
 547         if(direction != 0)
 548         {
 549             // draw the direction indicator caps at the sides of the hud
 550             // vertical line
 551             drawfill(panel_pos + eX * (direction < 0 ? -direction_size_vertical.x : panel_size.x), direction_size_vertical, autocvar_hud_panel_strafehud_direction_color, panel_fg_alpha, DRAWFLAG_NORMAL);
 552             // top horizontal line
 553             drawfill(panel_pos + eX * (direction < 0 ? -direction_size_vertical.x : panel_size.x - direction_size_horizontal.x + direction_size_vertical.x) - eY * direction_size_horizontal.y, direction_size_horizontal, autocvar_hud_panel_strafehud_direction_color, panel_fg_alpha, DRAWFLAG_NORMAL);
 554             // bottom horizontal line
 555             drawfill(panel_pos + eX * (direction < 0 ? -direction_size_vertical.x : panel_size.x - direction_size_horizontal.x + direction_size_vertical.x) + eY * panel_size.y, direction_size_horizontal, autocvar_hud_panel_strafehud_direction_color, panel_fg_alpha, DRAWFLAG_NORMAL);
 556         }
 557
 558         if(show_indicators) // only draw indicators if enabled and minspeed is reached
 559         {
 560             // draw best angles for acceleration
 561             vector indicator_color;
 562             // both indicators are yellow if no direction can be determined
 563             indicator_color = direction != 0 ? autocvar_hud_panel_strafehud_indicator_color : autocvar_hud_panel_strafehud_indicator_switch_color;
 564             HUD_Panel_DrawStrafeHUD_drawfill(switch_bestangle_offset, bestangle_width, autocvar_hud_panel_strafehud_indicator_switch_color, 1, hidden_size);
 565             HUD_Panel_DrawStrafeHUD_drawfill(bestangle_offset, bestangle_width, indicator_color, 1, hidden_size);
 566         }
 567         if(speed < (maxspeed + .1))
 568         {
 569             bestangle_anywhere = true; // moving forward should suffice to gain speed
 570         }
 571
 572         // draw the actual strafe angle
 573         if(!bestangle_anywhere) // player gains speed with strafing
 574         {
 575             if((direction > 0 && (angle >= bestangle || angle <= -(bestangle + wishangle*2))) ||
 576                 (direction < 0 && (angle <= bestangle || angle >= -(bestangle + wishangle*2))))
 577             currentangle_color = autocvar_hud_panel_strafehud_good_color;
 578         }
 579
 580         if(fabs(moveangle) > 90) // player is overturning
 581         {
 582             currentangle_color = autocvar_hud_panel_strafehud_alert_color;
 583         }
 584
 585         if(bestangle_anywhere && currentangle_color != autocvar_hud_panel_strafehud_alert_color) // player gains speed without strafing
 586         {
 587             currentangle_color = autocvar_hud_panel_strafehud_good_color;
 588         }
 589
 590         if(mode == 0)
 591         {
 592             drawfill(panel_pos - eY * ((currentangle_size.y - panel_size.y) / 2) + eX * (panel_size.x/2 - currentangle_size.x/2), currentangle_size, currentangle_color, autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 593         }
 594         else
 595         {
 596             drawfill(panel_pos - eY * ((currentangle_size.y - panel_size.y) / 2) + eX * (currentangle_offset - currentangle_size.x/2), currentangle_size, currentangle_color, autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 597         }
 598     }
 599 }
 600
 601 // functions to make hud elements align perfectly in the hud area
 602 void HUD_Panel_DrawStrafeHUD_ProgressBar(float offset, float width, vector color, float alpha, float hidden)
 603 {
 604     float mirror_offset, mirror_width;
 605     vector size = panel_size;
 606     vector mirror_size = panel_size;
 607
 608     if(offset < 0)
 609     {
 610         mirror_width = min(fabs(offset), width);
 611         mirror_offset = panel_size.x + hidden - fabs(offset);
 612         width += offset;
 613         offset = 0;
 614     }
 615     else
 616     {
 617         mirror_width = min(offset + width - panel_size.x - hidden, width);
 618         mirror_offset = max(offset - panel_size.x - hidden, 0);
 619     }
 620     if((offset + width) > panel_size.x)
 621     {
 622         width = panel_size.x - offset;
 623     }
 624     if(mirror_offset < 0)
 625     {
 626         mirror_width += mirror_offset;
 627         mirror_offset = 0;
 628     }
 629     if((mirror_offset + mirror_width) > panel_size.x)
 630     {
 631         mirror_width = panel_size.x - mirror_offset;
 632     }
 633
 634     size.x = width;
 635     mirror_size.x = mirror_width;
 636     if(mirror_size.x > 0 && mirror_size.y > 0) HUD_Panel_DrawProgressBar(panel_pos + eX * mirror_offset, mirror_size, "progressbar", 1, 0, 0, color, alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 637     if(size.x > 0 && size.y > 0) HUD_Panel_DrawProgressBar(panel_pos + eX * offset, size, "progressbar", 1, 0, 0, color, alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 638 }
 639
 640 void HUD_Panel_DrawStrafeHUD_drawfill(float offset, float width, vector color, float alpha, float hidden)
 641 {
 642     float mirror_offset, mirror_width;
 643     vector size = panel_size;
 644     vector mirror_size = panel_size;
 645
 646     if(offset < 0)
 647     {
 648         mirror_width = min(fabs(offset), width);
 649         mirror_offset = panel_size.x + hidden - fabs(offset);
 650         width += offset;
 651         offset = 0;
 652     }
 653     else
 654     {
 655         mirror_width = min(offset + width - panel_size.x - hidden, width);
 656         mirror_offset = max(offset - panel_size.x - hidden, 0);
 657     }
 658     if((offset + width) > panel_size.x)
 659     {
 660         width = panel_size.x - offset;
 661     }
 662     if(mirror_offset < 0)
 663     {
 664         mirror_width += mirror_offset;
 665         mirror_offset = 0;
 666     }
 667     if((mirror_offset + mirror_width) > panel_size.x)
 668     {
 669         mirror_width = panel_size.x - mirror_offset;
 670     }
 671
 672     size.x = width;
 673     mirror_size.x = mirror_width;
 674     if(mirror_width > 0) drawfill(panel_pos + eX * mirror_offset, mirror_size, color, alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 675     if(width > 0) drawfill(panel_pos + eX * offset, size, color, alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 676 }