qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float trace_dphitcontents;
   4 float trace_networkentity;
   5 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   6 float DPCONTENTS_SOLID = 1; // blocks player movement
   7 float DPCONTENTS_BODY = 32; // blocks player movement
   8 float DPCONTENTS_CORPSE = 64; // blocks player movement
   9 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  10 void Porto_Draw()
  11 {
  12         vector p, dir, ang, q, nextdir;
  13         float idx, portal_number, portal1_idx;
  14
  15         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  16                 return;
  17         if(intermission == 1)
  18                 return;
  19         if(intermission == 2)
  20                 return;
  21         if (getstati(STAT_HEALTH) <= 0)
  22                 return;
  23
  24         dir = view_forward;
  25
  26         if(angles_held_status)
  27         {
  28                 makevectors(angles_held);
  29                 dir = v_forward;
  30         }
  31
  32         p = view_origin;
  33
  34         polyline[0] = p;
  35         idx = 1;
  36         portal_number = 0;
  37         nextdir = dir;
  38
  39         for(;;)
  40         {
  41                 dir = nextdir;
  42                 traceline(p, p + 65536 * dir, TRUE, porto);
  43                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  44                         return;
  45                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  46                 p = trace_endpos;
  47                 polyline[idx] = p;
  48                 ++idx;
  49                 if(idx >= 16)
  50                         return;
  51                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  52                         continue;
  53                 ++portal_number;
  54                 ang = vectoangles2(trace_plane_normal, dir);
  55                 ang_x = -ang_x;
  56                 makevectors(ang);
  57                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  58                         return;
  59                 if(portal_number == 1)
  60                         portal1_idx = idx;
  61                 if(portal_number >= 2)
  62                         break;
  63         }
  64
  65         while(idx >= 2)
  66         {
  67                 p = polyline[idx-2];
  68                 q = polyline[idx-1];
  69                 if(idx == 2)
  70                         p = p - view_up * 16;
  71                 if(idx-1 >= portal1_idx)
  72                 {
  73                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  74                 }
  75                 else
  76                 {
  77                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  78                 }
  79                 --idx;
  80         }
  81 }
  82
  83 /**
  84  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  85  *
  86  * TODO: Use a better solution where a common shared entitiy is used that contains
  87  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  88  * and STAT_FRAGLIMIT to be auto-sent)
  89  */
  90 void CheckForGamestartChange() {
  91         float startTime;
  92         startTime = getstatf(STAT_GAMESTARTTIME);
  93         if (previous_game_starttime != startTime) {
  94                 if ((time + 5.0) < startTime) {
  95                         //if connecting to server while restart was active don't always play prepareforbattle
  96                         sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
  97                 }
  98                 if (time < startTime) {
  99                         restartAnnouncer = spawn();
 100                         restartAnnouncer.think = restartAnnouncer_Think;
 101                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 102                 }
 103         }
 104         previous_game_starttime = startTime;
 105 }
 106
 107 void Porto_Init()
 108 {
 109         porto = spawn();
 110         porto.classname = "porto";
 111         porto.draw = Porto_Draw;
 112         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 113 }
 114
 115 float drawtime;
 116 float avgspeed;
 117 vector GetCurrentFov(float fov)
 118 {
 119         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 120
 121         zoomsensitivity = autocvar_cl_zoomsensitivity;
 122         zoomfactor = autocvar_cl_zoomfactor;
 123         if(zoomfactor < 1 || zoomfactor > 16)
 124                 zoomfactor = 2.5;
 125         zoomspeed = autocvar_cl_zoomspeed;
 126         if(zoomspeed >= 0)
 127                 if(zoomspeed < 0.5 || zoomspeed > 16)
 128                         zoomspeed = 3.5;
 129
 130         zoomdir = button_zoom;
 131         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_SNIPERRIFLE && sniperrifle_scope)) // do NOT use switchweapon here
 132                 zoomdir += button_attack2;
 133         if(spectatee_status > 0 || isdemo())
 134         {
 135                 if(spectatorbutton_zoom)
 136                         zoomdir = 0 + !zoomdir;
 137                 // do not even THINK about removing this 0
 138                 // _I_ know what I am doing
 139                 // fteqcc does not
 140         }
 141
 142         if(zoomdir)
 143                 zoomin_effect = 0;
 144
 145         if(zoomin_effect || camera_active)
 146         {
 147                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 148         }
 149         else
 150         {
 151                 if(zoomspeed < 0) // instant zoom
 152                 {
 153                         if(zoomdir)
 154                                 current_viewzoom = 1 / zoomfactor;
 155                         else
 156                                 current_viewzoom = 1;
 157                 }
 158                 else
 159                 {
 160                         if(zoomdir)
 161                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 162                         else
 163                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 164                 }
 165         }
 166
 167         if(almost_equals(current_viewzoom, 1))
 168                 current_zoomfraction = 0;
 169         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 170                 current_zoomfraction = 1;
 171         else
 172                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 173
 174         if(zoomsensitivity < 1)
 175                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 176         else
 177                 setsensitivityscale(1);
 178
 179         velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 180         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 181         velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 182
 183         //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 184
 185         float frustumx, frustumy, fovx, fovy;
 186         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 187         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 188         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 189         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 190
 191         return '1 0 0' * fovx + '0 1 0' * fovy;
 192 }
 193
 194 // this function must match W_SetupShot!
 195 float zoomscript_caught;
 196
 197 vector wcross_origin;
 198 float wcross_scale_prev, wcross_alpha_prev;
 199 vector wcross_color_prev;
 200 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 201 vector wcross_color_goal_prev;
 202 float wcross_changedonetime;
 203
 204 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 205 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 206 float wcross_name_changestarttime, wcross_name_changedonetime;
 207 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 208 entity trueaim;
 209 entity trueaim_rifle;
 210
 211 #define SHOTTYPE_HITTEAM 1
 212 #define SHOTTYPE_HITOBSTRUCTION 2
 213 #define SHOTTYPE_HITWORLD 3
 214 #define SHOTTYPE_HITENEMY 4
 215
 216 void TrueAim_Init()
 217 {
 218         trueaim = spawn();
 219         trueaim.classname = "trueaim";
 220         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 221         trueaim_rifle = spawn();
 222         trueaim_rifle.classname = "trueaim_rifle";
 223         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 224 }
 225
 226 float EnemyHitCheck()
 227 {
 228         float t;
 229         wcross_origin = project_3d_to_2d(trace_endpos);
 230         wcross_origin_z = 0;
 231         if(trace_networkentity < 1)
 232                 return SHOTTYPE_HITWORLD;
 233         if(trace_networkentity > maxclients)
 234                 return SHOTTYPE_HITWORLD;
 235         t = GetPlayerColor(trace_networkentity - 1);
 236         if(teamplay)
 237                 if(t == myteam)
 238                         return SHOTTYPE_HITTEAM;
 239         if(t == COLOR_SPECTATOR)
 240                 return SHOTTYPE_HITWORLD;
 241         return SHOTTYPE_HITENEMY;
 242 }
 243
 244 float TrueAimCheck()
 245 {
 246         float nudge = 1; // added to traceline target and subtracted from result
 247         vector vecs, trueaimpoint, w_shotorg;
 248         vector mi, ma, dv;
 249         float shottype;
 250         entity ta;
 251         float mv;
 252
 253         mi = ma = '0 0 0';
 254         ta = trueaim;
 255         mv = MOVE_NOMONSTERS;
 256
 257         switch(activeweapon)
 258         {
 259                 case WEP_TUBA: // no aim
 260                 case WEP_PORTO: // shoots from eye
 261                 case WEP_HOOK: // no trueaim
 262                 case WEP_GRENADE_LAUNCHER: // toss curve
 263                         return SHOTTYPE_HITWORLD;
 264                 case WEP_NEX:
 265                 case WEP_MINSTANEX:
 266                         mv = MOVE_NORMAL;
 267                         break;
 268                 case WEP_SNIPERRIFLE:
 269                         ta = trueaim_rifle;
 270                         mv = MOVE_NORMAL;
 271                         if(zoomscript_caught)
 272                         {
 273                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 274                                 return EnemyHitCheck();
 275                         }
 276                         break;
 277                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 278                         mi = '-3 -3 -3';
 279                         ma = '3 3 3';
 280                         break;
 281                 case WEP_FIREBALL: // projectile has a size!
 282                         mi = '-16 -16 -16';
 283                         ma = '16 16 16';
 284                         break;
 285                 case WEP_SEEKER: // projectile has a size!
 286                         mi = '-2 -2 -2';
 287                         ma = '2 2 2';
 288                         break;
 289                 case WEP_ELECTRO: // projectile has a size!
 290                         mi = '0 0 -3';
 291                         ma = '0 0 -3';
 292                         break;
 293         }
 294
 295         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 296
 297         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 298         trueaimpoint = trace_endpos;
 299
 300         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 301                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 302
 303         if(vecs_x > 0)
 304                 vecs_y = -vecs_y;
 305         else
 306                 vecs = '0 0 0';
 307
 308         dv = view_right * vecs_y + view_up * vecs_z;
 309         w_shotorg = view_origin + dv;
 310
 311         // now move the vecs forward as much as requested if possible
 312         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 313         w_shotorg = trace_endpos - view_forward * nudge;
 314
 315         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 316         shottype = EnemyHitCheck();
 317         if(shottype != SHOTTYPE_HITWORLD)
 318                 return shottype;
 319
 320 #if 0
 321         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 322         // or rather, I know why, but see no fix
 323         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 324                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 325                 return SHOTTYPE_HITOBSTRUCTION;
 326 #endif
 327
 328         return SHOTTYPE_HITWORLD;
 329 }
 330
 331 void CSQC_common_hud(void);
 332
 333 void PostInit(void);
 334 void CSQC_Demo_Camera();
 335 float HUD_WouldDrawScoreboard();
 336 float view_set;
 337 float camera_mode;
 338 float reticle_type;
 339 string NextFrameCommand;
 340 void CSQC_SPIDER_HUD();
 341 void CSQC_RAPTOR_HUD();
 342
 343 vector freeze_pmove_org, freeze_input_angles;
 344 entity nightvision_noise, nightvision_noise2;
 345
 346 float pickup_crosshair_time, pickup_crosshair_size;
 347 float hit_time, typehit_time;
 348 float nextsound_hit_time, nextsound_typehit_time;
 349 float hitindication_crosshair_time, hitindication_crosshair_size;
 350 float use_nex_chargepool;
 351
 352 float myhealth, myhealth_prev;
 353 float myhealth_flash;
 354
 355 vector myhealth_gentlergb;
 356
 357 float contentavgalpha, liquidalpha_prev;
 358 vector liquidcolor_prev;
 359
 360 float checkfail[16];
 361
 362 void CSQC_UpdateView(float w, float h)
 363 {
 364         entity e;
 365         float fov;
 366         float f, i, j;
 367         vector v, vo;
 368         vector vf_size, vf_min;
 369         float a;
 370
 371 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 372         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 373         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 374         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 375         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 376         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 377         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 378
 379         vf_size = R_SetView3fv(VF_SIZE);
 380         vf_min = R_SetView3fv(VF_MIN);
 381         vid_width = vf_size_x;
 382         vid_height = vf_size_y;
 383
 384         vector reticle_pos, reticle_size;
 385         vector splash_pos, splash_size;
 386
 387         WaypointSprite_Load();
 388
 389         if(spectatee_status)
 390                 myteam = GetPlayerColor(spectatee_status - 1);
 391         else
 392                 myteam = GetPlayerColor(player_localentnum - 1);
 393
 394         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 395         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 396
 397         warpzone_fixview_origin = pmove_org + vo;
 398         warpzone_fixview_cl_viewangles = input_angles;
 399         warpzone_fixview_angles = view_angles;
 400         WarpZone_FixView();
 401         pmove_org = warpzone_fixview_origin - vo;
 402         input_angles = warpzone_fixview_cl_viewangles;
 403         view_angles = warpzone_fixview_angles;
 404
 405         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0))
 406         {
 407                 pmove_org = freeze_pmove_org;
 408                 input_angles = view_angles = freeze_input_angles;
 409                 R_SetView(VF_ORIGIN, pmove_org + vo);
 410                 R_SetView(VF_ANGLES, view_angles);
 411                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 412         }
 413         freeze_pmove_org = pmove_org;
 414         freeze_input_angles = input_angles;
 415
 416         // Render the Scene
 417         if(!intermission || !view_set)
 418         {
 419                 view_origin = pmove_org + vo;
 420                 view_angles = input_angles;
 421                 makevectors(view_angles);
 422                 view_forward = v_forward;
 423                 view_right = v_right;
 424                 view_up = v_up;
 425                 view_set = 1;
 426         }
 427
 428 #ifdef BLURTEST
 429         if(time > blurtest_time0 && time < blurtest_time1)
 430         {
 431                 float r, t;
 432
 433                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 434                 r = t * blurtest_radius;
 435                 f = 1 / pow(t, blurtest_power) - 1;
 436
 437                 cvar_set("r_glsl_postprocess", "1");
 438                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 439         }
 440         else
 441         {
 442                 cvar_set("r_glsl_postprocess", "0");
 443                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 444         }
 445 #endif
 446
 447         TargetMusic_Advance();
 448         Fog_Force();
 449
 450         drawframetime = max(0.000001, time - drawtime);
 451         drawtime = time;
 452
 453         // watch for gametype changes here...
 454         // in ParseStuffCMD the cmd isn't executed yet :/
 455         // might even be better to add the gametype to TE_CSQC_INIT...?
 456         if(!postinit)
 457                 PostInit();
 458
 459         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 460                 if(calledhooks & HOOK_START)
 461                 {
 462                         localcmd("\ncl_hook_gameend\n");
 463                         calledhooks |= HOOK_END;
 464                 }
 465
 466         CheckForGamestartChange();
 467         serverAnnouncer();
 468         maptimeAnnouncer();
 469         carrierAnnouncer();
 470
 471         fov = autocvar_fov;
 472         if(button_zoom || fov <= 59.5)
 473         {
 474                 if(!zoomscript_caught)
 475                 {
 476                         localcmd("+button4\n");
 477                         zoomscript_caught = 1;
 478                         ignore_plus_zoom += 1;
 479                 }
 480         }
 481         else
 482         {
 483                 if(zoomscript_caught)
 484                 {
 485                         localcmd("-button4\n");
 486                         zoomscript_caught = 0;
 487                         ignore_minus_zoom += 1;
 488                 }
 489         }
 490
 491         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 492         activeweapon = getstati(STAT_SWITCHWEAPON);
 493         f = (serverflags & SERVERFLAG_TEAMPLAY);
 494         if(f != teamplay)
 495         {
 496                 teamplay = f;
 497                 HUD_InitScores();
 498         }
 499
 500         if(last_weapon != activeweapon) {
 501                 weapontime = time;
 502                 last_weapon = activeweapon;
 503
 504                 e = get_weaponinfo(activeweapon);
 505                 if(e.netname != "")
 506                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 507                 else
 508                         localcmd("\ncl_hook_activeweapon none\n");
 509         }
 510
 511         // ALWAYS Clear Current Scene First
 512         R_ClearScene();
 513
 514         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 515         R_SetView(VF_SIZE, vf_size);
 516         R_SetView(VF_MIN, vf_min);
 517
 518         // Assign Standard Viewflags
 519         // Draw the World (and sky)
 520         R_SetView(VF_DRAWWORLD, 1);
 521
 522         // Set the console size vars
 523         vid_conwidth = autocvar_vid_conwidth;
 524         vid_conheight = autocvar_vid_conheight;
 525         vid_pixelheight = autocvar_vid_pixelheight;
 526
 527         R_SetView(VF_FOV, GetCurrentFov(fov));
 528
 529         // Camera for demo playback
 530         if(camera_active)
 531         {
 532                 if(autocvar_camera_enable)
 533                         CSQC_Demo_Camera();
 534                 else
 535                 {
 536                         cvar_set("chase_active", ftos(chase_active_backup));
 537                         cvar_set("cl_demo_mousegrab", "0");
 538                         camera_active = FALSE;
 539                 }
 540         }
 541 #ifdef CAMERATEST
 542         else if(autocvar_camera_enable)
 543 #else
 544         else if(autocvar_camera_enable && isdemo())
 545 #endif
 546         {
 547                 // Enable required Darkplaces cvars
 548                 chase_active_backup = autocvar_chase_active;
 549                 cvar_set("chase_active", "2");
 550                 cvar_set("cl_demo_mousegrab", "1");
 551                 camera_active = TRUE;
 552                 camera_mode = FALSE;
 553         }
 554
 555         // Draw the Crosshair
 556         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 557
 558         // Draw the Engine Status Bar (the default Quake HUD)
 559         R_SetView(VF_DRAWENGINEHUD, 0);
 560
 561         // fetch this one only once per frame
 562         hud_showbinds = autocvar_hud_showbinds;
 563         hud_showbinds_limit = autocvar_hud_showbinds_limit;
 564
 565         // Update the mouse position
 566         /*
 567            mousepos_x = vid_conwidth;
 568            mousepos_y = vid_conheight;
 569            mousepos = mousepos*0.5 + getmousepos();
 570          */
 571
 572         e = self;
 573         for(self = world; (self = nextent(self)); )
 574                 if(self.draw)
 575                         self.draw();
 576         self = e;
 577
 578         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 579         R_RenderScene();
 580
 581         // now switch to 2D drawing mode by calling a 2D drawing function
 582         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 583         // next R_RenderScene call
 584         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 585
 586         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 587         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 588         {
 589                 // apply night vision effect
 590                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 591
 592                 if(!nightvision_noise)
 593                 {
 594                         nightvision_noise = spawn();
 595                         nightvision_noise.classname = "nightvision_noise";
 596                 }
 597                 if(!nightvision_noise2)
 598                 {
 599                         nightvision_noise2 = spawn();
 600                         nightvision_noise2.classname = "nightvision_noise2";
 601                 }
 602
 603                 // color tint in yellow
 604                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 605
 606                 // draw BG
 607                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 608                 rgb = '1 1 1';
 609                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 610                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 611                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 612                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 613                 tc_11 = tc_01 + tc_10 - tc_00;
 614                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 615                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 616                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 617                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 618                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 619                 R_EndPolygon();
 620
 621                 // draw FG
 622                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 623                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 624                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 625                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 626                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 627                 tc_11 = tc_01 + tc_10 - tc_00;
 628                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 629                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 630                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 631                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 632                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 633                 R_EndPolygon();
 634         }
 635
 636         // Draw the aiming reticle for weapons that use it
 637         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 638         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 639         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 640         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 641                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 642         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_SNIPERRIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 643                 reticle_type = 2; // nex zoom
 644         else if(button_zoom || zoomscript_caught)
 645                 reticle_type = 1; // normal zoom
 646         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_SNIPERRIFLE && button_attack2)
 647                 reticle_type = 2; // nex zoom
 648
 649         if (reticle_type)
 650         {
 651                 if(autocvar_cl_reticle_stretch)
 652                 {
 653                         reticle_size_x = vid_conwidth;
 654                         reticle_size_y = vid_conheight;
 655                         reticle_pos_x = 0;
 656                         reticle_pos_y = 0;
 657                 }
 658                 else
 659                 {
 660                         reticle_size_x = max(vid_conwidth, vid_conheight);
 661                         reticle_size_y = max(vid_conwidth, vid_conheight);
 662                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 663                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 664                 }
 665
 666                 f = current_zoomfraction;
 667                 if(zoomscript_caught)
 668                         f = 1;
 669                 if(autocvar_cl_reticle_item_normal)
 670                 {
 671                         if(reticle_type == 1 && f)
 672                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 673                 }
 674                 if(autocvar_cl_reticle_item_nex)
 675                 {
 676                         if(reticle_type == 2 && f)
 677                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 678                 }
 679         }
 680
 681
 682         // improved polyblend
 683         vector rgb;
 684         if(autocvar_hud_contents)
 685         {
 686                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 687                 vector liquidcolor;
 688
 689                 switch(pointcontents(view_origin))
 690                 {
 691                         case CONTENT_WATER:
 692                                 liquidalpha = autocvar_hud_contents_water_alpha;
 693                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 694                                 incontent = 1;
 695                                 break;
 696
 697                         case CONTENT_LAVA:
 698                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 699                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 700                                 incontent = 1;
 701                                 break;
 702
 703                         case CONTENT_SLIME:
 704                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 705                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 706                                 incontent = 1;
 707                                 break;
 708
 709                         default:
 710                                 liquidalpha = 0;
 711                                 liquidcolor = '0 0 0';
 712                                 incontent = 0;
 713                                 break;
 714                 }
 715
 716                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 717                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 718                         contentfadetime = autocvar_hud_contents_fadeintime;
 719                         liquidalpha_prev = liquidalpha;
 720                         liquidcolor_prev = liquidcolor;
 721                 }
 722                 else
 723                         contentfadetime = autocvar_hud_contents_fadeouttime;
 724
 725                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 726                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 727
 728                 if(contentavgalpha)
 729                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 730         }
 731
 732         if(autocvar_hud_damage)
 733         {
 734                 splash_size_x = max(vid_conwidth, vid_conheight);
 735                 splash_size_y = max(vid_conwidth, vid_conheight);
 736                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 737                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 738
 739                 float myhealth_flash_temp;
 740                 myhealth = getstati(STAT_HEALTH);
 741
 742                 // fade out
 743                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 744                 // add new damage
 745                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 746
 747                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 748                 pain_threshold = autocvar_hud_damage_pain_threshold;
 749                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 750                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 751
 752                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 753                 {
 754                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 755                 }
 756
 757                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 758
 759                 if(myhealth_prev < 1)
 760                 {
 761                         if(myhealth >= 1)
 762                         {
 763                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 764                                 myhealth_flash_temp = 0;
 765                         }
 766                         else
 767                         {
 768                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 769                         }
 770                 }
 771
 772                 if(spectatee_status == -1 || intermission)
 773                 {
 774                         myhealth_flash = 0; // observing, or match ended
 775                         myhealth_flash_temp = 0;
 776                 }
 777
 778                 myhealth_prev = myhealth;
 779
 780                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 781                 {
 782                         if(autocvar_cl_gentle_damage == 2)
 783                         {
 784                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 785                                 {
 786                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 787                                 }
 788                         }
 789                         else
 790                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 791
 792                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 793                 }
 794                 else
 795                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 796         }
 797
 798         // Draw the mouse cursor
 799         // NOTE: drawpic must happen after R_RenderScene for some reason
 800         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 801         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 802         //self = edict_num(player_localnum);
 803         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 804         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 805         // as long as the ctf part isn't in, this is useless
 806         if(menu_visible)
 807                 menu_show();
 808
 809         /*if(gametype == GAME_CTF)
 810           {
 811           ctf_view();
 812           } else */
 813
 814         // draw 2D entities
 815         e = self;
 816         for(self = world; (self = nextent(self)); )
 817                 if(self.draw2d)
 818                         self.draw2d();
 819         self = e;
 820
 821         scoreboard_active = HUD_WouldDrawScoreboard();
 822
 823         hit_time = getstatf(STAT_HIT_TIME);
 824         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 825         {
 826                 sound(world, CHAN_AUTO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 827                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 828         }
 829         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 830         if(typehit_time > nextsound_typehit_time)
 831         {
 832                 sound(world, CHAN_AUTO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 833                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 834         }
 835
 836         float hud;
 837         hud = getstati(STAT_HUD);
 838         if(hud == HUD_SPIDERBOT)
 839                 CSQC_SPIDER_HUD();
 840         else if(hud == HUD_WAKIZASHI)
 841         CSQC_WAKIZASHI_HUD();
 842     else if(hud == HUD_RAPTOR)
 843         CSQC_RAPTOR_HUD();
 844     else if(hud == HUD_BUMBLEBEE)
 845         CSQC_BUMBLE_HUD();
 846         else
 847         {
 848                 if(gametype == GAME_FREEZETAG)
 849                 {
 850                         if(getstati(STAT_FROZEN))
 851                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 852                         if(getstatf(STAT_REVIVE_PROGRESS))
 853                         {
 854                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 855                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 856                         }
 857                 }
 858
 859                 if(autocvar_r_letterbox == 0)
 860                         if(autocvar_viewsize < 120)
 861                                 CSQC_common_hud();
 862
 863                 // crosshair goes VERY LAST
 864                 if(!scoreboard_active && !camera_active && intermission != 2) {
 865                         string wcross_style;
 866                         float wcross_alpha, wcross_resolution;
 867                         wcross_style = autocvar_crosshair;
 868                         if (wcross_style == "0")
 869                                 return;
 870                         wcross_resolution = autocvar_crosshair_size;
 871                         if (wcross_resolution == 0)
 872                                 return;
 873                         wcross_alpha = autocvar_crosshair_alpha;
 874                         if (wcross_alpha == 0)
 875                                 return;
 876
 877                         // TrueAim check
 878                         float shottype;
 879
 880                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 881                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 882                         wcross_origin_z = 0;
 883                         if(autocvar_crosshair_hittest)
 884                         {
 885                                 vector wcross_oldorigin;
 886                                 wcross_oldorigin = wcross_origin;
 887                                 shottype = TrueAimCheck();
 888                                 if(shottype == SHOTTYPE_HITWORLD)
 889                                 {
 890                                         v = wcross_origin - wcross_oldorigin;
 891                                         v_x /= vid_conwidth;
 892                                         v_y /= vid_conheight;
 893                                         if(vlen(v) > 0.01)
 894                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 895                                 }
 896                                 if(!autocvar_crosshair_hittest_showimpact)
 897                                         wcross_origin = wcross_oldorigin;
 898                         }
 899                         else
 900                                 shottype = SHOTTYPE_HITWORLD;
 901
 902                         vector wcross_color, wcross_size;
 903                         string wcross_wep, wcross_name;
 904                         float wcross_scale, wcross_blur;
 905
 906                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
 907                                 e = get_weaponinfo(activeweapon);
 908                                 if (e && e.netname != "")
 909                                 {
 910                                         wcross_wep = e.netname;
 911                                         if(autocvar_crosshair_per_weapon)
 912                                         {
 913                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 914                                                 if (wcross_resolution == 0)
 915                                                         return;
 916                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
 917                                                 if (wcross_alpha == 0)
 918                                                         return;
 919
 920                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 921                                                 if(wcross_style == "" || wcross_style == "0")
 922                                                         wcross_style = wcross_wep;
 923                                         }
 924                                 }
 925                         }
 926                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
 927                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
 928                         else if(autocvar_crosshair_color_by_health)
 929                         {
 930                                 local float x = getstati(STAT_HEALTH);
 931
 932                                 //x = red
 933                                 //y = green
 934                                 //z = blue
 935
 936                                 wcross_color_z = 0;
 937
 938                                 if(x > 200)
 939                                 {
 940                                         wcross_color_x = 0;
 941                                         wcross_color_y = 1;
 942                                 }
 943                                 else if(x > 150)
 944                                 {
 945                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
 946                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
 947                                 }
 948                                 else if(x > 100)
 949                                 {
 950                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
 951                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
 952                                         wcross_color_z = 1 - (x-100)*0.02;
 953                                 }
 954                                 else if(x > 50)
 955                                 {
 956                                         wcross_color_x = 1;
 957                                         wcross_color_y = 1;
 958                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
 959                                 }
 960                                 else if(x > 20)
 961                                 {
 962                                         wcross_color_x = 1;
 963                                         wcross_color_y = (x-20)*90/27/100;
 964                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
 965                                 }
 966                                 else
 967                                 {
 968                                         wcross_color_x = 1;
 969                                         wcross_color_y = 0;
 970                                 }
 971                         }
 972                         else
 973                                 wcross_color = stov(autocvar_crosshair_color);
 974
 975                         wcross_name = strcat("gfx/crosshair", wcross_style);
 976
 977                         if(autocvar_crosshair_effect_scalefade)
 978                         {
 979                                 wcross_scale = wcross_resolution;
 980                                 wcross_resolution = 1;
 981                         }
 982                         else
 983                         {
 984                                 wcross_scale = 1;
 985                         }
 986
 987                         if(autocvar_crosshair_pickup)
 988                         {
 989                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
 990                                 {
 991                                         pickup_crosshair_size = 1;
 992                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
 993                                 }
 994
 995                                 if(pickup_crosshair_size > 0)
 996                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 997                                 else
 998                                         pickup_crosshair_size = 0;
 999
1000                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1001                         }
1002
1003                         vector hitindication_color;
1004                         if(autocvar_crosshair_hitindication)
1005                         {
1006                                 hitindication_color = stov(autocvar_crosshair_hitindication_color);
1007                                 if(hitindication_crosshair_time < hit_time)
1008                                 {
1009                                         hitindication_crosshair_size = 1;
1010                                         hitindication_crosshair_time = hit_time;
1011                                 }
1012
1013                                 if(hitindication_crosshair_size > 0)
1014                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1015                                 else
1016                                         hitindication_crosshair_size = 0;
1017
1018                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1019                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1020                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1021                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1022                         }
1023
1024                         if(shottype == SHOTTYPE_HITENEMY)
1025                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1026                         if(shottype == SHOTTYPE_HITTEAM)
1027                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1028
1029                         f = autocvar_crosshair_effect_speed;
1030                         if(f < 0)
1031                                 f *= -2 * g_weaponswitchdelay;
1032                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1033                         {
1034                                 wcross_changedonetime = time + f;
1035                         }
1036                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1037                         {
1038                                 wcross_name_changestarttime = time;
1039                                 wcross_name_changedonetime = time + f;
1040                                 if(wcross_name_goal_prev_prev)
1041                                         strunzone(wcross_name_goal_prev_prev);
1042                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1043                                 wcross_name_goal_prev = strzone(wcross_name);
1044                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1045                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1046                                 wcross_resolution_goal_prev = wcross_resolution;
1047                         }
1048
1049                         wcross_scale_goal_prev = wcross_scale;
1050                         wcross_alpha_goal_prev = wcross_alpha;
1051                         wcross_color_goal_prev = wcross_color;
1052
1053                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1054                         {
1055                                 wcross_blur = 1;
1056                                 wcross_alpha *= 0.75;
1057                         }
1058                         else
1059                                 wcross_blur = 0;
1060                         // *_prev is at time-frametime
1061                         // * is at wcross_changedonetime+f
1062                         // what do we have at time?
1063                         if(time < wcross_changedonetime)
1064                         {
1065                                 f = frametime / (wcross_changedonetime - time + frametime);
1066                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1067                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1068                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1069                         }
1070
1071                         wcross_scale_prev = wcross_scale;
1072                         wcross_alpha_prev = wcross_alpha;
1073                         wcross_color_prev = wcross_color;
1074
1075                         wcross_scale *= 1 - autocvar__menu_alpha;
1076                         wcross_alpha *= 1 - autocvar__menu_alpha;
1077                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1078
1079                         // crosshair rings for weapon stats
1080                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1081                         {
1082                                 // declarations and stats
1083                                 float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1084                                 string ring_image, ring_inner_image;
1085                                 vector ring_rgb, ring_inner_rgb;
1086
1087                                 ring_scale = autocvar_crosshair_ring_size;
1088
1089                                 float weapon_clipload, weapon_clipsize;
1090                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1091                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1092
1093                                 float nex_charge, nex_chargepool;
1094                                 nex_charge = getstatf(STAT_NEX_CHARGE);
1095                                 nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1096
1097                                 if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1098                                         nex_charge_movingavg = nex_charge;
1099
1100
1101                                 // handle the values
1102                                 if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1103                                 {
1104                                         if (nex_chargepool || use_nex_chargepool) {
1105                                                 use_nex_chargepool = 1;
1106                                                 ring_inner_value = nex_chargepool;
1107                                         } else {
1108                                                 nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1109                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1110                                         }
1111
1112                                         ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1113                                         ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1114                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1115
1116                                         // draw the outer ring to show the current charge of the weapon
1117                                         ring_value = nex_charge;
1118                                         ring_alpha = autocvar_crosshair_ring_nex_alpha;
1119                                         ring_rgb = wcross_color;
1120                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1121                                 }
1122                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1123                                 {
1124                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1125                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1126                                         ring_rgb = wcross_color;
1127                                         ring_image = "gfx/crosshair_ring.tga";
1128                                 }
1129
1130                                 if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1131                                 {
1132                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1133                                         ring_scale = autocvar_crosshair_ring_reload_size;
1134                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1135                                         ring_rgb = wcross_color;
1136
1137                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1138                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1139                                         if ((activeweapon == WEP_SNIPERRIFLE) && (weapon_clipsize == 80))
1140                                                 ring_image = "gfx/crosshair_ring_sniperrifle.tga";
1141                                         else
1142                                                 ring_image = "gfx/crosshair_ring.tga";
1143                                 }
1144
1145                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1146                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1147
1148                                 if (ring_value)
1149                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1150                         }
1151
1152 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1153                         do \
1154                         { \
1155                                 if(wcross_blur > 0) \
1156                                 { \
1157                                         for(i = -2; i <= 2; ++i) \
1158                                                 for(j = -2; j <= 2; ++j) \
1159                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1160                                 } \
1161                                 else \
1162                                 { \
1163                                         M(0,0,sz,wcross_name,wcross_alpha); \
1164                                 } \
1165                         } \
1166                         while(0)
1167
1168 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1169                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1170
1171 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1172                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1173
1174                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1175                         {
1176                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1177                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1178                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1179                                 f = 1 - f;
1180                         }
1181                         else
1182                         {
1183                                 f = 1;
1184                         }
1185
1186                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1187                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1188
1189                         if(autocvar_crosshair_dot)
1190             {
1191                 vector wcross_color_old;
1192                 wcross_color_old = wcross_color;
1193                 if(autocvar_crosshair_dot_color != "0")
1194                     wcross_color = stov(autocvar_crosshair_dot_color);
1195                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1196                 wcross_color = wcross_color_old;
1197             }
1198
1199                         wcross_name_alpha_goal_prev = f;
1200                 }
1201                 else
1202                 {
1203                         wcross_scale_prev = 0;
1204                         wcross_alpha_prev = 0;
1205                         wcross_scale_goal_prev = 0;
1206                         wcross_alpha_goal_prev = 0;
1207                         wcross_changedonetime = 0;
1208                         if(wcross_name_goal_prev)
1209                                 strunzone(wcross_name_goal_prev);
1210                         wcross_name_goal_prev = string_null;
1211                         if(wcross_name_goal_prev_prev)
1212                                 strunzone(wcross_name_goal_prev_prev);
1213                         wcross_name_goal_prev_prev = string_null;
1214                         wcross_name_changestarttime = 0;
1215                         wcross_name_changedonetime = 0;
1216                         wcross_name_alpha_goal_prev = 0;
1217                         wcross_name_alpha_goal_prev_prev = 0;
1218                         wcross_resolution_goal_prev = 0;
1219                         wcross_resolution_goal_prev_prev = 0;
1220                 }
1221         }
1222
1223         if(NextFrameCommand)
1224         {
1225                 localcmd("\n", NextFrameCommand, "\n");
1226                 NextFrameCommand = string_null;
1227         }
1228
1229         // we must do this check AFTER a frame was rendered, or it won't work
1230         if(cs_project_is_b0rked == 0)
1231         {
1232                 string w0, h0;
1233                 w0 = ftos(autocvar_vid_conwidth);
1234                 h0 = ftos(autocvar_vid_conheight);
1235                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1236                 //R_SetView(VF_FOV, '90 90 0');
1237                 R_SetView(VF_ORIGIN, '0 0 0');
1238                 R_SetView(VF_ANGLES, '0 0 0');
1239                 R_SetView(VF_PERSPECTIVE, 1);
1240                 makevectors('0 0 0');
1241                 vector v1, v2;
1242                 cvar_set("vid_conwidth", "800");
1243                 cvar_set("vid_conheight", "600");
1244                 v1 = cs_project(v_forward);
1245                 cvar_set("vid_conwidth", "640");
1246                 cvar_set("vid_conheight", "480");
1247                 v2 = cs_project(v_forward);
1248                 if(v1 == v2)
1249                         cs_project_is_b0rked = 1;
1250                 else
1251                         cs_project_is_b0rked = -1;
1252                 cvar_set("vid_conwidth", w0);
1253                 cvar_set("vid_conheight", h0);
1254         }
1255
1256         if(autocvar__hud_configure)
1257                 HUD_Panel_Mouse();
1258
1259         // let's reset the view back to normal for the end
1260         R_SetView(VF_MIN, '0 0 0');
1261         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1262 }
1263
1264 void CSQC_common_hud(void)
1265 {
1266         // HUD_SortFrags(); done in HUD_Draw
1267         float hud;
1268         hud = getstati(STAT_HUD);
1269
1270         //hud = 10;
1271         switch(hud)
1272         {
1273                 case HUD_NORMAL:
1274                         // do some accuracy var caching
1275                         float i;
1276                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1277                         {
1278                                 if(autocvar_accuracy_color_levels != acc_color_levels)
1279                                 {
1280                                         if(acc_color_levels)
1281                                                 strunzone(acc_color_levels);
1282                                         acc_color_levels = strzone(autocvar_accuracy_color_levels);
1283                                         acc_levels = tokenize(acc_color_levels);
1284                                         if (acc_levels > MAX_ACCURACY_LEVELS)
1285                                                 acc_levels = MAX_ACCURACY_LEVELS;
1286
1287                                         for (i = 0; i < acc_levels; ++i)
1288                                                 acc_lev[i] = stof(argv(i)) / 100.0;
1289                                 }
1290                                 // let know that acc_col[] needs to be loaded
1291                                 acc_col_x[0] = -1;
1292                         }
1293
1294                         HUD_Main(); // always run these functions for alpha checks
1295                         HUD_DrawScoreboard();
1296
1297                         if (scoreboard_active) // scoreboard/accuracy
1298                         {
1299                                 HUD_Reset();
1300                                 // HUD_DrawScoreboard takes care of centerprint_start
1301                         }
1302                         else if (intermission == 2) // map voting screen
1303                         {
1304                                 HUD_FinaleOverlay();
1305                                 HUD_Reset();
1306
1307                                 centerprint_start_x = 0;
1308                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1309                         }
1310                         else // hud
1311                         {
1312                                 centerprint_start_x = 0;
1313                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1314                         }
1315
1316                         HUD_DrawCenterPrint();
1317                         break;
1318
1319                 case HUD_SPIDERBOT:
1320                         CSQC_SPIDER_HUD();
1321                         break;
1322
1323                 case HUD_WAKIZASHI:
1324                         CSQC_WAKIZASHI_HUD();
1325                         break;
1326
1327         case HUD_BUMBLEBEE:
1328             CSQC_BUMBLE_HUD();
1329             break;
1330
1331         }
1332 }
1333
1334
1335 // following vectors must be global to allow seamless switching between camera modes
1336 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1337 void CSQC_Demo_Camera()
1338 {
1339         float speed, attenuation, dimensions;
1340         vector tmp, delta;
1341
1342         if( autocvar_camera_reset || !camera_mode )
1343         {
1344                 camera_offset = '0 0 0';
1345                 current_angles = '0 0 0';
1346                 camera_direction = '0 0 0';
1347                 camera_offset_z += 30;
1348                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1349                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1350                 current_origin = view_origin;
1351                 current_camera_offset  = camera_offset;
1352                 cvar_set("camera_reset", "0");
1353                 camera_mode = CAMERA_CHASE;
1354         }
1355
1356         // Camera angles
1357         if( camera_roll )
1358                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1359
1360         if(autocvar_camera_look_player)
1361         {
1362                 local vector dir;
1363                 local float n;
1364
1365                 dir = normalize(view_origin - current_position);
1366                 n = mouse_angles_z;
1367                 mouse_angles = vectoangles(dir);
1368                 mouse_angles_x = mouse_angles_x * -1;
1369                 mouse_angles_z = n;
1370         }
1371         else
1372         {
1373                 tmp = getmousepos() * 0.1;
1374                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1375                 {
1376                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1377                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1378                 }
1379         }
1380
1381         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1382         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1383         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1384         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1385
1386         // Fix difference when angles don't have the same sign
1387         delta = '0 0 0';
1388         if(mouse_angles_y < -60 && current_angles_y > 60)
1389                 delta = '0 360 0';
1390         if(mouse_angles_y > 60 && current_angles_y < -60)
1391                 delta = '0 -360 0';
1392
1393         if(autocvar_camera_look_player)
1394                 attenuation = autocvar_camera_look_attenuation;
1395         else
1396                 attenuation = autocvar_camera_speed_attenuation;
1397
1398         attenuation = 1 / max(1, attenuation);
1399         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1400
1401         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1402         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1403         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1404         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1405
1406         // Camera position
1407         tmp = '0 0 0';
1408         dimensions = 0;
1409
1410         if( camera_direction_x )
1411         {
1412                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1413                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1414                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1415                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1416                 ++dimensions;
1417         }
1418
1419         if( camera_direction_y )
1420         {
1421                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1422                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1423                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1424                 ++dimensions;
1425         }
1426
1427         if( camera_direction_z )
1428         {
1429                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1430                 ++dimensions;
1431         }
1432
1433         if(autocvar_camera_free)
1434                 speed = autocvar_camera_speed_free;
1435         else
1436                 speed = autocvar_camera_speed_chase;
1437
1438         if(dimensions)
1439         {
1440                 speed = speed * sqrt(1 / dimensions);
1441                 camera_offset += tmp * speed;
1442         }
1443
1444         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1445
1446         // Camera modes
1447         if( autocvar_camera_free )
1448         {
1449                 if ( camera_mode == CAMERA_CHASE )
1450                 {
1451                         current_camera_offset = current_origin + current_camera_offset;
1452                         camera_offset = current_origin + camera_offset;
1453                 }
1454
1455                 camera_mode = CAMERA_FREE;
1456                 current_position = current_camera_offset;
1457         }
1458         else
1459         {
1460                 if ( camera_mode == CAMERA_FREE )
1461                 {
1462                         current_origin = view_origin;
1463                         camera_offset = camera_offset - current_origin;
1464                         current_camera_offset = current_camera_offset - current_origin;
1465                 }
1466
1467                 camera_mode = CAMERA_CHASE;
1468
1469                 if(autocvar_camera_chase_smoothly)
1470                         current_origin += (view_origin - current_origin) * attenuation;
1471                 else
1472                         current_origin = view_origin;
1473
1474                 current_position = current_origin + current_camera_offset;
1475         }
1476
1477         R_SetView(VF_ANGLES, current_angles);
1478         R_SetView(VF_ORIGIN, current_position);
1479 }