data/qcsrc/server/vore.qc

   1 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   2 .float complain_vore;\r
   3 .float vore_oldmovetype, vore_oldsolid;\r
   4 \r
   5 const float system_delay_time = 0.1;\r
   6 const float complain_delay_time = 1;\r
   7 const float button_delay_time = 0.5;\r
   8 \r
   9 entity Swallow_player_check()\r
  10 {\r
  11         // check if we can swallow a player instead of firing our weapon\r
  12 \r
  13         float swallow_range;\r
  14         vector vore_w_shotorg, vore_w_shotdir;\r
  15 \r
  16         swallow_range = cvar("g_balance_vore_swallow_range");\r
  17         if(cvar("g_healthsize")) // we can swallow from further or closer based on our size\r
  18                 swallow_range *= self.scale;\r
  19         makevectors(self.angles);\r
  20         vore_w_shotorg = self.origin;\r
  21         vore_w_shotdir = v_forward;\r
  22 \r
  23         if(self.antilag_debug)\r
  24                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, self.antilag_debug);\r
  25         else\r
  26                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  27         if(trace_fraction < 1)\r
  28         if(trace_ent.classname == "player")\r
  29                 return trace_ent;\r
  30         return world;\r
  31 }\r
  32 \r
  33 float Swallow_condition_check(entity prey)\r
  34 {\r
  35         // checks the necessary conditions for swallowing a player\r
  36 \r
  37         if(prey != self)\r
  38         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  39         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  40         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  41         {\r
  42                 float prey_mass;\r
  43                 prey_mass = cvar("g_balance_vore_load_prey_mass");\r
  44                 if(cvar("g_healthsize"))\r
  45                         prey_mass *= prey.scale;\r
  46 \r
  47                 string swallow_complain;\r
  48                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  49                         swallow_complain = "You cannot swallow your team mates\n";\r
  50                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  51                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  52                 else if(self.stomach_load + prey_mass > self.stomach_maxload)\r
  53                         swallow_complain = strcat("You don't have any room to swallow this player. Their mass is ^3", ftos(prey_mass), "^7 and your remaining capacity is ^3", ftos(self.stomach_maxload - self.stomach_load), "\n");\r
  54                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  55                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  56                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  57                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  58 \r
  59                 if(swallow_complain != "")\r
  60                 {\r
  61                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  62                         {\r
  63                                 play2(self, "misc/forbidden.wav");\r
  64                                 sprint(self, swallow_complain);\r
  65                                 self.complain_vore = time + complain_delay_time;\r
  66                         }\r
  67                         return FALSE;\r
  68                 }\r
  69                 return TRUE;\r
  70         }\r
  71         return FALSE;\r
  72 }\r
  73 \r
  74 float Stomach_TeamMates_check(entity pred)\r
  75 {\r
  76         // checks if a player's stomach contains any team mates\r
  77 \r
  78         entity head;\r
  79         if(teams_matter)\r
  80         {\r
  81                 FOR_EACH_PLAYER(head)\r
  82                 {\r
  83                         if(head.predator == pred && head.team == pred.team)\r
  84                                 return TRUE;\r
  85                 }\r
  86         }\r
  87         return FALSE;\r
  88 }\r
  89 \r
  90 float Stomach_HasLivePrey(entity pred)\r
  91 {\r
  92         entity head;\r
  93         FOR_EACH_PLAYER(head)\r
  94         {\r
  95                 if(head.predator == pred)\r
  96                 if(head.deadflag == DEAD_NO)\r
  97                         return TRUE;\r
  98         }\r
  99         return FALSE;\r
 100 }\r
 101 \r
 102 float Vore_CanLeave()\r
 103 {\r
 104         if(self.stat_eaten)\r
 105         {\r
 106                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
 107                         return TRUE;\r
 108                 if(teams_matter && self.team == self.predator.team)\r
 109                         return TRUE;\r
 110                 if(g_rpg && cvar("g_rpg_canleave"))\r
 111                         return TRUE;\r
 112         }\r
 113         return FALSE;\r
 114 }\r
 115 \r
 116 // position the camera properly for prey\r
 117 void Vore_SetPreyPositions(entity pred)\r
 118 {\r
 119         // pred is the predator and head is the prey\r
 120 \r
 121         local entity head;\r
 122 \r
 123         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 124         // else all players overlap in the center. To do this, we use a random origin on all players in the same stomach.\r
 125         FOR_EACH_PLAYER(head)\r
 126         {\r
 127                 if(head.predator == pred)\r
 128                 {\r
 129                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 130                         head.view_ofs_x = PL_PREY_VIEW_OFS_x + crandom() * cvar("g_vore_neighborprey_distance");\r
 131                         head.view_ofs_y = PL_PREY_VIEW_OFS_y + crandom() * cvar("g_vore_neighborprey_distance");\r
 132                         head.view_ofs_z = PL_PREY_VIEW_OFS_z;\r
 133                 }\r
 134         }\r
 135 }\r
 136 \r
 137 .float gurgle_oldstomachload;\r
 138 void Vore_GurgleSound()\r
 139 {\r
 140         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 141         {\r
 142                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 143 \r
 144                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 145                 self.gurgle_oldstomachload = self.stomach_load;\r
 146         }\r
 147 }\r
 148 \r
 149 void Vore_StomachLoad_Apply()\r
 150 {\r
 151         // apply stomach weight that makes you heavier and larger the more you eat\r
 152         // slowing the player is done in cl_physics.qc\r
 153         if(self.classname != "player")\r
 154                 return;\r
 155 \r
 156         entity e;\r
 157         float prey_mass;\r
 158 \r
 159         // apply the stomach capacity of the predator\r
 160         self.stomach_maxload = cvar("g_balance_vore_load_pred_capacity");\r
 161         if(cvar("g_healthsize"))\r
 162                 self.stomach_maxload *= self.scale;\r
 163         self.stomach_maxload = floor(self.stomach_maxload);\r
 164 \r
 165         self.stomach_load = 0; // start from zero\r
 166         FOR_EACH_PLAYER(e)\r
 167         {\r
 168                 if(e.predator == self)\r
 169                 {\r
 170                         prey_mass = cvar("g_balance_vore_load_prey_mass");\r
 171                         if(cvar("g_healthsize"))\r
 172                                 prey_mass *= e.scale;\r
 173                         self.stomach_load += floor(prey_mass);\r
 174                 }\r
 175         }\r
 176         for(e = world; (e = find(e, classname, "consumable")); )\r
 177         {\r
 178                 if(e.predator == self)\r
 179                         self.stomach_load += floor(e.dmg);\r
 180         }\r
 181 \r
 182         // apply weight\r
 183         self.gravity = 1 + (self.stomach_load / self.stomach_maxload) * cvar("g_balance_vore_load_pred_weight");\r
 184         if(!self.gravity && self.stomach_load)\r
 185                 self.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 186 }\r
 187 \r
 188 void Vore_AutoDigest(entity e)\r
 189 {\r
 190         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 191 \r
 192         if(!cvar("g_vore_digestion") || e.digesting)\r
 193                 return;\r
 194         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 195                 return; // this feature is only for players, not bots\r
 196         if(e.stomach_load)\r
 197                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 198         if(Stomach_TeamMates_check(e))\r
 199                 return; // never begin automatic digestion if we've swallowed a team mate\r
 200 \r
 201         e.digesting = TRUE;\r
 202 }\r
 203 \r
 204 .entity swallow_model;\r
 205 float Vore_SwallowModel_CustomizeEntityForClient()\r
 206 {\r
 207         // use the same system as the weapon model\r
 208 \r
 209         self.viewmodelforclient = self.owner;\r
 210         self.alpha = self.owner.cvar_cl_vore_swallowmodel;\r
 211 \r
 212         if(other.classname == "spectator")\r
 213         if(other.enemy == self.owner)\r
 214         {\r
 215                 self.viewmodelforclient = other;\r
 216                 self.alpha = other.cvar_cl_vore_swallowmodel;\r
 217         }\r
 218 \r
 219         return TRUE;\r
 220 }\r
 221 \r
 222 void Vore_SwallowModel_Think()\r
 223 {\r
 224         // update the position of the swallow model to match our swallow progress\r
 225         float dist;\r
 226         dist = (-0.5 + self.owner.swallow_progress_prey) * cvar("g_vore_swallowmodel_range"); // the model is centered at 0.5 progress\r
 227         if(cvar("g_healthsize"))\r
 228                 dist *= self.scale;\r
 229         self.view_ofs = '1 0 0' * dist;\r
 230 \r
 231         // if our swallow progress is gone or we are dead, the swallow model also goes away\r
 232         if(!self.owner.swallow_progress_prey || self.owner.deadflag != DEAD_NO || self.owner.classname != "player")\r
 233         {\r
 234                 remove(self.owner.swallow_model);\r
 235                 self.owner.swallow_model = world;\r
 236                 return;\r
 237         }\r
 238 \r
 239         // properties that should update whenever possible, but when the predator is not available\r
 240         self.nextthink = time;\r
 241 }\r
 242 \r
 243 void Vore_SwallowModel_Update(entity prey, entity pred)\r
 244 {\r
 245         // if we don't have a swallow model already, spawn one\r
 246         if(!prey.swallow_model)\r
 247         {\r
 248                 prey.swallow_model = spawn();\r
 249                 prey.swallow_model.movetype = MOVETYPE_FOLLOW;\r
 250                 prey.swallow_model.solid = SOLID_NOT;\r
 251                 //prey.swallow_model.effects |= EF_NOGUNBOB; // let it bob\r
 252                 prey.swallow_model.effects |= EF_NODEPTHTEST; // don't hide behind walls\r
 253                 prey.swallow_model.owner = prey;\r
 254                 prey.swallow_model.customizeentityforclient = Vore_SwallowModel_CustomizeEntityForClient;\r
 255                 prey.swallow_model.think = Vore_SwallowModel_Think;\r
 256                 prey.swallow_model.nextthink = time;\r
 257         }\r
 258 \r
 259         // properties that should update whenever possible, but when the predator is available\r
 260         string player_swallowmodel;\r
 261         player_swallowmodel = strcat(substring(pred.playermodel, 0, strlen(pred.playermodel) - 4), "_swallow.md3"); // 4 is the extension length\r
 262         if(prey.swallow_model.model != player_swallowmodel) // player model can be changed while the predator is active\r
 263                 setmodel(prey.swallow_model, player_swallowmodel);\r
 264         if(prey.swallow_model.skin != pred.skin) // player skin can be changed while the predator is active\r
 265                 prey.swallow_model.skin = pred.skin;\r
 266         if(cvar("g_healthsize"))\r
 267                 prey.swallow_model.scale = pred.scale / prey.scale; // player size difference\r
 268         if(prey.swallow_model.enemy != pred)\r
 269                 prey.swallow_model.enemy = pred; // enemy is the predator\r
 270         if(prey.swallow_model.colormap != pred.colormap)\r
 271                 prey.swallow_model.colormap = pred.colormap; // pants and shirt color\r
 272         if(prey.swallow_model.glowmod != pred.glowmod)\r
 273                 prey.swallow_model.glowmod = pred.glowmod; // glow color\r
 274 }\r
 275 \r
 276 .entity pusher;\r
 277 .float pushltime;\r
 278 void Vore_Swallow(entity e)\r
 279 {\r
 280         // this player is being swallowed by another player, apply the proper changes\r
 281 \r
 282         e.vore_oldmovetype = e.movetype;\r
 283         e.vore_oldsolid = e.solid;\r
 284         e.punchvector_z = cvar("g_balance_vore_swallow_prey_punchvector");\r
 285 \r
 286         e.predator = self;\r
 287         setorigin(e, e.predator.origin);\r
 288         e.velocity = '0 0 0';\r
 289         e.movetype = MOVETYPE_FOLLOW;\r
 290         e.solid = SOLID_NOT;\r
 291         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 292 \r
 293         // drop keys (KH) and flags (CTF) when we get swallowed\r
 294         kh_Key_DropAll(e, FALSE);\r
 295         if(e.flagcarried)\r
 296                 DropFlag(e.flagcarried, world, e.predator);\r
 297 \r
 298         if(stov(cvar_string("g_vore_regurgitatecolor_color_normal")))\r
 299                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_color_normal"));\r
 300 \r
 301         if(teams_matter && e.team == e.predator.team)\r
 302         {\r
 303                 if(cvar("g_vore_kick"))\r
 304                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 305                 if(cvar("g_vore_digestion"))\r
 306                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 307         }\r
 308 \r
 309         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 310         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 311         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_predator_punchangle");\r
 312         e.predator.regurgitate_prepare = 0;\r
 313         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 314         e.predator.hitsound += 1; // play this for team mates too, as we could be swallowing them to heal them\r
 315         Vore_AutoDigest(e.predator);\r
 316         Vore_SetPreyPositions(e.predator);\r
 317 \r
 318         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 319         e.predator.weapon_delay = time + button_delay_time;\r
 320         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 321         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 322         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 323 }\r
 324 \r
 325 void Vore_SwallowStep(entity e)\r
 326 {\r
 327         if(!cvar("g_balance_vore_swallow_speed_fill"))\r
 328         {\r
 329                 Vore_Swallow(e);\r
 330                 return;\r
 331         }\r
 332 \r
 333         Vore_SwallowModel_Update(e, self);\r
 334 \r
 335         // increase the progress value until it reaches 1, then swallow the player\r
 336         if(e.swallow_progress_prey < 1)\r
 337         {\r
 338                 float fill;\r
 339                 fill = cvar("g_balance_vore_swallow_speed_fill") * frametime;\r
 340                 if(cvar("g_healthsize") && cvar("g_balance_vore_swallow_speed_fill_scalediff")) // fill rate depends on predator size compared to prey size\r
 341                         fill *= pow(self.scale / e.scale, cvar("g_balance_vore_swallow_speed_fill_scalediff"));\r
 342                 if(cvar("g_balance_vore_swallow_speed_fill_stomachload") && e.stomach_load) // fill rate is influenced by the prey's stomach load\r
 343                         fill /= e.stomach_load;\r
 344 \r
 345                 e.swallow_progress_prey += fill;\r
 346         }\r
 347         else\r
 348         {\r
 349                 Vore_Swallow(e);\r
 350                 e.swallow_progress_prey = 0;\r
 351         }\r
 352 \r
 353         // the predator's progress is how much the prey got swallowed\r
 354         self.swallow_progress_pred = e.swallow_progress_prey;\r
 355 }\r
 356 \r
 357 void Vore_Regurgitate(entity e)\r
 358 {\r
 359         // this player is being regurgitated by their predator, apply the proper changes\r
 360 \r
 361         e.movetype = e.vore_oldmovetype;\r
 362         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 363                 e.solid = e.vore_oldsolid;\r
 364         e.view_ofs_z = PL_VIEW_OFS_z;\r
 365         e.punchvector_z = -cvar("g_balance_vore_regurgitate_prey_punchvector");\r
 366 \r
 367         // if the prey has been fully digested, silently detach them\r
 368         if(e.deadflag != DEAD_NO && e.health <= cvar("g_balance_vore_digestion_limit"))\r
 369         {\r
 370                 e.predator = world;\r
 371                 e.modelindex = 0; // hide the dead body\r
 372                 return;\r
 373         }\r
 374 \r
 375         // apply velocities\r
 376         makevectors(e.predator.v_angle);\r
 377         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 378         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 379         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 380         e.pushltime = time + cvar("g_maxpushtime");\r
 381 \r
 382         // if the dead body of the prey is below gibbing health, gib it\r
 383         e.stat_eaten = 0; // necessary for gibs to show\r
 384         PlayerGib(e, e.predator);\r
 385 \r
 386         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
 387         if(cvar("g_balance_vore_swallow_speed_fill") && cvar("g_balance_vore_regurgitate_swallowprogress"))\r
 388         {\r
 389                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
 390                 Vore_SwallowModel_Update(e, e.predator);\r
 391         }\r
 392 \r
 393         // apply regurgitation damage to the predator\r
 394         if(cvar("g_balance_vore_regurgitate_damage"))\r
 395         {\r
 396                 float regurgitate_dmg;\r
 397                 regurgitate_dmg = cvar("g_balance_vore_regurgitate_damage");\r
 398                 if(cvar("g_healthsize"))\r
 399                         regurgitate_dmg *= e.scale / e.predator.scale;\r
 400                 Damage(e.predator, e, e, regurgitate_dmg, DEATH_REGURGITATION, e.predator.origin, '0 0 0');\r
 401         }\r
 402 \r
 403         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 404         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 405         pointparticles(particleeffectnum("vore_regurgitate"), e.predator.origin, '0 0 0', 1);\r
 406         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_predator_punchangle");\r
 407         e.predator.regurgitate_prepare = 0;\r
 408         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 409         Vore_SetPreyPositions(e.predator);\r
 410 \r
 411         // block firing for a small amount of time, or we'll be firing the next frame\r
 412         e.weapon_delay = time + button_delay_time;\r
 413         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 414         e.predator = world;\r
 415 }\r
 416 \r
 417 void Vore_Disconnect()\r
 418 {\r
 419         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 420 \r
 421         // prey disconnects or goes spectating while inside someone's belly\r
 422         if(self.stat_eaten)\r
 423                 Vore_Regurgitate(self);\r
 424 \r
 425         // pred disconnects or goes spectating with players in their belly\r
 426         entity head;\r
 427         FOR_EACH_PLAYER(head)\r
 428         {\r
 429                 if(head.predator == self)\r
 430                         Vore_Regurgitate(head);\r
 431         }\r
 432         Vore_GurgleSound(); // stop the gurgling sound\r
 433 \r
 434         self.stomach_load = self.gravity = 0; // prevents a bug\r
 435 }\r
 436 \r
 437 .float digestion_step;\r
 438 void Vore_Digest()\r
 439 {\r
 440         // apply digestion to prey\r
 441 \r
 442         if(self.predator.deadflag != DEAD_NO) // dead predators don't digest\r
 443         {\r
 444                 self.predator.digesting = FALSE;\r
 445                 return;\r
 446         }\r
 447         if(self.health <= cvar("g_balance_vore_digestion_limit")) // don't digest below this amount of health\r
 448                 return;\r
 449 \r
 450         if(time > self.digestion_step)\r
 451         {\r
 452                 // if distributed digestion is enabled, reduce digestion strength by the amount of prey in our stomach\r
 453                 float damage, damage_offset;\r
 454 \r
 455                 damage_offset = 1;\r
 456                 if(cvar("g_balance_vore_digestion_distribute")) // apply distributed digestion damage\r
 457                         damage_offset *= self.predator.stomach_load / self.predator.stomach_maxload;\r
 458                 if(cvar("g_healthsize") && cvar("g_balance_vore_digestion_scalediff")) // apply player scale to digestion damage\r
 459                         damage_offset *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_digestion_scalediff"));\r
 460                 damage_offset = ceil(damage_offset);\r
 461 \r
 462                 damage = cvar("g_balance_vore_digestion_damage") / damage_offset;\r
 463                 if(cvar("g_balance_vore_digestion_damage_death") && self.deadflag != DEAD_NO) // amplify digestion damage for dead prey\r
 464                         damage *= cvar("g_balance_vore_digestion_damage_death");\r
 465 \r
 466                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
 467                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 468                         self.predator.health += damage * cvar("g_balance_vore_digestion_vampire");\r
 469 \r
 470                 if (self.predator.digestsound_finished < time)\r
 471                 {\r
 472                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 473                         self.predator.digestsound_finished = time + 0.5;\r
 474                 }\r
 475                 self.digestion_step = time + vore_steptime;\r
 476         }\r
 477 \r
 478         if(stov(cvar_string("g_vore_regurgitatecolor_color_digest")))\r
 479                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_color_digest"));\r
 480 }\r
 481 \r
 482 .float teamheal_step;\r
 483 void Vore_Teamheal()\r
 484 {\r
 485         // apply teamheal\r
 486 \r
 487         if(self.deadflag != DEAD_NO)\r
 488                 return;\r
 489 \r
 490         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 491         if(time > self.teamheal_step)\r
 492         {\r
 493                 self.health += cvar("g_balance_vore_teamheal");\r
 494                 self.teamheal_step = time + vore_steptime;\r
 495 \r
 496                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 497                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 498                 {\r
 499                         play2(self, "misc/beep.wav");\r
 500                         play2(self.predator, "misc/beep.wav");\r
 501                 }\r
 502         }\r
 503 }\r
 504 \r
 505 .float kick_pressed;\r
 506 void Vore_StomachKick()\r
 507 {\r
 508         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 509 \r
 510         if(self.deadflag != DEAD_NO)\r
 511                 return;\r
 512 \r
 513         if(time > self.stomachkick_delay && !self.kick_pressed)\r
 514         {\r
 515                 float damage, vol;\r
 516                 vector force;\r
 517                 damage = cvar("g_balance_vore_kick_damage");\r
 518                 force = v_forward * cvar("g_balance_vore_kick_force");\r
 519                 vol = VOL_BASE;\r
 520 \r
 521                 // apply player scale to the damage / force of the kick\r
 522                 if(cvar("g_healthsize") && cvar("g_balance_vore_kick_scalediff"))\r
 523                 {\r
 524                         damage *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 525                         force *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 526                         vol *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff")); // kick sound volume based on the same scale\r
 527                 }\r
 528                 vol = bound(0, vol, 1);\r
 529 \r
 530                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
 531                 sound(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), vol, ATTN_NORM);\r
 532                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 533                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 534 \r
 535                 // abort the predator's scheduled regurgitation\r
 536                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
 537                         self.predator.regurgitate_prepare = 0;\r
 538 \r
 539                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 540                 if(cvar("g_balance_vore_kick_repress"))\r
 541                 if not(clienttype(self) == CLIENTTYPE_BOT) // not for bots, to prevent an issue\r
 542                         self.kick_pressed = TRUE;\r
 543         }\r
 544 }\r
 545 \r
 546 void Vore_StomachLeave()\r
 547 {\r
 548         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 549 \r
 550         if(self.deadflag != DEAD_NO)\r
 551                 return;\r
 552 \r
 553         if(Vore_CanLeave())\r
 554                 Vore_Regurgitate(self);\r
 555         else if(time > self.complain_vore)\r
 556         {\r
 557                 play2(self, "misc/forbidden.wav");\r
 558                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 559                 self.complain_vore = time + complain_delay_time;\r
 560         }\r
 561 }\r
 562 \r
 563 void Vore_AutoTaunt()\r
 564 {\r
 565         // triggers ambient vore taunts, for both pred and prey\r
 566 \r
 567         float taunt_time;\r
 568 \r
 569         // predator taunts\r
 570         if((self.swallow_progress_pred || (self.stomach_load && Stomach_HasLivePrey(self))) && !Stomach_TeamMates_check(self))\r
 571         {\r
 572                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 573                 {\r
 574                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 575                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 576                 }\r
 577         }\r
 578         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 579         {\r
 580                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 581                 SetAutoTaunt(self, 0, 0);\r
 582         }\r
 583 \r
 584         // prey taunts\r
 585         if((self.swallow_progress_prey || (self.stat_eaten && !(teams_matter && self.team == self.predator.team))) && self.deadflag == DEAD_NO)\r
 586         {\r
 587                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 588                 {\r
 589                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 590                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 591                 }\r
 592         }\r
 593         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 594         {\r
 595                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 596                 SetAutoTaunt(self, 0, 0);\r
 597         }\r
 598 }\r
 599 \r
 600 void Vore_SetSbarRings()\r
 601 {\r
 602         // first clear the ring stats, then configure them if needed\r
 603         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 604         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 605 \r
 606         if(self.stat_eaten)\r
 607         {\r
 608                 if(time <= self.stomachkick_delay)\r
 609                 {\r
 610                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
 611                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 612                 }\r
 613         }\r
 614         else\r
 615         {\r
 616                 if(self.swallow_progress_pred)\r
 617                 {\r
 618                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
 619                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
 620                 }\r
 621                 else if(time <= self.action_delay)\r
 622                 {\r
 623                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
 624                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 625                 }\r
 626 \r
 627                 if(self.swallow_progress_prey)\r
 628                 {\r
 629                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
 630                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
 631                 }\r
 632                 else if(time <= self.regurgitate_prepare)\r
 633                 {\r
 634                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
 635                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 636                 }\r
 637         }\r
 638 }\r
 639 \r
 640 .float regurgitatecolor_particles_tick;\r
 641 void Vore()\r
 642 {\r
 643         // main vore code, this is where it all happens\r
 644 \r
 645         Vore_AutoTaunt();\r
 646 \r
 647         if(!self.stat_eaten)\r
 648         if(self.modelindex) // not if we're a gibbed dead body or not visible any more\r
 649         if(self.colormod)\r
 650         if(self.colormod != '1 1 1')\r
 651         {\r
 652                 // slowly wash stomach fluids off players once they're out of the stomach\r
 653                 if(cvar("g_vore_regurgitatecolor_fade"))\r
 654                 if(self.deadflag == DEAD_NO) // not for dead bodies\r
 655                 {\r
 656                         float goo_fade;\r
 657                         goo_fade = cvar("g_vore_regurgitatecolor_fade") * frametime;\r
 658                         goo_fade *= 1 + self.waterlevel; // fade faster when underwater\r
 659 \r
 660                         self.colormod_x += goo_fade;\r
 661                         if(self.colormod_x > 1)\r
 662                                 self.colormod_x = 1;\r
 663                         self.colormod_y += goo_fade;\r
 664                         if(self.colormod_y > 1)\r
 665                                 self.colormod_y = 1;\r
 666                         self.colormod_z += goo_fade;\r
 667                         if(self.colormod_z > 1)\r
 668                                 self.colormod_z = 1;\r
 669                 }\r
 670 \r
 671                 // constant particles falling off dirty players\r
 672                 if(cvar("g_vore_regurgitatecolor_particles"))\r
 673                 if(self.regurgitatecolor_particles_tick < time)\r
 674                 {\r
 675                         pointparticles(particleeffectnum("vore_regurgitate_constant"), self.origin, '0 0 0', 1);\r
 676                         self.regurgitatecolor_particles_tick = time + cvar("g_vore_regurgitatecolor_particles") * vlen(self.colormod); // particle time depends on how dirty the player is\r
 677                 }\r
 678         }\r
 679 \r
 680         // set all vore stats\r
 681         Vore_SetSbarRings();\r
 682         if(self.predator.classname == "player")\r
 683         {\r
 684                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 685                 self.stat_stomachmaxload = self.predator.stomach_maxload; // necessary for the stomach board\r
 686                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 687                 self.stat_eaten = num_for_edict(self.predator);\r
 688         }\r
 689         else\r
 690         {\r
 691                 self.stat_stomachload = self.stomach_load;\r
 692                 self.stat_stomachmaxload = self.stomach_maxload;\r
 693                 self.stat_digesting = self.digesting;\r
 694                 self.stat_eaten = 0;\r
 695         }\r
 696         self.stat_canleave = Vore_CanLeave();\r
 697 \r
 698         // don't allow a player inside a player inside another player :)\r
 699         // prevent this by checking if such has happened, and taking the proper measures\r
 700         // this code has a high priority and must not be stopped by any delay, so run it here\r
 701         if(self.predator.stat_eaten)\r
 702                 Vore_Regurgitate(self);\r
 703 \r
 704         // the swallow progress of prey and preds idly decrease by this amount\r
 705         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
 706         {\r
 707                 if(self.swallow_progress_pred)\r
 708                 {\r
 709                         self.swallow_progress_pred -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 710                         if(self.swallow_progress_pred < 0)\r
 711                                 self.swallow_progress_pred = 0;\r
 712                 }\r
 713                 if(self.swallow_progress_prey)\r
 714                 {\r
 715                         self.swallow_progress_prey -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 716                         if(self.swallow_progress_prey < 0)\r
 717                                 self.swallow_progress_prey = 0;\r
 718                 }\r
 719         }\r
 720 \r
 721         // set the predator's stomach load and capacity\r
 722         Vore_StomachLoad_Apply();\r
 723 \r
 724         // apply delays and skip the vore system under some circumstances\r
 725         if(!cvar("g_vore")) // the vore system is disabled\r
 726         {\r
 727                 Vore_Disconnect();\r
 728                 return;\r
 729         }\r
 730         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 731         {\r
 732                 Vore_Disconnect();\r
 733                 return;\r
 734         }\r
 735         if(self.spectatee_status)\r
 736                 return;\r
 737         if(time < self.system_delay)\r
 738                 return;\r
 739 \r
 740 // --------------------------------\r
 741 // Code that addresses predators:\r
 742 // --------------------------------\r
 743 \r
 744         entity prey;\r
 745         prey = Swallow_player_check();\r
 746 \r
 747         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 748         self.stat_canswallow = 0;\r
 749         if(Swallow_condition_check(prey))\r
 750         {\r
 751                 // canswallow stat, used by the HUD\r
 752                 if(teams_matter && prey.team == self.team)\r
 753                         self.stat_canswallow = 2;\r
 754                 else\r
 755                         self.stat_canswallow = 1;\r
 756 \r
 757                 if(self.BUTTON_ATCK)\r
 758                         Vore_SwallowStep(prey);\r
 759         }\r
 760         else if(prey != world)\r
 761                 self.stat_canswallow = -1;\r
 762 \r
 763         // toggle digestion, if the player has someone in their stomach\r
 764         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 765         {\r
 766                 if(self.stomach_load)\r
 767                 {\r
 768                         if(time > self.digest_button_delay_time)\r
 769                         {\r
 770                                 self.digesting = !self.digesting;\r
 771                                 self.digest_button_delay_time = time + button_delay_time;\r
 772                         }\r
 773                 }\r
 774                 else if(time > self.complain_vore)\r
 775                 {\r
 776                         play2(self, "misc/forbidden.wav");\r
 777                         sprint(self, "There is nothing to digest\n");\r
 778                         self.complain_vore = time + complain_delay_time;\r
 779                 }\r
 780         }\r
 781         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 782                 self.digesting = FALSE;\r
 783 \r
 784         // predator wishes to regurgitate his prey\r
 785         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 786         {\r
 787                 if(self.stomach_load)\r
 788                 {\r
 789                         if(time > self.regurgitate_button_delay_time)\r
 790                         {\r
 791                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 792                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 793                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE); // looks good for preparing regurgitation\r
 794                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 795                         }\r
 796                 }\r
 797                 else if(time > self.complain_vore)\r
 798                 {\r
 799                         play2(self, "misc/forbidden.wav");\r
 800                         sprint(self, "There is nothing to regurgitate\n");\r
 801                         self.complain_vore = time + complain_delay_time;\r
 802                 }\r
 803         }\r
 804 \r
 805         if(self.stomach_load > self.stomach_maxload) // the predator got beyond his capacity after eating, so some prey must pop out\r
 806         {\r
 807                 self.regurgitate_prepare = -1;\r
 808                 return;\r
 809         }\r
 810         if(cvar("g_balance_vore_load_pred_speedcap") && self.stomach_load && vlen(self.velocity) >= cvar("g_balance_vore_load_pred_speedcap") / (self.stomach_load / self.stomach_maxload)) // predator's going too fast, gets sick and throws up\r
 811         {\r
 812                 self.regurgitate_prepare = -1;\r
 813                 return;\r
 814         }\r
 815 \r
 816         if(cvar("g_vore_gurglesound"))\r
 817                 Vore_GurgleSound();\r
 818 \r
 819 // --------------------------------\r
 820 // Code that addresses the prey:\r
 821 // --------------------------------\r
 822 \r
 823         if(!self.stat_eaten)\r
 824                 return;\r
 825 \r
 826         if(self.deadflag != DEAD_NO && self.health < cvar("g_balance_vore_digestion_limit")) // make sure health doesn't go below the limit\r
 827                 self.health = cvar("g_balance_vore_digestion_limit");\r
 828 \r
 829         // automatically regurgitate prey that has reached their digestion limit\r
 830         if(cvar("g_balance_vore_digestion_limit_regurgitate"))\r
 831         if(self.health <= cvar("g_balance_vore_digestion_limit"))\r
 832         {\r
 833                 Vore_Regurgitate(self);\r
 834                 return;\r
 835         }\r
 836 \r
 837         // do we stick around inside dead furries? x_x\r
 838         if(self.predator.deadflag != DEAD_NO)\r
 839         {\r
 840                 if(!cvar("g_balance_vore_deadpredator") || !self.predator.modelindex) // if the predator is gibbed, we are out\r
 841                 {\r
 842                         Vore_Regurgitate(self);\r
 843                         return;\r
 844                 }\r
 845                 if(self.predator.regurgitate_prepare) // abort scheduled regurgitation\r
 846                         self.predator.regurgitate_prepare = 0;\r
 847         }\r
 848 \r
 849         // apply delayed regurgitating if it was scheduled\r
 850         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 851         {\r
 852                 self.predator.regurgitate_prepare = 0;\r
 853                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 854                 Vore_Regurgitate(self);\r
 855         }\r
 856 \r
 857         // execute digesting and team healing\r
 858         if(self.predator.digesting == TRUE)\r
 859                 Vore_Digest();\r
 860         if(teams_matter && self.team == self.predator.team)\r
 861         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 862                 Vore_Teamheal();\r
 863 \r
 864         // execute prey commands\r
 865         if(self.BUTTON_ATCK)\r
 866         {\r
 867                 if(cvar("g_vore_kick"))\r
 868                         Vore_StomachKick();\r
 869         }\r
 870         else\r
 871                 self.kick_pressed = FALSE;\r
 872         if(self.BUTTON_JUMP)\r
 873                 Vore_StomachLeave();\r
 874 \r
 875         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 876         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 877         kh_Key_DropAll(self, FALSE);\r
 878 \r
 879         // always position camera at the center of the stomach, to reduce probability of the view poking out\r
 880         self.view_ofs_z = PL_PREY_VIEW_OFS_z * self.predator.scale;\r
 881 }