qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if (!clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 string forcefog;
  32 void WaypointSprite_Load();
  33 void ConsoleCommand_macro_init();
  34 void CSQC_Init(void)
  35 {
  36         prvm_language = cvar_string("prvm_language");
  37
  38 #ifdef WATERMARK
  39         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
  40 #endif
  41
  42         float i;
  43
  44         binddb = db_create();
  45         tempdb = db_create();
  46         ClientProgsDB = db_load("client.db");
  47         compressShortVector_init();
  48
  49         draw_endBoldFont();
  50         menu_visible = FALSE;
  51         menu_show = menu_show_error;
  52         menu_action = func_null;
  53
  54         for(i = 0; i < 255; ++i)
  55                 if(getplayerkeyvalue(i, "viewentity") == "")
  56                         break;
  57         maxclients = i;
  58
  59         //registercommand("hud_configure");
  60         //registercommand("hud_save");
  61         //registercommand("menu_action");
  62
  63         ConsoleCommand_macro_init();
  64
  65         registercvar("hud_usecsqc", "1");
  66         registercvar("scoreboard_columns", "default");
  67
  68         registercvar("cl_nade_type", "3");
  69         registercvar("cl_pokenade_type", "zombie");
  70
  71         gametype = 0;
  72
  73         // hud_fields uses strunzone on the titles!
  74         for(i = 0; i < MAX_HUD_FIELDS; ++i)
  75                 hud_title[i] = strzone("(null)");
  76
  77         Cmd_HUD_SetFields(0);
  78
  79         postinit = false;
  80
  81         calledhooks = 0;
  82
  83         teams = Sort_Spawn();
  84         players = Sort_Spawn();
  85
  86         GetTeam(NUM_SPECTATOR, true); // add specs first
  87
  88         // needs to be done so early because of the constants they create
  89         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
  90         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
  91         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
  92         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
  93         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
  94         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
  95         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
  96
  97         WaypointSprite_Load();
  98
  99         // precaches
 100         precache_model("null");
 101         precache_sound("misc/hit.wav");
 102         precache_sound("misc/typehit.wav");
 103
 104         generator_precache();
 105         Projectile_Precache();
 106         Hook_Precache();
 107         GibSplash_Precache();
 108         Casings_Precache();
 109         Vehicles_Precache();
 110         turrets_precache();
 111         Tuba_Precache();
 112         CSQCPlayer_Precache();
 113
 114         if(autocvar_cl_reticle)
 115         {
 116                 precache_pic("gfx/reticle_normal");
 117                 // weapon reticles are precached in weapon files
 118         }
 119
 120         get_mi_min_max_texcoords(1); // try the CLEVER way first
 121         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 122         shortmapname = mi_shortname;
 123
 124         if(precache_pic(minimapname) == "")
 125         {
 126                 // but maybe we have a non-clever minimap
 127                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 128                 if(precache_pic(minimapname) == "")
 129                         minimapname = ""; // FAIL
 130                 else
 131                         get_mi_min_max_texcoords(0); // load new texcoords
 132         }
 133
 134         mi_center = (mi_min + mi_max) * 0.5;
 135         mi_scale = mi_max - mi_min;
 136         minimapname = strzone(minimapname);
 137
 138         WarpZone_Init();
 139
 140         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 141         hud_configure_prev = -1;
 142
 143         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 144 }
 145
 146 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 147 void Shutdown(void)
 148 {
 149         WarpZone_Shutdown();
 150
 151         remove(teams);
 152         remove(players);
 153         db_close(binddb);
 154         db_close(tempdb);
 155         if(autocvar_cl_db_saveasdump)
 156                 db_dump(ClientProgsDB, "client.db");
 157         else
 158                 db_save(ClientProgsDB, "client.db");
 159         db_close(ClientProgsDB);
 160
 161         if(camera_active)
 162                 cvar_set("chase_active",ftos(chase_active_backup));
 163
 164         // unset the event chasecam's chase_active
 165         if(autocvar_chase_active < 0)
 166                 cvar_set("chase_active", "0");
 167
 168         if (!isdemo())
 169         {
 170                 if (!(calledhooks & HOOK_START))
 171                         localcmd("\n_cl_hook_gamestart nop\n");
 172                 if (!(calledhooks & HOOK_END))
 173                         localcmd("\ncl_hook_gameend\n");
 174         }
 175 }
 176
 177 .float has_team;
 178 float SetTeam(entity o, float Team)
 179 {
 180         entity tm;
 181         if(teamplay)
 182         {
 183                 switch(Team)
 184                 {
 185                         case -1:
 186                         case NUM_TEAM_1:
 187                         case NUM_TEAM_2:
 188                         case NUM_TEAM_3:
 189                         case NUM_TEAM_4:
 190                                 break;
 191                         default:
 192                                 if(GetTeam(Team, false) == world)
 193                                 {
 194                                         dprintf("trying to switch to unsupported team %d\n", Team);
 195                                         Team = NUM_SPECTATOR;
 196                                 }
 197                                 break;
 198                 }
 199         }
 200         else
 201         {
 202                 switch(Team)
 203                 {
 204                         case -1:
 205                         case 0:
 206                                 break;
 207                         default:
 208                                 if(GetTeam(Team, false) == world)
 209                                 {
 210                                         dprintf("trying to switch to unsupported team %d\n", Team);
 211                                         Team = NUM_SPECTATOR;
 212                                 }
 213                                 break;
 214                 }
 215         }
 216         if(Team == -1) // leave
 217         {
 218                 if(o.has_team)
 219                 {
 220                         tm = GetTeam(o.team, false);
 221                         tm.team_size -= 1;
 222                         o.has_team = 0;
 223                         return TRUE;
 224                 }
 225         }
 226         else
 227         {
 228                 if (!o.has_team)
 229                 {
 230                         o.team = Team;
 231                         tm = GetTeam(Team, true);
 232                         tm.team_size += 1;
 233                         o.has_team = 1;
 234                         return TRUE;
 235                 }
 236                 else if(Team != o.team)
 237                 {
 238                         tm = GetTeam(o.team, false);
 239                         tm.team_size -= 1;
 240                         o.team = Team;
 241                         tm = GetTeam(Team, true);
 242                         tm.team_size += 1;
 243                         return TRUE;
 244                 }
 245         }
 246         return FALSE;
 247 }
 248
 249 void Playerchecker_Think()
 250 {
 251         float i;
 252         entity e;
 253         for(i = 0; i < maxclients; ++i)
 254         {
 255                 e = playerslots[i];
 256                 if(GetPlayerName(i) == "")
 257                 {
 258                         if(e.sort_prev)
 259                         {
 260                                 // player disconnected
 261                                 SetTeam(e, -1);
 262                                 RemovePlayer(e);
 263                                 e.sort_prev = world;
 264                                 //e.gotscores = 0;
 265                         }
 266                 }
 267                 else
 268                 {
 269                         if (!e.sort_prev)
 270                         {
 271                                 // player connected
 272                                 if (!e)
 273                                         playerslots[i] = e = spawn();
 274                                 e.sv_entnum = i;
 275                                 e.ping = 0;
 276                                 e.ping_packetloss = 0;
 277                                 e.ping_movementloss = 0;
 278                                 //e.gotscores = 0; // we might already have the scores...
 279                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 280                                 RegisterPlayer(e);
 281                                 HUD_UpdatePlayerPos(e);
 282                         }
 283                 }
 284         }
 285         self.nextthink = time + 0.2;
 286 }
 287
 288 void Porto_Init();
 289 void TrueAim_Init();
 290 void PostInit(void)
 291 {
 292         entity playerchecker;
 293         playerchecker = spawn();
 294         playerchecker.think = Playerchecker_Think;
 295         playerchecker.nextthink = time + 0.2;
 296
 297         Porto_Init();
 298         TrueAim_Init();
 299
 300         postinit = true;
 301 }
 302
 303 float button_zoom;
 304
 305 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 306 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 307 // All keys are in ascii.
 308 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 309 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 310 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 311 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 312 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 313 {
 314         float bSkipKey;
 315         bSkipKey = false;
 316
 317         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 318                 return true;
 319
 320         if ( HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary) )
 321                 return true;
 322
 323         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 324                 return true;
 325
 326         if(menu_visible && menu_action)
 327                 if(menu_action(bInputType, nPrimary, nSecondary))
 328                         return TRUE;
 329
 330         return bSkipKey;
 331 }
 332
 333 // END REQUIRED CSQC FUNCTIONS
 334 // --------------------------------------------------------------------------
 335
 336 // --------------------------------------------------------------------------
 337 // BEGIN OPTIONAL CSQC FUNCTIONS
 338 void Ent_RemoveEntCS()
 339 {
 340         entcs_receiver[self.sv_entnum] = world;
 341 }
 342 void Ent_ReadEntCS()
 343 {
 344         float sf;
 345         InterpolateOrigin_Undo();
 346
 347         self.classname = "entcs_receiver";
 348         sf = ReadByte();
 349
 350         if(sf & 1)
 351                 self.sv_entnum = ReadByte();
 352         if(sf & 2)
 353         {
 354                 self.origin_x = ReadShort();
 355                 self.origin_y = ReadShort();
 356                 self.origin_z = ReadShort();
 357                 setorigin(self, self.origin);
 358         }
 359         if(sf & 4)
 360         {
 361                 self.angles_y = ReadByte() * 360.0 / 256;
 362                 self.angles_x = self.angles_z = 0;
 363         }
 364         if(sf & 8)
 365                 self.healthvalue = ReadByte() * 10;
 366         if(sf & 16)
 367                 self.armorvalue = ReadByte() * 10;
 368
 369         entcs_receiver[self.sv_entnum] = self;
 370         self.entremove = Ent_RemoveEntCS;
 371         self.iflags |= IFLAG_ORIGIN;
 372
 373         InterpolateOrigin_Note();
 374 }
 375
 376 void Ent_Remove();
 377
 378 void Ent_RemovePlayerScore()
 379 {
 380         float i;
 381
 382         if(self.owner)
 383         {
 384                 SetTeam(self.owner, -1);
 385                 self.owner.gotscores = 0;
 386                 for(i = 0; i < MAX_SCORE; ++i)
 387                         self.owner.(scores[i]) = 0; // clear all scores
 388         }
 389 }
 390
 391 void Ent_ReadPlayerScore()
 392 {
 393         float i, n;
 394         float isNew;
 395         entity o;
 396
 397         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 398         // (no I've never heard of M-x replace-string, sed, or anything like that)
 399         isNew = !self.owner; // workaround for DP bug
 400         n = ReadByte()-1;
 401
 402 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 403         if(!isNew && n != self.sv_entnum)
 404         {
 405                 //print("A CSQC entity changed its owner!\n");
 406                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 407                 isNew = true;
 408                 Ent_Remove();
 409                 self.enttype = ENT_CLIENT_SCORES;
 410         }
 411 #endif
 412
 413         self.sv_entnum = n;
 414
 415         if (!(playerslots[self.sv_entnum]))
 416                 playerslots[self.sv_entnum] = spawn();
 417         o = self.owner = playerslots[self.sv_entnum];
 418         o.sv_entnum = self.sv_entnum;
 419         o.gotscores = 1;
 420
 421         //if (!o.sort_prev)
 422         //      RegisterPlayer(o);
 423         //playerchecker will do this for us later, if it has not already done so
 424
 425         float sf, lf;
 426 #if MAX_SCORE <= 8
 427         sf = ReadByte();
 428         lf = ReadByte();
 429 #else
 430         sf = ReadShort();
 431         lf = ReadShort();
 432 #endif
 433         float p;
 434         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 435                 if(sf & p)
 436                 {
 437                         if(lf & p)
 438                                 o.(scores[i]) = ReadInt24_t();
 439                         else
 440                                 o.(scores[i]) = ReadChar();
 441                 }
 442
 443         if(o.sort_prev)
 444                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 445
 446         self.entremove = Ent_RemovePlayerScore;
 447 }
 448
 449 void Ent_ReadTeamScore()
 450 {
 451         float i;
 452         entity o;
 453
 454         self.team = ReadByte();
 455         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 456
 457         float sf, lf;
 458 #if MAX_TEAMSCORE <= 8
 459         sf = ReadByte();
 460         lf = ReadByte();
 461 #else
 462         sf = ReadShort();
 463         lf = ReadShort();
 464 #endif
 465         float p;
 466         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 467                 if(sf & p)
 468                 {
 469                         if(lf & p)
 470                                 o.(teamscores[i]) = ReadInt24_t();
 471                         else
 472                                 o.(teamscores[i]) = ReadChar();
 473                 }
 474
 475         HUD_UpdateTeamPos(o);
 476 }
 477
 478 void Ent_ClientData()
 479 {
 480         float f;
 481         float newspectatee_status;
 482
 483         f = ReadByte();
 484
 485         scoreboard_showscores_force = (f & 1);
 486
 487         if(f & 2)
 488         {
 489                 newspectatee_status = ReadByte();
 490                 if(newspectatee_status == player_localnum + 1)
 491                         newspectatee_status = -1; // observing
 492         }
 493         else
 494                 newspectatee_status = 0;
 495
 496         spectatorbutton_zoom = (f & 4);
 497
 498         if(f & 8)
 499         {
 500                 angles_held_status = 1;
 501                 angles_held_x = ReadAngle();
 502                 angles_held_y = ReadAngle();
 503                 angles_held_z = 0;
 504         }
 505         else
 506                 angles_held_status = 0;
 507
 508         if(newspectatee_status != spectatee_status)
 509         {
 510                 // clear race stuff
 511                 race_laptime = 0;
 512                 race_checkpointtime = 0;
 513         }
 514         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 515         {
 516                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 517                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 518                 )
 519                         prev_p_health = -1;
 520                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 521                         prev_health = -1;
 522         }
 523         spectatee_status = newspectatee_status;
 524
 525         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 526 }
 527
 528 void Ent_Nagger()
 529 {
 530         float nags, i, j, b, f;
 531
 532         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 533
 534         if(!(nags & 4))
 535         {
 536                 if(vote_called_vote)
 537                         strunzone(vote_called_vote);
 538                 vote_called_vote = string_null;
 539                 vote_active = 0;
 540         }
 541         else
 542         {
 543                 vote_active = 1;
 544         }
 545
 546         if(nags & 64)
 547         {
 548                 vote_yescount = ReadByte();
 549                 vote_nocount = ReadByte();
 550                 vote_needed = ReadByte();
 551                 vote_highlighted = ReadChar();
 552         }
 553
 554         if(nags & 128)
 555         {
 556                 if(vote_called_vote)
 557                         strunzone(vote_called_vote);
 558                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 559         }
 560
 561         if(nags & 1)
 562         {
 563                 for(j = 0; j < maxclients; ++j)
 564                         if(playerslots[j])
 565                                 playerslots[j].ready = 1;
 566                 for(i = 1; i <= maxclients; i += 8)
 567                 {
 568                         f = ReadByte();
 569                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 570                                 if (!(f & b))
 571                                         if(playerslots[j])
 572                                                 playerslots[j].ready = 0;
 573                 }
 574         }
 575
 576         ready_waiting = (nags & 1);
 577         ready_waiting_for_me = (nags & 2);
 578         vote_waiting = (nags & 4);
 579         vote_waiting_for_me = (nags & 8);
 580         warmup_stage = (nags & 16);
 581 }
 582
 583 void Ent_EliminatedPlayers()
 584 {
 585         float sf, i, j, b, f;
 586
 587         sf = ReadByte();
 588         if(sf & 1)
 589         {
 590                 for(j = 0; j < maxclients; ++j)
 591                         if(playerslots[j])
 592                                 playerslots[j].eliminated = 1;
 593                 for(i = 1; i <= maxclients; i += 8)
 594                 {
 595                         f = ReadByte();
 596                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 597                                 if (!(f & b))
 598                                         if(playerslots[j])
 599                                                 playerslots[j].eliminated = 0;
 600                 }
 601         }
 602 }
 603
 604 void Ent_RandomSeed()
 605 {
 606         float s;
 607         prandom_debug();
 608         s = ReadShort();
 609         psrandom(s);
 610 }
 611
 612 void Ent_ReadAccuracy(void)
 613 {
 614         float sf, f, w, b;
 615         sf = ReadInt24_t();
 616         if(sf == 0)
 617         {
 618                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 619                         weapon_accuracy[w] = -1;
 620                 return;
 621         }
 622
 623         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 624         {
 625                 if(sf & f)
 626                 {
 627                         b = ReadByte();
 628                         if(b == 0)
 629                                 weapon_accuracy[w] = -1;
 630                         else if(b == 255)
 631                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 632                         else
 633                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 634                 }
 635                 if(f == 0x800000)
 636                         f = 1;
 637                 else
 638                         f *= 2;
 639         }
 640 }
 641
 642 void Spawn_Draw(void)
 643 {
 644         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 645 }
 646
 647 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 648 {
 649         float teamnum = (ReadByte() - 1);
 650         vector spn_origin;
 651         spn_origin_x = ReadShort();
 652         spn_origin_y = ReadShort();
 653         spn_origin_z = ReadShort();
 654
 655         if(is_new)
 656         {
 657                 self.origin = spn_origin;
 658                 setsize(self, PL_MIN, PL_MAX);
 659                 droptofloor();
 660
 661                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 662                 {
 663                         self.mdl = "models/spawnpoint.md3";
 664                         self.colormod = Team_ColorRGB(teamnum);
 665                         precache_model(self.mdl);
 666                         setmodel(self, self.mdl);
 667                         self.drawmask = MASK_NORMAL;
 668                         //self.movetype = MOVETYPE_NOCLIP;
 669                         //self.draw = Spawn_Draw;
 670                 }*/
 671                 if(autocvar_cl_spawn_point_particles)
 672                 {
 673                         if((serverflags & SERVERFLAG_TEAMPLAY))
 674                         {
 675                                 switch(teamnum)
 676                                 {
 677                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 678                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 679                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 680                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 681                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 682                                 }
 683                         }
 684                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 685
 686                         self.draw = Spawn_Draw;
 687                 }
 688         }
 689
 690         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 691 }
 692
 693 void Ent_ReadSpawnEvent(float is_new)
 694 {
 695         // If entnum is 0, ONLY do the local spawn actions
 696         // this way the server can disable the sending of
 697         // spawn origin or such to clients if wanted.
 698         float entnum = ReadByte();
 699
 700         if(entnum)
 701         {
 702                 self.origin_x = ReadShort();
 703                 self.origin_y = ReadShort();
 704                 self.origin_z = ReadShort();
 705
 706                 if(is_new)
 707                 {
 708                         float teamnum = GetPlayerColor(entnum - 1);
 709
 710                         if(autocvar_cl_spawn_event_particles)
 711                         {
 712                                 switch(teamnum)
 713                                 {
 714                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 715                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 716                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 717                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 718                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 719                                 }
 720                         }
 721                         if(autocvar_cl_spawn_event_sound)
 722                         {
 723                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 724                         }
 725                 }
 726         }
 727
 728         // local spawn actions
 729         if(is_new && (!entnum || (entnum == player_localentnum)))
 730         {
 731                 zoomin_effect = 1;
 732                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 733
 734                 if(autocvar_cl_unpress_zoom_on_spawn)
 735                 {
 736                         localcmd("-zoom\n");
 737                         button_zoom = FALSE;
 738                 }
 739         }
 740         HUD_Radar_Hide_Maximized();
 741         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 742 }
 743
 744 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 745 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 746 void Ent_RadarLink();
 747 void Ent_Init();
 748 void Ent_ScoresInfo();
 749 void CSQC_Ent_Update(float bIsNewEntity)
 750 {
 751         float t;
 752         float savetime;
 753         t = ReadByte();
 754
 755         if(autocvar_developer_csqcentities)
 756                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 757
 758         // set up the "time" global for received entities to be correct for interpolation purposes
 759         savetime = time;
 760         if(servertime)
 761         {
 762                 time = servertime;
 763         }
 764         else
 765         {
 766                 serverprevtime = time;
 767                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 768                 time = serverprevtime + serverdeltatime;
 769         }
 770
 771 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 772         if(self.enttype)
 773         {
 774                 if(t != self.enttype || bIsNewEntity)
 775                 {
 776                         //print("A CSQC entity changed its type!\n");
 777                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 778                         Ent_Remove();
 779                         clearentity(self);
 780                         bIsNewEntity = 1;
 781                 }
 782         }
 783         else
 784         {
 785                 if(!bIsNewEntity)
 786                 {
 787                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 788                         bIsNewEntity = 1;
 789                 }
 790         }
 791 #endif
 792         self.enttype = t;
 793         switch(t)
 794         {
 795                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 796                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 797                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 798                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 799                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 800                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 801                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 802                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 803                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 804                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 805                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 806                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 807                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 808                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 809                 case ENT_CLIENT_INIT: Ent_Init(); break;
 810                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 811                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 812                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 813                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 814                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 815                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 816                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 817                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 818                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 819                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 820                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 821                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 822                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 823                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 824                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 825                 case ENT_CLIENT_TURRET: ent_turret(); break;
 826                 case ENT_CLIENT_GENERATOR: ent_generator(); break;
 827                 case ENT_CLIENT_CONTROLPOINT_ICON: ent_cpicon(); break;
 828                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 829                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 830                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 831                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 832                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 833                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 834                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 835
 836                 default:
 837                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 838                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 839                         break;
 840         }
 841
 842         time = savetime;
 843 }
 844 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 845 // used when an entity changes its type. For an entity that someone interacts
 846 // with others, make sure it can no longer do so.
 847 void Ent_Remove()
 848 {
 849         if(self.entremove)
 850                 self.entremove();
 851
 852         if(self.skeletonindex)
 853         {
 854                 skel_delete(self.skeletonindex);
 855                 self.skeletonindex = 0;
 856         }
 857
 858         if(self.snd_looping > 0)
 859         {
 860                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 861                 self.snd_looping = 0;
 862         }
 863
 864         self.enttype = 0;
 865         self.classname = "";
 866         self.draw = menu_sub_null;
 867         self.entremove = menu_sub_null;
 868         // TODO possibly set more stuff to defaults
 869 }
 870 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 871 void CSQC_Ent_Remove()
 872 {
 873         if(autocvar_developer_csqcentities)
 874                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 875
 876         if(wasfreed(self))
 877         {
 878                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 879                 return;
 880         }
 881         if(self.enttype)
 882                 Ent_Remove();
 883         remove(self);
 884 }
 885
 886 void Gamemode_Init()
 887 {
 888         if (!isdemo())
 889         {
 890                 if(!(calledhooks & HOOK_START))
 891                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 892                 calledhooks |= HOOK_START;
 893         }
 894 }
 895 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 896 void CSQC_Parse_StuffCmd(string strMessage)
 897 {
 898         if(autocvar_developer_csqcentities)
 899                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 900
 901         localcmd(strMessage);
 902 }
 903 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 904 void CSQC_Parse_Print(string strMessage)
 905 {
 906         if(autocvar_developer_csqcentities)
 907                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 908
 909         print(ColorTranslateRGB(strMessage));
 910 }
 911
 912 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 913 void CSQC_Parse_CenterPrint(string strMessage)
 914 {
 915         if(autocvar_developer_csqcentities)
 916                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 917
 918         centerprint_hud(strMessage);
 919 }
 920
 921 string notranslate_fogcmd1 = "\nfog ";
 922 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 923 void Fog_Force()
 924 {
 925         // TODO somehow thwart prvm_globalset client ...
 926
 927         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 928                 { localcmd("\nr_drawfog 0\n"); }
 929         else if(forcefog != "")
 930                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 931 }
 932
 933 void Gamemode_Init();
 934 void Ent_ScoresInfo()
 935 {
 936         float i;
 937         self.classname = "ent_client_scores_info";
 938         gametype = ReadInt24_t();
 939         HUD_ModIcons_SetFunc();
 940         for(i = 0; i < MAX_SCORE; ++i)
 941         {
 942                 if(scores_label[i])
 943                         strunzone(scores_label[i]);
 944                 scores_label[i] = strzone(ReadString());
 945                 scores_flags[i] = ReadByte();
 946         }
 947         for(i = 0; i < MAX_TEAMSCORE; ++i)
 948         {
 949                 if(teamscores_label[i])
 950                         strunzone(teamscores_label[i]);
 951                 teamscores_label[i] = strzone(ReadString());
 952                 teamscores_flags[i] = ReadByte();
 953         }
 954         HUD_InitScores();
 955         Gamemode_Init();
 956 }
 957
 958 void Ent_Init()
 959 {
 960         self.classname = "ent_client_init";
 961
 962         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 963
 964         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 965         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 966         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 967         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 968         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 969         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 970         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 971         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 972
 973         if(forcefog)
 974                 strunzone(forcefog);
 975         forcefog = strzone(ReadString());
 976
 977         armorblockpercent = ReadByte() / 255.0;
 978
 979         g_balance_mortar_bouncefactor = ReadCoord();
 980         g_balance_mortar_bouncestop = ReadCoord();
 981         g_balance_electro_secondary_bouncefactor = ReadCoord();
 982         g_balance_electro_secondary_bouncestop = ReadCoord();
 983
 984         vortex_scope = !ReadByte();
 985         rifle_scope = !ReadByte();
 986
 987         serverflags = ReadByte();
 988
 989         minelayer_maxmines = ReadByte();
 990
 991         hagar_maxrockets = ReadByte();
 992
 993         g_trueaim_minrange = ReadCoord();
 994         g_balance_porto_secondary = ReadByte();
 995
 996         if(!postinit)
 997                 PostInit();
 998 }
 999
1000 void Net_ReadRace()
1001 {
1002         float b;
1003
1004         b = ReadByte();
1005
1006         switch(b)
1007         {
1008                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1009                         race_checkpoint = ReadByte();
1010                         race_time = ReadInt24_t();
1011                         race_previousbesttime = ReadInt24_t();
1012                         if(race_previousbestname)
1013                                 strunzone(race_previousbestname);
1014                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1015
1016                         race_checkpointtime = time;
1017
1018                         if(race_checkpoint == 0 || race_checkpoint == 254)
1019                         {
1020                                 race_penaltyaccumulator = 0;
1021                                 race_laptime = time; // valid
1022                         }
1023
1024                         break;
1025
1026                 case RACE_NET_CHECKPOINT_CLEAR:
1027                         race_laptime = 0;
1028                         race_checkpointtime = 0;
1029                         break;
1030
1031                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1032                         race_laptime = ReadCoord();
1033                         race_checkpointtime = -99999;
1034                         // fall through
1035                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1036                         race_nextcheckpoint = ReadByte();
1037
1038                         race_nextbesttime = ReadInt24_t();
1039                         if(race_nextbestname)
1040                                 strunzone(race_nextbestname);
1041                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1042                         break;
1043
1044                 case RACE_NET_CHECKPOINT_HIT_RACE:
1045                         race_mycheckpoint = ReadByte();
1046                         race_mycheckpointtime = time;
1047                         race_mycheckpointdelta = ReadInt24_t();
1048                         race_mycheckpointlapsdelta = ReadByte();
1049                         if(race_mycheckpointlapsdelta >= 128)
1050                                 race_mycheckpointlapsdelta -= 256;
1051                         if(race_mycheckpointenemy)
1052                                 strunzone(race_mycheckpointenemy);
1053                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1054                         break;
1055
1056                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1057                         race_othercheckpoint = ReadByte();
1058                         race_othercheckpointtime = time;
1059                         race_othercheckpointdelta = ReadInt24_t();
1060                         race_othercheckpointlapsdelta = ReadByte();
1061                         if(race_othercheckpointlapsdelta >= 128)
1062                                 race_othercheckpointlapsdelta -= 256;
1063                         if(race_othercheckpointenemy)
1064                                 strunzone(race_othercheckpointenemy);
1065                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1066                         break;
1067
1068                 case RACE_NET_PENALTY_RACE:
1069                         race_penaltyeventtime = time;
1070                         race_penaltytime = ReadShort();
1071                         //race_penaltyaccumulator += race_penaltytime;
1072                         if(race_penaltyreason)
1073                                 strunzone(race_penaltyreason);
1074                         race_penaltyreason = strzone(ReadString());
1075                         break;
1076
1077                 case RACE_NET_PENALTY_QUALIFYING:
1078                         race_penaltyeventtime = time;
1079                         race_penaltytime = ReadShort();
1080                         race_penaltyaccumulator += race_penaltytime;
1081                         if(race_penaltyreason)
1082                                 strunzone(race_penaltyreason);
1083                         race_penaltyreason = strzone(ReadString());
1084                         break;
1085
1086                 case RACE_NET_SERVER_RECORD:
1087                         race_server_record = ReadInt24_t();
1088                         break;
1089                 case RACE_NET_SPEED_AWARD:
1090                         race_speedaward = ReadInt24_t();
1091                         if(race_speedaward_holder)
1092                                 strunzone(race_speedaward_holder);
1093                         race_speedaward_holder = strzone(ReadString());
1094                         break;
1095                 case RACE_NET_SPEED_AWARD_BEST:
1096                         race_speedaward_alltimebest = ReadInt24_t();
1097                         if(race_speedaward_alltimebest_holder)
1098                                 strunzone(race_speedaward_alltimebest_holder);
1099                         race_speedaward_alltimebest_holder = strzone(ReadString());
1100                         break;
1101                 case RACE_NET_SERVER_RANKINGS:
1102                         float pos, prevpos, del;
1103                         pos = ReadShort();
1104                         prevpos = ReadShort();
1105                         del = ReadShort();
1106
1107                         // move other rankings out of the way
1108                         float i;
1109                         if (prevpos) {
1110                                 for (i=prevpos-1;i>pos-1;--i) {
1111                                         grecordtime[i] = grecordtime[i-1];
1112                                         if(grecordholder[i])
1113                                                 strunzone(grecordholder[i]);
1114                                         grecordholder[i] = strzone(grecordholder[i-1]);
1115                                 }
1116                         } else if (del) { // a record has been deleted by the admin
1117                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1118                                         if (i == RANKINGS_CNT-1) { // clear out last record
1119                                                 grecordtime[i] = 0;
1120                                                 if (grecordholder[i])
1121                                                         strunzone(grecordholder[i]);
1122                                                 grecordholder[i] = string_null;
1123                                         }
1124                                         else {
1125                                                 grecordtime[i] = grecordtime[i+1];
1126                                                 if (grecordholder[i])
1127                                                         strunzone(grecordholder[i]);
1128                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1129                                         }
1130                                 }
1131                         } else { // player has no ranked record yet
1132                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1133                                         grecordtime[i] = grecordtime[i-1];
1134                                         if(grecordholder[i])
1135                                                 strunzone(grecordholder[i]);
1136                                         grecordholder[i] = strzone(grecordholder[i-1]);
1137                                 }
1138                         }
1139
1140                         // store new ranking
1141                         if(grecordholder[pos-1] != "")
1142                                 strunzone(grecordholder[pos-1]);
1143                         grecordholder[pos-1] = strzone(ReadString());
1144                         grecordtime[pos-1] = ReadInt24_t();
1145                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1146                                 race_myrank = pos;
1147                         break;
1148                 case RACE_NET_SERVER_STATUS:
1149                         race_status = ReadShort();
1150                         if(race_status_name)
1151                                 strunzone(race_status_name);
1152                         race_status_name = strzone(ReadString());
1153         }
1154 }
1155
1156 void Net_TeamNagger()
1157 {
1158         teamnagger = 1;
1159 }
1160
1161 void Net_ReadPingPLReport()
1162 {
1163         float e, pi, pl, ml;
1164         e = ReadByte();
1165         pi = ReadShort();
1166         pl = ReadByte();
1167         ml = ReadByte();
1168         if (!(playerslots[e]))
1169                 return;
1170         playerslots[e].ping = pi;
1171         playerslots[e].ping_packetloss = pl / 255.0;
1172         playerslots[e].ping_movementloss = ml / 255.0;
1173 }
1174
1175 void Net_WeaponComplain()
1176 {
1177         complain_weapon = ReadByte();
1178
1179         if(complain_weapon_name)
1180                 strunzone(complain_weapon_name);
1181         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1182
1183         complain_weapon_type = ReadByte();
1184
1185         complain_weapon_time = time;
1186         weapontime = time; // ping the weapon panel
1187
1188         switch(complain_weapon_type)
1189         {
1190                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1191                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1192                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1193         }
1194 }
1195
1196 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1197 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1198 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1199 float CSQC_Parse_TempEntity()
1200 {
1201         float bHandled;
1202                 bHandled  = true;
1203         // Acquire TE ID
1204         float nTEID;
1205                 nTEID = ReadByte();
1206
1207         if(autocvar_developer_csqcentities)
1208                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1209
1210                 // NOTE: Could just do return instead of break...
1211         switch(nTEID)
1212         {
1213                 case TE_CSQC_TARGET_MUSIC:
1214                         Net_TargetMusic();
1215                         bHandled = true;
1216                         break;
1217                 case TE_CSQC_PICTURE:
1218                         Net_MapVote_Picture();
1219                         bHandled = true;
1220                         break;
1221                 case TE_CSQC_RACE:
1222                         Net_ReadRace();
1223                         bHandled = true;
1224                         break;
1225                 case TE_CSQC_VORTEXBEAMPARTICLE:
1226                         Net_ReadVortexBeamParticle();
1227                         bHandled = true;
1228                         break;
1229                 case TE_CSQC_TEAMNAGGER:
1230                         Net_TeamNagger();
1231                         bHandled = true;
1232                         break;
1233                 case TE_CSQC_ARC:
1234                         Net_ReadArc();
1235                         bHandled = true;
1236                         break;
1237                 case TE_CSQC_PINGPLREPORT:
1238                         Net_ReadPingPLReport();
1239                         bHandled = true;
1240                         break;
1241                 case TE_CSQC_WEAPONCOMPLAIN:
1242                         Net_WeaponComplain();
1243                         bHandled = true;
1244                         break;
1245                 case TE_CSQC_VEHICLESETUP:
1246                         Net_VehicleSetup();
1247                         bHandled = true;
1248                         break;
1249                 case TE_CSQC_SVNOTICE:
1250                         cl_notice_read();
1251                         bHandled = true;
1252                         break;
1253                 case TE_CSQC_SHOCKWAVEPARTICLE:
1254                         Net_ReadShockwaveParticle();
1255                         bHandled = true;
1256                         break;
1257                 default:
1258                         // No special logic for this temporary entity; return 0 so the engine can handle it
1259                         bHandled = false;
1260                         break;
1261         }
1262
1263         return bHandled;
1264 }
1265
1266 string getcommandkey(string text, string command)
1267 {
1268         string keys;
1269         float n, j, k, l = 0;
1270
1271         if (!autocvar_hud_showbinds)
1272                 return text;
1273
1274         keys = db_get(binddb, command);
1275         if (keys == "")
1276         {
1277                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1278                 for(j = 0; j < n; ++j)
1279                 {
1280                         k = stof(argv(j));
1281                         if(k != -1)
1282                         {
1283                                 if ("" == keys)
1284                                         keys = keynumtostring(k);
1285                                 else
1286                                         keys = strcat(keys, ", ", keynumtostring(k));
1287
1288                                 ++l;
1289                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1290                                         break;
1291                         }
1292
1293                 }
1294                 if (keys == "")
1295                         keys = "NO_KEY";
1296                 db_put(binddb, command, keys);
1297         }
1298
1299         if (keys == "NO_KEY") {
1300                 if (autocvar_hud_showbinds > 1)
1301                         return sprintf(_("%s (not bound)"), text);
1302                 else
1303                         return text;
1304         }
1305         else if (autocvar_hud_showbinds > 1)
1306                 return sprintf("%s (%s)", text, keys);
1307         else
1308                 return keys;
1309 }