qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void menu_show_error()
  29 {
  30         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  31 }
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void menu_sub_null()
  37 {
  38 }
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 void WaypointSprite_Load();
  46 void CSQC_Init(void)
  47 {
  48         prvm_language = cvar_string("prvm_language");
  49
  50 #ifdef USE_FTE
  51 #pragma target ID
  52         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  53         if(!__engine_check)
  54         {
  55                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  56                 localcmd("\ndisconnect\n");
  57                 return;
  58         }
  59 #pragma target FTE
  60 #endif
  61
  62         check_unacceptable_compiler_bugs();
  63
  64 #ifdef WATERMARK
  65         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK()));
  66 #endif
  67
  68         float i;
  69
  70         binddb = db_create();
  71         tempdb = db_create();
  72         ClientProgsDB = db_load("client.db");
  73         compressShortVector_init();
  74
  75         drawfont = FONT_USER+1;
  76         menu_visible = FALSE;
  77         menu_show = menu_show_error;
  78         menu_action = menu_sub_null;
  79
  80         for(i = 0; i < 255; ++i)
  81                 if(getplayerkeyvalue(i, "viewentity") == "")
  82                         break;
  83         maxclients = i;
  84
  85         registercommand("hud_configure");
  86         registercommand("hud_save");
  87         //registercommand("menu_action");
  88
  89         registercommand("+showscores");registercommand("-showscores");
  90         registercommand("+showaccuracy");registercommand("-showaccuracy");
  91
  92 #ifndef CAMERATEST
  93         if(isdemo())
  94         {
  95 #endif
  96                 registercommand("+forward");registercommand("-forward");
  97                 registercommand("+back");registercommand("-back");
  98                 registercommand("+moveup");registercommand("-moveup");
  99                 registercommand("+movedown");registercommand("-movedown");
 100                 registercommand("+moveright");registercommand("-moveright");
 101                 registercommand("+moveleft");registercommand("-moveleft");
 102                 registercommand("+roll_right");registercommand("-roll_right");
 103                 registercommand("+roll_left");registercommand("-roll_left");
 104 #ifndef CAMERATEST
 105         }
 106 #endif
 107         registercvar("hud_usecsqc", "1");
 108         registercvar("scoreboard_columns", "default");
 109
 110         gametype = 0;
 111
 112         // hud_fields uses strunzone on the titles!
 113         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 114                 hud_title[i] = strzone("(null)");
 115
 116         postinit = false;
 117
 118         calledhooks = 0;
 119
 120         teams = Sort_Spawn();
 121         players = Sort_Spawn();
 122
 123         GetTeam(COLOR_SPECTATOR, true); // add specs first
 124
 125         RegisterWeapons();
 126
 127         WaypointSprite_Load();
 128
 129         // precaches
 130         precache_model("null");
 131         precache_sound("misc/hit.wav");
 132         precache_sound("misc/typehit.wav");
 133         Projectile_Precache();
 134         Hook_Precache();
 135         GibSplash_Precache();
 136         Casings_Precache();
 137         DamageInfo_Precache();
 138         Vehicles_Precache();
 139         turrets_precache();
 140   Announcer_Precache();
 141         Tuba_Precache();
 142
 143         if(autocvar_cl_reticle)
 144         {
 145                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 146                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 147         }
 148
 149         get_mi_min_max_texcoords(1); // try the CLEVER way first
 150         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 151         shortmapname = mi_shortname;
 152
 153         if(precache_pic(minimapname) == "")
 154         {
 155                 // but maybe we have a non-clever minimap
 156                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 157                 if(precache_pic(minimapname) == "")
 158                         minimapname = ""; // FAIL
 159                 else
 160                         get_mi_min_max_texcoords(0); // load new texcoords
 161         }
 162
 163         mi_center = (mi_min + mi_max) * 0.5;
 164         mi_scale = mi_max - mi_min;
 165         minimapname = strzone(minimapname);
 166
 167         WarpZone_Init();
 168
 169         hud_configure_prev = -1;
 170         tab_panel = -1;
 171 }
 172
 173 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 174 void CSQC_Shutdown(void)
 175 {
 176 #ifdef USE_FTE
 177 #pragma TARGET id
 178         if(!__engine_check)
 179                 return 0;
 180 #pragma TARGET fte
 181 #endif
 182
 183         WarpZone_Shutdown();
 184
 185         remove(teams);
 186         remove(players);
 187         db_close(binddb);
 188         db_close(tempdb);
 189         if(autocvar_cl_db_saveasdump)
 190                 db_dump(ClientProgsDB, "client.db");
 191         else
 192                 db_save(ClientProgsDB, "client.db");
 193         db_close(ClientProgsDB);
 194
 195         cvar_clientsettemp_restore();
 196
 197         if(camera_active)
 198                 cvar_set("chase_active",ftos(chase_active_backup));
 199
 200         // unset the event chasecam's chase_active
 201         if(autocvar_chase_active < 0)
 202                 cvar_set("chase_active", "0");
 203
 204         if not(isdemo())
 205         {
 206                 if not(calledhooks & HOOK_START)
 207                         localcmd("\n_cl_hook_gamestart nop\n");
 208                 if not(calledhooks & HOOK_END)
 209                         localcmd("\ncl_hook_gameend\n");
 210         }
 211 }
 212
 213 .float has_team;
 214 float SetTeam(entity o, float Team)
 215 {
 216         entity tm;
 217         if(teamplay)
 218         {
 219                 switch(Team)
 220                 {
 221                         case -1:
 222                         case COLOR_TEAM1:
 223                         case COLOR_TEAM2:
 224                         case COLOR_TEAM3:
 225                         case COLOR_TEAM4:
 226                                 break;
 227                         default:
 228                                 if(GetTeam(Team, false) == world)
 229                                 {
 230                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 231                                         Team = COLOR_SPECTATOR;
 232                                 }
 233                                 break;
 234                 }
 235         }
 236         else
 237         {
 238                 switch(Team)
 239                 {
 240                         case -1:
 241                         case 0:
 242                                 break;
 243                         default:
 244                                 if(GetTeam(Team, false) == world)
 245                                 {
 246                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 247                                         Team = COLOR_SPECTATOR;
 248                                 }
 249                                 break;
 250                 }
 251         }
 252         if(Team == -1) // leave
 253         {
 254                 if(o.has_team)
 255                 {
 256                         tm = GetTeam(o.team, false);
 257                         tm.team_size -= 1;
 258                         o.has_team = 0;
 259                         return TRUE;
 260                 }
 261         }
 262         else
 263         {
 264                 if not(o.has_team)
 265                 {
 266                         o.team = Team;
 267                         tm = GetTeam(Team, true);
 268                         tm.team_size += 1;
 269                         o.has_team = 1;
 270                         return TRUE;
 271                 }
 272                 else if(Team != o.team)
 273                 {
 274                         tm = GetTeam(o.team, false);
 275                         tm.team_size -= 1;
 276                         o.team = Team;
 277                         tm = GetTeam(Team, true);
 278                         tm.team_size += 1;
 279                         return TRUE;
 280                 }
 281         }
 282         return FALSE;
 283 }
 284
 285 void Playerchecker_Think()
 286 {
 287         float i;
 288         entity e;
 289         for(i = 0; i < maxclients; ++i)
 290         {
 291                 e = playerslots[i];
 292                 if(GetPlayerName(i) == "")
 293                 {
 294                         if(e.sort_prev)
 295                         {
 296                                 // player disconnected
 297                                 SetTeam(e, -1);
 298                                 RemovePlayer(e);
 299                                 e.sort_prev = world;
 300                                 //e.gotscores = 0;
 301                         }
 302                 }
 303                 else
 304                 {
 305                         if not(e.sort_prev)
 306                         {
 307                                 // player connected
 308                                 if not(e)
 309                                         playerslots[i] = e = spawn();
 310                                 e.sv_entnum = i;
 311                                 e.ping = 0;
 312                                 e.ping_packetloss = 0;
 313                                 e.ping_movementloss = 0;
 314                                 //e.gotscores = 0; // we might already have the scores...
 315                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 316                                 RegisterPlayer(e);
 317                                 HUD_UpdatePlayerPos(e);
 318                         }
 319                 }
 320         }
 321         self.nextthink = time + 0.2;
 322 }
 323
 324 void Porto_Init();
 325 void TrueAim_Init();
 326 void PostInit(void)
 327 {
 328         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 329
 330         entity playerchecker;
 331         playerchecker = spawn();
 332         playerchecker.think = Playerchecker_Think;
 333         playerchecker.nextthink = time + 0.2;
 334
 335         Porto_Init();
 336         TrueAim_Init();
 337
 338         postinit = true;
 339 }
 340
 341 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercommand" function
 342 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 343 float button_zoom;
 344 void Cmd_HUD_SetFields(float);
 345 void Cmd_HUD_Help(float);
 346 float CSQC_ConsoleCommand(string strMessage)
 347 {
 348         float argc;
 349         // Tokenize String
 350         argc = tokenize_console(strMessage);
 351
 352         // Acquire Command
 353         string strCmd;
 354         strCmd = argv(0);
 355
 356         if(strCmd == "hud_configure") { // config hud
 357                 cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 358                 return true;
 359         } else if(strCmd == "hud_save") { // save hud config
 360                 if(argv(1) == "" || argv(2)) {
 361                         print(_("Usage:\n"));
 362                         print(_("hud_save configname   (saves to hud_skinname_configname.cfg)\n"));
 363                 }
 364                 else
 365                         HUD_Panel_ExportCfg(argv(1));
 366                 return true;
 367         } else if(strCmd == "+showscores") {
 368                 scoreboard_showscores = true;
 369                 return true;
 370         } else if(strCmd == "-showscores") {
 371                 scoreboard_showscores = false;
 372                 return true;
 373         } else if(strCmd == "+showaccuracy") {
 374                 scoreboard_showaccuracy = true;
 375                 return true;
 376         } else if(strCmd == "-showaccuracy") {
 377                 scoreboard_showaccuracy = false;
 378                 return true;
 379         }
 380
 381         if(camera_active)
 382         if(strCmd == "+forward" || strCmd == "-back") {
 383                 ++camera_direction_x;
 384                 return true;
 385         } else if(strCmd == "-forward" || strCmd == "+back") {
 386                 --camera_direction_x;
 387                 return true;
 388         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 389                 --camera_direction_y;
 390                 return true;
 391         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 392                 ++camera_direction_y;
 393                 return true;
 394         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 395                 ++camera_direction_z;
 396                 return true;
 397         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 398                 --camera_direction_z;
 399                 return true;
 400         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 401                 ++camera_roll;
 402                 return true;
 403         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 404                 --camera_roll;
 405                 return true;
 406         }
 407
 408         return false;
 409 }
 410
 411 .vector view_ofs;
 412 entity debug_shotorg;
 413 void ShotOrg_Draw()
 414 {
 415         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 416         self.angles = view_angles;
 417         self.angles_x = -self.angles_x;
 418         if not(self.cnt)
 419                 self.drawmask = MASK_NORMAL;
 420         else
 421                 self.drawmask = 0;
 422 }
 423 void ShotOrg_Draw2D()
 424 {
 425         vector coord2d_topleft, coord2d_topright, coord2d;
 426         string s;
 427         vector fs;
 428
 429         s = vtos(self.view_ofs);
 430         s = substring(s, 1, strlen(s) - 2);
 431         if(tokenize_console(s) == 3)
 432                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 433
 434         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 435         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 436
 437         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 438
 439         coord2d = coord2d_topleft;
 440         if(fs_x < 8)
 441         {
 442                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 443                 fs = '8 8 0';
 444         }
 445         coord2d_y -= fs_y;
 446         coord2d_z = 0;
 447         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 448 }
 449
 450 void ShotOrg_Spawn()
 451 {
 452         debug_shotorg = spawn();
 453         debug_shotorg.draw = ShotOrg_Draw;
 454         debug_shotorg.draw2d = ShotOrg_Draw2D;
 455         debug_shotorg.renderflags = RF_VIEWMODEL;
 456         debug_shotorg.effects = EF_FULLBRIGHT;
 457         precache_model("models/shotorg_adjuster.md3");
 458         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 459         debug_shotorg.scale = 2;
 460         debug_shotorg.view_ofs = '25 8 -8';
 461 }
 462
 463 void DrawDebugModel()
 464 {
 465         if(time - floor(time) > 0.5)
 466         {
 467                 PolyDrawModel(self);
 468                 self.drawmask = 0;
 469         }
 470         else
 471         {
 472                 self.renderflags = 0;
 473                 self.drawmask = MASK_NORMAL;
 474         }
 475 }
 476
 477 void GameCommand(string msg)
 478 {
 479         string s;
 480         float argc;
 481         entity e;
 482         argc = tokenize_console(msg);
 483
 484         if(argv(0) == "help" || argc == 0)
 485         {
 486                 print(_("Usage: cl_cmd COMMAND..., where possible commands are:\n"));
 487                 print(_("  settemp cvar value\n"));
 488                 print(_("  scoreboard_columns_set ...\n"));
 489                 print(_("  scoreboard_columns_help\n"));
 490                 GameCommand_Generic("help");
 491                 return;
 492         }
 493
 494         if(GameCommand_Generic(msg))
 495                 return;
 496
 497         string cmd;
 498         cmd = argv(0);
 499         if(cmd == "mv_download") {
 500                 Cmd_MapVote_MapDownload(argc);
 501         }
 502         else if(cmd == "hud_panel_radar_maximized")
 503         {
 504                 if(argc == 1)
 505                         hud_panel_radar_maximized = !hud_panel_radar_maximized;
 506                 else
 507                         hud_panel_radar_maximized = (stof(argv(1)) != 0);
 508         }
 509         else if(cmd == "settemp") {
 510                 cvar_clientsettemp(argv(1), argv(2));
 511         }
 512         else if(cmd == "scoreboard_columns_set") {
 513                 Cmd_HUD_SetFields(argc);
 514         }
 515         else if(cmd == "scoreboard_columns_help") {
 516                 Cmd_HUD_Help(argc);
 517         }
 518 #ifdef BLURTEST
 519         else if(cmd == "blurtest") {
 520                 blurtest_time0 = time;
 521                 blurtest_time1 = time + stof(argv(1));
 522                 blurtest_radius = stof(argv(2));
 523                 blurtest_power = stof(argv(3));
 524         }
 525 #endif
 526         else if(cmd == "shotorg_move") {
 527                 if(!debug_shotorg)
 528                         ShotOrg_Spawn();
 529                 else
 530                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 531                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 532         }
 533         else if(cmd == "shotorg_movez") {
 534                 if(!debug_shotorg)
 535                         ShotOrg_Spawn();
 536                 else
 537                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 538                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 539         }
 540         else if(cmd == "shotorg_set") {
 541                 if(!debug_shotorg)
 542                         ShotOrg_Spawn();
 543                 else
 544                         debug_shotorg.view_ofs = stov(argv(1));
 545                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 546         }
 547         else if(cmd == "shotorg_setz") {
 548                 if(!debug_shotorg)
 549                         ShotOrg_Spawn();
 550                 else
 551                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 552                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 553         }
 554         else if(cmd == "shotorg_toggle_hide") {
 555                 if(debug_shotorg)
 556                 {
 557                         debug_shotorg.cnt = !debug_shotorg.cnt;
 558                 }
 559         }
 560         else if(cmd == "shotorg_end") {
 561                 if(debug_shotorg)
 562                 {
 563                         print(vtos(debug_shotorg.view_ofs), "\n");
 564                         remove(debug_shotorg);
 565                         debug_shotorg = world;
 566                 }
 567                 localcmd("sv_cmd debug_shotorg\n");
 568         }
 569         else if(cmd == "sendcvar") {
 570                 // W_FixWeaponOrder will trash argv, so save what we need.
 571                 string thiscvar;
 572                 thiscvar = strzone(argv(1));
 573                 s = cvar_string(thiscvar);
 574                 if(thiscvar == "cl_weaponpriority")
 575                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 576                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 577                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 578                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 579                 strunzone(thiscvar);
 580         }
 581         else if(cmd == "spawn") {
 582                 s = argv(1);
 583                 e = spawn();
 584                 precache_model(s);
 585                 setmodel(e, s);
 586                 setorigin(e, view_origin);
 587                 e.angles = view_angles;
 588                 e.draw = DrawDebugModel;
 589                 e.classname = "debugmodel";
 590         }
 591     else if(cmd == "vyes")
 592     {
 593         if(uid2name_dialog)
 594         {
 595             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
 596             vote_prev = 0;
 597             localcmd("setreport cl_allow_uid2name 1\n");
 598             vote_change = -9999;
 599                         uid2name_dialog = 0;
 600         }
 601         else
 602         {
 603             localcmd("cmd vote yes\n");
 604         }
 605     }
 606     else if(cmd == "vno")
 607     {
 608         if(uid2name_dialog)
 609         {
 610             vote_active = 0;
 611             vote_prev = 0;
 612             localcmd("setreport cl_allow_uid2name 0\n");
 613             vote_change = -9999;
 614                         uid2name_dialog = 0;
 615         }
 616         else
 617         {
 618             localcmd("cmd vote no\n");
 619         }
 620     }
 621
 622         else
 623         {
 624                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 625         }
 626
 627         return;
 628 }
 629
 630 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 631 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 632 // All keys are in ascii.
 633 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 634 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 635 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 636 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 637 {
 638         float bSkipKey;
 639         bSkipKey = false;
 640
 641         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 642                 return true;
 643
 644         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 645                 return true;
 646
 647         if(menu_visible)
 648                 if(menu_action(bInputType, nPrimary, nSecondary))
 649                         return TRUE;
 650
 651         return bSkipKey;
 652 }
 653
 654 // END REQUIRED CSQC FUNCTIONS
 655 // --------------------------------------------------------------------------
 656
 657 // --------------------------------------------------------------------------
 658 // BEGIN OPTIONAL CSQC FUNCTIONS
 659 void Ent_RemoveEntCS()
 660 {
 661         entcs_receiver[self.sv_entnum] = world;
 662 }
 663 void Ent_ReadEntCS()
 664 {
 665         float sf;
 666         InterpolateOrigin_Undo();
 667
 668         self.classname = "entcs_receiver";
 669         sf = ReadByte();
 670
 671         if(sf & 1)
 672                 self.sv_entnum = ReadByte();
 673         if(sf & 2)
 674         {
 675                 self.origin_x = ReadShort();
 676                 self.origin_y = ReadShort();
 677                 self.origin_z = ReadShort();
 678         }
 679         if(sf & 4)
 680         {
 681                 self.angles_y = ReadByte() * 360.0 / 256;
 682                 self.angles_x = self.angles_z = 0;
 683         }
 684         if(sf & 8)
 685                 self.healthvalue = ReadByte() * 10;
 686         if(sf & 16)
 687                 self.armorvalue = ReadByte() * 10;
 688
 689         entcs_receiver[self.sv_entnum] = self;
 690         self.entremove = Ent_RemoveEntCS;
 691
 692         InterpolateOrigin_Note();
 693 }
 694
 695 void Ent_Remove();
 696
 697 void Ent_RemovePlayerScore()
 698 {
 699         float i;
 700
 701         if(self.owner)
 702         {
 703                 SetTeam(self.owner, -1);
 704                 self.owner.gotscores = 0;
 705                 for(i = 0; i < MAX_SCORE; ++i)
 706                         self.owner.(scores[i]) = 0; // clear all scores
 707         }
 708 }
 709
 710 void Ent_ReadPlayerScore()
 711 {
 712         float i, n;
 713         float isNew;
 714         entity o;
 715
 716         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 717         // (no I've never heard of M-x replace-string, sed, or anything like that)
 718         isNew = !self.owner; // workaround for DP bug
 719         n = ReadByte()-1;
 720
 721 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 722         if(!isNew && n != self.sv_entnum)
 723         {
 724                 //print(_("A CSQC entity changed its owner!\n"));
 725                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 726                 isNew = true;
 727                 Ent_Remove();
 728                 self.enttype = ENT_CLIENT_SCORES;
 729         }
 730 #endif
 731
 732         self.sv_entnum = n;
 733
 734         if not(playerslots[self.sv_entnum])
 735                 playerslots[self.sv_entnum] = spawn();
 736         o = self.owner = playerslots[self.sv_entnum];
 737         o.sv_entnum = self.sv_entnum;
 738         o.gotscores = 1;
 739
 740         //if not(o.sort_prev)
 741         //      RegisterPlayer(o);
 742         //playerchecker will do this for us later, if it has not already done so
 743
 744         float sf, lf;
 745 #if MAX_SCORE <= 8
 746         sf = ReadByte();
 747         lf = ReadByte();
 748 #else
 749         sf = ReadShort();
 750         lf = ReadShort();
 751 #endif
 752         float p;
 753         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 754                 if(sf & p)
 755                 {
 756                         if(lf & p)
 757                                 o.(scores[i]) = ReadInt24_t();
 758                         else
 759                                 o.(scores[i]) = ReadChar();
 760                 }
 761
 762         if(o.sort_prev)
 763                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 764
 765         self.entremove = Ent_RemovePlayerScore;
 766 }
 767
 768 void Ent_ReadTeamScore()
 769 {
 770         float i;
 771         entity o;
 772
 773         self.team = ReadByte();
 774         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 775
 776         float sf, lf;
 777 #if MAX_TEAMSCORE <= 8
 778         sf = ReadByte();
 779         lf = ReadByte();
 780 #else
 781         sf = ReadShort();
 782         lf = ReadShort();
 783 #endif
 784         float p;
 785         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 786                 if(sf & p)
 787                 {
 788                         if(lf & p)
 789                                 o.(teamscores[i]) = ReadInt24_t();
 790                         else
 791                                 o.(teamscores[i]) = ReadChar();
 792                 }
 793
 794         HUD_UpdateTeamPos(o);
 795 }
 796
 797 void Ent_ClientData()
 798 {
 799         float f;
 800         float newspectatee_status;
 801
 802         f = ReadByte();
 803
 804         scoreboard_showscores_force = (f & 1);
 805
 806         if(f & 2)
 807         {
 808                 newspectatee_status = ReadByte();
 809                 if(newspectatee_status == player_localentnum)
 810                         newspectatee_status = -1; // observing
 811         }
 812         else
 813                 newspectatee_status = 0;
 814
 815         spectatorbutton_zoom = (f & 4);
 816
 817         if(f & 8)
 818         {
 819                 angles_held_status = 1;
 820                 angles_held_x = ReadAngle();
 821                 angles_held_y = ReadAngle();
 822                 angles_held_z = 0;
 823         }
 824         else
 825                 angles_held_status = 0;
 826
 827         if(newspectatee_status != spectatee_status)
 828         {
 829                 // clear race stuff
 830                 race_laptime = 0;
 831                 race_checkpointtime = 0;
 832         }
 833         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 834         {
 835                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 836                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 837                 )
 838                         prev_p_health = -1;
 839                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 840                         prev_health = -1;
 841         }
 842         spectatee_status = newspectatee_status;
 843 }
 844
 845 void Ent_Nagger()
 846 {
 847         float nags, i, j, b, f;
 848
 849         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 850
 851         if(!(nags & 4))
 852         {
 853                 if(vote_called_vote)
 854                         strunzone(vote_called_vote);
 855                 vote_called_vote = string_null;
 856                 vote_active = 0;
 857         }
 858         else
 859         {
 860                 vote_active = 1;
 861         }
 862
 863         if(nags & 64)
 864         {
 865                 vote_yescount = ReadByte();
 866                 vote_nocount = ReadByte();
 867                 vote_needed = ReadByte();
 868                 vote_highlighted = ReadChar();
 869         }
 870
 871         if(nags & 128)
 872         {
 873                 if(vote_called_vote)
 874                         strunzone(vote_called_vote);
 875                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 876         }
 877
 878         if(nags & 1)
 879         {
 880                 for(j = 0; j < maxclients; ++j)
 881                         if(playerslots[j])
 882                                 playerslots[j].ready = 1;
 883                 for(i = 1; i <= maxclients; i += 8)
 884                 {
 885                         f = ReadByte();
 886                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 887                                 if not(f & b)
 888                                         if(playerslots[j])
 889                                                 playerslots[j].ready = 0;
 890                 }
 891         }
 892
 893         ready_waiting = (nags & 1);
 894         ready_waiting_for_me = (nags & 2);
 895         vote_waiting = (nags & 4);
 896         vote_waiting_for_me = (nags & 8);
 897         warmup_stage = (nags & 16);
 898 }
 899
 900 void Ent_RandomSeed()
 901 {
 902         float s;
 903         prandom_debug();
 904         s = ReadShort();
 905         psrandom(s);
 906 }
 907
 908 void Ent_ReadAccuracy(void)
 909 {
 910         float sf, f, w, b;
 911         sf = ReadInt24_t();
 912         if(sf == 0)
 913         {
 914                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 915                         weapon_accuracy[w] = -1;
 916                 return;
 917         }
 918
 919         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 920         {
 921                 if(sf & f)
 922                 {
 923                         b = ReadByte();
 924                         if(b == 0)
 925                                 weapon_accuracy[w] = -1;
 926                         else if(b == 255)
 927                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 928                         else
 929                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 930                 }
 931         }
 932 }
 933
 934 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 935 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 936 void Ent_RadarLink();
 937 void Ent_Init();
 938 void Ent_ScoresInfo();
 939 void CSQC_Ent_Update(float bIsNewEntity)
 940 {
 941         float t;
 942         float savetime;
 943         t = ReadByte();
 944
 945         // set up the "time" global for received entities to be correct for interpolation purposes
 946         savetime = time;
 947         if(servertime)
 948         {
 949                 time = servertime;
 950         }
 951         else
 952         {
 953                 serverprevtime = time;
 954                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 955                 time = serverprevtime + serverdeltatime;
 956         }
 957
 958 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 959         if(self.enttype)
 960         {
 961                 if(t != self.enttype || bIsNewEntity)
 962                 {
 963                         //print(_("A CSQC entity changed its type!\n"));
 964                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n"), num_for_edict(self), self.entnum, self.enttype, t));
 965                         Ent_Remove();
 966                         bIsNewEntity = 1;
 967                 }
 968         }
 969         else
 970         {
 971                 if(!bIsNewEntity)
 972                 {
 973                         print(sprintf(_("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n"), num_for_edict(self), self.entnum, t));
 974                         bIsNewEntity = 1;
 975                 }
 976         }
 977 #endif
 978         self.enttype = t;
 979         switch(t)
 980         {
 981                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 982                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 983                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 984                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 985                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 986                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 987                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 988                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 989                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 990                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 991                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 992                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 993                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 994                 case ENT_CLIENT_INIT: Ent_Init(); break;
 995                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 996                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 997                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 998                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 999                 case ENT_CLIENT_WALL: Ent_Wall(); break;
1000                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
1001                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
1002                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
1003                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
1004                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
1005                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
1006                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
1007                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
1008                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
1009                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
1010                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
1011                 case ENT_CLIENT_TURRET: ent_turret(); break;
1012                 case ENT_CLIENT_MODEL: CSQCModel_Read(); break;
1013                 default:
1014                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
1015                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
1016                         break;
1017         }
1018
1019         time = savetime;
1020 }
1021 // Destructor, but does NOT deallocate the entity by calling remove(). Also
1022 // used when an entity changes its type. For an entity that someone interacts
1023 // with others, make sure it can no longer do so.
1024 void Ent_Remove()
1025 {
1026         if(self.entremove)
1027                 self.entremove();
1028
1029         self.enttype = 0;
1030         self.classname = "";
1031         self.draw = menu_sub_null;
1032         self.entremove = menu_sub_null;
1033         // TODO possibly set more stuff to defaults
1034 }
1035 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
1036 void CSQC_Ent_Remove()
1037 {
1038         if(self.enttype)
1039                 Ent_Remove();
1040         remove(self);
1041 }
1042
1043 void Gamemode_Init()
1044 {
1045         if not(isdemo())
1046         {
1047                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
1048                 calledhooks |= HOOK_START;
1049         }
1050 }
1051 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1052 void CSQC_Parse_StuffCmd(string strMessage)
1053 {
1054         localcmd(strMessage);
1055 }
1056 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1057 void CSQC_Parse_Print(string strMessage)
1058 {
1059         print(ColorTranslateRGB(strMessage));
1060 }
1061
1062 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
1063 void CSQC_Parse_CenterPrint(string strMessage)
1064 {
1065         centerprint_hud(strMessage);
1066 }
1067
1068 string notranslate_fogcmd1 = "\nfog ";
1069 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1070 void Fog_Force()
1071 {
1072         // TODO somehow thwart prvm_globalset client ...
1073
1074         if(forcefog != "")
1075                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1076 }
1077
1078 void Gamemode_Init();
1079 void Ent_ScoresInfo()
1080 {
1081         float i;
1082         self.classname = "ent_client_scores_info";
1083         gametype = ReadByte();
1084         for(i = 0; i < MAX_SCORE; ++i)
1085         {
1086                 scores_label[i] = strzone(ReadString());
1087                 scores_flags[i] = ReadByte();
1088         }
1089         for(i = 0; i < MAX_TEAMSCORE; ++i)
1090         {
1091                 teamscores_label[i] = strzone(ReadString());
1092                 teamscores_flags[i] = ReadByte();
1093         }
1094         HUD_InitScores();
1095         Gamemode_Init();
1096 }
1097
1098 void Ent_Init()
1099 {
1100         self.classname = "ent_client_init";
1101
1102         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1103
1104         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1105         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1106         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1107         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1108         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1109         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1110         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1111         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1112         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1113         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1114         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1115         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1116
1117         if(forcefog)
1118                 strunzone(forcefog);
1119         forcefog = strzone(ReadString());
1120
1121         armorblockpercent = ReadByte() / 255.0;
1122
1123         g_weaponswitchdelay = ReadByte() / 255.0;
1124
1125         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1126         g_balance_grenadelauncher_bouncestop = ReadCoord();
1127         g_balance_electro_secondary_bouncefactor = ReadCoord();
1128         g_balance_electro_secondary_bouncestop = ReadCoord();
1129
1130         nex_scope = !ReadByte();
1131         rifle_scope = !ReadByte();
1132
1133         serverflags = ReadByte();
1134
1135         minelayer_maxmines = ReadByte();
1136
1137         hagar_maxrockets = ReadByte();
1138
1139         g_trueaim_minrange = ReadCoord();
1140
1141         if(!postinit)
1142                 PostInit();
1143 }
1144
1145 void Net_ReadRace()
1146 {
1147         float b;
1148
1149         b = ReadByte();
1150
1151         switch(b)
1152         {
1153                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1154                         race_checkpoint = ReadByte();
1155                         race_time = ReadInt24_t();
1156                         race_previousbesttime = ReadInt24_t();
1157                         if(race_previousbestname)
1158                                 strunzone(race_previousbestname);
1159                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1160
1161                         race_checkpointtime = time;
1162
1163                         if(race_checkpoint == 0 || race_checkpoint == 254)
1164                         {
1165                                 race_penaltyaccumulator = 0;
1166                                 race_laptime = time; // valid
1167                         }
1168
1169                         break;
1170
1171                 case RACE_NET_CHECKPOINT_CLEAR:
1172                         race_laptime = 0;
1173                         race_checkpointtime = 0;
1174                         break;
1175
1176                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1177                         race_laptime = ReadCoord();
1178                         race_checkpointtime = -99999;
1179                         // fall through
1180                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1181                         race_nextcheckpoint = ReadByte();
1182
1183                         race_nextbesttime = ReadInt24_t();
1184                         if(race_nextbestname)
1185                                 strunzone(race_nextbestname);
1186                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1187                         break;
1188
1189                 case RACE_NET_CHECKPOINT_HIT_RACE:
1190                         race_mycheckpoint = ReadByte();
1191                         race_mycheckpointtime = time;
1192                         race_mycheckpointdelta = ReadInt24_t();
1193                         race_mycheckpointlapsdelta = ReadByte();
1194                         if(race_mycheckpointlapsdelta >= 128)
1195                                 race_mycheckpointlapsdelta -= 256;
1196                         if(race_mycheckpointenemy)
1197                                 strunzone(race_mycheckpointenemy);
1198                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1199                         break;
1200
1201                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1202                         race_othercheckpoint = ReadByte();
1203                         race_othercheckpointtime = time;
1204                         race_othercheckpointdelta = ReadInt24_t();
1205                         race_othercheckpointlapsdelta = ReadByte();
1206                         if(race_othercheckpointlapsdelta >= 128)
1207                                 race_othercheckpointlapsdelta -= 256;
1208                         if(race_othercheckpointenemy)
1209                                 strunzone(race_othercheckpointenemy);
1210                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1211                         break;
1212
1213                 case RACE_NET_PENALTY_RACE:
1214                         race_penaltyeventtime = time;
1215                         race_penaltytime = ReadShort();
1216                         //race_penaltyaccumulator += race_penaltytime;
1217                         if(race_penaltyreason)
1218                                 strunzone(race_penaltyreason);
1219                         race_penaltyreason = strzone(ReadString());
1220                         break;
1221
1222                 case RACE_NET_PENALTY_QUALIFYING:
1223                         race_penaltyeventtime = time;
1224                         race_penaltytime = ReadShort();
1225                         race_penaltyaccumulator += race_penaltytime;
1226                         if(race_penaltyreason)
1227                                 strunzone(race_penaltyreason);
1228                         race_penaltyreason = strzone(ReadString());
1229                         break;
1230
1231                 case RACE_NET_SERVER_RECORD:
1232                         race_server_record = ReadInt24_t();
1233                         break;
1234                 case RACE_NET_SPEED_AWARD:
1235                         race_speedaward = ReadInt24_t();
1236                         if(race_speedaward_holder)
1237                                 strunzone(race_speedaward_holder);
1238                         race_speedaward_holder = strzone(ReadString());
1239                         break;
1240                 case RACE_NET_SPEED_AWARD_BEST:
1241                         race_speedaward_alltimebest = ReadInt24_t();
1242                         if(race_speedaward_alltimebest_holder)
1243                                 strunzone(race_speedaward_alltimebest_holder);
1244                         race_speedaward_alltimebest_holder = strzone(ReadString());
1245                         break;
1246                 case RACE_NET_SERVER_RANKINGS:
1247                         float pos, prevpos, del;
1248                         pos = ReadShort();
1249                         prevpos = ReadShort();
1250                         del = ReadShort();
1251
1252                         // move other rankings out of the way
1253                         float i;
1254                         if (prevpos) {
1255                                 for (i=prevpos-1;i>pos-1;--i) {
1256                                         grecordtime[i] = grecordtime[i-1];
1257                                         if(grecordholder[i])
1258                                                 strunzone(grecordholder[i]);
1259                                         grecordholder[i] = strzone(grecordholder[i-1]);
1260                                 }
1261                         } else if (del) { // a record has been deleted by the admin
1262                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1263                                         if (i == RANKINGS_CNT-1) { // clear out last record
1264                                                 grecordtime[i] = 0;
1265                                                 if (grecordholder[i])
1266                                                         strunzone(grecordholder[i]);
1267                                                 grecordholder[i] = string_null;
1268                                         }
1269                                         else {
1270                                                 grecordtime[i] = grecordtime[i+1];
1271                                                 if (grecordholder[i])
1272                                                         strunzone(grecordholder[i]);
1273                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1274                                         }
1275                                 }
1276                         } else { // player has no ranked record yet
1277                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1278                                         grecordtime[i] = grecordtime[i-1];
1279                                         if(grecordholder[i])
1280                                                 strunzone(grecordholder[i]);
1281                                         grecordholder[i] = strzone(grecordholder[i-1]);
1282                                 }
1283                         }
1284
1285                         // store new ranking
1286                         if(grecordholder[pos-1] != "")
1287                                 strunzone(grecordholder[pos-1]);
1288                         grecordholder[pos-1] = strzone(ReadString());
1289                         grecordtime[pos-1] = ReadInt24_t();
1290                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1291                                 race_myrank = pos;
1292                         break;
1293                 case RACE_NET_SERVER_STATUS:
1294                         race_status = ReadShort();
1295                         if(race_status_name)
1296                                 strunzone(race_status_name);
1297                         race_status_name = strzone(ReadString());
1298         }
1299 }
1300
1301 void Net_ReadSpawn()
1302 {
1303         zoomin_effect = 1;
1304         current_viewzoom = 0.6;
1305 }
1306
1307 void Net_TeamNagger()
1308 {
1309         teamnagger = 1;
1310 }
1311
1312 void Net_ReadPingPLReport()
1313 {
1314         float e, pi, pl, ml;
1315         e = ReadByte();
1316         pi = ReadShort();
1317         pl = ReadByte();
1318         ml = ReadByte();
1319         if not(playerslots[e])
1320                 return;
1321         playerslots[e].ping = pi;
1322         playerslots[e].ping_packetloss = pl / 255.0;
1323         playerslots[e].ping_movementloss = ml / 255.0;
1324 }
1325
1326 void Net_WeaponComplain() {
1327         complain_weapon = ReadByte();
1328
1329         if(complain_weapon_name)
1330                 strunzone(complain_weapon_name);
1331         complain_weapon_name = strzone(ReadString());
1332
1333         complain_weapon_type = ReadByte();
1334
1335         complain_weapon_time = time;
1336         weapontime = time; // ping the weapon panel
1337 }
1338
1339 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1340 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1341 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1342 float CSQC_Parse_TempEntity()
1343 {
1344         float bHandled;
1345                 bHandled  = true;
1346         // Acquire TE ID
1347         float nTEID;
1348                 nTEID = ReadByte();
1349
1350                 // NOTE: Could just do return instead of break...
1351         switch(nTEID)
1352         {
1353                 case TE_CSQC_TARGET_MUSIC:
1354                         Net_TargetMusic();
1355                         bHandled = true;
1356                         break;
1357                 case TE_CSQC_PICTURE:
1358                         Net_MapVote_Picture();
1359                         bHandled = true;
1360                         break;
1361                 case TE_CSQC_RACE:
1362                         Net_ReadRace();
1363                         bHandled = true;
1364                         break;
1365                 case TE_CSQC_SPAWN:
1366                         Net_ReadSpawn();
1367                         bHandled = true;
1368                         break;
1369                 case TE_CSQC_ZCURVEPARTICLES:
1370                         Net_ReadZCurveParticles();
1371                         bHandled = true;
1372                         break;
1373                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1374                         Net_ReadNexgunBeamParticle();
1375                         bHandled = true;
1376                         break;
1377                 case TE_CSQC_TEAMNAGGER:
1378                         Net_TeamNagger();
1379                         bHandled = true;
1380                         break;
1381                 case TE_CSQC_LIGHTNINGARC:
1382                         Net_ReadLightningarc();
1383                         bHandled = true;
1384                         break;
1385                 case TE_CSQC_PINGPLREPORT:
1386                         Net_ReadPingPLReport();
1387                         bHandled = true;
1388                         break;
1389                 case TE_CSQC_ANNOUNCE:
1390                         Announcer_Play(ReadString());
1391                         bHandled = true;
1392                         break;
1393                 case TE_CSQC_KILLNOTIFY:
1394                         HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1395                         bHandled = true;
1396                         break;
1397                 case TE_CSQC_KILLCENTERPRINT:
1398                         HUD_KillCenterprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1399                         bHandled = true;
1400                         break;
1401                 case TE_CSQC_CENTERPRINT_GENERIC:
1402                         float id;
1403                         string s;
1404                         id = ReadByte();
1405                         s = ReadString();
1406                         if (id != 0 && s != "")
1407                                 centerprint_generic(id, s, ReadByte(), ReadByte());
1408                         else
1409                                 centerprint_generic(id, s, 0, 0);
1410                         bHandled = true;
1411                         break;
1412                 case TE_CSQC_WEAPONCOMPLAIN:
1413                         Net_WeaponComplain();
1414                         bHandled = true;
1415                         break;
1416                 case TE_CSQC_VEHICLESETUP:
1417                         Net_VehicleSetup();
1418                         bHandled = true;
1419                         break;
1420                 default:
1421                         // No special logic for this temporary entity; return 0 so the engine can handle it
1422                         bHandled = false;
1423                         break;
1424         }
1425
1426         return bHandled;
1427 }
1428
1429 string getcommandkey(string text, string command)
1430 {
1431         string keys;
1432         float n, j, k, l;
1433
1434         if (!autocvar_hud_showbinds)
1435                 return text;
1436
1437         keys = db_get(binddb, command);
1438         if (!keys)
1439         {
1440                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1441                 for(j = 0; j < n; ++j)
1442                 {
1443                         k = stof(argv(j));
1444                         if(k != -1)
1445                         {
1446                                 if ("" == keys)
1447                                         keys = keynumtostring(k);
1448                                 else
1449                                         keys = strcat(keys, ", ", keynumtostring(k));
1450
1451                                 ++l;
1452                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1453                         }
1454
1455                 }
1456                 db_put(binddb, command, keys);
1457         }
1458
1459         if ("" == keys) {
1460                 if (autocvar_hud_showbinds > 1)
1461                         return sprintf(_("%s (not bound)"), text);
1462                 else
1463                         return text;
1464         }
1465         else if (autocvar_hud_showbinds > 1)
1466                 return sprintf(_("%s (%s)"), text, keys);
1467         else
1468                 return keys;
1469 }