qcsrc/client/hud/hud_config.qc

   1 #include "hud_config.qh"
   2
   3 #include <client/draw.qh>
   4 #include <client/hud/hud.qh>
   5 #include <client/hud/panel/chat.qh>
   6 #include <client/hud/panel/scoreboard.qh>
   7 #include <client/view.qh>
   8
   9 // Save the config
  10 void HUD_Panel_ExportCfg(string cfgname)
  11 {
  12         float fh;
  13         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  14         string str = "";
  15         fh = fopen(filename, FILE_WRITE);
  16         if(fh >= 0)
  17         {
  18                 HUD_Write("//title \n");
  19                 HUD_Write("//author \n");
  20                 HUD_Write("\n");
  21                 HUD_Write_Cvar("hud_skin");
  22                 HUD_Write_Cvar("hud_panel_bg");
  23                 HUD_Write_Cvar("hud_panel_bg_color");
  24                 HUD_Write_Cvar("hud_panel_bg_color_team");
  25                 HUD_Write_Cvar("hud_panel_bg_alpha");
  26                 HUD_Write_Cvar("hud_panel_bg_border");
  27                 HUD_Write_Cvar("hud_panel_bg_padding");
  28                 HUD_Write_Cvar("hud_panel_fg_alpha");
  29                 HUD_Write("\n");
  30
  31                 HUD_Write_Cvar("hud_dock");
  32                 HUD_Write_Cvar("hud_dock_color");
  33                 HUD_Write_Cvar("hud_dock_color_team");
  34                 HUD_Write_Cvar("hud_dock_alpha");
  35                 HUD_Write("\n");
  36
  37                 HUD_Write_Cvar("hud_progressbar_alpha");
  38                 HUD_Write_Cvar("hud_progressbar_strength_color");
  39                 HUD_Write_Cvar("hud_progressbar_superweapons_color");
  40                 HUD_Write_Cvar("hud_progressbar_shield_color");
  41                 HUD_Write_Cvar("hud_progressbar_health_color");
  42                 HUD_Write_Cvar("hud_progressbar_armor_color");
  43                 HUD_Write_Cvar("hud_progressbar_fuel_color");
  44                 HUD_Write_Cvar("hud_progressbar_oxygen_color");
  45                 HUD_Write_Cvar("hud_progressbar_nexball_color");
  46                 HUD_Write_Cvar("hud_progressbar_speed_color");
  47                 HUD_Write_Cvar("hud_progressbar_acceleration_color");
  48                 HUD_Write_Cvar("hud_progressbar_acceleration_neg_color");
  49                 HUD_Write_Cvar("hud_progressbar_vehicles_ammo1_color");
  50                 HUD_Write_Cvar("hud_progressbar_vehicles_ammo2_color");
  51                 HUD_Write("\n");
  52
  53                 HUD_Write_Cvar("_hud_panelorder");
  54                 HUD_Write("\n");
  55
  56                 HUD_Write_Cvar("hud_configure_grid");
  57                 HUD_Write_Cvar("hud_configure_grid_xsize");
  58                 HUD_Write_Cvar("hud_configure_grid_ysize");
  59                 HUD_Write("\n");
  60
  61                 // common cvars for all panels
  62                 for (int i = 0; i < REGISTRY_COUNT(hud_panels); ++i)
  63                 {
  64                         panel = REGISTRY_GET(hud_panels, i);
  65
  66                         HUD_Write_PanelCvar("_pos");
  67                         HUD_Write_PanelCvar("_size");
  68                         HUD_Write_PanelCvar("_bg");
  69                         HUD_Write_PanelCvar("_bg_color");
  70                         HUD_Write_PanelCvar("_bg_color_team");
  71                         HUD_Write_PanelCvar("_bg_alpha");
  72                         HUD_Write_PanelCvar("_bg_border");
  73                         HUD_Write_PanelCvar("_bg_padding");
  74                         panel.panel_export(fh);
  75                         HUD_Write("\n");
  76                 }
  77
  78                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
  79
  80                 LOG_INFOF(_("^2Successfully exported to %s! (Note: It's saved in data/data/)"), filename);
  81                 fclose(fh);
  82         }
  83         else
  84                 LOG_INFOF(_("^1Couldn't write to %s"), filename);
  85 }
  86
  87 void HUD_Configure_Exit_Force()
  88 {
  89         if (hud_configure_menu_open)
  90         {
  91                 hud_configure_menu_open = 0;
  92                 localcmd("togglemenu\n");
  93         }
  94         cursor_type = CURSOR_NORMAL;
  95         cvar_set("_hud_configure", "0");
  96 }
  97
  98 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
  99 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 100 {
 101         vector myCenter, targCenter;
 102         vector myTarget = myPos;
 103         int i;
 104         for (i = 0; i < REGISTRY_COUNT(hud_panels); ++i) {
 105                 panel = REGISTRY_GET(hud_panels, i);
 106                 if(!(panel.panel_configflags & PANEL_CONFIG_MAIN)) continue;
 107                 if(panel == highlightedPanel) continue;
 108                 HUD_Panel_UpdatePosSize();
 109                 if(!panel_enabled) continue;
 110
 111                 panel_pos -= '1 1 0' * panel_bg_border;
 112                 panel_size += '2 2 0' * panel_bg_border;
 113
 114                 if(myPos.y + mySize.y < panel_pos.y)
 115                         continue;
 116                 if(myPos.y > panel_pos.y + panel_size.y)
 117                         continue;
 118
 119                 if(myPos.x + mySize.x < panel_pos.x)
 120                         continue;
 121                 if(myPos.x > panel_pos.x + panel_size.x)
 122                         continue;
 123
 124                 // OK, there IS a collision.
 125
 126                 myCenter.x = myPos.x + 0.5 * mySize.x;
 127                 myCenter.y = myPos.y + 0.5 * mySize.y;
 128
 129                 targCenter.x = panel_pos.x + 0.5 * panel_size.x;
 130                 targCenter.y = panel_pos.y + 0.5 * panel_size.y;
 131
 132                 if(myCenter.x < targCenter.x && myCenter.y < targCenter.y) // top left (of the target panel)
 133                 {
 134                         if(myPos.x + mySize.x - panel_pos.x < myPos.y + mySize.y - panel_pos.y) // push it to the side
 135                                 myTarget.x = panel_pos.x - mySize.x;
 136                         else // push it upwards
 137                                 myTarget.y = panel_pos.y - mySize.y;
 138                 }
 139                 else if(myCenter.x > targCenter.x && myCenter.y < targCenter.y) // top right
 140                 {
 141                         if(panel_pos.x + panel_size.x - myPos.x < myPos.y + mySize.y - panel_pos.y) // push it to the side
 142                                 myTarget.x = panel_pos.x + panel_size.x;
 143                         else // push it upwards
 144                                 myTarget.y = panel_pos.y - mySize.y;
 145                 }
 146                 else if(myCenter.x < targCenter.x && myCenter.y > targCenter.y) // bottom left
 147                 {
 148                         if(myPos.x + mySize.x - panel_pos.x < panel_pos.y + panel_size.y - myPos.y) // push it to the side
 149                                 myTarget.x = panel_pos.x - mySize.x;
 150                         else // push it downwards
 151                                 myTarget.y = panel_pos.y + panel_size.y;
 152                 }
 153                 else if(myCenter.x > targCenter.x && myCenter.y > targCenter.y) // bottom right
 154                 {
 155                         if(panel_pos.x + panel_size.x - myPos.x < panel_pos.y + panel_size.y - myPos.y) // push it to the side
 156                                 myTarget.x = panel_pos.x + panel_size.x;
 157                         else // push it downwards
 158                                 myTarget.y = panel_pos.y + panel_size.y;
 159                 }
 160                 //if(cvar("hud_configure_checkcollisions_debug"))
 161                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 162         }
 163
 164         return myTarget;
 165 }
 166
 167 void HUD_Panel_SetPos(vector pos)
 168 {
 169         panel = highlightedPanel;
 170         HUD_Panel_UpdatePosSize();
 171         vector mySize;
 172         mySize = panel_size;
 173
 174         //if(cvar("hud_configure_checkcollisions_debug"))
 175                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 176
 177         if(autocvar_hud_configure_grid)
 178         {
 179                 pos.x = floor((pos.x/vid_conwidth)/hud_configure_gridSize.x + 0.5) * hud_configure_realGridSize.x;
 180                 pos.y = floor((pos.y/vid_conheight)/hud_configure_gridSize.y + 0.5) * hud_configure_realGridSize.y;
 181         }
 182
 183         if(hud_configure_checkcollisions)
 184                 pos = HUD_Panel_CheckMove(pos, mySize);
 185
 186         pos.x = bound(0, pos.x, vid_conwidth - mySize.x);
 187         pos.y = bound(0, pos.y, vid_conheight - mySize.y);
 188
 189         string s;
 190         s = strcat(ftos(pos.x/vid_conwidth), " ", ftos(pos.y/vid_conheight));
 191
 192         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_pos"), s);
 193 }
 194
 195 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 196 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 197         vector targEndPos;
 198         vector dist;
 199         float ratio = mySize.x/mySize.y;
 200         int i;
 201         for (i = 0; i < REGISTRY_COUNT(hud_panels); ++i) {
 202                 panel = REGISTRY_GET(hud_panels, i);
 203                 if(!(panel.panel_configflags & PANEL_CONFIG_MAIN)) continue;
 204                 if(panel == highlightedPanel) continue;
 205                 HUD_Panel_UpdatePosSize();
 206                 if(!panel_enabled) continue;
 207
 208                 panel_pos -= '1 1 0' * panel_bg_border;
 209                 panel_size += '2 2 0' * panel_bg_border;
 210
 211                 targEndPos = panel_pos + panel_size;
 212
 213                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 214                 if(resizeorigin.x > panel_pos.x && resizeorigin.x < targEndPos.x && resizeorigin.y > panel_pos.y && resizeorigin.y < targEndPos.y)
 215                         continue;
 216
 217                 if (resizeCorner == 1)
 218                 {
 219                         // check if this panel is on our way
 220                         if (resizeorigin.x <= panel_pos.x)
 221                                 continue;
 222                         if (resizeorigin.y <= panel_pos.y)
 223                                 continue;
 224                         if (targEndPos.x <= resizeorigin.x - mySize.x)
 225                                 continue;
 226                         if (targEndPos.y <= resizeorigin.y - mySize.y)
 227                                 continue;
 228
 229                         // there is a collision:
 230                         // detect which side of the panel we are facing is actually limiting the resizing
 231                         // (which side the resize direction finds for first) and reduce the size up to there
 232                         //
 233                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 234                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 235                         dist.x = resizeorigin.x - targEndPos.x;
 236                         dist.y = resizeorigin.y - targEndPos.y;
 237                         if (dist.y <= 0 || dist.x / dist.y > ratio)
 238                                 mySize.x = min(mySize.x, dist.x);
 239                         else
 240                                 mySize.y = min(mySize.y, dist.y);
 241                 }
 242                 else if (resizeCorner == 2)
 243                 {
 244                         if (resizeorigin.x >= targEndPos.x)
 245                                 continue;
 246                         if (resizeorigin.y <= panel_pos.y)
 247                                 continue;
 248                         if (panel_pos.x >= resizeorigin.x + mySize.x)
 249                                 continue;
 250                         if (targEndPos.y <= resizeorigin.y - mySize.y)
 251                                 continue;
 252
 253                         dist.x = panel_pos.x - resizeorigin.x;
 254                         dist.y = resizeorigin.y - targEndPos.y;
 255                         if (dist.y <= 0 || dist.x / dist.y > ratio)
 256                                 mySize.x = min(mySize.x, dist.x);
 257                         else
 258                                 mySize.y = min(mySize.y, dist.y);
 259                 }
 260                 else if (resizeCorner == 3)
 261                 {
 262                         if (resizeorigin.x <= panel_pos.x)
 263                                 continue;
 264                         if (resizeorigin.y >= targEndPos.y)
 265                                 continue;
 266                         if (targEndPos.x <= resizeorigin.x - mySize.x)
 267                                 continue;
 268                         if (panel_pos.y >= resizeorigin.y + mySize.y)
 269                                 continue;
 270
 271                         dist.x = resizeorigin.x - targEndPos.x;
 272                         dist.y = panel_pos.y - resizeorigin.y;
 273                         if (dist.y <= 0 || dist.x / dist.y > ratio)
 274                                 mySize.x = min(mySize.x, dist.x);
 275                         else
 276                                 mySize.y = min(mySize.y, dist.y);
 277                 }
 278                 else if (resizeCorner == 4)
 279                 {
 280                         if (resizeorigin.x >= targEndPos.x)
 281                                 continue;
 282                         if (resizeorigin.y >= targEndPos.y)
 283                                 continue;
 284                         if (panel_pos.x >= resizeorigin.x + mySize.x)
 285                                 continue;
 286                         if (panel_pos.y >= resizeorigin.y + mySize.y)
 287                                 continue;
 288
 289                         dist.x = panel_pos.x - resizeorigin.x;
 290                         dist.y = panel_pos.y - resizeorigin.y;
 291                         if (dist.y <= 0 || dist.x / dist.y > ratio)
 292                                 mySize.x = min(mySize.x, dist.x);
 293                         else
 294                                 mySize.y = min(mySize.y, dist.y);
 295                 }
 296                 //if(cvar("hud_configure_checkcollisions_debug"))
 297                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 298         }
 299
 300         return mySize;
 301 }
 302
 303 void HUD_Panel_SetPosSize(vector mySize)
 304 {
 305         panel = highlightedPanel;
 306         HUD_Panel_UpdatePosSize();
 307         vector resizeorigin = panel_click_resizeorigin;
 308         vector myPos;
 309
 310         // minimum panel size cap
 311         mySize.x = max(0.025 * vid_conwidth, mySize.x);
 312         mySize.y = max(0.025 * vid_conheight, mySize.y);
 313
 314         if(highlightedPanel == HUD_PANEL(CHAT)) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 315         {
 316                 mySize.x = max(17 * autocvar_con_chatsize, mySize.x);
 317                 mySize.y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize.y);
 318         }
 319
 320         // collision testing|
 321         // -----------------+
 322
 323         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 324         if(resizeCorner == 1) {
 325                 myPos.x = resizeorigin.x - mySize.x;
 326                 myPos.y = resizeorigin.y - mySize.y;
 327         } else if(resizeCorner == 2) {
 328                 myPos.x = resizeorigin.x;
 329                 myPos.y = resizeorigin.y - mySize.y;
 330         } else if(resizeCorner == 3) {
 331                 myPos.x = resizeorigin.x - mySize.x;
 332                 myPos.y = resizeorigin.y;
 333         } else { // resizeCorner == 4
 334                 myPos.x = resizeorigin.x;
 335                 myPos.y = resizeorigin.y;
 336         }
 337
 338         // left/top screen edges
 339         if(myPos.x < 0)
 340                 mySize.x = mySize.x + myPos.x;
 341         if(myPos.y < 0)
 342                 mySize.y = mySize.y + myPos.y;
 343
 344         // bottom/right screen edges
 345         if(myPos.x + mySize.x > vid_conwidth)
 346                 mySize.x = vid_conwidth - myPos.x;
 347         if(myPos.y + mySize.y > vid_conheight)
 348                 mySize.y = vid_conheight - myPos.y;
 349
 350         //if(cvar("hud_configure_checkcollisions_debug"))
 351                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 352
 353         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 354         if(autocvar_hud_configure_grid)
 355         {
 356                 mySize.x = floor((mySize.x/vid_conwidth)/hud_configure_gridSize.x + 0.5) * hud_configure_realGridSize.x;
 357                 mySize.y = floor((mySize.y/vid_conheight)/hud_configure_gridSize.y + 0.5) * hud_configure_realGridSize.y;
 358         }
 359
 360         if(hud_configure_checkcollisions)
 361                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 362
 363         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 364         mySize.x = max(0.025 * vid_conwidth, mySize.x);
 365         mySize.y = max(0.025 * vid_conheight, mySize.y);
 366
 367         // do another pos check, as size might have changed by now
 368         if(resizeCorner == 1) {
 369                 myPos.x = resizeorigin.x - mySize.x;
 370                 myPos.y = resizeorigin.y - mySize.y;
 371         } else if(resizeCorner == 2) {
 372                 myPos.x = resizeorigin.x;
 373                 myPos.y = resizeorigin.y - mySize.y;
 374         } else if(resizeCorner == 3) {
 375                 myPos.x = resizeorigin.x - mySize.x;
 376                 myPos.y = resizeorigin.y;
 377         } else { // resizeCorner == 4
 378                 myPos.x = resizeorigin.x;
 379                 myPos.y = resizeorigin.y;
 380         }
 381
 382         //if(cvar("hud_configure_checkcollisions_debug"))
 383                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 384
 385         string s;
 386         s = strcat(ftos(mySize.x/vid_conwidth), " ", ftos(mySize.y/vid_conheight));
 387         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_size"), s);
 388
 389         s = strcat(ftos(myPos.x/vid_conwidth), " ", ftos(myPos.y/vid_conheight));
 390         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_pos"), s);
 391 }
 392
 393 float pressed_key_time;
 394 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 395 void HUD_Panel_Arrow_Action(float nPrimary)
 396 {
 397         if(!highlightedPanel)
 398                 return;
 399
 400         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 401
 402         float step;
 403         if(autocvar_hud_configure_grid)
 404         {
 405                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 406                 {
 407                         if (hudShiftState & S_SHIFT)
 408                                 step = hud_configure_realGridSize.y;
 409                         else
 410                                 step = 2 * hud_configure_realGridSize.y;
 411                 }
 412                 else
 413                 {
 414                         if (hudShiftState & S_SHIFT)
 415                                 step = hud_configure_realGridSize.x;
 416                         else
 417                                 step = 2 * hud_configure_realGridSize.x;
 418                 }
 419         }
 420         else
 421         {
 422                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 423                         step = vid_conheight;
 424                 else
 425                         step = vid_conwidth;
 426                 if (hudShiftState & S_SHIFT)
 427                         step = (step / 256); // more precision
 428                 else
 429                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 430         }
 431
 432         panel = highlightedPanel;
 433         HUD_Panel_UpdatePosSize();
 434
 435         highlightedPanel_initial_pos = panel_pos;
 436         highlightedPanel_initial_size = panel_size;
 437
 438         if (hudShiftState & S_ALT) // resize
 439         {
 440                 if(nPrimary == K_UPARROW)
 441                         resizeCorner = 1;
 442                 else if(nPrimary == K_RIGHTARROW)
 443                         resizeCorner = 2;
 444                 else if(nPrimary == K_LEFTARROW)
 445                         resizeCorner = 3;
 446                 else // if(nPrimary == K_DOWNARROW)
 447                         resizeCorner = 4;
 448
 449                 // ctrl+arrow reduces the size, instead of increasing it
 450                 // Note that ctrl disables collisions check too, but it's fine
 451                 // since we don't collide with anything reducing the size
 452                 if (hudShiftState & S_CTRL) {
 453                         step = -step;
 454                         resizeCorner = 5 - resizeCorner;
 455                 }
 456
 457                 vector mySize;
 458                 mySize = panel_size;
 459                 panel_click_resizeorigin = panel_pos;
 460                 if(resizeCorner == 1) {
 461                         panel_click_resizeorigin += mySize;
 462                         mySize.y += step;
 463                 } else if(resizeCorner == 2) {
 464                         panel_click_resizeorigin.y += mySize.y;
 465                         mySize.x += step;
 466                 } else if(resizeCorner == 3) {
 467                         panel_click_resizeorigin.x += mySize.x;
 468                         mySize.x += step;
 469                 } else { // resizeCorner == 4
 470                         mySize.y += step;
 471                 }
 472                 HUD_Panel_SetPosSize(mySize);
 473         }
 474         else // move
 475         {
 476                 vector pos;
 477                 pos = panel_pos;
 478                 if(nPrimary == K_UPARROW)
 479                         pos.y -= step;
 480                 else if(nPrimary == K_DOWNARROW)
 481                         pos.y += step;
 482                 else if(nPrimary == K_LEFTARROW)
 483                         pos.x -= step;
 484                 else // if(nPrimary == K_RIGHTARROW)
 485                         pos.x += step;
 486
 487                 HUD_Panel_SetPos(pos);
 488         }
 489
 490         panel = highlightedPanel;
 491         HUD_Panel_UpdatePosSize();
 492
 493         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 494         {
 495                 // backup!
 496                 panel_pos_backup = highlightedPanel_initial_pos;
 497                 panel_size_backup = highlightedPanel_initial_size;
 498                 highlightedPanel_backup = highlightedPanel;
 499         }
 500 }
 501
 502 entity tab_panels[REGISTRY_MAX(hud_panels)];
 503 entity tab_panel;
 504 vector tab_panel_pos;
 505 float tab_backward;
 506 void reset_tab_panels()
 507 {
 508         for (int i = 0; i < REGISTRY_COUNT(hud_panels); ++i)
 509                 tab_panels[i] = NULL;
 510 }
 511 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 512 {
 513         string s;
 514
 515         if(!autocvar__hud_configure)
 516                 return false;
 517
 518         if(bInputType == 3)
 519         {
 520                 mousepos.x = nPrimary;
 521                 mousepos.y = nSecondary;
 522                 return true;
 523         }
 524
 525         if(bInputType == 2)
 526                 return false;
 527
 528         // at this point bInputType can only be 0 or 1 (key pressed or released)
 529         bool key_pressed = (bInputType == 0);
 530
 531         // block any input while a menu dialog is fading
 532         // don't block mousepos read as it leads to cursor jumps in the interaction with the menu
 533         if(autocvar__menu_alpha)
 534         {
 535                 hudShiftState = 0;
 536                 mouseClicked = 0;
 537                 return true;
 538         }
 539
 540         int hudShiftState_prev = hudShiftState;
 541         int mouseClicked_prev = mouseClicked;
 542         if(key_pressed) {
 543                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 544                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 545                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 546                 if(nPrimary == K_MOUSE1) mouseClicked |= S_MOUSE1;
 547                 if(nPrimary == K_MOUSE2) mouseClicked |= S_MOUSE2;
 548         }
 549         else {
 550                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 551                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 552                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 553                 if(nPrimary == K_MOUSE1) mouseClicked -= (mouseClicked & S_MOUSE1);
 554                 if(nPrimary == K_MOUSE2) mouseClicked -= (mouseClicked & S_MOUSE2);
 555         }
 556
 557         if(nPrimary == K_CTRL)
 558         {
 559                 if (!key_pressed) //ctrl has been released
 560                 {
 561                         if (tab_panel)
 562                         {
 563                                 //switch to selected panel
 564                                 highlightedPanel = tab_panel;
 565                                 highlightedAction = 0;
 566                                 HUD_Panel_FirstInDrawQ(highlightedPanel.panel_id);
 567                         }
 568                         tab_panel = NULL;
 569                         reset_tab_panels();
 570                 }
 571         }
 572
 573         if(nPrimary == K_ESCAPE)
 574         {
 575                 if (!key_pressed)
 576                         return true;
 577                 hud_configure_menu_open = 1;
 578                 localcmd("menu_showhudexit\n");
 579         }
 580         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
 581         {
 582                 if (!key_pressed)
 583                         return true;
 584                 if (!hud_configure_menu_open)
 585                         HUD_Configure_Exit_Force();
 586         }
 587         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // switch panel
 588         {
 589                 if (!key_pressed || mouseClicked)
 590                         return true;
 591
 592                 // FIXME minor bug: if a panel is highlighted, has the same pos_x and
 593                 // lays in the same level of another panel then the next consecutive
 594                 // CTRL TAB presses will reselect once more the highlighted panel
 595
 596                 entity starting_panel;
 597                 entity old_tab_panel = tab_panel;
 598                 if (!tab_panel) //first press of TAB
 599                 {
 600                         if (highlightedPanel)
 601                         {
 602                                 panel = highlightedPanel;
 603                                 HUD_Panel_UpdatePosSize();
 604                         }
 605                         else
 606                                 panel_pos = '0 0 0';
 607                         starting_panel = highlightedPanel;
 608                         tab_panel_pos = panel_pos; //to compute level
 609                 }
 610                 else
 611                 {
 612                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 613                                 reset_tab_panels();
 614                         starting_panel = tab_panel;
 615                 }
 616                 tab_backward = (hudShiftState & S_SHIFT);
 617
 618                 float k, level = 0, start_posX;
 619                 vector candidate_pos = '0 0 0';
 620                 const float LEVELS_NUM = 4;
 621                 float level_height = vid_conheight / LEVELS_NUM;
 622                 LABEL(find_tab_panel)
 623                 level = floor(tab_panel_pos.y / level_height) * level_height; //starting level
 624                 candidate_pos.x = (!tab_backward) ? vid_conwidth : 0;
 625                 start_posX = tab_panel_pos.x;
 626                 tab_panel = NULL;
 627                 k=0;
 628                 while(++k)
 629                 {
 630                         for(int i = 0; i < REGISTRY_COUNT(hud_panels); ++i)
 631                         {
 632                                 panel = REGISTRY_GET(hud_panels, i);
 633                                 if(!(panel.panel_configflags & PANEL_CONFIG_MAIN))
 634                                         continue;
 635                                 if (panel == tab_panels[i] || panel == starting_panel)
 636                                         continue;
 637                                 HUD_Panel_UpdatePosSize();
 638                                 if (panel_pos.y >= level && (panel_pos.y - level) < level_height)
 639                                 if (  ( !tab_backward && panel_pos.x >= start_posX && (panel_pos.x < candidate_pos.x || (panel_pos.x == candidate_pos.x && panel_pos.y <= candidate_pos.y)) )
 640                                         || ( tab_backward && panel_pos.x <= start_posX && (panel_pos.x > candidate_pos.x || (panel_pos.x == candidate_pos.x && panel_pos.y >= candidate_pos.y)) )  )
 641                                 {
 642                                         tab_panel = panel;
 643                                         tab_panel_pos = candidate_pos = panel_pos;
 644                                 }
 645                         }
 646                         if (tab_panel)
 647                                 break;
 648                         if (k == LEVELS_NUM) //tab_panel not found
 649                         {
 650                                 reset_tab_panels();
 651                                 if (!old_tab_panel)
 652                                 {
 653                                         tab_panel = NULL;
 654                                         return true;
 655                                 }
 656                                 starting_panel = old_tab_panel;
 657                                 old_tab_panel = NULL;
 658                                 goto find_tab_panel; //u must find tab_panel!
 659                         }
 660                         if (!tab_backward)
 661                         {
 662                                 level = (level + level_height) % vid_conheight;
 663                                 start_posX = 0;
 664                                 candidate_pos.x = vid_conwidth;
 665                         }
 666                         else
 667                         {
 668                                 level = (level - level_height) % vid_conheight;
 669                                 start_posX = vid_conwidth;
 670                                 candidate_pos.x = 0;
 671                         }
 672                 }
 673
 674                 tab_panels[tab_panel.panel_id] = tab_panel;
 675         }
 676         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 677         {
 678                 if (!key_pressed || mouseClicked)
 679                         return true;
 680
 681                 if (highlightedPanel)
 682                 {
 683                         if(panel.panel_configflags & PANEL_CONFIG_CANBEOFF)
 684                                 cvar_set(strcat("hud_panel_", highlightedPanel.panel_name), ftos(!cvar(strcat("hud_panel_", highlightedPanel.panel_name))));
 685                 }
 686                 else
 687                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 688         }
 689         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 690         {
 691                 if (!key_pressed || mouseClicked)
 692                         return true;
 693
 694                 if (highlightedPanel)
 695                 {
 696                         panel = highlightedPanel;
 697                         HUD_Panel_UpdatePosSize();
 698                         panel_size_copied = panel_size;
 699                 }
 700         }
 701         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 702         {
 703                 if (!key_pressed || mouseClicked)
 704                         return true;
 705
 706                 if (panel_size_copied == '0 0 0' || !highlightedPanel)
 707                         return true;
 708
 709                 panel = highlightedPanel;
 710                 HUD_Panel_UpdatePosSize();
 711
 712                 // reduce size if it'd go beyond screen boundaries
 713                 vector tmp_size = panel_size_copied;
 714                 if (panel_pos.x + panel_size_copied.x > vid_conwidth)
 715                         tmp_size.x = vid_conwidth - panel_pos.x;
 716                 if (panel_pos.y + panel_size_copied.y > vid_conheight)
 717                         tmp_size.y = vid_conheight - panel_pos.y;
 718
 719                 if (panel_size == tmp_size)
 720                         return true;
 721
 722                 // backup first!
 723                 panel_pos_backup = panel_pos;
 724                 panel_size_backup = panel_size;
 725                 highlightedPanel_backup = highlightedPanel;
 726
 727                 s = strcat(ftos(tmp_size.x/vid_conwidth), " ", ftos(tmp_size.y/vid_conheight));
 728                 cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_size"), s);
 729         }
 730         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 731         {
 732                 if (!key_pressed || mouseClicked)
 733                         return true;
 734                 //restore previous values
 735                 if (highlightedPanel_backup)
 736                 {
 737                         s = strcat(ftos(panel_pos_backup.x/vid_conwidth), " ", ftos(panel_pos_backup.y/vid_conheight));
 738                         cvar_set(strcat("hud_panel_", highlightedPanel_backup.panel_name, "_pos"), s);
 739                         s = strcat(ftos(panel_size_backup.x/vid_conwidth), " ", ftos(panel_size_backup.y/vid_conheight));
 740                         cvar_set(strcat("hud_panel_", highlightedPanel_backup.panel_name, "_size"), s);
 741                         highlightedPanel_backup = NULL;
 742                 }
 743         }
 744         else if(nPrimary == 's' && hudShiftState & S_CTRL) // save config
 745         {
 746                 if (!key_pressed || mouseClicked)
 747                         return true;
 748                 localcmd("hud save myconfig\n");
 749         }
 750         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 751         {
 752                 if (!key_pressed)
 753                 {
 754                         pressed_key_time = 0;
 755                         return true;
 756                 }
 757                 else if (pressed_key_time == 0)
 758                         pressed_key_time = time;
 759
 760                 if (!mouseClicked)
 761                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 762         }
 763         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 764         {
 765                 if (bInputType == 1)
 766                         return true;
 767                 if (highlightedPanel)
 768                         HUD_Panel_EnableMenu();
 769         }
 770         else if(nPrimary == K_PAUSE)
 771                 return false;
 772         else if (hudShiftState_prev == hudShiftState && mouseClicked_prev == mouseClicked)
 773         {
 774                 // allow console bind to work
 775                 string con_keys = findkeysforcommand("toggleconsole", 0);
 776                 int keys = tokenize(con_keys); // findkeysforcommand returns data for this
 777                 for (int i = 0; i < keys; ++i)
 778                 {
 779                         if(nPrimary == stof(argv(i)))
 780                                 return false; // hit console bind
 781                 }
 782         }
 783
 784         return true;
 785 }
 786
 787 int HUD_Panel_Check_Mouse_Pos(bool allow_move)
 788 {
 789         int i, j = 0;
 790         while(j < REGISTRY_COUNT(hud_panels))
 791         {
 792                 i = panel_order[j];
 793                 j += 1;
 794
 795                 panel = REGISTRY_GET(hud_panels, i);
 796                 if(!(panel.panel_configflags & PANEL_CONFIG_MAIN)) continue;
 797                 HUD_Panel_UpdatePosSize();
 798
 799                 float border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 800
 801                 // move
 802                 if(allow_move && mousepos.x > panel_pos.x && mousepos.y > panel_pos.y && mousepos.x < panel_pos.x + panel_size.x && mousepos.y < panel_pos.y + panel_size.y)
 803                 {
 804                         return CURSOR_MOVE;
 805                 }
 806                 // resize from topleft border
 807                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
 808                 {
 809                         return CURSOR_RESIZE;
 810                 }
 811                 // resize from topright border
 812                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
 813                 {
 814                         return CURSOR_RESIZE2;
 815                 }
 816                 // resize from bottomleft border
 817                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + panel_size.y + border)
 818                 {
 819                         return CURSOR_RESIZE2;
 820                 }
 821                 // resize from bottomright border
 822                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + panel_size.y + border)
 823                 {
 824                         return CURSOR_RESIZE;
 825                 }
 826         }
 827         return CURSOR_NORMAL;
 828 }
 829
 830 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 831 void HUD_Panel_FirstInDrawQ(float id)
 832 {
 833         int i;
 834         int place = -1;
 835         // find out where in the array our current id is, save into place
 836         for(i = 0; i < REGISTRY_COUNT(hud_panels); ++i)
 837         {
 838                 if(panel_order[i] == id)
 839                 {
 840                         place = i;
 841                         break;
 842                 }
 843         }
 844         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 845         if(place == -1)
 846                 place = REGISTRY_COUNT(hud_panels) - 1;
 847
 848         // move all ids up by one step in the array until "place"
 849         for(i = place; i > 0; --i)
 850         {
 851                 panel_order[i] = panel_order[i-1];
 852         }
 853         // now save the new top id
 854         panel_order[0] = id;
 855
 856         // let's save them into the cvar by some strcat trickery
 857         string s = "";
 858         for(i = 0; i < REGISTRY_COUNT(hud_panels); ++i)
 859         {
 860                 s = strcat(s, ftos(panel_order[i]), " ");
 861         }
 862         cvar_set("_hud_panelorder", s);
 863         strcpy(hud_panelorder_prev, autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
 864 }
 865
 866 void HUD_Panel_Highlight(float allow_move)
 867 {
 868         int i, j = 0;
 869
 870         while(j < REGISTRY_COUNT(hud_panels))
 871         {
 872                 i = panel_order[j];
 873                 j += 1;
 874
 875                 panel = REGISTRY_GET(hud_panels, i);
 876                 if(!(panel.panel_configflags & PANEL_CONFIG_MAIN))
 877                         continue;
 878                 HUD_Panel_UpdatePosSize();
 879
 880                 float border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 881
 882                 // move
 883                 if(allow_move && mousepos.x > panel_pos.x && mousepos.y > panel_pos.y && mousepos.x < panel_pos.x + panel_size.x && mousepos.y < panel_pos.y + panel_size.y)
 884                 {
 885                         highlightedPanel = REGISTRY_GET(hud_panels, i);
 886                         HUD_Panel_FirstInDrawQ(i);
 887                         highlightedAction = 1;
 888                         panel_click_distance = mousepos - panel_pos;
 889                         return;
 890                 }
 891                 // resize from topleft border
 892                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
 893                 {
 894                         highlightedPanel = REGISTRY_GET(hud_panels, i);
 895                         HUD_Panel_FirstInDrawQ(i);
 896                         highlightedAction = 2;
 897                         resizeCorner = 1;
 898                         panel_click_distance = mousepos - panel_pos;
 899                         panel_click_resizeorigin = panel_pos + panel_size;
 900                         return;
 901                 }
 902                 // resize from topright border
 903                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
 904                 {
 905                         highlightedPanel = REGISTRY_GET(hud_panels, i);
 906                         HUD_Panel_FirstInDrawQ(i);
 907                         highlightedAction = 2;
 908                         resizeCorner = 2;
 909                         panel_click_distance.x = panel_size.x - mousepos.x + panel_pos.x;
 910                         panel_click_distance.y = mousepos.y - panel_pos.y;
 911                         panel_click_resizeorigin = panel_pos + eY * panel_size.y;
 912                         return;
 913                 }
 914                 // resize from bottomleft border
 915                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + panel_size.y + border)
 916                 {
 917                         highlightedPanel = REGISTRY_GET(hud_panels, i);
 918                         HUD_Panel_FirstInDrawQ(i);
 919                         highlightedAction = 2;
 920                         resizeCorner = 3;
 921                         panel_click_distance.x = mousepos.x - panel_pos.x;
 922                         panel_click_distance.y = panel_size.y - mousepos.y + panel_pos.y;
 923                         panel_click_resizeorigin = panel_pos + eX * panel_size.x;
 924                         return;
 925                 }
 926                 // resize from bottomright border
 927                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + panel_size.y + border)
 928                 {
 929                         highlightedPanel = REGISTRY_GET(hud_panels, i);
 930                         HUD_Panel_FirstInDrawQ(i);
 931                         highlightedAction = 2;
 932                         resizeCorner = 4;
 933                         panel_click_distance = panel_size - mousepos + panel_pos;
 934                         panel_click_resizeorigin = panel_pos;
 935                         return;
 936                 }
 937         }
 938         highlightedPanel = NULL;
 939         highlightedAction = 0;
 940 }
 941
 942 void HUD_Panel_EnableMenu()
 943 {
 944         hud_configure_menu_open = 2;
 945         localcmd("menu_showhudoptions ", highlightedPanel.panel_name, "\n");
 946 }
 947 void HUD_Panel_Mouse()
 948 {
 949         if(autocvar__menu_alpha == 1)
 950                 return;
 951
 952         if(mouseClicked)
 953         {
 954                 if(prevMouseClicked == 0)
 955                 {
 956                         if (tab_panel)
 957                         {
 958                                 //stop ctrl-tab selection
 959                                 tab_panel = NULL;
 960                                 reset_tab_panels();
 961                         }
 962                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
 963                                                                         // and calls HUD_Panel_UpdatePosSize() for the highlighted panel
 964                         if (highlightedPanel)
 965                         {
 966                                 highlightedPanel_initial_pos = panel_pos;
 967                                 highlightedPanel_initial_size = panel_size;
 968                         }
 969                         // doubleclick check
 970                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel && prevMouseClickedPos == mousepos)
 971                         {
 972                                 mouseClicked = 0; // to prevent spam, I guess.
 973                                 HUD_Panel_EnableMenu();
 974                         }
 975                         else
 976                         {
 977                                 if (mouseClicked & S_MOUSE1)
 978                                 {
 979                                         prevMouseClickedTime = time;
 980                                         prevMouseClickedPos = mousepos;
 981                                 }
 982                                 cursor_type = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
 983                         }
 984                 }
 985                 else
 986                 {
 987                         panel = highlightedPanel;
 988                         HUD_Panel_UpdatePosSize();
 989                 }
 990
 991                 if (highlightedPanel)
 992                 {
 993                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
 994                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 995                         {
 996                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 997                                 // backup!
 998                                 panel_pos_backup = highlightedPanel_initial_pos;
 999                                 panel_size_backup = highlightedPanel_initial_size;
1000                                 highlightedPanel_backup = highlightedPanel;
1001                         }
1002                         else
1003                                 // in case the clicked panel is inside another panel and we aren't
1004                                 // moving it, avoid the immediate "fix" of its position/size
1005                                 // (often unwanted and hateful) by disabling collisions check
1006                                 hud_configure_checkcollisions = false;
1007                 }
1008
1009                 if(highlightedAction == 1)
1010                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1011                 else if(highlightedAction == 2)
1012                 {
1013                         vector mySize = '0 0 0';
1014                         if(resizeCorner == 1) {
1015                                 mySize.x = panel_click_resizeorigin.x - (mousepos.x - panel_click_distance.x);
1016                                 mySize.y = panel_click_resizeorigin.y - (mousepos.y - panel_click_distance.y);
1017                         } else if(resizeCorner == 2) {
1018                                 mySize.x = mousepos.x + panel_click_distance.x - panel_click_resizeorigin.x;
1019                                 mySize.y = panel_click_distance.y + panel_click_resizeorigin.y - mousepos.y;
1020                         } else if(resizeCorner == 3) {
1021                                 mySize.x = panel_click_resizeorigin.x + panel_click_distance.x - mousepos.x;
1022                                 mySize.y = mousepos.y + panel_click_distance.y - panel_click_resizeorigin.y;
1023                         } else { // resizeCorner == 4
1024                                 mySize.x = mousepos.x - (panel_click_resizeorigin.x - panel_click_distance.x);
1025                                 mySize.y = mousepos.y - (panel_click_resizeorigin.y - panel_click_distance.y);
1026                         }
1027                         HUD_Panel_SetPosSize(mySize);
1028                 }
1029         }
1030         else
1031         {
1032                 if(prevMouseClicked)
1033                         highlightedAction = 0;
1034                 if(hud_configure_menu_open == 2)
1035                         cursor_type = CURSOR_NORMAL;
1036                 else
1037                         cursor_type = HUD_Panel_Check_Mouse_Pos(true);
1038                 if (cursor_type != CURSOR_NORMAL && !tab_panel) // mouse over a panel?
1039                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1040         }
1041 }
1042 void HUD_Configure_DrawGrid()
1043 {
1044         float i;
1045         if(autocvar_hud_configure_grid && autocvar_hud_configure_grid_alpha)
1046         {
1047                 hud_configure_gridSize.x = bound(0.005, cvar("hud_configure_grid_xsize"), 0.2);
1048                 hud_configure_gridSize.y = bound(0.005, cvar("hud_configure_grid_ysize"), 0.2);
1049                 hud_configure_realGridSize.x = hud_configure_gridSize.x * vid_conwidth;
1050                 hud_configure_realGridSize.y = hud_configure_gridSize.y * vid_conheight;
1051                 vector s;
1052                 // x-axis
1053                 s = vec2(1, vid_conheight);
1054                 for(i = 1; i < 1/hud_configure_gridSize.x; ++i)
1055                         drawfill(eX * i * hud_configure_realGridSize.x, s, '0.5 0.5 0.5', autocvar_hud_configure_grid_alpha, DRAWFLAG_NORMAL);
1056                 // y-axis
1057                 s = vec2(vid_conwidth, 1);
1058                 for(i = 1; i < 1/hud_configure_gridSize.y; ++i)
1059                         drawfill(eY * i * hud_configure_realGridSize.y, s, '0.5 0.5 0.5', autocvar_hud_configure_grid_alpha, DRAWFLAG_NORMAL);
1060         }
1061 }
1062
1063 float _menu_alpha_prev;
1064 void HUD_Configure_Frame()
1065 {
1066         int i;
1067         if(autocvar__hud_configure)
1068         {
1069                 if(isdemo() || intermission == 2 || scoreboard_active)
1070                 {
1071                         HUD_Configure_Exit_Force();
1072                         return;
1073                 }
1074
1075                 if(!hud_configure_prev)
1076                 {
1077                         hudShiftState = 0;
1078                         for(i = REGISTRY_COUNT(hud_panels) - 1; i >= 0; --i)
1079                                 REGISTRY_GET(hud_panels, panel_order[i]).update_time = time;
1080                 }
1081
1082                 // NOTE this check is necessary because _menu_alpha isn't updated the frame the menu gets enabled
1083                 if(autocvar__menu_alpha != _menu_alpha_prev)
1084                 {
1085                         if(autocvar__menu_alpha == 0)
1086                                 hud_configure_menu_open = 0;
1087                         _menu_alpha_prev = autocvar__menu_alpha;
1088                 }
1089
1090                 HUD_Configure_DrawGrid();
1091         }
1092         else if(hud_configure_prev)
1093         {
1094                 if(hud_configure_menu_open)
1095                         hud_configure_menu_open = 0;
1096                 hud_dynamic_shake_factor = -1;
1097         }
1098 }
1099
1100 const float hlBorderSize = 2;
1101 const string hlBorder = "gfx/hud/default/border_highlighted";
1102 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1103 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1104 {
1105         vector pos = panel_pos - vec2(myBorder, myBorder);
1106         drawfill(pos, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1107         drawpic_tiled(pos, hlBorder, '8 1 0' * hlBorderSize, vec2(panel_size.x + 2 * myBorder, hlBorderSize), color, theAlpha, DRAWFLAG_NORMAL);
1108         drawpic_tiled(pos + eY * (panel_size.y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, vec2(panel_size.x + 2 * myBorder, hlBorderSize), color, theAlpha, DRAWFLAG_NORMAL);
1109         pos.y += hlBorderSize;
1110         drawpic_tiled(pos, hlBorder2, '1 8 0' * hlBorderSize, vec2(hlBorderSize, panel_size.y + 2 * myBorder - 2 * hlBorderSize), color, theAlpha, DRAWFLAG_NORMAL);
1111         drawpic_tiled(pos + eX * (panel_size.x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, vec2(hlBorderSize, panel_size.y + 2 * myBorder - 2 * hlBorderSize), color, theAlpha, DRAWFLAG_NORMAL);
1112 }
1113
1114 void HUD_Configure_PostDraw()
1115 {
1116         if(autocvar__hud_configure)
1117         {
1118                 if(tab_panel)
1119                 {
1120                         panel = tab_panel;
1121                         HUD_Panel_UpdatePosSize();
1122                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .2, DRAWFLAG_NORMAL);
1123                 }
1124                 if(highlightedPanel)
1125                 {
1126                         panel = highlightedPanel;
1127                         HUD_Panel_UpdatePosSize();
1128                         HUD_Panel_HlBorder(panel_bg_border * hlBorderSize, '0 0.5 1', 0.4 * (1 - autocvar__menu_alpha));
1129                 }
1130         }
1131 }