qcsrc/client/announcer.qc

   1 float previous_announcement_time;
   2 float previous_game_starttime;
   3 string previous_announcement;
   4
   5 // remaining maptime announcer sounds, true when sound was already played
   6 float announcer_1min;
   7 float announcer_5min;
   8
   9 void Announcer_Play(string announcement)
  10 {
  11         if((announcement != previous_announcement) || (time >= (previous_announcement_time + autocvar_cl_announcer_antispam)))
  12         {
  13                 sound(world, CH_INFO, strcat("announcer/", autocvar_cl_announcer, "/", announcement, ".wav"), VOL_BASEVOICE, ATTN_NONE);
  14
  15                 previous_announcement = announcement;
  16                 previous_announcement_time = time;
  17         }
  18 }
  19
  20 void Announcer_Countdown()
  21 {
  22         float starttime = getstatf(STAT_GAMESTARTTIME);
  23         float countdown = (starttime - time);
  24         float countdown_rounded = floor(0.5 + countdown);
  25
  26         if(countdown <= 0) // countdown has finished, starttime is now
  27         {
  28                 if (!spectatee_status)
  29                         centerprint_generic(CPID_GAME_STARTING, _("^1Begin!"), 1, 0);
  30
  31                 Announcer_Play("begin");
  32                 announcer_5min = announcer_1min = FALSE; // reset maptime announcers now as well
  33                 remove(self);
  34                 return;
  35         }
  36         else // countdown is still going
  37         {
  38                 if (!spectatee_status)
  39                         centerprint_generic(CPID_GAME_STARTING, _("^1Game starts in %d seconds"), 1, countdown_rounded);
  40
  41                 if(countdown_rounded <= 3 && countdown_rounded >= 1)
  42                         Announcer_Play(ftos(countdown_rounded));
  43
  44                 self.nextthink = (starttime - (countdown - 1));
  45         }
  46 }
  47
  48 /**
  49  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  50  *
  51  * TODO: Use a better solution where a common shared entitiy is used that contains
  52  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  53  * and STAT_FRAGLIMIT to be auto-sent)
  54  */
  55 void Announcer_Gamestart()
  56 {
  57         float startTime = getstatf(STAT_GAMESTARTTIME);
  58
  59         if(previous_game_starttime != startTime)
  60         {
  61                 if((time + 5.0) < startTime) // if connecting to server while restart was active don't always play prepareforbattle
  62                         Announcer_Play("prepareforbattle");
  63
  64                 if(time < startTime)
  65                 {
  66                         entity e;
  67                         e = spawn();
  68                         e.think = Announcer_Countdown;
  69                         e.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
  70                 }
  71         }
  72
  73         previous_game_starttime = startTime;
  74 }
  75
  76
  77 // Plays the 1 minute or 5 minutes (of maptime) remaining sound, if client wants it
  78 void Announcer_Time()
  79 {
  80         float timelimit = getstatf(STAT_TIMELIMIT);
  81         float timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
  82         float warmup_timeleft;
  83
  84         if(warmup_stage)
  85                 if(autocvar_g_warmup_limit > 0)
  86                         warmup_timeleft = max(0, autocvar_g_warmup_limit + getstatf(STAT_GAMESTARTTIME) - time);
  87
  88         // 5 minute check
  89         if(autocvar_cl_announcer_maptime >= 2)
  90         {
  91                 // make sure that after connect (and e.g. 4 minutes left) we will not get a wrong sound
  92                 if(announcer_5min)
  93                 {
  94                         if(((!warmup_stage || autocvar_g_warmup_limit == 0) && timeleft > 300)
  95                                 || (warmup_stage && autocvar_g_warmup_limit > 0 && warmup_timeleft > 300))
  96                                         announcer_5min = FALSE;
  97                 }
  98                 else
  99                 {
 100                         if(((!warmup_stage || autocvar_g_warmup_limit == 0) && timelimit > 0 && timeleft < 300 && timeleft > 299)
 101                                 || (warmup_stage && autocvar_g_warmup_limit > 0 && warmup_timeleft < 300 && warmup_timeleft > 299))
 102                         {
 103                                 //if we're in warmup mode, check whether there's a warmup timelimit
 104                                 if not(autocvar_g_warmup_limit == -1 && warmup_stage)
 105                                 {
 106                                         announcer_5min = TRUE;
 107                                         Announcer_Play("5minutesremain");
 108                                 }
 109                         }
 110                 }
 111         }
 112
 113         // 1 minute check
 114         if((autocvar_cl_announcer_maptime == 1) || (autocvar_cl_announcer_maptime == 3))
 115         {
 116                 if (announcer_1min)
 117                 {
 118                         if(((!warmup_stage || autocvar_g_warmup_limit == 0) && timeleft > 60)
 119                                 || (warmup_stage && autocvar_g_warmup_limit > 0 && warmup_timeleft > 60))
 120                                         announcer_1min = FALSE;
 121                 }
 122                 else if(((!warmup_stage || autocvar_g_warmup_limit == 0) && timelimit > 0 && timeleft < 60)
 123                         || (warmup_stage && autocvar_g_warmup_limit > 0 && warmup_timeleft < 60))
 124                 {
 125                         // if we're in warmup mode, check whether there's a warmup timelimit
 126                         if not(autocvar_g_warmup_limit == -1 && warmup_stage)
 127                         {
 128                                 announcer_1min = TRUE;
 129                                 Announcer_Play("1minuteremains");
 130                         }
 131                 }
 132         }
 133 }
 134
 135 float redflag_prev;
 136 float blueflag_prev;
 137 void carrierAnnouncer() {
 138         float stat_items, redflag, blueflag;
 139         float pickup;
 140         string item;
 141
 142         if not(autocvar_cl_notify_carried_items)
 143                 return;
 144
 145         stat_items = getstati(STAT_ITEMS);
 146
 147         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
 148         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
 149
 150         if (redflag == 3 && redflag != redflag_prev) {
 151                 item = _("^1RED^7 flag");
 152                 pickup = (redflag_prev == 2);
 153         }
 154
 155         if (blueflag == 3 && blueflag != blueflag_prev) {
 156                 item = _("^4BLUE^7 flag");
 157                 pickup = (blueflag_prev == 2);
 158         }
 159
 160         if (item)
 161         {
 162                 if (pickup) {
 163                         if (autocvar_cl_notify_carried_items & 2)
 164                                 centerprint(sprintf(_("You picked up the %s!"), item));
 165                 }
 166                 else {
 167                         if (autocvar_cl_notify_carried_items & 1)
 168                                 centerprint(sprintf(_("You got the %s!"), item));
 169                 }
 170         }
 171
 172         blueflag_prev = blueflag;
 173         redflag_prev = redflag;
 174 }
 175
 176 void Announcer()
 177 {
 178         Announcer_Gamestart();
 179         Announcer_Time();
 180         carrierAnnouncer();
 181 }
 182
 183 void Announcer_Precache ()
 184 {
 185         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1minuteremains.wav"));
 186         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/5minutesremain.wav"));
 187
 188         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/electrobitch.wav"));
 189         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/airshot.wav"));
 190         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/03kills.wav"));
 191         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/05kills.wav"));
 192         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/10kills.wav"));
 193         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/15kills.wav"));
 194         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/20kills.wav"));
 195         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/25kills.wav"));
 196         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/30kills.wav"));
 197         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/botlike.wav"));
 198         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/yoda.wav"));
 199         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/amazing.wav"));
 200         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/awesome.wav"));
 201         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/headshot.wav"));
 202         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/impressive.wav"));
 203
 204         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"));
 205         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/begin.wav"));
 206         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/timeoutcalled.wav"));
 207         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1fragleft.wav"));
 208         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/2fragsleft.wav"));
 209         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/3fragsleft.wav"));
 210         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/terminated.wav"));
 211
 212         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1.wav"));
 213         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/2.wav"));
 214         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/3.wav"));
 215         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/4.wav"));
 216         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/5.wav"));
 217         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/6.wav"));
 218         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/7.wav"));
 219         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/8.wav"));
 220         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/9.wav"));
 221         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/10.wav"));
 222
 223         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/lastsecond.wav"));
 224         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/narrowly.wav"));
 225
 226         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/voteaccept.wav"));
 227         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/votecall.wav"));
 228         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/votefail.wav"));
 229 }