qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49         prvm_language = cvar_string("prvm_language");
  50
  51 #ifdef USE_FTE
  52 #pragma target ID
  53         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  54         if(!__engine_check)
  55         {
  56                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  57                 localcmd("\ndisconnect\n");
  58                 return;
  59         }
  60 #pragma target FTE
  61 #endif
  62
  63         check_unacceptable_compiler_bugs();
  64
  65 #ifdef WATERMARK
  66         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK()));
  67 #endif
  68
  69         float i;
  70
  71         binddb = db_create();
  72         tempdb = db_create();
  73         ClientProgsDB = db_load("client.db");
  74         compressShortVector_init();
  75
  76         drawfont = FONT_USER+1;
  77         menu_visible = FALSE;
  78         menu_show = menu_show_error;
  79         menu_action = menu_sub_null;
  80
  81         for(i = 0; i < 255; ++i)
  82                 if(getplayerkey(i, "viewentity") == "")
  83                         break;
  84         maxclients = i;
  85
  86         //ctf_temp_1 = "";
  87         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  88         //registercmd("ctf_menu");
  89         registercmd("ons_map");
  90         registercmd("hud_configure");
  91         registercmd("hud_save");
  92         //registercmd("menu_action");
  93
  94         registercmd("+showscores");registercmd("-showscores");
  95         registercmd("+showaccuracy");registercmd("-showaccuracy");
  96
  97 #ifndef CAMERATEST
  98         if(isdemo())
  99         {
 100 #endif
 101                 registercmd("+forward");registercmd("-forward");
 102                 registercmd("+back");registercmd("-back");
 103                 registercmd("+moveup");registercmd("-moveup");
 104                 registercmd("+movedown");registercmd("-movedown");
 105                 registercmd("+moveright");registercmd("-moveright");
 106                 registercmd("+moveleft");registercmd("-moveleft");
 107                 registercmd("+roll_right");registercmd("-roll_right");
 108                 registercmd("+roll_left");registercmd("-roll_left");
 109 #ifndef CAMERATEST
 110         }
 111 #endif
 112         registercvar("hud_usecsqc", "1");
 113         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 114
 115         gametype = 0;
 116
 117         // hud_fields uses strunzone on the titles!
 118         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 119                 hud_title[i] = strzone("(null)");
 120
 121         postinit = false;
 122
 123         calledhooks = 0;
 124
 125         teams = Sort_Spawn();
 126         players = Sort_Spawn();
 127
 128         GetTeam(COLOR_SPECTATOR, true); // add specs first
 129
 130         RegisterWeapons();
 131
 132         WaypointSprite_Load();
 133
 134         // precaches
 135         precache_sound("misc/hit.wav");
 136         precache_sound("misc/typehit.wav");
 137         Projectile_Precache();
 138         Hook_Precache();
 139         GibSplash_Precache();
 140         Casings_Precache();
 141         DamageInfo_Precache();
 142         Vehicles_Precache();
 143
 144         if(autocvar_cl_announcer != cl_announcer_prev) {
 145                 Announcer_Precache();
 146                 if(cl_announcer_prev)
 147                         strunzone(cl_announcer_prev);
 148                 cl_announcer_prev = strzone(autocvar_cl_announcer);
 149         }
 150         Tuba_Precache();
 151
 152         if(autocvar_cl_reticle_item_normal) precache_pic("gfx/reticle_normal");
 153         if(autocvar_cl_reticle_item_nex) precache_pic("gfx/reticle_nex");
 154
 155         get_mi_min_max_texcoords(1); // try the CLEVER way first
 156         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 157         shortmapname = mi_shortname;
 158
 159         if(precache_pic(minimapname) == "")
 160         {
 161                 // but maybe we have a non-clever minimap
 162                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 163                 if(precache_pic(minimapname) == "")
 164                         minimapname = ""; // FAIL
 165                 else
 166                         get_mi_min_max_texcoords(0); // load new texcoords
 167         }
 168
 169         mi_center = (mi_min + mi_max) * 0.5;
 170         mi_scale = mi_max - mi_min;
 171         minimapname = strzone(minimapname);
 172
 173         WarpZone_Init();
 174
 175         hud_configure_prev = -1;
 176         tab_panel = -1;
 177 }
 178
 179 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 180 void CSQC_Shutdown(void)
 181 {
 182 #ifdef USE_FTE
 183 #pragma TARGET id
 184         if(!__engine_check)
 185                 return 0;
 186 #pragma TARGET fte
 187 #endif
 188
 189         WarpZone_Shutdown();
 190
 191         remove(teams);
 192         remove(players);
 193         db_close(binddb);
 194         db_close(tempdb);
 195         if(autocvar_cl_db_saveasdump)
 196                 db_dump(ClientProgsDB, "client.db");
 197         else
 198                 db_save(ClientProgsDB, "client.db");
 199         db_close(ClientProgsDB);
 200
 201         cvar_clientsettemp_restore();
 202
 203         if(camera_active)
 204                 cvar_set("chase_active",ftos(chase_active_backup));
 205
 206         // unset the event chasecam's chase_active
 207         if(autocvar_chase_active < 0)
 208                 cvar_set("chase_active", "0");
 209
 210         if not(isdemo())
 211         {
 212                 if not(calledhooks & HOOK_START)
 213                         localcmd("\n_cl_hook_gamestart nop\n");
 214                 if not(calledhooks & HOOK_END)
 215                         localcmd("\ncl_hook_gameend\n");
 216         }
 217 }
 218
 219 .float has_team;
 220 float SetTeam(entity o, float Team)
 221 {
 222         entity tm;
 223         if(teamplay)
 224         {
 225                 switch(Team)
 226                 {
 227                         case -1:
 228                         case COLOR_TEAM1:
 229                         case COLOR_TEAM2:
 230                         case COLOR_TEAM3:
 231                         case COLOR_TEAM4:
 232                                 break;
 233                         default:
 234                                 if(GetTeam(Team, false) == NULL)
 235                                 {
 236                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 237                                         Team = COLOR_SPECTATOR;
 238                                 }
 239                                 break;
 240                 }
 241         }
 242         else
 243         {
 244                 switch(Team)
 245                 {
 246                         case -1:
 247                         case 0:
 248                                 break;
 249                         default:
 250                                 if(GetTeam(Team, false) == NULL)
 251                                 {
 252                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 253                                         Team = COLOR_SPECTATOR;
 254                                 }
 255                                 break;
 256                 }
 257         }
 258         if(Team == -1) // leave
 259         {
 260                 if(o.has_team)
 261                 {
 262                         tm = GetTeam(o.team, false);
 263                         tm.team_size -= 1;
 264                         o.has_team = 0;
 265                         return TRUE;
 266                 }
 267         }
 268         else
 269         {
 270                 if not(o.has_team)
 271                 {
 272                         o.team = Team;
 273                         tm = GetTeam(Team, true);
 274                         tm.team_size += 1;
 275                         o.has_team = 1;
 276                         return TRUE;
 277                 }
 278                 else if(Team != o.team)
 279                 {
 280                         tm = GetTeam(o.team, false);
 281                         tm.team_size -= 1;
 282                         o.team = Team;
 283                         tm = GetTeam(Team, true);
 284                         tm.team_size += 1;
 285                         return TRUE;
 286                 }
 287         }
 288         return FALSE;
 289 }
 290
 291 void Playerchecker_Think()
 292 {
 293         float i;
 294         entity e;
 295         for(i = 0; i < maxclients; ++i)
 296         {
 297                 e = playerslots[i];
 298                 if(GetPlayerName(i) == "")
 299                 {
 300                         if(e.sort_prev)
 301                         {
 302                                 // player disconnected
 303                                 SetTeam(e, -1);
 304                                 RemovePlayer(e);
 305                                 e.sort_prev = world;
 306                                 //e.gotscores = 0;
 307                         }
 308                 }
 309                 else
 310                 {
 311                         if not(e.sort_prev)
 312                         {
 313                                 // player connected
 314                                 if not(e)
 315                                         playerslots[i] = e = spawn();
 316                                 e.sv_entnum = i;
 317                                 e.ping = 0;
 318                                 e.ping_packetloss = 0;
 319                                 e.ping_movementloss = 0;
 320                                 //e.gotscores = 0; // we might already have the scores...
 321                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 322                                 RegisterPlayer(e);
 323                                 HUD_UpdatePlayerPos(e);
 324                         }
 325                 }
 326         }
 327         self.nextthink = time + 0.2;
 328 }
 329
 330 void Porto_Init();
 331 void TrueAim_Init();
 332 void PostInit(void)
 333 {
 334         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 335
 336         entity playerchecker;
 337         playerchecker = spawn();
 338         playerchecker.think = Playerchecker_Think;
 339         playerchecker.nextthink = time + 0.2;
 340
 341         Porto_Init();
 342         TrueAim_Init();
 343
 344         postinit = true;
 345 }
 346
 347 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 348 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 349 float button_zoom;
 350 void Cmd_HUD_SetFields(float);
 351 void Cmd_HUD_Help(float);
 352 float CSQC_ConsoleCommand(string strMessage)
 353 {
 354         float argc;
 355         // Tokenize String
 356         //argc = tokenize(strMessage);
 357         argc = tokenize_console(strMessage);
 358
 359         // Acquire Command
 360         local string strCmd;
 361         strCmd = argv(0);
 362
 363         if(strCmd == "hud_configure") { // config hud
 364                 cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 365                 return true;
 366         } else if(strCmd == "hud_save") { // save hud config
 367                 if(argv(1) == "" || argv(2)) {
 368                         print(_("Usage:\n"));
 369                         print(_("hud_save configname   (saves to hud_skinname_configname.cfg)\n"));
 370                 }
 371                 else
 372                         HUD_Panel_ExportCfg(argv(1));
 373                 return true;
 374         } else if(strCmd == "+showscores") {
 375                 scoreboard_showscores = true;
 376                 return true;
 377         } else if(strCmd == "-showscores") {
 378                 scoreboard_showscores = false;
 379                 return true;
 380         } else if(strCmd == "+showaccuracy") {
 381                 scoreboard_showaccuracy = true;
 382                 return true;
 383         } else if(strCmd == "-showaccuracy") {
 384                 scoreboard_showaccuracy = false;
 385                 return true;
 386         }
 387
 388         if(camera_active)
 389         if(strCmd == "+forward" || strCmd == "-back") {
 390                 ++camera_direction_x;
 391                 return true;
 392         } else if(strCmd == "-forward" || strCmd == "+back") {
 393                 --camera_direction_x;
 394                 return true;
 395         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 396                 --camera_direction_y;
 397                 return true;
 398         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 399                 ++camera_direction_y;
 400                 return true;
 401         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 402                 ++camera_direction_z;
 403                 return true;
 404         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 405                 --camera_direction_z;
 406                 return true;
 407         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 408                 ++camera_roll;
 409                 return true;
 410         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 411                 --camera_roll;
 412                 return true;
 413         }
 414
 415         return false;
 416 }
 417
 418 .vector view_ofs;
 419 entity debug_shotorg;
 420 void ShotOrg_Draw()
 421 {
 422         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 423         self.angles = view_angles;
 424         self.angles_x = -self.angles_x;
 425         if not(self.cnt)
 426                 self.drawmask = MASK_NORMAL;
 427         else
 428                 self.drawmask = 0;
 429 }
 430 void ShotOrg_Draw2D()
 431 {
 432         vector coord2d_topleft, coord2d_topright, coord2d;
 433         string s;
 434         vector fs;
 435
 436         s = vtos(self.view_ofs);
 437         s = substring(s, 1, strlen(s) - 2);
 438         if(tokenize_console(s) == 3)
 439                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 440
 441         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 442         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 443
 444         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 445
 446         coord2d = coord2d_topleft;
 447         if(fs_x < 8)
 448         {
 449                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 450                 fs = '8 8 0';
 451         }
 452         coord2d_y -= fs_y;
 453         coord2d_z = 0;
 454         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 455 }
 456
 457 void ShotOrg_Spawn()
 458 {
 459         debug_shotorg = spawn();
 460         debug_shotorg.draw = ShotOrg_Draw;
 461         debug_shotorg.draw2d = ShotOrg_Draw2D;
 462         debug_shotorg.renderflags = RF_VIEWMODEL;
 463         debug_shotorg.effects = EF_FULLBRIGHT;
 464         precache_model("models/shotorg_adjuster.md3");
 465         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 466         debug_shotorg.scale = 2;
 467         debug_shotorg.view_ofs = '25 8 -8';
 468 }
 469
 470 void DrawDebugModel()
 471 {
 472         if(time - floor(time) > 0.5)
 473         {
 474                 PolyDrawModel(self);
 475                 self.drawmask = 0;
 476         }
 477         else
 478         {
 479                 self.renderflags = 0;
 480                 self.drawmask = MASK_NORMAL;
 481         }
 482 }
 483
 484 void GameCommand(string msg)
 485 {
 486         string s;
 487         float argc;
 488         entity e;
 489         argc = tokenize_console(msg);
 490
 491         if(argv(0) == "help" || argc == 0)
 492         {
 493                 print(_("Usage: cl_cmd COMMAND..., where possible commands are:\n"));
 494                 print(_("  settemp cvar value\n"));
 495                 print(_("  scoreboard_columns_set ...\n"));
 496                 print(_("  scoreboard_columns_help\n"));
 497                 GameCommand_Generic("help");
 498                 return;
 499         }
 500
 501         if(GameCommand_Generic(msg))
 502                 return;
 503
 504         string cmd;
 505         cmd = argv(0);
 506         if(cmd == "mv_download") {
 507                 Cmd_MapVote_MapDownload(argc);
 508         }
 509         else if(cmd == "settemp") {
 510                 cvar_clientsettemp(argv(1), argv(2));
 511         }
 512         else if(cmd == "scoreboard_columns_set") {
 513                 Cmd_HUD_SetFields(argc);
 514         }
 515         else if(cmd == "scoreboard_columns_help") {
 516                 Cmd_HUD_Help(argc);
 517         }
 518 #ifdef BLURTEST
 519         else if(cmd == "blurtest") {
 520                 blurtest_time0 = time;
 521                 blurtest_time1 = time + stof(argv(1));
 522                 blurtest_radius = stof(argv(2));
 523                 blurtest_power = stof(argv(3));
 524         }
 525 #endif
 526         else if(cmd == "shotorg_move") {
 527                 if(!debug_shotorg)
 528                         ShotOrg_Spawn();
 529                 else
 530                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 531                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 532         }
 533         else if(cmd == "shotorg_movez") {
 534                 if(!debug_shotorg)
 535                         ShotOrg_Spawn();
 536                 else
 537                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 538                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 539         }
 540         else if(cmd == "shotorg_set") {
 541                 if(!debug_shotorg)
 542                         ShotOrg_Spawn();
 543                 else
 544                         debug_shotorg.view_ofs = stov(argv(1));
 545                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 546         }
 547         else if(cmd == "shotorg_setz") {
 548                 if(!debug_shotorg)
 549                         ShotOrg_Spawn();
 550                 else
 551                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 552                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 553         }
 554         else if(cmd == "shotorg_toggle_hide") {
 555                 if(debug_shotorg)
 556                 {
 557                         debug_shotorg.cnt = !debug_shotorg.cnt;
 558                 }
 559         }
 560         else if(cmd == "shotorg_end") {
 561                 if(debug_shotorg)
 562                 {
 563                         print(vtos(debug_shotorg.view_ofs), "\n");
 564                         remove(debug_shotorg);
 565                         debug_shotorg = world;
 566                 }
 567                 localcmd("sv_cmd debug_shotorg\n");
 568         }
 569         else if(cmd == "sendcvar") {
 570                 // W_FixWeaponOrder will trash argv, so save what we need.
 571                 string thiscvar;
 572                 thiscvar = strzone(argv(1));
 573                 s = cvar_string(thiscvar);
 574                 if(thiscvar == "cl_weaponpriority")
 575                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 576                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 577                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 578                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 579                 strunzone(thiscvar);
 580         }
 581         else if(cmd == "spawn") {
 582                 s = argv(1);
 583                 e = spawn();
 584                 precache_model(s);
 585                 setmodel(e, s);
 586                 setorigin(e, view_origin);
 587                 e.angles = view_angles;
 588                 e.draw = DrawDebugModel;
 589                 e.classname = "debugmodel";
 590         }
 591     else if(cmd == "vyes")
 592     {
 593         if(uid2name_dialog)
 594         {
 595             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
 596             vote_prev = 0;
 597             cvar_set("cl_allow_uid2name", "1");
 598             vote_change = -9999;
 599                         uid2name_dialog = 0;
 600         }
 601         else
 602         {
 603             localcmd("cmd vote yes\n");
 604         }
 605     }
 606     else if(cmd == "vno")
 607     {
 608         if(uid2name_dialog)
 609         {
 610             vote_active = 0;
 611             vote_prev = 0;
 612             cvar_set("cl_allow_uid2name", "0");
 613             vote_change = -9999;
 614                         uid2name_dialog = 0;
 615         }
 616         else
 617         {
 618             localcmd("cmd vote no\n");
 619         }
 620     }
 621
 622         else
 623         {
 624                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 625         }
 626
 627         return;
 628 }
 629
 630 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 631 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 632 // All keys are in ascii.
 633 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 634 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 635 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 636 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 637 {
 638         local float bSkipKey;
 639         bSkipKey = false;
 640
 641         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 642                 return true;
 643
 644         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 645                 return true;
 646
 647         if(menu_visible)
 648                 if(menu_action(bInputType, nPrimary, nSecondary))
 649                         return TRUE;
 650
 651         return bSkipKey;
 652 }
 653
 654 // END REQUIRED CSQC FUNCTIONS
 655 // --------------------------------------------------------------------------
 656
 657 // --------------------------------------------------------------------------
 658 // BEGIN OPTIONAL CSQC FUNCTIONS
 659 void Ent_RemoveEntCS()
 660 {
 661         entcs_receiver[self.sv_entnum] = world;
 662 }
 663 void Ent_ReadEntCS()
 664 {
 665         float sf;
 666         InterpolateOrigin_Undo();
 667
 668         self.classname = "entcs_receiver";
 669         sf = ReadByte();
 670
 671         if(sf & 1)
 672                 self.sv_entnum = ReadByte();
 673         if(sf & 2)
 674         {
 675                 self.origin_x = ReadShort();
 676                 self.origin_y = ReadShort();
 677                 self.origin_z = ReadShort();
 678         }
 679         if(sf & 4)
 680         {
 681                 self.angles_y = ReadByte() * 360.0 / 256;
 682                 self.angles_x = self.angles_z = 0;
 683         }
 684         if(sf & 8)
 685                 self.healthvalue = ReadByte() * 10;
 686         if(sf & 16)
 687                 self.armorvalue = ReadByte() * 10;
 688
 689         entcs_receiver[self.sv_entnum] = self;
 690         self.entremove = Ent_RemoveEntCS;
 691
 692         InterpolateOrigin_Note();
 693 }
 694
 695 void Ent_Remove();
 696
 697 void Ent_RemovePlayerScore()
 698 {
 699         float i;
 700
 701         if(self.owner)
 702         {
 703                 SetTeam(self.owner, -1);
 704                 self.owner.gotscores = 0;
 705                 for(i = 0; i < MAX_SCORE; ++i)
 706                         self.owner.(scores[i]) = 0; // clear all scores
 707         }
 708 }
 709
 710 void Ent_ReadPlayerScore()
 711 {
 712         float i, n;
 713         float isNew;
 714         entity o;
 715
 716         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 717         // (no I've never heard of M-x replace-string, sed, or anything like that)
 718         isNew = !self.owner; // workaround for DP bug
 719         n = ReadByte()-1;
 720
 721 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 722         if(!isNew && n != self.sv_entnum)
 723         {
 724                 //print(_("A CSQC entity changed its owner!\n"));
 725                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 726                 isNew = true;
 727                 Ent_Remove();
 728                 self.enttype = ENT_CLIENT_SCORES;
 729         }
 730 #endif
 731
 732         self.sv_entnum = n;
 733
 734         if not(playerslots[self.sv_entnum])
 735                 playerslots[self.sv_entnum] = spawn();
 736         o = self.owner = playerslots[self.sv_entnum];
 737         o.sv_entnum = self.sv_entnum;
 738         o.gotscores = 1;
 739
 740         //if not(o.sort_prev)
 741         //      RegisterPlayer(o);
 742         //playerchecker will do this for us later, if it has not already done so
 743
 744         float sf, lf;
 745 #if MAX_SCORE <= 8
 746         sf = ReadByte();
 747         lf = ReadByte();
 748 #else
 749         sf = ReadShort();
 750         lf = ReadShort();
 751 #endif
 752         float p;
 753         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 754                 if(sf & p)
 755                 {
 756                         if(lf & p)
 757                                 o.(scores[i]) = ReadInt24_t();
 758                         else
 759                                 o.(scores[i]) = ReadChar();
 760                 }
 761
 762         if(o.sort_prev)
 763                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 764
 765         self.entremove = Ent_RemovePlayerScore;
 766 }
 767
 768 void Ent_ReadTeamScore()
 769 {
 770         float i;
 771         entity o;
 772
 773         self.team = ReadByte();
 774         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 775
 776         float sf, lf;
 777 #if MAX_TEAMSCORE <= 8
 778         sf = ReadByte();
 779         lf = ReadByte();
 780 #else
 781         sf = ReadShort();
 782         lf = ReadShort();
 783 #endif
 784         float p;
 785         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 786                 if(sf & p)
 787                 {
 788                         if(lf & p)
 789                                 o.(teamscores[i]) = ReadInt24_t();
 790                         else
 791                                 o.(teamscores[i]) = ReadChar();
 792                 }
 793
 794         HUD_UpdateTeamPos(o);
 795 }
 796
 797 void Ent_ClientData()
 798 {
 799         float f;
 800         float newspectatee_status;
 801
 802         f = ReadByte();
 803
 804         scoreboard_showscores_force = (f & 1);
 805
 806         if(f & 2)
 807         {
 808                 newspectatee_status = ReadByte();
 809                 if(newspectatee_status == player_localentnum)
 810                         newspectatee_status = -1; // observing
 811         }
 812         else
 813                 newspectatee_status = 0;
 814
 815         spectatorbutton_zoom = (f & 4);
 816
 817         if(f & 8)
 818         {
 819                 angles_held_status = 1;
 820                 angles_held_x = ReadAngle();
 821                 angles_held_y = ReadAngle();
 822                 angles_held_z = 0;
 823         }
 824         else
 825                 angles_held_status = 0;
 826
 827         if(newspectatee_status != spectatee_status)
 828         {
 829                 float i;
 830
 831                 // clear race stuff
 832                 race_laptime = 0;
 833                 race_checkpointtime = 0;
 834         }
 835         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 836         {
 837                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 838                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 839                 )
 840                         prev_p_health = -1;
 841                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 842                         prev_health = -1;
 843         }
 844         spectatee_status = newspectatee_status;
 845 }
 846
 847 void Ent_Nagger()
 848 {
 849         float nags, i, j, b, f;
 850
 851         nags = ReadByte();
 852
 853         if(nags & 128)
 854         {
 855                 if(vote_called_vote)
 856                         strunzone(vote_called_vote);
 857                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 858         }
 859
 860         if(nags & 1)
 861         {
 862                 for(j = 0; j < maxclients; ++j)
 863                         if(playerslots[j])
 864                                 playerslots[j].ready = 1;
 865                 for(i = 1; i <= maxclients; i += 8)
 866                 {
 867                         f = ReadByte();
 868                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 869                                 if not(f & b)
 870                                         if(playerslots[j])
 871                                                 playerslots[j].ready = 0;
 872                 }
 873         }
 874
 875         ready_waiting = (nags & 1);
 876         ready_waiting_for_me = (nags & 2);
 877         vote_waiting = (nags & 4);
 878         vote_waiting_for_me = (nags & 8);
 879         warmup_stage = (nags & 16);
 880 }
 881
 882 void Ent_RandomSeed()
 883 {
 884         float s;
 885         prandom_debug();
 886         s = ReadShort();
 887         psrandom(s);
 888 }
 889
 890 void Ent_ReadAccuracy(void)
 891 {
 892         float sf, f, w, b;
 893         sf = ReadInt24_t();
 894         if(sf == 0)
 895         {
 896                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 897                         weapon_accuracy[w] = -1;
 898                 return;
 899         }
 900
 901         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 902         {
 903                 if(sf & f)
 904                 {
 905                         b = ReadByte();
 906                         if(b == 0)
 907                                 weapon_accuracy[w] = -1;
 908                         else if(b == 255)
 909                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 910                         else
 911                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 912                 }
 913         }
 914 }
 915
 916 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 917 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 918 void Ent_RadarLink();
 919 void Ent_Init();
 920 void Ent_ScoresInfo();
 921 void(float bIsNewEntity) CSQC_Ent_Update =
 922 {
 923         float t;
 924         float savetime;
 925         t = ReadByte();
 926
 927         // set up the "time" global for received entities to be correct for interpolation purposes
 928         savetime = time;
 929         if(servertime)
 930         {
 931                 time = servertime;
 932         }
 933         else
 934         {
 935                 serverprevtime = time;
 936                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 937                 time = serverprevtime + serverdeltatime;
 938         }
 939
 940 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 941         if(self.enttype)
 942                 if(t != self.enttype)
 943                 {
 944                         //print(_("A CSQC entity changed its type!\n"));
 945                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 946                         Ent_Remove();
 947                         bIsNewEntity = 1;
 948                 }
 949 #endif
 950         self.enttype = t;
 951         switch(t)
 952         {
 953                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 954                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 955                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 956                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 957                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 958                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 959                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 960                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 961                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 962                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 963                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 964                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 965                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 966                 case ENT_CLIENT_INIT: Ent_Init(); break;
 967                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 968                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 969                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 970                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 971                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 972                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 973                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 974                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 975                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 976                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 977                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 978                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 979                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 980                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 981                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 982                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 983                 default:
 984                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 985                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 986                         break;
 987         }
 988
 989         time = savetime;
 990 };
 991 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 992 // used when an entity changes its type. For an entity that someone interacts
 993 // with others, make sure it can no longer do so.
 994 void Ent_Remove()
 995 {
 996         if(self.entremove)
 997                 self.entremove();
 998
 999         self.enttype = 0;
1000         self.classname = "";
1001         self.draw = menu_sub_null;
1002         self.entremove = menu_sub_null;
1003         // TODO possibly set more stuff to defaults
1004 }
1005 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
1006 void CSQC_Ent_Remove()
1007 {
1008         if(self.enttype)
1009                 Ent_Remove();
1010         remove(self);
1011 }
1012
1013 void Gamemode_Init()
1014 {
1015         if not(isdemo())
1016         {
1017                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
1018                 calledhooks |= HOOK_START;
1019         }
1020 }
1021 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1022 void CSQC_Parse_StuffCmd(string strMessage)
1023 {
1024         localcmd(strMessage);
1025 }
1026 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1027 void CSQC_Parse_Print(string strMessage)
1028 {
1029         print(ColorTranslateRGB(strMessage));
1030 }
1031
1032 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1033 void CSQC_Parse_CenterPrint(string strMessage)
1034 {
1035         centerprint(strMessage);
1036 }
1037
1038 string notranslate_fogcmd1 = "\nfog ";
1039 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1040 void Fog_Force()
1041 {
1042         // TODO somehow thwart prvm_globalset client ...
1043
1044         if(forcefog != "")
1045                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1046 }
1047
1048 void Gamemode_Init();
1049 void Ent_ScoresInfo()
1050 {
1051         float i;
1052         self.classname = "ent_client_scores_info";
1053         gametype = ReadByte();
1054         for(i = 0; i < MAX_SCORE; ++i)
1055         {
1056                 scores_label[i] = strzone(ReadString());
1057                 scores_flags[i] = ReadByte();
1058         }
1059         for(i = 0; i < MAX_TEAMSCORE; ++i)
1060         {
1061                 teamscores_label[i] = strzone(ReadString());
1062                 teamscores_flags[i] = ReadByte();
1063         }
1064         HUD_InitScores();
1065         Gamemode_Init();
1066 }
1067
1068 void Ent_Init()
1069 {
1070         self.classname = "ent_client_init";
1071
1072         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1073
1074         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1075         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1076         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1077         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1078         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1079         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1080         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1081         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1082         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1083         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1084         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1085         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1086
1087         if(forcefog)
1088                 strunzone(forcefog);
1089         forcefog = strzone(ReadString());
1090
1091         armorblockpercent = ReadByte() / 255.0;
1092
1093         g_weaponswitchdelay = ReadByte() / 255.0;
1094
1095         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1096         g_balance_grenadelauncher_bouncestop = ReadCoord();
1097         g_balance_electro_secondary_bouncefactor = ReadCoord();
1098         g_balance_electro_secondary_bouncestop = ReadCoord();
1099
1100         nex_scope = !ReadByte();
1101         rifle_scope = !ReadByte();
1102
1103         serverflags = ReadByte();
1104
1105         minelayer_maxmines = ReadByte();
1106
1107         hagar_maxrockets = ReadByte();
1108
1109         g_trueaim_minrange = ReadCoord();
1110
1111         if(!postinit)
1112                 PostInit();
1113 }
1114
1115 void Net_ReadRace()
1116 {
1117         float b;
1118
1119         b = ReadByte();
1120
1121         switch(b)
1122         {
1123                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1124                         race_checkpoint = ReadByte();
1125                         race_time = ReadInt24_t();
1126                         race_previousbesttime = ReadInt24_t();
1127                         if(race_previousbestname)
1128                                 strunzone(race_previousbestname);
1129                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1130
1131                         race_checkpointtime = time;
1132
1133                         if(race_checkpoint == 0 || race_checkpoint == 254)
1134                         {
1135                                 race_penaltyaccumulator = 0;
1136                                 race_laptime = time; // valid
1137                         }
1138
1139                         break;
1140
1141                 case RACE_NET_CHECKPOINT_CLEAR:
1142                         race_laptime = 0;
1143                         race_checkpointtime = 0;
1144                         break;
1145
1146                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1147                         race_laptime = ReadCoord();
1148                         race_checkpointtime = -99999;
1149                         // fall through
1150                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1151                         race_nextcheckpoint = ReadByte();
1152
1153                         race_nextbesttime = ReadInt24_t();
1154                         if(race_nextbestname)
1155                                 strunzone(race_nextbestname);
1156                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1157                         break;
1158
1159                 case RACE_NET_CHECKPOINT_HIT_RACE:
1160                         race_mycheckpoint = ReadByte();
1161                         race_mycheckpointtime = time;
1162                         race_mycheckpointdelta = ReadInt24_t();
1163                         race_mycheckpointlapsdelta = ReadByte();
1164                         if(race_mycheckpointlapsdelta >= 128)
1165                                 race_mycheckpointlapsdelta -= 256;
1166                         if(race_mycheckpointenemy)
1167                                 strunzone(race_mycheckpointenemy);
1168                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1169                         break;
1170
1171                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1172                         race_othercheckpoint = ReadByte();
1173                         race_othercheckpointtime = time;
1174                         race_othercheckpointdelta = ReadInt24_t();
1175                         race_othercheckpointlapsdelta = ReadByte();
1176                         if(race_othercheckpointlapsdelta >= 128)
1177                                 race_othercheckpointlapsdelta -= 256;
1178                         if(race_othercheckpointenemy)
1179                                 strunzone(race_othercheckpointenemy);
1180                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1181                         break;
1182
1183                 case RACE_NET_PENALTY_RACE:
1184                         race_penaltyeventtime = time;
1185                         race_penaltytime = ReadShort();
1186                         //race_penaltyaccumulator += race_penaltytime;
1187                         if(race_penaltyreason)
1188                                 strunzone(race_penaltyreason);
1189                         race_penaltyreason = strzone(ReadString());
1190                         break;
1191
1192                 case RACE_NET_PENALTY_QUALIFYING:
1193                         race_penaltyeventtime = time;
1194                         race_penaltytime = ReadShort();
1195                         race_penaltyaccumulator += race_penaltytime;
1196                         if(race_penaltyreason)
1197                                 strunzone(race_penaltyreason);
1198                         race_penaltyreason = strzone(ReadString());
1199                         break;
1200
1201                 case RACE_NET_SERVER_RECORD:
1202                         race_server_record = ReadInt24_t();
1203                         break;
1204                 case RACE_NET_SPEED_AWARD:
1205                         race_speedaward = ReadInt24_t();
1206                         if(race_speedaward_holder)
1207                                 strunzone(race_speedaward_holder);
1208                         race_speedaward_holder = strzone(ReadString());
1209                         break;
1210                 case RACE_NET_SPEED_AWARD_BEST:
1211                         race_speedaward_alltimebest = ReadInt24_t();
1212                         if(race_speedaward_alltimebest_holder)
1213                                 strunzone(race_speedaward_alltimebest_holder);
1214                         race_speedaward_alltimebest_holder = strzone(ReadString());
1215                         break;
1216                 case RACE_NET_SERVER_RANKINGS:
1217                         float pos, prevpos, del;
1218                         pos = ReadShort();
1219                         prevpos = ReadShort();
1220                         del = ReadShort();
1221
1222                         // move other rankings out of the way
1223                         float i;
1224                         if (prevpos) {
1225                                 for (i=prevpos-1;i>pos-1;--i) {
1226                                         grecordtime[i] = grecordtime[i-1];
1227                                         if(grecordholder[i])
1228                                                 strunzone(grecordholder[i]);
1229                                         grecordholder[i] = strzone(grecordholder[i-1]);
1230                                 }
1231                         } else if (del) { // a record has been deleted by the admin
1232                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1233                                         if (i == RANKINGS_CNT-1) { // clear out last record
1234                                                 grecordtime[i] = 0;
1235                                                 if (grecordholder[i])
1236                                                         strunzone(grecordholder[i]);
1237                                                 grecordholder[i] = string_null;
1238                                         }
1239                                         else {
1240                                                 grecordtime[i] = grecordtime[i+1];
1241                                                 if (grecordholder[i])
1242                                                         strunzone(grecordholder[i]);
1243                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1244                                         }
1245                                 }
1246                         } else { // player has no ranked record yet
1247                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1248                                         grecordtime[i] = grecordtime[i-1];
1249                                         if(grecordholder[i])
1250                                                 strunzone(grecordholder[i]);
1251                                         grecordholder[i] = strzone(grecordholder[i-1]);
1252                                 }
1253                         }
1254
1255                         // store new ranking
1256                         if(grecordholder[pos-1] != "")
1257                                 strunzone(grecordholder[pos-1]);
1258                         grecordholder[pos-1] = strzone(ReadString());
1259                         grecordtime[pos-1] = ReadInt24_t();
1260                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1261                                 race_myrank = pos;
1262                         break;
1263                 case RACE_NET_SERVER_STATUS:
1264                         race_status = ReadShort();
1265                         if(race_status_name)
1266                                 strunzone(race_status_name);
1267                         race_status_name = strzone(ReadString());
1268         }
1269 }
1270
1271 void Net_ReadSpawn()
1272 {
1273         zoomin_effect = 1;
1274         current_viewzoom = 0.6;
1275 }
1276
1277 void Net_TeamNagger()
1278 {
1279         teamnagger = 1;
1280 }
1281
1282 void Net_ReadPingPLReport()
1283 {
1284         float e, pi, pl, ml;
1285         e = ReadByte();
1286         pi = ReadShort();
1287         pl = ReadByte();
1288         ml = ReadByte();
1289         if not(playerslots[e])
1290                 return;
1291         playerslots[e].ping = pi;
1292         playerslots[e].ping_packetloss = pl / 255.0;
1293         playerslots[e].ping_movementloss = ml / 255.0;
1294 }
1295
1296 void Net_VoteDialog(float highlight) {
1297         if(highlight) {
1298                 vote_highlighted = ReadByte();
1299                 return;
1300         }
1301
1302         vote_yescount = ReadByte();
1303         vote_nocount = ReadByte();
1304         vote_needed = ReadByte();
1305         vote_active = 1;
1306 }
1307
1308 void Net_VoteDialogReset() {
1309         vote_active = 0;
1310 }
1311
1312 void Net_Notify() {
1313         float type;
1314         type = ReadByte();
1315
1316         if(type == CSQC_KILLNOTIFY)
1317         {
1318                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1319         }
1320         else if(type == CSQC_CENTERPRINT)
1321         {
1322                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1323         }
1324 }
1325
1326 void Net_WeaponComplain() {
1327         complain_weapon = ReadByte();
1328
1329         if(complain_weapon_name)
1330                 strunzone(complain_weapon_name);
1331         complain_weapon_name = strzone(ReadString());
1332
1333         complain_weapon_type = ReadByte();
1334
1335         complain_weapon_time = time;
1336         weapontime = time; // ping the weapon panel
1337 }
1338
1339 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1340 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1341 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1342 float CSQC_Parse_TempEntity()
1343 {
1344         local float bHandled;
1345                 bHandled  = true;
1346         // Acquire TE ID
1347         local float nTEID;
1348                 nTEID = ReadByte();
1349
1350                 // NOTE: Could just do return instead of break...
1351         switch(nTEID)
1352         {
1353                 case TE_CSQC_TARGET_MUSIC:
1354                         Net_TargetMusic();
1355                         bHandled = true;
1356                         break;
1357                 case TE_CSQC_PICTURE:
1358                         Net_MapVote_Picture();
1359                         bHandled = true;
1360                         break;
1361                 case TE_CSQC_RACE:
1362                         Net_ReadRace();
1363                         bHandled = true;
1364                         break;
1365                 case TE_CSQC_SPAWN:
1366                         Net_ReadSpawn();
1367                         bHandled = true;
1368                         break;
1369                 case TE_CSQC_ZCURVEPARTICLES:
1370                         Net_ReadZCurveParticles();
1371                         bHandled = true;
1372                         break;
1373                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1374                         Net_ReadNexgunBeamParticle();
1375                         bHandled = true;
1376                         break;
1377                 case TE_CSQC_TEAMNAGGER:
1378                         Net_TeamNagger();
1379                         bHandled = true;
1380                         break;
1381                 case TE_CSQC_VOTE:
1382                         Net_VoteDialog(ReadByte());
1383                         bHandled = true;
1384                         break;
1385                 case TE_CSQC_VOTERESET:
1386                         Net_VoteDialogReset();
1387                         bHandled = true;
1388                         break;
1389                 case TE_CSQC_LIGHTNINGARC:
1390                         Net_ReadLightningarc();
1391                         bHandled = true;
1392                         break;
1393                 case TE_CSQC_PINGPLREPORT:
1394                         Net_ReadPingPLReport();
1395                         bHandled = true;
1396                         break;
1397                 case TE_CSQC_ANNOUNCE:
1398                         announce_snd = strzone(ReadString());
1399                         bHandled = true;
1400                         break;
1401                 case TE_CSQC_NOTIFY:
1402                         Net_Notify();
1403                         bHandled = true;
1404                         break;
1405                 case TE_CSQC_WEAPONCOMPLAIN:
1406                         Net_WeaponComplain();
1407                         bHandled = true;
1408                         break;
1409         case TE_CSQC_VEHICLESETUP:
1410             Net_VehicleSetup();
1411             bHandled = true;
1412             break;
1413                 default:
1414                         // No special logic for this temporary entity; return 0 so the engine can handle it
1415                         bHandled = false;
1416                         break;
1417         }
1418
1419         return bHandled;
1420 }
1421
1422 string getcommandkey(string text, string command)
1423 {
1424         string keys;
1425         float n, j, k, l;
1426
1427         if (!autocvar_hud_showbinds)
1428                 return text;
1429
1430         keys = db_get(binddb, command);
1431         if (!keys)
1432         {
1433                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1434                 for(j = 0; j < n; ++j)
1435                 {
1436                         k = stof(argv(j));
1437                         if(k != -1)
1438                         {
1439                                 if ("" == keys)
1440                                         keys = keynumtostring(k);
1441                                 else
1442                                         keys = strcat(keys, ", ", keynumtostring(k));
1443
1444                                 ++l;
1445                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1446                         }
1447
1448                 }
1449                 db_put(binddb, command, keys);
1450         }
1451
1452         if ("" == keys) {
1453                 if (autocvar_hud_showbinds > 1)
1454                         return sprintf(_("%s (not bound)"), text);
1455                 else
1456                         return text;
1457         }
1458         else if (autocvar_hud_showbinds > 1)
1459                 return sprintf(_("%s (%s)"), text, keys);
1460         else
1461                 return keys;
1462 }