qcsrc/client/hud/panel/quickmenu.qc

   1 #include "quickmenu.qh"
   2
   3 #include <client/autocvars.qh>
   4 #include <client/defs.qh>
   5 #include <client/miscfunctions.qh>
   6 #include <common/ent_cs.qh>
   7 #include <client/hud/_mod.qh>
   8 #include <client/mapvoting.qh>
   9
  10 // QuickMenu (#23)
  11
  12 // QUICKMENU_MAXLINES must be <= 10
  13 const int QUICKMENU_MAXLINES = 10;
  14 // visible entries are loaded from QuickMenu_Buffer into QuickMenu_Page_* arrays
  15 string QuickMenu_Page_Command[QUICKMENU_MAXLINES];
  16 string QuickMenu_Page_Description[QUICKMENU_MAXLINES];
  17 int QuickMenu_Page_Command_Type[QUICKMENU_MAXLINES];
  18 int QuickMenu_Page_Entries;
  19 int QuickMenu_Page;
  20 int QuickMenu_Page_ActivatedEntry = -1;
  21 bool QuickMenu_Page_ActivatedEntry_Close;
  22 float QuickMenu_Page_ActivatedEntry_Time;
  23 bool QuickMenu_IsLastPage;
  24 // all the entries are loaded into QuickMenu_Buffer
  25 // each entry (submenu or command) is composed of 2 entries
  26 const int QUICKMENU_MAXENTRIES = 256;
  27 const int QUICKMENU_BUFFER_MAXENTRIES = 2 * QUICKMENU_MAXENTRIES;
  28 int QuickMenu_Buffer = -1;
  29 int QuickMenu_Buffer_Size;
  30 int QuickMenu_Buffer_Index;
  31 string QuickMenu_CurrentSubMenu;
  32 float QuickMenu_TimeOut;
  33
  34 // QuickMenu_Buffer are labeled with these tags
  35 #define QM_TAG_TITLE "T"
  36 #define QM_TAG_SUBMENU "S"
  37 #define QM_TAG_COMMAND "C"
  38 #define QM_TAG_PLCOMMAND "P"
  39
  40 #define QuickMenu_Buffer_Set(tag, string) bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat(tag, string))
  41 #define QuickMenu_Buffer_Get() bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index)
  42
  43 // if s1 is not empty s will be displayed as command otherwise as submenu
  44 void QuickMenu_Page_LoadEntry(int i, string s, string s1)
  45 {
  46     TC(int, i);
  47         //LOG_INFOF("^xc80 entry %d: %s, %s\n", i, s, s1);
  48         strcpy(QuickMenu_Page_Description[i], s);
  49         strcpy(QuickMenu_Page_Command[i], s1);
  50 }
  51
  52 void QuickMenu_Page_ClearEntry(int i)
  53 {
  54     TC(int, i);
  55         if (QuickMenu_Page_Description[i])
  56                 strunzone(QuickMenu_Page_Description[i]);
  57         QuickMenu_Page_Description[i] = string_null;
  58         if (QuickMenu_Page_Command[i])
  59                 strunzone(QuickMenu_Page_Command[i]);
  60         QuickMenu_Page_Command[i] = string_null;
  61         QuickMenu_Page_Command_Type[i] = 0;
  62 }
  63
  64 float QuickMenu_Page_Load(string target_submenu, float new_page);
  65 void QuickMenu_Default(string submenu);
  66 bool QuickMenu_Open(string mode, string submenu, string file)
  67 {
  68         int fh = -1;
  69         string s;
  70
  71         if(mode == "")
  72         {
  73                 if(file == "" || file == "0")
  74                         mode = "default";
  75                 else
  76                         mode = "file";
  77         }
  78
  79         if(mode == "file")
  80         {
  81                 if(file == "" || file == "0")
  82                         LOG_INFO("No file name is set in hud_panel_quickmenu_file, loading default quickmenu");
  83                 else
  84                 {
  85                         fh = fopen(file, FILE_READ);
  86                         if(fh < 0)
  87                                 LOG_INFOF("Couldn't open file \"%s\", loading default quickmenu", file);
  88                 }
  89                 if(fh < 0)
  90                         mode = "default";
  91         }
  92
  93         if(mode == "default")
  94         {
  95                 QuickMenu_Buffer = buf_create();
  96                 if(QuickMenu_Buffer < 0)
  97                         return false;
  98
  99                 QuickMenu_Default(submenu);
 100         }
 101         else if(mode == "file")
 102         {
 103                 QuickMenu_Buffer = buf_create();
 104                 if(QuickMenu_Buffer < 0)
 105                 {
 106                         fclose(fh);
 107                         return false;
 108                 }
 109
 110                 QuickMenu_Buffer_Size = 0;
 111                 while((s = fgets(fh)) && QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES)
 112                 {
 113                         // first skip invalid entries, so we don't check them anymore
 114                         float argc;
 115                         argc = tokenize_console(s);
 116                         if(argc == 0 || argv(0) == "")
 117                                 continue;
 118                         if(argc == 1)
 119                                 QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 120                         else if(argc == 2)
 121                         {
 122                                 if(argv(1) == "")
 123                                         continue;
 124                                 QuickMenu_Buffer_Set(QM_TAG_TITLE, argv(0));
 125                                 ++QuickMenu_Buffer_Size;
 126                                 QuickMenu_Buffer_Set(QM_TAG_COMMAND, argv(1));
 127                         }
 128                         else if(argc == 3)
 129                         {
 130                                 // check for special keywords
 131                                 float teamplayers = 0, without_me = 0;
 132                                 switch(argv(2))
 133                                 {
 134                                         case "ALLPLAYERS_BUT_ME":               without_me = 1; // fall through
 135                                         case "ALLPLAYERS":                              teamplayers = 0; break;
 136                                         case "OWNTEAMPLAYERS_BUT_ME":   without_me = 1; // fall through
 137                                         case "OWNTEAMPLAYERS":                  teamplayers = 1; break;
 138                                         case "ENEMYTEAMPLAYERS":                teamplayers = 2; break;
 139                                         default: continue;
 140                                 }
 141
 142                                 if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES)
 143                                 {
 144                                         QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 145                                         ++QuickMenu_Buffer_Size;
 146                                         QuickMenu_Buffer_Set(QM_TAG_TITLE, strcat(ftos(teamplayers), ftos(without_me))); // put PLCOMMAND arguments in the title string
 147                                         ++QuickMenu_Buffer_Size;
 148                                         QuickMenu_Buffer_Set(QM_TAG_PLCOMMAND, argv(1));
 149                                         ++QuickMenu_Buffer_Size;
 150                                         QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 151                                 }
 152                         }
 153                         ++QuickMenu_Buffer_Size;
 154                 }
 155                 fclose(fh);
 156         }
 157         else
 158         {
 159                 LOG_WARNF("Unrecognized mode %s", mode);
 160                 return false;
 161         }
 162
 163         if (QuickMenu_Buffer_Size <= 0)
 164         {
 165                 buf_del(QuickMenu_Buffer);
 166                 QuickMenu_Buffer = -1;
 167                 return false;
 168         }
 169
 170         if(mode == "file")
 171                 QuickMenu_Page_Load(submenu, 0);
 172         else
 173                 QuickMenu_Page_Load("", 0);
 174
 175         hud_panel_quickmenu = 1;
 176         if(autocvar_hud_cursormode)
 177                 setcursormode(1);
 178         hudShiftState = 0;
 179
 180         QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 181         return true;
 182 }
 183
 184 void QuickMenu_Buffer_Close()
 185 {
 186         if (QuickMenu_Buffer >= 0)
 187         {
 188                 buf_del(QuickMenu_Buffer);
 189                 QuickMenu_Buffer = -1;
 190                 QuickMenu_Buffer_Size = 0;
 191         }
 192 }
 193
 194 void QuickMenu_Close()
 195 {
 196         if (QuickMenu_CurrentSubMenu)
 197                 strunzone(QuickMenu_CurrentSubMenu);
 198         QuickMenu_CurrentSubMenu = string_null;
 199         int i;
 200         for (i = 0; i < QUICKMENU_MAXLINES; ++i)
 201                 QuickMenu_Page_ClearEntry(i);
 202         QuickMenu_Page_Entries = 0;
 203         hud_panel_quickmenu = 0;
 204         mouseClicked = 0;
 205         prevMouseClicked = 0;
 206         QuickMenu_Buffer_Close();
 207
 208         if(autocvar_hud_cursormode)
 209         if(!mv_active)
 210                 setcursormode(0);
 211 }
 212
 213 // It assumes submenu open tag is already detected
 214 void QuickMenu_skip_submenu(string submenu)
 215 {
 216         string s, z_submenu;
 217         z_submenu = strzone(submenu);
 218         for(++QuickMenu_Buffer_Index ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 219         {
 220                 s = QuickMenu_Buffer_Get();
 221                 if(substring(s, 0, 1) != QM_TAG_SUBMENU)
 222                         continue;
 223                 if(substring(s, 1, -1) == z_submenu) // submenu end
 224                         break;
 225                 QuickMenu_skip_submenu(substring(s, 1, -1));
 226         }
 227         strunzone(z_submenu);
 228 }
 229
 230 bool QuickMenu_IsOpened()
 231 {
 232         return (QuickMenu_Page_Entries > 0);
 233 }
 234
 235 void HUD_Quickmenu_PlayerListEntries(string cmd, int teamplayers, bool without_me);
 236 bool HUD_Quickmenu_PlayerListEntries_Create(string cmd, int teamplayers, bool without_me)
 237 {
 238     TC(int, teamplayers); TC(bool, without_me);
 239         int i;
 240         for(i = 0; i < QUICKMENU_MAXLINES; ++i)
 241                 QuickMenu_Page_ClearEntry(i);
 242         QuickMenu_Buffer_Close();
 243
 244         QuickMenu_Buffer = buf_create();
 245         if(QuickMenu_Buffer < 0)
 246                 return false;
 247
 248         HUD_Quickmenu_PlayerListEntries(cmd, teamplayers, without_me);
 249
 250         if(QuickMenu_Buffer_Size <= 0)
 251         {
 252                 buf_del(QuickMenu_Buffer);
 253                 QuickMenu_Buffer = -1;
 254                 return false;
 255         }
 256         return true;
 257 }
 258
 259 // new_page 0 means page 0, new_page != 0 means next page
 260 int QuickMenu_Buffer_Index_Prev;
 261 bool QuickMenu_Page_Load(string target_submenu, bool new_page)
 262 {
 263     TC(bool, new_page);
 264         string s = string_null, cmd = string_null, z_submenu;
 265
 266         if (new_page == 0)
 267                 QuickMenu_Page = 0;
 268         else
 269                 ++QuickMenu_Page;
 270
 271         z_submenu = strzone(target_submenu);
 272         strcpy(QuickMenu_CurrentSubMenu, z_submenu);
 273
 274         QuickMenu_IsLastPage = true;
 275         QuickMenu_Page_Entries = 0;
 276
 277         QuickMenu_Buffer_Index = 0;
 278         if (z_submenu != "")
 279         {
 280                 // skip everything until the submenu open tag is found
 281                 for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 282                 {
 283                         s = QuickMenu_Buffer_Get();
 284                         if(substring(s, 0, 1) == QM_TAG_SUBMENU && substring(s, 1, -1) == z_submenu)
 285                         {
 286                                 //LOG_INFOF("^3 beginning of %s\n", z_submenu);
 287                                 ++QuickMenu_Buffer_Index;
 288                                 break; // target_submenu found!
 289                         }
 290                         //LOG_INFOF("^1 skipping %s\n", s);
 291                 }
 292                 if(QuickMenu_Buffer_Index == QuickMenu_Buffer_Size)
 293                         LOG_WARNF("Couldn't find submenu \"%s\"", z_submenu);
 294         }
 295
 296         // only the last page can contain up to QUICKMENU_MAXLINES entries
 297         // the other ones contain only (QUICKMENU_MAXLINES - 2) entries
 298         // so that the panel can show an empty row and "Continue..."
 299         float first_entry = QuickMenu_Page * (QUICKMENU_MAXLINES - 2);
 300         int entry_num = 0; // counts entries in target_submenu
 301         for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 302         {
 303                 s = QuickMenu_Buffer_Get();
 304
 305                 if(z_submenu != "" && substring(s, 1, -1) == z_submenu)
 306                 {
 307                         //LOG_INFOF("^3 end of %s\n", z_submenu);
 308                         break;
 309                 }
 310
 311                 if(entry_num >= first_entry)
 312                 {
 313                         ++QuickMenu_Page_Entries;
 314                         if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES - 2)
 315                                 QuickMenu_Buffer_Index_Prev = QuickMenu_Buffer_Index;
 316                         else if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES)
 317                         {
 318                                 QuickMenu_Page_ClearEntry(QUICKMENU_MAXLINES - 1);
 319                                 QuickMenu_Buffer_Index = QuickMenu_Buffer_Index_Prev;
 320                                 QuickMenu_IsLastPage = false;
 321                                 break;
 322                         }
 323                 }
 324
 325                 // NOTE: entries are loaded starting from 1, not from 0
 326                 if(substring(s, 0, 1) == QM_TAG_SUBMENU)
 327                 {
 328                         if(entry_num >= first_entry)
 329                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), "");
 330                         QuickMenu_skip_submenu(substring(s, 1, -1));
 331                 }
 332                 else if(substring(s, 0, 1) == QM_TAG_TITLE)
 333                 {
 334                         ++QuickMenu_Buffer_Index;
 335                         if(entry_num >= first_entry)
 336                         {
 337                                 cmd = QuickMenu_Buffer_Get();
 338                                 string command_code = substring(cmd, 0, 1);
 339                                 if(command_code == QM_TAG_COMMAND)
 340                                         cmd = substring(cmd, 1, -1);
 341                                 else if(command_code == QM_TAG_PLCOMMAND)
 342                                 {
 343                                         // throw away the current quickmenu buffer and load a new one
 344                                         cmd = substring(cmd, 1, -1);
 345                                         strunzone(z_submenu);
 346                                         if(HUD_Quickmenu_PlayerListEntries_Create(cmd, stof(substring(s, 1, 1)), stof(substring(s, 2, 1))))
 347                                                 return QuickMenu_Page_Load("", 0);
 348                                         QuickMenu_Close();
 349                                         return false;
 350                                 }
 351
 352                                 tokenize_console(cmd);
 353                                 QuickMenu_Page_Command_Type[QuickMenu_Page_Entries] = (argv(1) && argv(0) == "toggle");
 354
 355                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), cmd);
 356                         }
 357
 358                 }
 359
 360                 ++entry_num;
 361         }
 362         strunzone(z_submenu);
 363         if (QuickMenu_Page_Entries == 0)
 364         {
 365                 QuickMenu_Close();
 366                 return false;
 367         }
 368         QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 369         return true;
 370 }
 371
 372 bool QuickMenu_ActionForNumber(int num)
 373 {
 374     TC(int, num);
 375         if (!QuickMenu_IsLastPage)
 376         {
 377                 if (num < 0 || num >= QUICKMENU_MAXLINES)
 378                         return false;
 379                 if (num == QUICKMENU_MAXLINES - 1)
 380                         return false;
 381                 if (num == 0)
 382                 {
 383                         QuickMenu_Page_Load(QuickMenu_CurrentSubMenu, +1);
 384                         return false;
 385                 }
 386         } else if (num <= 0 || num > QuickMenu_Page_Entries)
 387                 return false;
 388
 389         if (QuickMenu_Page_Command[num] != "")
 390         {
 391                 localcmd(strcat("\n", QuickMenu_Page_Command[num], "\n"));
 392                 QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 393                 return true;
 394         }
 395         if (QuickMenu_Page_Description[num] != "")
 396                 QuickMenu_Page_Load(QuickMenu_Page_Description[num], 0);
 397         return false;
 398 }
 399
 400 void QuickMenu_Page_ActiveEntry(int entry_num)
 401 {
 402     TC(int, entry_num);
 403         QuickMenu_Page_ActivatedEntry = entry_num;
 404         QuickMenu_Page_ActivatedEntry_Time = time + 0.1;
 405         if(QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 406         {
 407                 bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 408                 // toggle commands don't close the quickmenu
 409                 if(QuickMenu_Page_Command_Type[QuickMenu_Page_ActivatedEntry] == 1)
 410                         QuickMenu_Page_ActivatedEntry_Close = false;
 411                 else
 412                         QuickMenu_Page_ActivatedEntry_Close = (f && !(hudShiftState & S_CTRL));
 413         }
 414         else
 415                 QuickMenu_Page_ActivatedEntry_Close = (!(hudShiftState & S_CTRL));
 416 }
 417
 418 bool QuickMenu_InputEvent(int bInputType, float nPrimary, float nSecondary)
 419 {
 420     TC(int, bInputType);
 421         // we only care for keyboard events
 422         if(bInputType == 2)
 423                 return false;
 424
 425         if(!QuickMenu_IsOpened() || autocvar__hud_configure || mv_active)
 426                 return false;
 427
 428         if(bInputType == 3)
 429         {
 430                 mousepos.x = nPrimary;
 431                 mousepos.y = nSecondary;
 432                 return true;
 433         }
 434
 435         // allow console bind to work
 436         string con_keys = findkeysforcommand("toggleconsole", 0);
 437         int keys = tokenize(con_keys); // findkeysforcommand returns data for this
 438         bool hit_con_bind = false;
 439         int i;
 440         for (i = 0; i < keys; ++i)
 441         {
 442                 if(nPrimary == stof(argv(i)))
 443                         hit_con_bind = true;
 444         }
 445
 446         if(bInputType == 0) {
 447                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 448                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 449                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 450         }
 451         else if(bInputType == 1) {
 452                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 453                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 454                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 455         }
 456
 457         if(nPrimary == K_ESCAPE)
 458         {
 459                 if (bInputType == 1)
 460                         return true;
 461                 QuickMenu_Close();
 462         }
 463         else if(nPrimary >= '0' && nPrimary <= '9')
 464         {
 465                 if (bInputType == 1)
 466                         return true;
 467                 QuickMenu_Page_ActiveEntry(stof(chr2str(nPrimary)));
 468         }
 469         if(nPrimary == K_MOUSE1)
 470         {
 471                 if(bInputType == 0) // key pressed
 472                         mouseClicked |= S_MOUSE1;
 473                 else if(bInputType == 1) // key released
 474                         mouseClicked -= (mouseClicked & S_MOUSE1);
 475         }
 476         else if(nPrimary == K_MOUSE2)
 477         {
 478                 if(bInputType == 0) // key pressed
 479                         mouseClicked |= S_MOUSE2;
 480                 else if(bInputType == 1) // key released
 481                         mouseClicked -= (mouseClicked & S_MOUSE2);
 482         }
 483         else if(hit_con_bind)
 484                 return false;
 485
 486         return true;
 487 }
 488
 489 void QuickMenu_Mouse()
 490 {
 491         if(mv_active) return;
 492
 493         if(!mouseClicked)
 494         if(prevMouseClicked & S_MOUSE2)
 495         {
 496                 QuickMenu_Close();
 497                 return;
 498         }
 499
 500         if (!autocvar_hud_cursormode)
 501                 update_mousepos();
 502
 503         panel = HUD_PANEL(QUICKMENU);
 504         HUD_Panel_LoadCvars();
 505
 506         if(panel_bg_padding)
 507         {
 508                 panel_pos += '1 1 0' * panel_bg_padding;
 509                 panel_size -= '2 2 0' * panel_bg_padding;
 510         }
 511
 512         float first_entry_pos, entries_height;
 513         vector fontsize;
 514         fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
 515         first_entry_pos = panel_pos.y + ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) / 2;
 516         entries_height = panel_size.y - ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y);
 517
 518         if (mousepos.x >= panel_pos.x && mousepos.y >= first_entry_pos && mousepos.x <= panel_pos.x + panel_size.x && mousepos.y <= first_entry_pos + entries_height)
 519         {
 520                 int entry_num = min(QuickMenu_Page_Entries - 1, floor((mousepos.y - first_entry_pos) / fontsize.y));
 521                 if (QuickMenu_IsLastPage || entry_num != QUICKMENU_MAXLINES - 2)
 522                 {
 523                         // recycling panel_pos as entry_pos
 524                         panel_pos.y = first_entry_pos + entry_num * fontsize.y;
 525                         vector color;
 526                         if(mouseClicked & S_MOUSE1)
 527                                 color = '0.5 1 0.5';
 528                         else if(hudShiftState & S_CTRL)
 529                                 color = '1 1 0.3';
 530                         else
 531                                 color = '1 1 1';
 532                         drawfill(panel_pos, vec2(panel_size.x, fontsize.y), color, .2, DRAWFLAG_NORMAL);
 533
 534                         if(!mouseClicked && (prevMouseClicked & S_MOUSE1))
 535                                 QuickMenu_Page_ActiveEntry((entry_num < QUICKMENU_MAXLINES - 1) ? entry_num + 1 : 0);
 536                 }
 537         }
 538
 539         draw_cursor_normal(mousepos, '1 1 1', 0.8);
 540
 541         prevMouseClicked = mouseClicked;
 542 }
 543
 544 void HUD_Quickmenu_DrawEntry(vector pos, string desc, string option, vector fontsize)
 545 {
 546         string entry;
 547         float offset;
 548         float desc_width = panel_size.x;
 549         if(option)
 550         {
 551                 string pic = strcat(hud_skin_path, "/", option);
 552                 if(precache_pic(pic) == "")
 553                         pic = strcat("gfx/hud/default/", option);
 554                 vector option_size = '1 1 0' * fontsize.y * 0.8;
 555                 desc_width -= option_size.x;
 556                 drawpic(pos + vec2(desc_width, (fontsize.y - option_size.y) / 2), pic, option_size, '1 1 1', panel_fg_alpha, DRAWFLAG_ADDITIVE);
 557                 desc_width -= fontsize.x / 4;
 558         }
 559         entry = textShortenToWidth(desc, desc_width, fontsize, stringwidth_colors);
 560         if (autocvar_hud_panel_quickmenu_align > 0)
 561         {
 562                 float real_desc_width = stringwidth_colors(entry, fontsize);
 563                 offset = (desc_width - real_desc_width) * min(autocvar_hud_panel_quickmenu_align, 1);
 564
 565                 if(option)
 566                 {
 567                         // when there's enough room align description regardless the checkbox
 568                         float extra_offset = (panel_size.x - desc_width) * min(autocvar_hud_panel_quickmenu_align, 1);
 569                         if(offset + real_desc_width + extra_offset < desc_width)
 570                                 offset += extra_offset;
 571                         else
 572                                 offset = max(0, desc_width - real_desc_width);
 573                 }
 574                 drawcolorcodedstring(pos + eX * offset, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 575         }
 576         else
 577                 drawcolorcodedstring(pos, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 578 }
 579
 580 void HUD_QuickMenu()
 581 {
 582         if(!autocvar__hud_configure)
 583         {
 584                 if (hud_configure_prev && hud_configure_prev != -1)
 585                         QuickMenu_Close();
 586
 587                 if(!hud_draw_maximized) return;
 588                 if(mv_active) return;
 589                 //if(!autocvar_hud_panel_quickmenu) return;
 590                 if(!hud_panel_quickmenu) return;
 591
 592                 if(QuickMenu_TimeOut)
 593                 if(time > QuickMenu_TimeOut)
 594                 {
 595                         QuickMenu_Close();
 596                         return;
 597                 }
 598         }
 599         else
 600         {
 601                 if(!QuickMenu_IsOpened())
 602                 {
 603                         QuickMenu_Page_Entries = 1;
 604                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 605                         ++QuickMenu_Page_Entries;
 606                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 607                         ++QuickMenu_Page_Entries;
 608                         // although real command doesn't matter here, it must not be empty
 609                         // otherwise the entry is displayed like a submenu
 610                         for (; QuickMenu_Page_Entries < QUICKMENU_MAXLINES - 1; ++QuickMenu_Page_Entries)
 611                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Command%d"), QuickMenu_Page_Entries), "-");
 612                         ++QuickMenu_Page_Entries;
 613                         QuickMenu_Page_ClearEntry(QuickMenu_Page_Entries);
 614                         QuickMenu_IsLastPage = false;
 615                 }
 616         }
 617
 618         HUD_Panel_LoadCvars();
 619
 620         HUD_Scale_Disable();
 621         HUD_Panel_DrawBg();
 622
 623         if(panel_bg_padding)
 624         {
 625                 panel_pos += '1 1 0' * panel_bg_padding;
 626                 panel_size -= '2 2 0' * panel_bg_padding;
 627         }
 628
 629         int i;
 630         vector fontsize;
 631         string color;
 632         fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
 633
 634         if (!QuickMenu_IsLastPage)
 635         {
 636                 color = "^5";
 637                 HUD_Quickmenu_DrawEntry(panel_pos + eY * (panel_size.y - fontsize.y), sprintf("%d: %s%s", 0, color, _("Continue...")), string_null, fontsize);
 638         }
 639         else
 640                 panel_pos.y += ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) / 2;
 641
 642         for (i = 1; i <= QuickMenu_Page_Entries; ++i) {
 643                 if (QuickMenu_Page_Description[i] == "")
 644                         break;
 645                 string option = string_null;
 646                 if (QuickMenu_Page_Command[i] == "")
 647                         color = "^4";
 648                 else
 649                 {
 650                         color = "^3";
 651                         if(QuickMenu_Page_Command_Type[i] == 1) // toggle command
 652                         {
 653                                 int end = strstrofs(QuickMenu_Page_Command[i], ";", 0);
 654                                 if(end < 0)
 655                                         tokenize_console(QuickMenu_Page_Command[i]);
 656                                 else
 657                                         tokenize_console(substring(QuickMenu_Page_Command[i], 0, end));
 658
 659                                 if(argv(1) && argv(0) == "toggle")
 660                                 {
 661                                         // "enable feature xxx" "toggle xxx" (or "toggle xxx 1 0")
 662                                         // "disable feature xxx" "toggle xxx 0 1"
 663                                         float ON_value = 1, OFF_value = 0;
 664                                         if(argv(2))
 665                                                 ON_value = stof(argv(2));
 666
 667                                         if(argv(3))
 668                                                 OFF_value = stof(argv(3));
 669                                         else
 670                                                 OFF_value = !ON_value;
 671
 672                                         float value = cvar(argv(1));
 673                                         if(value == ON_value)
 674                                                 option = "checkbox_checked";
 675                                         else if(value == OFF_value)
 676                                                 option = "checkbox_empty";
 677                                         else
 678                                                 option = "checkbox_undefined";
 679                                 }
 680                         }
 681                 }
 682                 HUD_Quickmenu_DrawEntry(panel_pos, sprintf("%d: %s%s", i, color, QuickMenu_Page_Description[i]), option, fontsize);
 683
 684                 if(QuickMenu_Page_ActivatedEntry_Time && time < QuickMenu_Page_ActivatedEntry_Time
 685                         && QuickMenu_Page_ActivatedEntry == i)
 686                         drawfill(panel_pos, vec2(panel_size.x, fontsize.y), '0.5 1 0.5', .2, DRAWFLAG_NORMAL);
 687
 688                 panel_pos.y += fontsize.y;
 689         }
 690
 691         if(QuickMenu_Page_ActivatedEntry >= 0 && time >= QuickMenu_Page_ActivatedEntry_Time)
 692         {
 693                 if(!QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 694                 {
 695                         bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 696                         if(f && QuickMenu_Page_ActivatedEntry_Close)
 697                                 QuickMenu_Close();
 698                 }
 699                 else if(QuickMenu_Page_ActivatedEntry_Close)
 700                         QuickMenu_Close();
 701                 QuickMenu_Page_ActivatedEntry = -1;
 702                 QuickMenu_Page_ActivatedEntry_Time = 0;
 703         }
 704 }
 705
 706
 707 #define QUICKMENU_SMENU(submenu,eng_submenu) { \
 708         if(target_submenu == eng_submenu && target_submenu_found) \
 709                 return; /* target_submenu entries are now loaded, exit */ \
 710         if(QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES) \
 711                 QuickMenu_Buffer_Set(QM_TAG_SUBMENU, submenu); \
 712         ++QuickMenu_Buffer_Size; \
 713         if(target_submenu == eng_submenu && !target_submenu_found) { \
 714                 QuickMenu_Buffer_Size = 0; /* enable load of next entries */ \
 715                 target_submenu_found = true; \
 716         } \
 717 }
 718
 719 #define QUICKMENU_ENTRY(title,command) { \
 720         if(QuickMenu_Buffer_Size + 1 < QUICKMENU_BUFFER_MAXENTRIES) \
 721         { \
 722                 QuickMenu_Buffer_Set(QM_TAG_TITLE, title); \
 723                 ++QuickMenu_Buffer_Size; \
 724                 QuickMenu_Buffer_Set(QM_TAG_COMMAND, command); \
 725         } \
 726         ++QuickMenu_Buffer_Size; \
 727 }
 728
 729 #define QUICKMENU_SMENU_PL(submenu,eng_submenu,command,teamplayers,without_me) { \
 730         if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES) {\
 731                 QUICKMENU_SMENU(submenu,eng_submenu) \
 732                 QuickMenu_Buffer_Set(QM_TAG_TITLE, strcat(ftos(teamplayers), ftos(without_me))); \
 733                 ++QuickMenu_Buffer_Size; \
 734                 QuickMenu_Buffer_Set(QM_TAG_PLCOMMAND, command); \
 735                 ++QuickMenu_Buffer_Size; \
 736                 QUICKMENU_SMENU(submenu,eng_submenu) \
 737         } \
 738 }
 739
 740
 741
 742 // useful to Translate a string inside the Command
 743 #define QUICKMENU_ENTRY_TC(title,command,text,translated_text) {\
 744         if(prvm_language == "en") { \
 745                 tc_title = title; \
 746                 tc_cmd = sprintf(command, text); \
 747         } \
 748         else if(!autocvar_hud_panel_quickmenu_translatecommands || translated_text == text) { \
 749                 tc_title = strcat("(en)", title); \
 750                 tc_cmd = sprintf(command, text); \
 751         } \
 752         else { \
 753                 tc_title = strcat("(", prvm_language, ")", title); \
 754                 tc_cmd = sprintf(command, translated_text); \
 755         } \
 756         QUICKMENU_ENTRY(tc_title, tc_cmd) \
 757 }
 758
 759 void HUD_Quickmenu_PlayerListEntries(string cmd, int teamplayers, bool without_me)
 760 {
 761     TC(int, teamplayers); TC(bool, without_me);
 762         entity pl;
 763         if(teamplayers && !team_count)
 764                 return;
 765
 766         for(pl = players.sort_next; pl; pl = pl.sort_next)
 767         {
 768                 if(teamplayers == 1 && (pl.team != myteam || pl.team == NUM_SPECTATOR)) // only own team players
 769                         continue;
 770                 if(teamplayers == 2 && (pl.team == myteam || pl.team == NUM_SPECTATOR)) // only enemy team players
 771                         continue;
 772                 if(without_me && pl.sv_entnum == player_localnum)
 773                         continue;
 774                 QUICKMENU_ENTRY(entcs_GetName(pl.sv_entnum), sprintf(cmd, entcs_GetName(pl.sv_entnum)))
 775         }
 776
 777         return;
 778 }
 779
 780
 781 // Specifying target_submenu, this function only loads entries inside target_submenu
 782 // NOTE: alternatively we could have loaded the whole default quickmenu and
 783 // then called QuickMenu_Page_Load(target_submenu, 0);
 784 // but this sytem is more reliable since we can always refer to target_submenu
 785 // with the English title even if a translation is active
 786 void QuickMenu_Default(string target_submenu)
 787 {
 788         bool target_submenu_found = false;
 789         if(target_submenu != "")
 790                 QuickMenu_Buffer_Size = QUICKMENU_BUFFER_MAXENTRIES; // forbids load of next entries until target_submenu
 791
 792         string tc_title;
 793         string tc_cmd;
 794
 795         QUICKMENU_SMENU(_("Chat"), "Chat")
 796                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^nice one")), "say %s", ":-) / nice one", CTX(_("QMCMD^:-) / nice one")))
 797                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^good game")), "say %s", "good game", CTX(_("QMCMD^good game")))
 798                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^hi / good luck")), "say %s", "hi / good luck and have fun", CTX(_("QMCMD^hi / good luck and have fun")))
 799                 if(prvm_language != "en")
 800                 QUICKMENU_ENTRY(CTX(_("QMCMD^Send in English")), "toggle hud_panel_quickmenu_translatecommands 0 1; quickmenu; wait; quickmenu default Chat")
 801         QUICKMENU_SMENU(_("Chat"), "Chat")
 802
 803         if(teamplay)
 804         {
 805         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 806                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^quad soon")), "say_team %s", "quad soon", CTX(_("QMCMD^quad soon")))
 807                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^free item, icon")), "say_team %s; g_waypointsprite_team_here_p", "free item %x^7 (l:%y^7)", CTX(_("QMCMD^free item %x^7 (l:%y^7)")))
 808                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^took item, icon")), "say_team %s; g_waypointsprite_team_here", "took item (l:%l^7)", CTX(_("QMCMD^took item (l:%l^7)")))
 809                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^negative")), "say_team %s", "negative", CTX(_("QMCMD^negative")))
 810                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^positive")), "say_team %s", "positive", CTX(_("QMCMD^positive")))
 811                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^need help, icon")), "say_team %s; g_waypointsprite_team_helpme; cmd voice needhelp", "need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 812                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^enemy seen, icon")), "say_team %s; g_waypointsprite_team_danger_p; cmd voice incoming", "enemy seen (l:%y^7)", CTX(_("QMCMD^enemy seen (l:%y^7)")))
 813                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^flag seen, icon")), "say_team %s; g_waypointsprite_team_here_p; cmd voice seenflag", "flag seen (l:%y^7)", CTX(_("QMCMD^flag seen (l:%y^7)")))
 814                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^defending, icon")), "say_team %s; g_waypointsprite_team_here", "defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 815                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^roaming, icon")), "say_team %s; g_waypointsprite_team_here", "roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 816                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^attacking, icon")), "say_team %s; g_waypointsprite_team_here", "attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 817                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^killed flagcarrier, icon")), "say_team %s; g_waypointsprite_team_here_p", "killed flagcarrier (l:%y^7)", CTX(_("QMCMD^killed flagcarrier (l:%y^7)")))
 818                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^dropped flag, icon")), "say_team %s; g_waypointsprite_team_here_d", "dropped flag (l:%d^7)", CTX(_("QMCMD^dropped flag (l:%d^7)")))
 819                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop weapon, icon")), "say_team %s; g_waypointsprite_team_here; wait; dropweapon", "dropped gun %w^7 (l:%l^7)", CTX(_("QMCMD^dropped weapon %w^7 (l:%l^7)")))
 820                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop flag/key, icon")), "say_team %s; g_waypointsprite_team_here; wait; use", "dropped flag/key %w^7 (l:%l^7)", CTX(_("QMCMD^dropped flag/key %w^7 (l:%l^7)")))
 821         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 822         }
 823
 824         QUICKMENU_SMENU_PL(CTX(_("QMCMD^Send private message to")), "Send private message to", "commandmode tell \"%s^7\"", 0, 1)
 825
 826         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 827                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 828                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person view")), "toggle chase_active")
 829                         QUICKMENU_ENTRY(CTX(_("QMCMD^Player models like mine")), "toggle cl_forceplayermodels")
 830                         QUICKMENU_ENTRY(CTX(_("QMCMD^Names above players")), "toggle hud_shownames")
 831                         QUICKMENU_ENTRY(CTX(_("QMCMD^Crosshair per weapon")), "toggle crosshair_per_weapon")
 832                         QUICKMENU_ENTRY(CTX(_("QMCMD^FPS")), "toggle hud_panel_engineinfo")
 833                         QUICKMENU_ENTRY(CTX(_("QMCMD^Net graph")), "toggle shownetgraph")
 834                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 835
 836                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 837                         QUICKMENU_ENTRY(CTX(_("QMCMD^Hit sound")), "toggle cl_hitsound")
 838                         QUICKMENU_ENTRY(CTX(_("QMCMD^Chat sound")), "toggle con_chatsound")
 839                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 840
 841                 if(spectatee_status > 0)
 842                 {
 843                 QUICKMENU_SMENU(CTX(_("QMCMD^Spectator camera")), "Spectator camera")
 844                         QUICKMENU_ENTRY(CTX(_("QMCMD^1st person")), "chase_active 0; -use")
 845                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person around player")), "chase_active 1; +use")
 846                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person behind")), "chase_active 1; -use")
 847                 QUICKMENU_SMENU(CTX(_("QMCMD^Spectator camera")), "Spectator camera")
 848                 }
 849
 850                 if(spectatee_status == -1)
 851                 {
 852                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 853                         QUICKMENU_ENTRY(CTX(_("QMCMD^Increase speed")), "weapnext")
 854                         QUICKMENU_ENTRY(CTX(_("QMCMD^Decrease speed")), "weapprev")
 855                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision off")), "+use")
 856                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision on")), "-use")
 857                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 858                 }
 859
 860                 QUICKMENU_ENTRY(CTX(_("QMCMD^Fullscreen")), "toggle vid_fullscreen; vid_restart")
 861         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 862
 863         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 864                 QUICKMENU_ENTRY(CTX(_("QMCMD^Restart the map")), "vcall restart")
 865                 QUICKMENU_ENTRY(CTX(_("QMCMD^End match")), "vcall endmatch")
 866                 if(STAT(TIMELIMIT) > 0)
 867                 {
 868                 QUICKMENU_ENTRY(CTX(_("QMCMD^Reduce match time")), "vcall reducematchtime")
 869                 QUICKMENU_ENTRY(CTX(_("QMCMD^Extend match time")), "vcall extendmatchtime")
 870                 }
 871                 if(teamplay)
 872                 QUICKMENU_ENTRY(CTX(_("QMCMD^Shuffle teams")), "vcall shuffleteams")
 873         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 874
 875         if(target_submenu != "" && !target_submenu_found)
 876         {
 877                 LOG_INFOF("Couldn't find submenu \"%s\"", target_submenu);
 878                 if(prvm_language != "en")
 879                         LOG_INFOF("^3Warning: submenu title must be in English", target_submenu);
 880                 QuickMenu_Buffer_Size = 0;
 881         }
 882 }
 883 #undef QUICKMENU_SMENU
 884 #undef QUICKMENU_ENTRY
 885 #undef QUICKMENU_ENTRY_TC