qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void menu_show_error()
  29 {
  30         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  31 }
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void menu_sub_null()
  37 {
  38 }
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49         prvm_language = cvar_string("prvm_language");
  50
  51 #ifdef USE_FTE
  52 #pragma target ID
  53         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  54         if(!__engine_check)
  55         {
  56                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  57                 localcmd("\ndisconnect\n");
  58                 return;
  59         }
  60 #pragma target FTE
  61 #endif
  62
  63         check_unacceptable_compiler_bugs();
  64
  65 #ifdef WATERMARK
  66         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK()));
  67 #endif
  68
  69         float i;
  70
  71         binddb = db_create();
  72         tempdb = db_create();
  73         ClientProgsDB = db_load("client.db");
  74         compressShortVector_init();
  75
  76         drawfont = FONT_USER+1;
  77         menu_visible = FALSE;
  78         menu_show = menu_show_error;
  79         menu_action = menu_sub_null;
  80
  81         for(i = 0; i < 255; ++i)
  82                 if(getplayerkey(i, "viewentity") == "")
  83                         break;
  84         maxclients = i;
  85
  86         //ctf_temp_1 = "";
  87         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  88         //registercmd("ctf_menu");
  89         registercmd("ons_map");
  90         registercmd("hud_configure");
  91         registercmd("hud_save");
  92         //registercmd("menu_action");
  93
  94         registercmd("+showscores");registercmd("-showscores");
  95         registercmd("+showaccuracy");registercmd("-showaccuracy");
  96
  97 #ifndef CAMERATEST
  98         if(isdemo())
  99         {
 100 #endif
 101                 registercmd("+forward");registercmd("-forward");
 102                 registercmd("+back");registercmd("-back");
 103                 registercmd("+moveup");registercmd("-moveup");
 104                 registercmd("+movedown");registercmd("-movedown");
 105                 registercmd("+moveright");registercmd("-moveright");
 106                 registercmd("+moveleft");registercmd("-moveleft");
 107                 registercmd("+roll_right");registercmd("-roll_right");
 108                 registercmd("+roll_left");registercmd("-roll_left");
 109 #ifndef CAMERATEST
 110         }
 111 #endif
 112         registercvar("hud_usecsqc", "1");
 113         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 114
 115         gametype = 0;
 116
 117         // hud_fields uses strunzone on the titles!
 118         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 119                 hud_title[i] = strzone("(null)");
 120
 121         postinit = false;
 122
 123         calledhooks = 0;
 124
 125         teams = Sort_Spawn();
 126         players = Sort_Spawn();
 127
 128         GetTeam(COLOR_SPECTATOR, true); // add specs first
 129
 130         RegisterWeapons();
 131
 132         WaypointSprite_Load();
 133
 134         // precaches
 135         precache_sound("misc/hit.wav");
 136         precache_sound("misc/typehit.wav");
 137         Projectile_Precache();
 138         Hook_Precache();
 139         GibSplash_Precache();
 140         Casings_Precache();
 141         DamageInfo_Precache();
 142         Vehicles_Precache();
 143         turrets_precache();
 144
 145         if(autocvar_cl_announcer != cl_announcer_prev) {
 146                 Announcer_Precache();
 147                 if(cl_announcer_prev)
 148                         strunzone(cl_announcer_prev);
 149                 cl_announcer_prev = strzone(autocvar_cl_announcer);
 150         }
 151         Tuba_Precache();
 152
 153         if(autocvar_cl_reticle)
 154         {
 155                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 156                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 157         }
 158
 159         get_mi_min_max_texcoords(1); // try the CLEVER way first
 160         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 161         shortmapname = mi_shortname;
 162
 163         if(precache_pic(minimapname) == "")
 164         {
 165                 // but maybe we have a non-clever minimap
 166                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 167                 if(precache_pic(minimapname) == "")
 168                         minimapname = ""; // FAIL
 169                 else
 170                         get_mi_min_max_texcoords(0); // load new texcoords
 171         }
 172
 173         mi_center = (mi_min + mi_max) * 0.5;
 174         mi_scale = mi_max - mi_min;
 175         minimapname = strzone(minimapname);
 176
 177         WarpZone_Init();
 178
 179         hud_configure_prev = -1;
 180         tab_panel = -1;
 181 }
 182
 183 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 184 void CSQC_Shutdown(void)
 185 {
 186 #ifdef USE_FTE
 187 #pragma TARGET id
 188         if(!__engine_check)
 189                 return 0;
 190 #pragma TARGET fte
 191 #endif
 192
 193         WarpZone_Shutdown();
 194
 195         remove(teams);
 196         remove(players);
 197         db_close(binddb);
 198         db_close(tempdb);
 199         if(autocvar_cl_db_saveasdump)
 200                 db_dump(ClientProgsDB, "client.db");
 201         else
 202                 db_save(ClientProgsDB, "client.db");
 203         db_close(ClientProgsDB);
 204
 205         cvar_clientsettemp_restore();
 206
 207         if(camera_active)
 208                 cvar_set("chase_active",ftos(chase_active_backup));
 209
 210         // unset the event chasecam's chase_active
 211         if(autocvar_chase_active < 0)
 212                 cvar_set("chase_active", "0");
 213
 214         if not(isdemo())
 215         {
 216                 if not(calledhooks & HOOK_START)
 217                         localcmd("\n_cl_hook_gamestart nop\n");
 218                 if not(calledhooks & HOOK_END)
 219                         localcmd("\ncl_hook_gameend\n");
 220         }
 221 }
 222
 223 .float has_team;
 224 float SetTeam(entity o, float Team)
 225 {
 226         entity tm;
 227         if(teamplay)
 228         {
 229                 switch(Team)
 230                 {
 231                         case -1:
 232                         case COLOR_TEAM1:
 233                         case COLOR_TEAM2:
 234                         case COLOR_TEAM3:
 235                         case COLOR_TEAM4:
 236                                 break;
 237                         default:
 238                                 if(GetTeam(Team, false) == NULL)
 239                                 {
 240                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 241                                         Team = COLOR_SPECTATOR;
 242                                 }
 243                                 break;
 244                 }
 245         }
 246         else
 247         {
 248                 switch(Team)
 249                 {
 250                         case -1:
 251                         case 0:
 252                                 break;
 253                         default:
 254                                 if(GetTeam(Team, false) == NULL)
 255                                 {
 256                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 257                                         Team = COLOR_SPECTATOR;
 258                                 }
 259                                 break;
 260                 }
 261         }
 262         if(Team == -1) // leave
 263         {
 264                 if(o.has_team)
 265                 {
 266                         tm = GetTeam(o.team, false);
 267                         tm.team_size -= 1;
 268                         o.has_team = 0;
 269                         return TRUE;
 270                 }
 271         }
 272         else
 273         {
 274                 if not(o.has_team)
 275                 {
 276                         o.team = Team;
 277                         tm = GetTeam(Team, true);
 278                         tm.team_size += 1;
 279                         o.has_team = 1;
 280                         return TRUE;
 281                 }
 282                 else if(Team != o.team)
 283                 {
 284                         tm = GetTeam(o.team, false);
 285                         tm.team_size -= 1;
 286                         o.team = Team;
 287                         tm = GetTeam(Team, true);
 288                         tm.team_size += 1;
 289                         return TRUE;
 290                 }
 291         }
 292         return FALSE;
 293 }
 294
 295 void Playerchecker_Think()
 296 {
 297         float i;
 298         entity e;
 299         for(i = 0; i < maxclients; ++i)
 300         {
 301                 e = playerslots[i];
 302                 if(GetPlayerName(i) == "")
 303                 {
 304                         if(e.sort_prev)
 305                         {
 306                                 // player disconnected
 307                                 SetTeam(e, -1);
 308                                 RemovePlayer(e);
 309                                 e.sort_prev = world;
 310                                 //e.gotscores = 0;
 311                         }
 312                 }
 313                 else
 314                 {
 315                         if not(e.sort_prev)
 316                         {
 317                                 // player connected
 318                                 if not(e)
 319                                         playerslots[i] = e = spawn();
 320                                 e.sv_entnum = i;
 321                                 e.ping = 0;
 322                                 e.ping_packetloss = 0;
 323                                 e.ping_movementloss = 0;
 324                                 //e.gotscores = 0; // we might already have the scores...
 325                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 326                                 RegisterPlayer(e);
 327                                 HUD_UpdatePlayerPos(e);
 328                         }
 329                 }
 330         }
 331         self.nextthink = time + 0.2;
 332 }
 333
 334 void Porto_Init();
 335 void TrueAim_Init();
 336 void PostInit(void)
 337 {
 338         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 339
 340         entity playerchecker;
 341         playerchecker = spawn();
 342         playerchecker.think = Playerchecker_Think;
 343         playerchecker.nextthink = time + 0.2;
 344
 345         Porto_Init();
 346         TrueAim_Init();
 347
 348         postinit = true;
 349 }
 350
 351 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 352 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 353 float button_zoom;
 354 void Cmd_HUD_SetFields(float);
 355 void Cmd_HUD_Help(float);
 356 float CSQC_ConsoleCommand(string strMessage)
 357 {
 358         float argc;
 359         // Tokenize String
 360         argc = tokenize_console(strMessage);
 361
 362         // Acquire Command
 363         string strCmd;
 364         strCmd = argv(0);
 365
 366         if(strCmd == "hud_configure") { // config hud
 367                 cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 368                 return true;
 369         } else if(strCmd == "hud_save") { // save hud config
 370                 if(argv(1) == "" || argv(2)) {
 371                         print(_("Usage:\n"));
 372                         print(_("hud_save configname   (saves to hud_skinname_configname.cfg)\n"));
 373                 }
 374                 else
 375                         HUD_Panel_ExportCfg(argv(1));
 376                 return true;
 377         } else if(strCmd == "+showscores") {
 378                 scoreboard_showscores = true;
 379                 return true;
 380         } else if(strCmd == "-showscores") {
 381                 scoreboard_showscores = false;
 382                 return true;
 383         } else if(strCmd == "+showaccuracy") {
 384                 scoreboard_showaccuracy = true;
 385                 return true;
 386         } else if(strCmd == "-showaccuracy") {
 387                 scoreboard_showaccuracy = false;
 388                 return true;
 389         }
 390
 391         if(camera_active)
 392         if(strCmd == "+forward" || strCmd == "-back") {
 393                 ++camera_direction_x;
 394                 return true;
 395         } else if(strCmd == "-forward" || strCmd == "+back") {
 396                 --camera_direction_x;
 397                 return true;
 398         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 399                 --camera_direction_y;
 400                 return true;
 401         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 402                 ++camera_direction_y;
 403                 return true;
 404         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 405                 ++camera_direction_z;
 406                 return true;
 407         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 408                 --camera_direction_z;
 409                 return true;
 410         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 411                 ++camera_roll;
 412                 return true;
 413         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 414                 --camera_roll;
 415                 return true;
 416         }
 417
 418         return false;
 419 }
 420
 421 .vector view_ofs;
 422 entity debug_shotorg;
 423 void ShotOrg_Draw()
 424 {
 425         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 426         self.angles = view_angles;
 427         self.angles_x = -self.angles_x;
 428         if not(self.cnt)
 429                 self.drawmask = MASK_NORMAL;
 430         else
 431                 self.drawmask = 0;
 432 }
 433 void ShotOrg_Draw2D()
 434 {
 435         vector coord2d_topleft, coord2d_topright, coord2d;
 436         string s;
 437         vector fs;
 438
 439         s = vtos(self.view_ofs);
 440         s = substring(s, 1, strlen(s) - 2);
 441         if(tokenize_console(s) == 3)
 442                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 443
 444         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 445         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 446
 447         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 448
 449         coord2d = coord2d_topleft;
 450         if(fs_x < 8)
 451         {
 452                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 453                 fs = '8 8 0';
 454         }
 455         coord2d_y -= fs_y;
 456         coord2d_z = 0;
 457         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 458 }
 459
 460 void ShotOrg_Spawn()
 461 {
 462         debug_shotorg = spawn();
 463         debug_shotorg.draw = ShotOrg_Draw;
 464         debug_shotorg.draw2d = ShotOrg_Draw2D;
 465         debug_shotorg.renderflags = RF_VIEWMODEL;
 466         debug_shotorg.effects = EF_FULLBRIGHT;
 467         precache_model("models/shotorg_adjuster.md3");
 468         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 469         debug_shotorg.scale = 2;
 470         debug_shotorg.view_ofs = '25 8 -8';
 471 }
 472
 473 void DrawDebugModel()
 474 {
 475         if(time - floor(time) > 0.5)
 476         {
 477                 PolyDrawModel(self);
 478                 self.drawmask = 0;
 479         }
 480         else
 481         {
 482                 self.renderflags = 0;
 483                 self.drawmask = MASK_NORMAL;
 484         }
 485 }
 486
 487 void GameCommand(string msg)
 488 {
 489         string s;
 490         float argc;
 491         entity e;
 492         argc = tokenize_console(msg);
 493
 494         if(argv(0) == "help" || argc == 0)
 495         {
 496                 print(_("Usage: cl_cmd COMMAND..., where possible commands are:\n"));
 497                 print(_("  settemp cvar value\n"));
 498                 print(_("  scoreboard_columns_set ...\n"));
 499                 print(_("  scoreboard_columns_help\n"));
 500                 GameCommand_Generic("help");
 501                 return;
 502         }
 503
 504         if(GameCommand_Generic(msg))
 505                 return;
 506
 507         string cmd;
 508         cmd = argv(0);
 509         if(cmd == "mv_download") {
 510                 Cmd_MapVote_MapDownload(argc);
 511         }
 512         else if(cmd == "hud_panel_radar_maximized")
 513         {
 514                 if(argc == 1)
 515                         hud_panel_radar_maximized = !hud_panel_radar_maximized;
 516                 else
 517                         hud_panel_radar_maximized = (stof(argv(1)) != 0);
 518         }
 519         else if(cmd == "settemp") {
 520                 cvar_clientsettemp(argv(1), argv(2));
 521         }
 522         else if(cmd == "scoreboard_columns_set") {
 523                 Cmd_HUD_SetFields(argc);
 524         }
 525         else if(cmd == "scoreboard_columns_help") {
 526                 Cmd_HUD_Help(argc);
 527         }
 528 #ifdef BLURTEST
 529         else if(cmd == "blurtest") {
 530                 blurtest_time0 = time;
 531                 blurtest_time1 = time + stof(argv(1));
 532                 blurtest_radius = stof(argv(2));
 533                 blurtest_power = stof(argv(3));
 534         }
 535 #endif
 536         else if(cmd == "shotorg_move") {
 537                 if(!debug_shotorg)
 538                         ShotOrg_Spawn();
 539                 else
 540                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 541                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 542         }
 543         else if(cmd == "shotorg_movez") {
 544                 if(!debug_shotorg)
 545                         ShotOrg_Spawn();
 546                 else
 547                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 548                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 549         }
 550         else if(cmd == "shotorg_set") {
 551                 if(!debug_shotorg)
 552                         ShotOrg_Spawn();
 553                 else
 554                         debug_shotorg.view_ofs = stov(argv(1));
 555                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 556         }
 557         else if(cmd == "shotorg_setz") {
 558                 if(!debug_shotorg)
 559                         ShotOrg_Spawn();
 560                 else
 561                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 562                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 563         }
 564         else if(cmd == "shotorg_toggle_hide") {
 565                 if(debug_shotorg)
 566                 {
 567                         debug_shotorg.cnt = !debug_shotorg.cnt;
 568                 }
 569         }
 570         else if(cmd == "shotorg_end") {
 571                 if(debug_shotorg)
 572                 {
 573                         print(vtos(debug_shotorg.view_ofs), "\n");
 574                         remove(debug_shotorg);
 575                         debug_shotorg = world;
 576                 }
 577                 localcmd("sv_cmd debug_shotorg\n");
 578         }
 579         else if(cmd == "sendcvar") {
 580                 // W_FixWeaponOrder will trash argv, so save what we need.
 581                 string thiscvar;
 582                 thiscvar = strzone(argv(1));
 583                 s = cvar_string(thiscvar);
 584                 if(thiscvar == "cl_weaponpriority")
 585                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 586                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 587                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 588                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 589                 strunzone(thiscvar);
 590         }
 591         else if(cmd == "spawn") {
 592                 s = argv(1);
 593                 e = spawn();
 594                 precache_model(s);
 595                 setmodel(e, s);
 596                 setorigin(e, view_origin);
 597                 e.angles = view_angles;
 598                 e.draw = DrawDebugModel;
 599                 e.classname = "debugmodel";
 600         }
 601     else if(cmd == "vyes")
 602     {
 603         if(uid2name_dialog)
 604         {
 605             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
 606             vote_prev = 0;
 607             localcmd("setreport cl_allow_uid2name 1\n");
 608             vote_change = -9999;
 609                         uid2name_dialog = 0;
 610         }
 611         else
 612         {
 613             localcmd("cmd vote yes\n");
 614         }
 615     }
 616     else if(cmd == "vno")
 617     {
 618         if(uid2name_dialog)
 619         {
 620             vote_active = 0;
 621             vote_prev = 0;
 622             localcmd("setreport cl_allow_uid2name 0\n");
 623             vote_change = -9999;
 624                         uid2name_dialog = 0;
 625         }
 626         else
 627         {
 628             localcmd("cmd vote no\n");
 629         }
 630     }
 631
 632         else
 633         {
 634                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 635         }
 636
 637         return;
 638 }
 639
 640 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 641 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 642 // All keys are in ascii.
 643 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 644 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 645 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 646 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 647 {
 648         float bSkipKey;
 649         bSkipKey = false;
 650
 651         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 652                 return true;
 653
 654         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 655                 return true;
 656
 657         if(menu_visible)
 658                 if(menu_action(bInputType, nPrimary, nSecondary))
 659                         return TRUE;
 660
 661         return bSkipKey;
 662 }
 663
 664 // END REQUIRED CSQC FUNCTIONS
 665 // --------------------------------------------------------------------------
 666
 667 // --------------------------------------------------------------------------
 668 // BEGIN OPTIONAL CSQC FUNCTIONS
 669 void Ent_RemoveEntCS()
 670 {
 671         entcs_receiver[self.sv_entnum] = world;
 672 }
 673 void Ent_ReadEntCS()
 674 {
 675         float sf;
 676         InterpolateOrigin_Undo();
 677
 678         self.classname = "entcs_receiver";
 679         sf = ReadByte();
 680
 681         if(sf & 1)
 682                 self.sv_entnum = ReadByte();
 683         if(sf & 2)
 684         {
 685                 self.origin_x = ReadShort();
 686                 self.origin_y = ReadShort();
 687                 self.origin_z = ReadShort();
 688         }
 689         if(sf & 4)
 690         {
 691                 self.angles_y = ReadByte() * 360.0 / 256;
 692                 self.angles_x = self.angles_z = 0;
 693         }
 694         if(sf & 8)
 695                 self.healthvalue = ReadByte() * 10;
 696         if(sf & 16)
 697                 self.armorvalue = ReadByte() * 10;
 698
 699         entcs_receiver[self.sv_entnum] = self;
 700         self.entremove = Ent_RemoveEntCS;
 701
 702         InterpolateOrigin_Note();
 703 }
 704
 705 void Ent_Remove();
 706
 707 void Ent_RemovePlayerScore()
 708 {
 709         float i;
 710
 711         if(self.owner)
 712         {
 713                 SetTeam(self.owner, -1);
 714                 self.owner.gotscores = 0;
 715                 for(i = 0; i < MAX_SCORE; ++i)
 716                         self.owner.(scores[i]) = 0; // clear all scores
 717         }
 718 }
 719
 720 void Ent_ReadPlayerScore()
 721 {
 722         float i, n;
 723         float isNew;
 724         entity o;
 725
 726         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 727         // (no I've never heard of M-x replace-string, sed, or anything like that)
 728         isNew = !self.owner; // workaround for DP bug
 729         n = ReadByte()-1;
 730
 731 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 732         if(!isNew && n != self.sv_entnum)
 733         {
 734                 //print(_("A CSQC entity changed its owner!\n"));
 735                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 736                 isNew = true;
 737                 Ent_Remove();
 738                 self.enttype = ENT_CLIENT_SCORES;
 739         }
 740 #endif
 741
 742         self.sv_entnum = n;
 743
 744         if not(playerslots[self.sv_entnum])
 745                 playerslots[self.sv_entnum] = spawn();
 746         o = self.owner = playerslots[self.sv_entnum];
 747         o.sv_entnum = self.sv_entnum;
 748         o.gotscores = 1;
 749
 750         //if not(o.sort_prev)
 751         //      RegisterPlayer(o);
 752         //playerchecker will do this for us later, if it has not already done so
 753
 754         float sf, lf;
 755 #if MAX_SCORE <= 8
 756         sf = ReadByte();
 757         lf = ReadByte();
 758 #else
 759         sf = ReadShort();
 760         lf = ReadShort();
 761 #endif
 762         float p;
 763         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 764                 if(sf & p)
 765                 {
 766                         if(lf & p)
 767                                 o.(scores[i]) = ReadInt24_t();
 768                         else
 769                                 o.(scores[i]) = ReadChar();
 770                 }
 771
 772         if(o.sort_prev)
 773                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 774
 775         self.entremove = Ent_RemovePlayerScore;
 776 }
 777
 778 void Ent_ReadTeamScore()
 779 {
 780         float i;
 781         entity o;
 782
 783         self.team = ReadByte();
 784         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 785
 786         float sf, lf;
 787 #if MAX_TEAMSCORE <= 8
 788         sf = ReadByte();
 789         lf = ReadByte();
 790 #else
 791         sf = ReadShort();
 792         lf = ReadShort();
 793 #endif
 794         float p;
 795         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 796                 if(sf & p)
 797                 {
 798                         if(lf & p)
 799                                 o.(teamscores[i]) = ReadInt24_t();
 800                         else
 801                                 o.(teamscores[i]) = ReadChar();
 802                 }
 803
 804         HUD_UpdateTeamPos(o);
 805 }
 806
 807 void Ent_ClientData()
 808 {
 809         float f;
 810         float newspectatee_status;
 811
 812         f = ReadByte();
 813
 814         scoreboard_showscores_force = (f & 1);
 815
 816         if(f & 2)
 817         {
 818                 newspectatee_status = ReadByte();
 819                 if(newspectatee_status == player_localentnum)
 820                         newspectatee_status = -1; // observing
 821         }
 822         else
 823                 newspectatee_status = 0;
 824
 825         spectatorbutton_zoom = (f & 4);
 826
 827         if(f & 8)
 828         {
 829                 angles_held_status = 1;
 830                 angles_held_x = ReadAngle();
 831                 angles_held_y = ReadAngle();
 832                 angles_held_z = 0;
 833         }
 834         else
 835                 angles_held_status = 0;
 836
 837         if(newspectatee_status != spectatee_status)
 838         {
 839                 // clear race stuff
 840                 race_laptime = 0;
 841                 race_checkpointtime = 0;
 842         }
 843         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 844         {
 845                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 846                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 847                 )
 848                         prev_p_health = -1;
 849                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 850                         prev_health = -1;
 851         }
 852         spectatee_status = newspectatee_status;
 853 }
 854
 855 void Ent_Nagger()
 856 {
 857         float nags, i, j, b, f;
 858
 859         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 860
 861         if(!(nags & 4))
 862         {
 863                 if(vote_called_vote)
 864                         strunzone(vote_called_vote);
 865                 vote_called_vote = string_null;
 866                 vote_active = 0;
 867         }
 868         else
 869         {
 870                 vote_active = 1;
 871         }
 872
 873         if(nags & 64)
 874         {
 875                 vote_yescount = ReadByte();
 876                 vote_nocount = ReadByte();
 877                 vote_needed = ReadByte();
 878                 vote_highlighted = ReadChar();
 879         }
 880
 881         if(nags & 128)
 882         {
 883                 if(vote_called_vote)
 884                         strunzone(vote_called_vote);
 885                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 886         }
 887
 888         if(nags & 1)
 889         {
 890                 for(j = 0; j < maxclients; ++j)
 891                         if(playerslots[j])
 892                                 playerslots[j].ready = 1;
 893                 for(i = 1; i <= maxclients; i += 8)
 894                 {
 895                         f = ReadByte();
 896                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 897                                 if not(f & b)
 898                                         if(playerslots[j])
 899                                                 playerslots[j].ready = 0;
 900                 }
 901         }
 902
 903         ready_waiting = (nags & 1);
 904         ready_waiting_for_me = (nags & 2);
 905         vote_waiting = (nags & 4);
 906         vote_waiting_for_me = (nags & 8);
 907         warmup_stage = (nags & 16);
 908 }
 909
 910 void Ent_RandomSeed()
 911 {
 912         float s;
 913         prandom_debug();
 914         s = ReadShort();
 915         psrandom(s);
 916 }
 917
 918 void Ent_ReadAccuracy(void)
 919 {
 920         float sf, f, w, b;
 921         sf = ReadInt24_t();
 922         if(sf == 0)
 923         {
 924                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 925                         weapon_accuracy[w] = -1;
 926                 return;
 927         }
 928
 929         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 930         {
 931                 if(sf & f)
 932                 {
 933                         b = ReadByte();
 934                         if(b == 0)
 935                                 weapon_accuracy[w] = -1;
 936                         else if(b == 255)
 937                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 938                         else
 939                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 940                 }
 941         }
 942 }
 943
 944 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 945 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 946 void Ent_RadarLink();
 947 void Ent_Init();
 948 void Ent_ScoresInfo();
 949 void CSQC_Ent_Update(float bIsNewEntity)
 950 {
 951         float t;
 952         float savetime;
 953         t = ReadByte();
 954
 955         // set up the "time" global for received entities to be correct for interpolation purposes
 956         savetime = time;
 957         if(servertime)
 958         {
 959                 time = servertime;
 960         }
 961         else
 962         {
 963                 serverprevtime = time;
 964                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 965                 time = serverprevtime + serverdeltatime;
 966         }
 967
 968 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 969         if(self.enttype)
 970                 if(t != self.enttype)
 971                 {
 972                         //print(_("A CSQC entity changed its type!\n"));
 973                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 974                         Ent_Remove();
 975                         bIsNewEntity = 1;
 976                 }
 977 #endif
 978         self.enttype = t;
 979         switch(t)
 980         {
 981                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 982                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 983                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 984                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 985                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 986                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 987                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 988                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 989                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 990                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 991                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 992                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 993                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 994                 case ENT_CLIENT_INIT: Ent_Init(); break;
 995                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 996                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 997                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 998                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 999                 case ENT_CLIENT_WALL: Ent_Wall(); break;
1000                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
1001                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
1002                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
1003                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
1004                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
1005                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
1006                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
1007                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
1008                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
1009                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
1010                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
1011                 case ENT_CLIENT_TURRET: ent_turret(); break;
1012                 default:
1013                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
1014                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
1015                         break;
1016         }
1017
1018         time = savetime;
1019 }
1020 // Destructor, but does NOT deallocate the entity by calling remove(). Also
1021 // used when an entity changes its type. For an entity that someone interacts
1022 // with others, make sure it can no longer do so.
1023 void Ent_Remove()
1024 {
1025         if(self.entremove)
1026                 self.entremove();
1027
1028         self.enttype = 0;
1029         self.classname = "";
1030         self.draw = menu_sub_null;
1031         self.entremove = menu_sub_null;
1032         // TODO possibly set more stuff to defaults
1033 }
1034 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
1035 void CSQC_Ent_Remove()
1036 {
1037         if(self.enttype)
1038                 Ent_Remove();
1039         remove(self);
1040 }
1041
1042 void Gamemode_Init()
1043 {
1044         if not(isdemo())
1045         {
1046                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
1047                 calledhooks |= HOOK_START;
1048         }
1049 }
1050 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1051 void CSQC_Parse_StuffCmd(string strMessage)
1052 {
1053         localcmd(strMessage);
1054 }
1055 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1056 void CSQC_Parse_Print(string strMessage)
1057 {
1058         print(ColorTranslateRGB(strMessage));
1059 }
1060
1061 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1062 void CSQC_Parse_CenterPrint(string strMessage)
1063 {
1064         centerprint(strMessage);
1065 }
1066
1067 string notranslate_fogcmd1 = "\nfog ";
1068 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1069 void Fog_Force()
1070 {
1071         // TODO somehow thwart prvm_globalset client ...
1072
1073         if(forcefog != "")
1074                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1075 }
1076
1077 void Gamemode_Init();
1078 void Ent_ScoresInfo()
1079 {
1080         float i;
1081         self.classname = "ent_client_scores_info";
1082         gametype = ReadByte();
1083         for(i = 0; i < MAX_SCORE; ++i)
1084         {
1085                 scores_label[i] = strzone(ReadString());
1086                 scores_flags[i] = ReadByte();
1087         }
1088         for(i = 0; i < MAX_TEAMSCORE; ++i)
1089         {
1090                 teamscores_label[i] = strzone(ReadString());
1091                 teamscores_flags[i] = ReadByte();
1092         }
1093         HUD_InitScores();
1094         Gamemode_Init();
1095 }
1096
1097 void Ent_Init()
1098 {
1099         self.classname = "ent_client_init";
1100
1101         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1102
1103         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1104         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1105         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1106         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1107         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1108         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1109         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1110         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1111         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1112         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1113         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1114         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1115
1116         if(forcefog)
1117                 strunzone(forcefog);
1118         forcefog = strzone(ReadString());
1119
1120         armorblockpercent = ReadByte() / 255.0;
1121
1122         g_weaponswitchdelay = ReadByte() / 255.0;
1123
1124         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1125         g_balance_grenadelauncher_bouncestop = ReadCoord();
1126         g_balance_electro_secondary_bouncefactor = ReadCoord();
1127         g_balance_electro_secondary_bouncestop = ReadCoord();
1128
1129         nex_scope = !ReadByte();
1130         rifle_scope = !ReadByte();
1131
1132         serverflags = ReadByte();
1133
1134         minelayer_maxmines = ReadByte();
1135
1136         hagar_maxrockets = ReadByte();
1137
1138         g_trueaim_minrange = ReadCoord();
1139
1140         if(!postinit)
1141                 PostInit();
1142 }
1143
1144 void Net_ReadRace()
1145 {
1146         float b;
1147
1148         b = ReadByte();
1149
1150         switch(b)
1151         {
1152                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1153                         race_checkpoint = ReadByte();
1154                         race_time = ReadInt24_t();
1155                         race_previousbesttime = ReadInt24_t();
1156                         if(race_previousbestname)
1157                                 strunzone(race_previousbestname);
1158                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1159
1160                         race_checkpointtime = time;
1161
1162                         if(race_checkpoint == 0 || race_checkpoint == 254)
1163                         {
1164                                 race_penaltyaccumulator = 0;
1165                                 race_laptime = time; // valid
1166                         }
1167
1168                         break;
1169
1170                 case RACE_NET_CHECKPOINT_CLEAR:
1171                         race_laptime = 0;
1172                         race_checkpointtime = 0;
1173                         break;
1174
1175                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1176                         race_laptime = ReadCoord();
1177                         race_checkpointtime = -99999;
1178                         // fall through
1179                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1180                         race_nextcheckpoint = ReadByte();
1181
1182                         race_nextbesttime = ReadInt24_t();
1183                         if(race_nextbestname)
1184                                 strunzone(race_nextbestname);
1185                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1186                         break;
1187
1188                 case RACE_NET_CHECKPOINT_HIT_RACE:
1189                         race_mycheckpoint = ReadByte();
1190                         race_mycheckpointtime = time;
1191                         race_mycheckpointdelta = ReadInt24_t();
1192                         race_mycheckpointlapsdelta = ReadByte();
1193                         if(race_mycheckpointlapsdelta >= 128)
1194                                 race_mycheckpointlapsdelta -= 256;
1195                         if(race_mycheckpointenemy)
1196                                 strunzone(race_mycheckpointenemy);
1197                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1198                         break;
1199
1200                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1201                         race_othercheckpoint = ReadByte();
1202                         race_othercheckpointtime = time;
1203                         race_othercheckpointdelta = ReadInt24_t();
1204                         race_othercheckpointlapsdelta = ReadByte();
1205                         if(race_othercheckpointlapsdelta >= 128)
1206                                 race_othercheckpointlapsdelta -= 256;
1207                         if(race_othercheckpointenemy)
1208                                 strunzone(race_othercheckpointenemy);
1209                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1210                         break;
1211
1212                 case RACE_NET_PENALTY_RACE:
1213                         race_penaltyeventtime = time;
1214                         race_penaltytime = ReadShort();
1215                         //race_penaltyaccumulator += race_penaltytime;
1216                         if(race_penaltyreason)
1217                                 strunzone(race_penaltyreason);
1218                         race_penaltyreason = strzone(ReadString());
1219                         break;
1220
1221                 case RACE_NET_PENALTY_QUALIFYING:
1222                         race_penaltyeventtime = time;
1223                         race_penaltytime = ReadShort();
1224                         race_penaltyaccumulator += race_penaltytime;
1225                         if(race_penaltyreason)
1226                                 strunzone(race_penaltyreason);
1227                         race_penaltyreason = strzone(ReadString());
1228                         break;
1229
1230                 case RACE_NET_SERVER_RECORD:
1231                         race_server_record = ReadInt24_t();
1232                         break;
1233                 case RACE_NET_SPEED_AWARD:
1234                         race_speedaward = ReadInt24_t();
1235                         if(race_speedaward_holder)
1236                                 strunzone(race_speedaward_holder);
1237                         race_speedaward_holder = strzone(ReadString());
1238                         break;
1239                 case RACE_NET_SPEED_AWARD_BEST:
1240                         race_speedaward_alltimebest = ReadInt24_t();
1241                         if(race_speedaward_alltimebest_holder)
1242                                 strunzone(race_speedaward_alltimebest_holder);
1243                         race_speedaward_alltimebest_holder = strzone(ReadString());
1244                         break;
1245                 case RACE_NET_SERVER_RANKINGS:
1246                         float pos, prevpos, del;
1247                         pos = ReadShort();
1248                         prevpos = ReadShort();
1249                         del = ReadShort();
1250
1251                         // move other rankings out of the way
1252                         float i;
1253                         if (prevpos) {
1254                                 for (i=prevpos-1;i>pos-1;--i) {
1255                                         grecordtime[i] = grecordtime[i-1];
1256                                         if(grecordholder[i])
1257                                                 strunzone(grecordholder[i]);
1258                                         grecordholder[i] = strzone(grecordholder[i-1]);
1259                                 }
1260                         } else if (del) { // a record has been deleted by the admin
1261                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1262                                         if (i == RANKINGS_CNT-1) { // clear out last record
1263                                                 grecordtime[i] = 0;
1264                                                 if (grecordholder[i])
1265                                                         strunzone(grecordholder[i]);
1266                                                 grecordholder[i] = string_null;
1267                                         }
1268                                         else {
1269                                                 grecordtime[i] = grecordtime[i+1];
1270                                                 if (grecordholder[i])
1271                                                         strunzone(grecordholder[i]);
1272                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1273                                         }
1274                                 }
1275                         } else { // player has no ranked record yet
1276                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1277                                         grecordtime[i] = grecordtime[i-1];
1278                                         if(grecordholder[i])
1279                                                 strunzone(grecordholder[i]);
1280                                         grecordholder[i] = strzone(grecordholder[i-1]);
1281                                 }
1282                         }
1283
1284                         // store new ranking
1285                         if(grecordholder[pos-1] != "")
1286                                 strunzone(grecordholder[pos-1]);
1287                         grecordholder[pos-1] = strzone(ReadString());
1288                         grecordtime[pos-1] = ReadInt24_t();
1289                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1290                                 race_myrank = pos;
1291                         break;
1292                 case RACE_NET_SERVER_STATUS:
1293                         race_status = ReadShort();
1294                         if(race_status_name)
1295                                 strunzone(race_status_name);
1296                         race_status_name = strzone(ReadString());
1297         }
1298 }
1299
1300 void Net_ReadSpawn()
1301 {
1302         zoomin_effect = 1;
1303         current_viewzoom = 0.6;
1304 }
1305
1306 void Net_TeamNagger()
1307 {
1308         teamnagger = 1;
1309 }
1310
1311 void Net_ReadPingPLReport()
1312 {
1313         float e, pi, pl, ml;
1314         e = ReadByte();
1315         pi = ReadShort();
1316         pl = ReadByte();
1317         ml = ReadByte();
1318         if not(playerslots[e])
1319                 return;
1320         playerslots[e].ping = pi;
1321         playerslots[e].ping_packetloss = pl / 255.0;
1322         playerslots[e].ping_movementloss = ml / 255.0;
1323 }
1324
1325 void Net_WeaponComplain() {
1326         complain_weapon = ReadByte();
1327
1328         if(complain_weapon_name)
1329                 strunzone(complain_weapon_name);
1330         complain_weapon_name = strzone(ReadString());
1331
1332         complain_weapon_type = ReadByte();
1333
1334         complain_weapon_time = time;
1335         weapontime = time; // ping the weapon panel
1336 }
1337
1338 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1339 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1340 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1341 float CSQC_Parse_TempEntity()
1342 {
1343         float bHandled;
1344                 bHandled  = true;
1345         // Acquire TE ID
1346         float nTEID;
1347                 nTEID = ReadByte();
1348
1349                 // NOTE: Could just do return instead of break...
1350         switch(nTEID)
1351         {
1352                 case TE_CSQC_TARGET_MUSIC:
1353                         Net_TargetMusic();
1354                         bHandled = true;
1355                         break;
1356                 case TE_CSQC_PICTURE:
1357                         Net_MapVote_Picture();
1358                         bHandled = true;
1359                         break;
1360                 case TE_CSQC_RACE:
1361                         Net_ReadRace();
1362                         bHandled = true;
1363                         break;
1364                 case TE_CSQC_SPAWN:
1365                         Net_ReadSpawn();
1366                         bHandled = true;
1367                         break;
1368                 case TE_CSQC_ZCURVEPARTICLES:
1369                         Net_ReadZCurveParticles();
1370                         bHandled = true;
1371                         break;
1372                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1373                         Net_ReadNexgunBeamParticle();
1374                         bHandled = true;
1375                         break;
1376                 case TE_CSQC_TEAMNAGGER:
1377                         Net_TeamNagger();
1378                         bHandled = true;
1379                         break;
1380                 case TE_CSQC_LIGHTNINGARC:
1381                         Net_ReadLightningarc();
1382                         bHandled = true;
1383                         break;
1384                 case TE_CSQC_PINGPLREPORT:
1385                         Net_ReadPingPLReport();
1386                         bHandled = true;
1387                         break;
1388                 case TE_CSQC_ANNOUNCE:
1389                         announce_snd = strzone(ReadString());
1390                         bHandled = true;
1391                         break;
1392                 case TE_CSQC_KILLNOTIFY:
1393                         HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1394                         bHandled = true;
1395                         break;
1396                 case TE_CSQC_KILLCENTERPRINT:
1397                         HUD_KillCenterprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1398                         bHandled = true;
1399                         break;
1400                 case TE_CSQC_CENTERPRINT_GENERIC:
1401                         float id;
1402                         string s;
1403                         id = ReadByte();
1404                         s = ReadString();
1405                         if (id != 0 && s != "")
1406                                 centerprint_generic(id, s, ReadByte(), ReadByte());
1407                         else
1408                                 centerprint_generic(id, s, 0, 0);
1409                         bHandled = true;
1410                         break;
1411                 case TE_CSQC_WEAPONCOMPLAIN:
1412                         Net_WeaponComplain();
1413                         bHandled = true;
1414                         break;
1415         case TE_CSQC_VEHICLESETUP:
1416             Net_VehicleSetup();
1417             bHandled = true;
1418             break;
1419                 default:
1420                         // No special logic for this temporary entity; return 0 so the engine can handle it
1421                         bHandled = false;
1422                         break;
1423         }
1424
1425         return bHandled;
1426 }
1427
1428 string getcommandkey(string text, string command)
1429 {
1430         string keys;
1431         float n, j, k, l;
1432
1433         if (!autocvar_hud_showbinds)
1434                 return text;
1435
1436         keys = db_get(binddb, command);
1437         if (!keys)
1438         {
1439                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1440                 for(j = 0; j < n; ++j)
1441                 {
1442                         k = stof(argv(j));
1443                         if(k != -1)
1444                         {
1445                                 if ("" == keys)
1446                                         keys = keynumtostring(k);
1447                                 else
1448                                         keys = strcat(keys, ", ", keynumtostring(k));
1449
1450                                 ++l;
1451                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1452                         }
1453
1454                 }
1455                 db_put(binddb, command, keys);
1456         }
1457
1458         if ("" == keys) {
1459                 if (autocvar_hud_showbinds > 1)
1460                         return sprintf(_("%s (not bound)"), text);
1461                 else
1462                         return text;
1463         }
1464         else if (autocvar_hud_showbinds > 1)
1465                 return sprintf(_("%s (%s)"), text, keys);
1466         else
1467                 return keys;
1468 }