qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49         prvm_language = cvar_string("prvm_language");
  50
  51 #ifdef USE_FTE
  52 #pragma target ID
  53         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  54         if(!__engine_check)
  55         {
  56                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  57                 localcmd("\ndisconnect\n");
  58                 return;
  59         }
  60 #pragma target FTE
  61 #endif
  62
  63         check_unacceptable_compiler_bugs();
  64
  65 #ifdef WATERMARK
  66         print(sprintf(_("^4CSQC Build information: %s\n"), WATERMARK()));
  67 #endif
  68
  69         float i;
  70
  71         binddb = db_create();
  72         tempdb = db_create();
  73         ClientProgsDB = db_load("client.db");
  74         compressShortVector_init();
  75
  76         drawfont = FONT_USER+1;
  77         menu_visible = FALSE;
  78         menu_show = menu_show_error;
  79         menu_action = menu_sub_null;
  80
  81         for(i = 0; i < 255; ++i)
  82                 if(getplayerkey(i, "viewentity") == "")
  83                         break;
  84         maxclients = i;
  85
  86         //ctf_temp_1 = "";
  87         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  88         //registercmd("ctf_menu");
  89         registercmd("ons_map");
  90         registercmd("hud_configure");
  91         registercmd("hud_save");
  92         //registercmd("menu_action");
  93
  94         registercmd("+button3");
  95         registercmd("-button3");
  96         registercmd("+button4");
  97         registercmd("-button4");
  98         registercmd("+showscores");registercmd("-showscores");
  99         registercmd("+showaccuracy");registercmd("-showaccuracy");
 100
 101 #ifndef CAMERATEST
 102         if(isdemo())
 103         {
 104 #endif
 105                 registercmd("+forward");registercmd("-forward");
 106                 registercmd("+back");registercmd("-back");
 107                 registercmd("+moveup");registercmd("-moveup");
 108                 registercmd("+movedown");registercmd("-movedown");
 109                 registercmd("+moveright");registercmd("-moveright");
 110                 registercmd("+moveleft");registercmd("-moveleft");
 111                 registercmd("+roll_right");registercmd("-roll_right");
 112                 registercmd("+roll_left");registercmd("-roll_left");
 113 #ifndef CAMERATEST
 114         }
 115 #endif
 116         registercvar("hud_usecsqc", "1");
 117         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 118
 119         gametype = 0;
 120
 121         // hud_fields uses strunzone on the titles!
 122         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 123                 hud_title[i] = strzone("(null)");
 124
 125         postinit = false;
 126
 127         calledhooks = 0;
 128
 129         teams = Sort_Spawn();
 130         players = Sort_Spawn();
 131
 132         GetTeam(COLOR_SPECTATOR, true); // add specs first
 133
 134         RegisterWeapons();
 135
 136         WaypointSprite_Load();
 137
 138         // precaches
 139         precache_sound("misc/hit.wav");
 140         precache_sound("misc/typehit.wav");
 141         Projectile_Precache();
 142         Hook_Precache();
 143         GibSplash_Precache();
 144         Casings_Precache();
 145         DamageInfo_Precache();
 146         if(autocvar_cl_announcer != cl_announcer_prev) {
 147                 Announcer_Precache();
 148                 if(cl_announcer_prev)
 149                         strunzone(cl_announcer_prev);
 150                 cl_announcer_prev = strzone(autocvar_cl_announcer);
 151         }
 152         Tuba_Precache();
 153
 154         get_mi_min_max_texcoords(1); // try the CLEVER way first
 155         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 156         shortmapname = mi_shortname;
 157
 158         if(precache_pic(minimapname) == "")
 159         {
 160                 // but maybe we have a non-clever minimap
 161                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 162                 if(precache_pic(minimapname) == "")
 163                         minimapname = ""; // FAIL
 164                 else
 165                         get_mi_min_max_texcoords(0); // load new texcoords
 166         }
 167
 168         mi_center = (mi_min + mi_max) * 0.5;
 169         mi_scale = mi_max - mi_min;
 170         minimapname = strzone(minimapname);
 171
 172         WarpZone_Init();
 173
 174         hud_configure_prev = -1;
 175         tab_panel = -1;
 176 }
 177
 178 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 179 void CSQC_Shutdown(void)
 180 {
 181 #ifdef USE_FTE
 182 #pragma TARGET id
 183         if(!__engine_check)
 184                 return 0;
 185 #pragma TARGET fte
 186 #endif
 187
 188         WarpZone_Shutdown();
 189
 190         remove(teams);
 191         remove(players);
 192         db_close(binddb);
 193         db_close(tempdb);
 194         if(autocvar_cl_db_saveasdump)
 195                 db_dump(ClientProgsDB, "client.db");
 196         else
 197                 db_save(ClientProgsDB, "client.db");
 198         db_close(ClientProgsDB);
 199
 200         cvar_clientsettemp_restore();
 201
 202         if(camera_active)
 203                 cvar_set("chase_active",ftos(chase_active_backup));
 204
 205         if not(isdemo())
 206         {
 207                 if not(calledhooks & HOOK_START)
 208                         localcmd("\n_cl_hook_gamestart nop\n");
 209                 if not(calledhooks & HOOK_END)
 210                         localcmd("\ncl_hook_gameend\n");
 211         }
 212 }
 213
 214 .float has_team;
 215 float SetTeam(entity o, float Team)
 216 {
 217         entity tm;
 218         if(teamplay)
 219         {
 220                 switch(Team)
 221                 {
 222                         case -1:
 223                         case COLOR_TEAM1:
 224                         case COLOR_TEAM2:
 225                         case COLOR_TEAM3:
 226                         case COLOR_TEAM4:
 227                                 break;
 228                         default:
 229                                 if(GetTeam(Team, false) == NULL)
 230                                 {
 231                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 232                                         Team = COLOR_SPECTATOR;
 233                                 }
 234                                 break;
 235                 }
 236         }
 237         else
 238         {
 239                 switch(Team)
 240                 {
 241                         case -1:
 242                         case 0:
 243                                 break;
 244                         default:
 245                                 if(GetTeam(Team, false) == NULL)
 246                                 {
 247                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 248                                         Team = COLOR_SPECTATOR;
 249                                 }
 250                                 break;
 251                 }
 252         }
 253         if(Team == -1) // leave
 254         {
 255                 if(o.has_team)
 256                 {
 257                         tm = GetTeam(o.team, false);
 258                         tm.team_size -= 1;
 259                         o.has_team = 0;
 260                         return TRUE;
 261                 }
 262         }
 263         else
 264         {
 265                 if not(o.has_team)
 266                 {
 267                         o.team = Team;
 268                         tm = GetTeam(Team, true);
 269                         tm.team_size += 1;
 270                         o.has_team = 1;
 271                         return TRUE;
 272                 }
 273                 else if(Team != o.team)
 274                 {
 275                         tm = GetTeam(o.team, false);
 276                         tm.team_size -= 1;
 277                         o.team = Team;
 278                         tm = GetTeam(Team, true);
 279                         tm.team_size += 1;
 280                         return TRUE;
 281                 }
 282         }
 283         return FALSE;
 284 }
 285
 286 void Playerchecker_Think()
 287 {
 288         float i;
 289         entity e;
 290         for(i = 0; i < maxclients; ++i)
 291         {
 292                 e = playerslots[i];
 293                 if(GetPlayerName(i) == "")
 294                 {
 295                         if(e.sort_prev)
 296                         {
 297                                 // player disconnected
 298                                 SetTeam(e, -1);
 299                                 RemovePlayer(e);
 300                                 e.sort_prev = world;
 301                                 //e.gotscores = 0;
 302                         }
 303                 }
 304                 else
 305                 {
 306                         if not(e.sort_prev)
 307                         {
 308                                 // player connected
 309                                 if not(e)
 310                                         playerslots[i] = e = spawn();
 311                                 e.sv_entnum = i;
 312                                 e.ping = 0;
 313                                 e.ping_packetloss = 0;
 314                                 e.ping_movementloss = 0;
 315                                 //e.gotscores = 0; // we might already have the scores...
 316                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 317                                 RegisterPlayer(e);
 318                                 HUD_UpdatePlayerPos(e);
 319                         }
 320                 }
 321         }
 322         self.nextthink = time + 0.2;
 323 }
 324
 325 void Porto_Init();
 326 void TrueAim_Init();
 327 void PostInit(void)
 328 {
 329         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 330
 331         entity playerchecker;
 332         playerchecker = spawn();
 333         playerchecker.think = Playerchecker_Think;
 334         playerchecker.nextthink = time + 0.2;
 335
 336         Porto_Init();
 337         TrueAim_Init();
 338
 339         postinit = true;
 340 }
 341
 342 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 343 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 344 float button_zoom;
 345 void Cmd_HUD_SetFields(float);
 346 void Cmd_HUD_Help(float);
 347 float CSQC_ConsoleCommand(string strMessage)
 348 {
 349         float argc;
 350         // Tokenize String
 351         //argc = tokenize(strMessage);
 352         argc = tokenize_console(strMessage);
 353
 354         // Acquire Command
 355         local string strCmd;
 356         strCmd = argv(0);
 357
 358         if(strCmd == "hud_configure") { // config hud
 359                 cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 360                 return true;
 361         } else if(strCmd == "hud_save") { // save hud config
 362                 if(argv(1) == "" || argv(2)) {
 363                         print(_("Usage:\n"));
 364                         print(_("hud_save configname   (saves to hud_skinname_configname.cfg)\n"));
 365                 }
 366                 else
 367                         HUD_Panel_ExportCfg(argv(1));
 368                 return true;
 369         } else if(strCmd == "+button4") { // zoom
 370                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
 371                 if(ignore_plus_zoom)
 372                 {
 373                         --ignore_plus_zoom;
 374                         return false;
 375                 }
 376                 button_zoom = 1;
 377                 return true;
 378         } else if(strCmd == "-button4") { // zoom
 379                 if(ignore_minus_zoom)
 380                 {
 381                         --ignore_minus_zoom;
 382                         return false;
 383                 }
 384                 button_zoom = 0;
 385                 return true;
 386         } else if(strCmd == "+button3") { // secondary
 387                 button_attack2 = 1;
 388                 return false;
 389         } else if(strCmd == "-button3") { // secondary
 390                 button_attack2 = 0;
 391                 return false;
 392         } else if(strCmd == "+showscores") {
 393                 scoreboard_showscores = true;
 394                 return true;
 395         } else if(strCmd == "-showscores") {
 396                 scoreboard_showscores = false;
 397                 return true;
 398         } else if(strCmd == "+showaccuracy") {
 399                 scoreboard_showaccuracy = true;
 400                 return true;
 401         } else if(strCmd == "-showaccuracy") {
 402                 scoreboard_showaccuracy = false;
 403                 return true;
 404         }
 405
 406         if(camera_active)
 407         if(strCmd == "+forward" || strCmd == "-back") {
 408                 ++camera_direction_x;
 409                 return true;
 410         } else if(strCmd == "-forward" || strCmd == "+back") {
 411                 --camera_direction_x;
 412                 return true;
 413         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 414                 --camera_direction_y;
 415                 return true;
 416         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 417                 ++camera_direction_y;
 418                 return true;
 419         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 420                 ++camera_direction_z;
 421                 return true;
 422         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 423                 --camera_direction_z;
 424                 return true;
 425         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 426                 ++camera_roll;
 427                 return true;
 428         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 429                 --camera_roll;
 430                 return true;
 431         }
 432
 433         return false;
 434 }
 435
 436 .vector view_ofs;
 437 entity debug_shotorg;
 438 void ShotOrg_Draw()
 439 {
 440         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 441         self.angles = view_angles;
 442         self.angles_x = -self.angles_x;
 443         if not(self.cnt)
 444                 self.drawmask = MASK_NORMAL;
 445         else
 446                 self.drawmask = 0;
 447 }
 448 void ShotOrg_Draw2D()
 449 {
 450         vector coord2d_topleft, coord2d_topright, coord2d;
 451         string s;
 452         vector fs;
 453
 454         s = vtos(self.view_ofs);
 455         s = substring(s, 1, strlen(s) - 2);
 456         if(tokenize_console(s) == 3)
 457                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 458
 459         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 460         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 461
 462         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 463
 464         coord2d = coord2d_topleft;
 465         if(fs_x < 8)
 466         {
 467                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 468                 fs = '8 8 0';
 469         }
 470         coord2d_y -= fs_y;
 471         coord2d_z = 0;
 472         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 473 }
 474
 475 void ShotOrg_Spawn()
 476 {
 477         debug_shotorg = spawn();
 478         debug_shotorg.draw = ShotOrg_Draw;
 479         debug_shotorg.draw2d = ShotOrg_Draw2D;
 480         debug_shotorg.renderflags = RF_VIEWMODEL;
 481         debug_shotorg.effects = EF_FULLBRIGHT;
 482         precache_model("models/shotorg_adjuster.md3");
 483         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 484         debug_shotorg.scale = 2;
 485         debug_shotorg.view_ofs = '25 8 -8';
 486 }
 487
 488 void DrawDebugModel()
 489 {
 490         if(time - floor(time) > 0.5)
 491         {
 492                 PolyDrawModel(self);
 493                 self.drawmask = 0;
 494         }
 495         else
 496         {
 497                 self.renderflags = 0;
 498                 self.drawmask = MASK_NORMAL;
 499         }
 500 }
 501
 502 void GameCommand(string msg)
 503 {
 504         string s;
 505         float argc;
 506         entity e;
 507         argc = tokenize_console(msg);
 508
 509         if(argv(0) == "help" || argc == 0)
 510         {
 511                 print(_("Usage: cl_cmd COMMAND..., where possible commands are:\n"));
 512                 print(_("  settemp cvar value\n"));
 513                 print(_("  scoreboard_columns_set ...\n"));
 514                 print(_("  scoreboard_columns_help\n"));
 515                 GameCommand_Generic("help");
 516                 return;
 517         }
 518
 519         if(GameCommand_Generic(msg))
 520                 return;
 521
 522         string cmd;
 523         cmd = argv(0);
 524         if(cmd == "mv_download") {
 525                 Cmd_MapVote_MapDownload(argc);
 526         }
 527         else if(cmd == "settemp") {
 528                 cvar_clientsettemp(argv(1), argv(2));
 529         }
 530         else if(cmd == "scoreboard_columns_set") {
 531                 Cmd_HUD_SetFields(argc);
 532         }
 533         else if(cmd == "scoreboard_columns_help") {
 534                 Cmd_HUD_Help(argc);
 535         }
 536 #ifdef BLURTEST
 537         else if(cmd == "blurtest") {
 538                 blurtest_time0 = time;
 539                 blurtest_time1 = time + stof(argv(1));
 540                 blurtest_radius = stof(argv(2));
 541                 blurtest_power = stof(argv(3));
 542         }
 543 #endif
 544         else if(cmd == "shotorg_move") {
 545                 if(!debug_shotorg)
 546                         ShotOrg_Spawn();
 547                 else
 548                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 549                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 550         }
 551         else if(cmd == "shotorg_movez") {
 552                 if(!debug_shotorg)
 553                         ShotOrg_Spawn();
 554                 else
 555                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 556                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 557         }
 558         else if(cmd == "shotorg_set") {
 559                 if(!debug_shotorg)
 560                         ShotOrg_Spawn();
 561                 else
 562                         debug_shotorg.view_ofs = stov(argv(1));
 563                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 564         }
 565         else if(cmd == "shotorg_setz") {
 566                 if(!debug_shotorg)
 567                         ShotOrg_Spawn();
 568                 else
 569                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 570                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 571         }
 572         else if(cmd == "shotorg_toggle_hide") {
 573                 if(debug_shotorg)
 574                 {
 575                         debug_shotorg.cnt = !debug_shotorg.cnt;
 576                 }
 577         }
 578         else if(cmd == "shotorg_end") {
 579                 if(debug_shotorg)
 580                 {
 581                         print(vtos(debug_shotorg.view_ofs), "\n");
 582                         remove(debug_shotorg);
 583                         debug_shotorg = world;
 584                 }
 585                 localcmd("sv_cmd debug_shotorg\n");
 586         }
 587         else if(cmd == "sendcvar") {
 588                 // W_FixWeaponOrder will trash argv, so save what we need.
 589                 string thiscvar;
 590                 thiscvar = strzone(argv(1));
 591                 s = cvar_string(thiscvar);
 592                 if(thiscvar == "cl_weaponpriority")
 593                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 594                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 595                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 596                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 597                 strunzone(thiscvar);
 598         }
 599         else if(cmd == "spawn") {
 600                 s = argv(1);
 601                 e = spawn();
 602                 precache_model(s);
 603                 setmodel(e, s);
 604                 setorigin(e, view_origin);
 605                 e.angles = view_angles;
 606                 e.draw = DrawDebugModel;
 607                 e.classname = "debugmodel";
 608         }
 609     else if(cmd == "vyes")
 610     {
 611         if(uid2name_dialog)
 612         {
 613             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
 614             vote_prev = 0;
 615             cvar_set("cl_allow_uid2name", "1");
 616             vote_change = -9999;
 617                         uid2name_dialog = 0;
 618         }
 619         else
 620         {
 621             localcmd("cmd vote yes\n");
 622         }
 623     }
 624     else if(cmd == "vno")
 625     {
 626         if(uid2name_dialog)
 627         {
 628             vote_active = 0;
 629             vote_prev = 0;
 630             cvar_set("cl_allow_uid2name", "0");
 631             vote_change = -9999;
 632                         uid2name_dialog = 0;
 633         }
 634         else
 635         {
 636             localcmd("cmd vote no\n");
 637         }
 638     }
 639
 640         else
 641         {
 642                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 643         }
 644
 645         return;
 646 }
 647
 648 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 649 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 650 // All keys are in ascii.
 651 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 652 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 653 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 654 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 655 {
 656         local float bSkipKey;
 657         bSkipKey = false;
 658
 659         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 660                 return true;
 661
 662         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 663                 return true;
 664
 665         if(menu_visible)
 666                 if(menu_action(bInputType, nPrimary, nSecondary))
 667                         return TRUE;
 668
 669         return bSkipKey;
 670 }
 671
 672 // END REQUIRED CSQC FUNCTIONS
 673 // --------------------------------------------------------------------------
 674
 675 // --------------------------------------------------------------------------
 676 // BEGIN OPTIONAL CSQC FUNCTIONS
 677 void Ent_ReadEntCS()
 678 {
 679         InterpolateOrigin_Undo();
 680
 681         self.classname = "entcs_receiver";
 682         self.sv_entnum = ReadByte() - 1;
 683         self.origin_x = ReadShort();
 684         self.origin_y = ReadShort();
 685         self.origin_z = ReadShort();
 686         self.angles_y = ReadByte() * 360.0 / 256;
 687         self.origin_z = self.angles_x = self.angles_z = 0;
 688
 689         InterpolateOrigin_Note();
 690 }
 691
 692 void Ent_Remove();
 693
 694 void Ent_RemovePlayerScore()
 695 {
 696         float i;
 697
 698         if(self.owner)
 699         {
 700                 SetTeam(self.owner, -1);
 701                 self.owner.gotscores = 0;
 702                 for(i = 0; i < MAX_SCORE; ++i)
 703                         self.owner.(scores[i]) = 0; // clear all scores
 704         }
 705 }
 706
 707 void Ent_ReadPlayerScore()
 708 {
 709         float i, n;
 710         float isNew;
 711         entity o;
 712
 713         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 714         // (no I've never heard of M-x replace-string, sed, or anything like that)
 715         isNew = !self.owner; // workaround for DP bug
 716         n = ReadByte()-1;
 717
 718 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 719         if(!isNew && n != self.sv_entnum)
 720         {
 721                 print(_("A CSQC entity changed its owner!\n"));
 722                 isNew = true;
 723                 Ent_Remove();
 724                 self.enttype = ENT_CLIENT_SCORES;
 725         }
 726 #endif
 727
 728         self.sv_entnum = n;
 729
 730         if not(playerslots[self.sv_entnum])
 731                 playerslots[self.sv_entnum] = spawn();
 732         o = self.owner = playerslots[self.sv_entnum];
 733         o.sv_entnum = self.sv_entnum;
 734         o.gotscores = 1;
 735
 736         //if not(o.sort_prev)
 737         //      RegisterPlayer(o);
 738         //playerchecker will do this for us later, if it has not already done so
 739
 740         float sf, lf;
 741 #if MAX_SCORE <= 8
 742         sf = ReadByte();
 743         lf = ReadByte();
 744 #else
 745         sf = ReadShort();
 746         lf = ReadShort();
 747 #endif
 748         float p;
 749         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 750                 if(sf & p)
 751                 {
 752                         if(lf & p)
 753                                 o.(scores[i]) = ReadInt24_t();
 754                         else
 755                                 o.(scores[i]) = ReadChar();
 756                 }
 757
 758         if(o.sort_prev)
 759                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 760
 761         self.entremove = Ent_RemovePlayerScore;
 762 }
 763
 764 void Ent_ReadTeamScore()
 765 {
 766         float i;
 767         entity o;
 768
 769         self.team = ReadByte();
 770         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 771
 772         float sf, lf;
 773 #if MAX_TEAMSCORE <= 8
 774         sf = ReadByte();
 775         lf = ReadByte();
 776 #else
 777         sf = ReadShort();
 778         lf = ReadShort();
 779 #endif
 780         float p;
 781         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 782                 if(sf & p)
 783                 {
 784                         if(lf & p)
 785                                 o.(teamscores[i]) = ReadInt24_t();
 786                         else
 787                                 o.(teamscores[i]) = ReadChar();
 788                 }
 789
 790         HUD_UpdateTeamPos(o);
 791 }
 792
 793 void Net_Reset()
 794 {
 795 }
 796
 797 void Ent_ClientData()
 798 {
 799         float f;
 800         float newspectatee_status;
 801
 802         f = ReadByte();
 803
 804         scoreboard_showscores_force = (f & 1);
 805
 806         if(f & 2)
 807         {
 808                 newspectatee_status = ReadByte();
 809                 if(newspectatee_status == player_localentnum)
 810                         newspectatee_status = -1; // observing
 811         }
 812         else
 813                 newspectatee_status = 0;
 814
 815         spectatorbutton_zoom = (f & 4);
 816
 817         if(f & 8)
 818         {
 819                 angles_held_status = 1;
 820                 angles_held_x = ReadAngle();
 821                 angles_held_y = ReadAngle();
 822                 angles_held_z = 0;
 823         }
 824         else
 825                 angles_held_status = 0;
 826
 827         if(newspectatee_status != spectatee_status)
 828         {
 829                 float i;
 830
 831                 // clear race stuff
 832                 race_laptime = 0;
 833                 race_checkpointtime = 0;
 834         }
 835         spectatee_status = newspectatee_status;
 836 }
 837
 838 void Ent_Nagger()
 839 {
 840         float nags, i, j, b, f;
 841
 842         nags = ReadByte();
 843
 844         if(nags & 128)
 845         {
 846                 if(vote_called_vote)
 847                         strunzone(vote_called_vote);
 848                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 849         }
 850
 851         if(nags & 1)
 852         {
 853                 for(j = 0; j < maxclients; ++j)
 854                         if(playerslots[j])
 855                                 playerslots[j].ready = 1;
 856                 for(i = 1; i <= maxclients; i += 8)
 857                 {
 858                         f = ReadByte();
 859                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 860                                 if not(f & b)
 861                                         if(playerslots[j])
 862                                                 playerslots[j].ready = 0;
 863                 }
 864         }
 865
 866         ready_waiting = (nags & 1);
 867         ready_waiting_for_me = (nags & 2);
 868         vote_waiting = (nags & 4);
 869         vote_waiting_for_me = (nags & 8);
 870         warmup_stage = (nags & 16);
 871 }
 872
 873 void Ent_RandomSeed()
 874 {
 875         float s;
 876         prandom_debug();
 877         s = ReadShort();
 878         psrandom(s);
 879 }
 880
 881 void Ent_ReadAccuracy(void)
 882 {
 883         float sf, f, w, b;
 884         sf = ReadInt24_t();
 885         if(sf == 0)
 886         {
 887                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 888                         weapon_accuracy[w] = -1;
 889                 return;
 890         }
 891
 892         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 893         {
 894                 if(sf & f)
 895                 {
 896                         b = ReadByte();
 897                         if(b == 0)
 898                                 weapon_accuracy[w] = -1;
 899                         else if(b == 255)
 900                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 901                         else
 902                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 903                 }
 904         }
 905 }
 906
 907 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 908 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 909 void Ent_RadarLink();
 910 void Ent_Init();
 911 void Ent_ScoresInfo();
 912 void(float bIsNewEntity) CSQC_Ent_Update =
 913 {
 914         float t;
 915         float savetime;
 916         t = ReadByte();
 917
 918         // set up the "time" global for received entities to be correct for interpolation purposes
 919         savetime = time;
 920         if(servertime)
 921         {
 922                 time = servertime;
 923         }
 924         else
 925         {
 926                 serverprevtime = time;
 927                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 928                 time = serverprevtime + serverdeltatime;
 929         }
 930
 931 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 932         if(self.enttype)
 933                 if(t != self.enttype)
 934                 {
 935                         print(_("A CSQC entity changed its type!\n"));
 936                         Ent_Remove();
 937                         bIsNewEntity = 1;
 938                 }
 939 #endif
 940         self.enttype = t;
 941         switch(t)
 942         {
 943                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 944                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 945                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 946                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 947                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 948                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 949                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 950                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 951                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 952                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 953                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 954                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 955                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 956                 case ENT_CLIENT_INIT: Ent_Init(); break;
 957                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 958                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 959                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 960                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 961                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 962                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 963                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 964                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 965                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 966                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 967                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 968                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 969                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 970                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 971                 default:
 972                         error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 973                         break;
 974         }
 975
 976         time = savetime;
 977 };
 978 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 979 // used when an entity changes its type. For an entity that someone interacts
 980 // with others, make sure it can no longer do so.
 981 void Ent_Remove()
 982 {
 983         if(self.entremove)
 984                 self.entremove();
 985
 986         self.enttype = 0;
 987         self.classname = "";
 988         self.draw = menu_sub_null;
 989         self.entremove = menu_sub_null;
 990         // TODO possibly set more stuff to defaults
 991 }
 992 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 993 void CSQC_Ent_Remove()
 994 {
 995         if(self.enttype)
 996                 Ent_Remove();
 997         remove(self);
 998 }
 999
1000 void Gamemode_Init()
1001 {
1002         if not(isdemo())
1003         {
1004                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
1005                 calledhooks |= HOOK_START;
1006         }
1007 }
1008 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1009 void CSQC_Parse_StuffCmd(string strMessage)
1010 {
1011         localcmd(strMessage);
1012 }
1013 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1014 void CSQC_Parse_Print(string strMessage)
1015 {
1016         print(ColorTranslateRGB(strMessage));
1017 }
1018
1019 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1020 void CSQC_Parse_CenterPrint(string strMessage)
1021 {
1022         centerprint(strMessage);
1023 }
1024
1025 string notranslate_fogcmd1 = "\nfog ";
1026 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1027 void Fog_Force()
1028 {
1029         // TODO somehow thwart prvm_globalset client ...
1030
1031         if(forcefog != "")
1032                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1033 }
1034
1035 void Gamemode_Init();
1036 void Ent_ScoresInfo()
1037 {
1038         float i;
1039         self.classname = "ent_client_scores_info";
1040         gametype = ReadByte();
1041         for(i = 0; i < MAX_SCORE; ++i)
1042         {
1043                 scores_label[i] = strzone(ReadString());
1044                 scores_flags[i] = ReadByte();
1045         }
1046         for(i = 0; i < MAX_TEAMSCORE; ++i)
1047         {
1048                 teamscores_label[i] = strzone(ReadString());
1049                 teamscores_flags[i] = ReadByte();
1050         }
1051         HUD_InitScores();
1052         Gamemode_Init();
1053 }
1054
1055 void Ent_Init()
1056 {
1057         self.classname = "ent_client_init";
1058
1059         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1060
1061         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1062         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1063         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1064         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1065         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1066         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1067         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1068         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1069         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1070         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1071         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1072         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1073
1074         if(forcefog)
1075                 strunzone(forcefog);
1076         forcefog = strzone(ReadString());
1077
1078         armorblockpercent = ReadByte() / 255.0;
1079
1080         g_weaponswitchdelay = ReadByte() / 255.0;
1081
1082         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1083         g_balance_grenadelauncher_bouncestop = ReadCoord();
1084         g_balance_electro_secondary_bouncefactor = ReadCoord();
1085         g_balance_electro_secondary_bouncestop = ReadCoord();
1086
1087         nex_scope = !ReadByte();
1088         sniperrifle_scope = !ReadByte();
1089
1090         serverflags = ReadByte();
1091
1092         minelayer_maxmines = ReadByte();
1093
1094         g_trueaim_minrange = ReadCoord();
1095
1096         if(!postinit)
1097                 PostInit();
1098 }
1099
1100 void Net_ReadRace()
1101 {
1102         float b;
1103
1104         b = ReadByte();
1105
1106         switch(b)
1107         {
1108                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1109                         race_checkpoint = ReadByte();
1110                         race_time = ReadInt24_t();
1111                         race_previousbesttime = ReadInt24_t();
1112                         if(race_previousbestname)
1113                                 strunzone(race_previousbestname);
1114                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1115
1116                         race_checkpointtime = time;
1117
1118                         if(race_checkpoint == 0 || race_checkpoint == 254)
1119                         {
1120                                 race_penaltyaccumulator = 0;
1121                                 race_laptime = time; // valid
1122                         }
1123
1124                         break;
1125
1126                 case RACE_NET_CHECKPOINT_CLEAR:
1127                         race_laptime = 0;
1128                         race_checkpointtime = 0;
1129                         break;
1130
1131                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1132                         race_laptime = ReadCoord();
1133                         race_checkpointtime = -99999;
1134                         // fall through
1135                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1136                         race_nextcheckpoint = ReadByte();
1137
1138                         race_nextbesttime = ReadInt24_t();
1139                         if(race_nextbestname)
1140                                 strunzone(race_nextbestname);
1141                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1142                         break;
1143
1144                 case RACE_NET_CHECKPOINT_HIT_RACE:
1145                         race_mycheckpoint = ReadByte();
1146                         race_mycheckpointtime = time;
1147                         race_mycheckpointdelta = ReadInt24_t();
1148                         race_mycheckpointlapsdelta = ReadByte();
1149                         if(race_mycheckpointlapsdelta >= 128)
1150                                 race_mycheckpointlapsdelta -= 256;
1151                         if(race_mycheckpointenemy)
1152                                 strunzone(race_mycheckpointenemy);
1153                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1154                         break;
1155
1156                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1157                         race_othercheckpoint = ReadByte();
1158                         race_othercheckpointtime = time;
1159                         race_othercheckpointdelta = ReadInt24_t();
1160                         race_othercheckpointlapsdelta = ReadByte();
1161                         if(race_othercheckpointlapsdelta >= 128)
1162                                 race_othercheckpointlapsdelta -= 256;
1163                         if(race_othercheckpointenemy)
1164                                 strunzone(race_othercheckpointenemy);
1165                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1166                         break;
1167
1168                 case RACE_NET_PENALTY_RACE:
1169                         race_penaltyeventtime = time;
1170                         race_penaltytime = ReadShort();
1171                         //race_penaltyaccumulator += race_penaltytime;
1172                         if(race_penaltyreason)
1173                                 strunzone(race_penaltyreason);
1174                         race_penaltyreason = strzone(ReadString());
1175                         break;
1176
1177                 case RACE_NET_PENALTY_QUALIFYING:
1178                         race_penaltyeventtime = time;
1179                         race_penaltytime = ReadShort();
1180                         race_penaltyaccumulator += race_penaltytime;
1181                         if(race_penaltyreason)
1182                                 strunzone(race_penaltyreason);
1183                         race_penaltyreason = strzone(ReadString());
1184                         break;
1185
1186                 case RACE_NET_SERVER_RECORD:
1187                         race_server_record = ReadInt24_t();
1188                         break;
1189                 case RACE_NET_SPEED_AWARD:
1190                         race_speedaward = ReadInt24_t();
1191                         if(race_speedaward_holder)
1192                                 strunzone(race_speedaward_holder);
1193                         race_speedaward_holder = strzone(ReadString());
1194                         break;
1195                 case RACE_NET_SPEED_AWARD_BEST:
1196                         race_speedaward_alltimebest = ReadInt24_t();
1197                         if(race_speedaward_alltimebest_holder)
1198                                 strunzone(race_speedaward_alltimebest_holder);
1199                         race_speedaward_alltimebest_holder = strzone(ReadString());
1200                         break;
1201                 case RACE_NET_SERVER_RANKINGS:
1202                         float pos, prevpos, del;
1203                         pos = ReadShort();
1204                         prevpos = ReadShort();
1205                         del = ReadShort();
1206
1207                         // move other rankings out of the way
1208                         float i;
1209                         if (prevpos) {
1210                                 for (i=prevpos-1;i>pos-1;--i) {
1211                                         grecordtime[i] = grecordtime[i-1];
1212                                         if(grecordholder[i])
1213                                                 strunzone(grecordholder[i]);
1214                                         grecordholder[i] = strzone(grecordholder[i-1]);
1215                                 }
1216                         } else if (del) { // a record has been deleted by the admin
1217                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1218                                         if (i == RANKINGS_CNT-1) { // clear out last record
1219                                                 grecordtime[i] = 0;
1220                                                 if (grecordholder[i])
1221                                                         strunzone(grecordholder[i]);
1222                                                 grecordholder[i] = string_null;
1223                                         }
1224                                         else {
1225                                                 grecordtime[i] = grecordtime[i+1];
1226                                                 if (grecordholder[i])
1227                                                         strunzone(grecordholder[i]);
1228                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1229                                         }
1230                                 }
1231                         } else { // player has no ranked record yet
1232                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1233                                         grecordtime[i] = grecordtime[i-1];
1234                                         if(grecordholder[i])
1235                                                 strunzone(grecordholder[i]);
1236                                         grecordholder[i] = strzone(grecordholder[i-1]);
1237                                 }
1238                         }
1239
1240                         // store new ranking
1241                         if(grecordholder[pos-1] != "")
1242                                 strunzone(grecordholder[pos-1]);
1243                         grecordholder[pos-1] = strzone(ReadString());
1244                         grecordtime[pos-1] = ReadInt24_t();
1245                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1246                                 race_myrank = pos;
1247                         break;
1248                 case RACE_NET_SERVER_STATUS:
1249                         race_status = ReadShort();
1250                         if(race_status_name)
1251                                 strunzone(race_status_name);
1252                         race_status_name = strzone(ReadString());
1253         }
1254 }
1255
1256 void Net_ReadSpawn()
1257 {
1258         zoomin_effect = 1;
1259         current_viewzoom = 0.6;
1260 }
1261
1262 void Net_TeamNagger()
1263 {
1264         teamnagger = 1;
1265 }
1266
1267 void Net_ReadPingPLReport()
1268 {
1269         float e, pi, pl, ml;
1270         e = ReadByte();
1271         pi = ReadShort();
1272         pl = ReadByte();
1273         ml = ReadByte();
1274         if not(playerslots[e])
1275                 return;
1276         playerslots[e].ping = pi;
1277         playerslots[e].ping_packetloss = pl / 255.0;
1278         playerslots[e].ping_movementloss = ml / 255.0;
1279 }
1280
1281 void Net_VoteDialog(float highlight) {
1282         if(highlight) {
1283                 vote_highlighted = ReadByte();
1284                 return;
1285         }
1286
1287         vote_yescount = ReadByte();
1288         vote_nocount = ReadByte();
1289         vote_needed = ReadByte();
1290         vote_active = 1;
1291 }
1292
1293 void Net_VoteDialogReset() {
1294         vote_active = 0;
1295 }
1296
1297 void Net_Notify() {
1298         float type;
1299         type = ReadByte();
1300
1301         if(type == CSQC_KILLNOTIFY)
1302         {
1303                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1304         }
1305         else if(type == CSQC_CENTERPRINT)
1306         {
1307                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1308         }
1309 }
1310
1311 void Net_WeaponComplain() {
1312         complain_weapon = ReadByte();
1313
1314         if(complain_weapon_name)
1315                 strunzone(complain_weapon_name);
1316         complain_weapon_name = strzone(ReadString());
1317
1318         complain_weapon_type = ReadByte();
1319
1320         complain_weapon_time = time;
1321         weapontime = time; // ping the weapon panel
1322 }
1323
1324 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1325 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1326 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1327 float CSQC_Parse_TempEntity()
1328 {
1329         local float bHandled;
1330                 bHandled  = true;
1331         // Acquire TE ID
1332         local float nTEID;
1333                 nTEID = ReadByte();
1334
1335                 // NOTE: Could just do return instead of break...
1336         switch(nTEID)
1337         {
1338                 case TE_CSQC_TARGET_MUSIC:
1339                         Net_TargetMusic();
1340                         bHandled = true;
1341                         break;
1342                 case TE_CSQC_PICTURE:
1343                         Net_MapVote_Picture();
1344                         bHandled = true;
1345                         break;
1346                 case TE_CSQC_RACE:
1347                         Net_ReadRace();
1348                         bHandled = true;
1349                         break;
1350                 case TE_CSQC_SPAWN:
1351                         Net_ReadSpawn();
1352                         bHandled = true;
1353                         break;
1354                 case TE_CSQC_ZCURVEPARTICLES:
1355                         Net_ReadZCurveParticles();
1356                         bHandled = true;
1357                         break;
1358                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1359                         Net_ReadNexgunBeamParticle();
1360                         bHandled = true;
1361                         break;
1362                 case TE_CSQC_TEAMNAGGER:
1363                         Net_TeamNagger();
1364                         bHandled = true;
1365                         break;
1366                 case TE_CSQC_VOTE:
1367                         Net_VoteDialog(ReadByte());
1368                         bHandled = true;
1369                         break;
1370                 case TE_CSQC_VOTERESET:
1371                         Net_VoteDialogReset();
1372                         bHandled = true;
1373                         break;
1374                 case TE_CSQC_LIGHTNINGARC:
1375                         Net_ReadLightningarc();
1376                         bHandled = true;
1377                         break;
1378                 case TE_CSQC_PINGPLREPORT:
1379                         Net_ReadPingPLReport();
1380                         bHandled = true;
1381                         break;
1382                 case TE_CSQC_ANNOUNCE:
1383                         announce_snd = strzone(ReadString());
1384                         bHandled = true;
1385                         break;
1386                 case TE_CSQC_NOTIFY:
1387                         Net_Notify();
1388                         bHandled = true;
1389                         break;
1390                 case TE_CSQC_WEAPONCOMPLAIN:
1391                         Net_WeaponComplain();
1392                         bHandled = true;
1393                         break;
1394                 default:
1395                         // No special logic for this temporary entity; return 0 so the engine can handle it
1396                         bHandled = false;
1397                         break;
1398         }
1399
1400         return bHandled;
1401 }
1402
1403 string getcommandkey(string text, string command)
1404 {
1405         string keys;
1406         float n, j, k, l;
1407
1408         if (!autocvar_hud_showbinds)
1409                 return text;
1410
1411         keys = db_get(binddb, command);
1412         if (!keys)
1413         {
1414                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1415                 for(j = 0; j < n; ++j)
1416                 {
1417                         k = stof(argv(j));
1418                         if(k != -1)
1419                         {
1420                                 if ("" == keys)
1421                                         keys = keynumtostring(k);
1422                                 else
1423                                         keys = strcat(keys, ", ", keynumtostring(k));
1424
1425                                 ++l;
1426                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1427                         }
1428
1429                 }
1430                 db_put(binddb, command, keys);
1431         }
1432
1433         if ("" == keys) {
1434                 if (autocvar_hud_showbinds > 1)
1435                         return sprintf(_("%s (not bound)"), text);
1436                 else
1437                         return text;
1438         }
1439         else if (autocvar_hud_showbinds > 1)
1440                 return sprintf(_("%s (%s)"), text, keys);
1441         else
1442                 return keys;
1443 }