qcsrc/client/announcer.qc

   1 void serverAnnouncer()
   2 {
   3         // check for pending announcement, play it and remove it
   4         if(announce_snd != "")
   5         {
   6                 sound(world, CH_INFO, strcat("announcer/", autocvar_cl_announcer, "/", announce_snd, ".wav"), VOL_BASEVOICE, ATTN_NONE);
   7                 strunzone(announce_snd);
   8                 announce_snd = "";
   9         }
  10 }
  11
  12 /**
  13  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  14  *
  15  * TODO: Use a better solution where a common shared entitiy is used that contains
  16  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  17  * and STAT_FRAGLIMIT to be auto-sent)
  18  */
  19 void CheckForGamestartChange() {
  20         float startTime;
  21         startTime = getstatf(STAT_GAMESTARTTIME);
  22         if (previous_game_starttime != startTime) {
  23                 if ((time + 5.0) < startTime) {
  24                         //if connecting to server while restart was active don't always play prepareforbattle
  25                         sound(world, CH_INFO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
  26                 }
  27                 if (time < startTime) {
  28                         restartAnnouncer = spawn();
  29                         restartAnnouncer.think = restartAnnouncer_Think;
  30                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
  31                 }
  32         }
  33         previous_game_starttime = startTime;
  34 }
  35
  36 void restartAnnouncer_Think() {
  37         float countdown_rounded, countdown;
  38         countdown = getstatf(STAT_GAMESTARTTIME) - time;
  39         countdown_rounded = floor(0.5 + countdown);
  40         if(countdown <= 0) {
  41                 if (!spectatee_status) //do cprint only for players
  42                         centerprint_generic(CPID_GAME_STARTING, _("^1Begin!"), 1, 0);
  43
  44                 sound(world, CH_INFO, strcat("announcer/", autocvar_cl_announcer, "/begin.wav"), VOL_BASEVOICE, ATTN_NONE);
  45                 //reset maptime announcers now as well
  46                 announcer_5min = announcer_1min = FALSE;
  47
  48                 remove(self);
  49                 return;
  50         }
  51         else {
  52                 if (!spectatee_status) //do cprint only for players
  53                         centerprint_generic(CPID_GAME_STARTING, _("^1Game starts in %d seconds"), 1, countdown_rounded);
  54
  55                 if(countdown_rounded <= 3 && countdown_rounded >= 1) {
  56                         sound(world, CH_INFO, strcat("announcer/", autocvar_cl_announcer, "/", ftos(countdown_rounded), ".wav"), VOL_BASEVOICE, ATTN_NONE);
  57                 }
  58
  59                 self.nextthink = getstatf(STAT_GAMESTARTTIME) - (countdown - 1);
  60         }
  61 }
  62
  63 /**
  64  * Plays the 1minute or 5 minutes (of maptime) remaining sound, if client wants it
  65  */
  66 void maptimeAnnouncer() {
  67         float timelimit;
  68         timelimit = getstatf(STAT_TIMELIMIT);
  69         float timeleft;
  70         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
  71
  72         float warmuplimit;
  73         float warmuptimeleft;
  74         if(warmup_stage) {
  75                 warmuplimit = autocvar_g_warmup_limit;
  76                 if(warmuplimit > 0) {
  77                         warmuptimeleft = max(0, warmuplimit + getstatf(STAT_GAMESTARTTIME) - time);
  78                 }
  79         }
  80
  81         //5 minute check
  82         if (autocvar_cl_sound_maptime_warning >= 2) {
  83                 //make sure that after connect (and e.g. 4 minutes left) we will not get a wrong sound
  84                 if(announcer_5min)
  85                 {
  86                         if(((!warmup_stage || warmuplimit == 0) && timeleft > 300) || (warmup_stage && warmuplimit > 0 && warmuptimeleft > 300))
  87                                 announcer_5min = FALSE;
  88                 }
  89                 else if (((!warmup_stage || warmuplimit == 0) && timelimit > 0 && timeleft < 300 && timeleft > 299) || (warmup_stage && warmuplimit > 0 && warmuptimeleft < 300 && warmuptimeleft > 299))
  90                         //if we're in warmup mode, check whether there's a warmup timelimit
  91                         if not (warmuplimit == -1 && warmup_stage) {
  92                                 announcer_5min = TRUE;
  93                                 sound(world, CH_INFO, strcat("announcer/", autocvar_cl_announcer, "/5minutesremain.wav"), VOL_BASEVOICE, ATTN_NONE);
  94                         }
  95         }
  96
  97         //1 minute check
  98         if (autocvar_cl_sound_maptime_warning == 1 || autocvar_cl_sound_maptime_warning == 3) {
  99                 if (announcer_1min)
 100                 {
 101                         if(((!warmup_stage || warmuplimit == 0) && timeleft > 60) || (warmup_stage && warmuplimit > 0 && warmuptimeleft > 60))
 102                                 announcer_1min = FALSE;
 103                 }
 104                 else if (((!warmup_stage || warmuplimit == 0) && timelimit > 0 && timeleft < 60) || (warmup_stage && warmuplimit > 0 && warmuptimeleft < 60))
 105                         //if we're in warmup mode, check whether there's a warmup timelimit
 106                         if not (warmuplimit == -1 && warmup_stage) {
 107                                 announcer_1min = TRUE;
 108                                 sound(world, CH_INFO, strcat("announcer/", autocvar_cl_announcer, "/1minuteremains.wav"), VOL_BASEVOICE, ATTN_NONE);
 109                         }
 110         }
 111 }
 112
 113 /**
 114  * Announce carried items (e.g. flags in CTF).
 115  */
 116 float redflag_prev;
 117 float blueflag_prev;
 118 void carrierAnnouncer() {
 119         float stat_items, redflag, blueflag;
 120         float pickup;
 121         string item;
 122
 123         if not(autocvar_cl_notify_carried_items)
 124                 return;
 125
 126         stat_items = getstati(STAT_ITEMS);
 127
 128         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
 129         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
 130
 131         if (redflag == 3 && redflag != redflag_prev) {
 132                 item = _("^1RED^7 flag");
 133                 pickup = (redflag_prev == 2);
 134         }
 135
 136         if (blueflag == 3 && blueflag != blueflag_prev) {
 137                 item = _("^4BLUE^7 flag");
 138                 pickup = (blueflag_prev == 2);
 139         }
 140
 141         if (item)
 142         {
 143                 if (pickup) {
 144                         if (autocvar_cl_notify_carried_items & 2)
 145                                 centerprint(sprintf(_("You picked up the %s!"), item));
 146                 }
 147                 else {
 148                         if (autocvar_cl_notify_carried_items & 1)
 149                                 centerprint(sprintf(_("You got the %s!"), item));
 150                 }
 151         }
 152
 153         blueflag_prev = blueflag;
 154         redflag_prev = redflag;
 155 }
 156
 157 void Announcer()
 158 {
 159   CheckForGamestartChange();
 160         serverAnnouncer();
 161         maptimeAnnouncer();
 162         carrierAnnouncer();
 163 }
 164
 165 /**
 166  * Add all future announcer sounds precaches here.
 167  * TODO: announcer queues
 168  */
 169 void Announcer_Precache () {
 170         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1minuteremains.wav"));
 171         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/5minutesremain.wav"));
 172
 173         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/electrobitch.wav"));
 174         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/airshot.wav"));
 175         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/03kills.wav"));
 176         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/05kills.wav"));
 177         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/10kills.wav"));
 178         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/15kills.wav"));
 179         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/20kills.wav"));
 180         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/25kills.wav"));
 181         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/30kills.wav"));
 182         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/botlike.wav"));
 183         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/yoda.wav"));
 184         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/amazing.wav"));
 185         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/awesome.wav"));
 186         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/headshot.wav"));
 187         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/impressive.wav"));
 188
 189         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"));
 190         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/begin.wav"));
 191         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/timeoutcalled.wav"));
 192         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1fragleft.wav"));
 193         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/2fragsleft.wav"));
 194         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/3fragsleft.wav"));
 195         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/terminated.wav"));
 196
 197         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1.wav"));
 198         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/2.wav"));
 199         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/3.wav"));
 200         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/4.wav"));
 201         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/5.wav"));
 202         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/6.wav"));
 203         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/7.wav"));
 204         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/8.wav"));
 205         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/9.wav"));
 206         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/10.wav"));
 207
 208         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/lastsecond.wav"));
 209         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/narrowly.wav"));
 210
 211         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/voteaccept.wav"));
 212         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/votecall.wav"));
 213         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/votefail.wav"));
 214 }