qcsrc/client/announcer.qc

   1 #include "announcer.qh"
   2
   3 #include <client/draw.qh>
   4 #include <client/hud/panel/centerprint.qh>
   5 #include <client/mutators/_mod.qh>
   6 #include <common/notifications/all.qh>
   7 #include <common/stats.qh>
   8 #include <common/mapinfo.qh>
   9 #include <common/ent_cs.qh>
  10
  11 bool announcer_1min;
  12 bool announcer_5min;
  13 string AnnouncerOption()
  14 {
  15         string ret = autocvar_cl_announcer;
  16         MUTATOR_CALLHOOK(AnnouncerOption, ret);
  17         ret = M_ARGV(0, string);
  18         return ret;
  19 }
  20
  21 entity announcer_countdown;
  22
  23 bool prev_inround;
  24 void Announcer_Countdown(entity this)
  25 {
  26         float starttime = STAT(GAMESTARTTIME);
  27         float roundstarttime = STAT(ROUNDSTARTTIME);
  28         if(roundstarttime == -1)
  29         {
  30                 Local_Notification(MSG_CENTER, CENTER_COUNTDOWN_ROUNDSTOP);
  31                 delete(this);
  32                 announcer_countdown = NULL;
  33                 centerprint_ClearTitle();
  34                 return;
  35         }
  36
  37         bool inround = (roundstarttime && time >= starttime);
  38         float countdown = (inround ? roundstarttime - time : starttime - time);
  39         float countdown_rounded = floor(0.5 + countdown);
  40
  41         if(countdown <= 0) // countdown has finished, starttime is now
  42         {
  43                 Local_Notification(MSG_CENTER, CENTER_COUNTDOWN_BEGIN);
  44                 Local_Notification(MSG_MULTI, MULTI_COUNTDOWN_BEGIN);
  45                 delete(this);
  46                 announcer_countdown = NULL;
  47                 centerprint_ClearTitle();
  48                 return;
  49         }
  50         else // countdown is still going
  51         {
  52                 if(inround)
  53                 {
  54                         if(!prev_inround) centerprint_ClearTitle(); // clear title if we just started the match
  55                         Local_Notification(MSG_CENTER, CENTER_COUNTDOWN_ROUNDSTART, STAT(ROUNDS_PLAYED) + 1, countdown_rounded);
  56                         Notification annce_num = Announcer_PickNumber(CNT_ROUNDSTART, countdown_rounded);
  57                         if(annce_num != NULL)
  58                                 Local_Notification(MSG_ANNCE, annce_num);
  59                         this.nextthink = (roundstarttime - (countdown - 1));
  60                 }
  61                 else
  62                 {
  63                         Local_Notification(MSG_CENTER, CENTER_COUNTDOWN_GAMESTART, countdown_rounded);
  64                         Notification annce_num = Announcer_PickNumber(CNT_GAMESTART, countdown_rounded);
  65                         if(!roundstarttime && annce_num != NULL) // Don't announce game start in round based modes
  66                                 Local_Notification(MSG_ANNCE, annce_num);
  67                         this.nextthink = (starttime - (countdown - 1));
  68                 }
  69         }
  70
  71         prev_inround = inround;
  72 }
  73
  74 /**
  75  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  76  *
  77  * TODO: Use a better solution where a common shared entitiy is used that contains
  78  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  79  * and STAT_FRAGLIMIT to be auto-sent)
  80  */
  81 float previous_game_starttime;
  82 void Announcer_Gamestart()
  83 {
  84         float startTime = STAT(GAMESTARTTIME);
  85         float roundstarttime = STAT(ROUNDSTARTTIME);
  86         if(roundstarttime > startTime)
  87                 startTime = roundstarttime;
  88         if(intermission)
  89         {
  90                 if(announcer_countdown)
  91                 {
  92                         centerprint_Kill(ORDINAL(CPID_ROUND));
  93                         if(announcer_countdown)
  94                         {
  95                                 delete(announcer_countdown);
  96                                 announcer_countdown = NULL;
  97                         }
  98                 }
  99                 return;
 100         }
 101
 102         if(previous_game_starttime != startTime)
 103         {
 104                 if(time < startTime)
 105                 {
 106                         if (!announcer_countdown)
 107                         {
 108                                 announcer_countdown = new(announcer_countdown);
 109                                 setthink(announcer_countdown, Announcer_Countdown);
 110                         }
 111
 112                         if(!warmup_stage && time < STAT(GAMESTARTTIME))
 113                         {
 114                                 if (gametype.m_1v1)
 115                                 {
 116                                         entity pl1 = players.sort_next;
 117                                         entity pl2 = pl1.sort_next;
 118                                         string pl1_name = (pl1 && pl1.team != NUM_SPECTATOR ? entcs_GetName(pl1.sv_entnum) : "???");
 119                                         string pl2_name = (pl2 && pl2.team != NUM_SPECTATOR ? entcs_GetName(pl2.sv_entnum) : "???");
 120
 121                                         float offset = stringwidth(pl2_name, true, hud_fontsize) - stringwidth(pl1_name, true, hud_fontsize) - 1;
 122                                         centerprint_SetTitle(sprintf("^BG%s^BG%s%s", pl1_name, _("  vs  "), pl2_name), offset / 2); // Show duelers in 1v1 game mode
 123                                 }
 124                                 else
 125                                         centerprint_SetTitle(strcat("^BG", MapInfo_Type_ToText(gametype)), 0); // Show game type as title
 126
 127                                 if(time + 5.0 < startTime) // if connecting to server while restart was active don't always play prepareforbattle
 128                                         Local_Notification(MSG_ANNCE, ANNCE_PREPARE);
 129                         }
 130
 131                         announcer_countdown.nextthink = startTime - floor(startTime - time + 0.5); //synchronize nextthink to startTime
 132                 }
 133         }
 134
 135         previous_game_starttime = startTime;
 136 }
 137
 138 #define ANNOUNCER_CHECKMINUTE(minute) MACRO_BEGIN \
 139         if(announcer_##minute##min) { \
 140                 if(timeleft > minute * 60) \
 141                         announcer_##minute##min = false; \
 142         } else { \
 143                 if(timeleft < minute * 60 && timeleft > minute * 60 - 1) { \
 144                         announcer_##minute##min = true; \
 145                         Local_Notification(MSG_ANNCE, ANNCE_REMAINING_MIN_##minute); \
 146                 } \
 147         } \
 148 MACRO_END
 149
 150 void Announcer_Time()
 151 {
 152         static bool warmup_stage_prev;
 153
 154         if(intermission)
 155                 return;
 156
 157         if (warmup_stage != warmup_stage_prev)
 158         {
 159                 announcer_5min = announcer_1min = false;
 160                 warmup_stage_prev = warmup_stage;
 161                 return;
 162         }
 163
 164         float starttime = STAT(GAMESTARTTIME);
 165         if(time < starttime)
 166         {
 167                 announcer_5min = announcer_1min = false;
 168                 return;
 169         }
 170
 171         float timeleft;
 172         if(warmup_stage)
 173         {
 174                 float warmup_timelimit = STAT(WARMUP_TIMELIMIT);
 175                 if(warmup_timelimit > 0)
 176                         timeleft = max(0, warmup_timelimit - time);
 177                 else
 178                         timeleft = 0;
 179         }
 180         else
 181                 timeleft = max(0, STAT(TIMELIMIT) * 60 + starttime - time);
 182
 183         if(autocvar_cl_announcer_maptime >= 2)
 184                 ANNOUNCER_CHECKMINUTE(5);
 185
 186         if((autocvar_cl_announcer_maptime == 1) || (autocvar_cl_announcer_maptime == 3))
 187                 ANNOUNCER_CHECKMINUTE(1);
 188 }
 189
 190 void Announcer()
 191 {
 192         Announcer_Gamestart();
 193         Announcer_Time();
 194 }