qcsrc/client/hud/panel/modicons.qc

   1 #include "modicons.qh"
   2
   3 #include <common/mapinfo.qh>
   4 #include <common/ent_cs.qh>
   5 #include <server/mutators/mutator/gamemode_ctf.qh> // TODO: remove
   6
   7 // Mod icons panel (#10)
   8
   9 bool mod_active; // is there any active mod icon?
  10
  11 void DrawCAItem(vector myPos, vector mySize, float aspect_ratio, int layout, int i)
  12 {
  13     TC(int, layout); TC(int, i);
  14         int stat = -1;
  15         string pic = "";
  16         vector color = '0 0 0';
  17         switch(i)
  18         {
  19                 case 0:
  20                         stat = STAT(REDALIVE);
  21                         pic = "player_red.tga";
  22                         color = '1 0 0';
  23                         break;
  24                 case 1:
  25                         stat = STAT(BLUEALIVE);
  26                         pic = "player_blue.tga";
  27                         color = '0 0 1';
  28                         break;
  29                 case 2:
  30                         stat = STAT(YELLOWALIVE);
  31                         pic = "player_yellow.tga";
  32                         color = '1 1 0';
  33                         break;
  34                 default:
  35                 case 3:
  36                         stat = STAT(PINKALIVE);
  37                         pic = "player_pink.tga";
  38                         color = '1 0 1';
  39                         break;
  40         }
  41
  42         if(mySize.x/mySize.y > aspect_ratio)
  43         {
  44                 i = aspect_ratio * mySize.y;
  45                 myPos.x = myPos.x + (mySize.x - i) / 2;
  46                 mySize.x = i;
  47         }
  48         else
  49         {
  50                 i = 1/aspect_ratio * mySize.x;
  51                 myPos.y = myPos.y + (mySize.y - i) / 2;
  52                 mySize.y = i;
  53         }
  54
  55         if(layout)
  56         {
  57                 drawpic_aspect_skin(myPos, pic, eX * 0.7 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  58                 drawstring_aspect(myPos + eX * 0.7 * mySize.x, ftos(stat), eX * 0.3 * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
  59         }
  60         else
  61                 drawstring_aspect(myPos, ftos(stat), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
  62 }
  63
  64 // Clan Arena and Freeze Tag HUD modicons
  65 void HUD_Mod_CA(vector myPos, vector mySize)
  66 {
  67         mod_active = 1; // required in each mod function that always shows something
  68
  69         int layout;
  70         if(gametype == MAPINFO_TYPE_CA)
  71                 layout = autocvar_hud_panel_modicons_ca_layout;
  72         else //if(gametype == MAPINFO_TYPE_FREEZETAG)
  73                 layout = autocvar_hud_panel_modicons_freezetag_layout;
  74         int rows, columns;
  75         float aspect_ratio;
  76         aspect_ratio = (layout) ? 2 : 1;
  77         rows = HUD_GetRowCount(team_count, mySize, aspect_ratio);
  78         columns = ceil(team_count/rows);
  79
  80         int i;
  81         float row = 0, column = 0;
  82         vector pos, itemSize;
  83         itemSize = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
  84         for(i=0; i<team_count; ++i)
  85         {
  86                 pos = myPos + eX * column * itemSize.x + eY * row * itemSize.y;
  87
  88                 DrawCAItem(pos, itemSize, aspect_ratio, layout, i);
  89
  90                 ++row;
  91                 if(row >= rows)
  92                 {
  93                         row = 0;
  94                         ++column;
  95                 }
  96         }
  97 }
  98
  99 // CTF HUD modicon section
 100 int redflag_prevframe, blueflag_prevframe, yellowflag_prevframe, pinkflag_prevframe, neutralflag_prevframe; // status during previous frame
 101 int redflag_prevstatus, blueflag_prevstatus, yellowflag_prevstatus, pinkflag_prevstatus, neutralflag_prevstatus; // last remembered status
 102 float redflag_statuschange_time, blueflag_statuschange_time, yellowflag_statuschange_time, pinkflag_statuschange_time, neutralflag_statuschange_time; // time when the status changed
 103
 104 void HUD_Mod_CTF_Reset()
 105 {
 106         redflag_prevstatus = blueflag_prevstatus = yellowflag_prevstatus = pinkflag_prevstatus = neutralflag_prevstatus = 0;
 107         redflag_prevframe = blueflag_prevframe = yellowflag_prevframe = pinkflag_prevframe = neutralflag_prevframe = 0;
 108         redflag_statuschange_time = blueflag_statuschange_time = yellowflag_statuschange_time = pinkflag_statuschange_time = neutralflag_statuschange_time = 0;
 109 }
 110
 111 void HUD_Mod_CTF(vector pos, vector mySize)
 112 {
 113         vector redflag_pos, blueflag_pos, yellowflag_pos, pinkflag_pos, neutralflag_pos;
 114         vector flag_size;
 115         float f; // every function should have that
 116
 117         int redflag, blueflag, yellowflag, pinkflag, neutralflag; // current status
 118         float redflag_statuschange_elapsedtime = 0, blueflag_statuschange_elapsedtime = 0, yellowflag_statuschange_elapsedtime = 0, pinkflag_statuschange_elapsedtime = 0, neutralflag_statuschange_elapsedtime = 0; // time since the status changed
 119         bool ctf_oneflag; // one-flag CTF mode enabled/disabled
 120         bool ctf_stalemate; // currently in stalemate
 121         int stat_items = STAT(CTF_FLAGSTATUS);
 122         float fs, fs2, fs3, size1, size2;
 123         vector e1, e2;
 124
 125         redflag = (stat_items/CTF_RED_FLAG_TAKEN) & 3;
 126         blueflag = (stat_items/CTF_BLUE_FLAG_TAKEN) & 3;
 127         yellowflag = (stat_items/CTF_YELLOW_FLAG_TAKEN) & 3;
 128         pinkflag = (stat_items/CTF_PINK_FLAG_TAKEN) & 3;
 129         neutralflag = (stat_items/CTF_NEUTRAL_FLAG_TAKEN) & 3;
 130
 131         ctf_oneflag = (stat_items & CTF_FLAG_NEUTRAL);
 132
 133         ctf_stalemate = (stat_items & CTF_STALEMATE);
 134
 135         mod_active = (redflag || blueflag || yellowflag || pinkflag || neutralflag || (stat_items & CTF_SHIELDED));
 136
 137         if (autocvar__hud_configure) {
 138                 redflag = 1;
 139                 blueflag = 2;
 140                 if (team_count >= 3)
 141                         yellowflag = 2;
 142                 if (team_count >= 4)
 143                         pinkflag = 3;
 144                 ctf_oneflag = neutralflag = 0; // disable neutral flag in hud editor?
 145         }
 146
 147         // when status CHANGES, set old status into prevstatus and current status into status
 148         #define X(team) MACRO_BEGIN {                                                                                                   \
 149                 if (team##flag != team##flag_prevframe) {                                                                       \
 150                 team##flag_statuschange_time = time;                                                                    \
 151                 team##flag_prevstatus = team##flag_prevframe;                                                   \
 152                 team##flag_prevframe = team##flag;                                                                              \
 153         }                                                                                                                                                       \
 154         team##flag_statuschange_elapsedtime = time - team##flag_statuschange_time;      \
 155     } MACRO_END
 156         X(red);
 157         X(blue);
 158         X(yellow);
 159         X(pink);
 160         X(neutral);
 161         #undef X
 162
 163         const float BLINK_FACTOR = 0.15;
 164         const float BLINK_BASE = 0.85;
 165         // note:
 166         //   RMS = sqrt(BLINK_BASE^2 + 0.5 * BLINK_FACTOR^2)
 167         // thus
 168         //   BLINK_BASE = sqrt(RMS^2 - 0.5 * BLINK_FACTOR^2)
 169         // ensure RMS == 1
 170         const float BLINK_FREQ = 5; // circle frequency, = 2*pi*frequency in hertz
 171
 172         #define X(team, cond) \
 173         string team##_icon = string_null, team##_icon_prevstatus = string_null; \
 174         int team##_alpha, team##_alpha_prevstatus; \
 175         team##_alpha = team##_alpha_prevstatus = 1; \
 176         MACRO_BEGIN { \
 177                 switch (team##flag) { \
 178                         case 1: team##_icon = "flag_" #team "_taken"; break; \
 179                         case 2: team##_icon = "flag_" #team "_lost"; break; \
 180                         case 3: team##_icon = "flag_" #team "_carrying"; team##_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break; \
 181                         default: \
 182                                 if ((stat_items & CTF_SHIELDED) && (cond)) { \
 183                                         team##_icon = "flag_" #team "_shielded"; \
 184                                 } else { \
 185                                         team##_icon = string_null; \
 186                                 } \
 187                                 break; \
 188                 } \
 189                 switch (team##flag_prevstatus) { \
 190                         case 1: team##_icon_prevstatus = "flag_" #team "_taken"; break; \
 191                         case 2: team##_icon_prevstatus = "flag_" #team "_lost"; break; \
 192                         case 3: team##_icon_prevstatus = "flag_" #team "_carrying"; team##_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break; \
 193                         default: \
 194                                 if (team##flag == 3) { \
 195                                         team##_icon_prevstatus = "flag_" #team "_carrying"; /* make it more visible */\
 196                                 } else if((stat_items & CTF_SHIELDED) && (cond)) { \
 197                                         team##_icon_prevstatus = "flag_" #team "_shielded"; \
 198                                 } else { \
 199                                         team##_icon_prevstatus = string_null; \
 200                                 } \
 201                                 break; \
 202                 } \
 203         } MACRO_END
 204         X(red, myteam != NUM_TEAM_1);
 205         X(blue, myteam != NUM_TEAM_2);
 206         X(yellow, myteam != NUM_TEAM_3 && team_count >= 3);
 207         X(pink, myteam != NUM_TEAM_4 && team_count >= 4);
 208         X(neutral, ctf_oneflag);
 209         #undef X
 210
 211         if (ctf_oneflag) {
 212                 // hacky, but these aren't needed
 213                 red_icon = red_icon_prevstatus = blue_icon = blue_icon_prevstatus = yellow_icon = yellow_icon_prevstatus = pink_icon = pink_icon_prevstatus = string_null;
 214                 fs = fs2 = fs3 = 1;
 215         } else switch (team_count) {
 216                 default:
 217                 case 2: fs = 0.5; fs2 = 0.5; fs3 = 0.5; break;
 218                 case 3: fs = 1; fs2 = 0.35; fs3 = 0.35; break;
 219                 case 4: fs = 0.75; fs2 = 0.25; fs3 = 0.5; break;
 220         }
 221
 222         if (mySize_x > mySize_y) {
 223                 size1 = mySize_x;
 224                 size2 = mySize_y;
 225                 e1 = eX;
 226                 e2 = eY;
 227         } else {
 228                 size1 = mySize_y;
 229                 size2 = mySize_x;
 230                 e1 = eY;
 231                 e2 = eX;
 232         }
 233
 234         switch (myteam) {
 235                 default:
 236                 case NUM_TEAM_1: {
 237                         redflag_pos = pos;
 238                         blueflag_pos = pos + eX * fs2 * size1;
 239                         yellowflag_pos = pos - eX * fs2 * size1;
 240                         pinkflag_pos = pos + eX * fs3 * size1;
 241                         break;
 242                 }
 243                 case NUM_TEAM_2: {
 244                         redflag_pos = pos + eX * fs2 * size1;
 245                         blueflag_pos = pos;
 246                         yellowflag_pos = pos - eX * fs2 * size1;
 247                         pinkflag_pos = pos + eX * fs3 * size1;
 248                         break;
 249                 }
 250                 case NUM_TEAM_3: {
 251                         redflag_pos = pos + eX * fs3 * size1;
 252                         blueflag_pos = pos - eX * fs2 * size1;
 253                         yellowflag_pos = pos;
 254                         pinkflag_pos = pos + eX * fs2 * size1;
 255                         break;
 256                 }
 257                 case NUM_TEAM_4: {
 258                         redflag_pos = pos - eX * fs2 * size1;
 259                         blueflag_pos = pos + eX * fs3 * size1;
 260                         yellowflag_pos = pos + eX * fs2 * size1;
 261                         pinkflag_pos = pos;
 262                         break;
 263                 }
 264         }
 265         neutralflag_pos = pos;
 266         flag_size = e1 * fs * size1 + e2 * size2;
 267
 268         #define X(team) MACRO_BEGIN { \
 269                 f = bound(0, team##flag_statuschange_elapsedtime * 2, 1); \
 270                 if (team##_icon && ctf_stalemate) \
 271                         drawpic_aspect_skin(team##flag_pos, "flag_stalemate", flag_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL); \
 272                 if (team##_icon_prevstatus && f < 1) \
 273                         drawpic_aspect_skin_expanding(team##flag_pos, team##_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * team##_alpha_prevstatus, DRAWFLAG_NORMAL, f); \
 274                 if (team##_icon) \
 275                         drawpic_aspect_skin(team##flag_pos, team##_icon, flag_size, '1 1 1', panel_fg_alpha * team##_alpha * f, DRAWFLAG_NORMAL); \
 276         } MACRO_END
 277         X(red);
 278         X(blue);
 279         X(yellow);
 280         X(pink);
 281         X(neutral);
 282         #undef X
 283 }
 284
 285 // Keyhunt HUD modicon section
 286 vector KH_SLOTS[4];
 287
 288 void HUD_Mod_KH(vector pos, vector mySize)
 289 {
 290         mod_active = 1; // keyhunt should never hide the mod icons panel
 291
 292         // Read current state
 293
 294         int state = STAT(KH_KEYS);
 295         int i, key_state;
 296         int all_keys, team1_keys, team2_keys, team3_keys, team4_keys, dropped_keys, carrying_keys;
 297         all_keys = team1_keys = team2_keys = team3_keys = team4_keys = dropped_keys = carrying_keys = 0;
 298
 299         for(i = 0; i < 4; ++i)
 300         {
 301                 key_state = (bitshift(state, i * -5) & 31) - 1;
 302
 303                 if(key_state == -1)
 304                         continue;
 305
 306                 if(key_state == 30)
 307                 {
 308                         ++carrying_keys;
 309                         key_state = myteam;
 310                 }
 311
 312                 switch(key_state)
 313                 {
 314                         case NUM_TEAM_1: ++team1_keys; break;
 315                         case NUM_TEAM_2: ++team2_keys; break;
 316                         case NUM_TEAM_3: ++team3_keys; break;
 317                         case NUM_TEAM_4: ++team4_keys; break;
 318                         case 29: ++dropped_keys; break;
 319                 }
 320
 321                 ++all_keys;
 322         }
 323
 324         // Calculate slot measurements
 325
 326         vector slot_size;
 327
 328         if(all_keys == 4 && mySize.x * 0.5 < mySize.y && mySize.y * 0.5 < mySize.x)
 329         {
 330                 // Quadratic arrangement
 331                 slot_size = eX * mySize.x * 0.5 + eY * mySize.y * 0.5;
 332                 KH_SLOTS[0] = pos;
 333                 KH_SLOTS[1] = pos + eX * slot_size.x;
 334                 KH_SLOTS[2] = pos + eY * slot_size.y;
 335                 KH_SLOTS[3] = pos + eX * slot_size.x + eY * slot_size.y;
 336         }
 337         else
 338         {
 339                 if(mySize.x > mySize.y)
 340                 {
 341                         // Horizontal arrangement
 342                         slot_size = eX * mySize.x / all_keys + eY * mySize.y;
 343                         for(i = 0; i < all_keys; ++i)
 344                                 KH_SLOTS[i] = pos + eX * slot_size.x * i;
 345                 }
 346                 else
 347                 {
 348                         // Vertical arrangement
 349                         slot_size = eX * mySize.x + eY * mySize.y / all_keys;
 350                         for(i = 0; i < all_keys; ++i)
 351                                 KH_SLOTS[i] = pos + eY * slot_size.y * i;
 352                 }
 353         }
 354
 355         // Make icons blink in case of RUN HERE
 356
 357         float blink = 0.6 + sin(2*M_PI*time) / 2.5; // Oscillate between 0.2 and 1
 358         float alpha;
 359         alpha = 1;
 360
 361         if(carrying_keys)
 362                 switch(myteam)
 363                 {
 364                         case NUM_TEAM_1: if(team1_keys == all_keys) alpha = blink; break;
 365                         case NUM_TEAM_2: if(team2_keys == all_keys) alpha = blink; break;
 366                         case NUM_TEAM_3: if(team3_keys == all_keys) alpha = blink; break;
 367                         case NUM_TEAM_4: if(team4_keys == all_keys) alpha = blink; break;
 368                 }
 369
 370         // Draw icons
 371
 372         i = 0;
 373
 374         while(team1_keys--)
 375                 if(myteam == NUM_TEAM_1 && carrying_keys)
 376                 {
 377                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 378                         --carrying_keys;
 379                 }
 380                 else
 381                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 382
 383         while(team2_keys--)
 384                 if(myteam == NUM_TEAM_2 && carrying_keys)
 385                 {
 386                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 387                         --carrying_keys;
 388                 }
 389                 else
 390                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 391
 392         while(team3_keys--)
 393                 if(myteam == NUM_TEAM_3 && carrying_keys)
 394                 {
 395                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 396                         --carrying_keys;
 397                 }
 398                 else
 399                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 400
 401         while(team4_keys--)
 402                 if(myteam == NUM_TEAM_4 && carrying_keys)
 403                 {
 404                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 405                         --carrying_keys;
 406                 }
 407                 else
 408                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 409
 410         while(dropped_keys--)
 411                 drawpic_aspect_skin(KH_SLOTS[i++], "kh_dropped", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 412 }
 413
 414 // Keepaway HUD mod icon
 415 int kaball_prevstatus; // last remembered status
 416 float kaball_statuschange_time; // time when the status changed
 417
 418 // we don't need to reset for keepaway since it immediately
 419 // autocorrects prevstatus as to if the player has the ball or not
 420
 421 void HUD_Mod_Keepaway(vector pos, vector mySize)
 422 {
 423         mod_active = 1; // keepaway should always show the mod HUD
 424
 425         float BLINK_FACTOR = 0.15;
 426         float BLINK_BASE = 0.85;
 427         float BLINK_FREQ = 5;
 428         float kaball_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
 429
 430         int stat_items = STAT(ITEMS);
 431         int kaball = (stat_items/IT_KEY1) & 1;
 432
 433         if(kaball != kaball_prevstatus)
 434         {
 435                 kaball_statuschange_time = time;
 436                 kaball_prevstatus = kaball;
 437         }
 438
 439         vector kaball_pos, kaball_size;
 440
 441         if(mySize.x > mySize.y) {
 442                 kaball_pos = pos + eX * 0.25 * mySize.x;
 443                 kaball_size = eX * 0.5 * mySize.x + eY * mySize.y;
 444         } else {
 445                 kaball_pos = pos + eY * 0.25 * mySize.y;
 446                 kaball_size = eY * 0.5 * mySize.y + eX * mySize.x;
 447         }
 448
 449         float kaball_statuschange_elapsedtime = time - kaball_statuschange_time;
 450         float f = bound(0, kaball_statuschange_elapsedtime*2, 1);
 451
 452         if(kaball_prevstatus && f < 1)
 453                 drawpic_aspect_skin_expanding(kaball_pos, "keepawayball_carrying", kaball_size, '1 1 1', panel_fg_alpha * kaball_alpha, DRAWFLAG_NORMAL, f);
 454
 455         if(kaball)
 456                 drawpic_aspect_skin(pos, "keepawayball_carrying", eX * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha * kaball_alpha * f, DRAWFLAG_NORMAL);
 457 }
 458
 459
 460 // Nexball HUD mod icon
 461 void HUD_Mod_NexBall(vector pos, vector mySize)
 462 {
 463         float nb_pb_starttime, dt, p;
 464         int stat_items;
 465
 466         stat_items = STAT(ITEMS);
 467         nb_pb_starttime = STAT(NB_METERSTART);
 468
 469         if (stat_items & IT_KEY1)
 470                 mod_active = 1;
 471         else
 472                 mod_active = 0;
 473
 474         //Manage the progress bar if any
 475         if (nb_pb_starttime > 0)
 476         {
 477                 dt = (time - nb_pb_starttime) % nb_pb_period;
 478                 // one period of positive triangle
 479                 p = 2 * dt / nb_pb_period;
 480                 if (p > 1)
 481                         p = 2 - p;
 482
 483                 HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", p, (mySize.x <= mySize.y), 0, autocvar_hud_progressbar_nexball_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 484         }
 485
 486         if (stat_items & IT_KEY1)
 487                 drawpic_aspect_skin(pos, "nexball_carrying", eX * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 488 }
 489
 490 // Race/CTS HUD mod icons
 491 float crecordtime_prev; // last remembered crecordtime
 492 float crecordtime_change_time; // time when crecordtime last changed
 493 float srecordtime_prev; // last remembered srecordtime
 494 float srecordtime_change_time; // time when srecordtime last changed
 495
 496 float race_status_time;
 497 int race_status_prev;
 498 string race_status_name_prev;
 499
 500 // Check if the given name already exist in race rankings? In that case, where? (otherwise return 0)
 501 int race_CheckName(string net_name)
 502 {
 503         int i;
 504         for (i=RANKINGS_CNT-1;i>=0;--i)
 505                 if(grecordholder[i] == net_name)
 506                         return i+1;
 507         return 0;
 508 }
 509
 510 void race_showTime(string text, vector pos, vector timeText_ofs, float theTime, vector textSize, float f)
 511 {
 512         drawstring_aspect(pos, text, textSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 513         drawstring_aspect(pos + timeText_ofs, TIME_ENCODED_TOSTRING(theTime), textSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 514         if (f < 1) {
 515                 drawstring_aspect_expanding(pos, text, textSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
 516                 drawstring_aspect_expanding(pos + timeText_ofs, TIME_ENCODED_TOSTRING(theTime), textSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
 517         }
 518 }
 519
 520 void HUD_Mod_Race(vector pos, vector mySize)
 521 {
 522         mod_active = 1; // race should never hide the mod icons panel
 523         entity me;
 524         me = playerslots[player_localnum];
 525         float score;
 526         score = me.(scores[ps_primary]);
 527
 528         if(!(scores_flags[ps_primary] & SFL_TIME) || teamplay) // race/cts record display on HUD
 529                 return; // no records in the actual race
 530
 531         // clientside personal record
 532         string rr;
 533         if(gametype == MAPINFO_TYPE_CTS)
 534                 rr = CTS_RECORD;
 535         else
 536                 rr = RACE_RECORD;
 537         float t = stof(db_get(ClientProgsDB, strcat(shortmapname, rr, "time")));
 538
 539         if(score && (score < t || !t)) {
 540                 db_put(ClientProgsDB, strcat(shortmapname, rr, "time"), ftos(score));
 541                 if(autocvar_cl_autodemo_delete_keeprecords)
 542                 {
 543                         float f = autocvar_cl_autodemo_delete;
 544                         f &= ~1;
 545                         cvar_set("cl_autodemo_delete", ftos(f)); // don't delete demo with new record!
 546                 }
 547         }
 548
 549         if(t != crecordtime_prev) {
 550                 crecordtime_prev = t;
 551                 crecordtime_change_time = time;
 552         }
 553
 554         vector textPos, medalPos;
 555         float squareSize;
 556         if(mySize.x > mySize.y) {
 557                 // text on left side
 558                 squareSize = min(mySize.y, mySize.x/2);
 559                 textPos = pos + eX * 0.5 * max(0, mySize.x/2 - squareSize) + eY * 0.5 * (mySize.y - squareSize);
 560                 medalPos = pos + eX * 0.5 * max(0, mySize.x/2 - squareSize) + eX * 0.5 * mySize.x + eY * 0.5 * (mySize.y - squareSize);
 561         } else {
 562                 // text on top
 563                 squareSize = min(mySize.x, mySize.y/2);
 564                 textPos = pos + eY * 0.5 * max(0, mySize.y/2 - squareSize) + eX * 0.5 * (mySize.x - squareSize);
 565                 medalPos = pos + eY * 0.5 * max(0, mySize.y/2 - squareSize) + eY * 0.5 * mySize.y + eX * 0.5 * (mySize.x - squareSize);
 566         }
 567         vector textSize = eX * squareSize + eY * 0.25 * squareSize;
 568
 569         race_showTime(_("Personal best"), textPos, eY * 0.25 * squareSize, t, textSize, time - crecordtime_change_time);
 570
 571         // server record
 572         t = race_server_record;
 573         if(t != srecordtime_prev) {
 574                 srecordtime_prev = t;
 575                 srecordtime_change_time = time;
 576         }
 577
 578         textPos += eY * 0.5 * squareSize;
 579         race_showTime(_("Server best"), textPos, eY * 0.25 * squareSize, t, textSize, time - srecordtime_change_time);
 580
 581         if (race_status != race_status_prev || race_status_name != race_status_name_prev) {
 582                 race_status_time = time + 5;
 583                 race_status_prev = race_status;
 584                 if (race_status_name_prev)
 585                         strunzone(race_status_name_prev);
 586                 race_status_name_prev = strzone(race_status_name);
 587         }
 588
 589         // race "awards"
 590         float a;
 591         a = bound(0, race_status_time - time, 1);
 592
 593         string s;
 594         s = textShortenToWidth(race_status_name, squareSize, '1 1 0' * 0.1 * squareSize, stringwidth_colors);
 595
 596         float rank;
 597         if(race_status > 0)
 598                 rank = race_CheckName(race_status_name);
 599         else
 600                 rank = 0;
 601         string rankname;
 602         rankname = count_ordinal(rank);
 603
 604         vector namepos;
 605         namepos = medalPos + '0 0.8 0' * squareSize;
 606         vector rankpos;
 607         rankpos = medalPos + '0 0.15 0' * squareSize;
 608
 609         if(race_status == 0)
 610                 drawpic_aspect_skin(medalPos, "race_newfail", '1 1 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 611         else if(race_status == 1) {
 612                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newtime", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 613                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
 614                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 615         } else if(race_status == 2) {
 616                 if(race_status_name == entcs_GetName(player_localnum) || !race_myrank || race_myrank < rank)
 617                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankgreen", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 618                 else
 619                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankyellow", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 620                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
 621                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 622         } else if(race_status == 3) {
 623                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrecordserver", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 624                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
 625                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 626         }
 627
 628         if (race_status_time - time <= 0) {
 629                 race_status_prev = -1;
 630                 race_status = -1;
 631                 if(race_status_name)
 632                         strunzone(race_status_name);
 633                 race_status_name = string_null;
 634                 if(race_status_name_prev)
 635                         strunzone(race_status_name_prev);
 636                 race_status_name_prev = string_null;
 637         }
 638 }
 639
 640 void DrawDomItem(vector myPos, vector mySize, float aspect_ratio, int layout, int i)
 641 {
 642     TC(int, layout); TC(int, i);
 643         float stat = -1;
 644         string pic = "";
 645         vector color = '0 0 0';
 646         switch(i)
 647         {
 648                 case 0:
 649                         stat = STAT(DOM_PPS_RED);
 650                         pic = "dom_icon_red";
 651                         color = '1 0 0';
 652                         break;
 653                 case 1:
 654                         stat = STAT(DOM_PPS_BLUE);
 655                         pic = "dom_icon_blue";
 656                         color = '0 0 1';
 657                         break;
 658                 case 2:
 659                         stat = STAT(DOM_PPS_YELLOW);
 660                         pic = "dom_icon_yellow";
 661                         color = '1 1 0';
 662                         break;
 663                 default:
 664                 case 3:
 665                         stat = STAT(DOM_PPS_PINK);
 666                         pic = "dom_icon_pink";
 667                         color = '1 0 1';
 668                         break;
 669         }
 670         float pps_ratio = stat / STAT(DOM_TOTAL_PPS);
 671
 672         if(mySize.x/mySize.y > aspect_ratio)
 673         {
 674                 i = aspect_ratio * mySize.y;
 675                 myPos.x = myPos.x + (mySize.x - i) / 2;
 676                 mySize.x = i;
 677         }
 678         else
 679         {
 680                 i = 1/aspect_ratio * mySize.x;
 681                 myPos.y = myPos.y + (mySize.y - i) / 2;
 682                 mySize.y = i;
 683         }
 684
 685         if (layout) // show text too
 686         {
 687                 //draw the text
 688                 color *= 0.5 + pps_ratio * (1 - 0.5); // half saturated color at min, full saturated at max
 689                 if (layout == 2) // average pps
 690                         drawstring_aspect(myPos + eX * mySize.y, ftos_decimals(stat, 2), eX * (2/3) * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 691                 else // percentage of average pps
 692                         drawstring_aspect(myPos + eX * mySize.y, strcat( ftos(floor(pps_ratio*100 + 0.5)), "%" ), eX * (2/3) * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 693         }
 694
 695         //draw the icon
 696         drawpic_aspect_skin(myPos, pic, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 697         if (stat > 0)
 698         {
 699                 drawsetcliparea(myPos.x, myPos.y + mySize.y * (1 - pps_ratio), mySize.y, mySize.y * pps_ratio);
 700                 drawpic_aspect_skin(myPos, strcat(pic, "-highlighted"), '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 701                 drawresetcliparea();
 702         }
 703 }
 704
 705 void HUD_Mod_Dom(vector myPos, vector mySize)
 706 {
 707         mod_active = 1; // required in each mod function that always shows something
 708
 709         int layout = autocvar_hud_panel_modicons_dom_layout;
 710         int rows, columns;
 711         float aspect_ratio;
 712         aspect_ratio = (layout) ? 3 : 1;
 713         rows = HUD_GetRowCount(team_count, mySize, aspect_ratio);
 714         columns = ceil(team_count/rows);
 715
 716         int i;
 717         float row = 0, column = 0;
 718         vector pos, itemSize;
 719         itemSize = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
 720         for(i=0; i<team_count; ++i)
 721         {
 722                 pos = myPos + eX * column * itemSize.x + eY * row * itemSize.y;
 723
 724                 DrawDomItem(pos, itemSize, aspect_ratio, layout, i);
 725
 726                 ++row;
 727                 if(row >= rows)
 728                 {
 729                         row = 0;
 730                         ++column;
 731                 }
 732         }
 733 }
 734
 735 void HUD_ModIcons_SetFunc()
 736 {
 737         switch(gametype)
 738         {
 739                 case MAPINFO_TYPE_KEYHUNT:              HUD_ModIcons_GameType = HUD_Mod_KH; break;
 740                 case MAPINFO_TYPE_CTF:                  HUD_ModIcons_GameType = HUD_Mod_CTF; break;
 741                 case MAPINFO_TYPE_NEXBALL:              HUD_ModIcons_GameType = HUD_Mod_NexBall; break;
 742                 case MAPINFO_TYPE_CTS:
 743                 case MAPINFO_TYPE_RACE:         HUD_ModIcons_GameType = HUD_Mod_Race; break;
 744                 case MAPINFO_TYPE_CA:
 745                 case MAPINFO_TYPE_FREEZETAG:    HUD_ModIcons_GameType = HUD_Mod_CA; break;
 746                 case MAPINFO_TYPE_DOMINATION:   HUD_ModIcons_GameType = HUD_Mod_Dom; break;
 747                 case MAPINFO_TYPE_KEEPAWAY:     HUD_ModIcons_GameType = HUD_Mod_Keepaway; break;
 748         }
 749 }
 750
 751 int mod_prev; // previous state of mod_active to check for a change
 752 float mod_alpha;
 753 float mod_change; // "time" when mod_active changed
 754
 755 void HUD_ModIcons()
 756 {
 757         if(!autocvar__hud_configure)
 758         {
 759                 if(!autocvar_hud_panel_modicons) return;
 760                 if(!HUD_ModIcons_GameType) return;
 761         }
 762
 763         HUD_Panel_UpdateCvars();
 764
 765         draw_beginBoldFont();
 766
 767         if(mod_active != mod_prev) {
 768                 mod_change = time;
 769                 mod_prev = mod_active;
 770         }
 771
 772         if(mod_active || autocvar__hud_configure)
 773                 mod_alpha = bound(0, (time - mod_change) * 2, 1);
 774         else
 775                 mod_alpha = bound(0, 1 - (time - mod_change) * 2, 1);
 776
 777         if (autocvar_hud_panel_modicons_dynamichud)
 778                 HUD_Scale_Enable();
 779         else
 780                 HUD_Scale_Disable();
 781         if(mod_alpha)
 782                 HUD_Panel_DrawBg(mod_alpha);
 783
 784         if(panel_bg_padding)
 785         {
 786                 panel_pos += '1 1 0' * panel_bg_padding;
 787                 panel_size -= '2 2 0' * panel_bg_padding;
 788         }
 789
 790         if(autocvar__hud_configure)
 791                 HUD_Mod_CTF(panel_pos, panel_size);
 792         else
 793                 HUD_ModIcons_GameType(panel_pos, panel_size);
 794
 795         draw_endBoldFont();
 796 }